cgit.sxemacs.org Git - riece/blob - lisp/riece-server.el

   1 ;;; riece-server.el --- functions to open and close servers
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-options)
  28 (require 'riece-globals)                ;for server local variables.
  29 (require 'riece-coding)                 ;riece-default-coding-system
  30 (require 'riece-identity)
  31 (require 'riece-compat)
  32
  33 (eval-and-compile
  34   (defvar riece-server-keyword-map
  35     '((:host)
  36       (:service 6667)
  37       (:nickname riece-nickname)
  38       (:username riece-username)
  39       (:password)
  40       (:function riece-default-open-connection-function)
  41       (:coding riece-default-coding-system))
  42     "Mapping from keywords to default values.
  43 All keywords that can be used must be listed here."))
  44
  45 (defmacro riece-server-keyword-bind (plist &rest body)
  46   "Return a `let' form that binds all variables in PLIST.
  47 After this is done, BODY will be executed in the scope
  48 of the `let' form.
  49
  50 The variables bound and their default values are described by
  51 the `riece-server-keyword-map' variable."
  52   `(let ,(mapcar
  53           (lambda (keyword)
  54             (list (intern (substring (symbol-name (car keyword)) 1))
  55                   (if (cadr keyword)
  56                       `(or (plist-get ,plist ',(car keyword))
  57                            ,(cadr keyword))
  58                     `(plist-get ,plist ',(car keyword)))))
  59           riece-server-keyword-map)
  60      ,@body))
  61
  62 (put 'riece-server-keyword-bind 'lisp-indent-function 1)
  63 (put 'riece-server-keyword-bind 'edebug-form-spec '(form body))
  64
  65 (defun riece-server-parse-string (string)
  66   "Convert a STRING set as `riece-server' and return a property list."
  67   (when (or (string-match "^\\[\\([^]]+\\)\\]:?\\([0-9]*\\)" string)
  68             (string-match "^\\([^:]+\\):?\\([0-9]*\\)" string))
  69     (let ((host (match-string 1 string))
  70           (service (match-string 2 string))
  71           (password (substring string (match-end 0)))
  72           plist)
  73       (setq plist (cons `(:host ,host) plist))
  74       (unless (equal service "")
  75         (setq plist (cons `(:service ,(string-to-int service)) plist)))
  76       (unless (equal password "")
  77         (setq plist (cons `(:password ,(substring password 1)) plist)))
  78       (apply #'nconc plist))))
  79
  80 (defun riece-server-name-to-server (server-name)
  81   (let ((entry (assoc server-name riece-server-alist)))
  82     (if entry
  83         (unless (listp (cdr entry))
  84           (setcdr entry (riece-server-parse-string (cdr entry))))
  85       (setq entry (cons server-name (riece-server-parse-string server-name))
  86             riece-server-alist (cons entry riece-server-alist)
  87             riece-save-variables-are-dirty t))
  88     (cdr entry)))
  89
  90 (defun riece-server-process-name (server-name)
  91   (if (equal server-name "")
  92       "IRC"
  93     (format "IRC<%s>" server-name)))
  94
  95 (defun riece-server-process (server-name)
  96   (cdr (assoc server-name riece-server-process-alist)))
  97
  98 (defmacro riece-with-server-buffer (server-name &rest body)
  99   `(let ((process (riece-server-process ,server-name)))
 100      (if process
 101          (with-current-buffer (process-buffer process)
 102            ,@body)
 103        (error "Server closed"))))
 104
 105 (put 'riece-with-server-buffer 'lisp-indent-function 1)
 106 (put 'riece-with-server-buffer 'edebug-form-spec '(form body))
 107
 108 (defun riece-process-send-string (process string)
 109   (with-current-buffer (process-buffer process)
 110     (process-send-string process (riece-encode-coding-string string))))
 111
 112 (defun riece-current-server-name ()
 113   (or riece-overriding-server-name
 114                                         ;already in the server buffer
 115       (if (local-variable-p 'riece-server-name (current-buffer))
 116           riece-server-name
 117         (if riece-current-channel
 118             (riece-identity-server riece-current-channel)
 119           (if (riece-server-opened "")
 120               "")))))
 121
 122 (defun riece-send-string (string)
 123   (let* ((server-name (riece-current-server-name))
 124          (process (riece-server-process server-name)))
 125     (unless process
 126       (error "%s" (substitute-command-keys
 127                    "Type \\[riece-command-open-server] to open server.")))
 128     (riece-process-send-string process string)))
 129
 130 (defun riece-open-server (server server-name)
 131   (let ((protocol (or (plist-get server :protocol)
 132                       riece-protocol))
 133         function
 134         process)
 135     (condition-case nil
 136         (require (intern (concat "riece-" (symbol-name protocol))))
 137       (error))
 138     (setq function (intern-soft (concat "riece-"
 139                                         (symbol-name protocol)
 140                                         "-open-server")))
 141     (unless function
 142       (error "\"%S\" is not supported" protocol))
 143     (condition-case nil
 144         (setq process (funcall function server server-name))
 145       (error))
 146     (when process
 147       (with-current-buffer (process-buffer process)
 148         (make-local-variable 'riece-protocol)
 149         (setq riece-protocol protocol))
 150       (setq riece-server-process-alist
 151             (cons (cons server-name process)
 152                   riece-server-process-alist)))))
 153
 154 (defun riece-quit-server-process (process &optional message)
 155   (let ((function (intern-soft
 156                    (concat "riece-"
 157                            (with-current-buffer (process-buffer process)
 158                              (symbol-name riece-protocol))
 159                            "-quit-server-process"))))
 160     (if function
 161         (funcall function process message))))
 162
 163 (defun riece-reset-process-buffer (process)
 164   (save-excursion
 165     (set-buffer (process-buffer process))
 166     (if (fboundp 'set-buffer-multibyte)
 167         (set-buffer-multibyte nil))
 168     (kill-all-local-variables)
 169     (make-local-variable 'riece-real-nickname)
 170     (make-local-variable 'riece-last-nickname)
 171     (make-local-variable 'riece-nick-accepted)
 172     (make-local-variable 'riece-real-server-name)
 173     (make-local-variable 'riece-real-userhost)
 174     (make-local-variable 'riece-user-at-host)
 175     (make-local-variable 'riece-user-at-host-type)
 176     (make-local-variable 'riece-supported-user-modes)
 177     (make-local-variable 'riece-supported-channel-modes)
 178     (make-local-variable 'riece-channel-filter)
 179     (make-local-variable 'riece-server-name)
 180     (make-local-variable 'riece-read-point)
 181     (setq riece-read-point (point-min))
 182     (make-local-variable 'riece-obarray)
 183     (setq riece-obarray (make-vector riece-obarray-size 0))
 184     (make-local-variable 'riece-coding-system)
 185     (buffer-disable-undo)
 186     (erase-buffer)))
 187
 188 (defun riece-close-server-process (process)
 189   (kill-buffer (process-buffer process))
 190   (setq riece-server-process-alist
 191         (delq (rassq process riece-server-process-alist)
 192               riece-server-process-alist)))
 193
 194 (defun riece-server-process-opened (process)
 195   (not (null (memq (process-status process) '(open run)))))
 196
 197 (defun riece-server-opened (&optional server-name)
 198   (if server-name
 199       (let ((process (riece-server-process server-name)))
 200         (and process
 201              (riece-server-process-opened process)))
 202     (let ((alist riece-server-process-alist))
 203       (catch 'found
 204         (while alist
 205           (if (riece-server-process-opened (cdr (car alist)))
 206               (throw 'found t))
 207           (setq alist (cdr alist)))))))
 208
 209 (provide 'riece-server)
 210
 211 ;;; riece-server.el ends here