cgit.sxemacs.org Git - packages/blob - xemacs-packages/w3/lisp/url-handlers.el

   1 ;;; url-handlers.el --- file-name-handler stuff for URL loading
   2
   3 ;; Copyright (C) 1996-1999, 2004-2012  Free Software Foundation, Inc.
   4
   5 ;; Keywords: comm, data, processes, hypermedia
   6
   7 ;; This file is part of GNU Emacs.
   8 ;;
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 ;; (require 'url)
  27 (require 'url-parse)
  28 ;; (require 'url-util)
  29 (eval-when-compile (require 'mm-decode))
  30 ;; (require 'mailcap)
  31 ;; The following functions in the byte compiler's warnings are known not
  32 ;; to cause any real problem for the following reasons:
  33 ;; - mm-save-part-to-file, mm-destroy-parts: always used
  34 ;;   after mm-dissect-buffer and defined in the same file.
  35 ;; The following are autoloaded instead of `require'd to avoid eagerly
  36 ;; loading all of URL when turning on url-handler-mode in the .emacs.
  37 (autoload 'url-expand-file-name "url-expand" "Convert url to a fully specified url, and canonicalize it.")
  38 (autoload 'mm-dissect-buffer "mm-decode" "Dissect the current buffer and return a list of MIME handles.")
  39 (autoload 'url-scheme-get-property "url-methods" "Get property of a URL SCHEME.")
  40
  41 ;; Implementation status
  42 ;; ---------------------
  43 ;; Function                             Status
  44 ;; ------------------------------------------------------------
  45 ;; add-name-to-file                     Needs DAV Bindings
  46 ;; copy-file                            Broken (assumes 1st item is URL)
  47 ;; delete-directory                     Finished (DAV)
  48 ;; delete-file                          Finished (DAV)
  49 ;; diff-latest-backup-file
  50 ;; directory-file-name                  unnecessary (what about VMS)?
  51 ;; directory-files                      Finished (DAV)
  52 ;; dired-call-process
  53 ;; dired-compress-file
  54 ;; dired-uncache
  55 ;; expand-file-name                     Finished
  56 ;; file-accessible-directory-p
  57 ;; file-attributes                      Finished, better with DAV
  58 ;; file-directory-p                     Needs DAV, finished
  59 ;; file-executable-p                    Finished
  60 ;; file-exists-p                        Finished
  61 ;; file-local-copy
  62 ;; file-modes
  63 ;; file-name-all-completions            Finished (DAV)
  64 ;; file-name-as-directory
  65 ;; file-name-completion                 Finished (DAV)
  66 ;; file-name-directory
  67 ;; file-name-nondirectory
  68 ;; file-name-sans-versions              why?
  69 ;; file-newer-than-file-p
  70 ;; file-ownership-preserved-p           No way to know
  71 ;; file-readable-p                      Finished
  72 ;; file-regular-p                       !directory_p
  73 ;; file-remote-p                        Finished
  74 ;; file-symlink-p                       Needs DAV bindings
  75 ;; file-truename                        Needs DAV bindings
  76 ;; file-writable-p                      Check for LOCK?
  77 ;; find-backup-file-name                why?
  78 ;; get-file-buffer                      why?
  79 ;; insert-directory                     Use DAV
  80 ;; insert-file-contents                 Finished
  81 ;; load
  82 ;; make-directory                       Finished (DAV)
  83 ;; make-symbolic-link                   Needs DAV bindings
  84 ;; rename-file                          Finished (DAV)
  85 ;; set-file-modes                       Use mod_dav specific executable flag?
  86 ;; set-visited-file-modtime             Impossible?
  87 ;; shell-command                        Impossible?
  88 ;; unhandled-file-name-directory
  89 ;; vc-registered                        Finished (DAV)
  90 ;; verify-visited-file-modtime
  91 ;; write-region
  92
  93 (defvar url-handler-regexp
  94   "\\`\\(https?\\|ftp\\|file\\|nfs\\)://"
  95   "A regular expression for matching URLs handled by `file-name-handler-alist'.
  96 Some valid URL protocols just do not make sense to visit interactively
  97 \(about, data, info, irc, mailto, etc\).  This regular expression
  98 avoids conflicts with local files that look like URLs \(Gnus is
  99 particularly bad at this\).")
 100
 101 ;;;###autoload
 102 (define-minor-mode url-handler-mode
 103   "Toggle using `url' library for URL filenames (URL Handler mode).
 104 With a prefix argument ARG, enable URL Handler mode if ARG is
 105 positive, and disable it otherwise.  If called from Lisp, enable
 106 the mode if ARG is omitted or nil."
 107   :global t :group 'url
 108   (if (not (boundp 'file-name-handler-alist))
 109       ;; Can't be turned ON anyway.
 110       (setq url-handler-mode nil)
 111     ;; Remove old entry, if any.
 112     (setq file-name-handler-alist
 113           (delq (rassq 'url-file-handler file-name-handler-alist)
 114                 file-name-handler-alist))
 115     (if url-handler-mode
 116         (push (cons url-handler-regexp 'url-file-handler)
 117               file-name-handler-alist))))
 118
 119 (defun url-run-real-handler (operation args)
 120   (let ((inhibit-file-name-handlers (cons 'url-file-handler
 121                                           (if (eq operation inhibit-file-name-operation)
 122                                               inhibit-file-name-handlers)))
 123         (inhibit-file-name-operation operation))
 124     (apply operation args)))
 125
 126 ;;;###autoload
 127 (defun url-file-handler (operation &rest args)
 128   "Function called from the `file-name-handler-alist' routines.
 129 OPERATION is what needs to be done (`file-exists-p', etc).  ARGS are
 130 the arguments that would have been passed to OPERATION."
 131   (let ((fn (or (get operation 'url-file-handlers)
 132                 (intern-soft (format "url-%s" operation))))
 133         (val nil)
 134         (hooked nil))
 135     (if (and fn (fboundp fn))
 136         (setq hooked t
 137               val (save-match-data (apply fn args)))
 138       (setq hooked nil
 139             val (url-run-real-handler operation args)))
 140     (url-debug 'handlers "%s %S%S => %S" (if hooked "Hooked" "Real")
 141                operation args val)
 142     val))
 143
 144 (defun url-file-handler-identity (&rest args)
 145   ;; Identity function
 146   (car args))
 147
 148 ;; These are operations that we can fully support
 149 (put 'file-readable-p 'url-file-handlers 'url-file-exists-p)
 150 (put 'substitute-in-file-name 'url-file-handlers 'url-file-handler-identity)
 151 (put 'file-name-absolute-p 'url-file-handlers (lambda (&rest ignored) t))
 152 (put 'expand-file-name 'url-file-handlers 'url-handler-expand-file-name)
 153 (put 'directory-file-name 'url-file-handlers 'url-handler-directory-file-name)
 154 (put 'unhandled-file-name-directory 'url-file-handlers 'url-handler-unhandled-file-name-directory)
 155 (put 'file-remote-p 'url-file-handlers 'url-handler-file-remote-p)
 156 ;; (put 'file-name-as-directory 'url-file-handlers 'url-handler-file-name-as-directory)
 157
 158 ;; These are operations that we do not support yet (DAV!!!)
 159 (put 'file-writable-p 'url-file-handlers 'ignore)
 160 (put 'file-symlink-p 'url-file-handlers 'ignore)
 161 ;; Just like for ange-ftp: let's not waste time trying to look for RCS/foo,v
 162 ;; files and such since we can't do anything clever with them anyway.
 163 (put 'vc-registered 'url-file-handlers 'ignore)
 164
 165 (defun url-handler-expand-file-name (file &optional base)
 166   ;; When we see "/foo/bar" in a file whose working dir is "http://bla/bla",
 167   ;; there are two interpretations possible: either it's a local "/foo/bar"
 168   ;; or it's "http:/bla/foo/bar".  When working with URLs, the second
 169   ;; interpretation is the right one, but when working with Emacs file
 170   ;; names, the first is preferred.
 171   (if (file-name-absolute-p file)
 172       (expand-file-name file "/")
 173     (url-expand-file-name file base)))
 174
 175 ;; directory-file-name and file-name-as-directory are kind of hard to
 176 ;; implement really right for URLs since URLs can have repeated / chars.
 177 ;; We'd want the following behavior:
 178 ;; idempotence: (d-f-n (d-f-n X) == (d-f-n X)
 179 ;; idempotence: (f-n-a-d (f-n-a-d X) == (f-n-a-d X)
 180 ;; reversible:  (d-f-n (f-n-a-d (d-f-n X))) == (d-f-n X)
 181 ;; reversible:  (f-n-a-d (d-f-n (f-n-a-d X))) == (f-n-a-d X)
 182 (defun url-handler-directory-file-name (dir)
 183   ;; When there's more than a single /, just don't touch the slashes at all.
 184   (if (string-match "//\\'" dir) dir
 185     (url-run-real-handler 'directory-file-name (list dir))))
 186
 187 (defun url-handler-unhandled-file-name-directory (filename)
 188   (let ((url (url-generic-parse-url filename)))
 189     (if (equal (url-type url) "file")
 190         ;; `file' URLs are actually local.  The filename part may be ""
 191         ;; which really stands for "/".
 192         ;; FIXME: maybe we should check that the host part is "" or "localhost"
 193         ;; or some name that represents the local host?
 194         (or (file-name-directory (url-filename url)) "/")
 195       ;; All other URLs are not expected to be directly accessible from
 196       ;; a local process.
 197       nil)))
 198
 199 (defun url-handler-file-remote-p (filename &optional identification connected)
 200   (let ((url (url-generic-parse-url filename)))
 201     (if (and (url-type url) (not (equal (url-type url) "file")))
 202         ;; Maybe we can find a suitable check for CONNECTED.  For now,
 203         ;; we ignore it.
 204         (cond
 205          ((eq identification 'method) (url-type url))
 206          ((eq identification 'user) (url-user url))
 207          ((eq identification 'host) (url-host url))
 208          ((eq identification 'localname) (url-filename url))
 209          (t (url-recreate-url
 210              (url-parse-make-urlobj (url-type url) (url-user url) nil
 211                                     (url-host url) (url-port url)))))
 212       ;; If there is no URL type, or it is a "file://" URL, the
 213       ;; filename is expected to be non remote.  A more subtle check
 214       ;; for "file://" URLs could be applied, as said in
 215       ;; `url-handler-unhandled-file-name-directory'.
 216       nil)))
 217
 218 ;; The actual implementation
 219 ;;;###autoload
 220 (defun url-copy-file (url newname &optional ok-if-already-exists
 221                           keep-time preserve-uid-gid)
 222   "Copy URL to NEWNAME.  Both args must be strings.
 223 Signals a `file-already-exists' error if file NEWNAME already exists,
 224 unless a third argument OK-IF-ALREADY-EXISTS is supplied and non-nil.
 225 A number as third arg means request confirmation if NEWNAME already exists.
 226 This is what happens in interactive use with M-x.
 227 Fourth arg KEEP-TIME non-nil means give the new file the same
 228 last-modified time as the old one.  (This works on only some systems.)
 229 Fifth arg PRESERVE-UID-GID is ignored.
 230 A prefix arg makes KEEP-TIME non-nil."
 231   (if (and (file-exists-p newname)
 232            (not ok-if-already-exists))
 233       (error "Opening output file: File already exists, %s" newname))
 234   (let ((buffer (url-retrieve-synchronously url))
 235         (handle nil))
 236     (if (not buffer)
 237         (error "Opening input file: No such file or directory, %s" url))
 238     (with-current-buffer buffer
 239       (setq handle (mm-dissect-buffer t)))
 240     (mm-save-part-to-file handle newname)
 241     (kill-buffer buffer)
 242     (mm-destroy-parts handle)))
 243
 244 ;;;###autoload
 245 (defun url-file-local-copy (url &rest ignored)
 246   "Copy URL into a temporary file on this machine.
 247 Returns the name of the local copy, or nil, if FILE is directly
 248 accessible."
 249   (let ((filename (make-temp-file "url")))
 250     (url-copy-file url filename 'ok-if-already-exists)
 251     filename))
 252
 253 (defun url-insert (buffer &optional beg end)
 254   "Insert the body of a URL object.
 255 BUFFER should be a complete URL buffer as returned by `url-retrieve'.
 256 If the headers specify a coding-system, it is applied to the body before it is inserted.
 257 Returns a list of the form (SIZE CHARSET), where SIZE is the size in bytes
 258 of the inserted text and CHARSET is the charset that was specified in the header,
 259 or nil if none was found.
 260 BEG and END can be used to only insert a subpart of the body.
 261 They count bytes from the beginning of the body."
 262   (let* ((handle (with-current-buffer buffer (mm-dissect-buffer t)))
 263          (data (with-current-buffer (mm-handle-buffer handle)
 264                  (if beg
 265                      (buffer-substring (+ (point-min) beg)
 266                                        (if end (+ (point-min) end) (point-max)))
 267                    (buffer-string))))
 268          (charset (mail-content-type-get (mm-handle-type handle)
 269                                           'charset)))
 270     (mm-destroy-parts handle)
 271     (if charset
 272         (insert (mm-decode-string data (mm-charset-to-coding-system charset)))
 273       (insert data))
 274     (list (length data) charset)))
 275
 276 ;;;###autoload
 277 (defun url-insert-file-contents (url &optional visit beg end replace)
 278   (let ((buffer (url-retrieve-synchronously url)))
 279     (if (not buffer)
 280         (error "Opening input file: No such file or directory, %s" url))
 281     (if visit (setq buffer-file-name url))
 282     (save-excursion
 283       (let* ((start (point))
 284              (size-and-charset (url-insert buffer beg end)))
 285         (kill-buffer buffer)
 286         (when replace
 287           (delete-region (point-min) start)
 288           (delete-region (point) (point-max)))
 289         (unless (cadr size-and-charset)
 290           ;; If the headers don't specify any particular charset, use the
 291           ;; usual heuristic/rules that we apply to files.
 292           (if (fboundp 'decode-coding-inserted-region)
 293               ;; XEmacs; ### add this.
 294               (decode-coding-inserted-region start (point) url visit beg end
 295                                              replace)))
 296         (list url (car size-and-charset))))))
 297
 298 (defun url-file-name-completion (url directory &optional predicate)
 299   (error "Unimplemented"))
 300
 301 (defun url-file-name-all-completions (file directory)
 302   (error "Unimplemented"))
 303
 304 ;; All other handlers map onto their respective backends.
 305 (defmacro url-handlers-create-wrapper (method args)
 306   `(defun ,(intern (format "url-%s" method)) ,args
 307      ,(format "URL file-name-handler wrapper for `%s' call.\n---\n%s" method
 308               (or (documentation method t) "No original documentation."))
 309      (setq url (url-generic-parse-url url))
 310      (when (url-type url)
 311        (funcall (url-scheme-get-property (url-type url) (quote ,method))
 312                 ,@(remove '&rest (remove '&optional args))))))
 313
 314 (url-handlers-create-wrapper file-exists-p (url))
 315 (url-handlers-create-wrapper file-attributes (url &optional id-format))
 316 (url-handlers-create-wrapper file-symlink-p (url))
 317 (url-handlers-create-wrapper file-writable-p (url))
 318 (url-handlers-create-wrapper file-directory-p (url))
 319 (url-handlers-create-wrapper file-executable-p (url))
 320 (url-handlers-create-wrapper directory-files (url &optional full match nosort))
 321 (url-handlers-create-wrapper file-truename (url &optional counter prev-dirs))
 322
 323 (add-hook 'find-file-hook 'url-handlers-set-buffer-mode)
 324
 325 (defun url-handlers-set-buffer-mode ()
 326   "Set correct modes for the current buffer if visiting a remote file."
 327   (and (stringp buffer-file-name)
 328        (string-match url-handler-regexp buffer-file-name)
 329        (auto-save-mode 0)))
 330
 331 (provide 'url-handlers)
 332
 333 ;;; url-handlers.el ends here