cgit.sxemacs.org Git - packages/blob - xemacs-packages/sieve/sieve.el

   1 ;;; sieve.el --- Utilities to manage sieve scripts
   2
   3 ;; Copyright (C) 2001, 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <simon@josefsson.org>
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 ;; Boston, MA 02110-1301, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This file contain utilities to facilate upload, download and
  27 ;; general management of sieve scripts.  Currently only the
  28 ;; Managesieve protocol is supported (using sieve-manage.el), but when
  29 ;; (useful) alternatives become available, they might be supported as
  30 ;; well.
  31 ;;
  32 ;; The cursor navigation was inspired by biff-mode by Franklin Lee.
  33 ;;
  34 ;; Release history:
  35 ;;
  36 ;; 2001-10-31 Committed to Oort Gnus.
  37 ;; 2002-07-27 Fix down-mouse-2 and down-mouse-3 in manage-mode.  Fix menubar
  38 ;;            in manage-mode.  Change some messages.  Added sieve-deactivate*,
  39 ;;            sieve-remove.  Fixed help text in manage-mode.  Suggested by
  40 ;;            Ned Ludd.
  41 ;;
  42 ;; Todo:
  43 ;;
  44 ;; * Namespace?  This file contains `sieve-manage' and
  45 ;;   `sieve-manage-mode', but there is a sieve-manage.el file as well.
  46 ;;   Can't think of a good solution though, this file need a *-mode,
  47 ;;   and naming it `sieve-mode' would collide with sieve-mode.el.  One
  48 ;;   solution would be to come up with some better name that this file
  49 ;;   can use that doesn't have the managesieve specific "manage" in
  50 ;;   it.  sieve-dired?  i dunno.  we could copy all off sieve.el into
  51 ;;   sieve-manage.el too, but I'd like to separate the interface from
  52 ;;   the protocol implementation since the backends are likely to
  53 ;;   change (well).
  54 ;;
  55 ;; * Define servers?  We could have a customize buffer to create a server,
  56 ;;   with authentication/stream/etc parameters, much like Gnus, and then
  57 ;;   only use names of defined servers when interacting with M-x sieve-*.
  58 ;;   Right now you can't use STARTTLS, which sieve-manage.el provides
  59
  60 ;;; Code:
  61
  62 (require 'sieve-manage)
  63 (require 'sieve-mode)
  64
  65 ;; User customizable variables:
  66
  67 (defgroup sieve nil
  68   "Manage sieve scripts."
  69   :group 'tools)
  70
  71 (defcustom sieve-new-script "<new script>"
  72   "Name of name script indicator."
  73   :type 'string
  74   :group 'sieve)
  75
  76 (defcustom sieve-buffer "*sieve*"
  77   "Name of sieve management buffer."
  78   :type 'string
  79   :group 'sieve)
  80
  81 (defcustom sieve-template "\
  82 require \"fileinto\";
  83
  84 # Example script (remove comment character '#' to make it effective!):
  85 #
  86 # if header :contains \"from\" \"coyote\" {
  87 #   discard;
  88 # } elsif header :contains [\"subject\"] [\"$$$\"] {
  89 #   discard;
  90 # } else {
  91 #  fileinto \"INBOX\";
  92 # }
  93 "
  94   "Template sieve script."
  95   :type 'string
  96   :group 'sieve)
  97
  98 ;; Internal variables:
  99
 100 (defvar sieve-manage-buffer nil)
 101 (defvar sieve-buffer-header-end nil)
 102
 103 ;; Sieve-manage mode:
 104
 105 (defvar sieve-manage-mode-map nil
 106   "Keymap for `sieve-manage-mode'.")
 107
 108 (if sieve-manage-mode-map
 109     ()
 110   (setq sieve-manage-mode-map (make-sparse-keymap))
 111   (suppress-keymap sieve-manage-mode-map)
 112   ;; various
 113   (define-key sieve-manage-mode-map "?" 'sieve-help)
 114   (define-key sieve-manage-mode-map "h" 'sieve-help)
 115   (define-key sieve-manage-mode-map "q" 'sieve-bury-buffer)
 116   ;; activating
 117   (define-key sieve-manage-mode-map "m" 'sieve-activate)
 118   (define-key sieve-manage-mode-map "u" 'sieve-deactivate)
 119   (define-key sieve-manage-mode-map "\M-\C-?" 'sieve-deactivate-all)
 120   ;; navigation keys
 121   (define-key sieve-manage-mode-map "\C-p" 'sieve-prev-line)
 122   (define-key sieve-manage-mode-map [up] 'sieve-prev-line)
 123   (define-key sieve-manage-mode-map "\C-n" 'sieve-next-line)
 124   (define-key sieve-manage-mode-map [down] 'sieve-next-line)
 125   (define-key sieve-manage-mode-map " " 'sieve-next-line)
 126   (define-key sieve-manage-mode-map "n" 'sieve-next-line)
 127   (define-key sieve-manage-mode-map "p" 'sieve-prev-line)
 128   (define-key sieve-manage-mode-map "\C-m" 'sieve-edit-script)
 129   (define-key sieve-manage-mode-map "f" 'sieve-edit-script)
 130   (define-key sieve-manage-mode-map "o" 'sieve-edit-script-other-window)
 131   (define-key sieve-manage-mode-map "r" 'sieve-remove)
 132   (define-key sieve-manage-mode-map [(down-mouse-2)] 'sieve-edit-script)
 133   (define-key sieve-manage-mode-map [(down-mouse-3)] 'sieve-manage-mode-menu))
 134
 135 (easy-menu-define sieve-manage-mode-menu sieve-manage-mode-map
 136   "Sieve Menu."
 137   '("Manage Sieve"
 138     ["Edit script" sieve-edit-script t]
 139     ["Activate script" sieve-activate t]
 140     ["Deactivate script" sieve-deactivate t]))
 141
 142 (define-derived-mode sieve-manage-mode fundamental-mode "SIEVE"
 143   "Mode used for sieve script management."
 144   (setq mode-name "SIEVE")
 145   (buffer-disable-undo (current-buffer))
 146   (setq truncate-lines t)
 147   (easy-menu-add sieve-manage-mode-menu sieve-manage-mode-map))
 148
 149 (put 'sieve-manage-mode 'mode-class 'special)
 150
 151 ;; This is necessary to allow correct handling of \\[cvs-mode-diff-map]
 152 ;; in substitute-command-keys.
 153 ;(fset 'sieve-manage-mode-map sieve-manage-mode-map)
 154
 155 ;; Commands used in sieve-manage mode:
 156
 157 (defun sieve-activate (&optional pos)
 158   (interactive "d")
 159   (let ((name (sieve-script-at-point)) err)
 160     (when (or (null name) (string-equal name sieve-new-script))
 161       (error "No sieve script at point"))
 162     (message "Activating script %s..." name)
 163     (setq err (sieve-manage-setactive name sieve-manage-buffer))
 164     (sieve-refresh-scriptlist)
 165     (if (sieve-manage-ok-p err)
 166         (message "Activating script %s...done" name)
 167       (message "Activating script %s...failed: %s" name (nth 2 err)))))
 168
 169 (defun sieve-deactivate-all (&optional pos)
 170   (interactive "d")
 171   (let ((name (sieve-script-at-point)) err)
 172     (message "Deactivating scripts...")
 173     (setq err (sieve-manage-setactive "" sieve-manage-buffer))
 174     (sieve-refresh-scriptlist)
 175     (if (sieve-manage-ok-p err)
 176         (message "Deactivating scripts...done")
 177       (message "Deactivating scripts...failed: %s" (nth 2 err)))))
 178
 179 (defalias 'sieve-deactivate 'sieve-deactivate-all)
 180
 181 (defun sieve-remove (&optional pos)
 182   (interactive "d")
 183   (let ((name (sieve-script-at-point)) err)
 184     (when (or (null name) (string-equal name sieve-new-script))
 185       (error "No sieve script at point"))
 186     (message "Removing sieve script %s..." name)
 187     (setq err (sieve-manage-deletescript name sieve-manage-buffer))
 188     (unless (sieve-manage-ok-p err)
 189       (error "Removing sieve script %s...failed: " err))
 190     (sieve-refresh-scriptlist)
 191     (message "Removing sieve script %s...done" name)))
 192
 193 (defun sieve-edit-script (&optional pos)
 194   (interactive "d")
 195   (let ((name (sieve-script-at-point)))
 196     (unless name
 197       (error "No sieve script at point"))
 198     (if (not (string-equal name sieve-new-script))
 199         (let ((newbuf (generate-new-buffer name))
 200               err)
 201           (setq err (sieve-manage-getscript name newbuf sieve-manage-buffer))
 202           (switch-to-buffer newbuf)
 203           (unless (sieve-manage-ok-p err)
 204             (error "Sieve download failed: %s" err)))
 205       (switch-to-buffer (get-buffer-create "template.siv"))
 206       (insert sieve-template))
 207     (sieve-mode)
 208     (message "Press C-c C-l to upload script to server.")))
 209
 210 (defmacro sieve-change-region (&rest body)
 211   "Turns off sieve-region before executing BODY, then re-enables it after.
 212 Used to bracket operations which move point in the sieve-buffer."
 213   `(progn
 214      (sieve-highlight nil)
 215      ,@body
 216      (sieve-highlight t)))
 217 (put 'sieve-change-region 'lisp-indent-function 0)
 218
 219 (defun sieve-next-line (&optional arg)
 220   (interactive)
 221   (unless arg
 222     (setq arg 1))
 223   (if (save-excursion
 224         (forward-line arg)
 225         (sieve-script-at-point))
 226       (sieve-change-region
 227         (forward-line arg))
 228     (message "End of list")))
 229
 230 (defun sieve-prev-line (&optional arg)
 231   (interactive)
 232   (unless arg
 233     (setq arg -1))
 234   (if (save-excursion
 235         (forward-line arg)
 236         (sieve-script-at-point))
 237       (sieve-change-region
 238         (forward-line arg))
 239     (message "Beginning of list")))
 240
 241 (defun sieve-help ()
 242   "Display help for various sieve commands."
 243   (interactive)
 244   (if (eq last-command 'sieve-help)
 245       ;; would need minor-mode for log-edit-mode
 246       (describe-function 'sieve-mode)
 247     (message "%s" (substitute-command-keys
 248               "`\\[sieve-edit-script]':edit `\\[sieve-activate]':activate `\\[sieve-deactivate]':deactivate `\\[sieve-remove]':remove"))))
 249
 250 (defun sieve-bury-buffer (buf &optional mainbuf)
 251   "Hide the buffer BUF that was temporarily popped up.
 252 BUF is assumed to be a temporary buffer used from the buffer MAINBUF."
 253   (interactive (list (current-buffer)))
 254   (save-current-buffer
 255     (let ((win (if (eq buf (window-buffer (selected-window))) (selected-window)
 256                  (get-buffer-window buf t))))
 257       (when win
 258         (if (window-dedicated-p win)
 259             (condition-case ()
 260                 (delete-window win)
 261               (error (iconify-frame (window-frame win))))
 262           (if (and mainbuf (get-buffer-window mainbuf))
 263               (delete-window win)))))
 264     (with-current-buffer buf
 265       (bury-buffer (unless (and (eq buf (window-buffer (selected-window)))
 266                                 (not (window-dedicated-p (selected-window))))
 267                      buf)))
 268     (when mainbuf
 269       (let ((mainwin (or (get-buffer-window mainbuf)
 270                          (get-buffer-window mainbuf 'visible))))
 271         (when mainwin (select-window mainwin))))))
 272
 273 ;; Create buffer:
 274
 275 (defun sieve-setup-buffer (server port)
 276   (setq buffer-read-only nil)
 277   (erase-buffer)
 278   (buffer-disable-undo)
 279   (insert "\
 280 Server  : " server ":" (or port "2000") "
 281
 282 ")
 283   (set (make-local-variable 'sieve-buffer-header-end)
 284        (point-max)))
 285
 286 (defun sieve-script-at-point (&optional pos)
 287   "Return name of sieve script at point POS, or nil."
 288   (interactive "d")
 289   (get-char-property (or pos (point)) 'script-name))
 290
 291 (eval-and-compile
 292   (defalias 'sieve-make-overlay (if (fboundp 'make-overlay)
 293                                     'make-overlay
 294                                   'make-extent))
 295   (defalias 'sieve-overlay-put (if (fboundp 'overlay-put)
 296                                    'overlay-put
 297                                  'set-extent-property))
 298   (defalias 'sieve-overlays-at (if (fboundp 'overlays-at)
 299                                    'overlays-at
 300                                  'extents-at)))
 301
 302 (defun sieve-highlight (on)
 303   "Turn ON or off highlighting on the current language overlay."
 304   (sieve-overlay-put (car (sieve-overlays-at (point)))
 305                      'face (if on 'highlight 'default)))
 306
 307 (defun sieve-insert-scripts (scripts)
 308   "Format and insert LANGUAGE-LIST strings into current buffer at point."
 309   (while scripts
 310     (let ((p (point))
 311           (ext nil)
 312           (script (pop scripts)))
 313       (if (consp script)
 314           (insert (format " ACTIVE %s" (cdr script)))
 315         (insert (format "        %s" script)))
 316       (setq ext (sieve-make-overlay p (point)))
 317       (sieve-overlay-put ext 'mouse-face 'highlight)
 318       (sieve-overlay-put ext 'script-name (if (consp script)
 319                                               (cdr script)
 320                                             script))
 321       (insert "\n"))))
 322
 323 (defun sieve-open-server (server &optional port)
 324   ;; open server
 325   (set (make-local-variable 'sieve-manage-buffer)
 326        (sieve-manage-open server))
 327   ;; authenticate
 328   (sieve-manage-authenticate nil nil sieve-manage-buffer))
 329
 330 (defun sieve-refresh-scriptlist ()
 331   (interactive)
 332   (with-current-buffer sieve-buffer
 333     (setq buffer-read-only nil)
 334     (delete-region (or sieve-buffer-header-end (point-max)) (point-max))
 335     (goto-char (point-max))
 336     ;; get list of script names and print them
 337     (let ((scripts (sieve-manage-listscripts sieve-manage-buffer)))
 338       (if (null scripts)
 339           (insert (format (concat "No scripts on server, press RET on %s to "
 340                                   "create a new script.\n") sieve-new-script))
 341         (insert (format (concat "%d script%s on server, press RET on a script "
 342                                 "name edits it, or\npress RET on %s to create "
 343                                 "a new script.\n") (length scripts)
 344                                 (if (eq (length scripts) 1) "" "s")
 345                                 sieve-new-script)))
 346       (save-excursion
 347         (sieve-insert-scripts (list sieve-new-script))
 348         (sieve-insert-scripts scripts)))
 349     (sieve-highlight t)
 350     (setq buffer-read-only t)))
 351
 352 ;;;###autoload
 353 (defun sieve-manage (server &optional port)
 354   (interactive "sServer: ")
 355   (switch-to-buffer (get-buffer-create sieve-buffer))
 356   (sieve-manage-mode)
 357   (sieve-setup-buffer server port)
 358   (if (sieve-open-server server port)
 359       (sieve-refresh-scriptlist)
 360     (message "Could not open server %s" server)))
 361
 362 ;;;###autoload
 363 (defun sieve-upload (&optional name)
 364   (interactive)
 365   (unless name
 366     (setq name (buffer-name)))
 367   (when (or (get-buffer sieve-buffer) (call-interactively 'sieve-manage))
 368     (let ((script (buffer-string)) err)
 369       (with-current-buffer (get-buffer sieve-buffer)
 370         (setq err (sieve-manage-putscript name script sieve-manage-buffer))
 371         (if (sieve-manage-ok-p err)
 372             (message (concat
 373                       "Sieve upload done.  Use `C-c RET' to manage scripts."))
 374           (message "Sieve upload failed: %s" (nth 2 err)))))))
 375
 376 ;;;###autoload
 377 (defun sieve-upload-and-bury (&optional name)
 378   (interactive)
 379   (sieve-upload name)
 380   (bury-buffer))
 381
 382 (provide 'sieve)
 383
 384 ;;; arch-tag: 7f6a6d94-94e1-4654-ab9a-aee21b9b8a94
 385 ;; sieve.el ends here