cgit.sxemacs.org Git - gnus/blob - lisp/spam-stat.el

   1 ;;; spam-stat.el --- detecting spam based on statistics
   2
   3 ;; Copyright (C) 2002, 2003 Free Software Foundation, Inc.
   4
   5 ;; Author: Alex Schroeder <alex@gnu.org>
   6 ;; Keywords: network
   7 ;; URL: http://www.emacswiki.org/cgi-bin/wiki.pl?SpamStat
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; This is free software; you can redistribute it and/or modify it
  12 ;; under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; This is distributed in the hope that it will be useful, but WITHOUT
  17 ;; ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  18 ;; or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public
  19 ;; License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This implements spam analysis according to Paul Graham in "A Plan
  29 ;; for Spam".  The basis for all this is a statistical distribution of
  30 ;; words for your spam and non-spam mails.  We need this information
  31 ;; in a hash-table so that the analysis can use the information when
  32 ;; looking at your mails.  Therefore, before you begin, you need tons
  33 ;; of mails (Graham uses 4000 non-spam and 4000 spam mails for his
  34 ;; experiments).
  35 ;;
  36 ;; The main interface to using spam-stat, are the following functions:
  37 ;;
  38 ;; `spam-stat-buffer-is-spam' -- called in a buffer, that buffer is
  39 ;; considered to be a new spam mail; use this for new mail that has
  40 ;; not been processed before
  41 ;;
  42 ;; `spam-stat-buffer-is-non-spam' -- called in a buffer, that buffer
  43 ;; is considered to be a new non-spam mail; use this for new mail that
  44 ;; has not been processed before
  45 ;;
  46 ;; `spam-stat-buffer-change-to-spam' -- called in a buffer, that
  47 ;; buffer is no longer considered to be normal mail but spam; use this
  48 ;; to change the status of a mail that has already been processed as
  49 ;; non-spam
  50 ;;
  51 ;; `spam-stat-buffer-change-to-non-spam' -- called in a buffer, that
  52 ;; buffer is no longer considered to be spam but normal mail; use this
  53 ;; to change the status of a mail that has already been processed as
  54 ;; spam
  55 ;;
  56 ;; `spam-stat-save' -- save the hash table to the file; the filename
  57 ;; used is stored in the variable `spam-stat-file'
  58 ;;
  59 ;; `spam-stat-load' -- load the hash table from a file; the filename
  60 ;; used is stored in the variable `spam-stat-file'
  61 ;;
  62 ;; `spam-stat-score-word' -- return the spam score for a word
  63 ;;
  64 ;; `spam-stat-score-buffer' -- return the spam score for a buffer
  65 ;;
  66 ;; `spam-stat-split-fancy' -- for fancy mail splitting; add
  67 ;; the rule (: spam-stat-split-fancy) to `nnmail-split-fancy'
  68 ;;
  69 ;; This requires the following in your ~/.gnus file:
  70 ;;
  71 ;; (require 'spam-stat)
  72 ;; (spam-stat-load)
  73
  74 ;;; Testing:
  75
  76 ;; Typical test will involve calls to the following functions:
  77 ;;
  78 ;; Reset: (spam-stat-reset)
  79 ;; Learn spam: (spam-stat-process-spam-directory "~/Mail/mail/spam")
  80 ;; Learn non-spam: (spam-stat-process-non-spam-directory "~/Mail/mail/misc")
  81 ;; Save table: (spam-stat-save)
  82 ;; File size: (nth 7 (file-attributes spam-stat-file))
  83 ;; Number of words: (hash-table-count spam-stat)
  84 ;; Test spam: (spam-stat-test-directory "~/Mail/mail/spam")
  85 ;; Test non-spam: (spam-stat-test-directory "~/Mail/mail/misc")
  86 ;; Reduce table size: (spam-stat-reduce-size)
  87 ;; Save table: (spam-stat-save)
  88 ;; File size: (nth 7 (file-attributes spam-stat-file))
  89 ;; Number of words: (hash-table-count spam-stat)
  90 ;; Test spam: (spam-stat-test-directory "~/Mail/mail/spam")
  91 ;; Test non-spam: (spam-stat-test-directory "~/Mail/mail/misc")
  92
  93 ;;; Dictionary Creation:
  94
  95 ;; Typically, you will filter away mailing lists etc. using specific
  96 ;; rules in `nnmail-split-fancy'.  Somewhere among these rules, you
  97 ;; will filter spam.  Here is how you would create your dictionary:
  98
  99 ;; Reset: (spam-stat-reset)
 100 ;; Learn spam: (spam-stat-process-spam-directory "~/Mail/mail/spam")
 101 ;; Learn non-spam: (spam-stat-process-non-spam-directory "~/Mail/mail/misc")
 102 ;; Repeat for any other non-spam group you need...
 103 ;; Reduce table size: (spam-stat-reduce-size)
 104 ;; Save table: (spam-stat-save)
 105
 106 ;;; Todo:
 107
 108 ;; Speed it up.  Integrate with Gnus such that it uses spam and expiry
 109 ;; marks to call the appropriate functions when leaving the summary
 110 ;; buffer and saves the hash table when leaving Gnus.  More testing:
 111 ;; More mails, disabling SpamAssassin, double checking algorithm, find
 112 ;; improved algorithm.
 113
 114 ;;; Thanks:
 115
 116 ;; Ted Zlatanov <tzz@lifelogs.com>
 117 ;; Jesper Harder <harder@myrealbox.com>
 118 ;; Dan Schmidt <dfan@dfan.org>
 119 ;; Lasse Rasinen <lrasinen@iki.fi>
 120 ;; Milan Zamazal <pdm@zamazal.org>
 121
 122 \f
 123
 124 ;;; Code:
 125
 126 (defgroup spam-stat nil
 127   "Statistical spam detection for Emacs.
 128 Use the functions to build a dictionary of words and their statistical
 129 distribution in spam and non-spam mails.  Then use a function to determine
 130 whether a buffer contains spam or not."
 131   :group 'gnus)
 132
 133 (defcustom spam-stat-file "~/.spam-stat.el"
 134   "File used to save and load the dictionary.
 135 See `spam-stat-to-hash-table' for the format of the file."
 136   :type 'file
 137   :group 'spam-stat)
 138
 139 (defcustom spam-stat-install-hooks t
 140   "Whether spam-stat should install its hooks in Gnus.
 141 This is set to nil if you use spam-stat through spam.el."
 142   :type 'boolean
 143   :group 'spam-stat)
 144
 145 (defcustom spam-stat-unknown-word-score 0.2
 146   "The score to use for unknown words.
 147 Also used for words that don't appear often enough."
 148   :type 'number
 149   :group 'spam-stat)
 150
 151 (defcustom spam-stat-max-word-length 15
 152   "Only words shorter than this will be considered."
 153   :type 'integer
 154   :group 'spam-stat)
 155
 156 (defcustom spam-stat-max-buffer-length 10240
 157   "Only the beginning of buffers will be analyzed.
 158 This variable says how many characters this will be."
 159   :type 'integer
 160   :group 'spam-stat)
 161
 162 (defcustom spam-stat-split-fancy-spam-group "mail.spam"
 163   "Name of the group where spam should be stored, if
 164 `spam-stat-split-fancy' is used in fancy splitting rules.  Has no
 165 effect when spam-stat is invoked through spam.el."
 166   :type 'string
 167   :group 'spam-stat)
 168
 169 (defcustom spam-stat-split-fancy-spam-threshhold 0.9
 170   "Spam score threshhold in spam-stat-split-fancy."
 171   :type 'number
 172   :group 'spam-stat)
 173
 174 (defvar spam-stat-syntax-table
 175   (let ((table (copy-syntax-table text-mode-syntax-table)))
 176     (modify-syntax-entry ?- "w" table)
 177     (modify-syntax-entry ?_ "w" table)
 178     (modify-syntax-entry ?. "w" table)
 179     (modify-syntax-entry ?! "w" table)
 180     (modify-syntax-entry ?? "w" table)
 181     (modify-syntax-entry ?+ "w" table)
 182     table)
 183   "Syntax table used when processing mails for statistical analysis.
 184 The important part is which characters are word constituents.")
 185
 186 (defvar spam-stat-dirty nil
 187   "Whether the spam-stat database needs saving.")
 188
 189 (defvar spam-stat-buffer nil
 190   "Buffer to use for scoring while splitting.
 191 This is set by hooking into Gnus.")
 192
 193 (defvar spam-stat-buffer-name " *spam stat buffer*"
 194   "Name of the `spam-stat-buffer'.")
 195
 196 ;; Hooking into Gnus
 197
 198 (defun spam-stat-store-current-buffer ()
 199   "Store a copy of the current buffer in `spam-stat-buffer'."
 200   (save-excursion
 201     (let ((str (buffer-string)))
 202       (set-buffer (get-buffer-create spam-stat-buffer-name))
 203       (erase-buffer)
 204       (insert str)
 205       (setq spam-stat-buffer (current-buffer)))))
 206
 207 (defun spam-stat-store-gnus-article-buffer ()
 208   "Store a copy of the current article in `spam-stat-buffer'.
 209 This uses `gnus-article-buffer'."
 210   (save-excursion
 211     (set-buffer gnus-original-article-buffer)
 212     (spam-stat-store-current-buffer)))
 213
 214 ;; Data -- not using defstruct in order to save space and time
 215
 216 (defvar spam-stat (make-hash-table :test 'equal)
 217   "Hash table used to store the statistics.
 218 Use `spam-stat-load' to load the file.
 219 Every word is used as a key in this table.  The value is a vector.
 220 Use `spam-stat-ngood', `spam-stat-nbad', `spam-stat-good',
 221 `spam-stat-bad', and `spam-stat-score' to access this vector.")
 222
 223 (defvar spam-stat-ngood 0
 224   "The number of good mails in the dictionary.")
 225
 226 (defvar spam-stat-nbad 0
 227   "The number of bad mails in the dictionary.")
 228
 229 (defsubst spam-stat-good (entry)
 230   "Return the number of times this word belongs to good mails."
 231   (aref entry 0))
 232
 233 (defsubst spam-stat-bad (entry)
 234   "Return the number of times this word belongs to bad mails."
 235   (aref entry 1))
 236
 237 (defsubst spam-stat-score (entry)
 238   "Set the score of this word."
 239   (if entry
 240       (aref entry 2)
 241     spam-stat-unknown-word-score))
 242
 243 (defsubst spam-stat-set-good (entry value)
 244   "Set the number of times this word belongs to good mails."
 245   (aset entry 0 value))
 246
 247 (defsubst spam-stat-set-bad (entry value)
 248   "Set the number of times this word belongs to bad mails."
 249   (aset entry 1 value))
 250
 251 (defsubst spam-stat-set-score (entry value)
 252   "Set the score of this word."
 253   (aset entry 2 value))
 254
 255 (defsubst spam-stat-make-entry (good bad)
 256   "Return a vector with the given properties."
 257   (let ((entry (vector good bad nil)))
 258     (spam-stat-set-score entry (spam-stat-compute-score entry))
 259     entry))
 260
 261 ;; Computing
 262
 263 (defun spam-stat-compute-score (entry)
 264   "Compute the score of this word.  1.0 means spam."
 265    ;; promote all numbers to floats for the divisions
 266    (let* ((g (* 2.0 (spam-stat-good entry)))
 267           (b (float (spam-stat-bad entry))))
 268      (cond ((< (+ g b) 5)
 269             .2)
 270            ((= 0 spam-stat-ngood)
 271             .99)
 272            ((= 0 spam-stat-nbad)
 273             .01)
 274            (t
 275             (max .01
 276                  (min .99 (/ (/ b spam-stat-nbad)
 277                              (+ (/ g spam-stat-ngood)
 278                                 (/ b spam-stat-nbad)))))))))
 279
 280 ;; Parsing
 281
 282 (defmacro with-spam-stat-max-buffer-size (&rest body)
 283   "Narrows the buffer down to the first 4k characters, then evaluates BODY."
 284   `(save-restriction
 285      (when (> (- (point-max)
 286                  (point-min))
 287               spam-stat-max-buffer-length)
 288        (narrow-to-region (point-min)
 289                          (+ (point-min) spam-stat-max-buffer-length)))
 290      ,@body))
 291
 292 (defun spam-stat-buffer-words ()
 293   "Return a hash table of words and number of occurences in the buffer."
 294   (with-spam-stat-max-buffer-size
 295    (with-syntax-table spam-stat-syntax-table
 296      (goto-char (point-min))
 297      (let ((result (make-hash-table :test 'equal))
 298            word count)
 299        (while (re-search-forward "\\w+" nil t)
 300          (setq word (match-string-no-properties 0)
 301                count (1+ (gethash word result 0)))
 302          (when (< (length word) spam-stat-max-word-length)
 303            (puthash word count result)))
 304        result))))
 305
 306 (defun spam-stat-buffer-is-spam ()
 307   "Consider current buffer to be a new spam mail."
 308   (setq spam-stat-nbad (1+ spam-stat-nbad))
 309   (maphash
 310    (lambda (word count)
 311      (let ((entry (gethash word spam-stat)))
 312        (if entry
 313            (spam-stat-set-bad entry (+ count (spam-stat-bad entry)))
 314          (setq entry (spam-stat-make-entry 0 count)))
 315        (spam-stat-set-score entry (spam-stat-compute-score entry))
 316        (puthash word entry spam-stat)))
 317    (spam-stat-buffer-words))
 318   (setq spam-stat-dirty t))
 319
 320 (defun spam-stat-buffer-is-non-spam ()
 321   "Consider current buffer to be a new non-spam mail."
 322   (setq spam-stat-ngood (1+ spam-stat-ngood))
 323   (maphash
 324    (lambda (word count)
 325      (let ((entry (gethash word spam-stat)))
 326        (if entry
 327            (spam-stat-set-good entry (+ count (spam-stat-good entry)))
 328          (setq entry (spam-stat-make-entry count 0)))
 329        (spam-stat-set-score entry (spam-stat-compute-score entry))
 330        (puthash word entry spam-stat)))
 331    (spam-stat-buffer-words))
 332   (setq spam-stat-dirty t))
 333
 334 (defun spam-stat-buffer-change-to-spam ()
 335   "Consider current buffer no longer normal mail but spam."
 336   (setq spam-stat-nbad (1+ spam-stat-nbad)
 337         spam-stat-ngood (1- spam-stat-ngood))
 338   (maphash
 339    (lambda (word count)
 340      (let ((entry (gethash word spam-stat)))
 341        (if (not entry)
 342            (error "This buffer has unknown words in it.")
 343          (spam-stat-set-good entry (- (spam-stat-good entry) count))
 344          (spam-stat-set-bad entry (+ (spam-stat-bad entry) count))
 345          (spam-stat-set-score entry (spam-stat-compute-score entry))
 346          (puthash word entry spam-stat))))
 347    (spam-stat-buffer-words))
 348   (setq spam-stat-dirty t))
 349
 350 (defun spam-stat-buffer-change-to-non-spam ()
 351   "Consider current buffer no longer spam but normal mail."
 352   (setq spam-stat-nbad (1- spam-stat-nbad)
 353         spam-stat-ngood (1+ spam-stat-ngood))
 354   (maphash
 355    (lambda (word count)
 356      (let ((entry (gethash word spam-stat)))
 357        (if (not entry)
 358            (error "This buffer has unknown words in it.")
 359          (spam-stat-set-good entry (+ (spam-stat-good entry) count))
 360          (spam-stat-set-bad entry (- (spam-stat-bad entry) count))
 361          (spam-stat-set-score entry (spam-stat-compute-score entry))
 362          (puthash word entry spam-stat))))
 363    (spam-stat-buffer-words))
 364   (setq spam-stat-dirty t))
 365
 366 ;; Saving and Loading
 367
 368 (defun spam-stat-save (&optional force)
 369   "Save the `spam-stat' hash table as lisp file."
 370   (interactive)
 371   (when (or force spam-stat-dirty)
 372     (with-temp-buffer
 373       (let ((standard-output (current-buffer))
 374             (font-lock-maximum-size 0))
 375         (insert "(setq spam-stat-ngood "
 376                 (number-to-string spam-stat-ngood)
 377                 " spam-stat-nbad "
 378                 (number-to-string spam-stat-nbad)
 379                 " spam-stat (spam-stat-to-hash-table '(")
 380         (maphash (lambda (word entry)
 381                    (prin1 (list word
 382                                 (spam-stat-good entry)
 383                                 (spam-stat-bad entry))))
 384                  spam-stat)
 385         (insert ")))")
 386         (write-file spam-stat-file)))
 387     (setq spam-stat-dirty nil)))
 388
 389 (defun spam-stat-load ()
 390   "Read the `spam-stat' hash table from disk."
 391   ;; TODO: maybe we should warn the user if spam-stat-dirty is t?
 392   (load-file spam-stat-file)
 393   (setq spam-stat-dirty nil))
 394
 395 (defun spam-stat-to-hash-table (entries)
 396   "Turn list ENTRIES into a hash table and store as `spam-stat'.
 397 Every element in ENTRIES has the form \(WORD GOOD BAD) where WORD is
 398 the word string, NGOOD is the number of good mails it has appeared in,
 399 NBAD is the number of bad mails it has appeared in, GOOD is the number
 400 of times it appeared in good mails, and BAD is the number of times it
 401 has appeared in bad mails."
 402   (let ((table (make-hash-table :test 'equal)))
 403     (mapc (lambda (l)
 404             (puthash (car l)
 405                      (spam-stat-make-entry (nth 1 l) (nth 2 l))
 406                      table))
 407           entries)
 408     table))
 409
 410 (defun spam-stat-reset ()
 411   "Reset `spam-stat' to an empty hash-table.
 412 This deletes all the statistics."
 413   (interactive)
 414   (setq spam-stat (make-hash-table :test 'equal)
 415         spam-stat-ngood 0
 416         spam-stat-nbad 0)
 417   (setq spam-stat-dirty t))
 418
 419 ;; Scoring buffers
 420
 421 (defvar spam-stat-score-data nil
 422   "Raw data used in the last run of `spam-stat-score-buffer'.")
 423
 424 (defsubst spam-stat-score-word (word)
 425   "Return score for WORD.
 426 The default score for unknown words is stored in
 427 `spam-stat-unknown-word-score'."
 428   (spam-stat-score (gethash word spam-stat)))
 429
 430 (defun spam-stat-buffer-words-with-scores ()
 431   "Process current buffer, return the 15 most conspicuous words.
 432 These are the words whose spam-stat differs the most from 0.5.
 433 The list returned contains elements of the form \(WORD SCORE DIFF),
 434 where DIFF is the difference between SCORE and 0.5."
 435   (with-spam-stat-max-buffer-size
 436    (with-syntax-table spam-stat-syntax-table
 437      (let (result word score)
 438        (maphash (lambda (word ignore)
 439                   (setq score (spam-stat-score-word word)
 440                         result (cons (list word score (abs (- score 0.5)))
 441                                      result)))
 442                 (spam-stat-buffer-words))
 443        (setq result (sort result (lambda (a b) (< (nth 2 b) (nth 2 a)))))
 444        (setcdr (nthcdr 14 result) nil)
 445        result))))
 446
 447 (defun spam-stat-score-buffer ()
 448   "Return a score describing the spam-probability for this buffer."
 449   (setq spam-stat-score-data (spam-stat-buffer-words-with-scores))
 450   (let* ((probs (mapcar (lambda (e) (cadr e)) spam-stat-score-data))
 451          (prod (apply #'* probs)))
 452     (/ prod (+ prod (apply #'* (mapcar #'(lambda (x) (- 1 x))
 453                                        probs))))))
 454
 455 (defun spam-stat-split-fancy ()
 456   "Return the name of the spam group if the current mail is spam.
 457 Use this function on `nnmail-split-fancy'.  If you are interested in
 458 the raw data used for the last run of `spam-stat-score-buffer',
 459 check the variable `spam-stat-score-data'."
 460   (condition-case var
 461       (progn
 462         (set-buffer spam-stat-buffer)
 463         (goto-char (point-min))
 464         (when (> (spam-stat-score-buffer) spam-stat-split-fancy-spam-threshhold)
 465           (when (boundp 'nnmail-split-trace)
 466             (mapc (lambda (entry)
 467                     (push entry nnmail-split-trace))
 468                   spam-stat-score-data))
 469           spam-stat-split-fancy-spam-group))
 470     (error (message "Error in spam-stat-split-fancy: %S" var)
 471            nil)))
 472
 473 ;; Testing
 474
 475 (defun spam-stat-process-directory (dir func)
 476   "Process all the regular files in directory DIR using function FUNC."
 477   (let* ((files (directory-files dir t "^[^.]"))
 478          (max (/ (length files) 100.0))
 479          (count 0))
 480     (with-temp-buffer
 481       (dolist (f files)
 482         (when (and (file-readable-p f)
 483                    (file-regular-p f)
 484                    (> (nth 7 (file-attributes f)) 0))
 485           (setq count (1+ count))
 486           (message "Reading %s: %.2f%%" dir (/ count max))
 487           (insert-file-contents f)
 488           (funcall func)
 489           (erase-buffer))))))
 490
 491 (defun spam-stat-process-spam-directory (dir)
 492   "Process all the regular files in directory DIR as spam."
 493   (interactive "D")
 494   (spam-stat-process-directory dir 'spam-stat-buffer-is-spam))
 495
 496 (defun spam-stat-process-non-spam-directory (dir)
 497   "Process all the regular files in directory DIR as non-spam."
 498   (interactive "D")
 499   (spam-stat-process-directory dir 'spam-stat-buffer-is-non-spam))
 500
 501 (defun spam-stat-count ()
 502   "Return size of `spam-stat'."
 503   (interactive)
 504   (hash-table-count spam-stat))
 505
 506 (defun spam-stat-test-directory (dir)
 507   "Test all the regular files in directory DIR for spam.
 508 If the result is 1.0, then all files are considered spam.
 509 If the result is 0.0, non of the files is considered spam.
 510 You can use this to determine error rates."
 511   (interactive "D")
 512   (let* ((files (directory-files dir t "^[^.]"))
 513          (total (length files))
 514          (score 0.0); float
 515          (max (/ total 100.0)); float
 516          (count 0))
 517     (with-temp-buffer
 518       (dolist (f files)
 519         (when (and (file-readable-p f)
 520                    (file-regular-p f)
 521                    (> (nth 7 (file-attributes f)) 0))
 522           (setq count (1+ count))
 523           (message "Reading %.2f%%, score %.2f%%"
 524                    (/ count max) (/ score count))
 525           (insert-file-contents f)
 526           (when (> (spam-stat-score-buffer) 0.9)
 527             (setq score (1+ score)))
 528           (erase-buffer))))
 529     (message "Final score: %d / %d = %f" score total (/ score total))))
 530
 531 ;; Shrinking the dictionary
 532
 533 (defun spam-stat-reduce-size (&optional count)
 534   "Reduce the size of `spam-stat'.
 535 This removes all words that occur less than COUNT from the dictionary.
 536 COUNT defaults to 5"
 537   (interactive)
 538   (setq count (or count 5))
 539   (maphash (lambda (key entry)
 540              (when (< (+ (spam-stat-good entry)
 541                          (spam-stat-bad entry))
 542                       count)
 543                (remhash key spam-stat)))
 544            spam-stat))
 545
 546 (defun spam-stat-install-hooks-function ()
 547   "Install the spam-stat function hooks"
 548   (interactive)
 549   (add-hook 'nnmail-prepare-incoming-message-hook
 550             'spam-stat-store-current-buffer)
 551   (add-hook 'gnus-select-article-hook
 552             'spam-stat-store-gnus-article-buffer))
 553
 554 (when spam-stat-install-hooks
 555   (spam-stat-install-hooks-function))
 556
 557 (defun spam-stat-unload-hook ()
 558   "Uninstall the spam-stat function hooks"
 559   (interactive)
 560   (remove-hook 'nnmail-prepare-incoming-message-hook
 561                'spam-stat-store-current-buffer)
 562   (remove-hook 'gnus-select-article-hook
 563                'spam-stat-store-gnus-article-buffer))
 564
 565 (provide 'spam-stat)
 566
 567 ;;; spam-stat.el ends here