cgit.sxemacs.org Git - gnus/blob - lisp/spam-report.el

   1 ;;; spam-report.el --- Reporting spam
   2 ;; Copyright (C) 2002, 2003, 2004 Free Software Foundation, Inc.
   3
   4 ;; Author: Teodor Zlatanov <tzz@lifelogs.com>
   5 ;; Keywords: network
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; This module addresses a few aspects of spam reporting under Gnus.  Page
  27 ;;; breaks are used for grouping declarations and documentation relating to
  28 ;;; each particular aspect.
  29
  30 ;;; Code:
  31 (require 'gnus)
  32 (require 'gnus-sum)
  33
  34 (eval-and-compile
  35   (autoload 'mm-url-insert "mm-url"))
  36
  37 (defgroup spam-report nil
  38   "Spam reporting configuration.")
  39
  40 (defcustom spam-report-gmane-regex nil
  41   "Regexp matching Gmane newsgroups, e.g. \"^nntp\\+.*:gmane\\.\"
  42 If you are using spam.el, consider setting gnus-spam-process-newsgroups
  43 or the gnus-group-spam-exit-processor-report-gmane group/topic parameter
  44 instead."
  45   :type '(radio (const nil)
  46                 (regexp :format "%t: %v\n" :size 0 :value "^nntp\+.*:gmane\."))
  47   :group 'spam-report)
  48
  49 (defcustom spam-report-gmane-spam-header
  50   "^X-Report-Spam: http://\\([^/]+\\)\\(.*\\)$"
  51   "String matching Gmane spam-reporting header.  Two match groups are needed."
  52   :type 'regexp
  53   :group 'spam-report)
  54
  55 (defcustom spam-report-gmane-use-article-number t
  56   "Whether the article number (faster!) or the header should be used."
  57   :type 'boolean
  58   :group 'spam-report)
  59
  60 (defcustom spam-report-url-ping-function
  61   'spam-report-url-ping-plain
  62   "Function to use for url ping spam reporting.
  63 The function must accept the arguments `host' and `report'."
  64   :type '(choice
  65           (const :tag "Connect directly"
  66                  spam-report-url-ping-plain)
  67           (const :tag "Use the external program specified in `mm-url-program'"
  68                  spam-report-url-ping-mm-url)
  69           (const :tag "Store request URLs in `spam-report-requests-file'"
  70                  spam-report-url-to-file)
  71           (function :tag "User defined function" nil))
  72   :group 'spam-report)
  73
  74 (defcustom spam-report-requests-file
  75   (nnheader-concat gnus-directory "spam/" "spam-report-requests.url")
  76   ;; Is there a convention for the extension of such a file?
  77   ;; Should we use `spam-directory'?
  78   "File where spam report request are stored."
  79   :type 'file
  80   :group 'spam-report)
  81
  82 (defun spam-report-gmane (&rest articles)
  83   "Report an article as spam through Gmane"
  84   (dolist (article articles)
  85     (when (and gnus-newsgroup-name
  86                (or (null spam-report-gmane-regex)
  87                    (string-match spam-report-gmane-regex gnus-newsgroup-name)))
  88       (gnus-message 6 "Reporting spam article %d to spam.gmane.org..." article)
  89       (if spam-report-gmane-use-article-number
  90           (spam-report-url-ping "spam.gmane.org"
  91                                 (format "/%s:%d"
  92                                         (gnus-group-real-name gnus-newsgroup-name)
  93                                         article))
  94         (with-current-buffer nntp-server-buffer
  95           (gnus-request-head article gnus-newsgroup-name)
  96           (goto-char (point-min))
  97           (if (re-search-forward spam-report-gmane-spam-header nil t)
  98               (let* ((host (match-string 1))
  99                      (report (match-string 2))
 100                      (url (format "http://%s%s" host report)))
 101                 (gnus-message 7 "Reporting spam through URL %s..." url)
 102                 (spam-report-url-ping host report))
 103             (gnus-message 3 "Could not find X-Report-Spam in article %d..."
 104                           article)))))))
 105
 106 (defun spam-report-url-ping (host report)
 107   "Ping a host through HTTP, addressing a specific GET resource using
 108 the function specified by `spam-report-url-ping-function'."
 109   (funcall spam-report-url-ping-function host report))
 110
 111 (defun spam-report-url-ping-plain (host report)
 112   "Ping a host through HTTP, addressing a specific GET resource."
 113   (let ((tcp-connection))
 114     (with-temp-buffer
 115       (or (setq tcp-connection
 116                 (open-network-stream
 117                  "URL ping"
 118                  (buffer-name)
 119                  host
 120                  80))
 121           (error "Could not open connection to %s" host))
 122       (set-marker (process-mark tcp-connection) (point-min))
 123       (process-send-string
 124        tcp-connection
 125        (format "GET %s HTTP/1.1\nUser-Agent: %s (spam-report.el)\nHost: %s\n\n"
 126                report (gnus-emacs-version) host)))))
 127
 128 (defun spam-report-url-ping-mm-url (host report)
 129   "Ping a host through HTTP, addressing a specific GET resource. Use
 130 the external program specified in `mm-url-program' to connect to
 131 server."
 132   (with-temp-buffer
 133     (let ((url (concat "http://" host report)))
 134       (mm-url-insert url t))))
 135
 136 (defun spam-report-url-to-file (host report)
 137   "Collect spam report requests in `spam-report-requests-file'.
 138 Customize `spam-report-url-ping-function' to use this function."
 139   (let ((url (concat "http://" host report))
 140         (file spam-report-requests-file))
 141     (gnus-make-directory (file-name-directory file))
 142     (gnus-message 9 "Writing URL `%s' to file `%s'" url file)
 143     (with-temp-buffer
 144       (insert url)
 145       (newline)
 146       (append-to-file (point-min) (point-max) file))))
 147
 148 (provide 'spam-report)
 149
 150 ;;; spam-report.el ends here.