cgit.sxemacs.org Git - gnus/blob - lisp/spam-report.el

   1 ;;; spam-report.el --- Reporting spam
   2
   3 ;; Copyright (C) 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   4
   5 ;; Author: Teodor Zlatanov <tzz@lifelogs.com>
   6 ;; Keywords: network
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; This module addresses a few aspects of spam reporting under Gnus.  Page
  28 ;;; breaks are used for grouping declarations and documentation relating to
  29 ;;; each particular aspect.
  30
  31 ;;; Code:
  32 (require 'gnus)
  33 (require 'gnus-sum)
  34
  35 (eval-and-compile
  36   (autoload 'mm-url-insert "mm-url"))
  37
  38 (defgroup spam-report nil
  39   "Spam reporting configuration."
  40   :group 'mail
  41   :group 'news)
  42
  43 (defcustom spam-report-gmane-regex nil
  44   "Regexp matching Gmane newsgroups, e.g. \"^nntp\\+.*:gmane\\.\"
  45 If you are using spam.el, consider setting gnus-spam-process-newsgroups
  46 or the gnus-group-spam-exit-processor-report-gmane group/topic parameter
  47 instead."
  48   :type '(radio (const nil)
  49                 (regexp :value "^nntp\+.*:gmane\."))
  50   :group 'spam-report)
  51
  52 (defcustom spam-report-gmane-use-article-number t
  53   "Whether the article number (faster!) or the header should be used."
  54   :type 'boolean
  55   :group 'spam-report)
  56
  57 (defcustom spam-report-url-ping-function
  58   'spam-report-url-ping-plain
  59   "Function to use for url ping spam reporting.
  60 The function must accept the arguments `host' and `report'."
  61   :type '(choice
  62           (const :tag "Connect directly"
  63                  spam-report-url-ping-plain)
  64           (const :tag "Use the external program specified in `mm-url-program'"
  65                  spam-report-url-ping-mm-url)
  66           (const :tag "Store request URLs in `spam-report-requests-file'"
  67                  spam-report-url-to-file)
  68           (function :tag "User defined function" nil))
  69   :group 'spam-report)
  70
  71 (defcustom spam-report-requests-file
  72   (nnheader-concat gnus-directory "spam/" "spam-report-requests.url")
  73   ;; Is there a convention for the extension of such a file?
  74   ;; Should we use `spam-directory'?
  75   "File where spam report request are stored."
  76   :type 'file
  77   :group 'spam-report)
  78
  79 (defcustom spam-report-resend-to nil
  80   "Email address that spam articles are resent to when reporting.
  81 If not set, the user will be prompted to enter a value which will be
  82 saved for future use."
  83   :type 'string
  84   :group 'spam-report)
  85
  86 (defvar spam-report-url-ping-temp-agent-function nil
  87   "Internal variable for `spam-report-agentize' and `spam-report-deagentize'.
  88 This variable will store the value of `spam-report-url-ping-function' from
  89 before `spam-report-agentize' was run, so that `spam-report-deagentize' can
  90 undo that change.")
  91
  92 (defun spam-report-resend (articles &optional ham)
  93   "Report an article as spam by resending via email.
  94 Reports is as ham when HAM is set."
  95   (dolist (article articles)
  96     (gnus-message 6
  97                   "Reporting %s article %d to <%s>..."
  98                   (if ham "ham" "spam")
  99                   article spam-report-resend-to)
 100     (unless spam-report-resend-to
 101       (customize-set-variable
 102        spam-report-resend-to
 103        (read-from-minibuffer "email address to resend SPAM/HAM to? ")))
 104     ;; This is ganked from the `gnus-summary-resend-message' function.
 105     ;; It involves rendering the SPAM, which is undesirable, but there does
 106     ;; not seem to be a nicer way to achieve this.
 107     ;; select this particular article
 108     (gnus-summary-select-article nil nil nil article)
 109     ;; resend it to the destination address
 110     (save-excursion
 111       (set-buffer gnus-original-article-buffer)
 112       (message-resend spam-report-resend-to))))
 113
 114 (defun spam-report-resend-ham (articles)
 115   "Report an article as ham by resending via email."
 116   (spam-report-resend articles t))
 117
 118 (defun spam-report-gmane (&rest articles)
 119   "Report an article as spam through Gmane."
 120   (interactive (gnus-summary-work-articles current-prefix-arg))
 121   (dolist (article articles)
 122     (when (and gnus-newsgroup-name
 123                (or (null spam-report-gmane-regex)
 124                    (string-match spam-report-gmane-regex gnus-newsgroup-name)))
 125       (gnus-message 6 "Reporting spam article %d to spam.gmane.org..." article)
 126       (if spam-report-gmane-use-article-number
 127           (spam-report-url-ping
 128            "spam.gmane.org"
 129            (format "/%s:%d"
 130                    (gnus-group-real-name gnus-newsgroup-name)
 131                    article))
 132         (with-current-buffer nntp-server-buffer
 133           (gnus-request-head article gnus-newsgroup-name)
 134           (let ((case-fold-search t)
 135                 field host report url)
 136             ;; First check for X-Report-Spam because it's more specific to
 137             ;; spam reporting than Archived-At.  OTOH, all new articles on
 138             ;; Gmane don't have X-Report-Spam anymore (unless Lars changes his
 139             ;; mind :-)).
 140             ;;
 141             ;; There might be more than one Archived-At header so we need to
 142             ;; find (and transform) the one related to Gmane.
 143             (setq field (or (gnus-fetch-field "X-Report-Spam")
 144                             (gnus-fetch-field "Archived-At")))
 145             (setq host (progn
 146                          (string-match
 147                           (concat "http://\\([a-z]+\\.gmane\\.org\\)"
 148                                   "\\(/[^:/]+[:/][0-9]+\\)")
 149                           field)
 150                          (match-string 1 field)))
 151             (setq report (match-string 2 field))
 152             (when (string-equal "permalink.gmane.org" host)
 153               (setq host "spam.gmane.org"))
 154             (setq url (format "http://%s%s" host report))
 155             (if (not (and host report url))
 156                 (gnus-message
 157                  3 "Could not find a spam report header in article %d..."
 158                  article)
 159               (gnus-message 7 "Reporting spam through URL %s..." url)
 160               (spam-report-url-ping host report))))))))
 161
 162
 163 (defun spam-report-url-ping (host report)
 164   "Ping a host through HTTP, addressing a specific GET resource using
 165 the function specified by `spam-report-url-ping-function'."
 166   ;; Example:
 167   ;; host: "spam.gmane.org"
 168   ;; report: "/gmane.some.group:123456"
 169   (funcall spam-report-url-ping-function host report))
 170
 171 (defun spam-report-url-ping-plain (host report)
 172   "Ping a host through HTTP, addressing a specific GET resource."
 173   (let ((tcp-connection))
 174     (with-temp-buffer
 175       (or (setq tcp-connection
 176                 (open-network-stream
 177                  "URL ping"
 178                  (buffer-name)
 179                  host
 180                  80))
 181           (error "Could not open connection to %s" host))
 182       (set-marker (process-mark tcp-connection) (point-min))
 183       (process-send-string
 184        tcp-connection
 185        (format "GET %s HTTP/1.1\nUser-Agent: %s (spam-report.el)\nHost: %s\n\n"
 186                report (gnus-emacs-version) host)))))
 187
 188 ;;;###autoload
 189 (defun spam-report-process-queue (&optional file keep)
 190   "Report all queued requests from `spam-report-requests-file'.
 191
 192 If FILE is given, use it instead of `spam-report-requests-file'.
 193 If KEEP is t, leave old requests in the file.  If KEEP is the
 194 symbol `ask', query before flushing the queue file."
 195   (interactive
 196    (list (read-file-name
 197           "File: "
 198           (file-name-directory spam-report-requests-file)
 199           spam-report-requests-file
 200           nil
 201           (file-name-nondirectory spam-report-requests-file))
 202          current-prefix-arg))
 203   (if (eq spam-report-url-ping-function 'spam-report-url-to-file)
 204       (error (concat "Cannot process requests when "
 205                      "`spam-report-url-ping-function' is "
 206                      "`spam-report-url-to-file'."))
 207     (gnus-message 7 "Processing requests using `%s'."
 208                   spam-report-url-ping-function))
 209   (or file (setq file spam-report-requests-file))
 210   (save-excursion
 211     (set-buffer (find-file-noselect file))
 212     (goto-char (point-min))
 213     (while (and (not (eobp))
 214                 (re-search-forward
 215                  "http://\\([^/]+\\)\\(/.*\\) *$" (point-at-eol) t))
 216       (funcall spam-report-url-ping-function (match-string 1) (match-string 2))
 217       (forward-line 1))
 218     (if (or (eq keep nil)
 219             (and (eq keep 'ask)
 220                  (y-or-n-p
 221                   (format
 222                    "Flush requests from `%s'? " (current-buffer)))))
 223         (progn
 224           (gnus-message 7 "Flushing request file `%s'"
 225                         spam-report-requests-file)
 226           (erase-buffer)
 227           (save-buffer)
 228           (kill-buffer (current-buffer)))
 229       (gnus-message 7 "Keeping requests in `%s'" spam-report-requests-file))))
 230
 231 ;;;###autoload
 232 (defun spam-report-url-ping-mm-url (host report)
 233   "Ping a host through HTTP, addressing a specific GET resource. Use
 234 the external program specified in `mm-url-program' to connect to
 235 server."
 236   (with-temp-buffer
 237     (let ((url (format "http://%s%s" host report)))
 238       (mm-url-insert url t))))
 239
 240 ;;;###autoload
 241 (defun spam-report-url-to-file (host report)
 242   "Collect spam report requests in `spam-report-requests-file'.
 243 Customize `spam-report-url-ping-function' to use this function."
 244   (let ((url (format "http://%s%s" host report))
 245         (file spam-report-requests-file))
 246     (gnus-make-directory (file-name-directory file))
 247     (gnus-message 9 "Writing URL `%s' to file `%s'" url file)
 248     (with-temp-buffer
 249       (insert url)
 250       (newline)
 251       (append-to-file (point-min) (point-max) file))))
 252
 253 ;;;###autoload
 254 (defun spam-report-agentize ()
 255   "Add spam-report support to the Agent.
 256 Spam reports will be queued with \\[spam-report-url-to-file] when
 257 the Agent is unplugged, and will be submitted in a batch when the
 258 Agent is plugged."
 259   (interactive)
 260   (add-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 261   (add-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 262
 263 ;;;###autoload
 264 (defun spam-report-deagentize ()
 265   "Remove spam-report support from the Agent.
 266 Spam reports will be queued with the method used when
 267 \\[spam-report-agentize] was run."
 268   (interactive)
 269   (remove-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 270   (remove-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 271
 272 (defun spam-report-plug-agent ()
 273   "Adjust spam report settings for plugged state.
 274 Process queued spam reports."
 275   ;; Process the queue, unless the user only wanted to report to a file
 276   ;; anyway.
 277   (unless (equal spam-report-url-ping-temp-agent-function
 278                  'spam-report-url-to-file)
 279     (spam-report-process-queue))
 280   ;; Set the reporting function, if we have memorized something otherwise,
 281   ;; stick with plain URL reporting.
 282   (setq spam-report-url-ping-function
 283         (or spam-report-url-ping-temp-agent-function
 284             'spam-report-url-ping-plain)))
 285
 286 (defun spam-report-unplug-agent ()
 287   "Restore spam report settings for unplugged state."
 288   ;; save the old value
 289   (setq spam-report-url-ping-temp-agent-function
 290         spam-report-url-ping-function)
 291   ;; store all reports to file
 292   (setq spam-report-url-ping-function
 293         'spam-report-url-to-file))
 294
 295 (provide 'spam-report)
 296
 297 ;;; arch-tag: f6683295-ec89-4ab5-8803-8cc842293022
 298 ;;; spam-report.el ends here.