cgit.sxemacs.org Git - gnus/blob - lisp/sieve-manage.el

   1 ;;; sieve-manage.el --- Implementation of the managesive protocol in elisp
   2
   3 ;; Copyright (C) 2001-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <simon@josefsson.org>
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;; This library provides an elisp API for the managesieve network
  25 ;; protocol.
  26 ;;
  27 ;; It uses the SASL library for authentication, which means it
  28 ;; supports DIGEST-MD5, CRAM-MD5, SCRAM-MD5, NTLM, PLAIN and LOGIN
  29 ;; methods.  STARTTLS is not well tested, but should be easy to get to
  30 ;; work if someone wants.
  31 ;;
  32 ;; The API should be fairly obvious for anyone familiar with the
  33 ;; managesieve protocol, interface functions include:
  34 ;;
  35 ;; `sieve-manage-open'
  36 ;; open connection to managesieve server, returning a buffer to be
  37 ;; used by all other API functions.
  38 ;;
  39 ;; `sieve-manage-opened'
  40 ;; check if a server is open or not
  41 ;;
  42 ;; `sieve-manage-close'
  43 ;; close a server connection.
  44 ;;
  45 ;; `sieve-manage-listscripts'
  46 ;; `sieve-manage-deletescript'
  47 ;; `sieve-manage-getscript'
  48 ;; performs managesieve protocol actions
  49 ;;
  50 ;; and that's it.  Example of a managesieve session in *scratch*:
  51 ;;
  52 ;; (with-current-buffer (sieve-manage-open "mail.example.com")
  53 ;;   (sieve-manage-authenticate)
  54 ;;   (sieve-manage-listscripts))
  55 ;;
  56 ;; => ((active . "main") "vacation")
  57 ;;
  58 ;; References:
  59 ;;
  60 ;; draft-martin-managesieve-02.txt,
  61 ;; "A Protocol for Remotely Managing Sieve Scripts",
  62 ;; by Tim Martin.
  63 ;;
  64 ;; Release history:
  65 ;;
  66 ;; 2001-10-31 Committed to Oort Gnus.
  67 ;; 2002-07-27 Added DELETESCRIPT.  Suggested by Ned Ludd.
  68 ;; 2002-08-03 Use SASL library.
  69
  70 ;;; Code:
  71
  72 ;; For Emacs <22.2 and XEmacs.
  73 (eval-and-compile
  74   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  75
  76 (if (locate-library "password-cache")
  77     (require 'password-cache)
  78   (require 'password))
  79
  80 (eval-when-compile
  81   (require 'cl)                         ; caddr
  82   (require 'sasl)
  83   (require 'starttls))
  84 (autoload 'sasl-find-mechanism "sasl")
  85 (autoload 'starttls-open-stream "starttls")
  86 (autoload 'auth-source-search "auth-source")
  87
  88 ;; User customizable variables:
  89
  90 (defgroup sieve-manage nil
  91   "Low-level Managesieve protocol issues."
  92   :group 'mail
  93   :prefix "sieve-")
  94
  95 (defcustom sieve-manage-log "*sieve-manage-log*"
  96   "Name of buffer for managesieve session trace."
  97   :type 'string
  98   :group 'sieve-manage)
  99
 100 (defcustom sieve-manage-server-eol "\r\n"
 101   "The EOL string sent from the server."
 102   :type 'string
 103   :group 'sieve-manage)
 104
 105 (defcustom sieve-manage-client-eol "\r\n"
 106   "The EOL string we send to the server."
 107   :type 'string
 108   :group 'sieve-manage)
 109
 110 (defcustom sieve-manage-streams '(network starttls shell)
 111   "Priority of streams to consider when opening connection to server."
 112   :group 'sieve-manage)
 113
 114 (defcustom sieve-manage-stream-alist
 115   '((network   sieve-manage-network-p          sieve-manage-network-open)
 116     (shell     sieve-manage-shell-p            sieve-manage-shell-open)
 117     (starttls  sieve-manage-starttls-p         sieve-manage-starttls-open))
 118   "Definition of network streams.
 119
 120 \(NAME CHECK OPEN)
 121
 122 NAME names the stream, CHECK is a function returning non-nil if the
 123 server support the stream and OPEN is a function for opening the
 124 stream."
 125   :group 'sieve-manage)
 126
 127 (defcustom sieve-manage-authenticators '(digest-md5
 128                                          cram-md5
 129                                          scram-md5
 130                                          ntlm
 131                                          plain
 132                                          login)
 133   "Priority of authenticators to consider when authenticating to server."
 134   :group 'sieve-manage)
 135
 136 (defcustom sieve-manage-authenticator-alist
 137   '((cram-md5   sieve-manage-cram-md5-p       sieve-manage-cram-md5-auth)
 138     (digest-md5 sieve-manage-digest-md5-p     sieve-manage-digest-md5-auth)
 139     (scram-md5  sieve-manage-scram-md5-p      sieve-manage-scram-md5-auth)
 140     (ntlm       sieve-manage-ntlm-p           sieve-manage-ntlm-auth)
 141     (plain      sieve-manage-plain-p          sieve-manage-plain-auth)
 142     (login      sieve-manage-login-p          sieve-manage-login-auth))
 143   "Definition of authenticators.
 144
 145 \(NAME CHECK AUTHENTICATE)
 146
 147 NAME names the authenticator.  CHECK is a function returning non-nil if
 148 the server support the authenticator and AUTHENTICATE is a function
 149 for doing the actual authentication."
 150   :group 'sieve-manage)
 151
 152 (defcustom sieve-manage-default-port 2000
 153   "Default port number or service name for managesieve protocol."
 154   :type 'integer
 155   :group 'sieve-manage)
 156
 157 (defcustom sieve-manage-default-stream 'network
 158   "Default stream type to use for `sieve-manage'.
 159 Must be a name of a stream in `sieve-manage-stream-alist'."
 160   :type 'symbol
 161   :group 'sieve-manage)
 162
 163 ;; Internal variables:
 164
 165 (defconst sieve-manage-local-variables '(sieve-manage-server
 166                                          sieve-manage-port
 167                                          sieve-manage-auth
 168                                          sieve-manage-stream
 169                                          sieve-manage-process
 170                                          sieve-manage-client-eol
 171                                          sieve-manage-server-eol
 172                                          sieve-manage-capability))
 173 (defconst sieve-manage-coding-system-for-read 'binary)
 174 (defconst sieve-manage-coding-system-for-write 'binary)
 175 (defvar sieve-manage-stream nil)
 176 (defvar sieve-manage-auth nil)
 177 (defvar sieve-manage-server nil)
 178 (defvar sieve-manage-port nil)
 179 (defvar sieve-manage-state 'closed
 180   "Managesieve state.
 181 Valid states are `closed', `initial', `nonauth', and `auth'.")
 182 (defvar sieve-manage-process nil)
 183 (defvar sieve-manage-capability nil)
 184
 185 ;; Internal utility functions
 186
 187 (defmacro sieve-manage-disable-multibyte ()
 188   "Enable multibyte in the current buffer."
 189   (unless (featurep 'xemacs)
 190     '(set-buffer-multibyte nil)))
 191
 192 (defun sieve-manage-erase (&optional p buffer)
 193   (let ((buffer (or buffer (current-buffer))))
 194     (and sieve-manage-log
 195          (with-current-buffer (get-buffer-create sieve-manage-log)
 196            (sieve-manage-disable-multibyte)
 197            (buffer-disable-undo)
 198            (goto-char (point-max))
 199            (insert-buffer-substring buffer (with-current-buffer buffer
 200                                              (point-min))
 201                                     (or p (with-current-buffer buffer
 202                                             (point-max)))))))
 203   (delete-region (point-min) (or p (point-max))))
 204
 205 (defun sieve-manage-open-1 (buffer)
 206   (with-current-buffer buffer
 207     (sieve-manage-erase)
 208     (setq sieve-manage-state 'initial
 209           sieve-manage-process
 210           (condition-case ()
 211               (funcall (nth 2 (assq sieve-manage-stream
 212                                     sieve-manage-stream-alist))
 213                        "sieve" buffer sieve-manage-server sieve-manage-port)
 214             ((error quit) nil)))
 215     (when sieve-manage-process
 216       (while (and (eq sieve-manage-state 'initial)
 217                   (memq (process-status sieve-manage-process) '(open run)))
 218         (message "Waiting for response from %s..." sieve-manage-server)
 219         (accept-process-output sieve-manage-process 1))
 220       (message "Waiting for response from %s...done" sieve-manage-server)
 221       (and (memq (process-status sieve-manage-process) '(open run))
 222            sieve-manage-process))))
 223
 224 ;; Streams
 225
 226 (defun sieve-manage-network-p (buffer)
 227   t)
 228
 229 (defun sieve-manage-network-open (name buffer server port)
 230   (let* ((port (or port sieve-manage-default-port))
 231          (coding-system-for-read sieve-manage-coding-system-for-read)
 232          (coding-system-for-write sieve-manage-coding-system-for-write)
 233          (process (open-network-stream name buffer server port)))
 234     (when process
 235       (while (and (memq (process-status process) '(open run))
 236                   (set-buffer buffer) ;; XXX "blue moon" nntp.el bug
 237                   (goto-char (point-min))
 238                   (not (sieve-manage-parse-greeting-1)))
 239         (accept-process-output process 1)
 240         (sit-for 1))
 241       (sieve-manage-erase nil buffer)
 242       (when (memq (process-status process) '(open run))
 243         process))))
 244
 245 (defun sieve-manage-starttls-p (buffer)
 246   (condition-case ()
 247       (progn
 248         (require 'starttls)
 249         (call-process "starttls"))
 250     (error nil)))
 251
 252 (defun sieve-manage-starttls-open (name buffer server port)
 253   (let* ((port (or port sieve-manage-default-port))
 254          (coding-system-for-read sieve-manage-coding-system-for-read)
 255          (coding-system-for-write sieve-manage-coding-system-for-write)
 256          (process (starttls-open-stream name buffer server port))
 257          done)
 258     (when process
 259       (while (and (memq (process-status process) '(open run))
 260                   (set-buffer buffer) ;; XXX "blue moon" nntp.el bug
 261                   (goto-char (point-min))
 262                   (not (sieve-manage-parse-greeting-1)))
 263         (accept-process-output process 1)
 264         (sit-for 1))
 265       (sieve-manage-erase nil buffer)
 266       (sieve-manage-send "STARTTLS")
 267       (starttls-negotiate process))
 268     (when (memq (process-status process) '(open run))
 269       process)))
 270
 271 ;; Authenticators
 272 (defun sieve-sasl-auth (buffer mech)
 273   "Login to server using the SASL MECH method."
 274   (message "sieve: Authenticating using %s..." mech)
 275   (with-current-buffer buffer
 276     (let* ((auth-info (auth-source-search :host sieve-manage-server
 277                                           :port "sieve"
 278                                           :max 1))
 279            (user-name (plist-get (nth 0 auth-info) :user))
 280            (user-password (plist-get (nth 0 auth-info) :secret))
 281            (user-password (if (functionp user-password)
 282                               (funcall user-password)
 283                             user-password))
 284            (client (sasl-make-client (sasl-find-mechanism (list mech))
 285                                      user-name "sieve" sieve-manage-server))
 286            (sasl-read-passphrase
 287             ;; We *need* to copy the password, because sasl will modify it
 288             ;; somehow.
 289             `(lambda (prompt) ,(copy-sequence user-password)))
 290            (step (sasl-next-step client nil))
 291            (tag (sieve-manage-send
 292                  (concat
 293                   "AUTHENTICATE \""
 294                   mech
 295                   "\""
 296                   (and (sasl-step-data step)
 297                        (concat
 298                         " \""
 299                         (base64-encode-string
 300                          (sasl-step-data step)
 301                          'no-line-break)
 302                         "\"")))))
 303            data rsp)
 304       (catch 'done
 305         (while t
 306           (setq rsp nil)
 307           (goto-char (point-min))
 308           (while (null (or (progn
 309                              (setq rsp (sieve-manage-is-string))
 310                              (if (not (and rsp (looking-at
 311                                                 sieve-manage-server-eol)))
 312                                  (setq rsp nil)
 313                                (goto-char (match-end 0))
 314                                rsp))
 315                            (setq rsp (sieve-manage-is-okno))))
 316             (accept-process-output sieve-manage-process 1)
 317             (goto-char (point-min)))
 318           (sieve-manage-erase)
 319           (when (sieve-manage-ok-p rsp)
 320             (when (and (cadr rsp)
 321                        (string-match "^SASL \"\\([^\"]+\\)\"" (cadr rsp)))
 322               (sasl-step-set-data
 323                step (base64-decode-string (match-string 1 (cadr rsp)))))
 324             (if (and (setq step (sasl-next-step client step))
 325                      (setq data (sasl-step-data step)))
 326                 ;; We got data for server but it's finished
 327                 (error "Server not ready for SASL data: %s" data)
 328               ;; The authentication process is finished.
 329               (throw 'done t)))
 330           (unless (stringp rsp)
 331             (error "Server aborted SASL authentication: %s" (caddr rsp)))
 332           (sasl-step-set-data step (base64-decode-string rsp))
 333           (setq step (sasl-next-step client step))
 334           (sieve-manage-send
 335            (if (sasl-step-data step)
 336                (concat "\""
 337                        (base64-encode-string (sasl-step-data step)
 338                                              'no-line-break)
 339                        "\"")
 340              ""))))
 341       (message "sieve: Login using %s...done" mech))))
 342
 343 (defun sieve-manage-cram-md5-p (buffer)
 344   (sieve-manage-capability "SASL" "CRAM-MD5" buffer))
 345
 346 (defun sieve-manage-cram-md5-auth (buffer)
 347   "Login to managesieve server using the CRAM-MD5 SASL method."
 348   (sieve-sasl-auth buffer "CRAM-MD5"))
 349
 350 (defun sieve-manage-digest-md5-p (buffer)
 351   (sieve-manage-capability "SASL" "DIGEST-MD5" buffer))
 352
 353 (defun sieve-manage-digest-md5-auth (buffer)
 354   "Login to managesieve server using the DIGEST-MD5 SASL method."
 355   (sieve-sasl-auth buffer "DIGEST-MD5"))
 356
 357 (defun sieve-manage-scram-md5-p (buffer)
 358   (sieve-manage-capability "SASL" "SCRAM-MD5" buffer))
 359
 360 (defun sieve-manage-scram-md5-auth (buffer)
 361   "Login to managesieve server using the SCRAM-MD5 SASL method."
 362   (sieve-sasl-auth buffer "SCRAM-MD5"))
 363
 364 (defun sieve-manage-ntlm-p (buffer)
 365   (sieve-manage-capability "SASL" "NTLM" buffer))
 366
 367 (defun sieve-manage-ntlm-auth (buffer)
 368   "Login to managesieve server using the NTLM SASL method."
 369   (sieve-sasl-auth buffer "NTLM"))
 370
 371 (defun sieve-manage-plain-p (buffer)
 372   (sieve-manage-capability "SASL" "PLAIN" buffer))
 373
 374 (defun sieve-manage-plain-auth (buffer)
 375   "Login to managesieve server using the PLAIN SASL method."
 376   (sieve-sasl-auth buffer "PLAIN"))
 377
 378 (defun sieve-manage-login-p (buffer)
 379   (sieve-manage-capability "SASL" "LOGIN" buffer))
 380
 381 (defun sieve-manage-login-auth (buffer)
 382   "Login to managesieve server using the LOGIN SASL method."
 383   (sieve-sasl-auth buffer "LOGIN"))
 384
 385 ;; Managesieve API
 386
 387 (defun sieve-manage-open (server &optional port stream auth buffer)
 388   "Open a network connection to a managesieve SERVER (string).
 389 Optional argument PORT is port number (integer) on remote server.
 390 Optional argument STREAM is any of `sieve-manage-streams' (a symbol).
 391 Optional argument AUTH indicates authenticator to use, see
 392 `sieve-manage-authenticators' for available authenticators.
 393 If nil, chooses the best stream the server is capable of.
 394 Optional argument BUFFER is buffer (buffer, or string naming buffer)
 395 to work in."
 396   (or port (setq port sieve-manage-default-port))
 397   (setq buffer (or buffer (format " *sieve* %s:%s" server port)))
 398   (with-current-buffer (get-buffer-create buffer)
 399     (mapc 'make-local-variable sieve-manage-local-variables)
 400     (sieve-manage-disable-multibyte)
 401     (buffer-disable-undo)
 402     (setq sieve-manage-server (or server sieve-manage-server))
 403     (setq sieve-manage-port port)
 404     (setq sieve-manage-stream (or stream sieve-manage-stream))
 405     (message "sieve: Connecting to %s..." sieve-manage-server)
 406     (if (let ((sieve-manage-stream
 407                (or sieve-manage-stream sieve-manage-default-stream)))
 408           (sieve-manage-open-1 buffer))
 409         ;; Choose stream.
 410         (let (stream-changed)
 411           (message "sieve: Connecting to %s...done" sieve-manage-server)
 412           (when (null sieve-manage-stream)
 413             (let ((streams sieve-manage-streams))
 414               (while (setq stream (pop streams))
 415                 (if (funcall (nth 1 (assq stream
 416                                           sieve-manage-stream-alist)) buffer)
 417                     (setq stream-changed
 418                           (not (eq (or sieve-manage-stream
 419                                        sieve-manage-default-stream)
 420                                    stream))
 421                           sieve-manage-stream stream
 422                           streams nil)))
 423               (unless sieve-manage-stream
 424                 (error "Couldn't figure out a stream for server"))))
 425           (when stream-changed
 426             (message "sieve: Reconnecting with stream `%s'..."
 427                      sieve-manage-stream)
 428             (sieve-manage-close buffer)
 429             (if (sieve-manage-open-1 buffer)
 430                 (message "sieve: Reconnecting with stream `%s'...done"
 431                          sieve-manage-stream)
 432               (message "sieve: Reconnecting with stream `%s'...failed"
 433                        sieve-manage-stream))
 434             (setq sieve-manage-capability nil))
 435           (if (sieve-manage-opened buffer)
 436               ;; Choose authenticator
 437               (when (and (null sieve-manage-auth)
 438                          (not (eq sieve-manage-state 'auth)))
 439                 (let ((auths sieve-manage-authenticators))
 440                   (while (setq auth (pop auths))
 441                     (if (funcall (nth 1 (assq
 442                                          auth
 443                                          sieve-manage-authenticator-alist))
 444                                  buffer)
 445                         (setq sieve-manage-auth auth
 446                               auths nil)))
 447                   (unless sieve-manage-auth
 448                     (error "Couldn't figure out authenticator for server"))))))
 449       (message "sieve: Connecting to %s...failed" sieve-manage-server))
 450     (when (sieve-manage-opened buffer)
 451       (sieve-manage-erase)
 452       buffer)))
 453
 454 (defun sieve-manage-authenticate (&optional buffer)
 455   "Authenticate on server in BUFFER.
 456 Return `sieve-manage-state' value."
 457   (with-current-buffer (or buffer (current-buffer))
 458     (if (eq sieve-manage-state 'nonauth)
 459         (when (funcall (nth 2 (assq sieve-manage-auth
 460                                     sieve-manage-authenticator-alist))
 461                        (current-buffer))
 462           (setq sieve-manage-state 'auth))
 463       sieve-manage-state)))
 464
 465 (defun sieve-manage-opened (&optional buffer)
 466   "Return non-nil if connection to managesieve server in BUFFER is open.
 467 If BUFFER is nil then the current buffer is used."
 468   (and (setq buffer (get-buffer (or buffer (current-buffer))))
 469        (buffer-live-p buffer)
 470        (with-current-buffer buffer
 471          (and sieve-manage-process
 472               (memq (process-status sieve-manage-process) '(open run))))))
 473
 474 (defun sieve-manage-close (&optional buffer)
 475   "Close connection to managesieve server in BUFFER.
 476 If BUFFER is nil, the current buffer is used."
 477   (with-current-buffer (or buffer (current-buffer))
 478     (when (sieve-manage-opened)
 479       (sieve-manage-send "LOGOUT")
 480       (sit-for 1))
 481     (when (and sieve-manage-process
 482                (memq (process-status sieve-manage-process) '(open run)))
 483       (delete-process sieve-manage-process))
 484     (setq sieve-manage-process nil)
 485     (sieve-manage-erase)
 486     t))
 487
 488 (defun sieve-manage-capability (&optional name value buffer)
 489   "Check if capability NAME of server BUFFER match VALUE.
 490 If it does, return the server value of NAME. If not returns nil.
 491 If VALUE is nil, do not check VALUE and return server value.
 492 If NAME is nil, return the full server list of capabilities."
 493   (with-current-buffer (or buffer (current-buffer))
 494     (if (null name)
 495         sieve-manage-capability
 496       (let ((server-value (cadr (assoc name sieve-manage-capability))))
 497         (when (or (null value)
 498                   (and server-value
 499                        (string-match value server-value)))
 500           server-value)))))
 501
 502 (defun sieve-manage-listscripts (&optional buffer)
 503   (with-current-buffer (or buffer (current-buffer))
 504     (sieve-manage-send "LISTSCRIPTS")
 505     (sieve-manage-parse-listscripts)))
 506
 507 (defun sieve-manage-havespace (name size &optional buffer)
 508   (with-current-buffer (or buffer (current-buffer))
 509     (sieve-manage-send (format "HAVESPACE \"%s\" %s" name size))
 510     (sieve-manage-parse-okno)))
 511
 512 (defun sieve-manage-putscript (name content &optional buffer)
 513   (with-current-buffer (or buffer (current-buffer))
 514     (sieve-manage-send (format "PUTSCRIPT \"%s\" {%d+}%s%s" name
 515                                ;; Here we assume that the coding-system will
 516                                ;; replace each char with a single byte.
 517                                ;; This is always the case if `content' is
 518                                ;; a unibyte string.
 519                                (length content)
 520                                sieve-manage-client-eol content))
 521     (sieve-manage-parse-okno)))
 522
 523 (defun sieve-manage-deletescript (name &optional buffer)
 524   (with-current-buffer (or buffer (current-buffer))
 525     (sieve-manage-send (format "DELETESCRIPT \"%s\"" name))
 526     (sieve-manage-parse-okno)))
 527
 528 (defun sieve-manage-getscript (name output-buffer &optional buffer)
 529   (with-current-buffer (or buffer (current-buffer))
 530     (sieve-manage-send (format "GETSCRIPT \"%s\"" name))
 531     (let ((script (sieve-manage-parse-string)))
 532       (sieve-manage-parse-crlf)
 533       (with-current-buffer output-buffer
 534         (insert script))
 535       (sieve-manage-parse-okno))))
 536
 537 (defun sieve-manage-setactive (name &optional buffer)
 538   (with-current-buffer (or buffer (current-buffer))
 539     (sieve-manage-send (format "SETACTIVE \"%s\"" name))
 540     (sieve-manage-parse-okno)))
 541
 542 ;; Protocol parsing routines
 543
 544 (defun sieve-manage-ok-p (rsp)
 545   (string= (downcase (or (car-safe rsp) "")) "ok"))
 546
 547 (defsubst sieve-manage-forward ()
 548   (or (eobp) (forward-char)))
 549
 550 (defun sieve-manage-is-okno ()
 551   (when (looking-at (concat
 552                      "^\\(OK\\|NO\\)\\( (\\([^)]+\\))\\)?\\( \\(.*\\)\\)?"
 553                      sieve-manage-server-eol))
 554     (let ((status (match-string 1))
 555           (resp-code (match-string 3))
 556           (response (match-string 5)))
 557       (when response
 558         (goto-char (match-beginning 5))
 559         (setq response (sieve-manage-is-string)))
 560       (list status resp-code response))))
 561
 562 (defun sieve-manage-parse-okno ()
 563   (let (rsp)
 564     (while (null rsp)
 565       (accept-process-output (get-buffer-process (current-buffer)) 1)
 566       (goto-char (point-min))
 567       (setq rsp (sieve-manage-is-okno)))
 568     (sieve-manage-erase)
 569     rsp))
 570
 571 (defun sieve-manage-parse-capability-1 ()
 572   "Accept a managesieve greeting."
 573   (let (str)
 574     (while (setq str (sieve-manage-is-string))
 575       (if (eq (char-after) ? )
 576           (progn
 577             (sieve-manage-forward)
 578             (push (list str (sieve-manage-is-string))
 579                   sieve-manage-capability))
 580         (push (list str) sieve-manage-capability))
 581       (forward-line)))
 582   (when (re-search-forward (concat "^OK.*" sieve-manage-server-eol) nil t)
 583     (setq sieve-manage-state 'nonauth)))
 584
 585 (defalias 'sieve-manage-parse-greeting-1 'sieve-manage-parse-capability-1)
 586
 587 (defun sieve-manage-is-string ()
 588   (cond ((looking-at "\"\\([^\"]+\\)\"")
 589          (prog1
 590              (match-string 1)
 591            (goto-char (match-end 0))))
 592         ((looking-at (concat "{\\([0-9]+\\+?\\)}" sieve-manage-server-eol))
 593          (let ((pos (match-end 0))
 594                (len (string-to-number (match-string 1))))
 595            (if (< (point-max) (+ pos len))
 596                nil
 597              (goto-char (+ pos len))
 598              (buffer-substring pos (+ pos len)))))))
 599
 600 (defun sieve-manage-parse-string ()
 601   (let (rsp)
 602     (while (null rsp)
 603       (accept-process-output (get-buffer-process (current-buffer)) 1)
 604       (goto-char (point-min))
 605       (setq rsp (sieve-manage-is-string)))
 606     (sieve-manage-erase (point))
 607     rsp))
 608
 609 (defun sieve-manage-parse-crlf ()
 610   (when (looking-at sieve-manage-server-eol)
 611     (sieve-manage-erase (match-end 0))))
 612
 613 (defun sieve-manage-parse-listscripts ()
 614   (let (tmp rsp data)
 615     (while (null rsp)
 616       (while (null (or (setq rsp (sieve-manage-is-okno))
 617                        (setq tmp (sieve-manage-is-string))))
 618         (accept-process-output (get-buffer-process (current-buffer)) 1)
 619         (goto-char (point-min)))
 620       (when tmp
 621         (while (not (looking-at (concat "\\( ACTIVE\\)?"
 622                                         sieve-manage-server-eol)))
 623           (accept-process-output (get-buffer-process (current-buffer)) 1)
 624           (goto-char (point-min)))
 625         (if (match-string 1)
 626             (push (cons 'active tmp) data)
 627           (push tmp data))
 628         (goto-char (match-end 0))
 629         (setq tmp nil)))
 630     (sieve-manage-erase)
 631     (if (sieve-manage-ok-p rsp)
 632         data
 633       rsp)))
 634
 635 (defun sieve-manage-send (cmdstr)
 636   (setq cmdstr (concat cmdstr sieve-manage-client-eol))
 637   (and sieve-manage-log
 638        (with-current-buffer (get-buffer-create sieve-manage-log)
 639          (sieve-manage-disable-multibyte)
 640          (buffer-disable-undo)
 641          (goto-char (point-max))
 642          (insert cmdstr)))
 643   (process-send-string sieve-manage-process cmdstr))
 644
 645 (provide 'sieve-manage)
 646
 647 ;; sieve-manage.el ends here