cgit.sxemacs.org Git - gnus/blob - lisp/shr.el

   1 ;;; shr.el --- Simple HTML Renderer
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package takes a HTML parse tree (as provided by
  26 ;; libxml-parse-html-region) and renders it in the current buffer.  It
  27 ;; does not do CSS, JavaScript or anything advanced: It's geared
  28 ;; towards rendering typical short snippets of HTML, like what you'd
  29 ;; find in HTML email and the like.
  30
  31 ;;; Code:
  32
  33 (eval-when-compile (require 'cl))
  34 (require 'browse-url)
  35 (unless (aref (char-category-set (make-char 'japanese-jisx0208 33 35)) ?>)
  36   (load "kinsoku" nil t))
  37
  38 (defgroup shr nil
  39   "Simple HTML Renderer"
  40   :group 'mail)
  41
  42 (defcustom shr-max-image-proportion 0.9
  43   "How big pictures displayed are in relation to the window they're in.
  44 A value of 0.7 means that they are allowed to take up 70% of the
  45 width and height of the window.  If they are larger than this,
  46 and Emacs supports it, then the images will be rescaled down to
  47 fit these criteria."
  48   :version "24.1"
  49   :group 'shr
  50   :type 'float)
  51
  52 (defcustom shr-blocked-images nil
  53   "Images that have URLs matching this regexp will be blocked."
  54   :version "24.1"
  55   :group 'shr
  56   :type 'regexp)
  57
  58 (defcustom shr-table-line ?-
  59   "Character used to draw table line."
  60   :group 'shr
  61   :type 'character)
  62
  63 (defcustom shr-table-corner ?+
  64   "Character used to draw table corner."
  65   :group 'shr
  66   :type 'character)
  67
  68 (defcustom shr-hr-line ?-
  69   "Character used to draw hr line."
  70   :group 'shr
  71   :type 'character)
  72
  73 (defcustom shr-width fill-column
  74   "Frame width to use for rendering."
  75   :type 'integer
  76   :group 'shr)
  77
  78 (defvar shr-content-function nil
  79   "If bound, this should be a function that will return the content.
  80 This is used for cid: URLs, and the function is called with the
  81 cid: URL as the argument.")
  82
  83 ;;; Internal variables.
  84
  85 (defvar shr-folding-mode nil)
  86 (defvar shr-state nil)
  87 (defvar shr-start nil)
  88 (defvar shr-indentation 0)
  89 (defvar shr-inhibit-images nil)
  90 (defvar shr-list-mode nil)
  91 (defvar shr-content-cache nil)
  92 (defvar shr-kinsoku-shorten nil)
  93
  94 (defvar shr-map
  95   (let ((map (make-sparse-keymap)))
  96     (define-key map "a" 'shr-show-alt-text)
  97     (define-key map "i" 'shr-browse-image)
  98     (define-key map "I" 'shr-insert-image)
  99     (define-key map "u" 'shr-copy-url)
 100     (define-key map "v" 'shr-browse-url)
 101     (define-key map "o" 'shr-save-contents)
 102     (define-key map "\r" 'shr-browse-url)
 103     map))
 104
 105 ;; Public functions and commands.
 106
 107 ;;;###autoload
 108 (defun shr-insert-document (dom)
 109   (setq shr-content-cache nil)
 110   (let ((shr-state nil)
 111         (shr-start nil))
 112     (shr-descend (shr-transform-dom dom))))
 113
 114 (defun shr-copy-url ()
 115   "Copy the URL under point to the kill ring.
 116 If called twice, then try to fetch the URL and see whether it
 117 redirects somewhere else."
 118   (interactive)
 119   (let ((url (get-text-property (point) 'shr-url)))
 120     (cond
 121      ((not url)
 122       (message "No URL under point"))
 123      ;; Resolve redirected URLs.
 124      ((equal url (car kill-ring))
 125       (url-retrieve
 126        url
 127        (lambda (a)
 128          (when (and (consp a)
 129                     (eq (car a) :redirect))
 130            (with-temp-buffer
 131              (insert (cadr a))
 132              (goto-char (point-min))
 133              ;; Remove common tracking junk from the URL.
 134              (when (re-search-forward ".utm_.*" nil t)
 135                (replace-match "" t t))
 136              (message "Copied %s" (buffer-string))
 137              (copy-region-as-kill (point-min) (point-max)))))))
 138      ;; Copy the URL to the kill ring.
 139      (t
 140       (with-temp-buffer
 141         (insert url)
 142         (copy-region-as-kill (point-min) (point-max))
 143         (message "Copied %s" url))))))
 144
 145 (defun shr-show-alt-text ()
 146   "Show the ALT text of the image under point."
 147   (interactive)
 148   (let ((text (get-text-property (point) 'shr-alt)))
 149     (if (not text)
 150         (message "No image under point")
 151       (message "%s" text))))
 152
 153 (defun shr-browse-image ()
 154   "Browse the image under point."
 155   (interactive)
 156   (let ((url (get-text-property (point) 'shr-image)))
 157     (if (not url)
 158         (message "No image under point")
 159       (message "Browsing %s..." url)
 160       (browse-url url))))
 161
 162 (defun shr-insert-image ()
 163   "Insert the image under point into the buffer."
 164   (interactive)
 165   (let ((url (get-text-property (point) 'shr-image)))
 166     (if (not url)
 167         (message "No image under point")
 168       (message "Inserting %s..." url)
 169       (url-retrieve url 'shr-image-fetched
 170                     (list (current-buffer) (1- (point)) (point-marker))
 171                     t))))
 172
 173 ;;; Utility functions.
 174
 175 (defun shr-transform-dom (dom)
 176   (let ((result (list (pop dom))))
 177     (dolist (arg (pop dom))
 178       (push (cons (intern (concat ":" (symbol-name (car arg))) obarray)
 179                   (cdr arg))
 180             result))
 181     (dolist (sub dom)
 182       (if (stringp sub)
 183           (push (cons :text sub) result)
 184         (push (shr-transform-dom sub) result)))
 185     (nreverse result)))
 186
 187 (defun shr-descend (dom)
 188   (let ((function (intern (concat "shr-tag-" (symbol-name (car dom))) obarray)))
 189     (if (fboundp function)
 190         (funcall function (cdr dom))
 191       (shr-generic (cdr dom)))))
 192
 193 (defun shr-generic (cont)
 194   (dolist (sub cont)
 195     (cond
 196      ((eq (car sub) :text)
 197       (shr-insert (cdr sub)))
 198      ((listp (cdr sub))
 199       (shr-descend sub)))))
 200
 201 (defun shr-insert (text)
 202   (when (and (eq shr-state 'image)
 203              (not (string-match "\\`[ \t\n]+\\'" text)))
 204     (insert "\n")
 205     (setq shr-state nil))
 206   (cond
 207    ((eq shr-folding-mode 'none)
 208     (insert text))
 209    (t
 210     (when (and (string-match "\\`[ \t\n]" text)
 211                (not (bolp))
 212                (not (eq (char-after (1- (point))) ? )))
 213       (insert " "))
 214     (dolist (elem (split-string text))
 215       (when (and (bolp)
 216                  (> shr-indentation 0))
 217         (shr-indent))
 218       ;; The shr-start is a special variable that is used to pass
 219       ;; upwards the first point in the buffer where the text really
 220       ;; starts.
 221       (unless shr-start
 222         (setq shr-start (point)))
 223       ;; No space is needed behind a wide character categorized as
 224       ;; kinsoku-bol, between characters both categorized as nospace,
 225       ;; or at the beginning of a line.
 226       (let (prev)
 227         (when (and (eq (preceding-char) ? )
 228                    (or (= (line-beginning-position) (1- (point)))
 229                        (and (aref fill-find-break-point-function-table
 230                                   (setq prev (char-after (- (point) 2))))
 231                             (aref (char-category-set prev) ?>))
 232                        (and (aref fill-nospace-between-words-table prev)
 233                             (aref fill-nospace-between-words-table
 234                                   (aref elem 0)))))
 235           (delete-char -1)))
 236       (insert elem)
 237       (while (> (current-column) shr-width)
 238         (unless (prog1
 239                     (shr-find-fill-point)
 240                   (when (eq (preceding-char) ? )
 241                     (delete-char -1))
 242                   (insert "\n"))
 243           (put-text-property (1- (point)) (point) 'shr-break t)
 244           ;; No space is needed at the beginning of a line.
 245           (when (eq (following-char) ? )
 246             (delete-char 1)))
 247         (when (> shr-indentation 0)
 248           (shr-indent))
 249         (end-of-line))
 250       (insert " "))
 251     (unless (string-match "[ \t\n]\\'" text)
 252       (delete-char -1)))))
 253
 254 (defun shr-find-fill-point ()
 255   (when (> (move-to-column shr-width) shr-width)
 256     (backward-char 1))
 257   (let (failed)
 258     (while (not
 259             (or (setq failed (= (current-column) shr-indentation))
 260                 (eq (preceding-char) ? )
 261                 (eq (following-char) ? )
 262                 (aref fill-find-break-point-function-table (preceding-char))))
 263       (backward-char 1))
 264     (if failed
 265         ;; There's no breakable point, so we give it up.
 266         (progn
 267           (end-of-line)
 268           (while (aref fill-find-break-point-function-table (preceding-char))
 269             (backward-char 1))
 270           nil)
 271       (or (eolp)
 272           ;; Don't put kinsoku-bol characters at the beginning of a line,
 273           ;; or kinsoku-eol characters at the end of a line,
 274           (let ((count 4))
 275             (if (or shr-kinsoku-shorten
 276                     (and (aref (char-category-set (preceding-char)) ?<)
 277                          (progn
 278                            (setq count (1- count))
 279                            (backward-char 1)
 280                            t)))
 281                 (while (and
 282                         (>= (setq count (1- count)) 0)
 283                         (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 284                         (or (aref (char-category-set (preceding-char)) ?<)
 285                             (aref (char-category-set (following-char)) ?>)))
 286                   (backward-char 1))
 287               (while (and (>= (setq count (1- count)) 0)
 288                           (aref (char-category-set (following-char)) ?>))
 289                 (forward-char 1)))
 290             (when (eq (following-char) ? )
 291               (forward-char 1))
 292             t)))))
 293
 294 (defun shr-ensure-newline ()
 295   (unless (zerop (current-column))
 296     (insert "\n")))
 297
 298 (defun shr-ensure-paragraph ()
 299   (unless (bobp)
 300     (if (<= (current-column) shr-indentation)
 301         (unless (save-excursion
 302                   (forward-line -1)
 303                   (looking-at " *$"))
 304           (insert "\n"))
 305       (if (save-excursion
 306             (beginning-of-line)
 307             (looking-at " *$"))
 308           (insert "\n")
 309         (insert "\n\n")))))
 310
 311 (defun shr-indent ()
 312   (when (> shr-indentation 0)
 313     (insert (make-string shr-indentation ? ))))
 314
 315 (defun shr-fontize-cont (cont &rest types)
 316   (let (shr-start)
 317     (shr-generic cont)
 318     (dolist (type types)
 319       (shr-add-font (or shr-start (point)) (point) type))))
 320
 321 ;; Add an overlay in the region, but avoid putting the font properties
 322 ;; on blank text at the start of the line, and the newline at the end,
 323 ;; to avoid ugliness.
 324 (defun shr-add-font (start end type)
 325   (save-excursion
 326     (goto-char start)
 327     (while (< (point) end)
 328       (when (bolp)
 329         (skip-chars-forward " "))
 330       (let ((overlay (make-overlay (point) (min (line-end-position) end))))
 331         (overlay-put overlay 'face type))
 332       (if (< (line-end-position) end)
 333           (forward-line 1)
 334         (goto-char end)))))
 335
 336 (defun shr-browse-url ()
 337   "Browse the URL under point."
 338   (interactive)
 339   (let ((url (get-text-property (point) 'shr-url)))
 340     (if (not url)
 341         (message "No link under point")
 342       (browse-url url))))
 343
 344 (defun shr-save-contents (directory)
 345   "Save the contents from URL in a file."
 346   (interactive "DSave contents of URL to directory: ")
 347   (let ((url (get-text-property (point) 'shr-url)))
 348     (if (not url)
 349         (message "No link under point")
 350       (url-retrieve (shr-encode-url url)
 351                     'shr-store-contents (list url directory)))))
 352
 353 (defun shr-store-contents (status url directory)
 354   (unless (plist-get status :error)
 355     (when (or (search-forward "\n\n" nil t)
 356               (search-forward "\r\n\r\n" nil t))
 357       (write-region (point) (point-max)
 358                     (expand-file-name (file-name-nondirectory url)
 359                                       directory)))))
 360
 361 (defun shr-image-fetched (status buffer start end)
 362   (when (and (buffer-name buffer)
 363              (not (plist-get status :error)))
 364     (url-store-in-cache (current-buffer))
 365     (when (or (search-forward "\n\n" nil t)
 366               (search-forward "\r\n\r\n" nil t))
 367       (let ((data (buffer-substring (point) (point-max))))
 368         (with-current-buffer buffer
 369           (let ((alt (buffer-substring start end))
 370                 (inhibit-read-only t))
 371             (delete-region start end)
 372             (shr-put-image data start alt))))))
 373   (kill-buffer (current-buffer)))
 374
 375 (defun shr-put-image (data point alt)
 376   (if (not (display-graphic-p))
 377       (insert alt)
 378     (let ((image (ignore-errors
 379                    (shr-rescale-image data))))
 380       (when image
 381         (put-image image point alt)))))
 382
 383 (defun shr-rescale-image (data)
 384   (if (or (not (fboundp 'imagemagick-types))
 385           (not (get-buffer-window (current-buffer))))
 386       (create-image data nil t)
 387     (let* ((image (create-image data nil t))
 388            (size (image-size image t))
 389            (width (car size))
 390            (height (cdr size))
 391            (edges (window-inside-pixel-edges
 392                    (get-buffer-window (current-buffer))))
 393            (window-width (truncate (* shr-max-image-proportion
 394                                       (- (nth 2 edges) (nth 0 edges)))))
 395            (window-height (truncate (* shr-max-image-proportion
 396                                        (- (nth 3 edges) (nth 1 edges)))))
 397            scaled-image)
 398       (when (> height window-height)
 399         (setq image (or (create-image data 'imagemagick t
 400                                       :height window-height)
 401                         image))
 402         (setq size (image-size image t)))
 403       (when (> (car size) window-width)
 404         (setq image (or
 405                      (create-image data 'imagemagick t
 406                                    :width window-width)
 407                      image)))
 408       image)))
 409
 410 (defun shr-get-image-data (url)
 411   "Get image data for URL.
 412 Return a string with image data."
 413   (with-temp-buffer
 414     (mm-disable-multibyte)
 415     (when (ignore-errors
 416             (url-cache-extract (url-cache-create-filename (shr-encode-url url)))
 417             t)
 418       (when (or (search-forward "\n\n" nil t)
 419                 (search-forward "\r\n\r\n" nil t))
 420         (buffer-substring (point) (point-max))))))
 421
 422 (defun shr-heading (cont &rest types)
 423   (shr-ensure-paragraph)
 424   (apply #'shr-fontize-cont cont types)
 425   (shr-ensure-paragraph))
 426
 427 ;;; Tag-specific rendering rules.
 428
 429 (defun shr-tag-p (cont)
 430   (shr-ensure-paragraph)
 431   (shr-indent)
 432   (shr-generic cont)
 433   (shr-ensure-paragraph))
 434
 435 (defun shr-tag-b (cont)
 436   (shr-fontize-cont cont 'bold))
 437
 438 (defun shr-tag-i (cont)
 439   (shr-fontize-cont cont 'italic))
 440
 441 (defun shr-tag-em (cont)
 442   (shr-fontize-cont cont 'bold))
 443
 444 (defun shr-tag-strong (cont)
 445   (shr-fontize-cont cont 'bold))
 446
 447 (defun shr-tag-u (cont)
 448   (shr-fontize-cont cont 'underline))
 449
 450 (defun shr-tag-s (cont)
 451   (shr-fontize-cont cont 'strike-through))
 452
 453 (defun shr-tag-span (cont)
 454   (let ((start (point))
 455         (color (cdr (assq 'color (shr-parse-style (cdr (assq :style cont)))))))
 456     (shr-generic cont)
 457     (when color
 458       (let ((overlay (make-overlay start (point))))
 459         (overlay-put overlay 'face (cons 'foreground-color color))))))
 460
 461 (defun shr-parse-style (style)
 462   (when style
 463     (let ((plist nil))
 464       (dolist (elem (split-string style ";"))
 465         (when elem
 466           (setq elem (split-string elem ":"))
 467           (when (and (car elem)
 468                      (cadr elem))
 469             (let ((name (replace-regexp-in-string "^ +\\| +$" "" (car elem)))
 470                   (value (replace-regexp-in-string "^ +\\| +$" "" (cadr elem))))
 471               (push (cons (intern name obarray)
 472                           value)
 473                     plist)))))
 474       plist)))
 475
 476 (defun shr-tag-a (cont)
 477   (let ((url (cdr (assq :href cont)))
 478         (start (point))
 479         shr-start)
 480     (shr-generic cont)
 481     (widget-convert-button
 482      'url-link (or shr-start start) (point)
 483      :help-echo url
 484      :keymap shr-map
 485      url)
 486     (put-text-property (or shr-start start) (point) 'shr-url url)))
 487
 488 (defun shr-encode-url (url)
 489   "Encode URL."
 490   (browse-url-url-encode-chars url "[)$ ]"))
 491
 492 (defun shr-tag-img (cont)
 493   (when (and cont
 494              (cdr (assq :src cont)))
 495     (when (and (> (current-column) 0)
 496                (not (eq shr-state 'image)))
 497       (insert "\n"))
 498     (let ((alt (cdr (assq :alt cont)))
 499           (url (cdr (assq :src cont))))
 500       (let ((start (point-marker)))
 501         (when (zerop (length alt))
 502           (setq alt "[img]"))
 503         (cond
 504          ((and (not shr-inhibit-images)
 505                (string-match "\\`cid:" url))
 506           (let ((url (substring url (match-end 0)))
 507                 image)
 508             (if (or (not shr-content-function)
 509                     (not (setq image (funcall shr-content-function url))))
 510                 (insert alt)
 511               (shr-put-image image (point) alt))))
 512          ((or shr-inhibit-images
 513               (and shr-blocked-images
 514                    (string-match shr-blocked-images url)))
 515           (setq shr-start (point))
 516           (let ((shr-state 'space))
 517             (if (> (length alt) 8)
 518                 (shr-insert (substring alt 0 8))
 519               (shr-insert alt))))
 520          ((url-is-cached (shr-encode-url url))
 521           (shr-put-image (shr-get-image-data url) (point) alt))
 522          (t
 523           (insert alt)
 524           (ignore-errors
 525             (url-retrieve (shr-encode-url url) 'shr-image-fetched
 526                           (list (current-buffer) start (point-marker))
 527                           t))))
 528         (insert " ")
 529         (put-text-property start (point) 'keymap shr-map)
 530         (put-text-property start (point) 'shr-alt alt)
 531         (put-text-property start (point) 'shr-image url)
 532         (setq shr-state 'image)))))
 533
 534 (defun shr-tag-pre (cont)
 535   (let ((shr-folding-mode 'none))
 536     (shr-ensure-newline)
 537     (shr-indent)
 538     (shr-generic cont)
 539     (shr-ensure-newline)))
 540
 541 (defun shr-tag-blockquote (cont)
 542   (shr-ensure-paragraph)
 543   (shr-indent)
 544   (let ((shr-indentation (+ shr-indentation 4)))
 545     (shr-generic cont))
 546   (shr-ensure-paragraph))
 547
 548 (defun shr-tag-ul (cont)
 549   (shr-ensure-paragraph)
 550   (let ((shr-list-mode 'ul))
 551     (shr-generic cont))
 552   (shr-ensure-paragraph))
 553
 554 (defun shr-tag-ol (cont)
 555   (shr-ensure-paragraph)
 556   (let ((shr-list-mode 1))
 557     (shr-generic cont))
 558   (shr-ensure-paragraph))
 559
 560 (defun shr-tag-li (cont)
 561   (shr-ensure-paragraph)
 562   (shr-indent)
 563   (let* ((bullet
 564           (if (numberp shr-list-mode)
 565               (prog1
 566                   (format "%d " shr-list-mode)
 567                 (setq shr-list-mode (1+ shr-list-mode)))
 568             "* "))
 569          (shr-indentation (+ shr-indentation (length bullet))))
 570     (insert bullet)
 571     (shr-generic cont)))
 572
 573 (defun shr-tag-br (cont)
 574   (unless (bobp)
 575     (insert "\n")
 576     (shr-indent))
 577   (shr-generic cont))
 578
 579 (defun shr-tag-h1 (cont)
 580   (shr-heading cont 'bold 'underline))
 581
 582 (defun shr-tag-h2 (cont)
 583   (shr-heading cont 'bold))
 584
 585 (defun shr-tag-h3 (cont)
 586   (shr-heading cont 'italic))
 587
 588 (defun shr-tag-h4 (cont)
 589   (shr-heading cont))
 590
 591 (defun shr-tag-h5 (cont)
 592   (shr-heading cont))
 593
 594 (defun shr-tag-h6 (cont)
 595   (shr-heading cont))
 596
 597 (defun shr-tag-hr (cont)
 598   (shr-ensure-newline)
 599   (insert (make-string shr-width shr-hr-line) "\n"))
 600
 601 ;;; Table rendering algorithm.
 602
 603 ;; Table rendering is the only complicated thing here.  We do this by
 604 ;; first counting how many TDs there are in each TR, and registering
 605 ;; how wide they think they should be ("width=45%", etc).  Then we
 606 ;; render each TD separately (this is done in temporary buffers, so
 607 ;; that we can use all the rendering machinery as if we were in the
 608 ;; main buffer).  Now we know how much space each TD really takes, so
 609 ;; we then render everything again with the new widths, and finally
 610 ;; insert all these boxes into the main buffer.
 611 (defun shr-tag-table-1 (cont)
 612   (setq cont (or (cdr (assq 'tbody cont))
 613                  cont))
 614   (let* ((shr-inhibit-images t)
 615          (shr-kinsoku-shorten t)
 616          ;; Find all suggested widths.
 617          (columns (shr-column-specs cont))
 618          ;; Compute how many characters wide each TD should be.
 619          (suggested-widths (shr-pro-rate-columns columns))
 620          ;; Do a "test rendering" to see how big each TD is (this can
 621          ;; be smaller (if there's little text) or bigger (if there's
 622          ;; unbreakable text).
 623          (sketch (shr-make-table cont suggested-widths))
 624          (sketch-widths (shr-table-widths sketch suggested-widths)))
 625     ;; This probably won't work very well.
 626     (when (> (+ (loop for width across sketch-widths
 627                       summing (1+ width))
 628                 shr-indentation 1)
 629              (frame-width))
 630       (setq truncate-lines t))
 631     ;; Then render the table again with these new "hard" widths.
 632     (shr-insert-table (shr-make-table cont sketch-widths t) sketch-widths))
 633   ;; Finally, insert all the images after the table.  The Emacs buffer
 634   ;; model isn't strong enough to allow us to put the images actually
 635   ;; into the tables.
 636   (dolist (elem (shr-find-elements cont 'img))
 637     (shr-tag-img (cdr elem))))
 638
 639 (defun shr-tag-table (cont)
 640   (shr-ensure-paragraph)
 641   (let* ((caption (cdr (assq 'caption cont)))
 642          (header (cdr (assq 'thead cont)))
 643          (body (or (cdr (assq 'tbody cont)) cont))
 644          (footer (cdr (assq 'tfoot cont)))
 645          (nheader (if header (shr-max-columns header)))
 646          (nbody (if body (shr-max-columns body)))
 647          (nfooter (if footer (shr-max-columns footer))))
 648     (shr-tag-table-1
 649      (nconc
 650       (if caption `((tr (td ,@caption))))
 651       (if header
 652           (if footer
 653               ;; hader + body + footer
 654               (if (= nheader nbody)
 655                   (if (= nbody nfooter)
 656                       `((tr (td (table (tbody ,@header ,@body ,@footer)))))
 657                     (nconc `((tr (td (table (tbody ,@header ,@body)))))
 658                            (if (= nfooter 1)
 659                                footer
 660                              `((tr (td (table (tbody ,@footer))))))))
 661                 (nconc `((tr (td (table (tbody ,@header)))))
 662                        (if (= nbody nfooter)
 663                            `((tr (td (table (tbody ,@body ,@footer)))))
 664                          (nconc `((tr (td (table (tbody ,@body)))))
 665                                 (if (= nfooter 1)
 666                                     footer
 667                                   `((tr (td (table (tbody ,@footer))))))))))
 668             ;; header + body
 669             (if (= nheader nbody)
 670                 `((tr (td (table (tbody ,@header ,@body)))))
 671               (if (= nheader 1)
 672                   `(,@header (tr (td (table (tbody ,@body)))))
 673                 `((tr (td (table (tbody ,@header))))
 674                   (tr (td (table (tbody ,@body))))))))
 675         (if footer
 676             ;; body + footer
 677             (if (= nbody nfooter)
 678                 `((tr (td (table (tbody ,@body ,@footer)))))
 679               (nconc `((tr (td (table (tbody ,@body)))))
 680                      (if (= nfooter 1)
 681                          footer
 682                        `((tr (td (table (tbody ,@footer))))))))
 683           (if caption
 684               `((tr (td (table (tbody ,@body)))))
 685             body)))))))
 686
 687 (defun shr-find-elements (cont type)
 688   (let (result)
 689     (dolist (elem cont)
 690       (cond ((eq (car elem) type)
 691              (push elem result))
 692             ((consp (cdr elem))
 693              (setq result (nconc (shr-find-elements (cdr elem) type) result)))))
 694     (nreverse result)))
 695
 696 (defun shr-insert-table (table widths)
 697   (shr-insert-table-ruler widths)
 698   (dolist (row table)
 699     (let ((start (point))
 700           (height (let ((max 0))
 701                     (dolist (column row)
 702                       (setq max (max max (cadr column))))
 703                     max)))
 704       (dotimes (i height)
 705         (shr-indent)
 706         (insert "|\n"))
 707       (dolist (column row)
 708         (goto-char start)
 709         (let ((lines (nth 2 column))
 710               (overlay-lines (nth 3 column))
 711               overlay overlay-line)
 712           (dolist (line lines)
 713             (setq overlay-line (pop overlay-lines))
 714             (end-of-line)
 715             (insert line "|")
 716             (dolist (overlay overlay-line)
 717               (let ((o (make-overlay (- (point) (nth 0 overlay) 1)
 718                                      (- (point) (nth 1 overlay) 1)))
 719                     (properties (nth 2 overlay)))
 720                 (while properties
 721                   (overlay-put o (pop properties) (pop properties)))))
 722             (forward-line 1))
 723           ;; Add blank lines at padding at the bottom of the TD,
 724           ;; possibly.
 725           (dotimes (i (- height (length lines)))
 726             (end-of-line)
 727             (insert (make-string (string-width (car lines)) ? ) "|")
 728             (forward-line 1)))))
 729     (shr-insert-table-ruler widths)))
 730
 731 (defun shr-insert-table-ruler (widths)
 732   (when (and (bolp)
 733              (> shr-indentation 0))
 734     (shr-indent))
 735   (insert shr-table-corner)
 736   (dotimes (i (length widths))
 737     (insert (make-string (aref widths i) shr-table-line) shr-table-corner))
 738   (insert "\n"))
 739
 740 (defun shr-table-widths (table suggested-widths)
 741   (let* ((length (length suggested-widths))
 742          (widths (make-vector length 0))
 743          (natural-widths (make-vector length 0)))
 744     (dolist (row table)
 745       (let ((i 0))
 746         (dolist (column row)
 747           (aset widths i (max (aref widths i)
 748                               (car column)))
 749           (aset natural-widths i (max (aref natural-widths i)
 750                                       (cadr column)))
 751           (setq i (1+ i)))))
 752     (let ((extra (- (apply '+ (append suggested-widths nil))
 753                     (apply '+ (append widths nil))))
 754           (expanded-columns 0))
 755       (when (> extra 0)
 756         (dotimes (i length)
 757           ;; If the natural width is wider than the rendered width, we
 758           ;; want to allow the column to expand.
 759           (when (> (aref natural-widths i) (aref widths i))
 760             (setq expanded-columns (1+ expanded-columns))))
 761         (dotimes (i length)
 762           (when (> (aref natural-widths i) (aref widths i))
 763             (aset widths i (min
 764                             (1+ (aref natural-widths i))
 765                             (+ (/ extra expanded-columns)
 766                                (aref widths i))))))))
 767     widths))
 768
 769 (defun shr-make-table (cont widths &optional fill)
 770   (let ((trs nil))
 771     (dolist (row cont)
 772       (when (eq (car row) 'tr)
 773         (let ((tds nil)
 774               (columns (cdr row))
 775               (i 0)
 776               column)
 777           (while (< i (length widths))
 778             (setq column (pop columns))
 779             (when (or (memq (car column) '(td th))
 780                       (null column))
 781               (push (shr-render-td (cdr column) (aref widths i) fill)
 782                     tds)
 783               (setq i (1+ i))))
 784           (push (nreverse tds) trs))))
 785     (nreverse trs)))
 786
 787 (defun shr-render-td (cont width fill)
 788   (with-temp-buffer
 789     (let ((cache (cdr (assoc (cons width cont) shr-content-cache))))
 790       (if cache
 791           (insert cache)
 792         (let ((shr-width width)
 793               (shr-indentation 0))
 794           (shr-generic cont))
 795         (delete-region
 796          (point)
 797          (+ (point)
 798             (skip-chars-backward " \t\n")))
 799         (push (cons (cons width cont) (buffer-string))
 800               shr-content-cache)))
 801     (goto-char (point-min))
 802     (let ((max 0))
 803       (while (not (eobp))
 804         (end-of-line)
 805         (setq max (max max (current-column)))
 806         (forward-line 1))
 807       (when fill
 808         (goto-char (point-min))
 809         ;; If the buffer is totally empty, then put a single blank
 810         ;; line here.
 811         (if (zerop (buffer-size))
 812             (insert (make-string width ? ))
 813           ;; Otherwise, fill the buffer.
 814           (while (not (eobp))
 815             (end-of-line)
 816             (when (> (- width (current-column)) 0)
 817               (insert (make-string (- width (current-column)) ? )))
 818             (forward-line 1))))
 819       (if fill
 820           (list max
 821                 (count-lines (point-min) (point-max))
 822                 (split-string (buffer-string) "\n")
 823                 (shr-collect-overlays))
 824         (list max
 825               (shr-natural-width))))))
 826
 827 (defun shr-natural-width ()
 828   (goto-char (point-min))
 829   (let ((current 0)
 830         (max 0))
 831     (while (not (eobp))
 832       (end-of-line)
 833       (setq current (+ current (current-column)))
 834       (unless (get-text-property (point) 'shr-break)
 835         (setq max (max max current)
 836               current 0))
 837       (forward-line 1))
 838     max))
 839
 840 (defun shr-collect-overlays ()
 841   (save-excursion
 842     (goto-char (point-min))
 843     (let ((overlays nil))
 844       (while (not (eobp))
 845         (push (shr-overlays-in-region (point) (line-end-position))
 846               overlays)
 847         (forward-line 1))
 848       (nreverse overlays))))
 849
 850 (defun shr-overlays-in-region (start end)
 851   (let (result)
 852     (dolist (overlay (overlays-in start end))
 853       (push (list (if (> start (overlay-start overlay))
 854                       (- end start)
 855                     (- end (overlay-start overlay)))
 856                   (if (< end (overlay-end overlay))
 857                       0
 858                     (- end (overlay-end overlay)))
 859                   (overlay-properties overlay))
 860             result))
 861     (nreverse result)))
 862
 863 (defun shr-pro-rate-columns (columns)
 864   (let ((total-percentage 0)
 865         (widths (make-vector (length columns) 0)))
 866     (dotimes (i (length columns))
 867       (setq total-percentage (+ total-percentage (aref columns i))))
 868     (setq total-percentage (/ 1.0 total-percentage))
 869     (dotimes (i (length columns))
 870       (aset widths i (max (truncate (* (aref columns i)
 871                                        total-percentage
 872                                        (- shr-width (1+ (length columns)))))
 873                           10)))
 874     widths))
 875
 876 ;; Return a summary of the number and shape of the TDs in the table.
 877 (defun shr-column-specs (cont)
 878   (let ((columns (make-vector (shr-max-columns cont) 1)))
 879     (dolist (row cont)
 880       (when (eq (car row) 'tr)
 881         (let ((i 0))
 882           (dolist (column (cdr row))
 883             (when (memq (car column) '(td th))
 884               (let ((width (cdr (assq :width (cdr column)))))
 885                 (when (and width
 886                            (string-match "\\([0-9]+\\)%" width))
 887                   (aset columns i
 888                         (/ (string-to-number (match-string 1 width))
 889                            100.0))))
 890               (setq i (1+ i)))))))
 891     columns))
 892
 893 (defun shr-count (cont elem)
 894   (let ((i 0))
 895     (dolist (sub cont)
 896       (when (eq (car sub) elem)
 897         (setq i (1+ i))))
 898     i))
 899
 900 (defun shr-max-columns (cont)
 901   (let ((max 0))
 902     (dolist (row cont)
 903       (when (eq (car row) 'tr)
 904         (setq max (max max (+ (shr-count (cdr row) 'td)
 905                               (shr-count (cdr row) 'th))))))
 906     max))
 907
 908 (provide 'shr)
 909
 910 ;;; shr.el ends here