cgit.sxemacs.org Git - gnus/blob - lisp/shr.el

   1 ;;; shr.el --- Simple HTML Renderer
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package takes a HTML parse tree (as provided by
  26 ;; libxml-parse-html-region) and renders it in the current buffer.  It
  27 ;; does not do CSS, JavaScript or anything advanced: It's geared
  28 ;; towards rendering typical short snippets of HTML, like what you'd
  29 ;; find in HTML email and the like.
  30
  31 ;;; Code:
  32
  33 (eval-when-compile (require 'cl))
  34 (require 'browse-url)
  35 (unless (aref (char-category-set (make-char 'japanese-jisx0208 33 35)) ?>)
  36   (load "kinsoku" nil t))
  37
  38 (defgroup shr nil
  39   "Simple HTML Renderer"
  40   :group 'mail)
  41
  42 (defcustom shr-max-image-proportion 0.9
  43   "How big pictures displayed are in relation to the window they're in.
  44 A value of 0.7 means that they are allowed to take up 70% of the
  45 width and height of the window.  If they are larger than this,
  46 and Emacs supports it, then the images will be rescaled down to
  47 fit these criteria."
  48   :version "24.1"
  49   :group 'shr
  50   :type 'float)
  51
  52 (defcustom shr-blocked-images nil
  53   "Images that have URLs matching this regexp will be blocked."
  54   :version "24.1"
  55   :group 'shr
  56   :type 'regexp)
  57
  58 (defcustom shr-table-line ?-
  59   "Character used to draw table line."
  60   :group 'shr
  61   :type 'character)
  62
  63 (defcustom shr-table-corner ?+
  64   "Character used to draw table corner."
  65   :group 'shr
  66   :type 'character)
  67
  68 (defcustom shr-hr-line ?-
  69   "Character used to draw hr line."
  70   :group 'shr
  71   :type 'character)
  72
  73 (defcustom shr-width fill-column
  74   "Frame width to use for rendering."
  75   :type 'integer
  76   :group 'shr)
  77
  78 (defvar shr-content-function nil
  79   "If bound, this should be a function that will return the content.
  80 This is used for cid: URLs, and the function is called with the
  81 cid: URL as the argument.")
  82
  83 ;;; Internal variables.
  84
  85 (defvar shr-folding-mode nil)
  86 (defvar shr-state nil)
  87 (defvar shr-start nil)
  88 (defvar shr-indentation 0)
  89 (defvar shr-inhibit-images nil)
  90 (defvar shr-list-mode nil)
  91 (defvar shr-content-cache nil)
  92 (defvar shr-kinsoku-shorten nil)
  93 (defvar shr-table-depth 0)
  94
  95 (defvar shr-map
  96   (let ((map (make-sparse-keymap)))
  97     (define-key map "a" 'shr-show-alt-text)
  98     (define-key map "i" 'shr-browse-image)
  99     (define-key map "I" 'shr-insert-image)
 100     (define-key map "u" 'shr-copy-url)
 101     (define-key map "v" 'shr-browse-url)
 102     (define-key map "o" 'shr-save-contents)
 103     (define-key map "\r" 'shr-browse-url)
 104     map))
 105
 106 ;; Public functions and commands.
 107
 108 ;;;###autoload
 109 (defun shr-insert-document (dom)
 110   (setq shr-content-cache nil)
 111   (let ((shr-state nil)
 112         (shr-start nil))
 113     (shr-descend (shr-transform-dom dom))))
 114
 115 (defun shr-copy-url ()
 116   "Copy the URL under point to the kill ring.
 117 If called twice, then try to fetch the URL and see whether it
 118 redirects somewhere else."
 119   (interactive)
 120   (let ((url (get-text-property (point) 'shr-url)))
 121     (cond
 122      ((not url)
 123       (message "No URL under point"))
 124      ;; Resolve redirected URLs.
 125      ((equal url (car kill-ring))
 126       (url-retrieve
 127        url
 128        (lambda (a)
 129          (when (and (consp a)
 130                     (eq (car a) :redirect))
 131            (with-temp-buffer
 132              (insert (cadr a))
 133              (goto-char (point-min))
 134              ;; Remove common tracking junk from the URL.
 135              (when (re-search-forward ".utm_.*" nil t)
 136                (replace-match "" t t))
 137              (message "Copied %s" (buffer-string))
 138              (copy-region-as-kill (point-min) (point-max)))))))
 139      ;; Copy the URL to the kill ring.
 140      (t
 141       (with-temp-buffer
 142         (insert url)
 143         (copy-region-as-kill (point-min) (point-max))
 144         (message "Copied %s" url))))))
 145
 146 (defun shr-show-alt-text ()
 147   "Show the ALT text of the image under point."
 148   (interactive)
 149   (let ((text (get-text-property (point) 'shr-alt)))
 150     (if (not text)
 151         (message "No image under point")
 152       (message "%s" text))))
 153
 154 (defun shr-browse-image ()
 155   "Browse the image under point."
 156   (interactive)
 157   (let ((url (get-text-property (point) 'shr-image)))
 158     (if (not url)
 159         (message "No image under point")
 160       (message "Browsing %s..." url)
 161       (browse-url url))))
 162
 163 (defun shr-insert-image ()
 164   "Insert the image under point into the buffer."
 165   (interactive)
 166   (let ((url (get-text-property (point) 'shr-image)))
 167     (if (not url)
 168         (message "No image under point")
 169       (message "Inserting %s..." url)
 170       (url-retrieve url 'shr-image-fetched
 171                     (list (current-buffer) (1- (point)) (point-marker))
 172                     t))))
 173
 174 ;;; Utility functions.
 175
 176 (defun shr-transform-dom (dom)
 177   (let ((result (list (pop dom))))
 178     (dolist (arg (pop dom))
 179       (push (cons (intern (concat ":" (symbol-name (car arg))) obarray)
 180                   (cdr arg))
 181             result))
 182     (dolist (sub dom)
 183       (if (stringp sub)
 184           (push (cons 'text sub) result)
 185         (push (shr-transform-dom sub) result)))
 186     (nreverse result)))
 187
 188 (defun shr-descend (dom)
 189   (let ((function (intern (concat "shr-tag-" (symbol-name (car dom))) obarray)))
 190     (if (fboundp function)
 191         (funcall function (cdr dom))
 192       (shr-generic (cdr dom)))))
 193
 194 (defun shr-generic (cont)
 195   (dolist (sub cont)
 196     (cond
 197      ((eq (car sub) 'text)
 198       (shr-insert (cdr sub)))
 199      ((listp (cdr sub))
 200       (shr-descend sub)))))
 201
 202 (defun shr-insert (text)
 203   (when (and (eq shr-state 'image)
 204              (not (string-match "\\`[ \t\n]+\\'" text)))
 205     (insert "\n")
 206     (setq shr-state nil))
 207   (cond
 208    ((eq shr-folding-mode 'none)
 209     (insert text))
 210    (t
 211     (when (and (string-match "\\`[ \t\n]" text)
 212                (not (bolp))
 213                (not (eq (char-after (1- (point))) ? )))
 214       (insert " "))
 215     (dolist (elem (split-string text))
 216       (when (and (bolp)
 217                  (> shr-indentation 0))
 218         (shr-indent))
 219       ;; The shr-start is a special variable that is used to pass
 220       ;; upwards the first point in the buffer where the text really
 221       ;; starts.
 222       (unless shr-start
 223         (setq shr-start (point)))
 224       ;; No space is needed behind a wide character categorized as
 225       ;; kinsoku-bol, between characters both categorized as nospace,
 226       ;; or at the beginning of a line.
 227       (let (prev)
 228         (when (and (eq (preceding-char) ? )
 229                    (or (= (line-beginning-position) (1- (point)))
 230                        (and (aref fill-find-break-point-function-table
 231                                   (setq prev (char-after (- (point) 2))))
 232                             (aref (char-category-set prev) ?>))
 233                        (and (aref fill-nospace-between-words-table prev)
 234                             (aref fill-nospace-between-words-table
 235                                   (aref elem 0)))))
 236           (delete-char -1)))
 237       (insert elem)
 238       (while (> (current-column) shr-width)
 239         (unless (prog1
 240                     (shr-find-fill-point)
 241                   (when (eq (preceding-char) ? )
 242                     (delete-char -1))
 243                   (insert "\n"))
 244           (put-text-property (1- (point)) (point) 'shr-break t)
 245           ;; No space is needed at the beginning of a line.
 246           (when (eq (following-char) ? )
 247             (delete-char 1)))
 248         (when (> shr-indentation 0)
 249           (shr-indent))
 250         (end-of-line))
 251       (insert " "))
 252     (unless (string-match "[ \t\n]\\'" text)
 253       (delete-char -1)))))
 254
 255 (defun shr-find-fill-point ()
 256   (when (> (move-to-column shr-width) shr-width)
 257     (backward-char 1))
 258   (let (failed)
 259     (while (not
 260             (or (setq failed (= (current-column) shr-indentation))
 261                 (eq (preceding-char) ? )
 262                 (eq (following-char) ? )
 263                 (aref fill-find-break-point-function-table (preceding-char))))
 264       (backward-char 1))
 265     (if failed
 266         ;; There's no breakable point, so we give it up.
 267         (progn
 268           (end-of-line)
 269           (while (aref fill-find-break-point-function-table (preceding-char))
 270             (backward-char 1))
 271           nil)
 272       (or (eolp)
 273           ;; Don't put kinsoku-bol characters at the beginning of a line,
 274           ;; or kinsoku-eol characters at the end of a line,
 275           (let ((count 4))
 276             (if (or shr-kinsoku-shorten
 277                     (and (aref (char-category-set (preceding-char)) ?<)
 278                          (progn
 279                            (setq count (1- count))
 280                            (backward-char 1)
 281                            t)))
 282                 (while (and
 283                         (>= (setq count (1- count)) 0)
 284                         (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 285                         (or (aref (char-category-set (preceding-char)) ?<)
 286                             (aref (char-category-set (following-char)) ?>)))
 287                   (backward-char 1))
 288               (while (and (>= (setq count (1- count)) 0)
 289                           (aref (char-category-set (following-char)) ?>)
 290                           (aref fill-find-break-point-function-table
 291                                 (following-char)))
 292                 (forward-char 1)))
 293             (when (eq (following-char) ? )
 294               (forward-char 1))
 295             t)))))
 296
 297 (defun shr-ensure-newline ()
 298   (unless (zerop (current-column))
 299     (insert "\n")))
 300
 301 (defun shr-ensure-paragraph ()
 302   (unless (bobp)
 303     (if (<= (current-column) shr-indentation)
 304         (unless (save-excursion
 305                   (forward-line -1)
 306                   (looking-at " *$"))
 307           (insert "\n"))
 308       (if (save-excursion
 309             (beginning-of-line)
 310             (looking-at " *$"))
 311           (insert "\n")
 312         (insert "\n\n")))))
 313
 314 (defun shr-indent ()
 315   (when (> shr-indentation 0)
 316     (insert (make-string shr-indentation ? ))))
 317
 318 (defun shr-fontize-cont (cont &rest types)
 319   (let (shr-start)
 320     (shr-generic cont)
 321     (dolist (type types)
 322       (shr-add-font (or shr-start (point)) (point) type))))
 323
 324 ;; Add an overlay in the region, but avoid putting the font properties
 325 ;; on blank text at the start of the line, and the newline at the end,
 326 ;; to avoid ugliness.
 327 (defun shr-add-font (start end type)
 328   (save-excursion
 329     (goto-char start)
 330     (while (< (point) end)
 331       (when (bolp)
 332         (skip-chars-forward " "))
 333       (let ((overlay (make-overlay (point) (min (line-end-position) end))))
 334         (overlay-put overlay 'face type))
 335       (if (< (line-end-position) end)
 336           (forward-line 1)
 337         (goto-char end)))))
 338
 339 (defun shr-browse-url ()
 340   "Browse the URL under point."
 341   (interactive)
 342   (let ((url (get-text-property (point) 'shr-url)))
 343     (cond
 344      ((not url)
 345       (message "No link under point"))
 346      ((string-match "^mailto:" url)
 347       (browse-url-mailto url))
 348      (t
 349       (browse-url url)))))
 350
 351 (defun shr-save-contents (directory)
 352   "Save the contents from URL in a file."
 353   (interactive "DSave contents of URL to directory: ")
 354   (let ((url (get-text-property (point) 'shr-url)))
 355     (if (not url)
 356         (message "No link under point")
 357       (url-retrieve (shr-encode-url url)
 358                     'shr-store-contents (list url directory)))))
 359
 360 (defun shr-store-contents (status url directory)
 361   (unless (plist-get status :error)
 362     (when (or (search-forward "\n\n" nil t)
 363               (search-forward "\r\n\r\n" nil t))
 364       (write-region (point) (point-max)
 365                     (expand-file-name (file-name-nondirectory url)
 366                                       directory)))))
 367
 368 (defun shr-image-fetched (status buffer start end)
 369   (when (and (buffer-name buffer)
 370              (not (plist-get status :error)))
 371     (url-store-in-cache (current-buffer))
 372     (when (or (search-forward "\n\n" nil t)
 373               (search-forward "\r\n\r\n" nil t))
 374       (let ((data (buffer-substring (point) (point-max))))
 375         (with-current-buffer buffer
 376           (let ((alt (buffer-substring start end))
 377                 (inhibit-read-only t))
 378             (delete-region start end)
 379             (goto-char start)
 380             (shr-put-image data alt))))))
 381   (kill-buffer (current-buffer)))
 382
 383 (defun shr-put-image (data alt)
 384   (if (display-graphic-p)
 385       (let ((image (ignore-errors
 386                      (shr-rescale-image data))))
 387         (when image
 388           (insert-image image (or alt "*"))))
 389     (insert alt)))
 390
 391 (defun shr-rescale-image (data)
 392   (if (or (not (fboundp 'imagemagick-types))
 393           (not (get-buffer-window (current-buffer))))
 394       (create-image data nil t)
 395     (let* ((image (create-image data nil t))
 396            (size (image-size image t))
 397            (width (car size))
 398            (height (cdr size))
 399            (edges (window-inside-pixel-edges
 400                    (get-buffer-window (current-buffer))))
 401            (window-width (truncate (* shr-max-image-proportion
 402                                       (- (nth 2 edges) (nth 0 edges)))))
 403            (window-height (truncate (* shr-max-image-proportion
 404                                        (- (nth 3 edges) (nth 1 edges)))))
 405            scaled-image)
 406       (when (> height window-height)
 407         (setq image (or (create-image data 'imagemagick t
 408                                       :height window-height)
 409                         image))
 410         (setq size (image-size image t)))
 411       (when (> (car size) window-width)
 412         (setq image (or
 413                      (create-image data 'imagemagick t
 414                                    :width window-width)
 415                      image)))
 416       image)))
 417
 418 ;; url-cache-extract autoloads url-cache.
 419 (declare-function url-cache-create-filename "url-cache" (url))
 420 (autoload 'mm-disable-multibyte "mm-util")
 421 (autoload 'browse-url-mailto "browse-url")
 422
 423 (defun shr-get-image-data (url)
 424   "Get image data for URL.
 425 Return a string with image data."
 426   (with-temp-buffer
 427     (mm-disable-multibyte)
 428     (when (ignore-errors
 429             (url-cache-extract (url-cache-create-filename (shr-encode-url url)))
 430             t)
 431       (when (or (search-forward "\n\n" nil t)
 432                 (search-forward "\r\n\r\n" nil t))
 433         (buffer-substring (point) (point-max))))))
 434
 435 (defun shr-heading (cont &rest types)
 436   (shr-ensure-paragraph)
 437   (apply #'shr-fontize-cont cont types)
 438   (shr-ensure-paragraph))
 439
 440 (autoload 'widget-convert-button "wid-edit")
 441
 442 (defun shr-urlify (start url)
 443   (widget-convert-button
 444    'url-link start (point)
 445    :help-echo url
 446    :keymap shr-map
 447    url)
 448   (put-text-property start (point) 'shr-url url))
 449
 450 (defun shr-encode-url (url)
 451   "Encode URL."
 452   (browse-url-url-encode-chars url "[)$ ]"))
 453
 454 ;;; Tag-specific rendering rules.
 455
 456 (defun shr-tag-p (cont)
 457   (shr-ensure-paragraph)
 458   (shr-indent)
 459   (shr-generic cont)
 460   (shr-ensure-paragraph))
 461
 462 (defun shr-tag-div (cont)
 463   (shr-ensure-newline)
 464   (shr-indent)
 465   (shr-generic cont)
 466   (shr-ensure-newline))
 467
 468 (defun shr-tag-b (cont)
 469   (shr-fontize-cont cont 'bold))
 470
 471 (defun shr-tag-i (cont)
 472   (shr-fontize-cont cont 'italic))
 473
 474 (defun shr-tag-em (cont)
 475   (shr-fontize-cont cont 'bold))
 476
 477 (defun shr-tag-strong (cont)
 478   (shr-fontize-cont cont 'bold))
 479
 480 (defun shr-tag-u (cont)
 481   (shr-fontize-cont cont 'underline))
 482
 483 (defun shr-tag-s (cont)
 484   (shr-fontize-cont cont 'strike-through))
 485
 486 (defun shr-parse-style (style)
 487   (when style
 488     (let ((plist nil))
 489       (dolist (elem (split-string style ";"))
 490         (when elem
 491           (setq elem (split-string elem ":"))
 492           (when (and (car elem)
 493                      (cadr elem))
 494             (let ((name (replace-regexp-in-string "^ +\\| +$" "" (car elem)))
 495                   (value (replace-regexp-in-string "^ +\\| +$" "" (cadr elem))))
 496               (push (cons (intern name obarray)
 497                           value)
 498                     plist)))))
 499       plist)))
 500
 501 (defun shr-tag-a (cont)
 502   (let ((url (cdr (assq :href cont)))
 503         (start (point))
 504         shr-start)
 505     (shr-generic cont)
 506     (shr-urlify (or shr-start start) url)))
 507
 508 (defun shr-tag-object (cont)
 509   (let ((start (point))
 510         url)
 511     (dolist (elem cont)
 512       (when (eq (car elem) 'embed)
 513         (setq url (or url (cdr (assq :src (cdr elem))))))
 514       (when (and (eq (car elem) 'param)
 515                  (equal (cdr (assq :name (cdr elem))) "movie"))
 516         (setq url (or url (cdr (assq :value (cdr elem)))))))
 517     (when url
 518       (shr-insert " [multimedia] ")
 519       (shr-urlify start url))
 520     (shr-generic cont)))
 521
 522 (defun shr-tag-video (cont)
 523   (let ((image (cdr (assq :poster cont)))
 524         (url (cdr (assq :src cont)))
 525         (start (point)))
 526     (shr-tag-img nil image)
 527     (shr-urlify start url)))
 528
 529 (defun shr-tag-img (cont &optional url)
 530   (when (or url
 531             (and cont
 532                  (cdr (assq :src cont))))
 533     (when (and (> (current-column) 0)
 534                (not (eq shr-state 'image)))
 535       (insert "\n"))
 536     (let ((alt (cdr (assq :alt cont)))
 537           (url (or url (cdr (assq :src cont)))))
 538       (let ((start (point-marker)))
 539         (when (zerop (length alt))
 540           (setq alt "*"))
 541         (cond
 542          ((or (member (cdr (assq :height cont)) '("0" "1"))
 543               (member (cdr (assq :width cont)) '("0" "1")))
 544           ;; Ignore zero-sized or single-pixel images.
 545           )
 546          ((and (not shr-inhibit-images)
 547                (string-match "\\`cid:" url))
 548           (let ((url (substring url (match-end 0)))
 549                 image)
 550             (if (or (not shr-content-function)
 551                     (not (setq image (funcall shr-content-function url))))
 552                 (insert alt)
 553               (shr-put-image image alt))))
 554          ((or shr-inhibit-images
 555               (and shr-blocked-images
 556                    (string-match shr-blocked-images url)))
 557           (setq shr-start (point))
 558           (let ((shr-state 'space))
 559             (if (> (string-width alt) 8)
 560                 (shr-insert (truncate-string-to-width alt 8))
 561               (shr-insert alt))))
 562          ((url-is-cached (shr-encode-url url))
 563           (shr-put-image (shr-get-image-data url) alt))
 564          (t
 565           (insert alt)
 566           (ignore-errors
 567             (url-retrieve (shr-encode-url url) 'shr-image-fetched
 568                           (list (current-buffer) start (point-marker))
 569                           t))))
 570         (put-text-property start (point) 'keymap shr-map)
 571         (put-text-property start (point) 'shr-alt alt)
 572         (put-text-property start (point) 'shr-image url)
 573         (put-text-property start (point) 'help-echo alt)
 574         (setq shr-state 'image)))))
 575
 576 (defun shr-tag-pre (cont)
 577   (let ((shr-folding-mode 'none))
 578     (shr-ensure-newline)
 579     (shr-indent)
 580     (shr-generic cont)
 581     (shr-ensure-newline)))
 582
 583 (defun shr-tag-blockquote (cont)
 584   (shr-ensure-paragraph)
 585   (shr-indent)
 586   (let ((shr-indentation (+ shr-indentation 4)))
 587     (shr-generic cont))
 588   (shr-ensure-paragraph))
 589
 590 (defun shr-tag-ul (cont)
 591   (shr-ensure-paragraph)
 592   (let ((shr-list-mode 'ul))
 593     (shr-generic cont))
 594   (shr-ensure-paragraph))
 595
 596 (defun shr-tag-ol (cont)
 597   (shr-ensure-paragraph)
 598   (let ((shr-list-mode 1))
 599     (shr-generic cont))
 600   (shr-ensure-paragraph))
 601
 602 (defun shr-tag-li (cont)
 603   (shr-ensure-paragraph)
 604   (shr-indent)
 605   (let* ((bullet
 606           (if (numberp shr-list-mode)
 607               (prog1
 608                   (format "%d " shr-list-mode)
 609                 (setq shr-list-mode (1+ shr-list-mode)))
 610             "* "))
 611          (shr-indentation (+ shr-indentation (length bullet))))
 612     (insert bullet)
 613     (shr-generic cont)))
 614
 615 (defun shr-tag-br (cont)
 616   (unless (bobp)
 617     (insert "\n")
 618     (shr-indent))
 619   (shr-generic cont))
 620
 621 (defun shr-tag-h1 (cont)
 622   (shr-heading cont 'bold 'underline))
 623
 624 (defun shr-tag-h2 (cont)
 625   (shr-heading cont 'bold))
 626
 627 (defun shr-tag-h3 (cont)
 628   (shr-heading cont 'italic))
 629
 630 (defun shr-tag-h4 (cont)
 631   (shr-heading cont))
 632
 633 (defun shr-tag-h5 (cont)
 634   (shr-heading cont))
 635
 636 (defun shr-tag-h6 (cont)
 637   (shr-heading cont))
 638
 639 (defun shr-tag-hr (cont)
 640   (shr-ensure-newline)
 641   (insert (make-string shr-width shr-hr-line) "\n"))
 642
 643 ;;; Table rendering algorithm.
 644
 645 ;; Table rendering is the only complicated thing here.  We do this by
 646 ;; first counting how many TDs there are in each TR, and registering
 647 ;; how wide they think they should be ("width=45%", etc).  Then we
 648 ;; render each TD separately (this is done in temporary buffers, so
 649 ;; that we can use all the rendering machinery as if we were in the
 650 ;; main buffer).  Now we know how much space each TD really takes, so
 651 ;; we then render everything again with the new widths, and finally
 652 ;; insert all these boxes into the main buffer.
 653 (defun shr-tag-table-1 (cont)
 654   (setq cont (or (cdr (assq 'tbody cont))
 655                  cont))
 656   (let* ((shr-inhibit-images t)
 657          (shr-table-depth (1+ shr-table-depth))
 658          (shr-kinsoku-shorten t)
 659          ;; Find all suggested widths.
 660          (columns (shr-column-specs cont))
 661          ;; Compute how many characters wide each TD should be.
 662          (suggested-widths (shr-pro-rate-columns columns))
 663          ;; Do a "test rendering" to see how big each TD is (this can
 664          ;; be smaller (if there's little text) or bigger (if there's
 665          ;; unbreakable text).
 666          (sketch (shr-make-table cont suggested-widths))
 667          (sketch-widths (shr-table-widths sketch suggested-widths)))
 668     ;; This probably won't work very well.
 669     (when (> (+ (loop for width across sketch-widths
 670                       summing (1+ width))
 671                 shr-indentation 1)
 672              (frame-width))
 673       (setq truncate-lines t))
 674     ;; Then render the table again with these new "hard" widths.
 675     (shr-insert-table (shr-make-table cont sketch-widths t) sketch-widths))
 676   ;; Finally, insert all the images after the table.  The Emacs buffer
 677   ;; model isn't strong enough to allow us to put the images actually
 678   ;; into the tables.
 679   (when (zerop shr-table-depth)
 680     (dolist (elem (shr-find-elements cont 'img))
 681       (shr-tag-img (cdr elem)))))
 682
 683 (defun shr-tag-table (cont)
 684   (shr-ensure-paragraph)
 685   (let* ((caption (cdr (assq 'caption cont)))
 686          (header (cdr (assq 'thead cont)))
 687          (body (or (cdr (assq 'tbody cont)) cont))
 688          (footer (cdr (assq 'tfoot cont)))
 689          (nheader (if header (shr-max-columns header)))
 690          (nbody (if body (shr-max-columns body)))
 691          (nfooter (if footer (shr-max-columns footer))))
 692     (shr-tag-table-1
 693      (nconc
 694       (if caption `((tr (td ,@caption))))
 695       (if header
 696           (if footer
 697               ;; hader + body + footer
 698               (if (= nheader nbody)
 699                   (if (= nbody nfooter)
 700                       `((tr (td (table (tbody ,@header ,@body ,@footer)))))
 701                     (nconc `((tr (td (table (tbody ,@header ,@body)))))
 702                            (if (= nfooter 1)
 703                                footer
 704                              `((tr (td (table (tbody ,@footer))))))))
 705                 (nconc `((tr (td (table (tbody ,@header)))))
 706                        (if (= nbody nfooter)
 707                            `((tr (td (table (tbody ,@body ,@footer)))))
 708                          (nconc `((tr (td (table (tbody ,@body)))))
 709                                 (if (= nfooter 1)
 710                                     footer
 711                                   `((tr (td (table (tbody ,@footer))))))))))
 712             ;; header + body
 713             (if (= nheader nbody)
 714                 `((tr (td (table (tbody ,@header ,@body)))))
 715               (if (= nheader 1)
 716                   `(,@header (tr (td (table (tbody ,@body)))))
 717                 `((tr (td (table (tbody ,@header))))
 718                   (tr (td (table (tbody ,@body))))))))
 719         (if footer
 720             ;; body + footer
 721             (if (= nbody nfooter)
 722                 `((tr (td (table (tbody ,@body ,@footer)))))
 723               (nconc `((tr (td (table (tbody ,@body)))))
 724                      (if (= nfooter 1)
 725                          footer
 726                        `((tr (td (table (tbody ,@footer))))))))
 727           (if caption
 728               `((tr (td (table (tbody ,@body)))))
 729             body)))))))
 730
 731 (defun shr-find-elements (cont type)
 732   (let (result)
 733     (dolist (elem cont)
 734       (cond ((eq (car elem) type)
 735              (push elem result))
 736             ((consp (cdr elem))
 737              (setq result (nconc (shr-find-elements (cdr elem) type) result)))))
 738     (nreverse result)))
 739
 740 (defun shr-insert-table (table widths)
 741   (shr-insert-table-ruler widths)
 742   (dolist (row table)
 743     (let ((start (point))
 744           (height (let ((max 0))
 745                     (dolist (column row)
 746                       (setq max (max max (cadr column))))
 747                     max)))
 748       (dotimes (i height)
 749         (shr-indent)
 750         (insert "|\n"))
 751       (dolist (column row)
 752         (goto-char start)
 753         (let ((lines (nth 2 column))
 754               (overlay-lines (nth 3 column))
 755               overlay overlay-line)
 756           (dolist (line lines)
 757             (setq overlay-line (pop overlay-lines))
 758             (end-of-line)
 759             (insert line "|")
 760             (dolist (overlay overlay-line)
 761               (let ((o (make-overlay (- (point) (nth 0 overlay) 1)
 762                                      (- (point) (nth 1 overlay) 1)))
 763                     (properties (nth 2 overlay)))
 764                 (while properties
 765                   (overlay-put o (pop properties) (pop properties)))))
 766             (forward-line 1))
 767           ;; Add blank lines at padding at the bottom of the TD,
 768           ;; possibly.
 769           (dotimes (i (- height (length lines)))
 770             (end-of-line)
 771             (insert (make-string (string-width (car lines)) ? ) "|")
 772             (forward-line 1)))))
 773     (shr-insert-table-ruler widths)))
 774
 775 (defun shr-insert-table-ruler (widths)
 776   (when (and (bolp)
 777              (> shr-indentation 0))
 778     (shr-indent))
 779   (insert shr-table-corner)
 780   (dotimes (i (length widths))
 781     (insert (make-string (aref widths i) shr-table-line) shr-table-corner))
 782   (insert "\n"))
 783
 784 (defun shr-table-widths (table suggested-widths)
 785   (let* ((length (length suggested-widths))
 786          (widths (make-vector length 0))
 787          (natural-widths (make-vector length 0)))
 788     (dolist (row table)
 789       (let ((i 0))
 790         (dolist (column row)
 791           (aset widths i (max (aref widths i)
 792                               (car column)))
 793           (aset natural-widths i (max (aref natural-widths i)
 794                                       (cadr column)))
 795           (setq i (1+ i)))))
 796     (let ((extra (- (apply '+ (append suggested-widths nil))
 797                     (apply '+ (append widths nil))))
 798           (expanded-columns 0))
 799       (when (> extra 0)
 800         (dotimes (i length)
 801           ;; If the natural width is wider than the rendered width, we
 802           ;; want to allow the column to expand.
 803           (when (> (aref natural-widths i) (aref widths i))
 804             (setq expanded-columns (1+ expanded-columns))))
 805         (dotimes (i length)
 806           (when (> (aref natural-widths i) (aref widths i))
 807             (aset widths i (min
 808                             (1+ (aref natural-widths i))
 809                             (+ (/ extra expanded-columns)
 810                                (aref widths i))))))))
 811     widths))
 812
 813 (defun shr-make-table (cont widths &optional fill)
 814   (let ((trs nil))
 815     (dolist (row cont)
 816       (when (eq (car row) 'tr)
 817         (let ((tds nil)
 818               (columns (cdr row))
 819               (i 0)
 820               column)
 821           (while (< i (length widths))
 822             (setq column (pop columns))
 823             (when (or (memq (car column) '(td th))
 824                       (null column))
 825               (push (shr-render-td (cdr column) (aref widths i) fill)
 826                     tds)
 827               (setq i (1+ i))))
 828           (push (nreverse tds) trs))))
 829     (nreverse trs)))
 830
 831 (defun shr-render-td (cont width fill)
 832   (with-temp-buffer
 833     (let ((cache (cdr (assoc (cons width cont) shr-content-cache))))
 834       (if cache
 835           (insert cache)
 836         (let ((shr-width width)
 837               (shr-indentation 0))
 838           (shr-generic cont))
 839         (delete-region
 840          (point)
 841          (+ (point)
 842             (skip-chars-backward " \t\n")))
 843         (push (cons (cons width cont) (buffer-string))
 844               shr-content-cache)))
 845     (goto-char (point-min))
 846     (let ((max 0))
 847       (while (not (eobp))
 848         (end-of-line)
 849         (setq max (max max (current-column)))
 850         (forward-line 1))
 851       (when fill
 852         (goto-char (point-min))
 853         ;; If the buffer is totally empty, then put a single blank
 854         ;; line here.
 855         (if (zerop (buffer-size))
 856             (insert (make-string width ? ))
 857           ;; Otherwise, fill the buffer.
 858           (while (not (eobp))
 859             (end-of-line)
 860             (when (> (- width (current-column)) 0)
 861               (insert (make-string (- width (current-column)) ? )))
 862             (forward-line 1))))
 863       (if fill
 864           (list max
 865                 (count-lines (point-min) (point-max))
 866                 (split-string (buffer-string) "\n")
 867                 (shr-collect-overlays))
 868         (list max
 869               (shr-natural-width))))))
 870
 871 (defun shr-natural-width ()
 872   (goto-char (point-min))
 873   (let ((current 0)
 874         (max 0))
 875     (while (not (eobp))
 876       (end-of-line)
 877       (setq current (+ current (current-column)))
 878       (unless (get-text-property (point) 'shr-break)
 879         (setq max (max max current)
 880               current 0))
 881       (forward-line 1))
 882     max))
 883
 884 (defun shr-collect-overlays ()
 885   (save-excursion
 886     (goto-char (point-min))
 887     (let ((overlays nil))
 888       (while (not (eobp))
 889         (push (shr-overlays-in-region (point) (line-end-position))
 890               overlays)
 891         (forward-line 1))
 892       (nreverse overlays))))
 893
 894 (defun shr-overlays-in-region (start end)
 895   (let (result)
 896     (dolist (overlay (overlays-in start end))
 897       (push (list (if (> start (overlay-start overlay))
 898                       (- end start)
 899                     (- end (overlay-start overlay)))
 900                   (if (< end (overlay-end overlay))
 901                       0
 902                     (- end (overlay-end overlay)))
 903                   (overlay-properties overlay))
 904             result))
 905     (nreverse result)))
 906
 907 (defun shr-pro-rate-columns (columns)
 908   (let ((total-percentage 0)
 909         (widths (make-vector (length columns) 0)))
 910     (dotimes (i (length columns))
 911       (setq total-percentage (+ total-percentage (aref columns i))))
 912     (setq total-percentage (/ 1.0 total-percentage))
 913     (dotimes (i (length columns))
 914       (aset widths i (max (truncate (* (aref columns i)
 915                                        total-percentage
 916                                        (- shr-width (1+ (length columns)))))
 917                           10)))
 918     widths))
 919
 920 ;; Return a summary of the number and shape of the TDs in the table.
 921 (defun shr-column-specs (cont)
 922   (let ((columns (make-vector (shr-max-columns cont) 1)))
 923     (dolist (row cont)
 924       (when (eq (car row) 'tr)
 925         (let ((i 0))
 926           (dolist (column (cdr row))
 927             (when (memq (car column) '(td th))
 928               (let ((width (cdr (assq :width (cdr column)))))
 929                 (when (and width
 930                            (string-match "\\([0-9]+\\)%" width))
 931                   (aset columns i
 932                         (/ (string-to-number (match-string 1 width))
 933                            100.0))))
 934               (setq i (1+ i)))))))
 935     columns))
 936
 937 (defun shr-count (cont elem)
 938   (let ((i 0))
 939     (dolist (sub cont)
 940       (when (eq (car sub) elem)
 941         (setq i (1+ i))))
 942     i))
 943
 944 (defun shr-max-columns (cont)
 945   (let ((max 0))
 946     (dolist (row cont)
 947       (when (eq (car row) 'tr)
 948         (setq max (max max (+ (shr-count (cdr row) 'td)
 949                               (shr-count (cdr row) 'th))))))
 950     max))
 951
 952 (provide 'shr)
 953
 954 ;;; shr.el ends here