cgit.sxemacs.org Git - gnus/blob - lisp/sha1-el.el

   1 ;;; sha1-el.el --- SHA1 Secure Hash Algorithm in Emacs-Lisp.
   2
   3 ;; Copyright (C) 1999, 2001, 2003  Free Software Foundation, Inc.
   4
   5 ;; Author: Shuhei KOBAYASHI <shuhei@aqua.ocn.ne.jp>
   6 ;; Keywords: SHA1, FIPS 180-1
   7
   8 ;; This file is part of FLIM (Faithful Library about Internet Message).
   9
  10 ;; This program is free software; you can redistribute it and/or
  11 ;; modify it under the terms of the GNU General Public License as
  12 ;; published by the Free Software Foundation; either version 2, or
  13 ;; (at your option) any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with this program; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This program is implemented from the definition of SHA-1 in FIPS PUB
  28 ;; 180-1 (Federal Information Processing Standards Publication 180-1),
  29 ;; "Announcing the Standard for SECURE HASH STANDARD".
  30 ;; <URL:http://www.itl.nist.gov/div897/pubs/fip180-1.htm>
  31 ;; (EXCEPTION; two optimizations taken from GnuPG/cipher/sha1.c)
  32 ;;
  33 ;; Test cases from FIPS PUB 180-1.
  34 ;;
  35 ;; (sha1 "abc")
  36 ;; => a9993e364706816aba3e25717850c26c9cd0d89d
  37 ;;
  38 ;; (sha1 "abcdbcdecdefdefgefghfghighijhijkijkljklmklmnlmnomnopnopq")
  39 ;; => 84983e441c3bd26ebaae4aa1f95129e5e54670f1
  40 ;;
  41 ;; (sha1 (make-string 1000000 ?a))
  42 ;; => 34aa973cd4c4daa4f61eeb2bdbad27316534016f
  43 ;;
  44 ;; BUGS:
  45 ;;  * It is assumed that length of input string is less than 2^29 bytes.
  46 ;;  * It is caller's responsibility to make string (or region) unibyte.
  47 ;;
  48 ;; TODO:
  49 ;;  * Rewrite from scratch!
  50 ;;    This version is much faster than Keiichi Suzuki's another sha1.el,
  51 ;;    but it is too dirty.
  52
  53 ;;; Code:
  54
  55 (require 'hex-util)
  56
  57 (ignore-errors (autoload 'executable-find "executable"))
  58
  59 ;;;
  60 ;;; external SHA1 function.
  61 ;;;
  62
  63 (defgroup sha1 nil
  64   "Elisp interface for SHA1 hash computation."
  65   :group 'extensions)
  66
  67 (defcustom sha1-maximum-internal-length 500
  68   "*Maximum length of message to use lisp version of SHA1 function.
  69 If message is longer than this, `sha1-program' is used instead.
  70
  71 If this variable is set to 0, use extarnal program only.
  72 If this variable is set to nil, use internal function only."
  73   :type 'integer
  74   :group 'sha1)
  75
  76 (defcustom sha1-program '("sha1sum")
  77   "*Name of program to compute SHA1.
  78 It must be a string \(program name\) or list of strings \(name and its args\)."
  79   :type '(repeat string)
  80   :group 'sha1)
  81
  82 (defcustom sha1-use-external (ignore-errors (executable-find (car sha1-program)))
  83   "*Use external SHA1 program.
  84 If this variable is set to nil, use internal function only."
  85   :type 'boolean
  86   :group 'sha1)
  87
  88 (defun sha1-string-external (string)
  89   ;; `with-temp-buffer' is new in v20, so we do not use it.
  90   (save-excursion
  91     (let (buffer)
  92       (unwind-protect
  93           (let (prog args)
  94             (if (consp sha1-program)
  95                 (setq prog (car sha1-program)
  96                       args (cdr sha1-program))
  97               (setq prog sha1-program
  98                     args nil))
  99             (setq buffer (set-buffer
 100                           (generate-new-buffer " *sha1 external*")))
 101             (insert string)
 102             (apply (function call-process-region)
 103                    (point-min)(point-max)
 104                    prog t t nil args)
 105             ;; SHA1 is 40 bytes long in hexadecimal form.
 106             (buffer-substring (point-min)(+ (point-min) 40)))
 107         (and buffer
 108              (buffer-name buffer)
 109              (kill-buffer buffer))))))
 110
 111 (defun sha1-region-external (beg end)
 112   (sha1-string-external (buffer-substring-no-properties beg end)))
 113
 114 ;;;
 115 ;;; internal SHA1 function.
 116 ;;;
 117
 118 (eval-when-compile
 119   ;; optional second arg of string-to-number is new in v20.
 120   (defconst sha1-K0-high 23170)         ; (string-to-number "5A82" 16)
 121   (defconst sha1-K0-low  31129)         ; (string-to-number "7999" 16)
 122   (defconst sha1-K1-high 28377)         ; (string-to-number "6ED9" 16)
 123   (defconst sha1-K1-low  60321)         ; (string-to-number "EBA1" 16)
 124   (defconst sha1-K2-high 36635)         ; (string-to-number "8F1B" 16)
 125   (defconst sha1-K2-low  48348)         ; (string-to-number "BCDC" 16)
 126   (defconst sha1-K3-high 51810)         ; (string-to-number "CA62" 16)
 127   (defconst sha1-K3-low  49622)         ; (string-to-number "C1D6" 16)
 128
 129 ;;; original definition of sha1-F0.
 130 ;;; (defmacro sha1-F0 (B C D)
 131 ;;;   (` (logior (logand (, B) (, C))
 132 ;;;          (logand (lognot (, B)) (, D)))))
 133 ;;; a little optimization from GnuPG/cipher/sha1.c.
 134   (defmacro sha1-F0 (B C D)
 135     (` (logxor (, D) (logand (, B) (logxor (, C) (, D))))))
 136   (defmacro sha1-F1 (B C D)
 137     (` (logxor (, B) (, C) (, D))))
 138 ;;; original definition of sha1-F2.
 139 ;;; (defmacro sha1-F2 (B C D)
 140 ;;;   (` (logior (logand (, B) (, C))
 141 ;;;          (logand (, B) (, D))
 142 ;;;          (logand (, C) (, D)))))
 143 ;;; a little optimization from GnuPG/cipher/sha1.c.
 144   (defmacro sha1-F2 (B C D)
 145     (` (logior (logand (, B) (, C))
 146                (logand (, D) (logior (, B) (, C))))))
 147   (defmacro sha1-F3 (B C D)
 148     (` (logxor (, B) (, C) (, D))))
 149
 150   (defmacro sha1-S1  (W-high W-low)
 151     (` (let ((W-high (, W-high))
 152              (W-low  (, W-low)))
 153          (setq S1W-high (+ (% (* W-high 2) 65536)
 154                            (/ W-low (, (/ 65536 2)))))
 155          (setq S1W-low (+ (/ W-high (, (/ 65536 2)))
 156                           (% (* W-low 2) 65536))))))
 157   (defmacro sha1-S5  (A-high A-low)
 158     (` (progn
 159          (setq S5A-high (+ (% (* (, A-high) 32) 65536)
 160                            (/ (, A-low) (, (/ 65536 32)))))
 161          (setq S5A-low  (+ (/ (, A-high) (, (/ 65536 32)))
 162                            (% (* (, A-low) 32) 65536))))))
 163   (defmacro sha1-S30 (B-high B-low)
 164     (` (progn
 165          (setq S30B-high (+ (/ (, B-high) 4)
 166                             (* (% (, B-low) 4) (, (/ 65536 4)))))
 167          (setq S30B-low  (+ (/ (, B-low) 4)
 168                             (* (% (, B-high) 4) (, (/ 65536 4))))))))
 169
 170   (defmacro sha1-OP (round)
 171     (` (progn
 172          (sha1-S5 sha1-A-high sha1-A-low)
 173          (sha1-S30 sha1-B-high sha1-B-low)
 174          (setq sha1-A-low (+ ((, (intern (format "sha1-F%d" round)))
 175                               sha1-B-low sha1-C-low sha1-D-low)
 176                              sha1-E-low
 177                              (, (symbol-value
 178                                  (intern (format "sha1-K%d-low" round))))
 179                              (aref block-low idx)
 180                              (progn
 181                                (setq sha1-E-low sha1-D-low)
 182                                (setq sha1-D-low sha1-C-low)
 183                                (setq sha1-C-low S30B-low)
 184                                (setq sha1-B-low sha1-A-low)
 185                                S5A-low)))
 186          (setq carry (/ sha1-A-low 65536))
 187          (setq sha1-A-low (% sha1-A-low 65536))
 188          (setq sha1-A-high (% (+ ((, (intern (format "sha1-F%d" round)))
 189                                   sha1-B-high sha1-C-high sha1-D-high)
 190                                  sha1-E-high
 191                                  (, (symbol-value
 192                                      (intern (format "sha1-K%d-high" round))))
 193                                  (aref block-high idx)
 194                                  (progn
 195                                    (setq sha1-E-high sha1-D-high)
 196                                    (setq sha1-D-high sha1-C-high)
 197                                    (setq sha1-C-high S30B-high)
 198                                    (setq sha1-B-high sha1-A-high)
 199                                    S5A-high)
 200                                  carry)
 201                               65536)))))
 202
 203   (defmacro sha1-add-to-H (H X)
 204     (` (progn
 205          (setq (, (intern (format "sha1-%s-low" H)))
 206                (+ (, (intern (format "sha1-%s-low" H)))
 207                   (, (intern (format "sha1-%s-low" X)))))
 208          (setq carry (/ (, (intern (format "sha1-%s-low" H))) 65536))
 209          (setq (, (intern (format "sha1-%s-low" H)))
 210                (% (, (intern (format "sha1-%s-low" H))) 65536))
 211          (setq (, (intern (format "sha1-%s-high" H)))
 212                (% (+ (, (intern (format "sha1-%s-high" H)))
 213                      (, (intern (format "sha1-%s-high" X)))
 214                      carry)
 215                   65536)))))
 216   )
 217
 218 ;;; buffers (H0 H1 H2 H3 H4).
 219 (defvar sha1-H0-high)
 220 (defvar sha1-H0-low)
 221 (defvar sha1-H1-high)
 222 (defvar sha1-H1-low)
 223 (defvar sha1-H2-high)
 224 (defvar sha1-H2-low)
 225 (defvar sha1-H3-high)
 226 (defvar sha1-H3-low)
 227 (defvar sha1-H4-high)
 228 (defvar sha1-H4-low)
 229
 230 (defun sha1-block (block-high block-low)
 231   (let (;; step (c) --- initialize buffers (A B C D E).
 232         (sha1-A-high sha1-H0-high) (sha1-A-low sha1-H0-low)
 233         (sha1-B-high sha1-H1-high) (sha1-B-low sha1-H1-low)
 234         (sha1-C-high sha1-H2-high) (sha1-C-low sha1-H2-low)
 235         (sha1-D-high sha1-H3-high) (sha1-D-low sha1-H3-low)
 236         (sha1-E-high sha1-H4-high) (sha1-E-low sha1-H4-low)
 237         (idx 16))
 238     ;; step (b).
 239     (let (;; temporary variables used in sha1-S1 macro.
 240           S1W-high S1W-low)
 241       (while (< idx 80)
 242         (sha1-S1 (logxor (aref block-high (- idx 3))
 243                          (aref block-high (- idx 8))
 244                          (aref block-high (- idx 14))
 245                          (aref block-high (- idx 16)))
 246                  (logxor (aref block-low  (- idx 3))
 247                          (aref block-low  (- idx 8))
 248                          (aref block-low  (- idx 14))
 249                          (aref block-low  (- idx 16))))
 250         (aset block-high idx S1W-high)
 251         (aset block-low  idx S1W-low)
 252         (setq idx (1+ idx))))
 253     ;; step (d).
 254     (setq idx 0)
 255     (let (;; temporary variables used in sha1-OP macro.
 256           S5A-high S5A-low S30B-high S30B-low carry)
 257       (while (< idx 20) (sha1-OP 0) (setq idx (1+ idx)))
 258       (while (< idx 40) (sha1-OP 1) (setq idx (1+ idx)))
 259       (while (< idx 60) (sha1-OP 2) (setq idx (1+ idx)))
 260       (while (< idx 80) (sha1-OP 3) (setq idx (1+ idx))))
 261     ;; step (e).
 262     (let (;; temporary variables used in sha1-add-to-H macro.
 263           carry)
 264       (sha1-add-to-H H0 A)
 265       (sha1-add-to-H H1 B)
 266       (sha1-add-to-H H2 C)
 267       (sha1-add-to-H H3 D)
 268       (sha1-add-to-H H4 E))))
 269
 270 (defun sha1-binary (string)
 271   "Return the SHA1 of STRING in binary form."
 272   (let (;; prepare buffers for a block. byte-length of block is 64.
 273         ;; input block is split into two vectors.
 274         ;;
 275         ;; input block: 00 01 02 03 04 05 06 07 08 09 0A 0B 0C 0D 0E 0F ...
 276         ;; block-high:  +-0-+       +-1-+       +-2-+       +-3-+
 277         ;; block-low:         +-0-+       +-1-+       +-2-+       +-3-+
 278         ;;
 279         ;; length of each vector is 80, and elements of each vector are
 280         ;; 16bit integers.  elements 0x10-0x4F of each vector are
 281         ;; assigned later in `sha1-block'.
 282         (block-high (eval-when-compile (make-vector 80 nil)))
 283         (block-low  (eval-when-compile (make-vector 80 nil))))
 284     (unwind-protect
 285         (let* (;; byte-length of input string.
 286                (len (length string))
 287                (lim (* (/ len 64) 64))
 288                (rem (% len 4))
 289                (idx 0)(pos 0))
 290           ;; initialize buffers (H0 H1 H2 H3 H4).
 291           (setq sha1-H0-high 26437      ; (string-to-number "6745" 16)
 292                 sha1-H0-low  8961       ; (string-to-number "2301" 16)
 293                 sha1-H1-high 61389      ; (string-to-number "EFCD" 16)
 294                 sha1-H1-low  43913      ; (string-to-number "AB89" 16)
 295                 sha1-H2-high 39098      ; (string-to-number "98BA" 16)
 296                 sha1-H2-low  56574      ; (string-to-number "DCFE" 16)
 297                 sha1-H3-high 4146       ; (string-to-number "1032" 16)
 298                 sha1-H3-low  21622      ; (string-to-number "5476" 16)
 299                 sha1-H4-high 50130      ; (string-to-number "C3D2" 16)
 300                 sha1-H4-low  57840)     ; (string-to-number "E1F0" 16)
 301           ;; loop for each 64 bytes block.
 302           (while (< pos lim)
 303             ;; step (a).
 304             (setq idx 0)
 305             (while (< idx 16)
 306               (aset block-high idx (+ (* (aref string pos) 256)
 307                                       (aref string (1+ pos))))
 308               (setq pos (+ pos 2))
 309               (aset block-low  idx (+ (* (aref string pos) 256)
 310                                       (aref string (1+ pos))))
 311               (setq pos (+ pos 2))
 312               (setq idx (1+ idx)))
 313             (sha1-block block-high block-low))
 314           ;; last block.
 315           (if (prog1
 316                   (< (- len lim) 56)
 317                 (setq lim (- len rem))
 318                 (setq idx 0)
 319                 (while (< pos lim)
 320                   (aset block-high idx (+ (* (aref string pos) 256)
 321                                           (aref string (1+ pos))))
 322                   (setq pos (+ pos 2))
 323                   (aset block-low  idx (+ (* (aref string pos) 256)
 324                                           (aref string (1+ pos))))
 325                   (setq pos (+ pos 2))
 326                   (setq idx (1+ idx)))
 327                 ;; this is the last (at most) 32bit word.
 328                 (cond
 329                  ((= rem 3)
 330                   (aset block-high idx (+ (* (aref string pos) 256)
 331                                           (aref string (1+ pos))))
 332                   (setq pos (+ pos 2))
 333                   (aset block-low  idx (+ (* (aref string pos) 256)
 334                                           128)))
 335                  ((= rem 2)
 336                   (aset block-high idx (+ (* (aref string pos) 256)
 337                                           (aref string (1+ pos))))
 338                   (aset block-low  idx 32768))
 339                  ((= rem 1)
 340                   (aset block-high idx (+ (* (aref string pos) 256)
 341                                           128))
 342                   (aset block-low  idx 0))
 343                  (t ;; (= rem 0)
 344                   (aset block-high idx 32768)
 345                   (aset block-low  idx 0)))
 346                 (setq idx (1+ idx))
 347                 (while (< idx 16)
 348                   (aset block-high idx 0)
 349                   (aset block-low  idx 0)
 350                   (setq idx (1+ idx))))
 351               ;; last block has enough room to write the length of string.
 352               (progn
 353                 ;; write bit length of string to last 4 bytes of the block.
 354                 (aset block-low  15 (* (% len 8192) 8))
 355                 (setq len (/ len 8192))
 356                 (aset block-high 15 (% len 65536))
 357                 ;; XXX: It is not practical to compute SHA1 of
 358                 ;;      such a huge message on emacs.
 359                 ;; (setq len (/ len 65536))     ; for 64bit emacs.
 360                 ;; (aset block-low  14 (% len 65536))
 361                 ;; (aset block-high 14 (/ len 65536))
 362                 (sha1-block block-high block-low))
 363             ;; need one more block.
 364             (sha1-block block-high block-low)
 365             (fillarray block-high 0)
 366             (fillarray block-low  0)
 367             ;; write bit length of string to last 4 bytes of the block.
 368             (aset block-low  15 (* (% len 8192) 8))
 369             (setq len (/ len 8192))
 370             (aset block-high 15 (% len 65536))
 371             ;; XXX: It is not practical to compute SHA1 of
 372             ;;      such a huge message on emacs.
 373             ;; (setq len (/ len 65536))         ; for 64bit emacs.
 374             ;; (aset block-low  14 (% len 65536))
 375             ;; (aset block-high 14 (/ len 65536))
 376             (sha1-block block-high block-low))
 377           ;; make output string (in binary form).
 378           (let ((result (make-string 20 0)))
 379             (aset result  0 (/ sha1-H0-high 256))
 380             (aset result  1 (% sha1-H0-high 256))
 381             (aset result  2 (/ sha1-H0-low  256))
 382             (aset result  3 (% sha1-H0-low  256))
 383             (aset result  4 (/ sha1-H1-high 256))
 384             (aset result  5 (% sha1-H1-high 256))
 385             (aset result  6 (/ sha1-H1-low  256))
 386             (aset result  7 (% sha1-H1-low  256))
 387             (aset result  8 (/ sha1-H2-high 256))
 388             (aset result  9 (% sha1-H2-high 256))
 389             (aset result 10 (/ sha1-H2-low  256))
 390             (aset result 11 (% sha1-H2-low  256))
 391             (aset result 12 (/ sha1-H3-high 256))
 392             (aset result 13 (% sha1-H3-high 256))
 393             (aset result 14 (/ sha1-H3-low  256))
 394             (aset result 15 (% sha1-H3-low  256))
 395             (aset result 16 (/ sha1-H4-high 256))
 396             (aset result 17 (% sha1-H4-high 256))
 397             (aset result 18 (/ sha1-H4-low  256))
 398             (aset result 19 (% sha1-H4-low  256))
 399             result))
 400       ;; do not leave a copy of input string.
 401       (fillarray block-high nil)
 402       (fillarray block-low  nil))))
 403
 404 (defun sha1-string-internal (string)
 405   (encode-hex-string (sha1-binary string)))
 406
 407 (defun sha1-region-internal (beg end)
 408   (sha1-string-internal (buffer-substring-no-properties beg end)))
 409
 410 ;;;
 411 ;;; application interface.
 412 ;;;
 413
 414 (defun sha1-region (beg end)
 415   (if (and sha1-use-external
 416            sha1-maximum-internal-length
 417            (> (abs (- end beg)) sha1-maximum-internal-length))
 418       (sha1-region-external beg end)
 419     (sha1-region-internal beg end)))
 420
 421 (defun sha1-string (string)
 422   (if (and sha1-use-external
 423            sha1-maximum-internal-length
 424            (> (length string) sha1-maximum-internal-length))
 425       (sha1-string-external string)
 426     (sha1-string-internal string)))
 427
 428 ;;;###autoload
 429 (defun sha1 (object &optional beg end)
 430   "Return the SHA1 (Secure Hash Algorithm) of an object.
 431 OBJECT is either a string or a buffer.
 432 Optional arguments BEG and END denote buffer positions for computing the
 433 hash of a portion of OBJECT."
 434   (if (stringp object)
 435       (sha1-string object)
 436     (save-excursion
 437       (set-buffer object)
 438       (sha1-region (or beg (point-min)) (or end (point-max))))))
 439
 440 (provide 'sha1-el)
 441
 442 ;;; sha1-el.el ends here