cgit.sxemacs.org Git - gnus/blob - lisp/rfc2047.el

   1 ;;; rfc2047.el --- functions for encoding and decoding rfc2047 messages
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2002, 2003, 2004
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; RFC 2047 is "MIME (Multipurpose Internet Mail Extensions) Part
  28 ;; Three:  Message Header Extensions for Non-ASCII Text".
  29
  30 ;;; Code:
  31
  32 (eval-when-compile
  33   (require 'cl)
  34   (defvar message-posting-charset))
  35
  36 (require 'qp)
  37 (require 'mm-util)
  38 ;; Fixme: Avoid this (used for mail-parse-charset) mm dependence on gnus.
  39 (require 'mail-prsvr)
  40 (require 'base64)
  41 (autoload 'mm-body-7-or-8 "mm-bodies")
  42
  43 (defvar rfc2047-header-encoding-alist
  44   '(("Newsgroups" . nil)
  45     ("Followup-To" . nil)
  46     ("Message-ID" . nil)
  47     ("\\(Resent-\\)?\\(From\\|Cc\\|To\\|Bcc\\|Reply-To\\|Sender\
  48 \\|Mail-Followup-To\\|Mail-Copies-To\\|Approved\\)" . address-mime)
  49     (t . mime))
  50   "*Header/encoding method alist.
  51 The list is traversed sequentially.  The keys can either be
  52 header regexps or t.
  53
  54 The values can be:
  55
  56 1) nil, in which case no encoding is done;
  57 2) `mime', in which case the header will be encoded according to RFC2047;
  58 3) `address-mime', like `mime', but takes account of the rules for address
  59    fields (where quoted strings and comments must be treated separately);
  60 4) a charset, in which case it will be encoded as that charset;
  61 5) `default', in which case the field will be encoded as the rest
  62    of the article.")
  63
  64 (defvar rfc2047-charset-encoding-alist
  65   '((us-ascii . nil)
  66     (iso-8859-1 . Q)
  67     (iso-8859-2 . Q)
  68     (iso-8859-3 . Q)
  69     (iso-8859-4 . Q)
  70     (iso-8859-5 . B)
  71     (koi8-r . B)
  72     (iso-8859-7 . B)
  73     (iso-8859-8 . B)
  74     (iso-8859-9 . Q)
  75     (iso-8859-14 . Q)
  76     (iso-8859-15 . Q)
  77     (iso-2022-jp . B)
  78     (iso-2022-kr . B)
  79     (gb2312 . B)
  80     (big5 . B)
  81     (cn-big5 . B)
  82     (cn-gb . B)
  83     (cn-gb-2312 . B)
  84     (euc-kr . B)
  85     (iso-2022-jp-2 . B)
  86     (iso-2022-int-1 . B)
  87     (viscii . Q))
  88   "Alist of MIME charsets to RFC2047 encodings.
  89 Valid encodings are nil, `Q' and `B'.  These indicate binary (no) encoding,
  90 quoted-printable and base64 respectively.")
  91
  92 (defvar rfc2047-encode-function-alist
  93   '((Q . rfc2047-q-encode-string)
  94     (B . rfc2047-b-encode-string)
  95     (nil . identity))
  96   "Alist of RFC2047 encodings to encoding functions.")
  97
  98 (defvar rfc2047-encode-encoded-words t
  99   "Whether encoded words should be encoded again.")
 100
 101 ;;;
 102 ;;; Functions for encoding RFC2047 messages
 103 ;;;
 104
 105 (defun rfc2047-qp-or-base64 ()
 106   "Return the type with which to encode the buffer.
 107 This is either `base64' or `quoted-printable'."
 108   (save-excursion
 109     (let ((limit (min (point-max) (+ 2000 (point-min))))
 110           (n8bit 0))
 111       (goto-char (point-min))
 112       (skip-chars-forward "\x20-\x7f\r\n\t" limit)
 113       (while (< (point) limit)
 114         (incf n8bit)
 115         (forward-char 1)
 116         (skip-chars-forward "\x20-\x7f\r\n\t" limit))
 117       (if (or (< (* 6 n8bit) (- limit (point-min)))
 118               ;; Don't base64, say, a short line with a single
 119               ;; non-ASCII char when splitting parts by charset.
 120               (= n8bit 1))
 121           'quoted-printable
 122         'base64))))
 123
 124 (defun rfc2047-narrow-to-field ()
 125   "Narrow the buffer to the header on the current line."
 126   (beginning-of-line)
 127   (narrow-to-region
 128    (point)
 129    (progn
 130      (forward-line 1)
 131      (if (re-search-forward "^[^ \n\t]" nil t)
 132          (point-at-bol)
 133        (point-max))))
 134   (goto-char (point-min)))
 135
 136 (defun rfc2047-field-value ()
 137   "Return the value of the field at point."
 138   (save-excursion
 139     (save-restriction
 140       (rfc2047-narrow-to-field)
 141       (re-search-forward ":[ \t\n]*" nil t)
 142       (buffer-substring-no-properties (point) (point-max)))))
 143
 144 (defvar rfc2047-encoding-type 'address-mime
 145   "The type of encoding done by `rfc2047-encode-region'.
 146 This should be dynamically bound around calls to
 147 `rfc2047-encode-region' to either `mime' or `address-mime'.  See
 148 `rfc2047-header-encoding-alist', for definitions.")
 149
 150 (defun rfc2047-encode-message-header ()
 151   "Encode the message header according to `rfc2047-header-encoding-alist'.
 152 Should be called narrowed to the head of the message."
 153   (interactive "*")
 154   (save-excursion
 155     (goto-char (point-min))
 156     (let (alist elem method)
 157       (while (not (eobp))
 158         (save-restriction
 159           (rfc2047-narrow-to-field)
 160           (if (not (rfc2047-encodable-p))
 161               (prog1
 162                   (if (and (eq (mm-body-7-or-8) '8bit)
 163                            (mm-multibyte-p)
 164                            (mm-coding-system-p
 165                             (car message-posting-charset)))
 166                       ;; 8 bit must be decoded.
 167                       (mm-encode-coding-region
 168                        (point-min) (point-max)
 169                        (mm-charset-to-coding-system
 170                         (car message-posting-charset))))
 171                 ;; No encoding necessary, but folding is nice
 172                 (when nil
 173                   (rfc2047-fold-region
 174                    (save-excursion
 175                      (goto-char (point-min))
 176                      (skip-chars-forward "^:")
 177                      (when (looking-at ": ")
 178                        (forward-char 2))
 179                      (point))
 180                    (point-max))))
 181             ;; We found something that may perhaps be encoded.
 182             (setq method nil
 183                   alist rfc2047-header-encoding-alist)
 184             (while (setq elem (pop alist))
 185               (when (or (and (stringp (car elem))
 186                              (looking-at (car elem)))
 187                         (eq (car elem) t))
 188                 (setq alist nil
 189                       method (cdr elem))))
 190             (re-search-forward "^[^:]+: *" nil t)
 191             (cond
 192              ((eq method 'address-mime)
 193               (rfc2047-encode-region (point) (point-max)))
 194              ((eq method 'mime)
 195               (let ((rfc2047-encoding-type 'mime))
 196                 (rfc2047-encode-region (point) (point-max))))
 197              ((eq method 'default)
 198               (if (and (featurep 'mule)
 199                        (if (boundp 'default-enable-multibyte-characters)
 200                            default-enable-multibyte-characters)
 201                        mail-parse-charset)
 202                   (mm-encode-coding-region (point) (point-max)
 203                                            mail-parse-charset)))
 204              ;; We get this when CC'ing messsages to newsgroups with
 205              ;; 8-bit names.  The group name mail copy just got
 206              ;; unconditionally encoded.  Previously, it would ask
 207              ;; whether to encode, which was quite confusing for the
 208              ;; user.  If the new behaviour is wrong, tell me. I have
 209              ;; left the old code commented out below.
 210              ;; -- Per Abrahamsen <abraham@dina.kvl.dk> Date: 2001-10-07.
 211              ;; Modified by Dave Love, with the commented-out code changed
 212              ;; in accordance with changes elsewhere.
 213              ((null method)
 214               (rfc2047-encode-region (point) (point-max)))
 215 ;;;          ((null method)
 216 ;;;           (if (or (message-options-get
 217 ;;;                    'rfc2047-encode-message-header-encode-any)
 218 ;;;                   (message-options-set
 219 ;;;                    'rfc2047-encode-message-header-encode-any
 220 ;;;                    (y-or-n-p
 221 ;;;                     "Some texts are not encoded. Encode anyway?")))
 222 ;;;               (rfc2047-encode-region (point-min) (point-max))
 223 ;;;             (error "Cannot send unencoded text")))
 224              ((mm-coding-system-p method)
 225               (if (and (featurep 'mule)
 226                        (if (boundp 'default-enable-multibyte-characters)
 227                            default-enable-multibyte-characters))
 228                   (mm-encode-coding-region (point) (point-max) method)))
 229              ;; Hm.
 230              (t)))
 231           (goto-char (point-max)))))))
 232
 233 ;; Fixme: This, and the require below may not be the Right Thing, but
 234 ;; should be safe just before release.  -- fx 2001-02-08
 235 (eval-when-compile (defvar message-posting-charset))
 236
 237 (defun rfc2047-encodable-p ()
 238   "Return non-nil if any characters in current buffer need encoding in headers.
 239 The buffer may be narrowed."
 240   (require 'message)                    ; for message-posting-charset
 241   (let ((charsets
 242          (mm-find-mime-charset-region (point-min) (point-max))))
 243     (goto-char (point-min))
 244     (or (and rfc2047-encode-encoded-words
 245              (prog1
 246                  (search-forward "=?" nil t)
 247                (goto-char (point-min))))
 248         (and charsets
 249              (not (equal charsets (list (car message-posting-charset))))))))
 250
 251 ;; Use this syntax table when parsing into regions that may need
 252 ;; encoding.  Double quotes are string delimiters, backslash is
 253 ;; character quoting, and all other RFC 2822 special characters are
 254 ;; treated as punctuation so we can use forward-sexp/forward-word to
 255 ;; skip to the end of regions appropriately.  Nb. ietf-drums does
 256 ;; things differently.
 257 (defconst rfc2047-syntax-table
 258   ;; (make-char-table 'syntax-table '(2)) only works in Emacs.
 259   (let ((table (make-syntax-table)))
 260     ;; The following is done to work for setting all elements of the table
 261     ;; in Emacs 21 and 22 and XEmacs; it appears to be the cleanest way.
 262     ;; Play safe and don't assume the form of the word syntax entry --
 263     ;; copy it from ?a.
 264     (if (fboundp 'set-char-table-range) ; Emacs
 265         (funcall (intern "set-char-table-range")
 266                  table t (aref (standard-syntax-table) ?a))
 267       (if (fboundp 'put-char-table)
 268           (if (fboundp 'get-char-table) ; warning avoidance
 269               (put-char-table t (get-char-table ?a (standard-syntax-table))
 270                               table))))
 271     (modify-syntax-entry ?\\ "\\" table)
 272     (modify-syntax-entry ?\" "\"" table)
 273     (modify-syntax-entry ?\( "(" table)
 274     (modify-syntax-entry ?\) ")" table)
 275     (modify-syntax-entry ?\< "." table)
 276     (modify-syntax-entry ?\> "." table)
 277     (modify-syntax-entry ?\[ "." table)
 278     (modify-syntax-entry ?\] "." table)
 279     (modify-syntax-entry ?: "." table)
 280     (modify-syntax-entry ?\; "." table)
 281     (modify-syntax-entry ?, "." table)
 282     (modify-syntax-entry ?@ "." table)
 283     table))
 284
 285 (defun rfc2047-encode-region (b e)
 286   "Encode words in region B to E that need encoding.
 287 By default, the region is treated as containing RFC2822 addresses.
 288 Dynamically bind `rfc2047-encoding-type' to change that."
 289   (save-restriction
 290     (narrow-to-region b e)
 291     (let ((encodable-regexp (if rfc2047-encode-encoded-words
 292                                 "[^\000-\177]+\\|=\\?"
 293                               "[^\000-\177]+"))
 294           start                         ; start of current token
 295           end begin
 296           ;; Whether there's an encoded word before the current token,
 297           ;; either immediately or separated by space.
 298           last-encoded
 299           (orig-text (buffer-substring-no-properties b e)))
 300       (if (eq 'mime rfc2047-encoding-type)
 301           ;; Simple case.  Continuous words in which all those contain
 302           ;; non-ASCII characters are encoded collectively.  Encoding
 303           ;; ASCII words, including `Re:' used in Subject headers, is
 304           ;; avoided for interoperability with non-MIME clients and
 305           ;; for making it easy to find keywords.
 306           (progn
 307             (goto-char (point-min))
 308             (while (progn (skip-chars-forward " \t\n")
 309                           (not (eobp)))
 310               (setq start (point))
 311               (while (and (looking-at "[ \t\n]*\\([^ \t\n]+\\)")
 312                           (progn
 313                             (setq end (match-end 0))
 314                             (re-search-forward encodable-regexp end t)))
 315                 (goto-char end))
 316               (if (> (point) start)
 317                   (rfc2047-encode start (point))
 318                 (goto-char end))))
 319         ;; `address-mime' case -- take care of quoted words, comments.
 320         (with-syntax-table rfc2047-syntax-table
 321           (goto-char (point-min))
 322           (condition-case nil           ; in case of unbalanced quotes
 323               ;; Look for rfc2822-style: sequences of atoms, quoted
 324               ;; strings, specials, whitespace.  (Specials mustn't be
 325               ;; encoded.)
 326               (while (not (eobp))
 327                 ;; Skip whitespace.
 328                 (skip-chars-forward " \t\n")
 329                 (setq start (point))
 330                 (cond
 331                  ((not (char-after)))   ; eob
 332                  ;; else token start
 333                  ((eq ?\" (char-syntax (char-after)))
 334                   ;; Quoted word.
 335                   (forward-sexp)
 336                   (setq end (point))
 337                   ;; Does it need encoding?
 338                   (goto-char start)
 339                   (if (re-search-forward encodable-regexp end 'move)
 340                       ;; It needs encoding.  Strip the quotes first,
 341                       ;; since encoded words can't occur in quotes.
 342                       (progn
 343                         (goto-char end)
 344                         (delete-backward-char 1)
 345                         (goto-char start)
 346                         (delete-char 1)
 347                         (when last-encoded
 348                           ;; There was a preceding quoted word.  We need
 349                           ;; to include any separating whitespace in this
 350                           ;; word to avoid it getting lost.
 351                           (skip-chars-backward " \t")
 352                           ;; A space is needed between the encoded words.
 353                           (insert ? )
 354                           (setq start (point)
 355                                 end (1+ end)))
 356                         ;; Adjust the end position for the deleted quotes.
 357                         (rfc2047-encode start (- end 2))
 358                         (setq last-encoded t)) ; record that it was encoded
 359                     (setq last-encoded  nil)))
 360                  ((eq ?. (char-syntax (char-after)))
 361                   ;; Skip other delimiters, but record that they've
 362                   ;; potentially separated quoted words.
 363                   (forward-char)
 364                   (setq last-encoded nil))
 365                  ((eq ?\) (char-syntax (char-after)))
 366                   (error "Unbalanced parentheses"))
 367                  ((eq ?\( (char-syntax (char-after)))
 368                   ;; Look for the end of parentheses.
 369                   (forward-list)
 370                   ;; Encode text as an unstructured field.
 371                   (let ((rfc2047-encoding-type 'mime))
 372                     (rfc2047-encode-region (1+ start) (1- (point)))
 373                     (forward-char)))
 374                  (t                 ; normal token/whitespace sequence
 375                   ;; Find the end.
 376                   ;; Skip one ASCII word, or encode continuous words
 377                   ;; in which all those contain non-ASCII characters.
 378                   (setq end nil)
 379                   (while (not end)
 380                     (when (looking-at "[\000-\177]+")
 381                       (setq begin (point)
 382                             end (match-end 0))
 383                       (if (re-search-forward "[ \t\n]\\|\\Sw" end 'move)
 384                           (progn
 385                             (setq end (match-beginning 0))
 386                             (if rfc2047-encode-encoded-words
 387                                 (progn
 388                                   (goto-char begin)
 389                                   (when (search-forward "=?" end 'move)
 390                                     (goto-char (match-beginning 0))
 391                                     (setq end nil)))
 392                               (goto-char end)))
 393                         (setq end nil)))
 394                     (unless end
 395                       (setq end t)
 396                       (when (looking-at encodable-regexp)
 397                         (goto-char (match-end 0))
 398                         (while (and (looking-at "[ \t\n]+\\([^ \t\n]+\\)")
 399                                     (setq end (match-end 0))
 400                                     (string-match encodable-regexp
 401                                                   (match-string 1)))
 402                           (goto-char end))
 403                         (when (looking-at "[^ \t\n]+")
 404                           (setq end (match-end 0))
 405                           (if (re-search-forward "\\Sw+" end t)
 406                               ;; There are special characters better
 407                               ;; to be encoded so that MTAs may parse
 408                               ;; them safely.
 409                               (cond ((= end (point)))
 410                                     ((looking-at encodable-regexp)
 411                                      (setq end nil))
 412                                     (t
 413                                      (goto-char (1- (match-end 0)))
 414                                      (unless (= (point) (match-beginning 0))
 415                                        (insert " "))))
 416                             (goto-char end)
 417                             (skip-chars-forward " \t\n")
 418                             (if (and (looking-at "[^ \t\n]+")
 419                                      (string-match encodable-regexp
 420                                                    (match-string 0)))
 421                                 (setq end nil)
 422                               (goto-char end)))))))
 423                   (skip-chars-backward " \t\n")
 424                   (setq end (point))
 425                   (goto-char start)
 426                   (if (re-search-forward encodable-regexp end 'move)
 427                       (progn
 428                         (rfc2047-encode start end)
 429                         (setq last-encoded t))
 430                     (setq last-encoded nil)))))
 431             (error
 432              (error "Invalid data for rfc2047 encoding: %s"
 433                     (mm-replace-in-string orig-text "[ \t\n]+" " ")))))))
 434     (rfc2047-fold-region b (point))
 435     (goto-char (point-max))))
 436
 437 (defun rfc2047-encode-string (string)
 438   "Encode words in STRING.
 439 By default, the string is treated as containing addresses (see
 440 `rfc2047-encoding-type')."
 441   (with-temp-buffer
 442     (insert string)
 443     (rfc2047-encode-region (point-min) (point-max))
 444     (buffer-string)))
 445
 446 (defun rfc2047-encode-1 (column string cs encoder start space &optional eword)
 447   "Subroutine used by `rfc2047-encode'."
 448   (cond ((string-equal string "")
 449          (or eword ""))
 450         ((>= column 76)
 451          (when (and eword
 452                     (string-match "\n[ \t]+\\'" eword))
 453            ;; Reomove a superfluous empty line.
 454            (setq eword (substring eword 0 (match-beginning 0))))
 455          (rfc2047-encode-1 (length space) string cs encoder start " "
 456                            (concat eword "\n" space)))
 457         (t
 458          (let ((index 0)
 459                (limit (1- (length string)))
 460                (prev "")
 461                next)
 462            (while (and prev
 463                        (<= index limit))
 464              (setq next (concat start
 465                                 (funcall encoder
 466                                          (if cs
 467                                              (mm-encode-coding-string
 468                                               (substring string 0 (1+ index))
 469                                               cs)
 470                                            (substring string 0 (1+ index))))
 471                                 "?="))
 472              (if (<= (+ column (length next)) 76)
 473                  (setq prev next
 474                        index (1+ index))
 475                (setq next prev
 476                      prev nil)))
 477            (setq eword (concat eword next))
 478            (if (> index limit)
 479                eword
 480              (when (string-match "\n[ \t]+\\'" eword)
 481                ;; Reomove a superfluous empty line.
 482                (setq eword (substring eword 0 (match-beginning 0))))
 483              (rfc2047-encode-1 (length space) (substring string index)
 484                                cs encoder start " "
 485                                (concat eword "\n" space)))))))
 486
 487 (defun rfc2047-encode (b e)
 488   "Encode the word(s) in the region B to E.
 489 Point moves to the end of the region."
 490   (let ((mime-charset (or (mm-find-mime-charset-region b e) (list 'us-ascii)))
 491         cs encoding space eword)
 492     (cond ((> (length mime-charset) 1)
 493            (error "Can't rfc2047-encode `%s'"
 494                   (buffer-substring-no-properties b e)))
 495           ((= (length mime-charset) 1)
 496            (setq mime-charset (car mime-charset)
 497                  cs (mm-charset-to-coding-system mime-charset))
 498            (unless (and (mm-multibyte-p)
 499                         (mm-coding-system-p cs))
 500              (setq cs nil))
 501            (save-restriction
 502              (narrow-to-region b e)
 503              (setq encoding
 504                    (or (cdr (assq mime-charset
 505                                   rfc2047-charset-encoding-alist))
 506                        ;; For the charsets that don't have a preferred
 507                        ;; encoding, choose the one that's shorter.
 508                        (if (eq (rfc2047-qp-or-base64) 'base64)
 509                            'B
 510                          'Q)))
 511              (widen)
 512              (goto-char b)
 513              (setq b (point-marker)
 514                    e (set-marker (make-marker) e))
 515              (rfc2047-fold-region (point-at-bol) b)
 516              (unless (= 0 (skip-chars-backward " \t"))
 517                (setq space (buffer-substring-no-properties (point) b)))
 518              (setq eword (rfc2047-encode-1
 519                           (- b (point-at-bol))
 520                           (mm-replace-in-string
 521                            (buffer-substring-no-properties b e)
 522                            "\n\\([ \t]?\\)" "\\1")
 523                           cs
 524                           (or (cdr (assq encoding
 525                                          rfc2047-encode-function-alist))
 526                               'identity)
 527                           (concat "=?" (downcase (symbol-name mime-charset))
 528                                   "?" (upcase (symbol-name encoding)) "?")
 529                           (or space " ")))
 530              (delete-region (if (eq (aref eword 0) ?\n)
 531                                 (point)
 532                               (goto-char b))
 533                             e)
 534              (insert eword)
 535              (set-marker b nil)
 536              (set-marker e nil)
 537              (unless (or (eolp)
 538                          (looking-at "[ \t\n)]"))
 539                (insert " "))))
 540           (t
 541            (goto-char e)))))
 542
 543 (defun rfc2047-fold-field ()
 544   "Fold the current header field."
 545   (save-excursion
 546     (save-restriction
 547       (rfc2047-narrow-to-field)
 548       (rfc2047-fold-region (point-min) (point-max)))))
 549
 550 (defun rfc2047-fold-region (b e)
 551   "Fold long lines in region B to E."
 552   (save-restriction
 553     (narrow-to-region b e)
 554     (goto-char (point-min))
 555     (let ((break nil)
 556           (qword-break nil)
 557           (first t)
 558           (bol (save-restriction
 559                  (widen)
 560                  (point-at-bol))))
 561       (while (not (eobp))
 562         (when (and (or break qword-break)
 563                    (> (- (point) bol) 76))
 564           (goto-char (or break qword-break))
 565           (setq break nil
 566                 qword-break nil)
 567           (skip-chars-backward " \t")
 568           (if (looking-at "[ \t]")
 569               (insert ?\n)
 570             (insert "\n "))
 571           (setq bol (1- (point)))
 572           ;; Don't break before the first non-LWSP characters.
 573           (skip-chars-forward " \t")
 574           (unless (eobp)
 575             (forward-char 1)))
 576         (cond
 577          ((eq (char-after) ?\n)
 578           (forward-char 1)
 579           (setq bol (point)
 580                 break nil
 581                 qword-break nil)
 582           (skip-chars-forward " \t")
 583           (unless (or (eobp) (eq (char-after) ?\n))
 584             (forward-char 1)))
 585          ((eq (char-after) ?\r)
 586           (forward-char 1))
 587          ((memq (char-after) '(?  ?\t))
 588           (skip-chars-forward " \t")
 589           (unless first ;; Don't break just after the header name.
 590             (setq break (point))))
 591          ((not break)
 592           (if (not (looking-at "=\\?[^=]"))
 593               (if (eq (char-after) ?=)
 594                   (forward-char 1)
 595                 (skip-chars-forward "^ \t\n\r="))
 596             ;; Don't break at the start of the field.
 597             (unless (= (point) b)
 598               (setq qword-break (point)))
 599             (skip-chars-forward "^ \t\n\r")))
 600          (t
 601           (skip-chars-forward "^ \t\n\r")))
 602         (setq first nil))
 603       (when (and (or break qword-break)
 604                  (> (- (point) bol) 76))
 605         (goto-char (or break qword-break))
 606         (setq break nil
 607               qword-break nil)
 608           (if (looking-at "[ \t]")
 609               (insert ?\n)
 610             (insert "\n "))
 611         (setq bol (1- (point)))
 612         ;; Don't break before the first non-LWSP characters.
 613         (skip-chars-forward " \t")
 614         (unless (eobp)
 615           (forward-char 1))))))
 616
 617 (defun rfc2047-unfold-field ()
 618   "Fold the current line."
 619   (save-excursion
 620     (save-restriction
 621       (rfc2047-narrow-to-field)
 622       (rfc2047-unfold-region (point-min) (point-max)))))
 623
 624 (defun rfc2047-unfold-region (b e)
 625   "Unfold lines in region B to E."
 626   (save-restriction
 627     (narrow-to-region b e)
 628     (goto-char (point-min))
 629     (let ((bol (save-restriction
 630                  (widen)
 631                  (point-at-bol)))
 632           (eol (point-at-eol)))
 633       (forward-line 1)
 634       (while (not (eobp))
 635         (if (and (looking-at "[ \t]")
 636                  (< (- (point-at-eol) bol) 76))
 637             (delete-region eol (progn
 638                                  (goto-char eol)
 639                                  (skip-chars-forward "\r\n")
 640                                  (point)))
 641           (setq bol (point-at-bol)))
 642         (setq eol (point-at-eol))
 643         (forward-line 1)))))
 644
 645 (defun rfc2047-b-encode-string (string)
 646   "Base64-encode the header contained in STRING."
 647   (base64-encode-string string t))
 648
 649 (defun rfc2047-q-encode-string (string)
 650   "Quoted-printable-encode the header in STRING."
 651   (mm-with-unibyte-buffer
 652     (insert string)
 653     (quoted-printable-encode-region
 654      (point-min) (point-max) nil
 655      ;; = (\075), _ (\137), ? (\077) are used in the encoded word.
 656      ;; Avoid using 8bit characters.
 657      ;; This list excludes `especials' (see the RFC2047 syntax),
 658      ;; meaning that some characters in non-structured fields will
 659      ;; get encoded when they con't need to be.  The following is
 660      ;; what it used to be.
 661      ;;;  ;; Equivalent to "^\000-\007\011\013\015-\037\200-\377=_?"
 662      ;;;  "\010\012\014\040-\074\076\100-\136\140-\177")
 663      "-\b\n\f !#-'*+0-9A-Z\\^`-~\d")
 664     (subst-char-in-region (point-min) (point-max) ?  ?_)
 665     (buffer-string)))
 666
 667 ;;;
 668 ;;; Functions for decoding RFC2047 messages
 669 ;;;
 670
 671 (eval-and-compile
 672   (defconst rfc2047-encoded-word-regexp
 673     "=\\?\\([^][\000-\040()<>@,\;:*\\\"/?.=]+\\)\\(?:\\*[^?]+\\)?\
 674 \\?\\(B\\|Q\\)\\?\\([!->@-~ ]*\\)\\?="))
 675
 676 ;; Fixme: This should decode in place, not cons intermediate strings.
 677 ;; Also check whether it needs to worry about delimiting fields like
 678 ;; encoding.
 679
 680 ;; In fact it's reported that (invalid) encoding of mailboxes in
 681 ;; addr-specs is in use, so delimiting fields might help.  Probably
 682 ;; not decoding a word which isn't properly delimited is good enough
 683 ;; and worthwhile (is it more correct or not?), e.g. something like
 684 ;; `=?iso-8859-1?q?foo?=@'.
 685
 686 (defun rfc2047-decode-region (start end)
 687   "Decode MIME-encoded words in region between START and END."
 688   (interactive "r")
 689   (let ((case-fold-search t)
 690         b e)
 691     (save-excursion
 692       (save-restriction
 693         (narrow-to-region start end)
 694         (goto-char (point-min))
 695         ;; Remove whitespace between encoded words.
 696         (while (re-search-forward
 697                 (eval-when-compile
 698                   (concat "\\(" rfc2047-encoded-word-regexp "\\)"
 699                           "\\(\n?[ \t]\\)+"
 700                           "\\(" rfc2047-encoded-word-regexp "\\)"))
 701                 nil t)
 702           (delete-region (goto-char (match-end 1)) (match-beginning 6)))
 703         ;; Decode the encoded words.
 704         (setq b (goto-char (point-min)))
 705         (while (re-search-forward rfc2047-encoded-word-regexp nil t)
 706           (setq e (match-beginning 0))
 707           (insert (rfc2047-parse-and-decode
 708                    (prog1
 709                        (match-string 0)
 710                      (delete-region (match-beginning 0) (match-end 0)))))
 711           ;; Remove newlines between decoded words, though such things
 712           ;; essentially must not be there.
 713           (save-restriction
 714             (narrow-to-region e (point))
 715             (goto-char e)
 716             (while (re-search-forward "[\n\r]+" nil t)
 717               (replace-match " "))
 718             (goto-char (point-max)))
 719           (when (and (mm-multibyte-p)
 720                      mail-parse-charset
 721                      (not (eq mail-parse-charset 'us-ascii))
 722                      (not (eq mail-parse-charset 'gnus-decoded)))
 723             (mm-decode-coding-region b e mail-parse-charset))
 724           (setq b (point)))
 725         (when (and (mm-multibyte-p)
 726                    mail-parse-charset
 727                    (not (eq mail-parse-charset 'us-ascii))
 728                    (not (eq mail-parse-charset 'gnus-decoded)))
 729           (mm-decode-coding-region b (point-max) mail-parse-charset))))))
 730
 731 (defun rfc2047-decode-string (string)
 732   "Decode the quoted-printable-encoded STRING and return the results."
 733   (let ((m (mm-multibyte-p)))
 734     (if (string-match "=\\?" string)
 735         (with-temp-buffer
 736           ;; Fixme: This logic is wrong, but seems to be required by
 737           ;; Gnus summary buffer generation.  The value of `m' depends
 738           ;; on the current buffer, not global multibyteness or that
 739           ;; of the string.  Also the string returned should always be
 740           ;; multibyte in a multibyte session, i.e. the buffer should
 741           ;; be multibyte before `buffer-string' is called.
 742           (when m
 743             (mm-enable-multibyte))
 744           (insert string)
 745           (inline
 746             (rfc2047-decode-region (point-min) (point-max)))
 747           (buffer-string))
 748       ;; Fixme: As above, `m' here is inappropriate.
 749       (if (and m
 750                mail-parse-charset
 751                (not (eq mail-parse-charset 'us-ascii))
 752                (not (eq mail-parse-charset 'gnus-decoded)))
 753           ;; `decode-coding-string' in Emacs offers a third optional
 754           ;; arg NOCOPY to avoid consing a new string if the decoding
 755           ;; is "trivial".  Unfortunately it currently doesn't
 756           ;; consider anything else than a `nil' coding system
 757           ;; trivial.
 758           ;; `rfc2047-decode-string' is called multiple times for each
 759           ;; article during summary buffer generation, and we really
 760           ;; want to avoid unnecessary consing.  So we bypass
 761           ;; `decode-coding-string' if the string is purely ASCII.
 762           (if (and (fboundp 'detect-coding-string)
 763                    ;; string is purely ASCII
 764                    (eq (detect-coding-string string t) 'undecided))
 765               string
 766             (mm-decode-coding-string string mail-parse-charset))
 767         (mm-string-as-multibyte string)))))
 768
 769 (defun rfc2047-parse-and-decode (word)
 770   "Decode WORD and return it if it is an encoded word.
 771 Return WORD if it is not not an encoded word or if the charset isn't
 772 decodable."
 773   (if (not (string-match rfc2047-encoded-word-regexp word))
 774       word
 775     (or
 776      (condition-case nil
 777          (rfc2047-decode
 778           (match-string 1 word)
 779           (string-to-char (match-string 2 word))
 780           (match-string 3 word))
 781        (error word))
 782      word)))                            ; un-decodable
 783
 784 (defun rfc2047-pad-base64 (string)
 785   "Pad STRING to quartets."
 786   ;; Be more liberal to accept buggy base64 strings. If
 787   ;; base64-decode-string accepts buggy strings, this function could
 788   ;; be aliased to identity.
 789   (if (= 0 (mod (length string) 4))
 790       string
 791     (when (string-match "=+$" string)
 792       (setq string (substring string 0 (match-beginning 0))))
 793     (case (mod (length string) 4)
 794       (0 string)
 795       (1 string) ;; Error, don't pad it.
 796       (2 (concat string "=="))
 797       (3 (concat string "=")))))
 798
 799 (defun rfc2047-decode (charset encoding string)
 800   "Decode STRING from the given MIME CHARSET in the given ENCODING.
 801 Valid ENCODINGs are the characters \"B\" and \"Q\".
 802 If your Emacs implementation can't decode CHARSET, return nil."
 803   (if (stringp charset)
 804       (setq charset (intern (downcase charset))))
 805   (if (or (not charset)
 806           (eq 'gnus-all mail-parse-ignored-charsets)
 807           (memq 'gnus-all mail-parse-ignored-charsets)
 808           (memq charset mail-parse-ignored-charsets))
 809       (setq charset mail-parse-charset))
 810   (let ((cs (mm-charset-to-coding-system charset)))
 811     (if (and (not cs) charset
 812              (listp mail-parse-ignored-charsets)
 813              (memq 'gnus-unknown mail-parse-ignored-charsets))
 814         (setq cs (mm-charset-to-coding-system mail-parse-charset)))
 815     (when cs
 816       (when (eq cs 'ascii)
 817         (setq cs (or mail-parse-charset 'raw-text)))
 818       (mm-decode-coding-string
 819        (cond
 820         ((char-equal ?B encoding)
 821          (base64-decode-string
 822           (rfc2047-pad-base64 string)))
 823         ((char-equal ?Q encoding)
 824          (quoted-printable-decode-string
 825           (mm-subst-char-in-string ?_ ? string t)))
 826         (t (error "Invalid encoding: %c" encoding)))
 827        cs))))
 828
 829 (provide 'rfc2047)
 830
 831 ;;; arch-tag: a07fe3d4-22b5-4c4a-bd89-b1f82d5d36f6
 832 ;;; rfc2047.el ends here