cgit.sxemacs.org Git - gnus/blob - lisp/rfc2047.el

   1 ;;; rfc2047.el --- functions for encoding and decoding rfc2047 messages
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2002, 2003, 2004
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; RFC 2047 is "MIME (Multipurpose Internet Mail Extensions) Part
  28 ;; Three:  Message Header Extensions for Non-ASCII Text".
  29
  30 ;;; Code:
  31
  32 (eval-when-compile
  33   (require 'cl)
  34   (defvar message-posting-charset))
  35
  36 (require 'qp)
  37 (require 'mm-util)
  38 ;; Fixme: Avoid this (used for mail-parse-charset) mm dependence on gnus.
  39 (require 'mail-prsvr)
  40 (require 'base64)
  41 (autoload 'mm-body-7-or-8 "mm-bodies")
  42
  43 (defvar rfc2047-header-encoding-alist
  44   '(("Newsgroups" . nil)
  45     ("Followup-To" . nil)
  46     ("Message-ID" . nil)
  47     ("\\(Resent-\\)?\\(From\\|Cc\\|To\\|Bcc\\|Reply-To\\|Sender\
  48 \\|Mail-Followup-To\\|Mail-Copies-To\\|Approved\\)" . address-mime)
  49     (t . mime))
  50   "*Header/encoding method alist.
  51 The list is traversed sequentially.  The keys can either be
  52 header regexps or t.
  53
  54 The values can be:
  55
  56 1) nil, in which case no encoding is done;
  57 2) `mime', in which case the header will be encoded according to RFC2047;
  58 3) `address-mime', like `mime', but takes account of the rules for address
  59    fields (where quoted strings and comments must be treated separately);
  60 4) a charset, in which case it will be encoded as that charset;
  61 5) `default', in which case the field will be encoded as the rest
  62    of the article.")
  63
  64 (defvar rfc2047-charset-encoding-alist
  65   '((us-ascii . nil)
  66     (iso-8859-1 . Q)
  67     (iso-8859-2 . Q)
  68     (iso-8859-3 . Q)
  69     (iso-8859-4 . Q)
  70     (iso-8859-5 . B)
  71     (koi8-r . B)
  72     (iso-8859-7 . B)
  73     (iso-8859-8 . B)
  74     (iso-8859-9 . Q)
  75     (iso-8859-14 . Q)
  76     (iso-8859-15 . Q)
  77     (iso-2022-jp . B)
  78     (iso-2022-kr . B)
  79     (gb2312 . B)
  80     (big5 . B)
  81     (cn-big5 . B)
  82     (cn-gb . B)
  83     (cn-gb-2312 . B)
  84     (euc-kr . B)
  85     (iso-2022-jp-2 . B)
  86     (iso-2022-int-1 . B)
  87     (viscii . Q))
  88   "Alist of MIME charsets to RFC2047 encodings.
  89 Valid encodings are nil, `Q' and `B'.  These indicate binary (no) encoding,
  90 quoted-printable and base64 respectively.")
  91
  92 (defvar rfc2047-encode-function-alist
  93   '((Q . rfc2047-q-encode-string)
  94     (B . rfc2047-b-encode-string)
  95     (nil . identity))
  96   "Alist of RFC2047 encodings to encoding functions.")
  97
  98 (defvar rfc2047-encode-encoded-words t
  99   "Whether encoded words should be encoded again.")
 100
 101 ;;;
 102 ;;; Functions for encoding RFC2047 messages
 103 ;;;
 104
 105 (defun rfc2047-qp-or-base64 ()
 106   "Return the type with which to encode the buffer.
 107 This is either `base64' or `quoted-printable'."
 108   (save-excursion
 109     (let ((limit (min (point-max) (+ 2000 (point-min))))
 110           (n8bit 0))
 111       (goto-char (point-min))
 112       (skip-chars-forward "\x20-\x7f\r\n\t" limit)
 113       (while (< (point) limit)
 114         (incf n8bit)
 115         (forward-char 1)
 116         (skip-chars-forward "\x20-\x7f\r\n\t" limit))
 117       (if (or (< (* 6 n8bit) (- limit (point-min)))
 118               ;; Don't base64, say, a short line with a single
 119               ;; non-ASCII char when splitting parts by charset.
 120               (= n8bit 1))
 121           'quoted-printable
 122         'base64))))
 123
 124 (defun rfc2047-narrow-to-field ()
 125   "Narrow the buffer to the header on the current line."
 126   (beginning-of-line)
 127   (narrow-to-region
 128    (point)
 129    (progn
 130      (forward-line 1)
 131      (if (re-search-forward "^[^ \n\t]" nil t)
 132          (point-at-bol)
 133        (point-max))))
 134   (goto-char (point-min)))
 135
 136 (defun rfc2047-field-value ()
 137   "Return the value of the field at point."
 138   (save-excursion
 139     (save-restriction
 140       (rfc2047-narrow-to-field)
 141       (re-search-forward ":[ \t\n]*" nil t)
 142       (buffer-substring-no-properties (point) (point-max)))))
 143
 144 (defvar rfc2047-encoding-type 'address-mime
 145   "The type of encoding done by `rfc2047-encode-region'.
 146 This should be dynamically bound around calls to
 147 `rfc2047-encode-region' to either `mime' or `address-mime'.  See
 148 `rfc2047-header-encoding-alist', for definitions.")
 149
 150 (defun rfc2047-encode-message-header ()
 151   "Encode the message header according to `rfc2047-header-encoding-alist'.
 152 Should be called narrowed to the head of the message."
 153   (interactive "*")
 154   (save-excursion
 155     (goto-char (point-min))
 156     (let (alist elem method)
 157       (while (not (eobp))
 158         (save-restriction
 159           (rfc2047-narrow-to-field)
 160           (if (not (rfc2047-encodable-p))
 161               (prog1
 162                   (if (and (eq (mm-body-7-or-8) '8bit)
 163                            (mm-multibyte-p)
 164                            (mm-coding-system-p
 165                             (car message-posting-charset)))
 166                       ;; 8 bit must be decoded.
 167                       (mm-encode-coding-region
 168                        (point-min) (point-max)
 169                        (mm-charset-to-coding-system
 170                         (car message-posting-charset))))
 171                 ;; No encoding necessary, but folding is nice
 172                 (when nil
 173                   (rfc2047-fold-region
 174                    (save-excursion
 175                      (goto-char (point-min))
 176                      (skip-chars-forward "^:")
 177                      (when (looking-at ": ")
 178                        (forward-char 2))
 179                      (point))
 180                    (point-max))))
 181             ;; We found something that may perhaps be encoded.
 182             (setq method nil
 183                   alist rfc2047-header-encoding-alist)
 184             (while (setq elem (pop alist))
 185               (when (or (and (stringp (car elem))
 186                              (looking-at (car elem)))
 187                         (eq (car elem) t))
 188                 (setq alist nil
 189                       method (cdr elem))))
 190             (re-search-forward "^[^:]+: *" nil t)
 191             (cond
 192              ((eq method 'address-mime)
 193               (rfc2047-encode-region (point) (point-max)))
 194              ((eq method 'mime)
 195               (let ((rfc2047-encoding-type 'mime))
 196                 (rfc2047-encode-region (point) (point-max))))
 197              ((eq method 'default)
 198               (if (and (featurep 'mule)
 199                        (if (boundp 'default-enable-multibyte-characters)
 200                            default-enable-multibyte-characters)
 201                        mail-parse-charset)
 202                   (mm-encode-coding-region (point) (point-max)
 203                                            mail-parse-charset)))
 204              ;; We get this when CC'ing messsages to newsgroups with
 205              ;; 8-bit names.  The group name mail copy just got
 206              ;; unconditionally encoded.  Previously, it would ask
 207              ;; whether to encode, which was quite confusing for the
 208              ;; user.  If the new behaviour is wrong, tell me. I have
 209              ;; left the old code commented out below.
 210              ;; -- Per Abrahamsen <abraham@dina.kvl.dk> Date: 2001-10-07.
 211              ;; Modified by Dave Love, with the commented-out code changed
 212              ;; in accordance with changes elsewhere.
 213              ((null method)
 214               (rfc2047-encode-region (point) (point-max)))
 215 ;;;          ((null method)
 216 ;;;           (if (or (message-options-get
 217 ;;;                    'rfc2047-encode-message-header-encode-any)
 218 ;;;                   (message-options-set
 219 ;;;                    'rfc2047-encode-message-header-encode-any
 220 ;;;                    (y-or-n-p
 221 ;;;                     "Some texts are not encoded. Encode anyway?")))
 222 ;;;               (rfc2047-encode-region (point-min) (point-max))
 223 ;;;             (error "Cannot send unencoded text")))
 224              ((mm-coding-system-p method)
 225               (if (and (featurep 'mule)
 226                        (if (boundp 'default-enable-multibyte-characters)
 227                            default-enable-multibyte-characters))
 228                   (mm-encode-coding-region (point) (point-max) method)))
 229              ;; Hm.
 230              (t)))
 231           (goto-char (point-max)))))))
 232
 233 ;; Fixme: This, and the require below may not be the Right Thing, but
 234 ;; should be safe just before release.  -- fx 2001-02-08
 235 (eval-when-compile (defvar message-posting-charset))
 236
 237 (defun rfc2047-encodable-p ()
 238   "Return non-nil if any characters in current buffer need encoding in headers.
 239 The buffer may be narrowed."
 240   (require 'message)                    ; for message-posting-charset
 241   (let ((charsets
 242          (mm-find-mime-charset-region (point-min) (point-max))))
 243     (goto-char (point-min))
 244     (or (and rfc2047-encode-encoded-words
 245              (prog1
 246                  (search-forward "=?" nil t)
 247                (goto-char (point-min))))
 248         (and charsets
 249              (not (equal charsets (list (car message-posting-charset))))))))
 250
 251 ;; Use this syntax table when parsing into regions that may need
 252 ;; encoding.  Double quotes are string delimiters, backslash is
 253 ;; character quoting, and all other RFC 2822 special characters are
 254 ;; treated as punctuation so we can use forward-sexp/forward-word to
 255 ;; skip to the end of regions appropriately.  Nb. ietf-drums does
 256 ;; things differently.
 257 (defconst rfc2047-syntax-table
 258   ;; (make-char-table 'syntax-table '(2)) only works in Emacs.
 259   (let ((table (make-syntax-table)))
 260     ;; The following is done to work for setting all elements of the table
 261     ;; in Emacs 21 and 22 and XEmacs; it appears to be the cleanest way.
 262     ;; Play safe and don't assume the form of the word syntax entry --
 263     ;; copy it from ?a.
 264     (if (fboundp 'set-char-table-range) ; Emacs
 265         (funcall (intern "set-char-table-range")
 266                  table t (aref (standard-syntax-table) ?a))
 267       (if (fboundp 'put-char-table)
 268           (if (fboundp 'get-char-table) ; warning avoidance
 269               (put-char-table t (get-char-table ?a (standard-syntax-table))
 270                               table))))
 271     (modify-syntax-entry ?\\ "\\" table)
 272     (modify-syntax-entry ?\" "\"" table)
 273     (modify-syntax-entry ?\( "(" table)
 274     (modify-syntax-entry ?\) ")" table)
 275     (modify-syntax-entry ?\< "." table)
 276     (modify-syntax-entry ?\> "." table)
 277     (modify-syntax-entry ?\[ "." table)
 278     (modify-syntax-entry ?\] "." table)
 279     (modify-syntax-entry ?: "." table)
 280     (modify-syntax-entry ?\; "." table)
 281     (modify-syntax-entry ?, "." table)
 282     (modify-syntax-entry ?@ "." table)
 283     table))
 284
 285 (defun rfc2047-encode-region (b e)
 286   "Encode words in region B to E that need encoding.
 287 By default, the region is treated as containing RFC2822 addresses.
 288 Dynamically bind `rfc2047-encoding-type' to change that."
 289   (save-restriction
 290     (narrow-to-region b e)
 291     (let ((encodable-regexp (if rfc2047-encode-encoded-words
 292                                 "[^\000-\177]+\\|=\\?"
 293                               "[^\000-\177]+"))
 294           start                         ; start of current token
 295           end begin csyntax
 296           ;; Whether there's an encoded word before the current token,
 297           ;; either immediately or separated by space.
 298           last-encoded
 299           (orig-text (buffer-substring-no-properties b e)))
 300       (if (eq 'mime rfc2047-encoding-type)
 301           ;; Simple case.  Continuous words in which all those contain
 302           ;; non-ASCII characters are encoded collectively.  Encoding
 303           ;; ASCII words, including `Re:' used in Subject headers, is
 304           ;; avoided for interoperability with non-MIME clients and
 305           ;; for making it easy to find keywords.
 306           (progn
 307             (goto-char (point-min))
 308             (while (progn (skip-chars-forward " \t\n")
 309                           (not (eobp)))
 310               (setq start (point))
 311               (while (and (looking-at "[ \t\n]*\\([^ \t\n]+\\)")
 312                           (progn
 313                             (setq end (match-end 0))
 314                             (re-search-forward encodable-regexp end t)))
 315                 (goto-char end))
 316               (if (> (point) start)
 317                   (rfc2047-encode start (point))
 318                 (goto-char end))))
 319         ;; `address-mime' case -- take care of quoted words, comments.
 320         (with-syntax-table rfc2047-syntax-table
 321           (goto-char (point-min))
 322           (condition-case nil           ; in case of unbalanced quotes
 323               ;; Look for rfc2822-style: sequences of atoms, quoted
 324               ;; strings, specials, whitespace.  (Specials mustn't be
 325               ;; encoded.)
 326               (while (not (eobp))
 327                 ;; Skip whitespace.
 328                 (skip-chars-forward " \t\n")
 329                 (setq start (point))
 330                 (cond
 331                  ((not (char-after)))   ; eob
 332                  ;; else token start
 333                  ((eq ?\" (setq csyntax (char-syntax (char-after))))
 334                   ;; Quoted word.
 335                   (forward-sexp)
 336                   (setq end (point))
 337                   ;; Does it need encoding?
 338                   (goto-char start)
 339                   (if (re-search-forward encodable-regexp end 'move)
 340                       ;; It needs encoding.  Strip the quotes first,
 341                       ;; since encoded words can't occur in quotes.
 342                       (progn
 343                         (goto-char end)
 344                         (delete-backward-char 1)
 345                         (goto-char start)
 346                         (delete-char 1)
 347                         (when last-encoded
 348                           ;; There was a preceding quoted word.  We need
 349                           ;; to include any separating whitespace in this
 350                           ;; word to avoid it getting lost.
 351                           (skip-chars-backward " \t")
 352                           ;; A space is needed between the encoded words.
 353                           (insert ? )
 354                           (setq start (point)
 355                                 end (1+ end)))
 356                         ;; Adjust the end position for the deleted quotes.
 357                         (rfc2047-encode start (- end 2))
 358                         (setq last-encoded t)) ; record that it was encoded
 359                     (setq last-encoded  nil)))
 360                  ((eq ?. csyntax)
 361                   ;; Skip other delimiters, but record that they've
 362                   ;; potentially separated quoted words.
 363                   (forward-char)
 364                   (setq last-encoded nil))
 365                  ((eq ?\) csyntax)
 366                   (error "Unbalanced parentheses"))
 367                  ((eq ?\( csyntax)
 368                   ;; Look for the end of parentheses.
 369                   (forward-list)
 370                   ;; Encode text as an unstructured field.
 371                   (let ((rfc2047-encoding-type 'mime))
 372                     (rfc2047-encode-region (1+ start) (1- (point)))
 373                     (forward-char)))
 374                  (t                 ; normal token/whitespace sequence
 375                   ;; Find the end.
 376                   ;; Skip one ASCII word, or encode continuous words
 377                   ;; in which all those contain non-ASCII characters.
 378                   (setq end nil)
 379                   (while (not end)
 380                     (when (looking-at "[\000-\177]+")
 381                       (setq begin (point)
 382                             end (match-end 0))
 383                       (if (progn
 384                             (while (and (re-search-forward "[ \t\n]\\|\\Sw"
 385                                                            end 'move)
 386                                         (eq ?\\ (char-syntax (char-before))))
 387                               ;; Skip backslash-quoted characters.
 388                               (forward-char))
 389                             (< (point) end))
 390                           (progn
 391                             (setq end (match-beginning 0))
 392                             (if rfc2047-encode-encoded-words
 393                                 (progn
 394                                   (goto-char begin)
 395                                   (when (search-forward "=?" end 'move)
 396                                     (goto-char (match-beginning 0))
 397                                     (setq end nil)))
 398                               (goto-char end)))
 399                         (setq end nil)))
 400                     (unless end
 401                       (setq end t)
 402                       (when (looking-at encodable-regexp)
 403                         (goto-char (match-end 0))
 404                         (while (and (looking-at "[ \t\n]+\\([^ \t\n]+\\)")
 405                                     (setq end (match-end 0))
 406                                     (string-match encodable-regexp
 407                                                   (match-string 1)))
 408                           (goto-char end))
 409                         (when (looking-at "[^ \t\n]+")
 410                           (setq end (match-end 0))
 411                           (if (re-search-forward "\\Sw+" end t)
 412                               ;; There are special characters better
 413                               ;; to be encoded so that MTAs may parse
 414                               ;; them safely.
 415                               (cond ((= end (point)))
 416                                     ((looking-at encodable-regexp)
 417                                      (setq end nil))
 418                                     (t
 419                                      (goto-char (1- (match-end 0)))
 420                                      (unless (= (point) (match-beginning 0))
 421                                        (insert " "))))
 422                             (goto-char end)
 423                             (skip-chars-forward " \t\n")
 424                             (if (and (looking-at "[^ \t\n]+")
 425                                      (string-match encodable-regexp
 426                                                    (match-string 0)))
 427                                 (setq end nil)
 428                               (goto-char end)))))))
 429                   (skip-chars-backward " \t\n")
 430                   (setq end (point))
 431                   (goto-char start)
 432                   (if (re-search-forward encodable-regexp end 'move)
 433                       (progn
 434                         (rfc2047-encode start end)
 435                         (setq last-encoded t))
 436                     (setq last-encoded nil)))))
 437             (error
 438              (error "Invalid data for rfc2047 encoding: %s"
 439                     (mm-replace-in-string orig-text "[ \t\n]+" " ")))))))
 440     (rfc2047-fold-region b (point))
 441     (goto-char (point-max))))
 442
 443 (defun rfc2047-encode-string (string)
 444   "Encode words in STRING.
 445 By default, the string is treated as containing addresses (see
 446 `rfc2047-encoding-type')."
 447   (mm-with-multibyte-buffer
 448     (insert string)
 449     (rfc2047-encode-region (point-min) (point-max))
 450     (buffer-string)))
 451
 452 (defun rfc2047-encode-1 (column string cs encoder start space &optional eword)
 453   "Subroutine used by `rfc2047-encode'."
 454   (cond ((string-equal string "")
 455          (or eword ""))
 456         ((>= column 76)
 457          (when (and eword
 458                     (string-match "\n[ \t]+\\'" eword))
 459            ;; Reomove a superfluous empty line.
 460            (setq eword (substring eword 0 (match-beginning 0))))
 461          (rfc2047-encode-1 (length space) string cs encoder start " "
 462                            (concat eword "\n" space)))
 463         (t
 464          (let ((index 0)
 465                (limit (1- (length string)))
 466                (prev "")
 467                next)
 468            (while (and prev
 469                        (<= index limit))
 470              (setq next (concat start
 471                                 (funcall encoder
 472                                          (if cs
 473                                              (mm-encode-coding-string
 474                                               (substring string 0 (1+ index))
 475                                               cs)
 476                                            (substring string 0 (1+ index))))
 477                                 "?="))
 478              (if (<= (+ column (length next)) 76)
 479                  (setq prev next
 480                        index (1+ index))
 481                (setq next prev
 482                      prev nil)))
 483            (setq eword (concat eword next))
 484            (if (> index limit)
 485                eword
 486              (when (string-match "\n[ \t]+\\'" eword)
 487                ;; Reomove a superfluous empty line.
 488                (setq eword (substring eword 0 (match-beginning 0))))
 489              (rfc2047-encode-1 (length space) (substring string index)
 490                                cs encoder start " "
 491                                (concat eword "\n" space)))))))
 492
 493 (defun rfc2047-encode (b e)
 494   "Encode the word(s) in the region B to E.
 495 Point moves to the end of the region."
 496   (let ((mime-charset (or (mm-find-mime-charset-region b e) (list 'us-ascii)))
 497         cs encoding space eword)
 498     (cond ((> (length mime-charset) 1)
 499            (error "Can't rfc2047-encode `%s'"
 500                   (buffer-substring-no-properties b e)))
 501           ((= (length mime-charset) 1)
 502            (setq mime-charset (car mime-charset)
 503                  cs (mm-charset-to-coding-system mime-charset))
 504            (unless (and (mm-multibyte-p)
 505                         (mm-coding-system-p cs))
 506              (setq cs nil))
 507            (save-restriction
 508              (narrow-to-region b e)
 509              (setq encoding
 510                    (or (cdr (assq mime-charset
 511                                   rfc2047-charset-encoding-alist))
 512                        ;; For the charsets that don't have a preferred
 513                        ;; encoding, choose the one that's shorter.
 514                        (if (eq (rfc2047-qp-or-base64) 'base64)
 515                            'B
 516                          'Q)))
 517              (widen)
 518              (goto-char b)
 519              (setq b (point-marker)
 520                    e (set-marker (make-marker) e))
 521              (rfc2047-fold-region (point-at-bol) b)
 522              (unless (= 0 (skip-chars-backward " \t"))
 523                (setq space (buffer-substring-no-properties (point) b)))
 524              (setq eword (rfc2047-encode-1
 525                           (- b (point-at-bol))
 526                           (mm-replace-in-string
 527                            (buffer-substring-no-properties b e)
 528                            "\n\\([ \t]?\\)" "\\1")
 529                           cs
 530                           (or (cdr (assq encoding
 531                                          rfc2047-encode-function-alist))
 532                               'identity)
 533                           (concat "=?" (downcase (symbol-name mime-charset))
 534                                   "?" (upcase (symbol-name encoding)) "?")
 535                           (or space " ")))
 536              (delete-region (if (eq (aref eword 0) ?\n)
 537                                 (point)
 538                               (goto-char b))
 539                             e)
 540              (insert eword)
 541              (set-marker b nil)
 542              (set-marker e nil)
 543              (unless (or (eolp)
 544                          (looking-at "[ \t\n)]"))
 545                (insert " "))))
 546           (t
 547            (goto-char e)))))
 548
 549 (defun rfc2047-fold-field ()
 550   "Fold the current header field."
 551   (save-excursion
 552     (save-restriction
 553       (rfc2047-narrow-to-field)
 554       (rfc2047-fold-region (point-min) (point-max)))))
 555
 556 (defun rfc2047-fold-region (b e)
 557   "Fold long lines in region B to E."
 558   (save-restriction
 559     (narrow-to-region b e)
 560     (goto-char (point-min))
 561     (let ((break nil)
 562           (qword-break nil)
 563           (first t)
 564           (bol (save-restriction
 565                  (widen)
 566                  (point-at-bol))))
 567       (while (not (eobp))
 568         (when (and (or break qword-break)
 569                    (> (- (point) bol) 76))
 570           (goto-char (or break qword-break))
 571           (setq break nil
 572                 qword-break nil)
 573           (skip-chars-backward " \t")
 574           (if (looking-at "[ \t]")
 575               (insert ?\n)
 576             (insert "\n "))
 577           (setq bol (1- (point)))
 578           ;; Don't break before the first non-LWSP characters.
 579           (skip-chars-forward " \t")
 580           (unless (eobp)
 581             (forward-char 1)))
 582         (cond
 583          ((eq (char-after) ?\n)
 584           (forward-char 1)
 585           (setq bol (point)
 586                 break nil
 587                 qword-break nil)
 588           (skip-chars-forward " \t")
 589           (unless (or (eobp) (eq (char-after) ?\n))
 590             (forward-char 1)))
 591          ((eq (char-after) ?\r)
 592           (forward-char 1))
 593          ((memq (char-after) '(?  ?\t))
 594           (skip-chars-forward " \t")
 595           (unless first ;; Don't break just after the header name.
 596             (setq break (point))))
 597          ((not break)
 598           (if (not (looking-at "=\\?[^=]"))
 599               (if (eq (char-after) ?=)
 600                   (forward-char 1)
 601                 (skip-chars-forward "^ \t\n\r="))
 602             ;; Don't break at the start of the field.
 603             (unless (= (point) b)
 604               (setq qword-break (point)))
 605             (skip-chars-forward "^ \t\n\r")))
 606          (t
 607           (skip-chars-forward "^ \t\n\r")))
 608         (setq first nil))
 609       (when (and (or break qword-break)
 610                  (> (- (point) bol) 76))
 611         (goto-char (or break qword-break))
 612         (setq break nil
 613               qword-break nil)
 614           (if (looking-at "[ \t]")
 615               (insert ?\n)
 616             (insert "\n "))
 617         (setq bol (1- (point)))
 618         ;; Don't break before the first non-LWSP characters.
 619         (skip-chars-forward " \t")
 620         (unless (eobp)
 621           (forward-char 1))))))
 622
 623 (defun rfc2047-unfold-field ()
 624   "Fold the current line."
 625   (save-excursion
 626     (save-restriction
 627       (rfc2047-narrow-to-field)
 628       (rfc2047-unfold-region (point-min) (point-max)))))
 629
 630 (defun rfc2047-unfold-region (b e)
 631   "Unfold lines in region B to E."
 632   (save-restriction
 633     (narrow-to-region b e)
 634     (goto-char (point-min))
 635     (let ((bol (save-restriction
 636                  (widen)
 637                  (point-at-bol)))
 638           (eol (point-at-eol)))
 639       (forward-line 1)
 640       (while (not (eobp))
 641         (if (and (looking-at "[ \t]")
 642                  (< (- (point-at-eol) bol) 76))
 643             (delete-region eol (progn
 644                                  (goto-char eol)
 645                                  (skip-chars-forward "\r\n")
 646                                  (point)))
 647           (setq bol (point-at-bol)))
 648         (setq eol (point-at-eol))
 649         (forward-line 1)))))
 650
 651 (defun rfc2047-b-encode-string (string)
 652   "Base64-encode the header contained in STRING."
 653   (base64-encode-string string t))
 654
 655 (defun rfc2047-q-encode-string (string)
 656   "Quoted-printable-encode the header in STRING."
 657   (mm-with-unibyte-buffer
 658     (insert string)
 659     (quoted-printable-encode-region
 660      (point-min) (point-max) nil
 661      ;; = (\075), _ (\137), ? (\077) are used in the encoded word.
 662      ;; Avoid using 8bit characters.
 663      ;; This list excludes `especials' (see the RFC2047 syntax),
 664      ;; meaning that some characters in non-structured fields will
 665      ;; get encoded when they con't need to be.  The following is
 666      ;; what it used to be.
 667      ;;;  ;; Equivalent to "^\000-\007\011\013\015-\037\200-\377=_?"
 668      ;;;  "\010\012\014\040-\074\076\100-\136\140-\177")
 669      "-\b\n\f !#-'*+0-9A-Z\\^`-~\d")
 670     (subst-char-in-region (point-min) (point-max) ?  ?_)
 671     (buffer-string)))
 672
 673 ;;;
 674 ;;; Functions for decoding RFC2047 messages
 675 ;;;
 676
 677 (eval-and-compile
 678   (defconst rfc2047-encoded-word-regexp
 679     "=\\?\\([^][\000-\040()<>@,\;:*\\\"/?.=]+\\)\\(?:\\*[^?]+\\)?\
 680 \\?\\(B\\|Q\\)\\?\\([!->@-~ ]*\\)\\?="))
 681
 682 ;; Fixme: This should decode in place, not cons intermediate strings.
 683 ;; Also check whether it needs to worry about delimiting fields like
 684 ;; encoding.
 685
 686 ;; In fact it's reported that (invalid) encoding of mailboxes in
 687 ;; addr-specs is in use, so delimiting fields might help.  Probably
 688 ;; not decoding a word which isn't properly delimited is good enough
 689 ;; and worthwhile (is it more correct or not?), e.g. something like
 690 ;; `=?iso-8859-1?q?foo?=@'.
 691
 692 (defun rfc2047-decode-region (start end)
 693   "Decode MIME-encoded words in region between START and END."
 694   (interactive "r")
 695   (let ((case-fold-search t)
 696         b e)
 697     (save-excursion
 698       (save-restriction
 699         (narrow-to-region start end)
 700         (goto-char (point-min))
 701         ;; Remove whitespace between encoded words.
 702         (while (re-search-forward
 703                 (eval-when-compile
 704                   (concat "\\(" rfc2047-encoded-word-regexp "\\)"
 705                           "\\(\n?[ \t]\\)+"
 706                           "\\(" rfc2047-encoded-word-regexp "\\)"))
 707                 nil t)
 708           (delete-region (goto-char (match-end 1)) (match-beginning 6)))
 709         ;; Decode the encoded words.
 710         (setq b (goto-char (point-min)))
 711         (while (re-search-forward rfc2047-encoded-word-regexp nil t)
 712           (setq e (match-beginning 0))
 713           (insert (rfc2047-parse-and-decode
 714                    (prog1
 715                        (match-string 0)
 716                      (delete-region (match-beginning 0) (match-end 0)))))
 717           ;; Remove newlines between decoded words, though such things
 718           ;; essentially must not be there.
 719           (save-restriction
 720             (narrow-to-region e (point))
 721             (goto-char e)
 722             (while (re-search-forward "[\n\r]+" nil t)
 723               (replace-match " "))
 724             (goto-char (point-max)))
 725           (when (and (mm-multibyte-p)
 726                      mail-parse-charset
 727                      (not (eq mail-parse-charset 'us-ascii))
 728                      (not (eq mail-parse-charset 'gnus-decoded)))
 729             (mm-decode-coding-region b e mail-parse-charset))
 730           (setq b (point)))
 731         (when (and (mm-multibyte-p)
 732                    mail-parse-charset
 733                    (not (eq mail-parse-charset 'us-ascii))
 734                    (not (eq mail-parse-charset 'gnus-decoded)))
 735           (mm-decode-coding-region b (point-max) mail-parse-charset))))))
 736
 737 (defun rfc2047-decode-string (string)
 738   "Decode the quoted-printable-encoded STRING and return the results."
 739   (let ((m (mm-multibyte-p)))
 740     (if (string-match "=\\?" string)
 741         (with-temp-buffer
 742           ;; Fixme: This logic is wrong, but seems to be required by
 743           ;; Gnus summary buffer generation.  The value of `m' depends
 744           ;; on the current buffer, not global multibyteness or that
 745           ;; of the string.  Also the string returned should always be
 746           ;; multibyte in a multibyte session, i.e. the buffer should
 747           ;; be multibyte before `buffer-string' is called.
 748           (when m
 749             (mm-enable-multibyte))
 750           (insert string)
 751           (inline
 752             (rfc2047-decode-region (point-min) (point-max)))
 753           (buffer-string))
 754       ;; Fixme: As above, `m' here is inappropriate.
 755       (if (and m
 756                mail-parse-charset
 757                (not (eq mail-parse-charset 'us-ascii))
 758                (not (eq mail-parse-charset 'gnus-decoded)))
 759           ;; `decode-coding-string' in Emacs offers a third optional
 760           ;; arg NOCOPY to avoid consing a new string if the decoding
 761           ;; is "trivial".  Unfortunately it currently doesn't
 762           ;; consider anything else than a `nil' coding system
 763           ;; trivial.
 764           ;; `rfc2047-decode-string' is called multiple times for each
 765           ;; article during summary buffer generation, and we really
 766           ;; want to avoid unnecessary consing.  So we bypass
 767           ;; `decode-coding-string' if the string is purely ASCII.
 768           (if (and (fboundp 'detect-coding-string)
 769                    ;; string is purely ASCII
 770                    (eq (detect-coding-string string t) 'undecided))
 771               string
 772             (mm-decode-coding-string string mail-parse-charset))
 773         (mm-string-as-multibyte string)))))
 774
 775 (defun rfc2047-parse-and-decode (word)
 776   "Decode WORD and return it if it is an encoded word.
 777 Return WORD if it is not not an encoded word or if the charset isn't
 778 decodable."
 779   (if (not (string-match rfc2047-encoded-word-regexp word))
 780       word
 781     (or
 782      (condition-case nil
 783          (rfc2047-decode
 784           (match-string 1 word)
 785           (string-to-char (match-string 2 word))
 786           (match-string 3 word))
 787        (error word))
 788      word)))                            ; un-decodable
 789
 790 (defun rfc2047-pad-base64 (string)
 791   "Pad STRING to quartets."
 792   ;; Be more liberal to accept buggy base64 strings. If
 793   ;; base64-decode-string accepts buggy strings, this function could
 794   ;; be aliased to identity.
 795   (if (= 0 (mod (length string) 4))
 796       string
 797     (when (string-match "=+$" string)
 798       (setq string (substring string 0 (match-beginning 0))))
 799     (case (mod (length string) 4)
 800       (0 string)
 801       (1 string) ;; Error, don't pad it.
 802       (2 (concat string "=="))
 803       (3 (concat string "=")))))
 804
 805 (defun rfc2047-decode (charset encoding string)
 806   "Decode STRING from the given MIME CHARSET in the given ENCODING.
 807 Valid ENCODINGs are the characters \"B\" and \"Q\".
 808 If your Emacs implementation can't decode CHARSET, return nil."
 809   (if (stringp charset)
 810       (setq charset (intern (downcase charset))))
 811   (if (or (not charset)
 812           (eq 'gnus-all mail-parse-ignored-charsets)
 813           (memq 'gnus-all mail-parse-ignored-charsets)
 814           (memq charset mail-parse-ignored-charsets))
 815       (setq charset mail-parse-charset))
 816   (let ((cs (mm-charset-to-coding-system charset)))
 817     (if (and (not cs) charset
 818              (listp mail-parse-ignored-charsets)
 819              (memq 'gnus-unknown mail-parse-ignored-charsets))
 820         (setq cs (mm-charset-to-coding-system mail-parse-charset)))
 821     (when cs
 822       (when (eq cs 'ascii)
 823         (setq cs (or mail-parse-charset 'raw-text)))
 824       (mm-decode-coding-string
 825        (cond
 826         ((char-equal ?B encoding)
 827          (base64-decode-string
 828           (rfc2047-pad-base64 string)))
 829         ((char-equal ?Q encoding)
 830          (quoted-printable-decode-string
 831           (mm-subst-char-in-string ?_ ? string t)))
 832         (t (error "Invalid encoding: %c" encoding)))
 833        cs))))
 834
 835 (provide 'rfc2047)
 836
 837 ;;; arch-tag: a07fe3d4-22b5-4c4a-bd89-b1f82d5d36f6
 838 ;;; rfc2047.el ends here