cgit.sxemacs.org Git - gnus/blob - lisp/proto-stream.el

   1 ;;; proto-stream.el --- negotiating TLS, STARTTLS and other connections
   2
   3 ;; Copyright (C) 2010-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: network
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This library is meant to provide the glue between modules that want
  26 ;; to establish a network connection to a server for protocols such as
  27 ;; IMAP, NNTP, SMTP and POP3.
  28
  29 ;; The main problem is that there's more than a couple of interfaces
  30 ;; towards doing this.  You have normal, plain connections, which are
  31 ;; no trouble at all, but you also have TLS/SSL connections, and you
  32 ;; have STARTTLS.  Negotiating this for each protocol can be rather
  33 ;; tedious, so this library provides a single entry point, and hides
  34 ;; much of the ugliness.
  35
  36 ;; Usage example:
  37
  38 ;; (open-protocol-stream
  39 ;;  "*nnimap*" buffer address port
  40 ;;  :type 'network
  41 ;;  :capability-command "1 CAPABILITY\r\n"
  42 ;;  :success " OK "
  43 ;;  :starttls-function
  44 ;;  (lambda (capabilities)
  45 ;;    (if (not (string-match "STARTTLS" capabilities))
  46 ;;        nil
  47 ;;      "1 STARTTLS\r\n")))
  48
  49 ;;; Code:
  50
  51 (require 'tls)
  52 (require 'starttls)
  53
  54 (autoload 'gnutls-negotiate "gnutls")
  55 (autoload 'open-gnutls-stream "gnutls")
  56
  57 ;;;###autoload
  58 (defun open-protocol-stream (name buffer host service &rest parameters)
  59   "Open a network stream to HOST, possibly with encryption.
  60 Normally, return a network process object; with a non-nil
  61 :return-list parameter, return a list instead (see below).
  62
  63 The first four parameters, NAME, BUFFER, HOST, and SERVICE, have
  64 the same meanings as in `open-network-stream'.  The remaining
  65 PARAMETERS should be a sequence of keywords and values:
  66
  67 :type specifies the connection type, one of the following:
  68   nil or `network'
  69              -- Begin with an ordinary network connection, and if
  70                 the parameters :success and :capability-command
  71                 are also supplied, try to upgrade to an encrypted
  72                 connection via STARTTLS.  Even if that
  73                 fails (e.g. if HOST does not support TLS), retain
  74                 an unencrypted connection.
  75   `plain'    -- An ordinary, unencrypted network connection.
  76   `starttls' -- Begin with an ordinary connection, and try
  77                 upgrading via STARTTLS.  If that fails for any
  78                 reason, drop the connection; in that case the
  79                 returned object is a killed process.
  80   `tls'      -- A TLS connection.
  81   `ssl'      -- Equivalent to `tls'.
  82   `shell'    -- A shell connection.
  83
  84 :return-list specifies this function's return value.
  85   If omitted or nil, return a process object.  A non-nil means to
  86   return (PROC . PROPS), where PROC is a process object and PROPS
  87   is a plist of connection properties, with these keywords:
  88    :greeting -- the greeting returned by HOST (a string), or nil.
  89    :capabilities -- a string representing HOST's capabilities,
  90                     or nil if none could be found.
  91    :type -- the resulting connection type; `plain' (unencrypted)
  92             or `tls' (TLS-encrypted).
  93
  94 :end-of-command specifies a regexp matching the end of a command.
  95   If non-nil, it defaults to \"\\n\".
  96
  97 :success specifies a regexp matching a message indicating a
  98   successful STARTTLS negotiation.  For instance, the default
  99   should be \"^3\" for an NNTP connection.
 100
 101 :capability-command specifies a command used to query the HOST
 102   for its capabilities.  For instance, for IMAP this should be
 103   \"1 CAPABILITY\\r\\n\".
 104
 105 :starttls-function specifies a function for handling STARTTLS.
 106   This function should take one parameter, the response to the
 107   capability command, and should return the command to switch on
 108   STARTTLS if the server supports STARTTLS, and nil otherwise."
 109   (let ((type (plist-get parameters :type))
 110         (return-list (plist-get parameters :return-list)))
 111     (if (and (not return-list)
 112              (or (eq type 'plain)
 113                  (and (memq type '(nil network))
 114                       (not (and (plist-get parameters :success)
 115                                 (plist-get parameters :capability-command))))))
 116         ;; The simplest case is equivalent to `open-network-stream'.
 117         (open-network-stream name buffer host service)
 118       ;; For everything else, refer to proto-stream-open-*.
 119       (unless (plist-get parameters :end-of-command)
 120         (setq parameters (append '(:end-of-command "\r\n") parameters)))
 121       (let* ((connection-function
 122               (cond
 123                ((eq type 'plain) 'proto-stream-open-plain)
 124                ((memq type '(nil network starttls))
 125                 'proto-stream-open-starttls)
 126                ((memq type '(tls ssl)) 'proto-stream-open-tls)
 127                ((eq type 'shell) 'proto-stream-open-shell)
 128                (t (error "Invalid connection type %s" type))))
 129              (result (funcall connection-function
 130                               name buffer host service parameters)))
 131         (if return-list
 132             (list (car result)
 133                   :greeting     (nth 1 result)
 134                   :capabilities (nth 2 result)
 135                   :type         (nth 3 result))
 136           (car result))))))
 137
 138 (defun proto-stream-open-plain (name buffer host service parameters)
 139   (let ((start (with-current-buffer buffer (point)))
 140         (stream (open-network-stream name buffer host service)))
 141     (list stream
 142           (proto-stream-get-response stream start
 143                                      (plist-get parameters :end-of-command))
 144           nil
 145           'plain)))
 146
 147 (defun proto-stream-open-starttls (name buffer host service parameters)
 148   (let* ((start (with-current-buffer buffer (point)))
 149          (require-tls    (eq (plist-get parameters :type) 'starttls))
 150          (starttls-function  (plist-get parameters :starttls-function))
 151          (success-string     (plist-get parameters :success))
 152          (capability-command (plist-get parameters :capability-command))
 153          (eoc                (plist-get parameters :end-of-command))
 154          ;; Return (STREAM GREETING CAPABILITIES RESULTING-TYPE)
 155          (stream (open-network-stream name buffer host service))
 156          (greeting (proto-stream-get-response stream start eoc))
 157          (capabilities (when capability-command
 158                          (proto-stream-command stream
 159                                                capability-command eoc)))
 160          (resulting-type 'plain)
 161          (builtin-starttls (and (fboundp 'gnutls-available-p)
 162                                 (gnutls-available-p)))
 163          starttls-command)
 164
 165     ;; If we have built-in STARTTLS support, try to upgrade the
 166     ;; connection.
 167     (when (and (or builtin-starttls
 168                    (and require-tls
 169                         (executable-find "gnutls-cli")))
 170                capabilities success-string starttls-function
 171                (setq starttls-command
 172                      (funcall starttls-function capabilities)))
 173       ;; If using external STARTTLS, drop this connection and start
 174       ;; anew with `starttls-open-stream'.
 175       (unless builtin-starttls
 176         (delete-process stream)
 177         (setq start (with-current-buffer buffer (point-max)))
 178         (let* ((starttls-use-gnutls t)
 179                (starttls-extra-arguments
 180                 (if require-tls
 181                     starttls-extra-arguments
 182                   ;; For opportunistic TLS upgrades, we don't really
 183                   ;; care about the identity of the peer.
 184                   (cons "--insecure" starttls-extra-arguments))))
 185           (setq stream (starttls-open-stream name buffer host service)))
 186         (proto-stream-get-response stream start eoc))
 187       (when (string-match success-string
 188                           (proto-stream-command stream starttls-command eoc))
 189         ;; The server said it was OK to begin STARTTLS negotiations.
 190         (if builtin-starttls
 191             (gnutls-negotiate :process stream :hostname host)
 192           (unless (starttls-negotiate stream)
 193             (delete-process stream)))
 194         (if (memq (process-status stream) '(open run))
 195             (setq resulting-type 'tls)
 196           ;; We didn't successfully negotiate STARTTLS; if TLS
 197           ;; isn't demanded, reopen an unencrypted connection.
 198           (unless require-tls
 199             (setq stream (open-network-stream name buffer host service))
 200             (proto-stream-get-response stream start eoc)))
 201         ;; Re-get the capabilities, which may have now changed.
 202         (setq capabilities
 203               (proto-stream-command stream capability-command eoc))))
 204
 205     ;; If TLS is mandatory, close the connection if it's unencrypted.
 206     (and require-tls
 207          (eq resulting-type 'plain)
 208          (delete-process stream))
 209     ;; Return value:
 210     (list stream greeting capabilities resulting-type)))
 211
 212 (defun proto-stream-command (stream command eoc)
 213   (let ((start (with-current-buffer (process-buffer stream) (point-max))))
 214     (process-send-string stream command)
 215     (proto-stream-get-response stream start eoc)))
 216
 217 (defun proto-stream-get-response (stream start end-of-command)
 218   (with-current-buffer (process-buffer stream)
 219     (save-excursion
 220       (goto-char start)
 221       (while (and (memq (process-status stream)
 222                         '(open run))
 223                   (not (re-search-forward end-of-command nil t)))
 224         (accept-process-output stream 0 50)
 225         (goto-char start))
 226       (if (= start (point))
 227           ;; The process died; return nil.
 228           nil
 229         ;; Return the data we got back.
 230         (buffer-substring start (point))))))
 231
 232 (defun proto-stream-open-tls (name buffer host service parameters)
 233   (with-current-buffer buffer
 234     (let* ((start (point-max))
 235            (builtin-starttls (and (fboundp 'gnutls-available-p)
 236                                   (gnutls-available-p)))
 237            (stream
 238             (funcall (if builtin-starttls
 239                          'open-gnutls-stream
 240                        'open-tls-stream)
 241                      name buffer host service))
 242            (eoc (plist-get parameters :end-of-command)))
 243       (if (null stream)
 244           (list nil nil nil 'plain)
 245         ;; If we're using tls.el, we have to delete the output from
 246         ;; openssl/gnutls-cli.
 247         (unless builtin-starttls
 248           (proto-stream-get-response stream start eoc)
 249           (goto-char (point-min))
 250           (when (re-search-forward eoc nil t)
 251             (goto-char (match-beginning 0))
 252             (delete-region (point-min) (line-beginning-position))))
 253         (proto-stream-capability-open start stream parameters 'tls)))))
 254
 255 (defun proto-stream-open-shell (name buffer host service parameters)
 256   (require 'format-spec)
 257   (proto-stream-capability-open
 258    (with-current-buffer buffer (point))
 259    (let ((process-connection-type nil))
 260      (start-process name buffer shell-file-name
 261                     shell-command-switch
 262                     (format-spec
 263                      (plist-get parameters :shell-command)
 264                      (format-spec-make
 265                       ?s host
 266                       ?p service))))
 267    parameters 'plain))
 268
 269 (defun proto-stream-capability-open (start stream parameters stream-type)
 270   (let* ((capability-command (plist-get parameters :capability-command))
 271          (eoc                (plist-get parameters :end-of-command))
 272          (greeting (proto-stream-get-response stream start eoc)))
 273     (list stream greeting
 274           (and capability-command
 275                (proto-stream-command stream capability-command eoc))
 276           stream-type)))
 277
 278 (provide 'proto-stream)
 279
 280 ;;; proto-stream.el ends here