cgit.sxemacs.org Git - gnus/blob - lisp/nnweb.el

   1 ;;; nnweb.el --- retrieving articles via web search engines
   2 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; Note: You need to have `url' and `w3' installed for this
  27 ;; backend to work.
  28
  29 ;;; Code:
  30
  31 (require 'nnoo)
  32 (require 'message)
  33 (require 'gnus-util)
  34 (require 'w3)
  35 (require 'url)
  36 (condition-case ()
  37     (require 'w3-forms)
  38   (error))
  39
  40 (nnoo-declare nnweb)
  41
  42 (defvoo nnweb-directory (nnheader-concat gnus-directory "nnweb/")
  43   "Where nnweb will save its files.")
  44
  45 (defvoo nnweb-type 'dejanews
  46   "What search engine type is being used.")
  47
  48 (defvar nnweb-type-definition
  49   '((dejanews
  50      (article . nnweb-dejanews-wash-article)
  51      (map . nnweb-dejanews-create-mapping)
  52      (search . nnweb-dejanews-search)
  53      (address . "http://search.dejanews.com/dnquery.xp"))
  54     (reference
  55      (article . nnweb-reference-wash-article)
  56      (map . nnweb-reference-create-mapping)
  57      (search . nnweb-reference-search)
  58      (address . "http://www.reference.com/cgi-bin/pn/go"))
  59     (altavista
  60      (article . nnweb-altavista-wash-article)
  61      (map . nnweb-altavista-create-mapping)
  62      (search . nnweb-altavista-search)
  63      (address . "http://www.altavista.digital.com/cgi-bin/query")
  64      (id . "/cgi-bin/news?id@%s")))
  65   "Type-definition alist.")
  66
  67 (defvoo nnweb-search nil
  68   "Search string to feed to DejaNews.")
  69
  70 (defvoo nnweb-max-hits 100
  71   "Maximum number of hits to display.")
  72
  73 (defvoo nnweb-ephemeral-p nil
  74   "Whether this nnweb server is ephemeral.")
  75
  76 ;;; Internal variables
  77
  78 (defvoo nnweb-articles nil)
  79 (defvoo nnweb-buffer nil)
  80 (defvoo nnweb-group-alist nil)
  81 (defvoo nnweb-group nil)
  82 (defvoo nnweb-hashtb nil)
  83
  84 ;;; Interface functions
  85
  86 (nnoo-define-basics nnweb)
  87
  88 (deffoo nnweb-retrieve-headers (articles &optional group server fetch-old)
  89   (nnweb-possibly-change-server group server)
  90   (save-excursion
  91     (set-buffer nntp-server-buffer)
  92     (erase-buffer)
  93     (let (article header)
  94       (while (setq article (pop articles))
  95         (when (setq header (cadr (assq article nnweb-articles)))
  96           (nnheader-insert-nov header)))
  97       'nov)))
  98
  99 (deffoo nnweb-request-scan (&optional group server)
 100   (nnweb-possibly-change-server group server)
 101   (funcall (nnweb-definition 'map))
 102   (unless nnweb-ephemeral-p
 103     (nnweb-write-active)
 104     (nnweb-write-overview group)))
 105
 106 (deffoo nnweb-request-group (group &optional server dont-check)
 107   (nnweb-possibly-change-server nil server)
 108   (when (and group
 109              (not (equal group nnweb-group))
 110              (not nnweb-ephemeral-p))
 111     (let ((info (assoc group nnweb-group-alist)))
 112       (setq nnweb-group group)
 113       (setq nnweb-type (nth 2 info))
 114       (setq nnweb-search (nth 3 info))
 115       (unless dont-check
 116         (nnweb-read-overview group))))
 117   (cond
 118    ((not nnweb-articles)
 119     (nnheader-report 'nnweb "No matching articles"))
 120    (t
 121     (let ((active (if nnweb-ephemeral-p
 122                       (cons (caar nnweb-articles)
 123                             (caar (last nnweb-articles)))
 124                     (cadr (assoc group nnweb-group-alist)))))
 125       (nnheader-report 'nnweb "Opened group %s" group)
 126       (nnheader-insert
 127        "211 %d %d %d %s\n" (length nnweb-articles)
 128        (car active) (cdr active) group)))))
 129
 130 (deffoo nnweb-close-group (group &optional server)
 131   (nnweb-possibly-change-server group server)
 132   (when (gnus-buffer-live-p nnweb-buffer)
 133     (save-excursion
 134       (set-buffer nnweb-buffer)
 135       (set-buffer-modified-p nil)
 136       (kill-buffer nnweb-buffer)))
 137   t)
 138
 139 (deffoo nnweb-request-article (article &optional group server buffer)
 140   (nnweb-possibly-change-server group server)
 141   (save-excursion
 142     (set-buffer (or buffer nntp-server-buffer))
 143     (let ((url (caddr (assq article nnweb-articles))))
 144       (when (or (and url
 145                      (nnweb-fetch-url url))
 146                 (and (stringp article)
 147                      (let ((fetch (nnweb-definition 'id))
 148                            art)
 149                        (when (string-match "^<\\(.*\\)>$" article)
 150                          (setq art (match-string 1 article)))
 151                        (and fetch
 152                             art
 153                             (nnweb-fetch-url
 154                              (format fetch article))))))
 155         (unless nnheader-callback-function
 156           (funcall (nnweb-definition 'article))
 157           (nnweb-decode-entities))
 158         (nnheader-report 'nnweb "Fetched article %s" article)
 159         t))))
 160
 161 (deffoo nnweb-close-server (&optional server)
 162   (when (and (nnweb-server-opened server)
 163              (gnus-buffer-live-p nnweb-buffer))
 164     (save-excursion
 165       (set-buffer nnweb-buffer)
 166       (set-buffer-modified-p nil)
 167       (kill-buffer nnweb-buffer)))
 168   (nnoo-close-server 'nnweb server))
 169
 170 (deffoo nnweb-request-list (&optional server)
 171   (nnweb-possibly-change-server nil server)
 172   (save-excursion
 173     (set-buffer nntp-server-buffer)
 174     (nnmail-generate-active nnweb-group-alist)
 175     t))
 176
 177 (deffoo nnweb-request-update-info (group info &optional server)
 178   (nnweb-possibly-change-server group server)
 179   ;;(setcar (cddr info) nil)
 180   )
 181
 182 (deffoo nnweb-asynchronous-p ()
 183   t)
 184
 185 (deffoo nnweb-request-create-group (group &optional server args)
 186   (nnweb-possibly-change-server nil server)
 187   (nnweb-request-delete-group group)
 188   (push `(,group ,(cons 1 0) ,@args) nnweb-group-alist)
 189   (nnweb-write-active)
 190   t)
 191
 192 (deffoo nnweb-request-delete-group (group &optional force server)
 193   (nnweb-possibly-change-server group server)
 194   (gnus-delete-assoc group nnweb-group-alist)
 195   (gnus-delete-file (nnweb-overview-file group))
 196   t)
 197
 198 (nnoo-define-skeleton nnweb)
 199
 200 ;;; Internal functions
 201
 202 (defun nnweb-read-overview (group)
 203   "Read the overview of GROUP and build the map."
 204   (when (file-exists-p (nnweb-overview-file group))
 205     (nnheader-temp-write nil
 206       (insert-file-contents (nnweb-overview-file group))
 207       (goto-char (point-min))
 208       (setq nnweb-hashtb (gnus-make-hashtable
 209                           (count-lines (point-min) (point-max))))
 210       (let (header)
 211         (while (not (eobp))
 212           (setq header (nnheader-parse-nov))
 213           (forward-line 1)
 214           (push (list (mail-header-number header)
 215                       header (nnheader-header-xref header))
 216                 nnweb-articles)
 217           (nnweb-set-hashtb header (car nnweb-articles)))))))
 218
 219 (defun nnweb-write-overview (group)
 220   "Write the overview file for GROUP."
 221   (nnheader-temp-write (nnweb-overview-file group)
 222     (let ((articles nnweb-articles))
 223       (while articles
 224         (nnheader-insert-nov (cadr (pop articles)))))))
 225
 226 (defun nnweb-set-hashtb (header data)
 227   (gnus-sethastb (nnweb-identifier (mail-header-xrefs header))
 228                  data nnweb-hashtb))
 229
 230 (defun nnweb-get-hashtb (url)
 231   (gnus-gethash (nnweb-identifier url) nnweb-hashtb))
 232
 233 (defun nnweb-identifier (ident)
 234   ident)
 235
 236 (defun nnweb-overview-file (group)
 237   "Return the name of the overview file of GROUP."
 238   (nnheader-concat nnweb-directory group ".overview"))
 239
 240 (defun nnweb-write-active ()
 241   "Save the active file."
 242   (nnheader-temp-write (nnheader-concat nnweb-directory "active")
 243     (prin1 `(setq nnweb-group-alist ',nnweb-group-alist) (current-buffer))))
 244
 245 (defun nnweb-read-active ()
 246   "Read the active file."
 247   (load (nnheader-concat nnweb-directory "active") t t t))
 248
 249 (defun nnweb-definition (type)
 250   "Return the definition of TYPE."
 251   (let ((def (cdr (assq type (assq nnweb-type nnweb-type-definition)))))
 252     (unless def
 253       (error "Undefined definition %s" type))
 254     def))
 255
 256 (defun nnweb-possibly-change-server (&optional group server)
 257   (nnweb-init server)
 258   (when server
 259     (unless (nnweb-server-opened server)
 260       (nnweb-open-server server)))
 261   (when group
 262     (when (and (not nnweb-ephemeral-p)
 263                (not (equal group nnweb-group)))
 264       (nnweb-request-group group nil t))))
 265
 266 (defun nnweb-init (server)
 267   "Initialize buffers and such."
 268   (unless (gnus-buffer-live-p nnweb-buffer)
 269     (setq nnweb-buffer
 270           (save-excursion
 271             (nnheader-set-temp-buffer
 272              (format " *nnweb %s %s %s*" nnweb-type nnweb-search server))))))
 273
 274 (defun nnweb-fetch-url (url)
 275   (save-excursion
 276     (if (not nnheader-callback-function)
 277         (let ((buf (current-buffer)))
 278           (save-excursion
 279             (set-buffer nnweb-buffer)
 280             (erase-buffer)
 281             (prog1
 282                 (url-insert-file-contents url)
 283               (copy-to-buffer buf (point-min) (point-max)))))
 284       (nnweb-url-retrieve-asynch
 285        url 'nnweb-callback (current-buffer) nnheader-callback-function)
 286       t)))
 287
 288 (defun nnweb-callback (buffer callback)
 289   (when (gnus-buffer-live-p url-working-buffer)
 290     (save-excursion
 291       (set-buffer url-working-buffer)
 292       (funcall (nnweb-definition 'article))
 293       (nnweb-decode-entities)
 294       (set-buffer buffer)
 295       (goto-char (point-max))
 296       (insert-buffer-substring url-working-buffer))
 297     (funcall callback t)
 298     (gnus-kill-buffer url-working-buffer)))
 299
 300 (defun nnweb-url-retrieve-asynch (url callback &rest data)
 301   (let ((url-request-method "GET")
 302         (old-asynch url-be-asynchronous)
 303         (url-request-data nil)
 304         (url-request-extra-headers nil)
 305         (url-working-buffer (generate-new-buffer-name " *nnweb*")))
 306     (setq-default url-be-asynchronous t)
 307     (save-excursion
 308       (set-buffer (get-buffer-create url-working-buffer))
 309       (setq url-current-callback-data data
 310             url-be-asynchronous t
 311             url-current-callback-func callback)
 312       (url-retrieve url))
 313     (setq-default url-be-asynchronous old-asynch)))
 314
 315 (defun nnweb-encode-www-form-urlencoded (pairs)
 316   "Return PAIRS encoded for forms."
 317   (mapconcat
 318    (function
 319     (lambda (data)
 320       (concat (w3-form-encode-xwfu (car data)) "="
 321               (w3-form-encode-xwfu (cdr data)))))
 322    pairs "&"))
 323
 324 (defun nnweb-fetch-form (url pairs)
 325   (let ((url-request-data (nnweb-encode-www-form-urlencoded pairs))
 326         (url-request-method 'POST)
 327         (url-request-extra-headers
 328          '(("Content-type" . "application/x-www-form-urlencoded"))))
 329     (url-insert-file-contents url)
 330     (setq buffer-file-name nil))
 331   t)
 332
 333 (defun nnweb-decode-entities ()
 334   (goto-char (point-min))
 335   (while (re-search-forward "&\\([a-z]+\\);" nil t)
 336     (replace-match (char-to-string (or (cdr (assq (intern (match-string 1))
 337                                                   w3-html-entities ))
 338                                        ?#))
 339                    t t)))
 340
 341 (defun nnweb-remove-markup ()
 342   (goto-char (point-min))
 343   (while (search-forward "<!--" nil t)
 344     (delete-region (match-beginning 0)
 345                    (or (search-forward "-->" nil t)
 346                        (point-max))))
 347   (goto-char (point-min))
 348   (while (re-search-forward "<[^>]+>" nil t)
 349     (replace-match "" t t)))
 350
 351 ;;;
 352 ;;; DejaNews functions.
 353 ;;;
 354
 355 (defun nnweb-dejanews-create-mapping ()
 356   "Perform the search and create an number-to-url alist."
 357   (save-excursion
 358     (set-buffer nnweb-buffer)
 359     (erase-buffer)
 360     (when (funcall (nnweb-definition 'search) nnweb-search)
 361       (let ((i 0)
 362             (more t)
 363             (case-fold-search t)
 364             (active (or (cadr (assoc nnweb-group nnweb-group-alist))
 365                         (cons 1 0)))
 366             Subject Score Date Newsgroup Author
 367             map url)
 368         (while more
 369           ;; Go through all the article hits on this page.
 370           (goto-char (point-min))
 371           (nnweb-decode-entities)
 372           (goto-char (point-min))
 373           (while (re-search-forward "^ +[0-9]+\\." nil t)
 374             (narrow-to-region
 375              (point)
 376              (cond ((re-search-forward "^ +[0-9]+\\." nil t)
 377                     (match-beginning 0))
 378                    ((search-forward "\n\n" nil t)
 379                     (point))
 380                    (t
 381                     (point-max))))
 382             (goto-char (point-min))
 383             (when (looking-at ".*HREF=\"\\([^\"]+\\)\"")
 384               (setq url (match-string 1)))
 385             (nnweb-remove-markup)
 386             (goto-char (point-min))
 387             (while (search-forward "\t" nil t)
 388               (replace-match " "))
 389             (goto-char (point-min))
 390             (while (re-search-forward "^ +\\([^:]+\\): +\\(.*\\)$" nil t)
 391               (set (intern (match-string 1)) (match-string 2)))
 392             (widen)
 393             (when (string-match "#[0-9]+/[0-9]+ *$" Subject)
 394               (setq Subject (substring Subject 0 (match-beginning 0))))
 395             (unless (nnweb-get-hashtb url)
 396               (incf i)
 397               (push
 398                (list
 399                 (incf (cdr active))
 400                 (make-full-mail-header
 401                  (cdr active) (concat  "(" Newsgroup ") " Subject) Author Date
 402                  (concat "<" (message-unique-id) "-" (int-to-string i)
 403                          "@dejanews>")
 404                  nil 0 (string-to-int Score) nil)
 405                 url)
 406                map)))
 407           ;; See whether there is a "Get next 20 hits" button here.
 408           (if (or (not (re-search-forward
 409                         "HREF=\"\\([^\"]+\\)\">Get next" nil t))
 410                   (>= i nnweb-max-hits))
 411               (setq more nil)
 412             ;; Yup -- fetch it.
 413             (setq more (match-string 1))
 414             (erase-buffer)
 415             (url-insert-file-contents more)))
 416         ;; Return the articles in the right order.
 417         (setq nnweb-articles
 418               (sort map (lambda (s1 s2) (< (car s1) (car s2)))))))))
 419
 420 (defun nnweb-dejanews-wash-article ()
 421   (let ((case-fold-search t))
 422     (goto-char (point-min))
 423     (re-search-forward "<PRE>" nil t)
 424     (delete-region (point-min) (point))
 425     (re-search-forward "</PRE>" nil t)
 426     (delete-region (point) (point-max))
 427     (nnweb-remove-markup)
 428     (goto-char (point-min))
 429     (while (and (looking-at " *$")
 430                 (not (eobp)))
 431       (gnus-delete-line))
 432     (while (looking-at "\\(^[^ ]+:\\) *")
 433       (replace-match "\\1 " t)
 434       (forward-line 1))
 435     (when (re-search-forward "\n\n+" nil t)
 436       (replace-match "\n" t t))))
 437
 438 (defun nnweb-dejanews-search (search)
 439   (nnweb-fetch-form
 440    (nnweb-definition 'address)
 441    `(("query" . ,search)
 442      ("defaultOp" . "AND")
 443      ("svcclass" . "dncurrent")
 444      ("maxhits" . "100")
 445      ("format" . "verbose")
 446      ("threaded" . "0")
 447      ("showsort" . "score")
 448      ("agesign" . "1")
 449      ("ageweight" . "1")))
 450   t)
 451
 452 ;;;
 453 ;;; InReference
 454 ;;;
 455
 456 (defun nnweb-reference-create-mapping ()
 457   "Perform the search and create an number-to-url alist."
 458   (save-excursion
 459     (set-buffer nnweb-buffer)
 460     (erase-buffer)
 461     (when (funcall (nnweb-definition 'search) nnweb-search)
 462       (let ((i 0)
 463             (more t)
 464             (case-fold-search t)
 465             (active (or (cadr (assoc nnweb-group nnweb-group-alist))
 466                         (cons 1 0)))
 467             Subject Score Date Newsgroups From Message-ID
 468             map url)
 469         (while more
 470           ;; Go through all the article hits on this page.
 471           (goto-char (point-min))
 472           (search-forward "</pre><hr>" nil t)
 473           (delete-region (point-min) (point))
 474                                         ;(nnweb-decode-entities)
 475           (goto-char (point-min))
 476           (while (re-search-forward "^ +[0-9]+\\." nil t)
 477             (narrow-to-region
 478              (point)
 479              (if (re-search-forward "^$" nil t)
 480                  (match-beginning 0)
 481                (point-max)))
 482             (goto-char (point-min))
 483             (when (looking-at ".*href=\"\\([^\"]+\\)\"")
 484               (setq url (match-string 1)))
 485             (nnweb-remove-markup)
 486             (goto-char (point-min))
 487             (while (search-forward "\t" nil t)
 488               (replace-match " "))
 489             (goto-char (point-min))
 490             (while (re-search-forward "^\\([^:]+\\): \\(.*\\)$" nil t)
 491               (set (intern (match-string 1)) (match-string 2)))
 492             (widen)
 493             (search-forward "</pre>" nil t)
 494             (unless (nnweb-get-hashtb url)
 495               (incf i)
 496               (push
 497                (list
 498                 (incf (cdr active))
 499                 (make-full-mail-header
 500                  (cdr active) (concat  "(" Newsgroups ") " Subject) From Date
 501                  Message-ID
 502                  nil 0 (string-to-int Score) nil)
 503                 url)
 504                map)))
 505           (setq more nil))
 506         ;; Return the articles in the right order.
 507         (setq nnweb-articles
 508               (sort map (lambda (s1 s2) (< (car s1) (car s2)))))))))
 509
 510 (defun nnweb-reference-wash-article ()
 511   (let ((case-fold-search t))
 512     (goto-char (point-min))
 513     (re-search-forward "^</center><hr>" nil t)
 514     (delete-region (point-min) (point))
 515     (search-forward "<pre>" nil t)
 516     (forward-line -1)
 517     (let ((body (point-marker)))
 518       (search-forward "</pre>" nil t)
 519       (delete-region (point) (point-max))
 520       (nnweb-remove-markup)
 521       (goto-char (point-min))
 522       (while (looking-at " *$")
 523         (gnus-delete-line))
 524       (narrow-to-region (point-min) body)
 525       (while (and (re-search-forward "^$" nil t)
 526                   (not (eobp)))
 527         (gnus-delete-line))
 528       (goto-char (point-min))
 529       (while (looking-at "\\(^[^ ]+:\\) *")
 530         (replace-match "\\1 " t)
 531         (forward-line 1))
 532       (goto-char (point-min))
 533       (when (re-search-forward "^References:" nil t)
 534         (narrow-to-region
 535          (point) (if (re-search-forward "^$\\|^[^:]+:" nil t)
 536                      (match-beginning 0)
 537                    (point-max)))
 538         (goto-char (point-min))
 539         (while (not (eobp))
 540           (unless (looking-at "References")
 541             (insert "\t")
 542             (forward-line 1)))
 543         (goto-char (point-min))
 544         (while (search-forward "," nil t)
 545           (replace-match " " t t)))
 546       (widen)
 547       (set-marker body nil))))
 548
 549 (defun nnweb-reference-search (search)
 550   (prog1
 551       (url-insert-file-contents
 552        (concat
 553         (nnweb-definition 'address)
 554         "?"
 555         (nnweb-encode-www-form-urlencoded
 556          `(("search" . "advanced")
 557            ("querytext" . ,search)
 558            ("subj" . "")
 559            ("name" . "")
 560            ("login" . "")
 561            ("host" . "")
 562            ("organization" . "")
 563            ("groups" . "")
 564            ("keywords" . "")
 565            ("choice" . "Search")
 566            ("startmonth" . "Jul")
 567            ("startday" . "25")
 568            ("startyear" . "1996")
 569            ("endmonth" . "Aug")
 570            ("endday" . "24")
 571            ("endyear" . "1996")
 572            ("mode" . "Quick")
 573            ("verbosity" . "Verbose")
 574            ("ranking" . "Relevance")
 575            ("first" . "1")
 576            ("last" . "25")
 577            ("score" . "50")))))
 578     (setq buffer-file-name nil))
 579   t)
 580
 581 ;;;
 582 ;;; Alta Vista
 583 ;;;
 584
 585 (defun nnweb-altavista-create-mapping ()
 586   "Perform the search and create an number-to-url alist."
 587   (save-excursion
 588     (set-buffer nnweb-buffer)
 589     (erase-buffer)
 590     (let ((part 0))
 591       (when (funcall (nnweb-definition 'search) nnweb-search part)
 592         (let ((i 0)
 593               (more t)
 594               (case-fold-search t)
 595               (active (or (cadr (assoc nnweb-group nnweb-group-alist))
 596                           (cons 1 0)))
 597               subject date from id group
 598               map url)
 599           (while more
 600             ;; Go through all the article hits on this page.
 601             (goto-char (point-min))
 602             (search-forward "<dt>" nil t)
 603             (delete-region (point-min) (match-beginning 0))
 604             (goto-char (point-min))
 605             (while (search-forward "<dt>" nil t)
 606               (replace-match "\n<blubb>"))
 607             (nnweb-decode-entities)
 608             (goto-char (point-min))
 609             (while (re-search-forward "<blubb>.*href=\"\\([^\"]+\\)\"><strong>\\([^>]*\\)</strong></a><dd>\\([^-]+\\)- <b>\\([^<]+\\)<.*href=\"news:\\([^\"]+\\)\">.*\">\\(.+\\)</a><P>"
 610                                       nil t)
 611               (setq url (match-string 1)
 612                     subject (match-string 2)
 613                     date (match-string 3)
 614                     group (match-string 4)
 615                     id (concat "<" (match-string 5) ">")
 616                     from (match-string 6))
 617               (unless (nnweb-get-hashtb url)
 618                 (incf i)
 619                 (push
 620                  (list
 621                   (incf (cdr active))
 622                   (make-full-mail-header
 623                    (cdr active) (concat  "(" group ") " subject) from date
 624                    id nil 0 0 nil)
 625                   url)
 626                  map)))
 627             ;; See if we want more.
 628             (when (or (not nnweb-articles)
 629                       (>= i nnweb-max-hits)
 630                       (not (funcall (nnweb-definition 'search)
 631                                     nnweb-search (incf part))))
 632               (setq more nil)))
 633           ;; Return the articles in the right order.
 634           (setq nnweb-articles
 635                 (sort map (lambda (s1 s2) (< (car s1) (car s2))))))))))
 636
 637 (defun nnweb-altavista-wash-article ()
 638   (goto-char (point-min))
 639   (let ((case-fold-search t))
 640     (when (re-search-forward "^<strong>" nil t)
 641       (delete-region (point-min) (match-beginning 0)))
 642     (goto-char (point-min))
 643     (while (looking-at "<strong>\\([^ ]+\\) +</strong> +\\(.*\\)$")
 644       (replace-match "\\1: \\2" t)
 645       (forward-line 1))
 646     (when (re-search-backward "^References:" nil t)
 647       (narrow-to-region (point) (progn (forward-line 1) (point)))
 648       (goto-char (point-min))
 649       (while (re-search-forward "<A.*\\?id@\\([^\"]+\\)\">[0-9]+</A>" nil t)
 650         (replace-match "&lt;\\1&gt; " t)))
 651     (widen)
 652     (nnweb-remove-markup)))
 653
 654 (defun nnweb-altavista-search (search &optional part)
 655   (prog1
 656       (url-insert-file-contents
 657        (concat
 658         (nnweb-definition 'address)
 659         "?"
 660         (nnweb-encode-www-form-urlencoded
 661          `(("pg" . "aq")
 662            ("what" . "news")
 663            ,@(when part `(("stq" . ,(int-to-string (* part 30)))))
 664            ("fmt" . "d")
 665            ("q" . ,search)
 666            ("r" . "")
 667            ("d0" . "")
 668            ("d1" . "")))))
 669     (setq buffer-file-name nil)))
 670
 671 (provide 'nnweb)
 672
 673 ;;; nnweb.el ends here