cgit.sxemacs.org Git - gnus/blob - lisp/nntp.el

   1 ;;; nntp.el --- nntp access for Gnus
   2 ;; Copyright (C) 1987, 1988, 1989, 1990, 1992, 1993, 1994, 1995, 1996,
   3 ;;        1997, 1998, 2000, 2001
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'nnheader)
  30 (require 'nnoo)
  31 (require 'gnus-util)
  32
  33 (nnoo-declare nntp)
  34
  35 (eval-when-compile (require 'cl))
  36
  37 (defvoo nntp-address nil
  38   "Address of the physical nntp server.")
  39
  40 (defvoo nntp-port-number "nntp"
  41   "Port number on the physical nntp server.")
  42
  43 (defvoo nntp-server-opened-hook '(nntp-send-mode-reader)
  44   "*Hook used for sending commands to the server at startup.
  45 The default value is `nntp-send-mode-reader', which makes an innd
  46 server spawn an nnrpd server.")
  47
  48 (defvoo nntp-authinfo-function 'nntp-send-authinfo
  49   "Function used to send AUTHINFO to the server.
  50 It is called with no parameters.")
  51
  52 (defvoo nntp-server-action-alist
  53     '(("nntpd 1\\.5\\.11t"
  54        (remove-hook 'nntp-server-opened-hook 'nntp-send-mode-reader))
  55       ("NNRP server Netscape"
  56        (setq nntp-server-list-active-group nil)))
  57   "Alist of regexps to match on server types and actions to be taken.
  58 For instance, if you want Gnus to beep every time you connect
  59 to innd, you could say something like:
  60
  61 \(setq nntp-server-action-alist
  62        '((\"innd\" (ding))))
  63
  64 You probably don't want to do that, though.")
  65
  66 (defvoo nntp-open-connection-function 'nntp-open-network-stream
  67   "*Function used for connecting to a remote system.
  68 It will be called with the buffer to output in.
  69
  70 Two pre-made functions are `nntp-open-network-stream', which is the
  71 default, and simply connects to some port or other on the remote
  72 system (see nntp-port-number).  The other are `nntp-open-rlogin',
  73 which does an rlogin on the remote system, and then does a telnet to
  74 the NNTP server available there (see nntp-rlogin-parameters) and
  75 `nntp-open-telnet' which telnets to a remote system, logs in and does
  76 the same.")
  77
  78 (defvoo nntp-rlogin-program "rsh"
  79   "*Program used to log in on remote machines.
  80 The default is \"rsh\", but \"ssh\" is a popular alternative.")
  81
  82 (defvoo nntp-rlogin-parameters '("telnet" "-8" "${NNTPSERVER:=news}" "nntp")
  83   "*Parameters to `nntp-open-rlogin'.
  84 That function may be used as `nntp-open-connection-function'.  In that
  85 case, this list will be used as the parameter list given to rsh.")
  86
  87 (defvoo nntp-rlogin-user-name nil
  88   "*User name on remote system when using the rlogin connect method.")
  89
  90 (defvoo nntp-telnet-parameters
  91     '("exec" "telnet" "-8" "${NNTPSERVER:=news}" "nntp")
  92   "*Parameters to `nntp-open-telnet'.
  93 That function may be used as `nntp-open-connection-function'.  In that
  94 case, this list will be executed as a command after logging in
  95 via telnet.")
  96
  97 (defvoo nntp-telnet-user-name nil
  98   "User name to log in via telnet with.")
  99
 100 (defvoo nntp-telnet-passwd nil
 101   "Password to use to log in via telnet with.")
 102
 103 (defvoo nntp-open-telnet-envuser nil
 104   "*If non-nil, telnet session (client and server both) will support the ENVIRON option and not prompt for login name.")
 105
 106 (defvoo nntp-telnet-shell-prompt "bash\\|\$ *\r?$\\|> *\r?"
 107   "*Regular expression to match the shell prompt on the remote machine.")
 108
 109 (defvoo nntp-telnet-command "telnet"
 110   "Command used to start telnet.")
 111
 112 (defvoo nntp-telnet-switches '("-8")
 113   "Switches given to the telnet command.")
 114
 115 (defvoo nntp-end-of-line "\r\n"
 116   "String to use on the end of lines when talking to the NNTP server.
 117 This is \"\\r\\n\" by default, but should be \"\\n\" when
 118 using rlogin or telnet to communicate with the server.")
 119
 120 (defvoo nntp-large-newsgroup 50
 121   "*The number of the articles which indicates a large newsgroup.
 122 If the number of the articles is greater than the value, verbose
 123 messages will be shown to indicate the current status.")
 124
 125 (defvoo nntp-maximum-request 400
 126   "*The maximum number of the requests sent to the NNTP server at one time.
 127 If Emacs hangs up while retrieving headers, set the variable to a
 128 lower value.")
 129
 130 (defvoo nntp-nov-is-evil nil
 131   "*If non-nil, nntp will never attempt to use XOVER when talking to the server.")
 132
 133 (defvoo nntp-xover-commands '("XOVER" "XOVERVIEW")
 134   "*List of strings that are used as commands to fetch NOV lines from a server.
 135 The strings are tried in turn until a positive response is gotten.  If
 136 none of the commands are successful, nntp will just grab headers one
 137 by one.")
 138
 139 (defvoo nntp-nov-gap 5
 140   "*Maximum allowed gap between two articles.
 141 If the gap between two consecutive articles is bigger than this
 142 variable, split the XOVER request into two requests.")
 143
 144 (defvoo nntp-prepare-server-hook nil
 145   "*Hook run before a server is opened.
 146 If can be used to set up a server remotely, for instance.  Say you
 147 have an account at the machine \"other.machine\".  This machine has
 148 access to an NNTP server that you can't access locally.  You could
 149 then use this hook to rsh to the remote machine and start a proxy NNTP
 150 server there that you can connect to.  See also
 151 `nntp-open-connection-function'")
 152
 153 (defvoo nntp-warn-about-losing-connection t
 154   "*If non-nil, beep when a server closes connection.")
 155
 156 (defvoo nntp-coding-system-for-read 'binary
 157   "*Coding system to read from NNTP.")
 158
 159 (defvoo nntp-coding-system-for-write 'binary
 160   "*Coding system to write to NNTP.")
 161
 162 (defcustom nntp-authinfo-file "~/.authinfo"
 163   ".netrc-like file that holds nntp authinfo passwords."
 164   :type
 165   '(choice file
 166            (repeat :tag "Entries"
 167                    :menu-tag "Inline"
 168                    (list :format "%v"
 169                          :value ("" ("login" . "") ("password" . ""))
 170                          (string :tag "Host")
 171                          (checklist :inline t
 172                                     (cons :format "%v"
 173                                           (const :format "" "login")
 174                                           (string :format "Login: %v"))
 175                                     (cons :format "%v"
 176                                           (const :format "" "password")
 177                                           (string :format "Password: %v")))))))
 178
 179 \f
 180
 181 (defvoo nntp-connection-timeout nil
 182   "*Number of seconds to wait before an nntp connection times out.
 183 If this variable is nil, which is the default, no timers are set.
 184 NOTE: This variable is never seen to work in Emacs 20 and XEmacs 21.")
 185
 186 ;;; Internal variables.
 187
 188 (defvar nntp-record-commands nil
 189   "*If non-nil, nntp will record all commands in the \"*nntp-log*\" buffer.")
 190
 191 (defvar nntp-have-messaged nil)
 192
 193 (defvar nntp-process-wait-for nil)
 194 (defvar nntp-process-to-buffer nil)
 195 (defvar nntp-process-callback nil)
 196 (defvar nntp-process-decode nil)
 197 (defvar nntp-process-start-point nil)
 198 (defvar nntp-inside-change-function nil)
 199 (defvoo nntp-last-command-time nil)
 200 (defvoo nntp-last-command nil)
 201 (defvoo nntp-authinfo-password nil)
 202 (defvoo nntp-authinfo-user nil)
 203
 204 (defvar nntp-connection-list nil)
 205
 206 (defvoo nntp-server-type nil)
 207 (defvoo nntp-connection-alist nil)
 208 (defvoo nntp-status-string "")
 209 (defconst nntp-version "nntp 5.0")
 210 (defvoo nntp-inhibit-erase nil)
 211 (defvoo nntp-inhibit-output nil)
 212
 213 (defvoo nntp-server-xover 'try)
 214 (defvoo nntp-server-list-active-group 'try)
 215
 216 (defvar nntp-async-needs-kluge
 217   (string-match "^GNU Emacs 20\\.3\\." (emacs-version))
 218   "*When non-nil, nntp will poll asynchronous connections
 219 once a second.  By default, this is turned on only for Emacs
 220 20.3, which has a bug that breaks nntp's normal method of
 221 noticing asynchronous data.")
 222
 223 (defvar nntp-async-timer nil)
 224 (defvar nntp-async-process-list nil)
 225
 226 (eval-and-compile
 227   (autoload 'mail-source-read-passwd "mail-source")
 228   (autoload 'open-ssl-stream "ssl"))
 229
 230 \f
 231
 232 ;;; Internal functions.
 233
 234 (defsubst nntp-send-string (process string)
 235   "Send STRING to PROCESS."
 236   ;; We need to store the time to provide timeouts, and
 237   ;; to store the command so the we can replay the command
 238   ;; if the server gives us an AUTHINFO challenge.
 239   (setq nntp-last-command-time (current-time)
 240         nntp-last-command string)
 241   (when nntp-record-commands
 242     (nntp-record-command string))
 243   (process-send-string process (concat string nntp-end-of-line)))
 244
 245 (defun nntp-record-command (string)
 246   "Record the command STRING."
 247   (save-excursion
 248     (set-buffer (get-buffer-create "*nntp-log*"))
 249     (goto-char (point-max))
 250     (let ((time (current-time)))
 251       (insert (format-time-string "%Y%m%dT%H%M%S" time)
 252               "." (format "%03d" (/ (nth 2 time) 1000))
 253               " " nntp-address " " string "\n"))))
 254
 255 (defsubst nntp-wait-for (process wait-for buffer &optional decode discard)
 256   "Wait for WAIT-FOR to arrive from PROCESS."
 257   (save-excursion
 258     (set-buffer (process-buffer process))
 259     (goto-char (point-min))
 260     (while (and (or (not (memq (char-after (point)) '(?2 ?3 ?4 ?5)))
 261                     (looking-at "480"))
 262                 (memq (process-status process) '(open run)))
 263       (when (looking-at "480")
 264         (nntp-handle-authinfo process))
 265       (nntp-accept-process-output process)
 266       (goto-char (point-min)))
 267     (prog1
 268         (cond
 269          ((looking-at "[45]")
 270           (progn
 271             (nntp-snarf-error-message)
 272             nil))
 273          ((not (memq (process-status process) '(open run)))
 274           (nnheader-report 'nntp "Server closed connection"))
 275          (t
 276           (goto-char (point-max))
 277           (let ((limit (point-min)))
 278             (while (not (re-search-backward wait-for limit t))
 279               (nntp-accept-process-output process)
 280               ;; We assume that whatever we wait for is less than 1000
 281               ;; characters long.
 282               (setq limit (max (- (point-max) 1000) (point-min)))
 283               (goto-char (point-max))))
 284           (nntp-decode-text (not decode))
 285           (unless discard
 286             (save-excursion
 287               (set-buffer buffer)
 288               (goto-char (point-max))
 289               (insert-buffer-substring (process-buffer process))
 290               ;; Nix out "nntp reading...." message.
 291               (when nntp-have-messaged
 292                 (setq nntp-have-messaged nil)
 293                 (nnheader-message 5 ""))))
 294           t))
 295       (unless discard
 296         (erase-buffer)))))
 297
 298 (defun nntp-kill-buffer (buffer)
 299   (when (buffer-name buffer)
 300     (kill-buffer buffer)
 301     (nnheader-init-server-buffer)))
 302
 303 (defsubst nntp-find-connection (buffer)
 304   "Find the connection delivering to BUFFER."
 305   (let ((alist nntp-connection-alist)
 306         (buffer (if (stringp buffer) (get-buffer buffer) buffer))
 307         process entry)
 308     (while (and alist (setq entry (pop alist)))
 309       (when (eq buffer (cadr entry))
 310         (setq process (car entry)
 311               alist nil)))
 312     (when process
 313       (if (memq (process-status process) '(open run))
 314           process
 315         (nntp-kill-buffer (process-buffer process))
 316         (setq nntp-connection-alist (delq entry nntp-connection-alist))
 317         nil))))
 318
 319 (defsubst nntp-find-connection-entry (buffer)
 320   "Return the entry for the connection to BUFFER."
 321   (assq (nntp-find-connection buffer) nntp-connection-alist))
 322
 323 (defun nntp-find-connection-buffer (buffer)
 324   "Return the process connection buffer tied to BUFFER."
 325   (let ((process (nntp-find-connection buffer)))
 326     (when process
 327       (process-buffer process))))
 328
 329 (defsubst nntp-retrieve-data (command address port buffer
 330                                       &optional wait-for callback decode)
 331   "Use COMMAND to retrieve data into BUFFER from PORT on ADDRESS."
 332   (let ((process (or (nntp-find-connection buffer)
 333                      (nntp-open-connection buffer))))
 334     (if (not process)
 335         (nnheader-report 'nntp "Couldn't open connection to %s" address)
 336       (unless (or nntp-inhibit-erase nnheader-callback-function)
 337         (save-excursion
 338           (set-buffer (process-buffer process))
 339           (erase-buffer)))
 340       (condition-case err
 341           (progn
 342             (when command
 343               (nntp-send-string process command))
 344             (cond
 345              ((eq callback 'ignore)
 346               t)
 347              ((and callback wait-for)
 348               (nntp-async-wait process wait-for buffer decode callback)
 349               t)
 350              (wait-for
 351               (nntp-wait-for process wait-for buffer decode))
 352              (t t)))
 353         (error
 354          (nnheader-report 'nntp "Couldn't open connection to %s: %s"
 355                           address err))
 356         (quit
 357          (message "Quit retrieving data from nntp")
 358          (signal 'quit nil)
 359          nil)))))
 360
 361 (defsubst nntp-send-command (wait-for &rest strings)
 362   "Send STRINGS to server and wait until WAIT-FOR returns."
 363   (when (and (not nnheader-callback-function)
 364              (not nntp-inhibit-output))
 365     (save-excursion
 366       (set-buffer nntp-server-buffer)
 367       (erase-buffer)))
 368   (nntp-retrieve-data
 369    (mapconcat 'identity strings " ")
 370    nntp-address nntp-port-number nntp-server-buffer
 371    wait-for nnheader-callback-function))
 372
 373 (defun nntp-send-command-nodelete (wait-for &rest strings)
 374   "Send STRINGS to server and wait until WAIT-FOR returns."
 375   (nntp-retrieve-data
 376    (mapconcat 'identity strings " ")
 377    nntp-address nntp-port-number nntp-server-buffer
 378    wait-for nnheader-callback-function))
 379
 380 (defun nntp-send-command-and-decode (wait-for &rest strings)
 381   "Send STRINGS to server and wait until WAIT-FOR returns."
 382   (when (and (not nnheader-callback-function)
 383              (not nntp-inhibit-output))
 384     (save-excursion
 385       (set-buffer nntp-server-buffer)
 386       (erase-buffer)))
 387   (nntp-retrieve-data
 388    (mapconcat 'identity strings " ")
 389    nntp-address nntp-port-number nntp-server-buffer
 390    wait-for nnheader-callback-function t))
 391
 392 (defun nntp-send-buffer (wait-for)
 393   "Send the current buffer to server and wait until WAIT-FOR returns."
 394   (when (and (not nnheader-callback-function)
 395              (not nntp-inhibit-output))
 396     (save-excursion
 397       (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 398       (erase-buffer)))
 399   (nntp-encode-text)
 400   (process-send-region (nntp-find-connection nntp-server-buffer)
 401                        (point-min) (point-max))
 402   (nntp-retrieve-data
 403    nil nntp-address nntp-port-number nntp-server-buffer
 404    wait-for nnheader-callback-function))
 405
 406 \f
 407
 408 ;;; Interface functions.
 409
 410 (nnoo-define-basics nntp)
 411
 412 (defsubst nntp-next-result-arrived-p ()
 413   (cond
 414    ;; A result that starts with a 2xx code is terminated by
 415    ;; a line with only a "." on it.
 416    ((eq (char-after) ?2)
 417     (if (re-search-forward "\n\\.\r?\n" nil t)
 418         t
 419       nil))
 420    ;; A result that starts with a 3xx or 4xx code is terminated
 421    ;; by a newline.
 422    ((looking-at "[34]")
 423     (if (search-forward "\n" nil t)
 424         t
 425       nil))
 426    ;; No result here.
 427    (t
 428     nil)))
 429
 430 (deffoo nntp-retrieve-headers (articles &optional group server fetch-old)
 431   "Retrieve the headers of ARTICLES."
 432   (nntp-possibly-change-group group server)
 433   (save-excursion
 434     (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 435     (erase-buffer)
 436     (if (and (not gnus-nov-is-evil)
 437              (not nntp-nov-is-evil)
 438              (nntp-retrieve-headers-with-xover articles fetch-old))
 439         ;; We successfully retrieved the headers via XOVER.
 440         'nov
 441       ;; XOVER didn't work, so we do it the hard, slow and inefficient
 442       ;; way.
 443       (let ((number (length articles))
 444             (count 0)
 445             (received 0)
 446             (last-point (point-min))
 447             (buf (nntp-find-connection-buffer nntp-server-buffer))
 448             (nntp-inhibit-erase t)
 449             article)
 450         ;; Send HEAD commands.
 451         (while (setq article (pop articles))
 452           (nntp-send-command
 453            nil
 454            "HEAD" (if (numberp article)
 455                       (int-to-string article)
 456                     ;; `articles' is either a list of article numbers
 457                     ;; or a list of article IDs.
 458                     article))
 459           (incf count)
 460           ;; Every 400 requests we have to read the stream in
 461           ;; order to avoid deadlocks.
 462           (when (or (null articles)     ;All requests have been sent.
 463                     (zerop (% count nntp-maximum-request)))
 464             (nntp-accept-response)
 465             (while (progn
 466                      (set-buffer buf)
 467                      (goto-char last-point)
 468                      ;; Count replies.
 469                      (while (nntp-next-result-arrived-p)
 470                        (setq last-point (point))
 471                        (incf received))
 472                      (< received count))
 473               ;; If number of headers is greater than 100, give
 474               ;;  informative messages.
 475               (and (numberp nntp-large-newsgroup)
 476                    (> number nntp-large-newsgroup)
 477                    (zerop (% received 20))
 478                    (nnheader-message 6 "NNTP: Receiving headers... %d%%"
 479                                      (/ (* received 100) number)))
 480               (nntp-accept-response))))
 481         (and (numberp nntp-large-newsgroup)
 482              (> number nntp-large-newsgroup)
 483              (nnheader-message 6 "NNTP: Receiving headers...done"))
 484
 485         ;; Now all of replies are received.  Fold continuation lines.
 486         (nnheader-fold-continuation-lines)
 487         ;; Remove all "\r"'s.
 488         (nnheader-strip-cr)
 489         (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 490         'headers))))
 491
 492 (deffoo nntp-retrieve-groups (groups &optional server)
 493   "Retrieve group info on GROUPS."
 494   (nntp-possibly-change-group nil server)
 495   (when (nntp-find-connection-buffer nntp-server-buffer)
 496     (save-excursion
 497       ;; Erase nntp-server-buffer before nntp-inhibit-erase.
 498       (set-buffer nntp-server-buffer)
 499       (erase-buffer)
 500       (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 501       ;; The first time this is run, this variable is `try'.  So we
 502       ;; try.
 503       (when (eq nntp-server-list-active-group 'try)
 504         (nntp-try-list-active (car groups)))
 505       (erase-buffer)
 506       (let ((count 0)
 507             (received 0)
 508             (last-point (point-min))
 509             (nntp-inhibit-erase t)
 510             (buf (nntp-find-connection-buffer nntp-server-buffer))
 511             (command (if nntp-server-list-active-group "LIST ACTIVE" "GROUP")))
 512         (while groups
 513           ;; Send the command to the server.
 514           (nntp-send-command nil command (pop groups))
 515           (incf count)
 516           ;; Every 400 requests we have to read the stream in
 517           ;; order to avoid deadlocks.
 518           (when (or (null groups)       ;All requests have been sent.
 519                     (zerop (% count nntp-maximum-request)))
 520             (nntp-accept-response)
 521             (while (and (gnus-buffer-live-p buf)
 522                         (progn
 523                           ;; Search `blue moon' in this file for the
 524                           ;; reason why set-buffer here.
 525                           (set-buffer buf)
 526                           (goto-char last-point)
 527                           ;; Count replies.
 528                           (while (re-search-forward "^[0-9]" nil t)
 529                             (incf received))
 530                           (setq last-point (point))
 531                           (< received count)))
 532               (nntp-accept-response))))
 533
 534         ;; Wait for the reply from the final command.
 535         (unless (gnus-buffer-live-p buf)
 536           (error
 537            (nnheader-report 'nntp "Connection to %s is closed." server)))
 538         (set-buffer buf)
 539         (goto-char (point-max))
 540         (re-search-backward "^[0-9]" nil t)
 541         (when (looking-at "^[23]")
 542           (while (and (gnus-buffer-live-p buf)
 543                       (progn
 544                         (set-buffer buf)
 545                         (goto-char (point-max))
 546                         (if (not nntp-server-list-active-group)
 547                             (not (re-search-backward "\r?\n" (- (point) 3) t))
 548                           (not (re-search-backward "^\\.\r?\n"
 549                                                    (- (point) 4) t)))))
 550                       (nntp-accept-response)))
 551
 552         ;; Now all replies are received.  We remove CRs.
 553         (unless (gnus-buffer-live-p buf)
 554           (error
 555            (nnheader-report 'nntp "Connection to %s is closed." server)))
 556         (set-buffer buf)
 557         (goto-char (point-min))
 558         (while (search-forward "\r" nil t)
 559           (replace-match "" t t))
 560
 561         (if (not nntp-server-list-active-group)
 562             (progn
 563               (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 564               'group)
 565           ;; We have read active entries, so we just delete the
 566           ;; superfluous gunk.
 567           (goto-char (point-min))
 568           (while (re-search-forward "^[.2-5]" nil t)
 569             (delete-region (match-beginning 0)
 570                            (progn (forward-line 1) (point))))
 571           (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 572           'active)))))
 573
 574 (deffoo nntp-retrieve-articles (articles &optional group server)
 575   (nntp-possibly-change-group group server)
 576   (save-excursion
 577     (let ((number (length articles))
 578           (count 0)
 579           (received 0)
 580           (last-point (point-min))
 581           (buf (nntp-find-connection-buffer nntp-server-buffer))
 582           (nntp-inhibit-erase t)
 583           (map (apply 'vector articles))
 584           (point 1)
 585           article)
 586       (set-buffer buf)
 587       (erase-buffer)
 588       ;; Send ARTICLE command.
 589       (while (setq article (pop articles))
 590         (nntp-send-command
 591          nil
 592          "ARTICLE" (if (numberp article)
 593                        (int-to-string article)
 594                      ;; `articles' is either a list of article numbers
 595                      ;; or a list of article IDs.
 596                      article))
 597         (incf count)
 598         ;; Every 400 requests we have to read the stream in
 599         ;; order to avoid deadlocks.
 600         (when (or (null articles)       ;All requests have been sent.
 601                   (zerop (% count nntp-maximum-request)))
 602           (nntp-accept-response)
 603           (while (progn
 604                    (set-buffer buf)
 605                    (goto-char last-point)
 606                    ;; Count replies.
 607                    (while (nntp-next-result-arrived-p)
 608                      (aset map received (cons (aref map received) (point)))
 609                      (setq last-point (point))
 610                      (incf received))
 611                    (< received count))
 612             ;; If number of headers is greater than 100, give
 613             ;;  informative messages.
 614             (and (numberp nntp-large-newsgroup)
 615                  (> number nntp-large-newsgroup)
 616                  (zerop (% received 20))
 617                  (nnheader-message 6 "NNTP: Receiving articles... %d%%"
 618                                    (/ (* received 100) number)))
 619             (nntp-accept-response))))
 620       (and (numberp nntp-large-newsgroup)
 621            (> number nntp-large-newsgroup)
 622            (nnheader-message 6 "NNTP: Receiving articles...done"))
 623
 624       ;; Now we have all the responses.  We go through the results,
 625       ;; wash it and copy it over to the server buffer.
 626       (set-buffer nntp-server-buffer)
 627       (erase-buffer)
 628       (setq last-point (point-min))
 629       (mapcar
 630        (lambda (entry)
 631          (narrow-to-region
 632           (setq point (goto-char (point-max)))
 633           (progn
 634             (insert-buffer-substring buf last-point (cdr entry))
 635             (point-max)))
 636          (setq last-point (cdr entry))
 637          (nntp-decode-text)
 638          (widen)
 639          (cons (car entry) point))
 640        map))))
 641
 642 (defun nntp-try-list-active (group)
 643   (nntp-list-active-group group)
 644   (save-excursion
 645     (set-buffer nntp-server-buffer)
 646     (goto-char (point-min))
 647     (cond ((or (eobp)
 648                (looking-at "5[0-9]+"))
 649            (setq nntp-server-list-active-group nil))
 650           (t
 651            (setq nntp-server-list-active-group t)))))
 652
 653 (deffoo nntp-list-active-group (group &optional server)
 654   "Return the active info on GROUP (which can be a regexp)."
 655   (nntp-possibly-change-group nil server)
 656   (nntp-send-command "^\\.*\r?\n" "LIST ACTIVE" group))
 657
 658 (deffoo nntp-request-group-articles (group &optional server)
 659   "Return the list of existing articles in GROUP."
 660   (nntp-possibly-change-group nil server)
 661   (nntp-send-command "^\\.*\r?\n" "LISTGROUP" group))
 662
 663 (deffoo nntp-request-article (article &optional group server buffer command)
 664   (nntp-possibly-change-group group server)
 665   (when (nntp-send-command-and-decode
 666          "\r?\n\\.\r?\n" "ARTICLE"
 667          (if (numberp article) (int-to-string article) article))
 668     (if (and buffer
 669              (not (equal buffer nntp-server-buffer)))
 670         (save-excursion
 671           (set-buffer nntp-server-buffer)
 672           (copy-to-buffer buffer (point-min) (point-max))
 673           (nntp-find-group-and-number))
 674       (nntp-find-group-and-number))))
 675
 676 (deffoo nntp-request-head (article &optional group server)
 677   (nntp-possibly-change-group group server)
 678   (when (nntp-send-command
 679          "\r?\n\\.\r?\n" "HEAD"
 680          (if (numberp article) (int-to-string article) article))
 681     (prog1
 682         (nntp-find-group-and-number)
 683       (nntp-decode-text))))
 684
 685 (deffoo nntp-request-body (article &optional group server)
 686   (nntp-possibly-change-group group server)
 687   (nntp-send-command-and-decode
 688    "\r?\n\\.\r?\n" "BODY"
 689    (if (numberp article) (int-to-string article) article)))
 690
 691 (deffoo nntp-request-group (group &optional server dont-check)
 692   (nntp-possibly-change-group nil server)
 693   (when (nntp-send-command "^[245].*\n" "GROUP" group)
 694     (let ((entry (nntp-find-connection-entry nntp-server-buffer)))
 695       (setcar (cddr entry) group))))
 696
 697 (deffoo nntp-close-group (group &optional server)
 698   t)
 699
 700 (deffoo nntp-server-opened (&optional server)
 701   "Say whether a connection to SERVER has been opened."
 702   (and (nnoo-current-server-p 'nntp server)
 703        nntp-server-buffer
 704        (gnus-buffer-live-p nntp-server-buffer)
 705        (nntp-find-connection nntp-server-buffer)))
 706
 707 (deffoo nntp-open-server (server &optional defs connectionless)
 708   (nnheader-init-server-buffer)
 709   (if (nntp-server-opened server)
 710       t
 711     (when (or (stringp (car defs))
 712               (numberp (car defs)))
 713       (setq defs (cons (list 'nntp-port-number (car defs)) (cdr defs))))
 714     (unless (assq 'nntp-address defs)
 715       (setq defs (append defs (list (list 'nntp-address server)))))
 716     (nnoo-change-server 'nntp server defs)
 717     (unless connectionless
 718       (or (nntp-find-connection nntp-server-buffer)
 719           (nntp-open-connection nntp-server-buffer)))))
 720
 721 (deffoo nntp-close-server (&optional server)
 722   (nntp-possibly-change-group nil server t)
 723   (let ((process (nntp-find-connection nntp-server-buffer)))
 724     (while process
 725       (when (memq (process-status process) '(open run))
 726         (ignore-errors
 727           (nntp-send-string process "QUIT")
 728           (unless (eq nntp-open-connection-function 'nntp-open-network-stream)
 729             ;; Ok, this is evil, but when using telnet and stuff
 730             ;; as the connection method, it's important that the
 731             ;; QUIT command actually is sent out before we kill
 732             ;; the process.
 733             (sleep-for 1))))
 734       (nntp-kill-buffer (process-buffer process))
 735       (setq process (car (pop nntp-connection-alist))))
 736     (nnoo-close-server 'nntp)))
 737
 738 (deffoo nntp-request-close ()
 739   (let (process)
 740     (while (setq process (pop nntp-connection-list))
 741       (when (memq (process-status process) '(open run))
 742         (ignore-errors
 743           (nntp-send-string process "QUIT")
 744           (unless (eq nntp-open-connection-function 'nntp-open-network-stream)
 745             ;; Ok, this is evil, but when using telnet and stuff
 746             ;; as the connection method, it's important that the
 747             ;; QUIT command actually is sent out before we kill
 748             ;; the process.
 749             (sleep-for 1))))
 750       (nntp-kill-buffer (process-buffer process)))))
 751
 752 (deffoo nntp-request-list (&optional server)
 753   (nntp-possibly-change-group nil server)
 754   (nntp-send-command-and-decode "\r?\n\\.\r?\n" "LIST"))
 755
 756 (deffoo nntp-request-list-newsgroups (&optional server)
 757   (nntp-possibly-change-group nil server)
 758   (nntp-send-command "\r?\n\\.\r?\n" "LIST NEWSGROUPS"))
 759
 760 (deffoo nntp-request-newgroups (date &optional server)
 761   (nntp-possibly-change-group nil server)
 762   (save-excursion
 763     (set-buffer nntp-server-buffer)
 764     (prog1
 765         (nntp-send-command
 766          "^\\.\r?\n" "NEWGROUPS"
 767          (format-time-string "%y%m%d %H%M%S" (date-to-time date)))
 768       (nntp-decode-text))))
 769
 770 (deffoo nntp-request-post (&optional server)
 771   (nntp-possibly-change-group nil server)
 772   (when (nntp-send-command "^[23].*\r?\n" "POST")
 773     (nntp-send-buffer "^[23].*\n")))
 774
 775 (deffoo nntp-request-type (group article)
 776   'news)
 777
 778 (deffoo nntp-asynchronous-p ()
 779   t)
 780
 781 ;;; Hooky functions.
 782
 783 (defun nntp-send-mode-reader ()
 784   "Send the MODE READER command to the nntp server.
 785 This function is supposed to be called from `nntp-server-opened-hook'.
 786 It will make innd servers spawn an nnrpd process to allow actual article
 787 reading."
 788   (nntp-send-command "^.*\n" "MODE READER"))
 789
 790 (defun nntp-send-authinfo (&optional send-if-force)
 791   "Send the AUTHINFO to the nntp server.
 792 It will look in the \"~/.authinfo\" file for matching entries.  If
 793 nothing suitable is found there, it will prompt for a user name
 794 and a password.
 795
 796 If SEND-IF-FORCE, only send authinfo to the server if the
 797 .authinfo file has the FORCE token."
 798   (let* ((list (gnus-parse-netrc nntp-authinfo-file))
 799          (alist (gnus-netrc-machine list nntp-address "nntp"))
 800          (force (gnus-netrc-get alist "force"))
 801          (user (or (gnus-netrc-get alist "login") nntp-authinfo-user))
 802          (passwd (gnus-netrc-get alist "password")))
 803     (when (or (not send-if-force)
 804               force)
 805       (unless user
 806         (setq user (read-string (format "NNTP (%s) user name: " nntp-address))
 807               nntp-authinfo-user user))
 808       (unless (member user '(nil ""))
 809         (nntp-send-command "^3.*\r?\n" "AUTHINFO USER" user)
 810         (when t                         ;???Should check if AUTHINFO succeeded
 811           (nntp-send-command
 812            "^2.*\r?\n" "AUTHINFO PASS"
 813            (or passwd
 814                nntp-authinfo-password
 815                (setq nntp-authinfo-password
 816                      (mail-source-read-passwd
 817                       (format "NNTP (%s@%s) password: "
 818                               user nntp-address))))))))))
 819
 820 (defun nntp-send-nosy-authinfo ()
 821   "Send the AUTHINFO to the nntp server."
 822   (let ((user (read-string (format "NNTP (%s) user name: " nntp-address))))
 823     (unless (member user '(nil ""))
 824       (nntp-send-command "^3.*\r?\n" "AUTHINFO USER" user)
 825       (when t                           ;???Should check if AUTHINFO succeeded
 826         (nntp-send-command "^2.*\r?\n" "AUTHINFO PASS"
 827                            (mail-source-read-passwd "NNTP (%s@%s) password: "
 828                                                     user nntp-address))))))
 829
 830 (defun nntp-send-authinfo-from-file ()
 831   "Send the AUTHINFO to the nntp server.
 832
 833 The authinfo login name is taken from the user's login name and the
 834 password contained in '~/.nntp-authinfo'."
 835   (when (file-exists-p "~/.nntp-authinfo")
 836     (with-temp-buffer
 837       (insert-file-contents "~/.nntp-authinfo")
 838       (goto-char (point-min))
 839       (nntp-send-command "^3.*\r?\n" "AUTHINFO USER" (user-login-name))
 840       (nntp-send-command
 841        "^2.*\r?\n" "AUTHINFO PASS"
 842        (buffer-substring (point) (progn (end-of-line) (point)))))))
 843
 844 ;;; Internal functions.
 845
 846 (defun nntp-handle-authinfo (process)
 847   "Take care of an authinfo response from the server."
 848   (let ((last nntp-last-command))
 849     (funcall nntp-authinfo-function)
 850     ;; We have to re-send the function that was interrupted by
 851     ;; the authinfo request.
 852     (save-excursion
 853       (set-buffer nntp-server-buffer)
 854       (erase-buffer))
 855     (nntp-send-string process last)))
 856
 857 (defun nntp-make-process-buffer (buffer)
 858   "Create a new, fresh buffer usable for nntp process connections."
 859   (save-excursion
 860     (set-buffer
 861      (generate-new-buffer
 862       (format " *server %s %s %s*"
 863               nntp-address nntp-port-number
 864               (gnus-buffer-exists-p buffer))))
 865     (mm-enable-multibyte)
 866     (set (make-local-variable 'after-change-functions) nil)
 867     (set (make-local-variable 'nntp-process-wait-for) nil)
 868     (set (make-local-variable 'nntp-process-callback) nil)
 869     (set (make-local-variable 'nntp-process-to-buffer) nil)
 870     (set (make-local-variable 'nntp-process-start-point) nil)
 871     (set (make-local-variable 'nntp-process-decode) nil)
 872     (current-buffer)))
 873
 874 (defun nntp-open-connection (buffer)
 875   "Open a connection to PORT on ADDRESS delivering output to BUFFER."
 876   (run-hooks 'nntp-prepare-server-hook)
 877   (let* ((pbuffer (nntp-make-process-buffer buffer))
 878          (timer
 879           (and nntp-connection-timeout
 880                (nnheader-run-at-time
 881                 nntp-connection-timeout nil
 882                 `(lambda ()
 883                    (nntp-kill-buffer ,pbuffer)))))
 884          (process
 885           (condition-case ()
 886               (let ((coding-system-for-read nntp-coding-system-for-read)
 887                     (coding-system-for-write nntp-coding-system-for-write))
 888                 (funcall nntp-open-connection-function pbuffer))
 889             (error nil)
 890             (quit
 891              (message "Quit opening connection")
 892              (nntp-kill-buffer pbuffer)
 893              (signal 'quit nil)
 894              nil))))
 895     (when timer
 896       (nnheader-cancel-timer timer))
 897     (unless process
 898       (nntp-kill-buffer pbuffer))
 899     (when (and (buffer-name pbuffer)
 900                process)
 901       (process-kill-without-query process)
 902       (if (and (nntp-wait-for process "^200.*\n" buffer nil t)
 903                (memq (process-status process) '(open run)))
 904           (prog1
 905               (caar (push (list process buffer nil) nntp-connection-alist))
 906             (push process nntp-connection-list)
 907             (save-excursion
 908               (set-buffer pbuffer)
 909               (nntp-read-server-type)
 910               (erase-buffer)
 911               (set-buffer nntp-server-buffer)
 912               (let ((nnheader-callback-function nil))
 913                 (run-hooks 'nntp-server-opened-hook)
 914                 (nntp-send-authinfo t))))
 915         (nntp-kill-buffer (process-buffer process))
 916         nil))))
 917
 918 (defun nntp-open-network-stream (buffer)
 919   (open-network-stream "nntpd" buffer nntp-address nntp-port-number))
 920
 921 (defun nntp-open-ssl-stream (buffer)
 922   (let* ((ssl-program-arguments '("-connect" (concat host ":" service)))
 923          (proc (open-ssl-stream "nntpd" buffer nntp-address nntp-port-number)))
 924     (save-excursion
 925       (set-buffer buffer)
 926       (nntp-wait-for-string "^\r*20[01]")
 927       (beginning-of-line)
 928       (delete-region (point-min) (point))
 929       proc)))
 930
 931 (defun nntp-read-server-type ()
 932   "Find out what the name of the server we have connected to is."
 933   ;; Wait for the status string to arrive.
 934   (setq nntp-server-type (buffer-string))
 935   (let ((alist nntp-server-action-alist)
 936         (case-fold-search t)
 937         entry)
 938     ;; Run server-specific commands.
 939     (while alist
 940       (setq entry (pop alist))
 941       (when (string-match (car entry) nntp-server-type)
 942         (if (and (listp (cadr entry))
 943                  (not (eq 'lambda (caadr entry))))
 944             (eval (cadr entry))
 945           (funcall (cadr entry)))))))
 946
 947 (defun nntp-async-wait (process wait-for buffer decode callback)
 948   (save-excursion
 949     (set-buffer (process-buffer process))
 950     (unless nntp-inside-change-function
 951       (erase-buffer))
 952     (setq nntp-process-wait-for wait-for
 953           nntp-process-to-buffer buffer
 954           nntp-process-decode decode
 955           nntp-process-callback callback
 956           nntp-process-start-point (point-max))
 957     (setq after-change-functions '(nntp-after-change-function))
 958     (if nntp-async-needs-kluge
 959         (nntp-async-kluge process))))
 960
 961 (defun nntp-async-kluge (process)
 962   ;; emacs 20.3 bug: process output with encoding 'binary
 963   ;; doesn't trigger after-change-functions.
 964   (unless nntp-async-timer
 965     (setq nntp-async-timer
 966           (nnheader-run-at-time 1 1 'nntp-async-timer-handler)))
 967   (add-to-list 'nntp-async-process-list process))
 968
 969 (defun nntp-async-timer-handler ()
 970   (mapcar
 971    (lambda (proc)
 972      (if (memq (process-status proc) '(open run))
 973          (nntp-async-trigger proc)
 974        (nntp-async-stop proc)))
 975    nntp-async-process-list))
 976
 977 (defun nntp-async-stop (proc)
 978   (setq nntp-async-process-list (delq proc nntp-async-process-list))
 979   (when (and nntp-async-timer (not nntp-async-process-list))
 980     (nnheader-cancel-timer nntp-async-timer)
 981     (setq nntp-async-timer nil)))
 982
 983 (defun nntp-after-change-function (beg end len)
 984   (unwind-protect
 985       ;; we only care about insertions at eob
 986       (when (and (eq 0 len) (eq (point-max) end))
 987         (save-match-data
 988           (let ((proc (get-buffer-process (current-buffer))))
 989             (when proc
 990               (nntp-async-trigger proc)))))
 991     ;; any throw from after-change-functions will leave it
 992     ;; set to nil.  so we reset it here, if necessary.
 993     (when quit-flag
 994       (setq after-change-functions '(nntp-after-change-function)))))
 995
 996 (defun nntp-async-trigger (process)
 997   (save-excursion
 998     (set-buffer (process-buffer process))
 999     (when nntp-process-callback
1000       ;; do we have an error message?
1001       (goto-char nntp-process-start-point)
1002       (if (memq (following-char) '(?4 ?5))
1003           ;; wants credentials?
1004           (if (looking-at "480")
1005               (nntp-handle-authinfo process)
1006             ;; report error message.
1007             (nntp-snarf-error-message)
1008             (nntp-do-callback nil))
1009
1010         ;; got what we expect?
1011         (goto-char (point-max))
1012         (when (re-search-backward
1013                nntp-process-wait-for nntp-process-start-point t)
1014           (nntp-async-stop process)
1015           ;; convert it.
1016           (when (gnus-buffer-exists-p nntp-process-to-buffer)
1017             (let ((buf (current-buffer))
1018                   (start nntp-process-start-point)
1019                   (decode nntp-process-decode))
1020               (save-excursion
1021                 (set-buffer nntp-process-to-buffer)
1022                 (goto-char (point-max))
1023                 (save-restriction
1024                   (narrow-to-region (point) (point))
1025                   (insert-buffer-substring buf start)
1026                   (when decode
1027                     (nntp-decode-text))))))
1028           ;; report it.
1029           (goto-char (point-max))
1030           (nntp-do-callback
1031            (buffer-name (get-buffer nntp-process-to-buffer))))))))
1032
1033 (defun nntp-do-callback (arg)
1034   (let ((callback nntp-process-callback)
1035         (nntp-inside-change-function t))
1036     (setq nntp-process-callback nil)
1037     (funcall callback arg)))
1038
1039 (defun nntp-snarf-error-message ()
1040   "Save the error message in the current buffer."
1041   (let ((message (buffer-string)))
1042     (while (string-match "[\r\n]+" message)
1043       (setq message (replace-match " " t t message)))
1044     (nnheader-report 'nntp message)
1045     message))
1046
1047 (defun nntp-accept-process-output (process &optional timeout)
1048   "Wait for output from PROCESS and message some dots."
1049   (save-excursion
1050     (set-buffer (or (nntp-find-connection-buffer nntp-server-buffer)
1051                     nntp-server-buffer))
1052     (let ((len (/ (point-max) 1024))
1053           message-log-max)
1054       (unless (< len 10)
1055         (setq nntp-have-messaged t)
1056         (nnheader-message 7 "nntp read: %dk" len)))
1057     (accept-process-output process (or timeout 1))))
1058
1059 (defun nntp-accept-response ()
1060   "Wait for output from the process that outputs to BUFFER."
1061   (nntp-accept-process-output (nntp-find-connection nntp-server-buffer)))
1062
1063 (defun nntp-possibly-change-group (group server &optional connectionless)
1064   (let ((nnheader-callback-function nil))
1065     (when server
1066       (or (nntp-server-opened server)
1067           (nntp-open-server server nil connectionless)))
1068
1069     (unless connectionless
1070       (or (nntp-find-connection nntp-server-buffer)
1071           (nntp-open-connection nntp-server-buffer))))
1072
1073   (when group
1074     (let ((entry (nntp-find-connection-entry nntp-server-buffer)))
1075       (when (not (equal group (caddr entry)))
1076         (save-excursion
1077           (set-buffer (process-buffer (car entry)))
1078           (erase-buffer)
1079           (nntp-send-command "^[245].*\n" "GROUP" group)
1080           (setcar (cddr entry) group)
1081           (erase-buffer))))))
1082
1083 (defun nntp-decode-text (&optional cr-only)
1084   "Decode the text in the current buffer."
1085   (goto-char (point-min))
1086   (while (search-forward "\r" nil t)
1087     (delete-char -1))
1088   (unless cr-only
1089     ;; Remove trailing ".\n" end-of-transfer marker.
1090     (goto-char (point-max))
1091     (forward-line -1)
1092     (when (looking-at ".\n")
1093       (delete-char 2))
1094     ;; Delete status line.
1095     (goto-char (point-min))
1096     (while (looking-at "[1-5][0-9][0-9] .*\n")
1097       ;; For some unknown reason, there is more than one status line.
1098       (delete-region (point) (progn (forward-line 1) (point))))
1099     ;; Remove "." -> ".." encoding.
1100     (while (search-forward "\n.." nil t)
1101       (delete-char -1))))
1102
1103 (defun nntp-encode-text ()
1104   "Encode the text in the current buffer."
1105   (save-excursion
1106     ;; Replace "." at beginning of line with "..".
1107     (goto-char (point-min))
1108     (while (re-search-forward "^\\." nil t)
1109       (insert "."))
1110     (goto-char (point-max))
1111     ;; Insert newline at the end of the buffer.
1112     (unless (bolp)
1113       (insert "\n"))
1114     ;; Insert `.' at end of buffer (end of text mark).
1115     (goto-char (point-max))
1116     (insert ".\n")
1117     (goto-char (point-min))
1118     (while (not (eobp))
1119       (end-of-line)
1120       (delete-char 1)
1121       (insert nntp-end-of-line))))
1122
1123 (defun nntp-retrieve-headers-with-xover (articles &optional fetch-old)
1124   (set-buffer nntp-server-buffer)
1125   (erase-buffer)
1126   (cond
1127
1128    ;; This server does not talk NOV.
1129    ((not nntp-server-xover)
1130     nil)
1131
1132    ;; We don't care about gaps.
1133    ((or (not nntp-nov-gap)
1134         fetch-old)
1135     (nntp-send-xover-command
1136      (if fetch-old
1137          (if (numberp fetch-old)
1138              (max 1 (- (car articles) fetch-old))
1139            1)
1140        (car articles))
1141      (car (last articles)) 'wait)
1142
1143     (goto-char (point-min))
1144     (when (looking-at "[1-5][0-9][0-9] .*\n")
1145       (delete-region (point) (progn (forward-line 1) (point))))
1146     (while (search-forward "\r" nil t)
1147       (replace-match "" t t))
1148     (goto-char (point-max))
1149     (forward-line -1)
1150     (when (looking-at "\\.")
1151       (delete-region (point) (progn (forward-line 1) (point)))))
1152
1153    ;; We do it the hard way.  For each gap, an XOVER command is sent
1154    ;; to the server.  We do not wait for a reply from the server, we
1155    ;; just send them off as fast as we can.  That means that we have
1156    ;; to count the number of responses we get back to find out when we
1157    ;; have gotten all we asked for.
1158    ((numberp nntp-nov-gap)
1159     (let ((count 0)
1160           (received 0)
1161           last-point
1162           in-process-buffer-p
1163           (buf nntp-server-buffer)
1164           (process-buffer (nntp-find-connection-buffer nntp-server-buffer))
1165           first)
1166       ;; We have to check `nntp-server-xover'.  If it gets set to nil,
1167       ;; that means that the server does not understand XOVER, but we
1168       ;; won't know that until we try.
1169       (while (and nntp-server-xover articles)
1170         (setq first (car articles))
1171         ;; Search forward until we find a gap, or until we run out of
1172         ;; articles.
1173         (while (and (cdr articles)
1174                     (< (- (nth 1 articles) (car articles)) nntp-nov-gap))
1175           (setq articles (cdr articles)))
1176
1177         (setq in-process-buffer-p (stringp nntp-server-xover))
1178         (nntp-send-xover-command first (car articles))
1179         (setq articles (cdr articles))
1180
1181         (when (and nntp-server-xover in-process-buffer-p)
1182           ;; Don't count tried request.
1183           (setq count (1+ count))
1184
1185           ;; Every 400 requests we have to read the stream in
1186           ;; order to avoid deadlocks.
1187           (when (or (null articles)     ;All requests have been sent.
1188                     (zerop (% count nntp-maximum-request)))
1189
1190             (nntp-accept-response)
1191             ;; On some Emacs versions the preceding function has a
1192             ;; tendency to change the buffer.  Perhaps.  It's quite
1193             ;; difficult to reproduce, because it only seems to happen
1194             ;; once in a blue moon.
1195             (set-buffer process-buffer)
1196             (while (progn
1197                      (goto-char (or last-point (point-min)))
1198                      ;; Count replies.
1199                      (while (re-search-forward "^[0-9][0-9][0-9] .*\n" nil t)
1200                        (incf received))
1201                      (setq last-point (point))
1202                      (< received count))
1203               (nntp-accept-response)
1204               (set-buffer process-buffer))
1205             (set-buffer buf))))
1206
1207       (when nntp-server-xover
1208         (when in-process-buffer-p
1209           (set-buffer process-buffer)
1210           ;; Wait for the reply from the final command.
1211           (goto-char (point-max))
1212           (while (not (re-search-backward "^[0-9][0-9][0-9] " nil t))
1213             (nntp-accept-response)
1214             (set-buffer process-buffer)
1215             (goto-char (point-max)))
1216           (when (looking-at "^[23]")
1217             (while (progn
1218                      (goto-char (point-max))
1219                      (forward-line -1)
1220                      (not (looking-at "^\\.\r?\n")))
1221               (nntp-accept-response)
1222               (set-buffer process-buffer)))
1223           (set-buffer buf)
1224           (goto-char (point-max))
1225           (insert-buffer-substring process-buffer)
1226           (set-buffer process-buffer)
1227           (erase-buffer)
1228           (set-buffer buf))
1229
1230         ;; We remove any "." lines and status lines.
1231         (goto-char (point-min))
1232         (while (search-forward "\r" nil t)
1233           (delete-char -1))
1234         (goto-char (point-min))
1235         (delete-matching-lines "^\\.$\\|^[1-5][0-9][0-9] ")
1236         t))))
1237
1238   nntp-server-xover)
1239
1240 (defun nntp-send-xover-command (beg end &optional wait-for-reply)
1241   "Send the XOVER command to the server."
1242   (let ((range (format "%d-%d" beg end))
1243         (nntp-inhibit-erase t))
1244     (if (stringp nntp-server-xover)
1245         ;; If `nntp-server-xover' is a string, then we just send this
1246         ;; command.
1247         (if wait-for-reply
1248             (nntp-send-command-nodelete
1249              "\r?\n\\.\r?\n" nntp-server-xover range)
1250           ;; We do not wait for the reply.
1251           (nntp-send-command-nodelete nil nntp-server-xover range))
1252       (let ((commands nntp-xover-commands))
1253         ;; `nntp-xover-commands' is a list of possible XOVER commands.
1254         ;; We try them all until we get at positive response.
1255         (while (and commands (eq nntp-server-xover 'try))
1256           (nntp-send-command-nodelete "\r?\n\\.\r?\n" (car commands) range)
1257           (save-excursion
1258             (set-buffer nntp-server-buffer)
1259             (goto-char (point-min))
1260             (and (looking-at "[23]")    ; No error message.
1261                  ;; We also have to look at the lines.  Some buggy
1262                  ;; servers give back simple lines with just the
1263                  ;; article number.  How... helpful.
1264                  (progn
1265                    (forward-line 1)
1266                    (looking-at "[0-9]+\t...")) ; More text after number.
1267                  (setq nntp-server-xover (car commands))))
1268           (setq commands (cdr commands)))
1269         ;; If none of the commands worked, we disable XOVER.
1270         (when (eq nntp-server-xover 'try)
1271           (save-excursion
1272             (set-buffer nntp-server-buffer)
1273             (erase-buffer)
1274             (setq nntp-server-xover nil)))
1275         nntp-server-xover))))
1276
1277 ;;; Alternative connection methods.
1278
1279 (defun nntp-wait-for-string (regexp)
1280   "Wait until string arrives in the buffer."
1281   (let ((buf (current-buffer)))
1282     (goto-char (point-min))
1283     (while (not (re-search-forward regexp nil t))
1284       (accept-process-output (nntp-find-connection nntp-server-buffer))
1285       (set-buffer buf)
1286       (goto-char (point-min)))))
1287
1288 (defun nntp-open-telnet (buffer)
1289   (save-excursion
1290     (set-buffer buffer)
1291     (erase-buffer)
1292     (let ((proc (apply
1293                  'start-process
1294                  "nntpd" buffer nntp-telnet-command nntp-telnet-switches))
1295           (case-fold-search t))
1296       (when (memq (process-status proc) '(open run))
1297         (nntp-wait-for-string "^r?telnet")
1298         (process-send-string proc "set escape \^X\n")
1299         (cond
1300          ((and nntp-open-telnet-envuser nntp-telnet-user-name)
1301           (process-send-string proc (concat "open " "-l" nntp-telnet-user-name
1302                                             nntp-address "\n")))
1303          (t
1304           (process-send-string proc (concat "open " nntp-address "\n"))))
1305         (cond
1306          ((not nntp-open-telnet-envuser)
1307           (nntp-wait-for-string "^\r*.?login:")
1308           (process-send-string
1309            proc (concat
1310                  (or nntp-telnet-user-name
1311                      (setq nntp-telnet-user-name (read-string "login: ")))
1312                  "\n"))))
1313         (nntp-wait-for-string "^\r*.?password:")
1314         (process-send-string
1315          proc (concat
1316                (or nntp-telnet-passwd
1317                    (setq nntp-telnet-passwd
1318                          (mail-source-read-passwd "Password: ")))
1319                "\n"))
1320         (nntp-wait-for-string nntp-telnet-shell-prompt)
1321         (process-send-string
1322          proc (concat (mapconcat 'identity nntp-telnet-parameters " ") "\n"))
1323         (nntp-wait-for-string "^\r*20[01]")
1324         (beginning-of-line)
1325         (delete-region (point-min) (point))
1326         (process-send-string proc "\^]")
1327         (nntp-wait-for-string "^r?telnet")
1328         (process-send-string proc "mode character\n")
1329         (accept-process-output proc 1)
1330         (sit-for 1)
1331         (goto-char (point-min))
1332         (forward-line 1)
1333         (delete-region (point) (point-max)))
1334       proc)))
1335
1336 (defun nntp-open-rlogin (buffer)
1337   "Open a connection to SERVER using rsh."
1338   (let ((proc (if nntp-rlogin-user-name
1339                   (apply 'start-process
1340                          "nntpd" buffer nntp-rlogin-program
1341                          nntp-address "-l" nntp-rlogin-user-name
1342                          nntp-rlogin-parameters)
1343                 (apply 'start-process
1344                        "nntpd" buffer nntp-rlogin-program nntp-address
1345                        nntp-rlogin-parameters))))
1346     (save-excursion
1347       (set-buffer buffer)
1348       (nntp-wait-for-string "^\r*20[01]")
1349       (beginning-of-line)
1350       (delete-region (point-min) (point))
1351       proc)))
1352
1353 (defun nntp-find-group-and-number ()
1354   (save-excursion
1355     (save-restriction
1356       (set-buffer nntp-server-buffer)
1357       (narrow-to-region (goto-char (point-min))
1358                         (or (search-forward "\n\n" nil t) (point-max)))
1359       (goto-char (point-min))
1360       ;; We first find the number by looking at the status line.
1361       (let ((number (and (looking-at "2[0-9][0-9] +\\([0-9]+\\) ")
1362                          (string-to-int
1363                           (buffer-substring (match-beginning 1)
1364                                             (match-end 1)))))
1365             group newsgroups xref)
1366         (and number (zerop number) (setq number nil))
1367         ;; Then we find the group name.
1368         (setq group
1369               (cond
1370                ;; If there is only one group in the Newsgroups header,
1371                ;; then it seems quite likely that this article comes
1372                ;; from that group, I'd say.
1373                ((and (setq newsgroups (mail-fetch-field "newsgroups"))
1374                      (not (string-match "," newsgroups)))
1375                 newsgroups)
1376                ;; If there is more than one group in the Newsgroups
1377                ;; header, then the Xref header should be filled out.
1378                ;; We hazard a guess that the group that has this
1379                ;; article number in the Xref header is the one we are
1380                ;; looking for.  This might very well be wrong if this
1381                ;; article happens to have the same number in several
1382                ;; groups, but that's life.
1383                ((and (setq xref (mail-fetch-field "xref"))
1384                      number
1385                      (string-match (format "\\([^ :]+\\):%d" number) xref))
1386                 (substring xref (match-beginning 1) (match-end 1)))
1387                (t "")))
1388         (when (string-match "\r" group)
1389           (setq group (substring group 0 (match-beginning 0))))
1390         (cons group number)))))
1391
1392 (provide 'nntp)
1393
1394 ;;; nntp.el ends here