cgit.sxemacs.org Git - gnus/blob - lisp/nntp.el

   1 ;;; nntp.el --- NNTP (RFC977) Interface for GNU Emacs
   2 ;; Copyright (C) 1987,88,89,90,92,93,94,95 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'rnews)
  29 (require 'nnheader)
  30
  31 (eval-and-compile
  32   (autoload 'news-setup "rnewspost")
  33   (autoload 'news-reply-mode "rnewspost")
  34   (autoload 'nnmail-request-post-buffer "nnmail")
  35   (autoload 'cancel-timer "timer"))
  36
  37 (defvar nntp-server-hook nil
  38   "Hooks for the NNTP server.
  39 If the kanji code of the NNTP server is different from the local kanji
  40 code, the correct kanji code of the buffer associated with the NNTP
  41 server must be specified as follows:
  42
  43 \(setq nntp-server-hook
  44       (function
  45        (lambda ()
  46          ;; Server's Kanji code is EUC (NEmacs hack).
  47          (make-local-variable 'kanji-fileio-code)
  48          (setq kanji-fileio-code 0))))
  49
  50 If you'd like to change something depending on the server in this
  51 hook, use the variable `nntp-server-name'.")
  52
  53 (defvar nntp-server-opened-hook nil
  54   "Hook used for sending commands to the server at startup.  The
  55 default value is `nntp-send-mode-reader', whick makes an innd server
  56 spawn an nnrpd server.  Another useful function to put in this hook
  57 might be `nntp-send-authinfo', which will prompt for a password to
  58 allow posting from the server.  Note that this is only necessary to do
  59 on servers that use strict access control.")
  60 (add-hook 'nntp-server-opened-hook 'nntp-send-mode-reader)
  61
  62 (defvar nntp-large-newsgroup 50
  63   "The number of the articles which indicates a large newsgroup.
  64 If the number of the articles is greater than the value, verbose
  65 messages will be shown to indicate the current status.")
  66
  67 (defvar nntp-buggy-select (memq system-type '(usg-unix-v fujitsu-uts))
  68   "t if your select routine is buggy.
  69 If the select routine signals error or fall into infinite loop while
  70 waiting for the server response, the variable must be set to t.  In
  71 case of Fujitsu UTS, it is set to T since `accept-process-output'
  72 doesn't work properly.")
  73
  74 (defvar nntp-maximum-request 400
  75   "The maximum number of the requests sent to the NNTP server at one time.
  76 If Emacs hangs up while retrieving headers, set the variable to a
  77 lower value.")
  78
  79 (defvar nntp-debug-read 10000
  80   "Display '...' every 10Kbytes of a message being received if it is non-nil.
  81 If it is a number, dots are displayed per the number.")
  82
  83 (defvar nntp-nov-is-evil nil
  84   "If non-nil, nntp will never attempt to use XOVER when talking to the server.")
  85
  86 (defvar nntp-xover-commands '("XOVER" "XOVERVIEW")
  87   "List of strings that are used as commands to fetch NOV lines from a server.
  88 The strings are tried in turn until a positive response is gotten. If
  89 none of the commands are successful, nntp will just grab headers one
  90 by one.")
  91
  92 (defvar nntp-connection-timeout nil
  93   "Number of seconds to wait before an nntp connection times out.
  94 If this variable is nil, which is the default, no timers are set.")
  95
  96 \f
  97 (defconst nntp-version "nntp 4.0"
  98   "Version numbers of this version of NNTP.")
  99
 100 (defvar nntp-server-name nil
 101   "The name of the NNTP server.")
 102
 103 (defvar nntp-server-buffer nil
 104   "Buffer associated with the NNTP server process.")
 105
 106 (defvar nntp-server-process nil
 107   "The NNTP server process.
 108 You'd better not use this variable in NNTP front-end program, but
 109 instead use `nntp-server-buffer'.")
 110
 111 (defvar nntp-status-string nil
 112   "Save the server response message.
 113 You'd better not use this variable in NNTP front-end program but
 114 instead call function `nntp-status-message' to get status message.")
 115
 116 (defvar nntp-current-server "")
 117 (defvar nntp-server-alist nil)
 118 (defvar nntp-server-xover t)
 119 (defvar nntp-current-group "")
 120
 121 ;;; Interface funtions.
 122
 123 (defun nntp-retrieve-headers (sequence &optional newsgroup server)
 124   "Retrieve the headers to the articles in SEQUENCE."
 125   (nntp-possibly-change-server newsgroup server)
 126   (save-excursion
 127     (set-buffer nntp-server-buffer)
 128     (erase-buffer)
 129     (if (and (not gnus-nov-is-evil)
 130              (not nntp-nov-is-evil)
 131              (nntp-retrieve-headers-with-xover sequence))
 132         'nov
 133       (let ((number (length sequence))
 134             (count 0)
 135             (received 0)
 136             (last-point (point-min)))
 137         ;; Send HEAD command.
 138         (while sequence
 139           (nntp-send-strings-to-server "HEAD" (car sequence))
 140           (setq sequence (cdr sequence))
 141           (setq count (1+ count))
 142           ;; Every 400 header requests we have to read stream in order
 143           ;;  to avoid deadlock.
 144           (if (or (null sequence)       ;All requests have been sent.
 145                   (zerop (% count nntp-maximum-request)))
 146               (progn
 147                 (accept-process-output)
 148                 (while (progn
 149                          (goto-char last-point)
 150                          ;; Count replies.
 151                          (while (re-search-forward "^[0-9]" nil t)
 152                            (setq received (1+ received)))
 153                          (setq last-point (point))
 154                          (< received count))
 155                   ;; If number of headers is greater than 100, give
 156                   ;;  informative messages.
 157                   (and (numberp nntp-large-newsgroup)
 158                        (> number nntp-large-newsgroup)
 159                        (zerop (% received 20))
 160                        (message "NNTP: Receiving headers... %d%%"
 161                                 (/ (* received 100) number)))
 162                   (nntp-accept-response)))))
 163         ;; Wait for text of last command.
 164         (goto-char (point-max))
 165         (re-search-backward "^[0-9]" nil t)
 166         (if (looking-at "^[23]")
 167             (while (progn
 168                      (goto-char (- (point-max) 3))
 169                      (not (looking-at "^\\.\r$")))
 170               (nntp-accept-response)))
 171         (and (numberp nntp-large-newsgroup)
 172              (> number nntp-large-newsgroup)
 173              (message "NNTP: Receiving headers... done"))
 174
 175         ;; Now all of replies are received.
 176         (setq received number)
 177         ;; First, fold continuation lines.
 178         (goto-char (point-min))
 179         (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
 180           (replace-match " " t t))
 181         ;; Remove all "\r"'s
 182         (goto-char (point-min))
 183         (while (re-search-forward "\r" nil t)
 184           (replace-match "" t t))
 185         'headers))))
 186
 187 (defun nntp-open-server (server &optional service)
 188   "Open SERVER.
 189 If SERVER is nil, use value of environment variable `NNTPSERVER'.
 190 If SERVICE, this this as the port number."
 191   (let ((server (or server (getenv "NNTPSERVER")))
 192         (status nil)
 193         (timer
 194          (and nntp-connection-timeout
 195               (run-at-time nntp-connection-timeout
 196                            nil 'nntp-kill-connection server))))
 197     (setq nntp-status-string "")
 198     (message "nntp: Connecting to server on %s..." server)
 199     (cond ((and server (nntp-open-server-internal server service))
 200            (setq nntp-current-server server)
 201            (condition-case nil
 202                (setq status (nntp-wait-for-response "^[23].*\r$"))
 203              (error (nntp-close-server-internal server)))
 204            (and nntp-server-process
 205                 (progn
 206                   (set-process-sentinel
 207                    nntp-server-process 'nntp-default-sentinel)
 208                   ;; You can send commands at startup like AUTHINFO here.
 209                   ;; Added by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>
 210                   (run-hooks 'nntp-server-opened-hook))))
 211           ((null server)
 212            (setq nntp-status-string "NNTP server is not specified.")))
 213     (and timer (cancel-timer timer))
 214     (message "")
 215     status))
 216
 217 (defun nntp-close-server (&optional server)
 218   "Close connection to SERVER."
 219   (nntp-possibly-change-server nil server)
 220   (unwind-protect
 221       (progn
 222         ;; Un-set default sentinel function before closing connection.
 223         (and nntp-server-process
 224              (eq 'nntp-default-sentinel
 225                  (process-sentinel nntp-server-process))
 226              (set-process-sentinel nntp-server-process nil))
 227         ;; We cannot send QUIT command unless the process is running.
 228         (if (nntp-server-opened)
 229             (nntp-send-command nil "QUIT")))
 230     (nntp-close-server-internal server)))
 231
 232 (fset 'nntp-request-quit (symbol-function 'nntp-close-server))
 233
 234 (defun nntp-server-opened (&optional server)
 235   "Say whether a connection to SERVER has been opened."
 236   (if (or server nntp-current-server)
 237       (let ((process (nth 1 (assoc (or server nntp-current-server)
 238                                    nntp-server-alist))))
 239         (and process
 240              (memq (process-status process) '(open run))))))
 241
 242 (defun nntp-status-message (&optional server)
 243   "Return server status as a string."
 244   (if (and nntp-status-string
 245            ;; NNN MESSAGE
 246            (string-match "[0-9][0-9][0-9][ \t]+\\([^\r]*\\).*$"
 247                          nntp-status-string))
 248       (substring nntp-status-string (match-beginning 1) (match-end 1))
 249     ;; Empty message if nothing.
 250     nntp-status-string))
 251
 252 (defun nntp-request-article (id &optional newsgroup server buffer)
 253   "Request article ID (message-id or number)."
 254   (nntp-possibly-change-server newsgroup server)
 255   (unwind-protect
 256       (progn
 257         (if buffer (set-process-buffer nntp-server-process buffer))
 258         (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
 259           ;; If NEmacs, end of message may look like: "\256\215" (".^M")
 260           (prog1
 261               (nntp-send-command "^\\.\r$" "ARTICLE" id)
 262             (nntp-decode-text))))
 263     (if buffer (set-process-buffer nntp-server-process nntp-server-buffer))))
 264
 265 (defun nntp-request-body (id &optional newsgroup server)
 266   "Request body of article ID (message-id or number)."
 267   (nntp-possibly-change-server newsgroup server)
 268   (prog1
 269       ;; If NEmacs, end of message may look like: "\256\215" (".^M")
 270       (nntp-send-command "^\\.\r$" "BODY" id)
 271     (nntp-decode-text)))
 272
 273 (defun nntp-request-head (id &optional newsgroup server)
 274   "Request head of article ID (message-id or number)."
 275   (nntp-possibly-change-server newsgroup server)
 276   (prog1
 277       (nntp-send-command "^\\.\r$" "HEAD" id)
 278     (nntp-decode-text)))
 279
 280 (defun nntp-request-stat (id &optional newsgroup server)
 281   "Request STAT of article ID (message-id or number)."
 282   (nntp-possibly-change-server newsgroup server)
 283   (nntp-send-command "^[23].*\r$" "STAT" id))
 284
 285 (defun nntp-request-group (group &optional server dont-check)
 286   "Select GROUP."
 287   (if (nntp-possibly-change-server nil server)
 288       (nntp-send-command "^.*\r$" "GROUP" group)))
 289
 290 (defun nntp-request-group-description (group &optional server)
 291   "Get description of GROUP."
 292   (if (nntp-possibly-change-server nil server)
 293       (prog1
 294           (nntp-send-command "^.*\r$" "XGTITLE" group)
 295         (nntp-decode-text))))
 296
 297 (defun nntp-close-group (group &optional server)
 298   t)
 299
 300 (defun nntp-request-list (&optional server)
 301   "List active groups."
 302   (nntp-possibly-change-server nil server)
 303   (prog1
 304       (nntp-send-command "^\\.\r$" "LIST")
 305     (nntp-decode-text)))
 306
 307 (defun nntp-request-list-newsgroups (&optional server)
 308   "List groups."
 309   (nntp-possibly-change-server nil server)
 310   (prog1
 311       (nntp-send-command "^\\.\r$" "LIST NEWSGROUPS")
 312     (nntp-decode-text)))
 313
 314 (defun nntp-request-newgroups (date &optional server)
 315   "List new groups."
 316   (nntp-possibly-change-server nil server)
 317   (let* ((date (timezone-parse-date date))
 318          (time-string
 319           (format "%s%02d%02d %s%s%s"
 320                   (substring (aref date 0) 2) (string-to-int (aref date 1))
 321                   (string-to-int (aref date 2)) (substring (aref date 3) 0 2)
 322                   (substring
 323                    (aref date 3) 3 5) (substring (aref date 3) 6 8))))
 324     (prog1
 325         (nntp-send-command "^\\.\r$" "NEWGROUPS" time-string)
 326       (nntp-decode-text))))
 327
 328 (defun nntp-request-list-distributions (&optional server)
 329   "List distributions."
 330   (nntp-possibly-change-server nil server)
 331   (prog1
 332       (nntp-send-command "^\\.\r$" "LIST DISTRIBUTIONS")
 333     (nntp-decode-text)))
 334
 335 (defun nntp-request-last (&optional newsgroup server)
 336   "Decrease the current article pointer."
 337   (nntp-possibly-change-server newsgroup server)
 338   (nntp-send-command "^[23].*\r$" "LAST"))
 339
 340 (defun nntp-request-next (&optional newsgroup server)
 341   "Advance the current article pointer."
 342   (nntp-possibly-change-server newsgroup server)
 343   (nntp-send-command "^[23].*\r$" "NEXT"))
 344
 345 (defun nntp-request-post (&optional server)
 346   "Post the current buffer."
 347   (nntp-possibly-change-server nil server)
 348   (if (nntp-send-command "^[23].*\r$" "POST")
 349       (progn
 350         (nntp-encode-text)
 351         (nntp-send-region-to-server (point-min) (point-max))
 352         ;; 1.2a NNTP's post command is buggy. "^M" (\r) is not
 353         ;;  appended to end of the status message.
 354         (nntp-wait-for-response "^[23].*$"))))
 355
 356 (defun nntp-request-post-buffer
 357   (post group subject header article-buffer info follow-to respect-poster)
 358   "Request a buffer suitable for composing an article.
 359 If POST, this is an original article; otherwise it's a followup.
 360 GROUP is the group to be posted to, the article should have subject
 361 SUBJECT.  HEADER is a Gnus header vector.  ARTICLE-BUFFER contains the
 362 article being followed up.  INFO is a Gnus info list.  If FOLLOW-TO,
 363 post to this group instead.  If RESPECT-POSTER, heed the special
 364 \"poster\" value of the Followup-to header."
 365   (if (assq 'to-address (nth 4 info))
 366       (nnmail-request-post-buffer
 367        post group subject header article-buffer info follow-to respect-poster)
 368     (let (from date to followup-to newsgroups message-of
 369                references distribution message-id)
 370       (save-excursion
 371         (set-buffer (get-buffer-create "*post-news*"))
 372         (news-reply-mode)
 373         (if (and (buffer-modified-p)
 374                  (> (buffer-size) 0)
 375                  (not (y-or-n-p "Unsent article being composed; erase it? ")))
 376             ()
 377           (erase-buffer)
 378           (if post
 379               (news-setup nil subject nil group nil)
 380             (save-excursion
 381               (set-buffer article-buffer)
 382               (goto-char (point-min))
 383               (narrow-to-region (point-min)
 384                                 (progn (search-forward "\n\n") (point)))
 385               (setq from (header-from header))
 386               (setq date (header-date header))
 387               (and from
 388                    (let ((stop-pos
 389                           (string-match "  *at \\|  *@ \\| *(\\| *<" from)))
 390                      (setq
 391                       message-of
 392                       (concat (if stop-pos (substring from 0 stop-pos) from)
 393                               "'s message of " date))))
 394               (setq subject (or subject (header-subject header)))
 395               (or (string-match "^[Rr][Ee]:" subject)
 396                   (setq subject (concat "Re: " subject)))
 397               (setq followup-to (mail-fetch-field "followup-to"))
 398               (if (or (null respect-poster) ;Ignore followup-to: field.
 399                       (string-equal "" followup-to) ;Bogus header.
 400                       (string-equal "poster" followup-to)) ;Poster
 401                   (setq followup-to nil))
 402               (setq newsgroups
 403                     (or follow-to followup-to (mail-fetch-field "newsgroups")))
 404               (setq references (header-references header))
 405               (setq distribution (mail-fetch-field "distribution"))
 406               ;; Remove bogus distribution.
 407               (and (stringp distribution)
 408                    (string-match "world" distribution)
 409                    (setq distribution nil))
 410               (setq message-id (header-id header))
 411               (widen))
 412             (setq news-reply-yank-from from)
 413             (setq news-reply-yank-message-id message-id)
 414             (news-setup to subject message-of newsgroups article-buffer)
 415             ;; Fold long references line to follow RFC1036.
 416             (mail-position-on-field "References")
 417             (let ((begin (- (point) (length "References: ")))
 418                   (fill-column 79)
 419                   (fill-prefix "\t"))
 420               (if references (insert references))
 421               (if (and references message-id) (insert " "))
 422               (if message-id (insert message-id))
 423               ;; The region must end with a newline to fill the region
 424               ;; without inserting extra newline.
 425               (fill-region-as-paragraph begin (1+ (point))))
 426             (if distribution
 427                 (progn
 428                   (mail-position-on-field "Distribution")
 429                   (insert distribution)))))
 430         (current-buffer)))))
 431
 432 ;;; Internal functions.
 433
 434 (defun nntp-send-mode-reader ()
 435   "Send the MODE READER command to the nntp server.
 436 This function is supposed to be called from `nntp-server-opened-hook'.
 437 It will make innd servers spawn an nnrpd process to allow actual article
 438 reading."
 439   (nntp-send-command "^.*\r$" "MODE READER"))
 440
 441 (defun nntp-send-authinfo ()
 442   "Send the AUTHINFO to the nntp server.
 443 This function is supposed to be called from `nntp-server-opened-hook'.
 444 It will prompt for a password."
 445   (nntp-send-command "^.*\r$" "AUTHINFO USER" (user-login-name))
 446   (nntp-send-command "^.*\r$" "AUTHINFO PASS" (read-string "NNTP password: ")))
 447
 448 (defun nntp-default-sentinel (proc status)
 449   "Default sentinel function for NNTP server process."
 450   (let ((servers nntp-server-alist))
 451     ;; Go through the alist of server names and find the name of the
 452     ;; server that the process that sent the signal is connected to.
 453     ;; If you get my drift.
 454     (while (and servers
 455                 (not (equal proc (nth 1 (car servers)))))
 456       (setq servers (cdr servers)))
 457     (message "nntp: Connection closed to server %s."
 458              (or (car (car servers)) "(none)"))
 459     (ding)))
 460
 461 (defun nntp-kill-connection (server)
 462   (let ((proc (nth 1 (assoc server nntp-server-alist))))
 463     (if proc (delete-process (process-name proc)))
 464     (nntp-close-server server)
 465     (setq nntp-status-string
 466           (message "Connection timed out to server %s." server))
 467     (ding)))
 468
 469 ;; Encoding and decoding of NNTP text.
 470
 471 (defun nntp-decode-text ()
 472   "Decode text transmitted by NNTP.
 473 0. Delete status line.
 474 1. Delete `^M' at end of line.
 475 2. Delete `.' at end of buffer (end of text mark).
 476 3. Delete `.' at beginning of line."
 477   (save-excursion
 478     (set-buffer nntp-server-buffer)
 479     ;; Insert newline at end of buffer.
 480     (goto-char (point-max))
 481     (or (bolp) (insert "\n"))
 482     ;; Delete status line.
 483     (goto-char (point-min))
 484     (delete-region (point) (progn (forward-line 1) (point)))
 485     ;; Delete `^M' at the end of lines.
 486     (while (not (eobp))
 487       (end-of-line)
 488       (and (= (preceding-char) ?\r)
 489            (delete-char -1))
 490       (forward-line 1))
 491     ;; Delete `.' at end of the buffer (end of text mark).
 492     (goto-char (point-max))
 493     (forward-line -1)
 494     (if (looking-at "^\\.$")
 495         (delete-region (point) (progn (forward-line 1) (point))))
 496     ;; Replace `..' at beginning of line with `.'.
 497     (goto-char (point-min))
 498     ;; (replace-regexp "^\\.\\." ".")
 499     (while (search-forward "\n.." nil t)
 500       (delete-char -1))))
 501
 502 (defun nntp-encode-text ()
 503   "Encode text in current buffer for NNTP transmission.
 504 1. Insert `.' at beginning of line.
 505 2. Insert `.' at end of buffer (end of text mark)."
 506   (save-excursion
 507     ;; Insert newline at end of buffer.
 508     (goto-char (point-max))
 509     (or (bolp) (insert "\n"))
 510     ;; Replace `.' at beginning of line with `..'.
 511     (goto-char (point-min))
 512     ;; (replace-regexp "^\\." "..")
 513     (while (search-forward "\n." nil t)
 514       (insert "."))
 515     ;; Insert `.' at end of buffer (end of text mark).
 516     (goto-char (point-max))
 517     (insert ".\r\n")))
 518
 519 \f
 520 ;;;
 521 ;;; Synchronous Communication with NNTP Server.
 522 ;;;
 523
 524 (defun nntp-send-command (response cmd &rest args)
 525   "Wait for server RESPONSE after sending CMD and optional ARGS to server."
 526   (save-excursion
 527     ;; Clear communication buffer.
 528     (set-buffer nntp-server-buffer)
 529     (erase-buffer)
 530     (apply 'nntp-send-strings-to-server cmd args)
 531     (if response
 532         (nntp-wait-for-response response)
 533       t)))
 534
 535 (defun nntp-wait-for-response (regexp)
 536   "Wait for server response which matches REGEXP."
 537   (save-excursion
 538     (let ((status t)
 539           (wait t)
 540           (dotnum 0)                    ;Number of "." being displayed.
 541           (dotsize                      ;How often "." displayed.
 542            (if (numberp nntp-debug-read) nntp-debug-read 10000)))
 543       (set-buffer nntp-server-buffer)
 544       ;; Wait for status response (RFC977).
 545       ;; 1xx - Informative message.
 546       ;; 2xx - Command ok.
 547       ;; 3xx - Command ok so far, send the rest of it.
 548       ;; 4xx - Command was correct, but couldn't be performed for some
 549       ;;       reason.
 550       ;; 5xx - Command unimplemented, or incorrect, or a serious
 551       ;;       program error occurred.
 552       (nntp-accept-response)
 553       (while wait
 554         (goto-char (point-min))
 555         (cond ((looking-at "[23]")
 556                (setq wait nil))
 557               ((looking-at "[45]")
 558                (setq status nil)
 559                (setq wait nil))
 560               (t (nntp-accept-response))))
 561       ;; Save status message.
 562       (end-of-line)
 563       (setq nntp-status-string
 564             (buffer-substring (point-min) (point)))
 565       (if status
 566           (progn
 567             (setq wait t)
 568             (while wait
 569               (goto-char (point-max))
 570               (forward-line -1)         ;(beginning-of-line)
 571               ;;(message (buffer-substring
 572               ;;         (point)
 573               ;;         (save-excursion (end-of-line) (point))))
 574               (if (looking-at regexp)
 575                   (setq wait nil)
 576                 (if nntp-debug-read
 577                     (let ((newnum (/ (buffer-size) dotsize)))
 578                       (if (not (= dotnum newnum))
 579                           (progn
 580                             (setq dotnum newnum)
 581                             (message "NNTP: Reading %s"
 582                                      (make-string dotnum ?.))))))
 583                 (nntp-accept-response)))
 584             ;; Remove "...".
 585             (if (and nntp-debug-read (> dotnum 0))
 586                 (message ""))
 587             ;; Successfully received server response.
 588             t)))))
 589
 590 \f
 591 ;;;
 592 ;;; Low-Level Interface to NNTP Server.
 593 ;;;
 594
 595 (defun nntp-retrieve-headers-with-xover (sequence)
 596   (if (not nntp-server-xover)
 597       ()
 598     (let ((range (format "%d-%d" (car sequence)
 599                          (nntp-last-element sequence))))
 600       (prog1
 601           (if (stringp nntp-server-xover)
 602               (nntp-send-command "^\\.\r$" nntp-server-xover range)
 603             (let ((commands nntp-xover-commands))
 604               (while (and commands
 605                           (eq t nntp-server-xover))
 606                 (nntp-send-command "^\\.\r$" (car commands) range)
 607                 (save-excursion
 608                   (set-buffer nntp-server-buffer)
 609                   (goto-char 1)
 610                   (if (looking-at "[23]")
 611                       (setq nntp-server-xover (car commands))))
 612                 (setq commands (cdr commands)))
 613               (if (eq t nntp-server-xover)
 614                   (setq nntp-server-xover nil))
 615               (setcar (nthcdr 2 (assoc nntp-current-server nntp-server-alist))
 616                       nntp-server-xover)
 617               nntp-server-xover))
 618         (if nntp-server-xover (nntp-decode-text) (erase-buffer))))))
 619
 620 (defun nntp-send-strings-to-server (&rest strings)
 621   "Send list of STRINGS to news server as command and its arguments."
 622   (let ((cmd (car strings))
 623         (strings (cdr strings)))
 624     ;; Command and each argument must be separated by one or more spaces.
 625     (while strings
 626       (setq cmd (concat cmd " " (car strings)))
 627       (setq strings (cdr strings)))
 628     ;; Command line must be terminated by a CR-LF.
 629     (if (not (nntp-server-opened nntp-current-server))
 630         (progn
 631           (nntp-close-server nntp-current-server)
 632           (if (not (nntp-open-server nntp-current-server))
 633               (error (nntp-status-message)))
 634           (save-excursion
 635             (set-buffer nntp-server-buffer)
 636             (erase-buffer))))
 637     (process-send-string nntp-server-process (concat cmd "\r\n"))))
 638
 639 (defun nntp-send-region-to-server (begin end)
 640   "Send current buffer region (from BEGIN to END) to news server."
 641   (save-excursion
 642     ;; We have to work in the buffer associated with NNTP server
 643     ;;  process because of NEmacs hack.
 644     (copy-to-buffer nntp-server-buffer begin end)
 645     (set-buffer nntp-server-buffer)
 646     (setq begin (point-min))
 647     (setq end (point-max))
 648     ;; `process-send-region' does not work if text to be sent is very
 649     ;;  large. I don't know maximum size of text sent correctly.
 650     (let ((last nil)
 651           (size 100))                   ;Size of text sent at once.
 652       (save-restriction
 653         (narrow-to-region begin end)
 654         (goto-char begin)
 655         (while (not (eobp))
 656           ;;(setq last (min end (+ (point) size)))
 657           ;; NEmacs gets confused if character at `last' is Kanji.
 658           (setq last (save-excursion
 659                        (goto-char (min end (+ (point) size)))
 660                        (or (eobp) (forward-char 1)) ;Adjust point
 661                        (point)))
 662           (process-send-region nntp-server-process (point) last)
 663           ;; I don't know whether the next codes solve the known
 664           ;;  problem of communication error of GNU Emacs.
 665           (accept-process-output)
 666           ;;(sit-for 0)
 667           (goto-char last))))
 668     ;; We cannot erase buffer, because reply may be received.
 669     (delete-region begin end)))
 670
 671 (defun nntp-open-server-internal (server &optional service)
 672   "Open connection to news server on SERVER by SERVICE (default is nntp)."
 673   (let (proc)
 674     (save-excursion
 675       ;; Use TCP/IP stream emulation package if needed.
 676       (or (fboundp 'open-network-stream)
 677           (require 'tcp))
 678       ;; Initialize communication buffer.
 679       (nnheader-init-server-buffer)
 680       (set-buffer nntp-server-buffer)
 681       (if (setq proc
 682                 (condition-case nil
 683                     (open-network-stream
 684                      "nntpd" (current-buffer) server (or service "nntp"))
 685                   (error nil)))
 686           (progn
 687             (setq nntp-server-process proc)
 688             ;; Suggested by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>.
 689             (process-kill-without-query proc)
 690             (setq nntp-server-xover t)
 691             (setq nntp-server-name server)
 692             (setq nntp-server-alist (cons (list server nntp-server-process t)
 693                                           nntp-server-alist))
 694             ;; It is possible to change kanji-fileio-code in this hook.
 695             (run-hooks 'nntp-server-hook)
 696             nntp-server-process)))))
 697
 698 (defun nntp-close-server-internal (&optional server)
 699   "Close connection to news server."
 700   (nntp-possibly-change-server nil server)
 701   (if nntp-server-process
 702       (delete-process nntp-server-process))
 703   (setq nntp-server-process nil)
 704   (setq nntp-server-alist (delq (assoc nntp-current-server nntp-server-alist)
 705                                 nntp-server-alist))
 706   (setq nntp-current-server ""))
 707
 708 (defun nntp-request-close ()
 709   "Close all server connections."
 710   (while nntp-server-alist
 711     (delete-process (car (cdr (car nntp-server-alist))))
 712     (setq nntp-server-alist (cdr nntp-server-alist)))
 713   (setq nntp-current-server "")
 714   (setq nntp-server-process nil))
 715
 716 (defun nntp-accept-response ()
 717   "Read response of server.
 718 It is well-known that the communication speed will be much improved by
 719 defining this function as macro."
 720   ;; To deal with server process exiting before
 721   ;;  accept-process-output is called.
 722   ;; Suggested by Jason Venner <jason@violet.berkeley.edu>.
 723   ;; This is a copy of `nntp-default-sentinel'.
 724   (if (or (not nntp-server-process)
 725           (not (memq (process-status nntp-server-process) '(open run))))
 726       (error (format "nntp: Process connection closed"))
 727     (if nntp-buggy-select
 728         (progn
 729           ;; We cannot use `accept-process-output'.
 730           ;; Fujitsu UTS requires messages during sleep-for. I don't know why.
 731           (message "NNTP: Reading...")
 732           (sleep-for 1)
 733           (message ""))
 734       (condition-case errorcode
 735           (accept-process-output nntp-server-process)
 736         (error
 737          (cond ((string-equal "select error: Invalid argument"
 738                               (nth 1 errorcode))
 739                 ;; Ignore select error.
 740                 nil)
 741                (t
 742                 (signal (car errorcode) (cdr errorcode)))))))))
 743
 744 (defun nntp-last-element (list)
 745   "Return last element of LIST."
 746   (while (cdr list)
 747     (setq list (cdr list)))
 748   (car list))
 749
 750 (defun nntp-possibly-change-server (newsgroup server)
 751   (let (result changed-server)
 752     ;; First see if we need to change the server - or even open a new
 753     ;; server.
 754     (if (and server (not (string= server nntp-current-server)))
 755         (progn
 756           ;; Fix by Sudish Joseph <joseph@cis.ohio-state.edu>.
 757           (if (or (assoc server nntp-server-alist)
 758                   (nntp-open-server server))
 759               ;; `nntp-open-server' may change `nntp-server-alist', so
 760               ;; we assoc again.
 761               (let ((info (assoc server nntp-server-alist)))
 762                 (setq nntp-current-server server)
 763                 ;; Variable for backwards compatability.
 764                 (setq nntp-server-name server)
 765                 (setq nntp-server-process (nth 1 info))
 766                 (setq nntp-server-xover (nth 2 info))
 767                 (setq changed-server t)
 768                 (setq result t))))
 769       (setq result t))
 770     ;; The we see whether it is necessary to change newsgroup.
 771     (and newsgroup result
 772          (or (not (string= newsgroup nntp-current-group))
 773              changed-server)
 774          (progn
 775            (setq result (nntp-request-group newsgroup server))
 776            (setq nntp-current-group newsgroup)))
 777     result))
 778
 779 (provide 'nntp)
 780
 781 ;;; nntp.el ends here