cgit.sxemacs.org Git - gnus/blob - lisp/nntp.el

   1 ;;; nntp.el --- NNTP (RFC977) Interface for GNU Emacs
   2 ;; Copyright (C) 1987,88,89,90,92,93,94,95 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'rnews)
  29 (require 'nnheader)
  30
  31 (eval-and-compile
  32   (autoload 'news-setup "rnewspost")
  33   (autoload 'news-reply-mode "rnewspost")
  34   (autoload 'nnmail-request-post-buffer "nnmail")
  35   (autoload 'cancel-timer "timer"))
  36
  37 (defvar nntp-server-hook nil
  38   "Hooks for the NNTP server.
  39 If the kanji code of the NNTP server is different from the local kanji
  40 code, the correct kanji code of the buffer associated with the NNTP
  41 server must be specified as follows:
  42
  43 \(setq nntp-server-hook
  44       (function
  45        (lambda ()
  46          ;; Server's Kanji code is EUC (NEmacs hack).
  47          (make-local-variable 'kanji-fileio-code)
  48          (setq kanji-fileio-code 0))))
  49
  50 If you'd like to change something depending on the server in this
  51 hook, use the variable `nntp-server-name'.")
  52
  53 (defvar nntp-server-opened-hook nil
  54   "Hook used for sending commands to the server at startup.  The
  55 default value is `nntp-send-mode-reader', whick makes an innd server
  56 spawn an nnrpd server.  Another useful function to put in this hook
  57 might be `nntp-send-authinfo', which will prompt for a password to
  58 allow posting from the server.  Note that this is only necessary to do
  59 on servers that use strict access control.")
  60 (add-hook 'nntp-server-opened-hook 'nntp-send-mode-reader)
  61
  62 (defvar nntp-large-newsgroup 50
  63   "The number of the articles which indicates a large newsgroup.
  64 If the number of the articles is greater than the value, verbose
  65 messages will be shown to indicate the current status.")
  66
  67 (defvar nntp-buggy-select (memq system-type '(usg-unix-v fujitsu-uts))
  68   "t if your select routine is buggy.
  69 If the select routine signals error or fall into infinite loop while
  70 waiting for the server response, the variable must be set to t.  In
  71 case of Fujitsu UTS, it is set to T since `accept-process-output'
  72 doesn't work properly.")
  73
  74 (defvar nntp-maximum-request 400
  75   "The maximum number of the requests sent to the NNTP server at one time.
  76 If Emacs hangs up while retrieving headers, set the variable to a
  77 lower value.")
  78
  79 (defvar nntp-debug-read 10000
  80   "Display '...' every 10Kbytes of a message being received if it is non-nil.
  81 If it is a number, dots are displayed per the number.")
  82
  83 (defvar nntp-nov-is-evil nil
  84   "If non-nil, nntp will never attempt to use XOVER when talking to the server.")
  85
  86 (defvar nntp-xover-commands '("XOVER" "XOVERVIEW")
  87   "List of strings that are used as commands to fetch NOV lines from a server.
  88 The strings are tried in turn until a positive response is gotten. If
  89 none of the commands are successful, nntp will just grab headers one
  90 by one.")
  91
  92 (defvar nntp-connection-timeout nil
  93   "Number of seconds to wait before an nntp connection times out.
  94 If this variable is nil, which is the default, no timers are set.")
  95
  96 \f
  97 (defconst nntp-version "nntp 4.0"
  98   "Version numbers of this version of NNTP.")
  99
 100 (defvar nntp-server-name nil
 101   "The name of the NNTP server.")
 102
 103 (defvar nntp-server-buffer nil
 104   "Buffer associated with the NNTP server process.")
 105
 106 (defvar nntp-server-process nil
 107   "The NNTP server process.
 108 You'd better not use this variable in NNTP front-end program, but
 109 instead use `nntp-server-buffer'.")
 110
 111 (defvar nntp-status-string nil
 112   "Save the server response message.
 113 You'd better not use this variable in NNTP front-end program but
 114 instead call function `nntp-status-message' to get status message.")
 115
 116 (defvar nntp-current-server "")
 117 (defvar nntp-server-alist nil)
 118 (defvar nntp-server-xover t)
 119 (defvar nntp-current-group "")
 120
 121 ;;; Interface funtions.
 122
 123 (defun nntp-retrieve-headers (sequence &optional newsgroup server)
 124   "Retrieve the headers to the articles in SEQUENCE."
 125   (nntp-possibly-change-server newsgroup server)
 126   (save-excursion
 127     (set-buffer nntp-server-buffer)
 128     (erase-buffer)
 129     (if (and (not gnus-nov-is-evil)
 130              (not nntp-nov-is-evil)
 131              (nntp-retrieve-headers-with-xover sequence))
 132         'nov
 133       (let ((number (length sequence))
 134             (count 0)
 135             (received 0)
 136             (last-point (point-min)))
 137         ;; Send HEAD command.
 138         (while sequence
 139           (nntp-send-strings-to-server "HEAD" (car sequence))
 140           (setq sequence (cdr sequence))
 141           (setq count (1+ count))
 142           ;; Every 400 header requests we have to read stream in order
 143           ;;  to avoid deadlock.
 144           (if (or (null sequence)       ;All requests have been sent.
 145                   (zerop (% count nntp-maximum-request)))
 146               (progn
 147                 (accept-process-output)
 148                 (while (progn
 149                          (goto-char last-point)
 150                          ;; Count replies.
 151                          (while (re-search-forward "^[0-9]" nil t)
 152                            (setq received (1+ received)))
 153                          (setq last-point (point))
 154                          (< received count))
 155                   ;; If number of headers is greater than 100, give
 156                   ;;  informative messages.
 157                   (and (numberp nntp-large-newsgroup)
 158                        (> number nntp-large-newsgroup)
 159                        (zerop (% received 20))
 160                        (message "NNTP: Receiving headers... %d%%"
 161                                 (/ (* received 100) number)))
 162                   (nntp-accept-response)))))
 163         ;; Wait for text of last command.
 164         (goto-char (point-max))
 165         (re-search-backward "^[0-9]" nil t)
 166         (if (looking-at "^[23]")
 167             (while (progn
 168                      (goto-char (- (point-max) 3))
 169                      (not (looking-at "^\\.\r$")))
 170               (nntp-accept-response)))
 171         (and (numberp nntp-large-newsgroup)
 172              (> number nntp-large-newsgroup)
 173              (message "NNTP: Receiving headers... done"))
 174
 175         ;; Now all of replies are received.
 176         (setq received number)
 177         ;; First, fold continuation lines.
 178         (goto-char (point-min))
 179         (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
 180           (replace-match " " t t))
 181         ;; Remove all "\r"'s
 182         (goto-char (point-min))
 183         (while (re-search-forward "\r" nil t)
 184           (replace-match "" t t))
 185         'headers))))
 186
 187 (defun nntp-open-server (server &optional service)
 188   "Open news server on SERVER.
 189 If SERVER is nil, use value of environment variable `NNTPSERVER'.
 190 If optional argument SERVICE is non-nil, open by the service name."
 191   (let ((server (or server (getenv "NNTPSERVER")))
 192         (status nil)
 193         (timer
 194          (and nntp-connection-timeout
 195               (run-at-time nntp-connection-timeout
 196                            nil 'nntp-kill-connection server))))
 197     (setq nntp-status-string "")
 198     (message "nntp: Connecting to server on %s..." server)
 199     (cond ((and server (nntp-open-server-internal server service))
 200            (setq nntp-current-server server)
 201            (condition-case nil
 202                (setq status (nntp-wait-for-response "^[23].*\r$"))
 203              (error (nntp-close-server-internal server)))
 204            (and nntp-server-process
 205                 (progn
 206                   (set-process-sentinel
 207                    nntp-server-process 'nntp-default-sentinel)
 208                   ;; You can send commands at startup like AUTHINFO here.
 209                   ;; Added by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>
 210                   (run-hooks 'nntp-server-opened-hook))))
 211           ((null server)
 212            (setq nntp-status-string "NNTP server is not specified.")))
 213     (and timer (cancel-timer timer))
 214     (message "")
 215     status))
 216
 217 (defun nntp-close-server (&optional server)
 218   "Close news server."
 219   (nntp-possibly-change-server nil server)
 220   (unwind-protect
 221       (progn
 222         ;; Un-set default sentinel function before closing connection.
 223         (and nntp-server-process
 224              (eq 'nntp-default-sentinel
 225                  (process-sentinel nntp-server-process))
 226              (set-process-sentinel nntp-server-process nil))
 227         ;; We cannot send QUIT command unless the process is running.
 228         (if (nntp-server-opened)
 229             (nntp-send-command nil "QUIT")))
 230     (nntp-close-server-internal server)))
 231
 232 (fset 'nntp-request-quit (symbol-function 'nntp-close-server))
 233
 234 (defun nntp-server-opened (&optional server)
 235   "Return server process status.
 236 If the stream is opened, return non-nil, otherwise return nil."
 237   (if (or server nntp-current-server)
 238       (let ((process (nth 1 (assoc (or server nntp-current-server)
 239                                    nntp-server-alist))))
 240         (and process
 241              (memq (process-status process) '(open run))))))
 242
 243 (defun nntp-status-message (&optional server)
 244   "Return server status response as string."
 245   (if (and nntp-status-string
 246            ;; NNN MESSAGE
 247            (string-match "[0-9][0-9][0-9][ \t]+\\([^\r]*\\).*$"
 248                          nntp-status-string))
 249       (substring nntp-status-string (match-beginning 1) (match-end 1))
 250     ;; Empty message if nothing.
 251     nntp-status-string))
 252
 253 (defun nntp-request-article (id &optional newsgroup server buffer)
 254   "Select article by message ID (or number)."
 255   (nntp-possibly-change-server newsgroup server)
 256   (unwind-protect
 257       (progn
 258         (if buffer (set-process-buffer nntp-server-process buffer))
 259         (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
 260           ;; If NEmacs, end of message may look like: "\256\215" (".^M")
 261           (prog1
 262               (nntp-send-command "^\\.\r$" "ARTICLE" id)
 263             (nntp-decode-text))))
 264     (if buffer (set-process-buffer nntp-server-process nntp-server-buffer))))
 265
 266 (defun nntp-request-body (id &optional newsgroup server)
 267   "Select article body by message ID (or number)."
 268   (nntp-possibly-change-server newsgroup server)
 269   (prog1
 270       ;; If NEmacs, end of message may look like: "\256\215" (".^M")
 271       (nntp-send-command "^\\.\r$" "BODY" id)
 272     (nntp-decode-text)))
 273
 274 (defun nntp-request-head (id &optional newsgroup server)
 275   "Select article head by message ID (or number)."
 276   (nntp-possibly-change-server newsgroup server)
 277   (prog1
 278       (nntp-send-command "^\\.\r$" "HEAD" id)
 279     (nntp-decode-text)))
 280
 281 (defun nntp-request-stat (id &optional newsgroup server)
 282   "Select article by message ID (or number)."
 283   (nntp-possibly-change-server newsgroup server)
 284   (nntp-send-command "^[23].*\r$" "STAT" id))
 285
 286 (defun nntp-request-group (group &optional server dont-check)
 287   "Select news GROUP."
 288   (if (nntp-possibly-change-server nil server)
 289       (nntp-send-command "^.*\r$" "GROUP" group)))
 290
 291 (defun nntp-request-group-description (group &optional server)
 292   "Select news GROUP."
 293   (if (nntp-possibly-change-server nil server)
 294       (nntp-send-command "^.*\r$" "XGTITLE" group)))
 295
 296 (defun nntp-close-group (group &optional server)
 297   t)
 298
 299 (defun nntp-request-list (&optional server)
 300   "List active newsgroups."
 301   (nntp-possibly-change-server nil server)
 302   (prog1
 303       (nntp-send-command "^\\.\r$" "LIST")
 304     (nntp-decode-text)))
 305
 306 (defun nntp-request-list-newsgroups (&optional server)
 307   "List newsgroups (defined in NNTP2)."
 308   (nntp-possibly-change-server nil server)
 309   (prog1
 310       (nntp-send-command "^\\.\r$" "LIST NEWSGROUPS")
 311     (nntp-decode-text)))
 312
 313 (defun nntp-request-newgroups (date &optional server)
 314   "List new groups (defined in NNTP2)."
 315   (nntp-possibly-change-server nil server)
 316   (let ((date (timezone-parse-date date))
 317         (time-string
 318          (format "%s%02d%02d %s%s%s"
 319                  (substring (aref date 0) 2) (string-to-int (aref date 1))
 320                  (string-to-int (aref date 2)) (substring (aref date 3) 0 2)
 321                  (substring (aref date 3) 3 5) (substring (aref date 3) 6 8))))
 322     (prog1
 323         (nntp-send-command "^\\.\r$" "NEWGROUPS" time-string)
 324       (nntp-decode-text))))
 325
 326 (defun nntp-request-list-distributions (&optional server)
 327   "List distributions (defined in NNTP2)."
 328   (nntp-possibly-change-server nil server)
 329   (prog1
 330       (nntp-send-command "^\\.\r$" "LIST DISTRIBUTIONS")
 331     (nntp-decode-text)))
 332
 333 (defun nntp-request-last (&optional newsgroup server)
 334   "Set current article pointer to the previous article
 335 in the current news group."
 336   (nntp-possibly-change-server newsgroup server)
 337   (nntp-send-command "^[23].*\r$" "LAST"))
 338
 339 (defun nntp-request-next (&optional newsgroup server)
 340   "Advance current article pointer."
 341   (nntp-possibly-change-server newsgroup server)
 342   (nntp-send-command "^[23].*\r$" "NEXT"))
 343
 344 (defun nntp-request-post (&optional server)
 345   "Post a new news in current buffer."
 346   (nntp-possibly-change-server nil server)
 347   (if (nntp-send-command "^[23].*\r$" "POST")
 348       (progn
 349         (nntp-encode-text)
 350         (nntp-send-region-to-server (point-min) (point-max))
 351         ;; 1.2a NNTP's post command is buggy. "^M" (\r) is not
 352         ;;  appended to end of the status message.
 353         (nntp-wait-for-response "^[23].*$"))))
 354
 355 (defun nntp-request-post-buffer
 356   (post group subject header article-buffer info follow-to
 357         respect-poster)
 358   (if (assq 'to-address (nth 4 info))
 359       (nnmail-request-post-buffer
 360        post group subject header article-buffer info follow-to respect-poster)
 361     (let (from date to followup-to newsgroups message-of
 362                references distribution message-id)
 363       (save-excursion
 364         (set-buffer (get-buffer-create "*post-news*"))
 365         (news-reply-mode)
 366         (if (and (buffer-modified-p)
 367                  (> (buffer-size) 0)
 368                  (not (y-or-n-p "Unsent article being composed; erase it? ")))
 369             ()
 370           (erase-buffer)
 371           (if post
 372               (news-setup nil subject nil group nil)
 373             (save-excursion
 374               (set-buffer article-buffer)
 375               (goto-char (point-min))
 376               (narrow-to-region (point-min)
 377                                 (progn (search-forward "\n\n") (point)))
 378               (setq from (header-from header))
 379               (setq date (header-date header))
 380               (and from
 381                    (let ((stop-pos
 382                           (string-match "  *at \\|  *@ \\| *(\\| *<" from)))
 383                      (setq
 384                       message-of
 385                       (concat (if stop-pos (substring from 0 stop-pos) from)
 386                               "'s message of " date))))
 387               (setq subject (or subject (header-subject header)))
 388               (or (string-match "^[Rr][Ee]:" subject)
 389                   (setq subject (concat "Re: " subject)))
 390               (setq followup-to (mail-fetch-field "followup-to"))
 391               (if (or (null respect-poster) ;Ignore followup-to: field.
 392                       (string-equal "" followup-to) ;Bogus header.
 393                       (string-equal "poster" followup-to)) ;Poster
 394                   (setq followup-to nil))
 395               (setq newsgroups
 396                     (or follow-to followup-to (mail-fetch-field "newsgroups")))
 397               (setq references (header-references header))
 398               (setq distribution (mail-fetch-field "distribution"))
 399               ;; Remove bogus distribution.
 400               (and (stringp distribution)
 401                    (string-match "world" distribution)
 402                    (setq distribution nil))
 403               (setq message-id (header-id header))
 404               (widen))
 405             (setq news-reply-yank-from from)
 406             (setq news-reply-yank-message-id message-id)
 407             (news-setup to subject message-of newsgroups article-buffer)
 408             ;; Fold long references line to follow RFC1036.
 409             (mail-position-on-field "References")
 410             (let ((begin (- (point) (length "References: ")))
 411                   (fill-column 79)
 412                   (fill-prefix "\t"))
 413               (if references (insert references))
 414               (if (and references message-id) (insert " "))
 415               (if message-id (insert message-id))
 416               ;; The region must end with a newline to fill the region
 417               ;; without inserting extra newline.
 418               (fill-region-as-paragraph begin (1+ (point))))
 419             (if distribution
 420                 (progn
 421                   (mail-position-on-field "Distribution")
 422                   (insert distribution)))))
 423         (current-buffer)))))
 424
 425 ;;; Internal functions.
 426
 427 (defun nntp-send-mode-reader ()
 428   "Send the MODE READER command to the nntp server.
 429 This function is supposed to be called from `nntp-server-opened-hook'.
 430 It will make innd servers enter nnrpd mode to allow actual article
 431 reading."
 432   (nntp-send-command "^.*\r$" "MODE READER"))
 433
 434 (defun nntp-send-authinfo ()
 435   "Send the AUTHINFO to the nntp server.
 436 This function is supposed to be called from `nntp-server-opened-hook'.
 437 It will prompt for a password."
 438   (nntp-send-command "^.*\r$" "AUTHINFO USER" (user-login-name))
 439   (nntp-send-command "^.*\r$" "AUTHINFO PASS" (read-string "NNTP password: ")))
 440
 441 (defun nntp-default-sentinel (proc status)
 442   "Default sentinel function for NNTP server process."
 443   (let ((servers nntp-server-alist))
 444     ;; Go through the alist of server names and find the name of the
 445     ;; server that the process that sent the signal is connected to.
 446     ;; If you get my drift.
 447     (while (and servers
 448                 (not (equal proc (nth 1 (car servers)))))
 449       (setq servers (cdr servers)))
 450     (message "nntp: Connection closed to server %s."
 451              (or (car (car servers)) "(none)"))
 452     (ding)))
 453
 454 (defun nntp-kill-connection (server)
 455   (let ((proc (nth 1 (assoc server nntp-server-alist))))
 456     (if proc (delete-process (process-name proc)))
 457     (nntp-close-server server)
 458     (setq nntp-status-string
 459           (message "Connection timed out to server %s." server))
 460     (ding)))
 461
 462 ;; Encoding and decoding of NNTP text.
 463
 464 (defun nntp-decode-text ()
 465   "Decode text transmitted by NNTP.
 466 0. Delete status line.
 467 1. Delete `^M' at end of line.
 468 2. Delete `.' at end of buffer (end of text mark).
 469 3. Delete `.' at beginning of line."
 470   (save-excursion
 471     (set-buffer nntp-server-buffer)
 472     ;; Insert newline at end of buffer.
 473     (goto-char (point-max))
 474     (if (not (bolp))
 475         (insert "\n"))
 476     ;; Delete status line.
 477     (goto-char (point-min))
 478     (delete-region (point) (progn (forward-line 1) (point)))
 479     ;; Delete `^M' at end of line.
 480     ;; (replace-regexp "\r$" "")
 481     (while (not (eobp))
 482       (end-of-line)
 483       (if (= (preceding-char) ?\r)
 484           (delete-char -1))
 485       (forward-line 1))
 486     ;; Delete `.' at end of buffer (end of text mark).
 487     (goto-char (point-max))
 488     (forward-line -1)                   ;(beginning-of-line)
 489     (if (looking-at "^\\.$")
 490         (delete-region (point) (progn (forward-line 1) (point))))
 491     ;; Replace `..' at beginning of line with `.'.
 492     (goto-char (point-min))
 493     ;; (replace-regexp "^\\.\\." ".")
 494     (while (search-forward "\n.." nil t)
 495       (delete-char -1))))
 496
 497 (defun nntp-encode-text ()
 498   "Encode text in current buffer for NNTP transmission.
 499 1. Insert `.' at beginning of line.
 500 2. Insert `.' at end of buffer (end of text mark)."
 501   (save-excursion
 502     ;; Insert newline at end of buffer.
 503     (goto-char (point-max))
 504     (if (not (bolp))
 505         (insert "\n"))
 506     ;; Replace `.' at beginning of line with `..'.
 507     (goto-char (point-min))
 508     ;; (replace-regexp "^\\." "..")
 509     (while (search-forward "\n." nil t)
 510       (insert "."))
 511     ;; Insert `.' at end of buffer (end of text mark).
 512     (goto-char (point-max))
 513     (insert ".\r\n")))
 514
 515 \f
 516 ;;;
 517 ;;; Synchronous Communication with NNTP Server.
 518 ;;;
 519
 520 (defun nntp-send-command (response cmd &rest args)
 521   "Wait for server RESPONSE after sending CMD and optional ARGS to server."
 522   (save-excursion
 523     ;; Clear communication buffer.
 524     (set-buffer nntp-server-buffer)
 525     (erase-buffer)
 526     (apply 'nntp-send-strings-to-server cmd args)
 527     (if response
 528         (nntp-wait-for-response response)
 529       t)))
 530
 531 (defun nntp-wait-for-response (regexp)
 532   "Wait for server response which matches REGEXP."
 533   (save-excursion
 534     (let ((status t)
 535           (wait t)
 536           (dotnum 0)                    ;Number of "." being displayed.
 537           (dotsize                      ;How often "." displayed.
 538            (if (numberp nntp-debug-read) nntp-debug-read 10000)))
 539       (set-buffer nntp-server-buffer)
 540       ;; Wait for status response (RFC977).
 541       ;; 1xx - Informative message.
 542       ;; 2xx - Command ok.
 543       ;; 3xx - Command ok so far, send the rest of it.
 544       ;; 4xx - Command was correct, but couldn't be performed for some
 545       ;;       reason.
 546       ;; 5xx - Command unimplemented, or incorrect, or a serious
 547       ;;       program error occurred.
 548       (nntp-accept-response)
 549       (while wait
 550         (goto-char (point-min))
 551         (cond ((looking-at "[23]")
 552                (setq wait nil))
 553               ((looking-at "[45]")
 554                (setq status nil)
 555                (setq wait nil))
 556               (t (nntp-accept-response))))
 557       ;; Save status message.
 558       (end-of-line)
 559       (setq nntp-status-string
 560             (buffer-substring (point-min) (point)))
 561       (if status
 562           (progn
 563             (setq wait t)
 564             (while wait
 565               (goto-char (point-max))
 566               (forward-line -1)         ;(beginning-of-line)
 567               ;;(message (buffer-substring
 568               ;;         (point)
 569               ;;         (save-excursion (end-of-line) (point))))
 570               (if (looking-at regexp)
 571                   (setq wait nil)
 572                 (if nntp-debug-read
 573                     (let ((newnum (/ (buffer-size) dotsize)))
 574                       (if (not (= dotnum newnum))
 575                           (progn
 576                             (setq dotnum newnum)
 577                             (message "NNTP: Reading %s"
 578                                      (make-string dotnum ?.))))))
 579                 (nntp-accept-response)))
 580             ;; Remove "...".
 581             (if (and nntp-debug-read (> dotnum 0))
 582                 (message ""))
 583             ;; Successfully received server response.
 584             t)))))
 585
 586 \f
 587 ;;;
 588 ;;; Low-Level Interface to NNTP Server.
 589 ;;;
 590
 591 (defun nntp-retrieve-headers-with-xover (sequence)
 592   (if (not nntp-server-xover)
 593       ()
 594     (let ((range (format "%d-%d" (car sequence)
 595                          (nntp-last-element sequence))))
 596       (prog1
 597           (if (stringp nntp-server-xover)
 598               (nntp-send-command "^\\.\r$" nntp-server-xover range)
 599             (let ((commands nntp-xover-commands))
 600               (while (and commands
 601                           (eq t nntp-server-xover))
 602                 (nntp-send-command "^\\.\r$" (car commands) range)
 603                 (save-excursion
 604                   (set-buffer nntp-server-buffer)
 605                   (goto-char 1)
 606                   (if (looking-at "[23]")
 607                       (setq nntp-server-xover (car commands))))
 608                 (setq commands (cdr commands)))
 609               (if (eq t nntp-server-xover)
 610                   (setq nntp-server-xover nil))
 611               (setcar (nthcdr 2 (assoc nntp-current-server nntp-server-alist))
 612                       nntp-server-xover)
 613               nntp-server-xover))
 614         (if nntp-server-xover (nntp-decode-text) (erase-buffer))))))
 615
 616 (defun nntp-send-strings-to-server (&rest strings)
 617   "Send list of STRINGS to news server as command and its arguments."
 618   (let ((cmd (car strings))
 619         (strings (cdr strings)))
 620     ;; Command and each argument must be separated by one or more spaces.
 621     (while strings
 622       (setq cmd (concat cmd " " (car strings)))
 623       (setq strings (cdr strings)))
 624     ;; Command line must be terminated by a CR-LF.
 625     (if (not (nntp-server-opened nntp-current-server))
 626         (progn
 627           (nntp-close-server nntp-current-server)
 628           (if (not (nntp-open-server nntp-current-server))
 629               (error (nntp-status-message)))
 630           (save-excursion
 631             (set-buffer nntp-server-buffer)
 632             (erase-buffer))))
 633     (process-send-string nntp-server-process (concat cmd "\r\n"))))
 634
 635 (defun nntp-send-region-to-server (begin end)
 636   "Send current buffer region (from BEGIN to END) to news server."
 637   (save-excursion
 638     ;; We have to work in the buffer associated with NNTP server
 639     ;;  process because of NEmacs hack.
 640     (copy-to-buffer nntp-server-buffer begin end)
 641     (set-buffer nntp-server-buffer)
 642     (setq begin (point-min))
 643     (setq end (point-max))
 644     ;; `process-send-region' does not work if text to be sent is very
 645     ;;  large. I don't know maximum size of text sent correctly.
 646     (let ((last nil)
 647           (size 100))                   ;Size of text sent at once.
 648       (save-restriction
 649         (narrow-to-region begin end)
 650         (goto-char begin)
 651         (while (not (eobp))
 652           ;;(setq last (min end (+ (point) size)))
 653           ;; NEmacs gets confused if character at `last' is Kanji.
 654           (setq last (save-excursion
 655                        (goto-char (min end (+ (point) size)))
 656                        (or (eobp) (forward-char 1)) ;Adjust point
 657                        (point)))
 658           (process-send-region nntp-server-process (point) last)
 659           ;; I don't know whether the next codes solve the known
 660           ;;  problem of communication error of GNU Emacs.
 661           (accept-process-output)
 662           ;;(sit-for 0)
 663           (goto-char last))))
 664     ;; We cannot erase buffer, because reply may be received.
 665     (delete-region begin end)))
 666
 667 (defun nntp-open-server-internal (server &optional service)
 668   "Open connection to news server on SERVER by SERVICE (default is nntp)."
 669   (let (proc)
 670     (save-excursion
 671       ;; Use TCP/IP stream emulation package if needed.
 672       (or (fboundp 'open-network-stream)
 673           (require 'tcp))
 674       ;; Initialize communication buffer.
 675       (nnheader-init-server-buffer)
 676       (set-buffer nntp-server-buffer)
 677       (if (setq proc
 678                 (condition-case nil
 679                     (open-network-stream
 680                      "nntpd" (current-buffer) server (or service "nntp"))
 681                   (error nil)))
 682           (progn
 683             (setq nntp-server-process proc)
 684             ;; Suggested by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>.
 685             (process-kill-without-query proc)
 686             (setq nntp-server-xover t)
 687             (setq nntp-server-name server)
 688             (setq nntp-server-alist (cons (list server nntp-server-process t)
 689                                           nntp-server-alist))
 690             ;; It is possible to change kanji-fileio-code in this hook.
 691             (run-hooks 'nntp-server-hook)
 692             nntp-server-process)))))
 693
 694 (defun nntp-close-server-internal (&optional server)
 695   "Close connection to news server."
 696   (nntp-possibly-change-server nil server)
 697   (if nntp-server-process
 698       (delete-process nntp-server-process))
 699   (setq nntp-server-process nil)
 700   (setq nntp-server-alist (delq (assoc nntp-current-server nntp-server-alist)
 701                                 nntp-server-alist))
 702   (setq nntp-current-server ""))
 703
 704 (defun nntp-request-close ()
 705   "Close all server connections."
 706   (while nntp-server-alist
 707     (delete-process (car (cdr (car nntp-server-alist))))
 708     (setq nntp-server-alist (cdr nntp-server-alist)))
 709   (setq nntp-current-server "")
 710   (setq nntp-server-process nil))
 711
 712 (defun nntp-accept-response ()
 713   "Read response of server.
 714 It is well-known that the communication speed will be much improved by
 715 defining this function as macro."
 716   ;; To deal with server process exiting before
 717   ;;  accept-process-output is called.
 718   ;; Suggested by Jason Venner <jason@violet.berkeley.edu>.
 719   ;; This is a copy of `nntp-default-sentinel'.
 720   (if (or (not nntp-server-process)
 721           (not (memq (process-status nntp-server-process) '(open run))))
 722       (error (format "nntp: Process connection closed"))
 723     (if nntp-buggy-select
 724         (progn
 725           ;; We cannot use `accept-process-output'.
 726           ;; Fujitsu UTS requires messages during sleep-for. I don't know why.
 727           (message "NNTP: Reading...")
 728           (sleep-for 1)
 729           (message ""))
 730       (condition-case errorcode
 731           (accept-process-output nntp-server-process)
 732         (error
 733          (cond ((string-equal "select error: Invalid argument"
 734                               (nth 1 errorcode))
 735                 ;; Ignore select error.
 736                 nil)
 737                (t
 738                 (signal (car errorcode) (cdr errorcode)))))))))
 739
 740 (defun nntp-last-element (list)
 741   "Return last element of LIST."
 742   (while (cdr list)
 743     (setq list (cdr list)))
 744   (car list))
 745
 746 (defun nntp-possibly-change-server (newsgroup server)
 747   (let (result changed-server)
 748     ;; First see if we need to change the server - or even open a new
 749     ;; server.
 750     (if (and server (not (string= server nntp-current-server)))
 751         (progn
 752           ;; Fix by Sudish Joseph <joseph@cis.ohio-state.edu>.
 753           (if (or (assoc server nntp-server-alist)
 754                   (nntp-open-server server))
 755               ;; `nntp-open-server' may change `nntp-server-alist', so
 756               ;; we assoc again.
 757               (let ((info (assoc server nntp-server-alist)))
 758                 (setq nntp-current-server server)
 759                 ;; Variable for backwards compatability.
 760                 (setq nntp-server-name server)
 761                 (setq nntp-server-process (nth 1 info))
 762                 (setq nntp-server-xover (nth 2 info))
 763                 (setq changed-server t)
 764                 (setq result t))))
 765       (setq result t))
 766     ;; The we see whether it is necessary to change newsgroup.
 767     (and newsgroup result
 768          (or (not (string= newsgroup nntp-current-group))
 769              changed-server)
 770          (progn
 771            (setq result (nntp-request-group newsgroup server))
 772            (setq nntp-current-group newsgroup)))
 773     result))
 774
 775 (provide 'nntp)
 776
 777 ;;; nntp.el ends here