cgit.sxemacs.org Git - gnus/blob - lisp/nntp.el

   1 ;;; nntp.el --- nntp access for Gnus
   2 ;; Copyright (C) 1987, 1988, 1989, 1990, 1992, 1993, 1994, 1995, 1996,
   3 ;;        1997, 1998, 2000
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'nnheader)
  30 (require 'nnoo)
  31 (require 'gnus-util)
  32
  33 (nnoo-declare nntp)
  34
  35 (eval-when-compile (require 'cl))
  36
  37 (defvoo nntp-address nil
  38   "Address of the physical nntp server.")
  39
  40 (defvoo nntp-port-number "nntp"
  41   "Port number on the physical nntp server.")
  42
  43 (defvoo nntp-server-opened-hook '(nntp-send-mode-reader)
  44   "*Hook used for sending commands to the server at startup.
  45 The default value is `nntp-send-mode-reader', which makes an innd
  46 server spawn an nnrpd server.")
  47
  48 (defvoo nntp-authinfo-function 'nntp-send-authinfo
  49   "Function used to send AUTHINFO to the server.
  50 It is called with no parameters.")
  51
  52 (defvoo nntp-server-action-alist
  53     '(("nntpd 1\\.5\\.11t"
  54        (remove-hook 'nntp-server-opened-hook 'nntp-send-mode-reader))
  55       ("NNRP server Netscape"
  56        (setq nntp-server-list-active-group nil)))
  57   "Alist of regexps to match on server types and actions to be taken.
  58 For instance, if you want Gnus to beep every time you connect
  59 to innd, you could say something like:
  60
  61 \(setq nntp-server-action-alist
  62        '((\"innd\" (ding))))
  63
  64 You probably don't want to do that, though.")
  65
  66 (defvoo nntp-open-connection-function 'nntp-open-network-stream
  67   "*Function used for connecting to a remote system.
  68 It will be called with the buffer to output in.
  69
  70 Two pre-made functions are `nntp-open-network-stream', which is the
  71 default, and simply connects to some port or other on the remote
  72 system (see nntp-port-number).  The other are `nntp-open-rlogin',
  73 which does an rlogin on the remote system, and then does a telnet to
  74 the NNTP server available there (see nntp-rlogin-parameters) and
  75 `nntp-open-telnet' which telnets to a remote system, logs in and does
  76 the same.")
  77
  78 (defvoo nntp-rlogin-program "rsh"
  79   "*Program used to log in on remote machines.
  80 The default is \"rsh\", but \"ssh\" is a popular alternative.")
  81
  82 (defvoo nntp-rlogin-parameters '("telnet" "-8" "${NNTPSERVER:=news}" "nntp")
  83   "*Parameters to `nntp-open-rlogin'.
  84 That function may be used as `nntp-open-connection-function'.  In that
  85 case, this list will be used as the parameter list given to rsh.")
  86
  87 (defvoo nntp-rlogin-user-name nil
  88   "*User name on remote system when using the rlogin connect method.")
  89
  90 (defvoo nntp-telnet-parameters
  91     '("exec" "telnet" "-8" "${NNTPSERVER:=news}" "nntp")
  92   "*Parameters to `nntp-open-telnet'.
  93 That function may be used as `nntp-open-connection-function'.  In that
  94 case, this list will be executed as a command after logging in
  95 via telnet.")
  96
  97 (defvoo nntp-telnet-user-name nil
  98   "User name to log in via telnet with.")
  99
 100 (defvoo nntp-telnet-passwd nil
 101   "Password to use to log in via telnet with.")
 102
 103 (defvoo nntp-open-telnet-envuser nil
 104   "*If non-nil, telnet session (client and server both) will support the ENVIRON option and not prompt for login name.")
 105
 106 (defvoo nntp-telnet-shell-prompt "bash\\|\$ *\r?$\\|> *\r?"
 107   "*Regular expression to match the shell prompt on the remote machine.")
 108
 109 (defvoo nntp-telnet-command "telnet"
 110   "Command used to start telnet.")
 111
 112 (defvoo nntp-telnet-switches '("-8")
 113   "Switches given to the telnet command.")
 114
 115 (defvoo nntp-end-of-line "\r\n"
 116   "String to use on the end of lines when talking to the NNTP server.
 117 This is \"\\r\\n\" by default, but should be \"\\n\" when
 118 using rlogin or telnet to communicate with the server.")
 119
 120 (defvoo nntp-large-newsgroup 50
 121   "*The number of the articles which indicates a large newsgroup.
 122 If the number of the articles is greater than the value, verbose
 123 messages will be shown to indicate the current status.")
 124
 125 (defvoo nntp-maximum-request 400
 126   "*The maximum number of the requests sent to the NNTP server at one time.
 127 If Emacs hangs up while retrieving headers, set the variable to a
 128 lower value.")
 129
 130 (defvoo nntp-nov-is-evil nil
 131   "*If non-nil, nntp will never attempt to use XOVER when talking to the server.")
 132
 133 (defvoo nntp-xover-commands '("XOVER" "XOVERVIEW")
 134   "*List of strings that are used as commands to fetch NOV lines from a server.
 135 The strings are tried in turn until a positive response is gotten.  If
 136 none of the commands are successful, nntp will just grab headers one
 137 by one.")
 138
 139 (defvoo nntp-nov-gap 5
 140   "*Maximum allowed gap between two articles.
 141 If the gap between two consecutive articles is bigger than this
 142 variable, split the XOVER request into two requests.")
 143
 144 (defvoo nntp-prepare-server-hook nil
 145   "*Hook run before a server is opened.
 146 If can be used to set up a server remotely, for instance.  Say you
 147 have an account at the machine \"other.machine\".  This machine has
 148 access to an NNTP server that you can't access locally.  You could
 149 then use this hook to rsh to the remote machine and start a proxy NNTP
 150 server there that you can connect to.  See also
 151 `nntp-open-connection-function'")
 152
 153 (defvoo nntp-warn-about-losing-connection t
 154   "*If non-nil, beep when a server closes connection.")
 155
 156 (defvoo nntp-coding-system-for-read 'binary
 157   "*Coding system to read from NNTP.")
 158
 159 (defvoo nntp-coding-system-for-write 'binary
 160   "*Coding system to write to NNTP.")
 161
 162 (defcustom nntp-authinfo-file "~/.authinfo"
 163   ".netrc-like file that holds nntp authinfo passwords."
 164   :type
 165   '(choice file
 166            (repeat :tag "Entries"
 167                    :menu-tag "Inline"
 168                    (list :format "%v"
 169                          :value ("" ("login" . "") ("password" . ""))
 170                          (string :tag "Host")
 171                          (checklist :inline t
 172                                     (cons :format "%v"
 173                                           (const :format "" "login")
 174                                           (string :format "Login: %v"))
 175                                     (cons :format "%v"
 176                                           (const :format "" "password")
 177                                           (string :format "Password: %v")))))))
 178
 179 \f
 180
 181 (defvoo nntp-connection-timeout nil
 182   "*Number of seconds to wait before an nntp connection times out.
 183 If this variable is nil, which is the default, no timers are set.")
 184
 185 ;;; Internal variables.
 186
 187 (defvar nntp-record-commands nil
 188   "*If non-nil, nntp will record all commands in the \"*nntp-log*\" buffer.")
 189
 190 (defvar nntp-have-messaged nil)
 191
 192 (defvar nntp-process-wait-for nil)
 193 (defvar nntp-process-to-buffer nil)
 194 (defvar nntp-process-callback nil)
 195 (defvar nntp-process-decode nil)
 196 (defvar nntp-process-start-point nil)
 197 (defvar nntp-inside-change-function nil)
 198 (defvoo nntp-last-command-time nil)
 199 (defvoo nntp-last-command nil)
 200 (defvoo nntp-authinfo-password nil)
 201 (defvoo nntp-authinfo-user nil)
 202
 203 (defvar nntp-connection-list nil)
 204
 205 (defvoo nntp-server-type nil)
 206 (defvoo nntp-connection-alist nil)
 207 (defvoo nntp-status-string "")
 208 (defconst nntp-version "nntp 5.0")
 209 (defvoo nntp-inhibit-erase nil)
 210 (defvoo nntp-inhibit-output nil)
 211
 212 (defvoo nntp-server-xover 'try)
 213 (defvoo nntp-server-list-active-group 'try)
 214
 215 (defvar nntp-async-needs-kluge
 216   (string-match "^GNU Emacs 20\\.3\\." (emacs-version))
 217   "*When non-nil, nntp will poll asynchronous connections
 218 once a second.  By default, this is turned on only for Emacs
 219 20.3, which has a bug that breaks nntp's normal method of
 220 noticing asynchronous data.")
 221
 222 (defvar nntp-async-timer nil)
 223 (defvar nntp-async-process-list nil)
 224
 225 (eval-and-compile
 226   (autoload 'mail-source-read-passwd "mail-source")
 227   (autoload 'open-ssl-stream "ssl"))
 228
 229 \f
 230
 231 ;;; Internal functions.
 232
 233 (defsubst nntp-send-string (process string)
 234   "Send STRING to PROCESS."
 235   ;; We need to store the time to provide timeouts, and
 236   ;; to store the command so the we can replay the command
 237   ;; if the server gives us an AUTHINFO challenge.
 238   (setq nntp-last-command-time (current-time)
 239         nntp-last-command string)
 240   (when nntp-record-commands
 241     (nntp-record-command string))
 242   (process-send-string process (concat string nntp-end-of-line)))
 243
 244 (defun nntp-record-command (string)
 245   "Record the command STRING."
 246   (save-excursion
 247     (set-buffer (get-buffer-create "*nntp-log*"))
 248     (goto-char (point-max))
 249     (let ((time (current-time)))
 250       (insert (format-time-string "%Y%m%dT%H%M%S" time)
 251               "." (format "%03d" (/ (nth 2 time) 1000))
 252               " " nntp-address " " string "\n"))))
 253
 254 (defsubst nntp-wait-for (process wait-for buffer &optional decode discard)
 255   "Wait for WAIT-FOR to arrive from PROCESS."
 256   (save-excursion
 257     (set-buffer (process-buffer process))
 258     (goto-char (point-min))
 259     (while (and (or (not (memq (char-after (point)) '(?2 ?3 ?4 ?5)))
 260                     (looking-at "480"))
 261                 (memq (process-status process) '(open run)))
 262       (when (looking-at "480")
 263         (nntp-handle-authinfo process))
 264       (nntp-accept-process-output process)
 265       (goto-char (point-min)))
 266     (prog1
 267         (cond
 268          ((looking-at "[45]")
 269           (progn
 270             (nntp-snarf-error-message)
 271             nil))
 272          ((not (memq (process-status process) '(open run)))
 273           (nnheader-report 'nntp "Server closed connection"))
 274          (t
 275           (goto-char (point-max))
 276           (let ((limit (point-min)))
 277             (while (not (re-search-backward wait-for limit t))
 278               (nntp-accept-process-output process)
 279               ;; We assume that whatever we wait for is less than 1000
 280               ;; characters long.
 281               (setq limit (max (- (point-max) 1000) (point-min)))
 282               (goto-char (point-max))))
 283           (nntp-decode-text (not decode))
 284           (unless discard
 285             (save-excursion
 286               (set-buffer buffer)
 287               (goto-char (point-max))
 288               (insert-buffer-substring (process-buffer process))
 289               ;; Nix out "nntp reading...." message.
 290               (when nntp-have-messaged
 291                 (setq nntp-have-messaged nil)
 292                 (nnheader-message 5 ""))
 293               t))))
 294       (unless discard
 295         (erase-buffer)))))
 296
 297 (defun nntp-kill-buffer (buffer)
 298   (when (buffer-name buffer)
 299     (kill-buffer buffer)
 300     (nnheader-init-server-buffer)))
 301
 302 (defsubst nntp-find-connection (buffer)
 303   "Find the connection delivering to BUFFER."
 304   (let ((alist nntp-connection-alist)
 305         (buffer (if (stringp buffer) (get-buffer buffer) buffer))
 306         process entry)
 307     (while (setq entry (pop alist))
 308       (when (eq buffer (cadr entry))
 309         (setq process (car entry)
 310               alist nil)))
 311     (when process
 312       (if (memq (process-status process) '(open run))
 313           process
 314         (nntp-kill-buffer (process-buffer process))
 315         (setq nntp-connection-alist (delq entry nntp-connection-alist))
 316         nil))))
 317
 318 (defsubst nntp-find-connection-entry (buffer)
 319   "Return the entry for the connection to BUFFER."
 320   (assq (nntp-find-connection buffer) nntp-connection-alist))
 321
 322 (defun nntp-find-connection-buffer (buffer)
 323   "Return the process connection buffer tied to BUFFER."
 324   (let ((process (nntp-find-connection buffer)))
 325     (when process
 326       (process-buffer process))))
 327
 328 (defsubst nntp-retrieve-data (command address port buffer
 329                                       &optional wait-for callback decode)
 330   "Use COMMAND to retrieve data into BUFFER from PORT on ADDRESS."
 331   (let ((process (or (nntp-find-connection buffer)
 332                      (nntp-open-connection buffer))))
 333     (if (not process)
 334         (nnheader-report 'nntp "Couldn't open connection to %s" address)
 335       (unless (or nntp-inhibit-erase nnheader-callback-function)
 336         (save-excursion
 337           (set-buffer (process-buffer process))
 338           (erase-buffer)))
 339       (condition-case err
 340           (progn
 341             (when command
 342               (nntp-send-string process command))
 343             (cond
 344              ((eq callback 'ignore)
 345               t)
 346              ((and callback wait-for)
 347               (nntp-async-wait process wait-for buffer decode callback)
 348               t)
 349              (wait-for
 350               (nntp-wait-for process wait-for buffer decode))
 351              (t t)))
 352         (error
 353          (nnheader-report 'nntp "Couldn't open connection to %s: %s"
 354                           address err))
 355         (quit
 356          (message "Quit retrieving data from nntp")
 357          (signal 'quit nil)
 358          nil)))))
 359
 360 (defsubst nntp-send-command (wait-for &rest strings)
 361   "Send STRINGS to server and wait until WAIT-FOR returns."
 362   (when (and (not nnheader-callback-function)
 363              (not nntp-inhibit-output))
 364     (save-excursion
 365       (set-buffer nntp-server-buffer)
 366       (erase-buffer)))
 367   (nntp-retrieve-data
 368    (mapconcat 'identity strings " ")
 369    nntp-address nntp-port-number nntp-server-buffer
 370    wait-for nnheader-callback-function))
 371
 372 (defun nntp-send-command-nodelete (wait-for &rest strings)
 373   "Send STRINGS to server and wait until WAIT-FOR returns."
 374   (nntp-retrieve-data
 375    (mapconcat 'identity strings " ")
 376    nntp-address nntp-port-number nntp-server-buffer
 377    wait-for nnheader-callback-function))
 378
 379 (defun nntp-send-command-and-decode (wait-for &rest strings)
 380   "Send STRINGS to server and wait until WAIT-FOR returns."
 381   (when (and (not nnheader-callback-function)
 382              (not nntp-inhibit-output))
 383     (save-excursion
 384       (set-buffer nntp-server-buffer)
 385       (erase-buffer)))
 386   (nntp-retrieve-data
 387    (mapconcat 'identity strings " ")
 388    nntp-address nntp-port-number nntp-server-buffer
 389    wait-for nnheader-callback-function t))
 390
 391 (defun nntp-send-buffer (wait-for)
 392   "Send the current buffer to server and wait until WAIT-FOR returns."
 393   (when (and (not nnheader-callback-function)
 394              (not nntp-inhibit-output))
 395     (save-excursion
 396       (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 397       (erase-buffer)))
 398   (nntp-encode-text)
 399   (process-send-region (nntp-find-connection nntp-server-buffer)
 400                        (point-min) (point-max))
 401   (nntp-retrieve-data
 402    nil nntp-address nntp-port-number nntp-server-buffer
 403    wait-for nnheader-callback-function))
 404
 405 \f
 406
 407 ;;; Interface functions.
 408
 409 (nnoo-define-basics nntp)
 410
 411 (defsubst nntp-next-result-arrived-p ()
 412   (cond
 413    ;; A result that starts with a 2xx code is terminated by
 414    ;; a line with only a "." on it.
 415    ((eq (char-after) ?2)
 416     (if (re-search-forward "\n\\.\r?\n" nil t)
 417         t
 418       nil))
 419    ;; A result that starts with a 3xx or 4xx code is terminated
 420    ;; by a newline.
 421    ((looking-at "[34]")
 422     (if (search-forward "\n" nil t)
 423         t
 424       nil))
 425    ;; No result here.
 426    (t
 427     nil)))
 428
 429 (deffoo nntp-retrieve-headers (articles &optional group server fetch-old)
 430   "Retrieve the headers of ARTICLES."
 431   (nntp-possibly-change-group group server)
 432   (save-excursion
 433     (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 434     (erase-buffer)
 435     (if (and (not gnus-nov-is-evil)
 436              (not nntp-nov-is-evil)
 437              (nntp-retrieve-headers-with-xover articles fetch-old))
 438         ;; We successfully retrieved the headers via XOVER.
 439         'nov
 440       ;; XOVER didn't work, so we do it the hard, slow and inefficient
 441       ;; way.
 442       (let ((number (length articles))
 443             (count 0)
 444             (received 0)
 445             (last-point (point-min))
 446             (buf (nntp-find-connection-buffer nntp-server-buffer))
 447             (nntp-inhibit-erase t)
 448             article)
 449         ;; Send HEAD commands.
 450         (while (setq article (pop articles))
 451           (nntp-send-command
 452            nil
 453            "HEAD" (if (numberp article)
 454                       (int-to-string article)
 455                     ;; `articles' is either a list of article numbers
 456                     ;; or a list of article IDs.
 457                     article))
 458           (incf count)
 459           ;; Every 400 requests we have to read the stream in
 460           ;; order to avoid deadlocks.
 461           (when (or (null articles)     ;All requests have been sent.
 462                     (zerop (% count nntp-maximum-request)))
 463             (nntp-accept-response)
 464             (while (progn
 465                      (set-buffer buf)
 466                      (goto-char last-point)
 467                      ;; Count replies.
 468                      (while (nntp-next-result-arrived-p)
 469                        (setq last-point (point))
 470                        (incf received))
 471                      (< received count))
 472               ;; If number of headers is greater than 100, give
 473               ;;  informative messages.
 474               (and (numberp nntp-large-newsgroup)
 475                    (> number nntp-large-newsgroup)
 476                    (zerop (% received 20))
 477                    (nnheader-message 6 "NNTP: Receiving headers... %d%%"
 478                                      (/ (* received 100) number)))
 479               (nntp-accept-response))))
 480         (and (numberp nntp-large-newsgroup)
 481              (> number nntp-large-newsgroup)
 482              (nnheader-message 6 "NNTP: Receiving headers...done"))
 483
 484         ;; Now all of replies are received.  Fold continuation lines.
 485         (nnheader-fold-continuation-lines)
 486         ;; Remove all "\r"'s.
 487         (nnheader-strip-cr)
 488         (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 489         'headers))))
 490
 491 (deffoo nntp-retrieve-groups (groups &optional server)
 492   "Retrieve group info on GROUPS."
 493   (nntp-possibly-change-group nil server)
 494   (when (nntp-find-connection-buffer nntp-server-buffer)
 495     (save-excursion
 496       ;; Erase nntp-server-buffer before nntp-inhibit-erase.
 497       (set-buffer nntp-server-buffer)
 498       (erase-buffer)
 499       (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 500       ;; The first time this is run, this variable is `try'.  So we
 501       ;; try.
 502       (when (eq nntp-server-list-active-group 'try)
 503         (nntp-try-list-active (car groups)))
 504       (erase-buffer)
 505       (let ((count 0)
 506             (received 0)
 507             (last-point (point-min))
 508             (nntp-inhibit-erase t)
 509             (buf (nntp-find-connection-buffer nntp-server-buffer))
 510             (command (if nntp-server-list-active-group "LIST ACTIVE" "GROUP")))
 511         (while groups
 512           ;; Send the command to the server.
 513           (nntp-send-command nil command (pop groups))
 514           (incf count)
 515           ;; Every 400 requests we have to read the stream in
 516           ;; order to avoid deadlocks.
 517           (when (or (null groups)       ;All requests have been sent.
 518                     (zerop (% count nntp-maximum-request)))
 519             (nntp-accept-response)
 520             (while (progn
 521                      ;; Search `blue moon' in this file for the
 522                      ;; reason why set-buffer here.
 523                      (set-buffer buf)
 524                      (goto-char last-point)
 525                      ;; Count replies.
 526                      (while (re-search-forward "^[0-9]" nil t)
 527                        (incf received))
 528                      (setq last-point (point))
 529                      (< received count))
 530               (nntp-accept-response))))
 531
 532         ;; Wait for the reply from the final command.
 533         (set-buffer buf)
 534         (goto-char (point-max))
 535         (re-search-backward "^[0-9]" nil t)
 536         (when (looking-at "^[23]")
 537           (while (progn
 538                    (set-buffer buf)
 539                    (goto-char (point-max))
 540                    (if (not nntp-server-list-active-group)
 541                        (not (re-search-backward "\r?\n" (- (point) 3) t))
 542                      (not (re-search-backward "^\\.\r?\n" (- (point) 4) t))))
 543             (nntp-accept-response)))
 544
 545         ;; Now all replies are received.  We remove CRs.
 546         (set-buffer buf)
 547         (goto-char (point-min))
 548         (while (search-forward "\r" nil t)
 549           (replace-match "" t t))
 550
 551         (if (not nntp-server-list-active-group)
 552             (progn
 553               (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 554               'group)
 555           ;; We have read active entries, so we just delete the
 556           ;; superfluous gunk.
 557           (goto-char (point-min))
 558           (while (re-search-forward "^[.2-5]" nil t)
 559             (delete-region (match-beginning 0)
 560                            (progn (forward-line 1) (point))))
 561           (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 562           'active)))))
 563
 564 (deffoo nntp-retrieve-articles (articles &optional group server)
 565   (nntp-possibly-change-group group server)
 566   (save-excursion
 567     (let ((number (length articles))
 568           (count 0)
 569           (received 0)
 570           (last-point (point-min))
 571           (buf (nntp-find-connection-buffer nntp-server-buffer))
 572           (nntp-inhibit-erase t)
 573           (map (apply 'vector articles))
 574           (point 1)
 575           article)
 576       (set-buffer buf)
 577       (erase-buffer)
 578       ;; Send ARTICLE command.
 579       (while (setq article (pop articles))
 580         (nntp-send-command
 581          nil
 582          "ARTICLE" (if (numberp article)
 583                        (int-to-string article)
 584                      ;; `articles' is either a list of article numbers
 585                      ;; or a list of article IDs.
 586                      article))
 587         (incf count)
 588         ;; Every 400 requests we have to read the stream in
 589         ;; order to avoid deadlocks.
 590         (when (or (null articles)       ;All requests have been sent.
 591                   (zerop (% count nntp-maximum-request)))
 592           (nntp-accept-response)
 593           (while (progn
 594                    (set-buffer buf)
 595                    (goto-char last-point)
 596                    ;; Count replies.
 597                    (while (nntp-next-result-arrived-p)
 598                      (aset map received (cons (aref map received) (point)))
 599                      (setq last-point (point))
 600                      (incf received))
 601                    (< received count))
 602             ;; If number of headers is greater than 100, give
 603             ;;  informative messages.
 604             (and (numberp nntp-large-newsgroup)
 605                  (> number nntp-large-newsgroup)
 606                  (zerop (% received 20))
 607                  (nnheader-message 6 "NNTP: Receiving articles... %d%%"
 608                                    (/ (* received 100) number)))
 609             (nntp-accept-response))))
 610       (and (numberp nntp-large-newsgroup)
 611            (> number nntp-large-newsgroup)
 612            (nnheader-message 6 "NNTP: Receiving articles...done"))
 613
 614       ;; Now we have all the responses.  We go through the results,
 615       ;; wash it and copy it over to the server buffer.
 616       (set-buffer nntp-server-buffer)
 617       (erase-buffer)
 618       (setq last-point (point-min))
 619       (mapcar
 620        (lambda (entry)
 621          (narrow-to-region
 622           (setq point (goto-char (point-max)))
 623           (progn
 624             (insert-buffer-substring buf last-point (cdr entry))
 625             (point-max)))
 626          (setq last-point (cdr entry))
 627          (nntp-decode-text)
 628          (widen)
 629          (cons (car entry) point))
 630        map))))
 631
 632 (defun nntp-try-list-active (group)
 633   (nntp-list-active-group group)
 634   (save-excursion
 635     (set-buffer nntp-server-buffer)
 636     (goto-char (point-min))
 637     (cond ((or (eobp)
 638                (looking-at "5[0-9]+"))
 639            (setq nntp-server-list-active-group nil))
 640           (t
 641            (setq nntp-server-list-active-group t)))))
 642
 643 (deffoo nntp-list-active-group (group &optional server)
 644   "Return the active info on GROUP (which can be a regexp)."
 645   (nntp-possibly-change-group nil server)
 646   (nntp-send-command "^\\.*\r?\n" "LIST ACTIVE" group))
 647
 648 (deffoo nntp-request-group-articles (group &optional server)
 649   "Return the list of existing articles in GROUP."
 650   (nntp-possibly-change-group nil server)
 651   (nntp-send-command "^\\.*\r?\n" "LISTGROUP" group))
 652
 653 (deffoo nntp-request-article (article &optional group server buffer command)
 654   (nntp-possibly-change-group group server)
 655   (when (nntp-send-command-and-decode
 656          "\r?\n\\.\r?\n" "ARTICLE"
 657          (if (numberp article) (int-to-string article) article))
 658     (if (and buffer
 659              (not (equal buffer nntp-server-buffer)))
 660         (save-excursion
 661           (set-buffer nntp-server-buffer)
 662           (copy-to-buffer buffer (point-min) (point-max))
 663           (nntp-find-group-and-number))
 664       (nntp-find-group-and-number))))
 665
 666 (deffoo nntp-request-head (article &optional group server)
 667   (nntp-possibly-change-group group server)
 668   (when (nntp-send-command
 669          "\r?\n\\.\r?\n" "HEAD"
 670          (if (numberp article) (int-to-string article) article))
 671     (prog1
 672         (nntp-find-group-and-number)
 673       (nntp-decode-text))))
 674
 675 (deffoo nntp-request-body (article &optional group server)
 676   (nntp-possibly-change-group group server)
 677   (nntp-send-command-and-decode
 678    "\r?\n\\.\r?\n" "BODY"
 679    (if (numberp article) (int-to-string article) article)))
 680
 681 (deffoo nntp-request-group (group &optional server dont-check)
 682   (nntp-possibly-change-group nil server)
 683   (when (nntp-send-command "^[245].*\n" "GROUP" group)
 684     (let ((entry (nntp-find-connection-entry nntp-server-buffer)))
 685       (setcar (cddr entry) group))))
 686
 687 (deffoo nntp-close-group (group &optional server)
 688   t)
 689
 690 (deffoo nntp-server-opened (&optional server)
 691   "Say whether a connection to SERVER has been opened."
 692   (and (nnoo-current-server-p 'nntp server)
 693        nntp-server-buffer
 694        (gnus-buffer-live-p nntp-server-buffer)
 695        (nntp-find-connection nntp-server-buffer)))
 696
 697 (deffoo nntp-open-server (server &optional defs connectionless)
 698   (nnheader-init-server-buffer)
 699   (if (nntp-server-opened server)
 700       t
 701     (when (or (stringp (car defs))
 702               (numberp (car defs)))
 703       (setq defs (cons (list 'nntp-port-number (car defs)) (cdr defs))))
 704     (unless (assq 'nntp-address defs)
 705       (setq defs (append defs (list (list 'nntp-address server)))))
 706     (nnoo-change-server 'nntp server defs)
 707     (unless connectionless
 708       (or (nntp-find-connection nntp-server-buffer)
 709           (nntp-open-connection nntp-server-buffer)))))
 710
 711 (deffoo nntp-close-server (&optional server)
 712   (nntp-possibly-change-group nil server t)
 713   (let ((process (nntp-find-connection nntp-server-buffer)))
 714     (while process
 715       (when (memq (process-status process) '(open run))
 716         (ignore-errors
 717           (nntp-send-string process "QUIT")
 718           (unless (eq nntp-open-connection-function 'nntp-open-network-stream)
 719             ;; Ok, this is evil, but when using telnet and stuff
 720             ;; as the connection method, it's important that the
 721             ;; QUIT command actually is sent out before we kill
 722             ;; the process.
 723             (sleep-for 1))))
 724       (nntp-kill-buffer (process-buffer process))
 725       (setq process (car (pop nntp-connection-alist))))
 726     (nnoo-close-server 'nntp)))
 727
 728 (deffoo nntp-request-close ()
 729   (let (process)
 730     (while (setq process (pop nntp-connection-list))
 731       (when (memq (process-status process) '(open run))
 732         (ignore-errors
 733           (nntp-send-string process "QUIT")
 734           (unless (eq nntp-open-connection-function 'nntp-open-network-stream)
 735             ;; Ok, this is evil, but when using telnet and stuff
 736             ;; as the connection method, it's important that the
 737             ;; QUIT command actually is sent out before we kill
 738             ;; the process.
 739             (sleep-for 1))))
 740       (nntp-kill-buffer (process-buffer process)))))
 741
 742 (deffoo nntp-request-list (&optional server)
 743   (nntp-possibly-change-group nil server)
 744   (nntp-send-command-and-decode "\r?\n\\.\r?\n" "LIST"))
 745
 746 (deffoo nntp-request-list-newsgroups (&optional server)
 747   (nntp-possibly-change-group nil server)
 748   (nntp-send-command "\r?\n\\.\r?\n" "LIST NEWSGROUPS"))
 749
 750 (deffoo nntp-request-newgroups (date &optional server)
 751   (nntp-possibly-change-group nil server)
 752   (save-excursion
 753     (set-buffer nntp-server-buffer)
 754     (prog1
 755         (nntp-send-command
 756          "^\\.\r?\n" "NEWGROUPS"
 757          (format-time-string "%y%m%d %H%M%S" (date-to-time date)))
 758       (nntp-decode-text))))
 759
 760 (deffoo nntp-request-post (&optional server)
 761   (nntp-possibly-change-group nil server)
 762   (when (nntp-send-command "^[23].*\r?\n" "POST")
 763     (nntp-send-buffer "^[23].*\n")))
 764
 765 (deffoo nntp-request-type (group article)
 766   'news)
 767
 768 (deffoo nntp-asynchronous-p ()
 769   t)
 770
 771 ;;; Hooky functions.
 772
 773 (defun nntp-send-mode-reader ()
 774   "Send the MODE READER command to the nntp server.
 775 This function is supposed to be called from `nntp-server-opened-hook'.
 776 It will make innd servers spawn an nnrpd process to allow actual article
 777 reading."
 778   (nntp-send-command "^.*\n" "MODE READER"))
 779
 780 (defun nntp-send-authinfo (&optional send-if-force)
 781   "Send the AUTHINFO to the nntp server.
 782 It will look in the \"~/.authinfo\" file for matching entries.  If
 783 nothing suitable is found there, it will prompt for a user name
 784 and a password.
 785
 786 If SEND-IF-FORCE, only send authinfo to the server if the
 787 .authinfo file has the FORCE token."
 788   (let* ((list (gnus-parse-netrc nntp-authinfo-file))
 789          (alist (gnus-netrc-machine list nntp-address "nntp"))
 790          (force (gnus-netrc-get alist "force"))
 791          (user (or (gnus-netrc-get alist "login") nntp-authinfo-user))
 792          (passwd (gnus-netrc-get alist "password")))
 793     (when (or (not send-if-force)
 794               force)
 795       (unless user
 796         (setq user (read-string (format "NNTP (%s) user name: " nntp-address))
 797               nntp-authinfo-user user))
 798       (unless (member user '(nil ""))
 799         (nntp-send-command "^3.*\r?\n" "AUTHINFO USER" user)
 800         (when t                         ;???Should check if AUTHINFO succeeded
 801           (nntp-send-command
 802            "^2.*\r?\n" "AUTHINFO PASS"
 803            (or passwd
 804                nntp-authinfo-password
 805                (setq nntp-authinfo-password
 806                      (mail-source-read-passwd
 807                       (format "NNTP (%s@%s) password: "
 808                               user nntp-address))))))))))
 809
 810 (defun nntp-send-nosy-authinfo ()
 811   "Send the AUTHINFO to the nntp server."
 812   (let ((user (read-string (format "NNTP (%s) user name: " nntp-address))))
 813     (unless (member user '(nil ""))
 814       (nntp-send-command "^3.*\r?\n" "AUTHINFO USER" user)
 815       (when t                           ;???Should check if AUTHINFO succeeded
 816         (nntp-send-command "^2.*\r?\n" "AUTHINFO PASS"
 817                            (mail-source-read-passwd "NNTP (%s@%s) password: "
 818                                                     user nntp-address))))))
 819
 820 (defun nntp-send-authinfo-from-file ()
 821   "Send the AUTHINFO to the nntp server.
 822
 823 The authinfo login name is taken from the user's login name and the
 824 password contained in '~/.nntp-authinfo'."
 825   (when (file-exists-p "~/.nntp-authinfo")
 826     (with-temp-buffer
 827       (insert-file-contents "~/.nntp-authinfo")
 828       (goto-char (point-min))
 829       (nntp-send-command "^3.*\r?\n" "AUTHINFO USER" (user-login-name))
 830       (nntp-send-command
 831        "^2.*\r?\n" "AUTHINFO PASS"
 832        (buffer-substring (point) (progn (end-of-line) (point)))))))
 833
 834 ;;; Internal functions.
 835
 836 (defun nntp-handle-authinfo (process)
 837   "Take care of an authinfo response from the server."
 838   (let ((last nntp-last-command))
 839     (funcall nntp-authinfo-function)
 840     ;; We have to re-send the function that was interrupted by
 841     ;; the authinfo request.
 842     (save-excursion
 843       (set-buffer nntp-server-buffer)
 844       (erase-buffer))
 845     (nntp-send-string process last)))
 846
 847 (defun nntp-make-process-buffer (buffer)
 848   "Create a new, fresh buffer usable for nntp process connections."
 849   (save-excursion
 850     (set-buffer
 851      (generate-new-buffer
 852       (format " *server %s %s %s*"
 853               nntp-address nntp-port-number
 854               (gnus-buffer-exists-p buffer))))
 855     (mm-enable-multibyte)
 856     (set (make-local-variable 'after-change-functions) nil)
 857     (set (make-local-variable 'nntp-process-wait-for) nil)
 858     (set (make-local-variable 'nntp-process-callback) nil)
 859     (set (make-local-variable 'nntp-process-to-buffer) nil)
 860     (set (make-local-variable 'nntp-process-start-point) nil)
 861     (set (make-local-variable 'nntp-process-decode) nil)
 862     (current-buffer)))
 863
 864 (defun nntp-open-connection (buffer)
 865   "Open a connection to PORT on ADDRESS delivering output to BUFFER."
 866   (run-hooks 'nntp-prepare-server-hook)
 867   (let* ((pbuffer (nntp-make-process-buffer buffer))
 868          (timer
 869           (and nntp-connection-timeout
 870                (nnheader-run-at-time
 871                 nntp-connection-timeout nil
 872                 `(lambda ()
 873                    (nntp-kill-buffer ,pbuffer)))))
 874          (process
 875           (condition-case ()
 876               (let ((coding-system-for-read nntp-coding-system-for-read)
 877                     (coding-system-for-write nntp-coding-system-for-write))
 878                 (funcall nntp-open-connection-function pbuffer))
 879             (error nil)
 880             (quit
 881              (message "Quit opening connection")
 882              (signal 'quit nil)
 883              nil))))
 884     (when timer
 885       (nnheader-cancel-timer timer))
 886     (when (and (buffer-name pbuffer)
 887                process)
 888       (process-kill-without-query process)
 889       (nntp-wait-for process "^.*\n" buffer nil t)
 890       (if (memq (process-status process) '(open run))
 891           (prog1
 892               (caar (push (list process buffer nil) nntp-connection-alist))
 893             (push process nntp-connection-list)
 894             (save-excursion
 895               (set-buffer pbuffer)
 896               (nntp-read-server-type)
 897               (erase-buffer)
 898               (set-buffer nntp-server-buffer)
 899               (let ((nnheader-callback-function nil))
 900                 (run-hooks 'nntp-server-opened-hook)
 901                 (nntp-send-authinfo t))))
 902         (nntp-kill-buffer (process-buffer process))
 903         nil))))
 904
 905 (defun nntp-open-network-stream (buffer)
 906   (open-network-stream "nntpd" buffer nntp-address nntp-port-number))
 907
 908 (defun nntp-open-ssl-stream (buffer)
 909   (let* ((ssl-program-arguments '("-connect" (concat host ":" service)))
 910          (proc (open-ssl-stream "nntpd" buffer nntp-address nntp-port-number)))
 911     (save-excursion
 912       (set-buffer buffer)
 913       (nntp-wait-for-string "^\r*20[01]")
 914       (beginning-of-line)
 915       (delete-region (point-min) (point))
 916       proc)))
 917
 918 (defun nntp-read-server-type ()
 919   "Find out what the name of the server we have connected to is."
 920   ;; Wait for the status string to arrive.
 921   (setq nntp-server-type (buffer-string))
 922   (let ((alist nntp-server-action-alist)
 923         (case-fold-search t)
 924         entry)
 925     ;; Run server-specific commands.
 926     (while alist
 927       (setq entry (pop alist))
 928       (when (string-match (car entry) nntp-server-type)
 929         (if (and (listp (cadr entry))
 930                  (not (eq 'lambda (caadr entry))))
 931             (eval (cadr entry))
 932           (funcall (cadr entry)))))))
 933
 934 (defun nntp-async-wait (process wait-for buffer decode callback)
 935   (save-excursion
 936     (set-buffer (process-buffer process))
 937     (unless nntp-inside-change-function
 938       (erase-buffer))
 939     (setq nntp-process-wait-for wait-for
 940           nntp-process-to-buffer buffer
 941           nntp-process-decode decode
 942           nntp-process-callback callback
 943           nntp-process-start-point (point-max))
 944     (setq after-change-functions '(nntp-after-change-function))
 945     (if nntp-async-needs-kluge
 946         (nntp-async-kluge process))))
 947
 948 (defun nntp-async-kluge (process)
 949   ;; emacs 20.3 bug: process output with encoding 'binary
 950   ;; doesn't trigger after-change-functions.
 951   (unless nntp-async-timer
 952     (setq nntp-async-timer
 953           (nnheader-run-at-time 1 1 'nntp-async-timer-handler)))
 954   (add-to-list 'nntp-async-process-list process))
 955
 956 (defun nntp-async-timer-handler ()
 957   (mapcar
 958    (lambda (proc)
 959      (if (memq (process-status proc) '(open run))
 960          (nntp-async-trigger proc)
 961        (nntp-async-stop proc)))
 962    nntp-async-process-list))
 963
 964 (defun nntp-async-stop (proc)
 965   (setq nntp-async-process-list (delq proc nntp-async-process-list))
 966   (when (and nntp-async-timer (not nntp-async-process-list))
 967     (nnheader-cancel-timer nntp-async-timer)
 968     (setq nntp-async-timer nil)))
 969
 970 (defun nntp-after-change-function (beg end len)
 971   (unwind-protect
 972       ;; we only care about insertions at eob
 973       (when (and (eq 0 len) (eq (point-max) end))
 974         (save-match-data
 975           (let ((proc (get-buffer-process (current-buffer))))
 976             (when proc
 977               (nntp-async-trigger proc)))))
 978     ;; any throw from after-change-functions will leave it
 979     ;; set to nil.  so we reset it here, if necessary.
 980     (when quit-flag
 981       (setq after-change-functions '(nntp-after-change-function)))))
 982
 983 (defun nntp-async-trigger (process)
 984   (save-excursion
 985     (set-buffer (process-buffer process))
 986     (when nntp-process-callback
 987       ;; do we have an error message?
 988       (goto-char nntp-process-start-point)
 989       (if (memq (following-char) '(?4 ?5))
 990           ;; wants credentials?
 991           (if (looking-at "480")
 992               (nntp-handle-authinfo process)
 993             ;; report error message.
 994             (nntp-snarf-error-message)
 995             (nntp-do-callback nil))
 996
 997         ;; got what we expect?
 998         (goto-char (point-max))
 999         (when (re-search-backward
1000                nntp-process-wait-for nntp-process-start-point t)
1001           (nntp-async-stop process)
1002           ;; convert it.
1003           (when (gnus-buffer-exists-p nntp-process-to-buffer)
1004             (let ((buf (current-buffer))
1005                   (start nntp-process-start-point)
1006                   (decode nntp-process-decode))
1007               (save-excursion
1008                 (set-buffer nntp-process-to-buffer)
1009                 (goto-char (point-max))
1010                 (save-restriction
1011                   (narrow-to-region (point) (point))
1012                   (insert-buffer-substring buf start)
1013                   (when decode
1014                     (nntp-decode-text))))))
1015           ;; report it.
1016           (goto-char (point-max))
1017           (nntp-do-callback
1018            (buffer-name (get-buffer nntp-process-to-buffer))))))))
1019
1020 (defun nntp-do-callback (arg)
1021   (let ((callback nntp-process-callback)
1022         (nntp-inside-change-function t))
1023     (setq nntp-process-callback nil)
1024     (funcall callback arg)))
1025
1026 (defun nntp-snarf-error-message ()
1027   "Save the error message in the current buffer."
1028   (let ((message (buffer-string)))
1029     (while (string-match "[\r\n]+" message)
1030       (setq message (replace-match " " t t message)))
1031     (nnheader-report 'nntp message)
1032     message))
1033
1034 (defun nntp-accept-process-output (process &optional timeout)
1035   "Wait for output from PROCESS and message some dots."
1036   (save-excursion
1037     (set-buffer (or (nntp-find-connection-buffer nntp-server-buffer)
1038                     nntp-server-buffer))
1039     (let ((len (/ (point-max) 1024))
1040           message-log-max)
1041       (unless (< len 10)
1042         (setq nntp-have-messaged t)
1043         (nnheader-message 7 "nntp read: %dk" len)))
1044     (accept-process-output process (or timeout 1))))
1045
1046 (defun nntp-accept-response ()
1047   "Wait for output from the process that outputs to BUFFER."
1048   (nntp-accept-process-output (nntp-find-connection nntp-server-buffer)))
1049
1050 (defun nntp-possibly-change-group (group server &optional connectionless)
1051   (let ((nnheader-callback-function nil))
1052     (when server
1053       (or (nntp-server-opened server)
1054           (nntp-open-server server nil connectionless)))
1055
1056     (unless connectionless
1057       (or (nntp-find-connection nntp-server-buffer)
1058           (nntp-open-connection nntp-server-buffer))))
1059
1060   (when group
1061     (let ((entry (nntp-find-connection-entry nntp-server-buffer)))
1062       (when (not (equal group (caddr entry)))
1063         (save-excursion
1064           (set-buffer (process-buffer (car entry)))
1065           (erase-buffer)
1066           (nntp-send-command "^[245].*\n" "GROUP" group)
1067           (setcar (cddr entry) group)
1068           (erase-buffer))))))
1069
1070 (defun nntp-decode-text (&optional cr-only)
1071   "Decode the text in the current buffer."
1072   (goto-char (point-min))
1073   (while (search-forward "\r" nil t)
1074     (delete-char -1))
1075   (unless cr-only
1076     ;; Remove trailing ".\n" end-of-transfer marker.
1077     (goto-char (point-max))
1078     (forward-line -1)
1079     (when (looking-at ".\n")
1080       (delete-char 2))
1081     ;; Delete status line.
1082     (goto-char (point-min))
1083     (delete-region (point) (progn (forward-line 1) (point)))
1084     ;; Remove "." -> ".." encoding.
1085     (while (search-forward "\n.." nil t)
1086       (delete-char -1))))
1087
1088 (defun nntp-encode-text ()
1089   "Encode the text in the current buffer."
1090   (save-excursion
1091     ;; Replace "." at beginning of line with "..".
1092     (goto-char (point-min))
1093     (while (re-search-forward "^\\." nil t)
1094       (insert "."))
1095     (goto-char (point-max))
1096     ;; Insert newline at the end of the buffer.
1097     (unless (bolp)
1098       (insert "\n"))
1099     ;; Insert `.' at end of buffer (end of text mark).
1100     (goto-char (point-max))
1101     (insert ".\n")
1102     (goto-char (point-min))
1103     (while (not (eobp))
1104       (end-of-line)
1105       (delete-char 1)
1106       (insert nntp-end-of-line))))
1107
1108 (defun nntp-retrieve-headers-with-xover (articles &optional fetch-old)
1109   (set-buffer nntp-server-buffer)
1110   (erase-buffer)
1111   (cond
1112
1113    ;; This server does not talk NOV.
1114    ((not nntp-server-xover)
1115     nil)
1116
1117    ;; We don't care about gaps.
1118    ((or (not nntp-nov-gap)
1119         fetch-old)
1120     (nntp-send-xover-command
1121      (if fetch-old
1122          (if (numberp fetch-old)
1123              (max 1 (- (car articles) fetch-old))
1124            1)
1125        (car articles))
1126      (car (last articles)) 'wait)
1127
1128     (goto-char (point-min))
1129     (when (looking-at "[1-5][0-9][0-9] .*\n")
1130       (delete-region (point) (progn (forward-line 1) (point))))
1131     (while (search-forward "\r" nil t)
1132       (replace-match "" t t))
1133     (goto-char (point-max))
1134     (forward-line -1)
1135     (when (looking-at "\\.")
1136       (delete-region (point) (progn (forward-line 1) (point)))))
1137
1138    ;; We do it the hard way.  For each gap, an XOVER command is sent
1139    ;; to the server.  We do not wait for a reply from the server, we
1140    ;; just send them off as fast as we can.  That means that we have
1141    ;; to count the number of responses we get back to find out when we
1142    ;; have gotten all we asked for.
1143    ((numberp nntp-nov-gap)
1144     (let ((count 0)
1145           (received 0)
1146           last-point
1147           in-process-buffer-p
1148           (buf nntp-server-buffer)
1149           (process-buffer (nntp-find-connection-buffer nntp-server-buffer))
1150           first)
1151       ;; We have to check `nntp-server-xover'.  If it gets set to nil,
1152       ;; that means that the server does not understand XOVER, but we
1153       ;; won't know that until we try.
1154       (while (and nntp-server-xover articles)
1155         (setq first (car articles))
1156         ;; Search forward until we find a gap, or until we run out of
1157         ;; articles.
1158         (while (and (cdr articles)
1159                     (< (- (nth 1 articles) (car articles)) nntp-nov-gap))
1160           (setq articles (cdr articles)))
1161
1162         (setq in-process-buffer-p (stringp nntp-server-xover))
1163         (nntp-send-xover-command first (car articles))
1164         (setq articles (cdr articles))
1165
1166         (when (and nntp-server-xover in-process-buffer-p)
1167           ;; Don't count tried request.
1168           (setq count (1+ count))
1169
1170           ;; Every 400 requests we have to read the stream in
1171           ;; order to avoid deadlocks.
1172           (when (or (null articles)     ;All requests have been sent.
1173                     (zerop (% count nntp-maximum-request)))
1174
1175             (nntp-accept-response)
1176             ;; On some Emacs versions the preceding function has a
1177             ;; tendency to change the buffer.  Perhaps.  It's quite
1178             ;; difficult to reproduce, because it only seems to happen
1179             ;; once in a blue moon.
1180             (set-buffer process-buffer)
1181             (while (progn
1182                      (goto-char (or last-point (point-min)))
1183                      ;; Count replies.
1184                      (while (re-search-forward "^[0-9][0-9][0-9] .*\n" nil t)
1185                        (incf received))
1186                      (setq last-point (point))
1187                      (< received count))
1188               (nntp-accept-response)
1189               (set-buffer process-buffer))
1190             (set-buffer buf))))
1191
1192       (when nntp-server-xover
1193         (when in-process-buffer-p
1194           (set-buffer process-buffer)
1195           ;; Wait for the reply from the final command.
1196           (goto-char (point-max))
1197           (while (not (re-search-backward "^[0-9][0-9][0-9] " nil t))
1198             (nntp-accept-response)
1199             (set-buffer process-buffer)
1200             (goto-char (point-max)))
1201           (when (looking-at "^[23]")
1202             (while (progn
1203                      (goto-char (point-max))
1204                      (forward-line -1)
1205                      (not (looking-at "^\\.\r?\n")))
1206               (nntp-accept-response)
1207               (set-buffer process-buffer)))
1208           (set-buffer buf)
1209           (goto-char (point-max))
1210           (insert-buffer-substring process-buffer)
1211           (set-buffer process-buffer)
1212           (erase-buffer)
1213           (set-buffer buf))
1214
1215         ;; We remove any "." lines and status lines.
1216         (goto-char (point-min))
1217         (while (search-forward "\r" nil t)
1218           (delete-char -1))
1219         (goto-char (point-min))
1220         (delete-matching-lines "^\\.$\\|^[1-5][0-9][0-9] ")
1221         t))))
1222
1223   nntp-server-xover)
1224
1225 (defun nntp-send-xover-command (beg end &optional wait-for-reply)
1226   "Send the XOVER command to the server."
1227   (let ((range (format "%d-%d" beg end))
1228         (nntp-inhibit-erase t))
1229     (if (stringp nntp-server-xover)
1230         ;; If `nntp-server-xover' is a string, then we just send this
1231         ;; command.
1232         (if wait-for-reply
1233             (nntp-send-command-nodelete
1234              "\r?\n\\.\r?\n" nntp-server-xover range)
1235           ;; We do not wait for the reply.
1236           (nntp-send-command-nodelete nil nntp-server-xover range))
1237       (let ((commands nntp-xover-commands))
1238         ;; `nntp-xover-commands' is a list of possible XOVER commands.
1239         ;; We try them all until we get at positive response.
1240         (while (and commands (eq nntp-server-xover 'try))
1241           (nntp-send-command-nodelete "\r?\n\\.\r?\n" (car commands) range)
1242           (save-excursion
1243             (set-buffer nntp-server-buffer)
1244             (goto-char (point-min))
1245             (and (looking-at "[23]")    ; No error message.
1246                  ;; We also have to look at the lines.  Some buggy
1247                  ;; servers give back simple lines with just the
1248                  ;; article number.  How... helpful.
1249                  (progn
1250                    (forward-line 1)
1251                    (looking-at "[0-9]+\t...")) ; More text after number.
1252                  (setq nntp-server-xover (car commands))))
1253           (setq commands (cdr commands)))
1254         ;; If none of the commands worked, we disable XOVER.
1255         (when (eq nntp-server-xover 'try)
1256           (save-excursion
1257             (set-buffer nntp-server-buffer)
1258             (erase-buffer)
1259             (setq nntp-server-xover nil)))
1260         nntp-server-xover))))
1261
1262 ;;; Alternative connection methods.
1263
1264 (defun nntp-wait-for-string (regexp)
1265   "Wait until string arrives in the buffer."
1266   (let ((buf (current-buffer)))
1267     (goto-char (point-min))
1268     (while (not (re-search-forward regexp nil t))
1269       (accept-process-output (nntp-find-connection nntp-server-buffer))
1270       (set-buffer buf)
1271       (goto-char (point-min)))))
1272
1273 (defun nntp-open-telnet (buffer)
1274   (save-excursion
1275     (set-buffer buffer)
1276     (erase-buffer)
1277     (let ((proc (apply
1278                  'start-process
1279                  "nntpd" buffer nntp-telnet-command nntp-telnet-switches))
1280           (case-fold-search t))
1281       (when (memq (process-status proc) '(open run))
1282         (nntp-wait-for-string "^r?telnet")
1283         (process-send-string proc "set escape \^X\n")
1284         (cond
1285          ((and nntp-open-telnet-envuser nntp-telnet-user-name)
1286           (process-send-string proc (concat "open " "-l" nntp-telnet-user-name
1287                                             nntp-address "\n")))
1288          (t
1289           (process-send-string proc (concat "open " nntp-address "\n"))))
1290         (cond
1291          ((not nntp-open-telnet-envuser)
1292           (nntp-wait-for-string "^\r*.?login:")
1293           (process-send-string
1294            proc (concat
1295                  (or nntp-telnet-user-name
1296                      (setq nntp-telnet-user-name (read-string "login: ")))
1297                  "\n"))))
1298         (nntp-wait-for-string "^\r*.?password:")
1299         (process-send-string
1300          proc (concat
1301                (or nntp-telnet-passwd
1302                    (setq nntp-telnet-passwd
1303                          (mail-source-read-passwd "Password: ")))
1304                "\n"))
1305         (nntp-wait-for-string nntp-telnet-shell-prompt)
1306         (process-send-string
1307          proc (concat (mapconcat 'identity nntp-telnet-parameters " ") "\n"))
1308         (nntp-wait-for-string "^\r*20[01]")
1309         (beginning-of-line)
1310         (delete-region (point-min) (point))
1311         (process-send-string proc "\^]")
1312         (nntp-wait-for-string "^r?telnet")
1313         (process-send-string proc "mode character\n")
1314         (accept-process-output proc 1)
1315         (sit-for 1)
1316         (goto-char (point-min))
1317         (forward-line 1)
1318         (delete-region (point) (point-max)))
1319       proc)))
1320
1321 (defun nntp-open-rlogin (buffer)
1322   "Open a connection to SERVER using rsh."
1323   (let ((proc (if nntp-rlogin-user-name
1324                   (apply 'start-process
1325                          "nntpd" buffer nntp-rlogin-program
1326                          nntp-address "-l" nntp-rlogin-user-name
1327                          nntp-rlogin-parameters)
1328                 (apply 'start-process
1329                        "nntpd" buffer nntp-rlogin-program nntp-address
1330                        nntp-rlogin-parameters))))
1331     (save-excursion
1332       (set-buffer buffer)
1333       (nntp-wait-for-string "^\r*20[01]")
1334       (beginning-of-line)
1335       (delete-region (point-min) (point))
1336       proc)))
1337
1338 (defun nntp-find-group-and-number ()
1339   (save-excursion
1340     (save-restriction
1341       (set-buffer nntp-server-buffer)
1342       (narrow-to-region (goto-char (point-min))
1343                         (or (search-forward "\n\n" nil t) (point-max)))
1344       (goto-char (point-min))
1345       ;; We first find the number by looking at the status line.
1346       (let ((number (and (looking-at "2[0-9][0-9] +\\([0-9]+\\) ")
1347                          (string-to-int
1348                           (buffer-substring (match-beginning 1)
1349                                             (match-end 1)))))
1350             group newsgroups xref)
1351         (and number (zerop number) (setq number nil))
1352         ;; Then we find the group name.
1353         (setq group
1354               (cond
1355                ;; If there is only one group in the Newsgroups header,
1356                ;; then it seems quite likely that this article comes
1357                ;; from that group, I'd say.
1358                ((and (setq newsgroups (mail-fetch-field "newsgroups"))
1359                      (not (string-match "," newsgroups)))
1360                 newsgroups)
1361                ;; If there is more than one group in the Newsgroups
1362                ;; header, then the Xref header should be filled out.
1363                ;; We hazard a guess that the group that has this
1364                ;; article number in the Xref header is the one we are
1365                ;; looking for.  This might very well be wrong if this
1366                ;; article happens to have the same number in several
1367                ;; groups, but that's life.
1368                ((and (setq xref (mail-fetch-field "xref"))
1369                      number
1370                      (string-match (format "\\([^ :]+\\):%d" number) xref))
1371                 (substring xref (match-beginning 1) (match-end 1)))
1372                (t "")))
1373         (when (string-match "\r" group)
1374           (setq group (substring group 0 (match-beginning 0))))
1375         (cons group number)))))
1376
1377 (provide 'nntp)
1378
1379 ;;; nntp.el ends here