cgit.sxemacs.org Git - gnus/blob - lisp/nntp.el

   1 ;;; Copyright (C) 1987,88,89,90,92,93,94,95,96 Free Software Foundation, Inc.
   2
   3 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   4 ;; Keywords: news
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  20 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 (require 'nnheader)
  27 (require 'nnoo)
  28 (require 'gnus-util)
  29
  30 (nnoo-declare nntp)
  31
  32 (eval-and-compile
  33   (unless (fboundp 'open-network-stream)
  34     (require 'tcp)))
  35
  36 (eval-when-compile (require 'cl))
  37
  38 (defvoo nntp-address nil
  39   "Address of the physical nntp server.")
  40
  41 (defvoo nntp-port-number "nntp"
  42   "Port number on the physical nntp server.")
  43
  44 (defvoo nntp-server-opened-hook '(nntp-send-mode-reader)
  45   "*Hook used for sending commands to the server at startup.
  46 The default value is `nntp-send-mode-reader', which makes an innd
  47 server spawn an nnrpd server.  Another useful function to put in this
  48 hook might be `nntp-send-authinfo', which will prompt for a password
  49 to allow posting from the server.  Note that this is only necessary to
  50 do on servers that use strict access control.")
  51
  52 (defvoo nntp-authinfo-function 'nntp-send-authinfo
  53   "Function used to send AUTHINFO to the server.")
  54
  55 (defvoo nntp-server-action-alist
  56   '(("nntpd 1\\.5\\.11t"
  57      (remove-hook 'nntp-server-opened-hook 'nntp-send-mode-reader))
  58     ("NNRP server Netscape"
  59      (setq nntp-server-list-active-group nil)))
  60   "Alist of regexps to match on server types and actions to be taken.
  61 For instance, if you want Gnus to beep every time you connect
  62 to innd, you could say something like:
  63
  64 \(setq nntp-server-action-alist
  65        '((\"innd\" (ding))))
  66
  67 You probably don't want to do that, though.")
  68
  69 (defvoo nntp-open-connection-function 'nntp-open-network-stream
  70   "*Function used for connecting to a remote system.
  71 It will be called with the buffer to output in.
  72
  73 Two pre-made functions are `nntp-open-network-stream', which is the
  74 default, and simply connects to some port or other on the remote
  75 system (see nntp-port-number).  The other are `nntp-open-rlogin', which
  76 does an rlogin on the remote system, and then does a telnet to the
  77 NNTP server available there (see nntp-rlogin-parameters) and `nntp-open-telnet' which
  78 telnets to a remote system, logs in and does the same")
  79
  80 (defvoo nntp-rlogin-parameters '("telnet" "-8" "${NNTPSERVER:=news}" "nntp")
  81   "*Parameters to `nntp-open-login'.
  82 That function may be used as `nntp-open-server-function'.  In that
  83 case, this list will be used as the parameter list given to rsh.")
  84
  85 (defvoo nntp-rlogin-user-name nil
  86   "*User name on remote system when using the rlogin connect method.")
  87
  88 (defvoo nntp-telnet-parameters '("exec" "telnet" "-8" "${NNTPSERVER:=news}" "nntp")
  89   "*Parameters to `nntp-open-telnet'.
  90 That function may be used as `nntp-open-server-function'.  In that
  91 case, this list will be executed as a command after logging in
  92 via telnet.")
  93
  94 (defvoo nntp-telnet-user-name nil
  95   "User name to log in via telnet with.")
  96
  97 (defvoo nntp-telnet-passwd nil
  98   "Password to use to log in via telnet with.")
  99
 100 (defvoo nntp-end-of-line "\r\n"
 101   "String to use on the end of lines when talking to the NNTP server.
 102 This is \"\\r\\n\" by default, but should be \"\\n\" when
 103 using rlogin or telnet to communicate with the server.")
 104
 105 (defvoo nntp-large-newsgroup 50
 106   "*The number of the articles which indicates a large newsgroup.
 107 If the number of the articles is greater than the value, verbose
 108 messages will be shown to indicate the current status.")
 109
 110 (defvoo nntp-maximum-request 400
 111   "*The maximum number of the requests sent to the NNTP server at one time.
 112 If Emacs hangs up while retrieving headers, set the variable to a
 113 lower value.")
 114
 115 (defvoo nntp-nov-is-evil nil
 116   "*If non-nil, nntp will never attempt to use XOVER when talking to the server.")
 117
 118 (defvoo nntp-xover-commands '("XOVER" "XOVERVIEW")
 119   "*List of strings that are used as commands to fetch NOV lines from a server.
 120 The strings are tried in turn until a positive response is gotten.  If
 121 none of the commands are successful, nntp will just grab headers one
 122 by one.")
 123
 124 (defvoo nntp-nov-gap 20
 125   "*Maximum allowed gap between two articles.
 126 If the gap between two consecutive articles is bigger than this
 127 variable, split the XOVER request into two requests.")
 128
 129 (defvoo nntp-connection-timeout nil
 130   "*Number of seconds to wait before an nntp connection times out.
 131 If this variable is nil, which is the default, no timers are set.")
 132
 133 (defvoo nntp-prepare-server-hook nil
 134   "*Hook run before a server is opened.
 135 If can be used to set up a server remotely, for instance.  Say you
 136 have an account at the machine \"other.machine\".  This machine has
 137 access to an NNTP server that you can't access locally.  You could
 138 then use this hook to rsh to the remote machine and start a proxy NNTP
 139 server there that you can connect to.  See also `nntp-open-connection-function'")
 140
 141 (defvoo nntp-warn-about-losing-connection t
 142   "*If non-nil, beep when a server closes connection.")
 143
 144 \f
 145
 146 ;;; Internal variables.
 147
 148 (defvar nntp-process-wait-for nil)
 149 (defvar nntp-process-to-buffer nil)
 150 (defvar nntp-process-callback nil)
 151 (defvar nntp-process-decode nil)
 152 (defvar nntp-process-start-point nil)
 153 (defvar nntp-inside-change-function nil)
 154
 155 (defvar nntp-connection-list nil)
 156
 157 (defvoo nntp-server-type nil)
 158 (defvoo nntp-connection-alist nil)
 159 (defvoo nntp-status-string "")
 160 (defconst nntp-version "nntp 5.0")
 161 (defvoo nntp-inhibit-erase nil)
 162
 163 (defvoo nntp-server-xover 'try)
 164 (defvoo nntp-server-list-active-group 'try)
 165
 166 (eval-and-compile
 167   (autoload 'nnmail-read-passwd "nnmail"))
 168
 169 \f
 170
 171 ;;; Interface functions.
 172
 173 (nnoo-define-basics nntp)
 174
 175 (deffoo nntp-retrieve-headers (articles &optional group server fetch-old)
 176   "Retrieve the headers of ARTICLES."
 177   (nntp-possibly-change-group group server)
 178   (save-excursion
 179     (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 180     (erase-buffer)
 181     (if (and (not gnus-nov-is-evil)
 182              (not nntp-nov-is-evil)
 183              (nntp-retrieve-headers-with-xover articles fetch-old))
 184         ;; We successfully retrieved the headers via XOVER.
 185         'nov
 186       ;; XOVER didn't work, so we do it the hard, slow and inefficient
 187       ;; way.
 188       (let ((number (length articles))
 189             (count 0)
 190             (received 0)
 191             (last-point (point-min))
 192             (buf (nntp-find-connection-buffer nntp-server-buffer))
 193             (nntp-inhibit-erase t))
 194         ;; Send HEAD command.
 195         (while articles
 196           (nntp-send-command
 197            nil
 198            "HEAD" (if (numberp (car articles))
 199                       (int-to-string (car articles))
 200                     ;; `articles' is either a list of article numbers
 201                     ;; or a list of article IDs.
 202                     (car articles)))
 203           (setq articles (cdr articles)
 204                 count (1+ count))
 205           ;; Every 400 header requests we have to read the stream in
 206           ;; order to avoid deadlocks.
 207           (when (or (null articles)     ;All requests have been sent.
 208                     (zerop (% count nntp-maximum-request)))
 209             (nntp-accept-response)
 210             (while (progn
 211                      (progn
 212                        (set-buffer buf)
 213                        (goto-char last-point))
 214                      ;; Count replies.
 215                      (while (re-search-forward "^[0-9]" nil t)
 216                        (incf received))
 217                      (setq last-point (point))
 218                      (< received count))
 219               ;; If number of headers is greater than 100, give
 220               ;;  informative messages.
 221               (and (numberp nntp-large-newsgroup)
 222                    (> number nntp-large-newsgroup)
 223                    (zerop (% received 20))
 224                    (message "NNTP: Receiving headers... %d%%"
 225                             (/ (* received 100) number)))
 226               (nntp-accept-response))))
 227         ;; Wait for text of last command.
 228         (goto-char (point-max))
 229         (re-search-backward "^[0-9]" nil t)
 230         (when (looking-at "^[23]")
 231           (while (progn
 232                    (goto-char (- (point-max) 3))
 233                    (not (looking-at "^\\.\r?\n")))
 234             (nntp-accept-response)))
 235         (and (numberp nntp-large-newsgroup)
 236              (> number nntp-large-newsgroup)
 237              (message "NNTP: Receiving headers...done"))
 238
 239         ;; Now all of replies are received.  Fold continuation lines.
 240         (nnheader-fold-continuation-lines)
 241         ;; Remove all "\r"'s.
 242         (goto-char (point-min))
 243         (while (search-forward "\r" nil t)
 244           (replace-match "" t t))
 245         (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 246         'headers))))
 247
 248 (deffoo nntp-retrieve-groups (groups &optional server)
 249   "Retrieve group info on GROUPS."
 250   (nntp-possibly-change-group nil server)
 251   (save-excursion
 252     (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 253     ;; The first time this is run, this variable is `try'.  So we
 254     ;; try.
 255     (when (eq nntp-server-list-active-group 'try)
 256       (nntp-try-list-active (car groups)))
 257     (erase-buffer)
 258     (let ((count 0)
 259           (received 0)
 260           (last-point (point-min))
 261           (nntp-inhibit-erase t)
 262           (command (if nntp-server-list-active-group "LIST ACTIVE" "GROUP")))
 263       (while groups
 264         ;; Send the command to the server.
 265         (nntp-send-command nil command (pop groups))
 266         (incf count)
 267         ;; Every 400 requests we have to read the stream in
 268         ;; order to avoid deadlocks.
 269         (when (or (null groups)         ;All requests have been sent.
 270                   (zerop (% count nntp-maximum-request)))
 271           (nntp-accept-response)
 272           (while (progn
 273                    (goto-char last-point)
 274                    ;; Count replies.
 275                    (while (re-search-forward "^[0-9]" nil t)
 276                      (incf received))
 277                    (setq last-point (point))
 278                    (< received count))
 279             (nntp-accept-response))))
 280
 281       ;; Wait for the reply from the final command.
 282       (goto-char (point-max))
 283       (re-search-backward "^[0-9]" nil t)
 284       (when (looking-at "^[23]")
 285         (while (progn
 286                  (goto-char (point-max))
 287                  (if (not nntp-server-list-active-group)
 288                      (not (re-search-backward "\r?\n" (- (point) 3) t))
 289                    (not (re-search-backward "^\\.\r?\n" (- (point) 4) t))))
 290           (nntp-accept-response)))
 291
 292       ;; Now all replies are received.  We remove CRs.
 293       (goto-char (point-min))
 294       (while (search-forward "\r" nil t)
 295         (replace-match "" t t))
 296
 297       (if (not nntp-server-list-active-group)
 298           (progn
 299             (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 300             'group)
 301         ;; We have read active entries, so we just delete the
 302         ;; superfluous gunk.
 303         (goto-char (point-min))
 304         (while (re-search-forward "^[.2-5]" nil t)
 305           (delete-region (match-beginning 0)
 306                          (progn (forward-line 1) (point))))
 307         (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 308         'active))))
 309
 310 (defun nntp-try-list-active (group)
 311   (nntp-list-active-group group)
 312   (save-excursion
 313     (set-buffer nntp-server-buffer)
 314     (goto-char (point-min))
 315     (cond ((looking-at "5[0-9]+")
 316            (setq nntp-server-list-active-group nil))
 317           (t
 318            (setq nntp-server-list-active-group t)))))
 319
 320 (deffoo nntp-list-active-group (group &optional server)
 321   "Return the active info on GROUP (which can be a regexp."
 322   (nntp-possibly-change-group nil server)
 323   (nntp-send-command "^.*\r?\n" "LIST ACTIVE" group))
 324
 325 (deffoo nntp-request-article (article &optional group server buffer command)
 326   (nntp-possibly-change-group group server)
 327   (when (nntp-send-command-and-decode
 328          "\r?\n\\.\r?\n" "ARTICLE"
 329          (if (numberp article) (int-to-string article) article))
 330     (when (and buffer
 331                (not (equal buffer nntp-server-buffer)))
 332       (save-excursion
 333         (set-buffer nntp-server-buffer)
 334         (copy-to-buffer buffer (point-min) (point-max))
 335         (nntp-find-group-and-number)))
 336     (nntp-find-group-and-number)))
 337
 338 (deffoo nntp-request-head (article &optional group server)
 339   (nntp-possibly-change-group group server)
 340   (when (nntp-send-command-and-decode
 341          "\r\n\\.\r\n" "HEAD"
 342          (if (numberp article) (int-to-string article) article))
 343     (nntp-find-group-and-number)))
 344
 345 (deffoo nntp-request-body (article &optional group server)
 346   (nntp-possibly-change-group group server)
 347   (nntp-send-command-and-decode
 348    "\r?\n\\.\r?\n" "BODY"
 349    (if (numberp article) (int-to-string article) article)))
 350
 351 (deffoo nntp-request-group (group &optional server dont-check)
 352   (nntp-possibly-change-group nil server)
 353   (when (nntp-send-command "^2.*\n" "GROUP" group)
 354     (let ((entry (nntp-find-connection-entry nntp-server-buffer)))
 355       (setcar (cddr entry) group))))
 356
 357 (deffoo nntp-close-group (group &optional server)
 358   t)
 359
 360 (deffoo nntp-server-opened (&optional server)
 361   "Say whether a connection to SERVER has been opened."
 362   (and (nnoo-current-server-p 'nntp server)
 363        nntp-server-buffer
 364        (gnus-buffer-live-p nntp-server-buffer)
 365        (nntp-find-connection nntp-server-buffer)))
 366
 367 (deffoo nntp-open-server (server &optional defs connectionless)
 368   (nnheader-init-server-buffer)
 369   (if (nntp-server-opened server)
 370       t
 371     (when (or (stringp (car defs))
 372               (numberp (car defs)))
 373       (setq defs (cons (list 'nntp-port-number (car defs)) (cdr defs))))
 374     (unless (assq 'nntp-address defs)
 375       (setq defs (append defs (list (list 'nntp-address server)))))
 376     (nnoo-change-server 'nntp server defs)
 377     (unless connectionless
 378       (or (nntp-find-connection nntp-server-buffer)
 379           (nntp-open-connection nntp-server-buffer)))))
 380
 381 (deffoo nntp-close-server (&optional server)
 382   (nntp-possibly-change-group nil server t)
 383   (let (process)
 384     (while (setq process (car (pop nntp-connection-alist)))
 385       (when (memq (process-status process) '(open run))
 386         (set-process-sentinel process nil)
 387         (nntp-send-string process "QUIT"))
 388       (when (buffer-name (process-buffer process))
 389         (kill-buffer (process-buffer process))))
 390     (nnoo-close-server 'nntp)))
 391
 392 (deffoo nntp-request-close ()
 393   (let (process)
 394     (while (setq process (pop nntp-connection-list))
 395       (when (memq (process-status process) '(open run))
 396         (set-process-sentinel process nil)
 397         (nntp-send-string process "QUIT"))
 398       (when (buffer-name (process-buffer process))
 399         (kill-buffer (process-buffer process))))))
 400
 401 (deffoo nntp-request-list (&optional server)
 402   (nntp-possibly-change-group nil server)
 403   (nntp-send-command-and-decode "\r?\n\\.\r?\n" "LIST"))
 404
 405 (deffoo nntp-request-list-newsgroups (&optional server)
 406   (nntp-possibly-change-group nil server)
 407   (nntp-send-command "\r?\n\\.\r?\n" "LIST NEWSGROUPS"))
 408
 409 (deffoo nntp-request-newgroups (date &optional server)
 410   (nntp-possibly-change-group nil server)
 411   (save-excursion
 412     (set-buffer nntp-server-buffer)
 413     (let* ((date (timezone-parse-date date))
 414            (time-string
 415             (format "%s%02d%02d %s%s%s"
 416                     (substring (aref date 0) 2) (string-to-int (aref date 1))
 417                     (string-to-int (aref date 2)) (substring (aref date 3) 0 2)
 418                     (substring
 419                      (aref date 3) 3 5) (substring (aref date 3) 6 8))))
 420       (prog1
 421           (nntp-send-command "^\\.\r?\n" "NEWGROUPS" time-string)
 422         (nntp-decode-text)))))
 423
 424 (deffoo nntp-request-post (&optional server)
 425   (nntp-possibly-change-group nil server)
 426   (when (nntp-send-command "^[23].*\r?\n" "POST")
 427     (nntp-send-buffer "^[23].*\n")))
 428
 429 (deffoo nntp-request-type (group article)
 430   'news)
 431
 432 (deffoo nntp-asynchronous-p ()
 433   t)
 434
 435 ;;; Hooky functions.
 436
 437 (defun nntp-send-mode-reader ()
 438   "Send the MODE READER command to the nntp server.
 439 This function is supposed to be called from `nntp-server-opened-hook'.
 440 It will make innd servers spawn an nnrpd process to allow actual article
 441 reading."
 442   (nntp-send-command "^.*\r?\n" "MODE READER"))
 443
 444 (defun nntp-send-nosy-authinfo ()
 445   "Send the AUTHINFO to the nntp server.
 446 This function is supposed to be called from `nntp-server-opened-hook'.
 447 It will prompt for a password."
 448   (nntp-send-command "^.*\r?\n" "AUTHINFO USER"
 449                      (read-string "NNTP user name: "))
 450   (nntp-send-command "^.*\r?\n" "AUTHINFO PASS"
 451                      (nnmail-read-passwd "NNTP password: ")))
 452
 453 (defun nntp-send-authinfo ()
 454   "Send the AUTHINFO to the nntp server.
 455 This function is supposed to be called from `nntp-server-opened-hook'.
 456 It will prompt for a password."
 457   (nntp-send-command "^.*\r?\n" "AUTHINFO USER" (user-login-name))
 458   (nntp-send-command "^.*\r?\n" "AUTHINFO PASS"
 459                      (read-string "NNTP password: ")))
 460
 461 (defun nntp-send-authinfo-from-file ()
 462   "Send the AUTHINFO to the nntp server.
 463 This function is supposed to be called from `nntp-server-opened-hook'.
 464 It will prompt for a password."
 465   (when (file-exists-p "~/.nntp-authinfo")
 466     (save-excursion
 467       (set-buffer (get-buffer-create " *authinfo*"))
 468       (buffer-disable-undo (current-buffer))
 469       (erase-buffer)
 470       (insert-file-contents "~/.nntp-authinfo")
 471       (goto-char (point-min))
 472       (nntp-send-command "^.*\r?\n" "AUTHINFO USER" (user-login-name))
 473       (nntp-send-command
 474        "^.*\r?\n" "AUTHINFO PASS"
 475        (buffer-substring (point) (progn (end-of-line) (point))))
 476       (kill-buffer (current-buffer)))))
 477
 478 ;;; Internal functions.
 479
 480 (defun nntp-send-command (wait-for &rest strings)
 481   "Send STRINGS to server and wait until WAIT-FOR returns."
 482   (unless nnheader-callback-function
 483     (save-excursion
 484       (set-buffer nntp-server-buffer)
 485       (erase-buffer)))
 486   (nntp-retrieve-data
 487    (mapconcat 'identity strings " ")
 488    nntp-address nntp-port-number nntp-server-buffer
 489    wait-for nnheader-callback-function))
 490
 491 (defun nntp-send-command-nodelete (wait-for &rest strings)
 492   "Send STRINGS to server and wait until WAIT-FOR returns."
 493   (nntp-retrieve-data
 494    (mapconcat 'identity strings " ")
 495    nntp-address nntp-port-number nntp-server-buffer
 496    wait-for nnheader-callback-function))
 497
 498 (defun nntp-send-command-and-decode (wait-for &rest strings)
 499   "Send STRINGS to server and wait until WAIT-FOR returns."
 500   (unless nnheader-callback-function
 501     (save-excursion
 502       (set-buffer nntp-server-buffer)
 503       (erase-buffer)))
 504   (nntp-retrieve-data
 505    (mapconcat 'identity strings " ")
 506    nntp-address nntp-port-number nntp-server-buffer
 507    wait-for nnheader-callback-function t))
 508
 509 (defun nntp-send-buffer (wait-for)
 510   "Send the current buffer to server and wait until WAIT-FOR returns."
 511   (unless nnheader-callback-function
 512     (save-excursion
 513       (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 514       (erase-buffer)))
 515   (nntp-encode-text)
 516   (process-send-region (nntp-find-connection nntp-server-buffer)
 517                        (point-min) (point-max))
 518   (nntp-retrieve-data
 519    nil nntp-address nntp-port-number nntp-server-buffer
 520    wait-for nnheader-callback-function))
 521
 522 (defun nntp-find-connection (buffer)
 523   "Find the connection delivering to BUFFER."
 524   (let ((alist nntp-connection-alist)
 525         (buffer (if (stringp buffer) (get-buffer buffer) buffer))
 526         process entry)
 527     (while (setq entry (pop alist))
 528       (when (eq buffer (cadr entry))
 529         (setq process (car entry)
 530               alist nil)))
 531     (when process
 532       (if (memq (process-status process) '(open run))
 533           process
 534         (when (buffer-name (process-buffer process))
 535           (kill-buffer (process-buffer process)))
 536         (setq nntp-connection-alist (delq entry nntp-connection-alist))
 537         nil))))
 538
 539 (defun nntp-find-connection-entry (buffer)
 540   "Return the entry for the connection to BUFFER."
 541   (assq (nntp-find-connection buffer) nntp-connection-alist))
 542
 543 (defun nntp-find-connection-buffer (buffer)
 544   "Return the process connection buffer tied to BUFFER."
 545   (let ((process (nntp-find-connection buffer)))
 546     (when process
 547       (process-buffer process))))
 548
 549 (defun nntp-make-process-buffer (buffer)
 550   "Create a new, fresh buffer usable for nntp process connections."
 551   (save-excursion
 552     (set-buffer
 553      (generate-new-buffer
 554       (format " *server %s %s %s*"
 555               nntp-address nntp-port-number
 556               (buffer-name (get-buffer buffer)))))
 557     (buffer-disable-undo (current-buffer))
 558     (set (make-local-variable 'after-change-functions) nil)
 559     (set (make-local-variable 'nntp-process-wait-for) nil)
 560     (set (make-local-variable 'nntp-process-callback) nil)
 561     (set (make-local-variable 'nntp-process-to-buffer) nil)
 562     (set (make-local-variable 'nntp-process-start-point) nil)
 563     (set (make-local-variable 'nntp-process-decode) nil)
 564     (current-buffer)))
 565
 566 (defun nntp-open-connection (buffer)
 567   "Open a connection to PORT on ADDRESS delivering output to BUFFER."
 568   (run-hooks 'nntp-prepare-server-hook)
 569   (let* ((pbuffer (nntp-make-process-buffer buffer))
 570          (process
 571           (condition-case ()
 572               (funcall
 573                nntp-open-connection-function pbuffer)
 574             (error nil))))
 575     (when process
 576       (process-kill-without-query process)
 577       (nntp-wait-for process "^.*\n" buffer)
 578       (if (memq (process-status process) '(open run))
 579           (prog1
 580               (caar (push (list process buffer nil)
 581                           nntp-connection-alist))
 582             (push process nntp-connection-list)
 583             (save-excursion
 584               (set-buffer nntp-server-buffer)
 585               (nntp-read-server-type)
 586               (run-hooks 'nntp-server-opened-hook)))
 587         (when (buffer-name (process-buffer process))
 588           (kill-buffer (process-buffer process)))
 589         nil))))
 590
 591 (defun nntp-open-network-stream (buffer)
 592   (open-network-stream "nntpd" buffer nntp-address nntp-port-number))
 593
 594 (defun nntp-read-server-type ()
 595   "Find out what the name of the server we have connected to is."
 596   ;; Wait for the status string to arrive.
 597   (setq nntp-server-type (buffer-string))
 598   (let ((alist nntp-server-action-alist)
 599         (case-fold-search t)
 600         entry)
 601     ;; Run server-specific commands.
 602     (while alist
 603       (setq entry (pop alist))
 604       (when (string-match (car entry) nntp-server-type)
 605         (if (and (listp (cadr entry))
 606                  (not (eq 'lambda (caadr entry))))
 607             (eval (cadr entry))
 608           (funcall (cadr entry)))))))
 609
 610 (defun nntp-after-change-function-callback (beg end len)
 611   (when nntp-process-callback
 612     (save-match-data
 613       (if (and (= beg (point-min))
 614                (memq (char-after beg) '(?4 ?5)))
 615           ;; Report back error messages.
 616           (save-excursion
 617             (goto-char beg)
 618             (if (looking-at "480")
 619                 (funcall nntp-authinfo-function)
 620               (nntp-snarf-error-message)
 621               (funcall nntp-process-callback nil)))
 622         (goto-char end)
 623         (when (and (> (point) nntp-process-start-point)
 624                    (re-search-backward nntp-process-wait-for
 625                                        nntp-process-start-point t))
 626           (when (buffer-name (get-buffer nntp-process-to-buffer))
 627             (let ((cur (current-buffer))
 628                   (start nntp-process-start-point))
 629               (save-excursion
 630                 (set-buffer (get-buffer nntp-process-to-buffer))
 631                 (goto-char (point-max))
 632                 (let ((b (point)))
 633                   (insert-buffer-substring cur start)
 634                   (narrow-to-region b (point-max))
 635                   (nntp-decode-text)
 636                   (widen)))))
 637           (goto-char end)
 638           (let ((callback nntp-process-callback)
 639                 (nntp-inside-change-function t))
 640             (setq nntp-process-callback nil)
 641             (save-excursion
 642               (funcall callback (buffer-name
 643                                  (get-buffer nntp-process-to-buffer))))))))))
 644
 645 (defun nntp-retrieve-data (command address port buffer
 646                                    &optional wait-for callback decode)
 647   "Use COMMAND to retrieve data into BUFFER from PORT on ADDRESS."
 648   (let ((process (or (nntp-find-connection buffer)
 649                      (nntp-open-connection buffer))))
 650     (if (not process)
 651         (nnheader-report 'nntp "Couldn't open connection to %s" address)
 652       (unless (or nntp-inhibit-erase nnheader-callback-function)
 653         (save-excursion
 654           (set-buffer (process-buffer process))
 655           (erase-buffer)))
 656       (when command
 657         (nntp-send-string process command))
 658       (cond
 659        ((eq callback 'ignore)
 660         t)
 661        ((and callback wait-for)
 662         (save-excursion
 663           (set-buffer (process-buffer process))
 664           (unless nntp-inside-change-function
 665             (erase-buffer))
 666           (setq nntp-process-decode decode
 667                 nntp-process-to-buffer buffer
 668                 nntp-process-wait-for wait-for
 669                 nntp-process-callback callback
 670                 nntp-process-start-point (point-max)
 671                 after-change-functions
 672                 (list 'nntp-after-change-function-callback)))
 673         t)
 674        (wait-for
 675         (nntp-wait-for process wait-for buffer decode))
 676        (t t)))))
 677
 678 (defun nntp-send-string (process string)
 679   "Send STRING to PROCESS."
 680   (process-send-string process (concat string nntp-end-of-line)))
 681
 682 (defun nntp-wait-for (process wait-for buffer &optional decode)
 683   "Wait for WAIT-FOR to arrive from PROCESS."
 684   (save-excursion
 685     (set-buffer (process-buffer process))
 686     (goto-char (point-min))
 687     (while (or (not (memq (following-char) '(?2 ?3 ?4 ?5)))
 688                (looking-at "480"))
 689       (when (looking-at "480")
 690         (erase-buffer)
 691         (funcall nntp-authinfo-function))
 692       (nntp-accept-process-output process)
 693       (goto-char (point-min)))
 694     (prog1
 695         (if (looking-at "[45]")
 696             (progn
 697               (nntp-snarf-error-message)
 698               nil)
 699           (goto-char (point-max))
 700           (while (not (re-search-backward wait-for nil t))
 701             (nntp-accept-process-output process)
 702             (goto-char (point-max)))
 703           (nntp-decode-text (not decode))
 704           (save-excursion
 705             (set-buffer buffer)
 706             (goto-char (point-max))
 707             (insert-buffer-substring (process-buffer process))
 708             t))
 709       (erase-buffer))))
 710
 711 (defun nntp-snarf-error-message ()
 712   "Save the error message in the current buffer."
 713   (setq nntp-status-string (buffer-string)))
 714
 715 (defun nntp-accept-process-output (process)
 716   "Wait for output from PROCESS and message some dots."
 717   (save-excursion
 718     (set-buffer (or (nntp-find-connection-buffer nntp-server-buffer)
 719                     nntp-server-buffer))
 720     (let ((len (/ (point-max) 10000)))
 721       (unless (zerop len)
 722         (message "nntp reading%s" (make-string len ?.))))
 723     (accept-process-output process 1)))
 724
 725 (defun nntp-accept-response ()
 726   "Wait for output from the process that outputs to BUFFER."
 727   (nntp-accept-process-output (nntp-find-connection nntp-server-buffer)))
 728
 729 (defun nntp-possibly-change-group (group server &optional connectionless)
 730   (when server
 731     (or (nntp-server-opened server)
 732         (nntp-open-server server nil connectionless)))
 733
 734   (unless connectionless
 735     (or (nntp-find-connection nntp-server-buffer)
 736         (nntp-open-connection nntp-server-buffer)))
 737
 738   (when group
 739     (let ((entry (nntp-find-connection-entry nntp-server-buffer)))
 740       (when (not (equal group (caddr entry)))
 741         (nntp-request-group group)))))
 742
 743 (defun nntp-decode-text (&optional cr-only)
 744   "Decode the text in the current buffer."
 745   (goto-char (point-min))
 746   ;; Remove \R's.
 747   (while (search-forward "\r" nil t)
 748     (delete-char -1))
 749   (unless cr-only
 750     ;; Remove trailing ".\n" end-of-transfer marker.
 751     (goto-char (point-max))
 752     (forward-line -1)
 753     (when (looking-at ".\n")
 754       (delete-char 2))
 755     ;; Delete status line.
 756     (goto-char (point-min))
 757     (delete-region (point) (progn (forward-line 1) (point)))
 758     ;; Remove "." -> ".." encoding.
 759     (while (search-forward "\n.." nil t)
 760       (delete-char -1))))
 761
 762 (defun nntp-encode-text ()
 763   "Encode the text in the current buffer."
 764   (save-excursion
 765     ;; Replace "." at beginning of line with "..".
 766     (goto-char (point-min))
 767     (while (re-search-forward "^\\." nil t)
 768       (insert "."))
 769     (goto-char (point-max))
 770     ;; Insert newline at the end of the buffer.
 771     (unless (bolp)
 772       (insert "\n"))
 773     ;; Insert `.' at end of buffer (end of text mark).
 774     (goto-char (point-max))
 775     (insert "." nntp-end-of-line)))
 776
 777 (defun nntp-retrieve-headers-with-xover (articles &optional fetch-old)
 778   (set-buffer nntp-server-buffer)
 779   (erase-buffer)
 780   (cond
 781
 782    ;; This server does not talk NOV.
 783    ((not nntp-server-xover)
 784     nil)
 785
 786    ;; We don't care about gaps.
 787    ((or (not nntp-nov-gap)
 788         fetch-old)
 789     (nntp-send-xover-command
 790      (if fetch-old
 791          (if (numberp fetch-old)
 792              (max 1 (- (car articles) fetch-old))
 793            1)
 794        (car articles))
 795      (car (last articles)) 'wait)
 796
 797     (goto-char (point-min))
 798     (when (looking-at "[1-5][0-9][0-9] ")
 799       (delete-region (point) (progn (forward-line 1) (point))))
 800     (while (search-forward "\r" nil t)
 801       (replace-match "" t t))
 802     (goto-char (point-max))
 803     (forward-line -1)
 804     (when (looking-at "\\.")
 805       (delete-region (point) (progn (forward-line 1) (point)))))
 806
 807    ;; We do it the hard way.  For each gap, an XOVER command is sent
 808    ;; to the server.  We do not wait for a reply from the server, we
 809    ;; just send them off as fast as we can.  That means that we have
 810    ;; to count the number of responses we get back to find out when we
 811    ;; have gotten all we asked for.
 812    ((numberp nntp-nov-gap)
 813     (let ((count 0)
 814           (received 0)
 815           (last-point (point-min))
 816           (buf nntp-server-buffer)
 817           ;;(process-buffer (nntp-find-connection (current-buffer))))
 818           first)
 819       ;; We have to check `nntp-server-xover'.  If it gets set to nil,
 820       ;; that means that the server does not understand XOVER, but we
 821       ;; won't know that until we try.
 822       (while (and nntp-server-xover articles)
 823         (setq first (car articles))
 824         ;; Search forward until we find a gap, or until we run out of
 825         ;; articles.
 826         (while (and (cdr articles)
 827                     (< (- (nth 1 articles) (car articles)) nntp-nov-gap))
 828           (setq articles (cdr articles)))
 829
 830         (when (nntp-send-xover-command first (car articles))
 831           (setq articles (cdr articles)
 832                 count (1+ count))
 833
 834           ;; Every 400 requests we have to read the stream in
 835           ;; order to avoid deadlocks.
 836           (when (or (null articles)     ;All requests have been sent.
 837                     (zerop (% count nntp-maximum-request)))
 838             (accept-process-output)
 839             ;; On some Emacs versions the preceding function has
 840             ;; a tendency to change the buffer.  Perhaps.  It's
 841             ;; quite difficult to reproduce, because it only
 842             ;; seems to happen once in a blue moon.
 843             (set-buffer buf)
 844             (while (progn
 845                      (goto-char last-point)
 846                      ;; Count replies.
 847                      (while (re-search-forward "^[0-9][0-9][0-9] " nil t)
 848                        (setq received (1+ received)))
 849                      (setq last-point (point))
 850                      (< received count))
 851               (accept-process-output)
 852               (set-buffer buf)))))
 853
 854       (when nntp-server-xover
 855         ;; Wait for the reply from the final command.
 856         (goto-char (point-max))
 857         (re-search-backward "^[0-9][0-9][0-9] " nil t)
 858         (when (looking-at "^[23]")
 859           (while (progn
 860                    (goto-char (point-max))
 861                    (forward-line -1)
 862                    (not (looking-at "^\\.\r?\n")))
 863             (nntp-accept-response)))
 864
 865         ;; We remove any "." lines and status lines.
 866         (goto-char (point-min))
 867         (while (search-forward "\r" nil t)
 868           (delete-char -1))
 869         (goto-char (point-min))
 870         (delete-matching-lines "^\\.$\\|^[1-5][0-9][0-9] ")
 871         ;;(copy-to-buffer nntp-server-buffer (point-min) (point-max))
 872         t))))
 873
 874   nntp-server-xover)
 875
 876 (defun nntp-send-xover-command (beg end &optional wait-for-reply)
 877   "Send the XOVER command to the server."
 878   (let ((range (format "%d-%d" beg end))
 879         (nntp-inhibit-erase t))
 880     (if (stringp nntp-server-xover)
 881         ;; If `nntp-server-xover' is a string, then we just send this
 882         ;; command.
 883         (if wait-for-reply
 884             (nntp-send-command-nodelete "\r?\n\\.\r?\n" nntp-server-xover range)
 885           ;; We do not wait for the reply.
 886           (nntp-send-command-nodelete "\r?\n\\.\r?\n" nntp-server-xover range))
 887       (let ((commands nntp-xover-commands))
 888         ;; `nntp-xover-commands' is a list of possible XOVER commands.
 889         ;; We try them all until we get at positive response.
 890         (while (and commands (eq nntp-server-xover 'try))
 891           (nntp-send-command-nodelete "\r?\n\\.\r?\n" (car commands) range)
 892           (save-excursion
 893             (set-buffer nntp-server-buffer)
 894             (goto-char (point-min))
 895             (and (looking-at "[23]")    ; No error message.
 896                  ;; We also have to look at the lines.  Some buggy
 897                  ;; servers give back simple lines with just the
 898                  ;; article number.  How... helpful.
 899                  (progn
 900                    (forward-line 1)
 901                    (looking-at "[0-9]+\t...")) ; More text after number.
 902                  (setq nntp-server-xover (car commands))))
 903           (setq commands (cdr commands)))
 904         ;; If none of the commands worked, we disable XOVER.
 905         (when (eq nntp-server-xover 'try)
 906           (save-excursion
 907             (set-buffer nntp-server-buffer)
 908             (erase-buffer)
 909             (setq nntp-server-xover nil)))
 910         nntp-server-xover))))
 911
 912 ;;; Alternative connection methods.
 913
 914 (defun nntp-wait-for-string (regexp)
 915   "Wait until string arrives in the buffer."
 916   (let ((buf (current-buffer)))
 917     (goto-char (point-min))
 918     (while (not (re-search-forward regexp nil t))
 919       (accept-process-output (nntp-find-connection nntp-server-buffer))
 920       (set-buffer buf)
 921       (goto-char (point-min)))))
 922
 923 (defun nntp-open-telnet (buffer)
 924   (save-excursion
 925     (set-buffer buffer)
 926     (erase-buffer)
 927     (let ((proc (start-process
 928                  "nntpd" buffer "telnet" "-8"))
 929           (case-fold-search t))
 930       (when (memq (process-status proc) '(open run))
 931         (process-send-string proc "set escape \^X\n")
 932         (process-send-string proc (concat "open " nntp-address "\n"))
 933         (nntp-wait-for-string "^\r*.?login:")
 934         (process-send-string
 935          proc (concat
 936                (or nntp-telnet-user-name
 937                    (setq nntp-telnet-user-name (read-string "login: ")))
 938                "\n"))
 939         (nntp-wait-for-string "^\r*.?password:")
 940         (process-send-string
 941          proc (concat
 942                (or nntp-telnet-passwd
 943                    (setq nntp-telnet-passwd
 944                          (nnmail-read-passwd "Password: ")))
 945                "\n"))
 946         (erase-buffer)
 947         (nntp-wait-for-string "bash\\|\$ *\r?$\\|> *\r?")
 948         (process-send-string
 949          proc (concat (mapconcat 'identity nntp-telnet-parameters " ") "\n"))
 950         (nntp-wait-for-string "^\r*200")
 951         (beginning-of-line)
 952         (delete-region (point-min) (point))
 953         (process-send-string proc "\^]")
 954         (nntp-wait-for-string "^telnet")
 955         (process-send-string proc "mode character\n")
 956         (accept-process-output proc 1)
 957         (sit-for 1)
 958         (goto-char (point-min))
 959         (forward-line 1)
 960         (delete-region (point) (point-max)))
 961       proc)))
 962
 963 (defun nntp-open-rlogin (buffer)
 964   "Open a connection to SERVER using rsh."
 965   (let ((proc (if nntp-rlogin-user-name
 966                   (start-process
 967                    "nntpd" buffer "rsh"
 968                    nntp-address "-l" nntp-rlogin-user-name
 969                    (mapconcat 'identity
 970                               nntp-rlogin-parameters " "))
 971                 (start-process
 972                  "nntpd" buffer "rsh" nntp-address
 973                  (mapconcat 'identity
 974                             nntp-rlogin-parameters " ")))))
 975     (set-buffer buffer)
 976     (nntp-wait-for-string "^\r*200")
 977     (beginning-of-line)
 978     (delete-region (point-min) (point))
 979     proc)
 980   )
 981
 982 (defun nntp-find-group-and-number ()
 983   (save-excursion
 984     (save-restriction
 985       (set-buffer nntp-server-buffer)
 986       (narrow-to-region (goto-char (point-min))
 987                         (or (search-forward "\n\n" nil t) (point-max)))
 988       (goto-char (point-min))
 989       ;; We first find the number by looking at the status line.
 990       (let ((number (and (looking-at "2[0-9][0-9] +\\([0-9]+\\) ")
 991                          (string-to-int
 992                           (buffer-substring (match-beginning 1)
 993                                             (match-end 1)))))
 994             group newsgroups xref)
 995         (and number (zerop number) (setq number nil))
 996         ;; Then we find the group name.
 997         (setq group
 998               (cond
 999                ;; If there is only one group in the Newsgroups header,
1000                ;; then it seems quite likely that this article comes
1001                ;; from that group, I'd say.
1002                ((and (setq newsgroups (mail-fetch-field "newsgroups"))
1003                      (not (string-match "," newsgroups)))
1004                 newsgroups)
1005                ;; If there is more than one group in the Newsgroups
1006                ;; header, then the Xref header should be filled out.
1007                ;; We hazard a guess that the group that has this
1008                ;; article number in the Xref header is the one we are
1009                ;; looking for.  This might very well be wrong if this
1010                ;; article happens to have the same number in several
1011                ;; groups, but that's life.
1012                ((and (setq xref (mail-fetch-field "xref"))
1013                      number
1014                      (string-match (format "\\([^ :]+\\):%d" number) xref))
1015                 (substring xref (match-beginning 1) (match-end 1)))
1016                (t "")))
1017         (when (string-match "\r" group)
1018           (setq group (substring group 0 (match-beginning 0))))
1019         (cons group number)))))
1020
1021 (provide 'nntp)
1022
1023 ;;; nntp.el ends here