cgit.sxemacs.org Git - gnus/blob - lisp/nnml.el

   1 ;;; nnml.el --- mail spool access for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;;; Code:
  32
  33 (require 'nnheader)
  34 (require 'nnmail)
  35 (require 'nnoo)
  36 (require 'cl)
  37
  38 (nnoo-declare nnml)
  39
  40 (defvoo nnml-directory message-directory
  41   "Mail spool directory.")
  42
  43 (defvoo nnml-active-file
  44   (concat (file-name-as-directory nnml-directory) "active")
  45   "Mail active file.")
  46
  47 (defvoo nnml-newsgroups-file
  48   (concat (file-name-as-directory nnml-directory) "newsgroups")
  49   "Mail newsgroups description file.")
  50
  51 (defvoo nnml-get-new-mail t
  52   "If non-nil, nnml will check the incoming mail file and split the mail.")
  53
  54 (defvoo nnml-nov-is-evil nil
  55   "If non-nil, Gnus will never generate and use nov databases for mail groups.
  56 Using nov databases will speed up header fetching considerably.
  57 This variable shouldn't be flipped much.  If you have, for some reason,
  58 set this to t, and want to set it to nil again, you should always run
  59 the `nnml-generate-nov-databases' command.  The function will go
  60 through all nnml directories and generate nov databases for them
  61 all.  This may very well take some time.")
  62
  63 (defvoo nnml-prepare-save-mail-hook nil
  64   "Hook run narrowed to an article before saving.")
  65
  66 (defvoo nnml-inhibit-expiry nil
  67   "If non-nil, inhibit expiry.")
  68
  69
  70 \f
  71
  72 (defconst nnml-version "nnml 1.0"
  73   "nnml version.")
  74
  75 (defvoo nnml-nov-file-name ".overview")
  76
  77 (defvoo nnml-current-directory nil)
  78 (defvoo nnml-current-group nil)
  79 (defvoo nnml-status-string "")
  80 (defvoo nnml-nov-buffer-alist nil)
  81 (defvoo nnml-group-alist nil)
  82 (defvoo nnml-active-timestamp nil)
  83 (defvoo nnml-article-file-alist nil)
  84
  85 (defvoo nnml-generate-active-function 'nnml-generate-active-info)
  86
  87 \f
  88
  89 ;;; Interface functions.
  90
  91 (nnoo-define-basics nnml)
  92
  93 (deffoo nnml-retrieve-headers (sequence &optional newsgroup server fetch-old)
  94   (save-excursion
  95     (set-buffer nntp-server-buffer)
  96     (erase-buffer)
  97     (let ((file nil)
  98           (number (length sequence))
  99           (count 0)
 100           beg article)
 101       (if (stringp (car sequence))
 102           'headers
 103         (nnml-possibly-change-directory newsgroup server)
 104         (unless nnml-article-file-alist
 105           (setq nnml-article-file-alist
 106                 (nnheader-article-to-file-alist nnml-current-directory)))
 107         (if (nnml-retrieve-headers-with-nov sequence fetch-old)
 108             'nov
 109           (while sequence
 110             (setq article (car sequence))
 111             (setq file
 112                   (concat nnml-current-directory
 113                           (or (cdr (assq article nnml-article-file-alist))
 114                               "")))
 115             (when (and (file-exists-p file)
 116                        (not (file-directory-p file)))
 117               (insert (format "221 %d Article retrieved.\n" article))
 118               (setq beg (point))
 119               (nnheader-insert-head file)
 120               (goto-char beg)
 121               (if (search-forward "\n\n" nil t)
 122                   (forward-char -1)
 123                 (goto-char (point-max))
 124                 (insert "\n\n"))
 125               (insert ".\n")
 126               (delete-region (point) (point-max)))
 127             (setq sequence (cdr sequence))
 128             (setq count (1+ count))
 129             (and (numberp nnmail-large-newsgroup)
 130                  (> number nnmail-large-newsgroup)
 131                  (zerop (% count 20))
 132                  (nnheader-message 6 "nnml: Receiving headers... %d%%"
 133                                    (/ (* count 100) number))))
 134
 135           (and (numberp nnmail-large-newsgroup)
 136                (> number nnmail-large-newsgroup)
 137                (nnheader-message 6 "nnml: Receiving headers...done"))
 138
 139           (nnheader-fold-continuation-lines)
 140           'headers)))))
 141
 142 (deffoo nnml-open-server (server &optional defs)
 143   (nnoo-change-server 'nnml server defs)
 144   (when (not (file-exists-p nnml-directory))
 145     (condition-case ()
 146         (make-directory nnml-directory t)
 147       (error t)))
 148   (cond
 149    ((not (file-exists-p nnml-directory))
 150     (nnml-close-server)
 151     (nnheader-report 'nnml "Couldn't create directory: %s" nnml-directory))
 152    ((not (file-directory-p (file-truename nnml-directory)))
 153     (nnml-close-server)
 154     (nnheader-report 'nnml "Not a directory: %s" nnml-directory))
 155    (t
 156     (nnheader-report 'nnml "Opened server %s using directory %s"
 157                      server nnml-directory)
 158     t)))
 159
 160 (deffoo nnml-request-article (id &optional newsgroup server buffer)
 161   (nnml-possibly-change-directory newsgroup server)
 162   (let* ((nntp-server-buffer (or buffer nntp-server-buffer))
 163          path gpath group-num)
 164     (if (stringp id)
 165         (when (and (setq group-num (nnml-find-group-number id))
 166                    (cdr
 167                     (assq (cdr group-num)
 168                           (nnheader-article-to-file-alist
 169                            (setq gpath
 170                                  (nnmail-group-pathname
 171                                   (car group-num)
 172                                   nnml-directory))))))
 173           (setq path (concat gpath (int-to-string (cdr group-num)))))
 174       (setq path (nnml-article-to-file id)))
 175     (cond
 176      ((not path)
 177       (nnheader-report 'nnml "No such article: %s" id))
 178      ((not (file-exists-p path))
 179       (nnheader-report 'nnml "No such file: %s" path))
 180      ((file-directory-p path)
 181       (nnheader-report 'nnml "File is a directory: %s" path))
 182      ((not (save-excursion (nnmail-find-file path)))
 183       (nnheader-report 'nnml "Couldn't read file: %s" path))
 184      (t
 185       (nnheader-report 'nnml "Article %s retrieved" id)
 186       ;; We return the article number.
 187       (cons newsgroup (string-to-int (file-name-nondirectory path)))))))
 188
 189 (deffoo nnml-request-group (group &optional server dont-check)
 190   (cond
 191    ((not (nnml-possibly-change-directory group server))
 192     (nnheader-report 'nnml "Invalid group (no such directory)"))
 193    ((not (file-exists-p nnml-current-directory))
 194     (nnheader-report 'nnml "Directory %s does not exist"
 195                      nnml-current-directory))
 196    ((not (file-directory-p nnml-current-directory))
 197     (nnheader-report 'nnml "%s is not a directory" nnml-current-directory))
 198    (dont-check
 199     (nnheader-report 'nnml "Group %s selected" group)
 200     t)
 201    (t
 202     (nnheader-re-read-dir nnml-current-directory)
 203     (nnmail-activate 'nnml)
 204     (let ((active (nth 1 (assoc group nnml-group-alist))))
 205       (if (not active)
 206           (nnheader-report 'nnml "No such group: %s" group)
 207         (nnheader-report 'nnml "Selected group %s" group)
 208         (nnheader-insert "211 %d %d %d %s\n"
 209                          (max (1+ (- (cdr active) (car active))) 0)
 210                          (car active) (cdr active) group))))))
 211
 212 (deffoo nnml-request-scan (&optional group server)
 213   (setq nnml-article-file-alist nil)
 214   (nnmail-get-new-mail 'nnml 'nnml-save-nov nnml-directory group))
 215
 216 (deffoo nnml-close-group (group &optional server)
 217   (setq nnml-article-file-alist nil)
 218   t)
 219
 220 (deffoo nnml-request-create-group (group &optional server args)
 221   (nnmail-activate 'nnml)
 222   (unless (assoc group nnml-group-alist)
 223     (let (active)
 224       (push (list group (setq active (cons 1 0)))
 225             nnml-group-alist)
 226       (nnml-possibly-create-directory group)
 227       (nnml-possibly-change-directory group server)
 228       (let ((articles (nnheader-directory-articles nnml-current-directory)))
 229         (when articles
 230           (setcar active (apply 'min articles))
 231           (setcdr active (apply 'max articles))))
 232       (nnmail-save-active nnml-group-alist nnml-active-file)))
 233   t)
 234
 235 (deffoo nnml-request-list (&optional server)
 236   (save-excursion
 237     (nnmail-find-file nnml-active-file)
 238     (setq nnml-group-alist (nnmail-get-active))))
 239
 240 (deffoo nnml-request-newgroups (date &optional server)
 241   (nnml-request-list server))
 242
 243 (deffoo nnml-request-list-newsgroups (&optional server)
 244   (save-excursion
 245     (nnmail-find-file nnml-newsgroups-file)))
 246
 247 (deffoo nnml-request-expire-articles (articles newsgroup &optional server force)
 248   (nnml-possibly-change-directory newsgroup server)
 249   (let* ((active-articles
 250           (nnheader-directory-articles nnml-current-directory))
 251          (is-old t)
 252          article rest mod-time number)
 253     (nnmail-activate 'nnml)
 254
 255     (unless nnml-article-file-alist
 256       (setq nnml-article-file-alist
 257             (nnheader-article-to-file-alist nnml-current-directory)))
 258
 259     (while (and articles is-old)
 260       (setq article (concat nnml-current-directory
 261                             (int-to-string
 262                              (setq number (pop articles)))))
 263       (when (setq mod-time (nth 5 (file-attributes article)))
 264         (if (and (nnml-deletable-article-p newsgroup number)
 265                  (setq is-old
 266                        (nnmail-expired-article-p newsgroup mod-time force
 267                                                  nnml-inhibit-expiry)))
 268             (progn
 269               (nnheader-message 5 "Deleting article %s in %s..."
 270                                 article newsgroup)
 271               (condition-case ()
 272                   (funcall nnmail-delete-file-function article)
 273                 (file-error
 274                  (push number rest)))
 275               (setq active-articles (delq number active-articles))
 276               (nnml-nov-delete-article newsgroup number))
 277           (push number rest))))
 278     (let ((active (nth 1 (assoc newsgroup nnml-group-alist))))
 279       (when active
 280         (setcar active (or (and active-articles
 281                                 (apply 'min active-articles))
 282                            (1+ (cdr active)))))
 283       (nnmail-save-active nnml-group-alist nnml-active-file))
 284     (nnml-save-nov)
 285     (message "")
 286     (nconc rest articles)))
 287
 288 (deffoo nnml-request-move-article
 289   (article group server accept-form &optional last)
 290   (let ((buf (get-buffer-create " *nnml move*"))
 291         result)
 292     (nnml-possibly-change-directory group server)
 293     (unless nnml-article-file-alist
 294       (setq nnml-article-file-alist
 295             (nnheader-article-to-file-alist nnml-current-directory)))
 296     (and
 297      (nnml-deletable-article-p group article)
 298      (nnml-request-article article group server)
 299      (save-excursion
 300        (set-buffer buf)
 301        (insert-buffer-substring nntp-server-buffer)
 302        (setq result (eval accept-form))
 303        (kill-buffer (current-buffer))
 304        result)
 305      (progn
 306        (nnml-possibly-change-directory group server)
 307        (condition-case ()
 308            (funcall nnmail-delete-file-function
 309                     (concat nnml-current-directory
 310                             (int-to-string article)))
 311          (file-error nil))
 312        (nnml-nov-delete-article group article)
 313        (and last (nnml-save-nov))))
 314     result))
 315
 316 (deffoo nnml-request-accept-article (group &optional server last)
 317   (nnml-possibly-change-directory group server)
 318   (nnmail-check-syntax)
 319   (let (result)
 320     (if (stringp group)
 321         (and
 322          (nnmail-activate 'nnml)
 323          (setq result (car (nnml-save-mail
 324                             (list (cons group (nnml-active-number group))))))
 325          (progn
 326            (nnmail-save-active nnml-group-alist nnml-active-file)
 327            (and last (nnml-save-nov))))
 328       (and
 329        (nnmail-activate 'nnml)
 330        (setq result (car (nnml-save-mail
 331                           (nnmail-article-group 'nnml-active-number))))
 332        (progn
 333          (nnmail-save-active nnml-group-alist nnml-active-file)
 334          (and last (nnml-save-nov)))))
 335     result))
 336
 337 (deffoo nnml-request-replace-article (article group buffer)
 338   (nnml-possibly-change-directory group)
 339   (save-excursion
 340     (set-buffer buffer)
 341     (nnml-possibly-create-directory group)
 342     (let ((chars (nnmail-insert-lines))
 343           (art (concat (int-to-string article) "\t"))
 344           headers)
 345       (when (condition-case ()
 346                 (progn
 347                   (nnmail-write-region
 348                    (point-min) (point-max)
 349                    (concat nnml-current-directory
 350                            (int-to-string article))
 351                    nil (if (nnheader-be-verbose 5) nil 'nomesg))
 352                   t)
 353               (error nil))
 354         (setq headers (nnml-parse-head chars article))
 355         ;; Replace the NOV line in the NOV file.
 356         (save-excursion
 357           (set-buffer (nnml-open-nov group))
 358           (goto-char (point-min))
 359           (if (or (looking-at art)
 360                   (search-forward (concat "\n" art) nil t))
 361               ;; Delete the old NOV line.
 362               (delete-region (progn (beginning-of-line) (point))
 363                              (progn (forward-line 1) (point)))
 364             ;; The line isn't here, so we have to find out where
 365             ;; we should insert it.  (This situation should never
 366             ;; occur, but one likes to make sure...)
 367             (while (and (looking-at "[0-9]+\t")
 368                         (< (string-to-int
 369                             (buffer-substring
 370                              (match-beginning 0) (match-end 0)))
 371                            article)
 372                         (zerop (forward-line 1)))))
 373           (beginning-of-line)
 374           (nnheader-insert-nov headers)
 375           (nnml-save-nov)
 376           t)))))
 377
 378 (deffoo nnml-request-delete-group (group &optional force server)
 379   (nnml-possibly-change-directory group server)
 380   (when force
 381     ;; Delete all articles in GROUP.
 382     (let ((articles
 383            (directory-files
 384             nnml-current-directory t
 385             (concat nnheader-numerical-short-files
 386                     "\\|" (regexp-quote nnml-nov-file-name) "$")))
 387           article)
 388       (while articles
 389         (setq article (pop articles))
 390         (when (file-writable-p article)
 391           (nnheader-message 5 "Deleting article %s in %s..." article group)
 392           (funcall nnmail-delete-file-function article))))
 393     ;; Try to delete the directory itself.
 394     (condition-case ()
 395         (delete-directory nnml-current-directory)
 396       (error nil)))
 397   ;; Remove the group from all structures.
 398   (setq nnml-group-alist
 399         (delq (assoc group nnml-group-alist) nnml-group-alist)
 400         nnml-current-group nil
 401         nnml-current-directory nil)
 402   ;; Save the active file.
 403   (nnmail-save-active nnml-group-alist nnml-active-file)
 404   t)
 405
 406 (deffoo nnml-request-rename-group (group new-name &optional server)
 407   (nnml-possibly-change-directory group server)
 408   (let ((new-dir (nnmail-group-pathname new-name nnml-directory))
 409         (old-dir (nnmail-group-pathname group nnml-directory)))
 410     (when (condition-case ()
 411               (progn
 412                 (make-directory new-dir t)
 413                 t)
 414             (error nil))
 415       ;; We move the articles file by file instead of renaming
 416       ;; the directory -- there may be subgroups in this group.
 417       ;; One might be more clever, I guess.
 418       (let ((files (nnheader-article-to-file-alist old-dir)))
 419         (while files
 420           (rename-file
 421            (concat old-dir (cdar files))
 422            (concat new-dir (cdar files)))
 423           (pop files)))
 424       ;; Move .overview file.
 425       (let ((overview (concat old-dir nnml-nov-file-name)))
 426         (when (file-exists-p overview)
 427           (rename-file overview (concat new-dir nnml-nov-file-name))))
 428       (when (<= (length (directory-files old-dir)) 2)
 429         (condition-case ()
 430             (delete-directory old-dir)
 431           (error nil)))
 432       ;; That went ok, so we change the internal structures.
 433       (let ((entry (assoc group nnml-group-alist)))
 434         (when entry
 435           (setcar entry new-name))
 436         (setq nnml-current-directory nil
 437               nnml-current-group nil)
 438         ;; Save the new group alist.
 439         (nnmail-save-active nnml-group-alist nnml-active-file)
 440         t))))
 441
 442 (deffoo nnml-set-status (article name value &optional group server)
 443   (nnml-possibly-change-directory group server)
 444   (let ((file (nnml-article-to-file article)))
 445     (cond
 446      ((not (file-exists-p file))
 447       (nnheader-report 'nnml "File %s does not exist" file))
 448      (t
 449       (nnheader-temp-write file
 450         (nnheader-insert-file-contents-literally file)
 451         (nnmail-replace-status name value))
 452       t))))
 453
 454 \f
 455 ;;; Internal functions.
 456
 457 (defun nnml-article-to-file (article)
 458   (unless nnml-article-file-alist
 459     (setq nnml-article-file-alist
 460           (nnheader-article-to-file-alist nnml-current-directory)))
 461   (let (file)
 462     (when (setq file (cdr (assq article nnml-article-file-alist)))
 463       (concat nnml-current-directory file))))
 464
 465 (defun nnml-deletable-article-p (group article)
 466   "Say whether ARTICLE in GROUP can be deleted."
 467   (let (file path)
 468     (when (setq file (cdr (assq article nnml-article-file-alist)))
 469       (setq path (concat nnml-current-directory file))
 470       (when (file-writable-p path)
 471         (or (not nnmail-keep-last-article)
 472             (not (eq (cdr (nth 1 (assoc group nnml-group-alist)))
 473                      article)))))))
 474
 475 ;; Find an article number in the current group given the Message-ID.
 476 (defun nnml-find-group-number (id)
 477   (save-excursion
 478     (set-buffer (get-buffer-create " *nnml id*"))
 479     (buffer-disable-undo (current-buffer))
 480     (let ((alist nnml-group-alist)
 481           number)
 482       ;; We want to look through all .overview files, but we want to
 483       ;; start with the one in the current directory.  It seems most
 484       ;; likely that the article we are looking for is in that group.
 485       (if (setq number (nnml-find-id nnml-current-group id))
 486           (cons nnml-current-group number)
 487         ;; It wasn't there, so we look through the other groups as well.
 488         (while (and (not number)
 489                     alist)
 490           (or (string= (caar alist) nnml-current-group)
 491               (setq number (nnml-find-id (caar alist) id)))
 492           (or number
 493               (setq alist (cdr alist))))
 494         (and number
 495              (cons (caar alist) number))))))
 496
 497 (defun nnml-find-id (group id)
 498   (erase-buffer)
 499   (let ((nov (concat (nnmail-group-pathname group nnml-directory)
 500                      nnml-nov-file-name))
 501         number found)
 502     (when (file-exists-p nov)
 503       (insert-file-contents nov)
 504       (while (and (not found)
 505                   (search-forward id nil t)) ; We find the ID.
 506         ;; And the id is in the fourth field.
 507         (when (search-backward
 508                "\t" (save-excursion (beginning-of-line) (point)) t 4)
 509           (beginning-of-line)
 510           (setq found t)
 511           ;; We return the article number.
 512           (setq number
 513                 (condition-case ()
 514                     (read (current-buffer))
 515                   (error nil)))))
 516       number)))
 517
 518 (defun nnml-retrieve-headers-with-nov (articles &optional fetch-old)
 519   (if (or gnus-nov-is-evil nnml-nov-is-evil)
 520       nil
 521     (let ((first (car articles))
 522           (last (progn (while (cdr articles) (setq articles (cdr articles)))
 523                        (car articles)))
 524           (nov (concat nnml-current-directory nnml-nov-file-name)))
 525       (when (file-exists-p nov)
 526         (save-excursion
 527           (set-buffer nntp-server-buffer)
 528           (erase-buffer)
 529           (insert-file-contents nov)
 530           (if (and fetch-old
 531                    (not (numberp fetch-old)))
 532               t                         ; Don't remove anything.
 533             (when fetch-old
 534               (setq first (max 1 (- first fetch-old))))
 535             (goto-char (point-min))
 536             (while (and (not (eobp)) (> first (read (current-buffer))))
 537               (forward-line 1))
 538             (beginning-of-line)
 539             (when (not (eobp))
 540               (delete-region 1 (point)))
 541             (while (and (not (eobp)) (>= last (read (current-buffer))))
 542               (forward-line 1))
 543             (beginning-of-line)
 544             (when (not (eobp))
 545               (delete-region (point) (point-max)))
 546             t))))))
 547
 548 (defun nnml-possibly-change-directory (group &optional server)
 549   (when (and server
 550              (not (nnml-server-opened server)))
 551     (nnml-open-server server))
 552   (when group
 553     (let ((pathname (nnmail-group-pathname group nnml-directory)))
 554       (when (not (equal pathname nnml-current-directory))
 555         (setq nnml-current-directory pathname
 556               nnml-current-group group
 557               nnml-article-file-alist nil))))
 558   t)
 559
 560 (defun nnml-possibly-create-directory (group)
 561   (let (dir dirs)
 562     (setq dir (nnmail-group-pathname group nnml-directory))
 563     (while (not (file-directory-p dir))
 564       (push dir dirs)
 565       (setq dir (file-name-directory (directory-file-name dir))))
 566     (while dirs
 567       (make-directory (directory-file-name (car dirs)))
 568       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 569       (setq dirs (cdr dirs)))))
 570
 571 (defun nnml-save-mail (group-art)
 572   "Called narrowed to an article."
 573   (let (chars headers)
 574     (setq chars (nnmail-insert-lines))
 575     (nnmail-insert-xref group-art)
 576     (run-hooks 'nnmail-prepare-save-mail-hook)
 577     (run-hooks 'nnml-prepare-save-mail-hook)
 578     (goto-char (point-min))
 579     (while (looking-at "From ")
 580       (replace-match "X-From-Line: ")
 581       (forward-line 1))
 582     ;; We save the article in all the newsgroups it belongs in.
 583     (let ((ga group-art)
 584           first)
 585       (while ga
 586         (nnml-possibly-create-directory (caar ga))
 587         (let ((file (concat (nnmail-group-pathname
 588                              (caar ga) nnml-directory)
 589                             (int-to-string (cdar ga)))))
 590           (if first
 591               ;; It was already saved, so we just make a hard link.
 592               (funcall nnmail-crosspost-link-function first file t)
 593             ;; Save the article.
 594             (nnmail-write-region (point-min) (point-max) file nil
 595                                  (if (nnheader-be-verbose 5) nil 'nomesg))
 596             (setq first file)))
 597         (setq ga (cdr ga))))
 598     ;; Generate a nov line for this article.  We generate the nov
 599     ;; line after saving, because nov generation destroys the
 600     ;; header.
 601     (setq headers (nnml-parse-head chars))
 602     ;; Output the nov line to all nov databases that should have it.
 603     (let ((ga group-art))
 604       (while ga
 605         (nnml-add-nov (caar ga) (cdar ga) headers)
 606         (setq ga (cdr ga))))
 607     group-art))
 608
 609 (defun nnml-active-number (group)
 610   "Compute the next article number in GROUP."
 611   (let ((active (cadr (assoc group nnml-group-alist))))
 612     ;; The group wasn't known to nnml, so we just create an active
 613     ;; entry for it.
 614     (unless active
 615       ;; Perhaps the active file was corrupt?  See whether
 616       ;; there are any articles in this group.
 617       (nnml-possibly-create-directory group)
 618       (nnml-possibly-change-directory group)
 619       (unless nnml-article-file-alist
 620         (setq nnml-article-file-alist
 621               (sort
 622                (nnheader-article-to-file-alist nnml-current-directory)
 623                (lambda (a1 a2) (< (car a1) (car a2))))))
 624       (setq active
 625             (if nnml-article-file-alist
 626                 (cons (caar nnml-article-file-alist)
 627                       (caar (last nnml-article-file-alist)))
 628               (cons 1 0)))
 629       (push (list group active) nnml-group-alist))
 630     (setcdr active (1+ (cdr active)))
 631     (while (file-exists-p
 632             (concat (nnmail-group-pathname group nnml-directory)
 633                     (int-to-string (cdr active))))
 634       (setcdr active (1+ (cdr active))))
 635     (cdr active)))
 636
 637 (defun nnml-add-nov (group article headers)
 638   "Add a nov line for the GROUP base."
 639   (save-excursion
 640     (set-buffer (nnml-open-nov group))
 641     (goto-char (point-max))
 642     (mail-header-set-number headers article)
 643     (nnheader-insert-nov headers)))
 644
 645 (defsubst nnml-header-value ()
 646   (buffer-substring (match-end 0) (progn (end-of-line) (point))))
 647
 648 (defun nnml-parse-head (chars &optional number)
 649   "Parse the head of the current buffer."
 650   (save-excursion
 651     (save-restriction
 652       (goto-char (point-min))
 653       (narrow-to-region
 654        (point)
 655        (1- (or (search-forward "\n\n" nil t) (point-max))))
 656       ;; Fold continuation lines.
 657       (goto-char (point-min))
 658       (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
 659         (replace-match " " t t))
 660       ;; Remove any tabs; they are too confusing.
 661       (subst-char-in-region (point-min) (point-max) ?\t ? )
 662       (let ((headers (nnheader-parse-head t)))
 663         (mail-header-set-chars headers chars)
 664         (mail-header-set-number headers number)
 665         headers))))
 666
 667 (defun nnml-open-nov (group)
 668   (or (cdr (assoc group nnml-nov-buffer-alist))
 669       (let ((buffer (find-file-noselect
 670                      (concat (nnmail-group-pathname group nnml-directory)
 671                              nnml-nov-file-name))))
 672         (save-excursion
 673           (set-buffer buffer)
 674           (buffer-disable-undo (current-buffer)))
 675         (push (cons group buffer) nnml-nov-buffer-alist)
 676         buffer)))
 677
 678 (defun nnml-save-nov ()
 679   (save-excursion
 680     (while nnml-nov-buffer-alist
 681       (when (buffer-name (cdar nnml-nov-buffer-alist))
 682         (set-buffer (cdar nnml-nov-buffer-alist))
 683         (when (buffer-modified-p)
 684           (nnmail-write-region 1 (point-max) (buffer-file-name) nil 'nomesg))
 685         (set-buffer-modified-p nil)
 686         (kill-buffer (current-buffer)))
 687       (setq nnml-nov-buffer-alist (cdr nnml-nov-buffer-alist)))))
 688
 689 ;;;###autoload
 690 (defun nnml-generate-nov-databases ()
 691   "Generate nov databases in all nnml directories."
 692   (interactive)
 693   ;; Read the active file to make sure we don't re-use articles
 694   ;; numbers in empty groups.
 695   (nnmail-activate 'nnml)
 696   (nnml-open-server (or (nnoo-current-server 'nnml) ""))
 697   (setq nnml-directory (expand-file-name nnml-directory))
 698   ;; Recurse down the directories.
 699   (nnml-generate-nov-databases-1 nnml-directory)
 700   ;; Save the active file.
 701   (nnmail-save-active nnml-group-alist nnml-active-file))
 702
 703 (defun nnml-generate-nov-databases-1 (dir)
 704   (setq dir (file-name-as-directory dir))
 705   ;; We descend recursively
 706   (let ((dirs (directory-files dir t nil t))
 707         dir)
 708     (while dirs
 709       (setq dir (pop dirs))
 710       (when (and (not (member (file-name-nondirectory dir) '("." "..")))
 711                  (file-directory-p dir))
 712         (nnml-generate-nov-databases-1 dir))))
 713   ;; Do this directory.
 714   (let ((files (sort
 715                 (mapcar
 716                  (lambda (name) (string-to-int name))
 717                  (directory-files dir nil "^[0-9]+$" t))
 718                 '<)))
 719     (when files
 720       (funcall nnml-generate-active-function dir)
 721       ;; Generate the nov file.
 722       (nnml-generate-nov-file dir files))))
 723
 724 (defvar files)
 725 (defun nnml-generate-active-info (dir)
 726   ;; Update the active info for this group.
 727   (let ((group (nnheader-file-to-group
 728                 (directory-file-name dir) nnml-directory)))
 729     (setq nnml-group-alist
 730           (delq (assoc group nnml-group-alist) nnml-group-alist))
 731     (push (list group
 732                 (cons (car files)
 733                       (let ((f files))
 734                         (while (cdr f) (setq f (cdr f)))
 735                         (car f))))
 736           nnml-group-alist)))
 737
 738 (defun nnml-generate-nov-file (dir files)
 739   (let* ((dir (file-name-as-directory dir))
 740          (nov (concat dir nnml-nov-file-name))
 741          (nov-buffer (get-buffer-create " *nov*"))
 742          chars file headers)
 743     (save-excursion
 744       ;; Init the nov buffer.
 745       (set-buffer nov-buffer)
 746       (buffer-disable-undo (current-buffer))
 747       (erase-buffer)
 748       (set-buffer nntp-server-buffer)
 749       ;; Delete the old NOV file.
 750       (when (file-exists-p nov)
 751         (funcall nnmail-delete-file-function nov))
 752       (while files
 753         (unless (file-directory-p
 754                  (setq file (concat dir (int-to-string (car files)))))
 755           (erase-buffer)
 756           (insert-file-contents file)
 757           (narrow-to-region
 758            (goto-char (point-min))
 759            (progn
 760              (search-forward "\n\n" nil t)
 761              (setq chars (- (point-max) (point)))
 762              (max 1 (1- (point)))))
 763           (when (and (not (= 0 chars))  ; none of them empty files...
 764                      (not (= (point-min) (point-max))))
 765             (goto-char (point-min))
 766             (setq headers (nnml-parse-head chars (car files)))
 767             (save-excursion
 768               (set-buffer nov-buffer)
 769               (goto-char (point-max))
 770               (nnheader-insert-nov headers)))
 771           (widen))
 772         (setq files (cdr files)))
 773       (save-excursion
 774         (set-buffer nov-buffer)
 775         (nnmail-write-region 1 (point-max) nov nil 'nomesg)
 776         (kill-buffer (current-buffer))))))
 777
 778 (defun nnml-nov-delete-article (group article)
 779   (save-excursion
 780     (set-buffer (nnml-open-nov group))
 781     (goto-char (point-min))
 782     (when (re-search-forward (concat "^" (int-to-string article) "\t") nil t)
 783       (delete-region (match-beginning 0) (progn (forward-line 1) (point))))
 784     t))
 785
 786 (provide 'nnml)
 787
 788 ;;; nnml.el ends here