cgit.sxemacs.org Git - gnus/blob - lisp/nnml.el

   1 ;;; nnml.el --- mail spool access for Gnus
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;;; Code:
  32
  33 (require 'nnheader)
  34 (require 'nnmail)
  35 (require 'nnoo)
  36 (require 'cl)
  37
  38 (nnoo-declare nnml)
  39
  40 (defvoo nnml-directory message-directory
  41   "Mail spool directory.")
  42
  43 (defvoo nnml-active-file
  44   (concat (file-name-as-directory nnml-directory) "active")
  45   "Mail active file.")
  46
  47 (defvoo nnml-newsgroups-file
  48   (concat (file-name-as-directory nnml-directory) "newsgroups")
  49   "Mail newsgroups description file.")
  50
  51 (defvoo nnml-get-new-mail t
  52   "If non-nil, nnml will check the incoming mail file and split the mail.")
  53
  54 (defvoo nnml-nov-is-evil nil
  55   "If non-nil, Gnus will never generate and use nov databases for mail groups.
  56 Using nov databases will speed up header fetching considerably.
  57 This variable shouldn't be flipped much.  If you have, for some reason,
  58 set this to t, and want to set it to nil again, you should always run
  59 the `nnml-generate-nov-databases' command.  The function will go
  60 through all nnml directories and generate nov databases for them
  61 all.  This may very well take some time.")
  62
  63 (defvoo nnml-prepare-save-mail-hook nil
  64   "Hook run narrowed to an article before saving.")
  65
  66 (defvoo nnml-inhibit-expiry nil
  67   "If non-nil, inhibit expiry.")
  68
  69
  70 \f
  71
  72 (defconst nnml-version "nnml 1.0"
  73   "nnml version.")
  74
  75 (defvoo nnml-nov-file-name ".overview")
  76
  77 (defvoo nnml-current-directory nil)
  78 (defvoo nnml-current-group nil)
  79 (defvoo nnml-status-string "")
  80 (defvoo nnml-nov-buffer-alist nil)
  81 (defvoo nnml-group-alist nil)
  82 (defvoo nnml-active-timestamp nil)
  83 (defvoo nnml-article-file-alist nil)
  84
  85 (defvoo nnml-generate-active-function 'nnml-generate-active-info)
  86
  87 \f
  88
  89 ;;; Interface functions.
  90
  91 (nnoo-define-basics nnml)
  92
  93 (deffoo nnml-retrieve-headers (sequence &optional group server fetch-old)
  94   (when (nnml-possibly-change-directory group server)
  95     (save-excursion
  96       (set-buffer nntp-server-buffer)
  97       (erase-buffer)
  98       (let ((file nil)
  99             (number (length sequence))
 100             (count 0)
 101             beg article)
 102         (if (stringp (car sequence))
 103             'headers
 104           (if (nnml-retrieve-headers-with-nov sequence fetch-old)
 105               'nov
 106             (while sequence
 107               (setq article (car sequence))
 108               (setq file (nnml-article-to-file article))
 109               (when (and file
 110                          (file-exists-p file)
 111                          (not (file-directory-p file)))
 112                 (insert (format "221 %d Article retrieved.\n" article))
 113                 (setq beg (point))
 114                 (nnheader-insert-head file)
 115                 (goto-char beg)
 116                 (if (search-forward "\n\n" nil t)
 117                     (forward-char -1)
 118                   (goto-char (point-max))
 119                   (insert "\n\n"))
 120                 (insert ".\n")
 121                 (delete-region (point) (point-max)))
 122               (setq sequence (cdr sequence))
 123               (setq count (1+ count))
 124               (and (numberp nnmail-large-newsgroup)
 125                    (> number nnmail-large-newsgroup)
 126                    (zerop (% count 20))
 127                    (nnheader-message 6 "nnml: Receiving headers... %d%%"
 128                                      (/ (* count 100) number))))
 129
 130             (and (numberp nnmail-large-newsgroup)
 131                  (> number nnmail-large-newsgroup)
 132                  (nnheader-message 6 "nnml: Receiving headers...done"))
 133
 134             (nnheader-fold-continuation-lines)
 135             'headers))))))
 136
 137 (deffoo nnml-open-server (server &optional defs)
 138   (nnoo-change-server 'nnml server defs)
 139   (when (not (file-exists-p nnml-directory))
 140     (condition-case ()
 141         (make-directory nnml-directory t)
 142       (error)))
 143   (cond
 144    ((not (file-exists-p nnml-directory))
 145     (nnml-close-server)
 146     (nnheader-report 'nnml "Couldn't create directory: %s" nnml-directory))
 147    ((not (file-directory-p (file-truename nnml-directory)))
 148     (nnml-close-server)
 149     (nnheader-report 'nnml "Not a directory: %s" nnml-directory))
 150    (t
 151     (nnheader-report 'nnml "Opened server %s using directory %s"
 152                      server nnml-directory)
 153     t)))
 154
 155 (defun nnml-request-regenerate (server)
 156   (nnml-possibly-change-directory nil server)
 157   (nnml-generate-nov-databases)
 158   t)
 159
 160 (deffoo nnml-request-article (id &optional group server buffer)
 161   (nnml-possibly-change-directory group server)
 162   (let* ((nntp-server-buffer (or buffer nntp-server-buffer))
 163          path gpath group-num)
 164     (if (stringp id)
 165         (when (and (setq group-num (nnml-find-group-number id))
 166                    (cdr
 167                     (assq (cdr group-num)
 168                           (nnheader-article-to-file-alist
 169                            (setq gpath
 170                                  (nnmail-group-pathname
 171                                   (car group-num)
 172                                   nnml-directory))))))
 173           (setq path (concat gpath (int-to-string (cdr group-num)))))
 174       (setq path (nnml-article-to-file id)))
 175     (cond
 176      ((not path)
 177       (nnheader-report 'nnml "No such article: %s" id))
 178      ((not (file-exists-p path))
 179       (nnheader-report 'nnml "No such file: %s" path))
 180      ((file-directory-p path)
 181       (nnheader-report 'nnml "File is a directory: %s" path))
 182      ((not (save-excursion (nnmail-find-file path)))
 183       (nnheader-report 'nnml "Couldn't read file: %s" path))
 184      (t
 185       (nnheader-report 'nnml "Article %s retrieved" id)
 186       ;; We return the article number.
 187       (cons (if group-num (car group-num) group)
 188             (string-to-int (file-name-nondirectory path)))))))
 189
 190 (deffoo nnml-request-group (group &optional server dont-check)
 191   (cond
 192    ((not (nnml-possibly-change-directory group server))
 193     (nnheader-report 'nnml "Invalid group (no such directory)"))
 194    ((not (file-exists-p nnml-current-directory))
 195     (nnheader-report 'nnml "Directory %s does not exist"
 196                      nnml-current-directory))
 197    ((not (file-directory-p nnml-current-directory))
 198     (nnheader-report 'nnml "%s is not a directory" nnml-current-directory))
 199    (dont-check
 200     (nnheader-report 'nnml "Group %s selected" group)
 201     t)
 202    (t
 203     (nnheader-re-read-dir nnml-current-directory)
 204     (nnmail-activate 'nnml)
 205     (let ((active (nth 1 (assoc group nnml-group-alist))))
 206       (if (not active)
 207           (nnheader-report 'nnml "No such group: %s" group)
 208         (nnheader-report 'nnml "Selected group %s" group)
 209         (nnheader-insert "211 %d %d %d %s\n"
 210                          (max (1+ (- (cdr active) (car active))) 0)
 211                          (car active) (cdr active) group))))))
 212
 213 (deffoo nnml-request-scan (&optional group server)
 214   (setq nnml-article-file-alist nil)
 215   (nnml-possibly-change-directory group server)
 216   (nnmail-get-new-mail 'nnml 'nnml-save-nov nnml-directory group))
 217
 218 (deffoo nnml-close-group (group &optional server)
 219   (setq nnml-article-file-alist nil)
 220   t)
 221
 222 (deffoo nnml-request-create-group (group &optional server args)
 223   (nnmail-activate 'nnml)
 224   (unless (assoc group nnml-group-alist)
 225     (let (active)
 226       (push (list group (setq active (cons 1 0)))
 227             nnml-group-alist)
 228       (nnml-possibly-create-directory group)
 229       (nnml-possibly-change-directory group server)
 230       (let ((articles (nnheader-directory-articles nnml-current-directory)))
 231         (when articles
 232           (setcar active (apply 'min articles))
 233           (setcdr active (apply 'max articles))))
 234       (nnmail-save-active nnml-group-alist nnml-active-file)))
 235   t)
 236
 237 (deffoo nnml-request-list (&optional server)
 238   (save-excursion
 239     (nnmail-find-file nnml-active-file)
 240     (setq nnml-group-alist (nnmail-get-active))
 241     t))
 242
 243 (deffoo nnml-request-newgroups (date &optional server)
 244   (nnml-request-list server))
 245
 246 (deffoo nnml-request-list-newsgroups (&optional server)
 247   (save-excursion
 248     (nnmail-find-file nnml-newsgroups-file)))
 249
 250 (deffoo nnml-request-expire-articles (articles group
 251                                                &optional server force)
 252   (nnml-possibly-change-directory group server)
 253   (let* ((active-articles
 254           (nnheader-directory-articles nnml-current-directory))
 255          (is-old t)
 256          article rest mod-time number)
 257     (nnmail-activate 'nnml)
 258
 259     (while (and articles is-old)
 260       (when (setq article (nnml-article-to-file (setq number (pop articles))))
 261         (when (setq mod-time (nth 5 (file-attributes article)))
 262           (if (and (nnml-deletable-article-p group number)
 263                    (setq is-old
 264                          (nnmail-expired-article-p group mod-time force
 265                                                    nnml-inhibit-expiry)))
 266               (progn
 267                 (nnheader-message 5 "Deleting article %s in %s"
 268                                   article group)
 269                 (condition-case ()
 270                     (funcall nnmail-delete-file-function article)
 271                   (file-error
 272                    (push number rest)))
 273                 (setq active-articles (delq number active-articles))
 274                 (nnml-nov-delete-article group number))
 275             (push number rest)))))
 276     (let ((active (nth 1 (assoc group nnml-group-alist))))
 277       (when active
 278         (setcar active (or (and active-articles
 279                                 (apply 'min active-articles))
 280                            (1+ (cdr active)))))
 281       (nnmail-save-active nnml-group-alist nnml-active-file))
 282     (nnml-save-nov)
 283     (nconc rest articles)))
 284
 285 (deffoo nnml-request-move-article
 286   (article group server accept-form &optional last)
 287   (let ((buf (get-buffer-create " *nnml move*"))
 288         result)
 289     (nnml-possibly-change-directory group server)
 290     (nnml-update-file-alist)
 291     (and
 292      (nnml-deletable-article-p group article)
 293      (nnml-request-article article group server)
 294      (save-excursion
 295        (set-buffer buf)
 296        (insert-buffer-substring nntp-server-buffer)
 297        (setq result (eval accept-form))
 298        (kill-buffer (current-buffer))
 299        result)
 300      (progn
 301        (nnml-possibly-change-directory group server)
 302        (condition-case ()
 303            (funcall nnmail-delete-file-function
 304                     (nnml-article-to-file  article))
 305          (file-error nil))
 306        (nnml-nov-delete-article group article)
 307        (when last
 308          (nnml-save-nov)
 309          (nnmail-save-active nnml-group-alist nnml-active-file))))
 310     result))
 311
 312 (deffoo nnml-request-accept-article (group &optional server last)
 313   (nnml-possibly-change-directory group server)
 314   (nnmail-check-syntax)
 315   (let (result)
 316     (when nnmail-cache-accepted-message-ids
 317       (nnmail-cache-insert (nnmail-fetch-field "message-id")))
 318     (if (stringp group)
 319         (and
 320          (nnmail-activate 'nnml)
 321          (setq result (car (nnml-save-mail
 322                             (list (cons group (nnml-active-number group))))))
 323          (progn
 324            (nnmail-save-active nnml-group-alist nnml-active-file)
 325            (and last (nnml-save-nov))))
 326       (and
 327        (nnmail-activate 'nnml)
 328        (if (and (not (setq result (nnmail-article-group 'nnml-active-number)))
 329                 (yes-or-no-p "Moved to `junk' group; delete article? "))
 330            (setq result 'junk)
 331          (setq result (car (nnml-save-mail result))))
 332        (when last
 333          (nnmail-save-active nnml-group-alist nnml-active-file)
 334          (when nnmail-cache-accepted-message-ids
 335            (nnmail-cache-close))
 336          (nnml-save-nov))))
 337     result))
 338
 339 (deffoo nnml-request-replace-article (article group buffer)
 340   (nnml-possibly-change-directory group)
 341   (save-excursion
 342     (set-buffer buffer)
 343     (nnml-possibly-create-directory group)
 344     (let ((chars (nnmail-insert-lines))
 345           (art (concat (int-to-string article) "\t"))
 346           headers)
 347       (when (condition-case ()
 348                 (progn
 349                   (nnmail-write-region
 350                    (point-min) (point-max)
 351                    (or (nnml-article-to-file article)
 352                        (concat nnml-current-directory
 353                                (int-to-string article)))
 354                    nil (if (nnheader-be-verbose 5) nil 'nomesg))
 355                   t)
 356               (error nil))
 357         (setq headers (nnml-parse-head chars article))
 358         ;; Replace the NOV line in the NOV file.
 359         (save-excursion
 360           (set-buffer (nnml-open-nov group))
 361           (goto-char (point-min))
 362           (if (or (looking-at art)
 363                   (search-forward (concat "\n" art) nil t))
 364               ;; Delete the old NOV line.
 365               (delete-region (progn (beginning-of-line) (point))
 366                              (progn (forward-line 1) (point)))
 367             ;; The line isn't here, so we have to find out where
 368             ;; we should insert it.  (This situation should never
 369             ;; occur, but one likes to make sure...)
 370             (while (and (looking-at "[0-9]+\t")
 371                         (< (string-to-int
 372                             (buffer-substring
 373                              (match-beginning 0) (match-end 0)))
 374                            article)
 375                         (zerop (forward-line 1)))))
 376           (beginning-of-line)
 377           (nnheader-insert-nov headers)
 378           (nnml-save-nov)
 379           t)))))
 380
 381 (deffoo nnml-request-delete-group (group &optional force server)
 382   (nnml-possibly-change-directory group server)
 383   (when force
 384     ;; Delete all articles in GROUP.
 385     (let ((articles
 386            (directory-files
 387             nnml-current-directory t
 388             (concat nnheader-numerical-short-files
 389                     "\\|" (regexp-quote nnml-nov-file-name) "$")))
 390           article)
 391       (while articles
 392         (setq article (pop articles))
 393         (when (file-writable-p article)
 394           (nnheader-message 5 "Deleting article %s in %s..." article group)
 395           (funcall nnmail-delete-file-function article))))
 396     ;; Try to delete the directory itself.
 397     (condition-case ()
 398         (delete-directory nnml-current-directory)
 399       (error nil)))
 400   ;; Remove the group from all structures.
 401   (setq nnml-group-alist
 402         (delq (assoc group nnml-group-alist) nnml-group-alist)
 403         nnml-current-group nil
 404         nnml-current-directory nil)
 405   ;; Save the active file.
 406   (nnmail-save-active nnml-group-alist nnml-active-file)
 407   t)
 408
 409 (deffoo nnml-request-rename-group (group new-name &optional server)
 410   (nnml-possibly-change-directory group server)
 411   (let ((new-dir (nnmail-group-pathname new-name nnml-directory))
 412         (old-dir (nnmail-group-pathname group nnml-directory)))
 413     (when (condition-case ()
 414               (progn
 415                 (make-directory new-dir t)
 416                 t)
 417             (error nil))
 418       ;; We move the articles file by file instead of renaming
 419       ;; the directory -- there may be subgroups in this group.
 420       ;; One might be more clever, I guess.
 421       (let ((files (nnheader-article-to-file-alist old-dir)))
 422         (while files
 423           (rename-file
 424            (concat old-dir (cdar files))
 425            (concat new-dir (cdar files)))
 426           (pop files)))
 427       ;; Move .overview file.
 428       (let ((overview (concat old-dir nnml-nov-file-name)))
 429         (when (file-exists-p overview)
 430           (rename-file overview (concat new-dir nnml-nov-file-name))))
 431       (when (<= (length (directory-files old-dir)) 2)
 432         (condition-case ()
 433             (delete-directory old-dir)
 434           (error nil)))
 435       ;; That went ok, so we change the internal structures.
 436       (let ((entry (assoc group nnml-group-alist)))
 437         (when entry
 438           (setcar entry new-name))
 439         (setq nnml-current-directory nil
 440               nnml-current-group nil)
 441         ;; Save the new group alist.
 442         (nnmail-save-active nnml-group-alist nnml-active-file)
 443         t))))
 444
 445 (deffoo nnml-set-status (article name value &optional group server)
 446   (nnml-possibly-change-directory group server)
 447   (let ((file (nnml-article-to-file article)))
 448     (cond
 449      ((not (file-exists-p file))
 450       (nnheader-report 'nnml "File %s does not exist" file))
 451      (t
 452       (nnheader-temp-write file
 453         (nnheader-insert-file-contents file)
 454         (nnmail-replace-status name value))
 455       t))))
 456
 457 \f
 458 ;;; Internal functions.
 459
 460 (defun nnml-article-to-file (article)
 461   (nnml-update-file-alist)
 462   (let (file)
 463     (if (setq file (cdr (assq article nnml-article-file-alist)))
 464         (concat nnml-current-directory file)
 465       ;; Just to make sure nothing went wrong when reading over NFS --
 466       ;; check once more.
 467       (when (file-exists-p
 468              (setq file (concat nnml-current-directory "/"
 469                                 (number-to-string article))))
 470         (nnml-update-file-alist t)
 471         file))))
 472
 473 (defun nnml-deletable-article-p (group article)
 474   "Say whether ARTICLE in GROUP can be deleted."
 475   (let (path)
 476     (when (setq path (nnml-article-to-file article))
 477       (when (file-writable-p path)
 478         (or (not nnmail-keep-last-article)
 479             (not (eq (cdr (nth 1 (assoc group nnml-group-alist)))
 480                      article)))))))
 481
 482 ;; Find an article number in the current group given the Message-ID.
 483 (defun nnml-find-group-number (id)
 484   (save-excursion
 485     (set-buffer (get-buffer-create " *nnml id*"))
 486     (buffer-disable-undo (current-buffer))
 487     (let ((alist nnml-group-alist)
 488           number)
 489       ;; We want to look through all .overview files, but we want to
 490       ;; start with the one in the current directory.  It seems most
 491       ;; likely that the article we are looking for is in that group.
 492       (if (setq number (nnml-find-id nnml-current-group id))
 493           (cons nnml-current-group number)
 494         ;; It wasn't there, so we look through the other groups as well.
 495         (while (and (not number)
 496                     alist)
 497           (or (string= (caar alist) nnml-current-group)
 498               (setq number (nnml-find-id (caar alist) id)))
 499           (or number
 500               (setq alist (cdr alist))))
 501         (and number
 502              (cons (caar alist) number))))))
 503
 504 (defun nnml-find-id (group id)
 505   (erase-buffer)
 506   (let ((nov (concat (nnmail-group-pathname group nnml-directory)
 507                      nnml-nov-file-name))
 508         number found)
 509     (when (file-exists-p nov)
 510       (nnheader-insert-file-contents nov)
 511       (while (and (not found)
 512                   (search-forward id nil t)) ; We find the ID.
 513         ;; And the id is in the fourth field.
 514         (if (not (and (search-backward "\t" nil t 4)
 515                       (not (search-backward"\t" (gnus-point-at-bol) t))))
 516             (forward-line 1)
 517           (beginning-of-line)
 518           (setq found t)
 519           ;; We return the article number.
 520           (setq number
 521                 (condition-case ()
 522                     (read (current-buffer))
 523                   (error nil)))))
 524       number)))
 525
 526 (defun nnml-retrieve-headers-with-nov (articles &optional fetch-old)
 527   (if (or gnus-nov-is-evil nnml-nov-is-evil)
 528       nil
 529     (let ((nov (concat nnml-current-directory nnml-nov-file-name)))
 530       (when (file-exists-p nov)
 531         (save-excursion
 532           (set-buffer nntp-server-buffer)
 533           (erase-buffer)
 534           (nnheader-insert-file-contents nov)
 535           (if (and fetch-old
 536                    (not (numberp fetch-old)))
 537               t                         ; Don't remove anything.
 538             (nnheader-nov-delete-outside-range
 539              (if fetch-old (max 1 (- (car articles) fetch-old))
 540                (car articles))
 541              (car (last articles)))
 542             t))))))
 543
 544 (defun nnml-possibly-change-directory (group &optional server)
 545   (when (and server
 546              (not (nnml-server-opened server)))
 547     (nnml-open-server server))
 548   (if (not group)
 549       t
 550     (let ((pathname (nnmail-group-pathname group nnml-directory)))
 551       (when (not (equal pathname nnml-current-directory))
 552         (setq nnml-current-directory pathname
 553               nnml-current-group group
 554               nnml-article-file-alist nil))
 555       (file-exists-p nnml-current-directory))))
 556
 557 (defun nnml-possibly-create-directory (group)
 558   (let (dir dirs)
 559     (setq dir (nnmail-group-pathname group nnml-directory))
 560     (while (not (file-directory-p dir))
 561       (push dir dirs)
 562       (setq dir (file-name-directory (directory-file-name dir))))
 563     (while dirs
 564       (make-directory (directory-file-name (car dirs)))
 565       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 566       (setq dirs (cdr dirs)))))
 567
 568 (defun nnml-save-mail (group-art)
 569   "Called narrowed to an article."
 570   (let (chars headers)
 571     (setq chars (nnmail-insert-lines))
 572     (nnmail-insert-xref group-art)
 573     (run-hooks 'nnmail-prepare-save-mail-hook)
 574     (run-hooks 'nnml-prepare-save-mail-hook)
 575     (goto-char (point-min))
 576     (while (looking-at "From ")
 577       (replace-match "X-From-Line: ")
 578       (forward-line 1))
 579     ;; We save the article in all the groups it belongs in.
 580     (let ((ga group-art)
 581           first)
 582       (while ga
 583         (nnml-possibly-create-directory (caar ga))
 584         (let ((file (concat (nnmail-group-pathname
 585                              (caar ga) nnml-directory)
 586                             (int-to-string (cdar ga)))))
 587           (if first
 588               ;; It was already saved, so we just make a hard link.
 589               (funcall nnmail-crosspost-link-function first file t)
 590             ;; Save the article.
 591             (nnmail-write-region (point-min) (point-max) file nil
 592                                  (if (nnheader-be-verbose 5) nil 'nomesg))
 593             (setq first file)))
 594         (setq ga (cdr ga))))
 595     ;; Generate a nov line for this article.  We generate the nov
 596     ;; line after saving, because nov generation destroys the
 597     ;; header.
 598     (setq headers (nnml-parse-head chars))
 599     ;; Output the nov line to all nov databases that should have it.
 600     (let ((ga group-art))
 601       (while ga
 602         (nnml-add-nov (caar ga) (cdar ga) headers)
 603         (setq ga (cdr ga))))
 604     group-art))
 605
 606 (defun nnml-active-number (group)
 607   "Compute the next article number in GROUP."
 608   (let ((active (cadr (assoc group nnml-group-alist))))
 609     ;; The group wasn't known to nnml, so we just create an active
 610     ;; entry for it.
 611     (unless active
 612       ;; Perhaps the active file was corrupt?  See whether
 613       ;; there are any articles in this group.
 614       (nnml-possibly-create-directory group)
 615       (nnml-possibly-change-directory group)
 616       (unless nnml-article-file-alist
 617         (setq nnml-article-file-alist
 618               (sort
 619                (nnheader-article-to-file-alist nnml-current-directory)
 620                (lambda (a1 a2) (< (car a1) (car a2))))))
 621       (setq active
 622             (if nnml-article-file-alist
 623                 (cons (caar nnml-article-file-alist)
 624                       (caar (last nnml-article-file-alist)))
 625               (cons 1 0)))
 626       (push (list group active) nnml-group-alist))
 627     (setcdr active (1+ (cdr active)))
 628     (while (file-exists-p
 629             (concat (nnmail-group-pathname group nnml-directory)
 630                     (int-to-string (cdr active))))
 631       (setcdr active (1+ (cdr active))))
 632     (cdr active)))
 633
 634 (defun nnml-add-nov (group article headers)
 635   "Add a nov line for the GROUP base."
 636   (save-excursion
 637     (set-buffer (nnml-open-nov group))
 638     (goto-char (point-max))
 639     (mail-header-set-number headers article)
 640     (nnheader-insert-nov headers)))
 641
 642 (defsubst nnml-header-value ()
 643   (buffer-substring (match-end 0) (progn (end-of-line) (point))))
 644
 645 (defun nnml-parse-head (chars &optional number)
 646   "Parse the head of the current buffer."
 647   (save-excursion
 648     (save-restriction
 649       (goto-char (point-min))
 650       (narrow-to-region
 651        (point)
 652        (1- (or (search-forward "\n\n" nil t) (point-max))))
 653       ;; Fold continuation lines.
 654       (goto-char (point-min))
 655       (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
 656         (replace-match " " t t))
 657       ;; Remove any tabs; they are too confusing.
 658       (subst-char-in-region (point-min) (point-max) ?\t ? )
 659       (let ((headers (nnheader-parse-head t)))
 660         (mail-header-set-chars headers chars)
 661         (mail-header-set-number headers number)
 662         headers))))
 663
 664 (defun nnml-open-nov (group)
 665   (or (cdr (assoc group nnml-nov-buffer-alist))
 666       (let ((buffer (nnheader-find-file-noselect
 667                      (concat (nnmail-group-pathname group nnml-directory)
 668                              nnml-nov-file-name))))
 669         (save-excursion
 670           (set-buffer buffer)
 671           (buffer-disable-undo (current-buffer)))
 672         (push (cons group buffer) nnml-nov-buffer-alist)
 673         buffer)))
 674
 675 (defun nnml-save-nov ()
 676   (save-excursion
 677     (while nnml-nov-buffer-alist
 678       (when (buffer-name (cdar nnml-nov-buffer-alist))
 679         (set-buffer (cdar nnml-nov-buffer-alist))
 680         (when (buffer-modified-p)
 681           (nnmail-write-region 1 (point-max) (buffer-file-name) nil 'nomesg))
 682         (set-buffer-modified-p nil)
 683         (kill-buffer (current-buffer)))
 684       (setq nnml-nov-buffer-alist (cdr nnml-nov-buffer-alist)))))
 685
 686 ;;;###autoload
 687 (defun nnml-generate-nov-databases ()
 688   "Generate NOV databases in all nnml directories."
 689   (interactive)
 690   ;; Read the active file to make sure we don't re-use articles
 691   ;; numbers in empty groups.
 692   (nnmail-activate 'nnml)
 693   (nnml-open-server (or (nnoo-current-server 'nnml) ""))
 694   (setq nnml-directory (expand-file-name nnml-directory))
 695   ;; Recurse down the directories.
 696   (nnml-generate-nov-databases-1 nnml-directory nil t)
 697   ;; Save the active file.
 698   (nnmail-save-active nnml-group-alist nnml-active-file))
 699
 700 (defun nnml-generate-nov-databases-1 (dir &optional seen no-active)
 701   "Regenerate the NOV database in DIR."
 702   (interactive "DRegenerate NOV in: ")
 703   (setq dir (file-name-as-directory dir))
 704   ;; Only scan this sub-tree if we haven't been here yet.
 705   (unless (member (file-truename dir) seen)
 706     (push (file-truename dir) seen)
 707     ;; We descend recursively
 708     (let ((dirs (directory-files dir t nil t))
 709           dir)
 710       (while (setq dir (pop dirs))
 711         (when (and (not (member (file-name-nondirectory dir) '("." "..")))
 712                    (file-directory-p dir))
 713           (nnml-generate-nov-databases-1 dir seen))))
 714     ;; Do this directory.
 715     (let ((files (sort (nnheader-article-to-file-alist dir)
 716                        (lambda (a b) (< (car a) (car b))))))
 717       (when files
 718         (funcall nnml-generate-active-function dir)
 719         ;; Generate the nov file.
 720         (nnml-generate-nov-file dir files)
 721         (unless no-active
 722           (nnmail-save-active nnml-group-alist nnml-active-file))))))
 723
 724 (defvar files)
 725 (defun nnml-generate-active-info (dir)
 726   ;; Update the active info for this group.
 727   (let ((group (nnheader-file-to-group
 728                 (directory-file-name dir) nnml-directory)))
 729     (setq nnml-group-alist
 730           (delq (assoc group nnml-group-alist) nnml-group-alist))
 731     (push (list group
 732                 (cons (caar files)
 733                       (let ((f files))
 734                         (while (cdr f) (setq f (cdr f)))
 735                         (caar f))))
 736           nnml-group-alist)))
 737
 738 (defun nnml-generate-nov-file (dir files)
 739   (let* ((dir (file-name-as-directory dir))
 740          (nov (concat dir nnml-nov-file-name))
 741          (nov-buffer (get-buffer-create " *nov*"))
 742          chars file headers)
 743     (save-excursion
 744       ;; Init the nov buffer.
 745       (set-buffer nov-buffer)
 746       (buffer-disable-undo (current-buffer))
 747       (erase-buffer)
 748       (set-buffer nntp-server-buffer)
 749       ;; Delete the old NOV file.
 750       (when (file-exists-p nov)
 751         (funcall nnmail-delete-file-function nov))
 752       (while files
 753         (unless (file-directory-p (setq file (concat dir (cdar files))))
 754           (erase-buffer)
 755           (nnheader-insert-file-contents file)
 756           (narrow-to-region
 757            (goto-char (point-min))
 758            (progn
 759              (search-forward "\n\n" nil t)
 760              (setq chars (- (point-max) (point)))
 761              (max 1 (1- (point)))))
 762           (when (and (not (= 0 chars))  ; none of them empty files...
 763                      (not (= (point-min) (point-max))))
 764             (goto-char (point-min))
 765             (setq headers (nnml-parse-head chars (caar files)))
 766             (save-excursion
 767               (set-buffer nov-buffer)
 768               (goto-char (point-max))
 769               (nnheader-insert-nov headers)))
 770           (widen))
 771         (setq files (cdr files)))
 772       (save-excursion
 773         (set-buffer nov-buffer)
 774         (nnmail-write-region 1 (point-max) nov nil 'nomesg)
 775         (kill-buffer (current-buffer))))))
 776
 777 (defun nnml-nov-delete-article (group article)
 778   (save-excursion
 779     (set-buffer (nnml-open-nov group))
 780     (when (nnheader-find-nov-line article)
 781       (delete-region (point) (progn (forward-line 1) (point)))
 782       (when (bobp)
 783         (let ((active (cadr (assoc group nnml-group-alist)))
 784               num)
 785           (when active
 786             (if (eobp)
 787                 (setf (car active) (1+ (cdr active)))
 788               (when (and (setq num (ignore-errors (read (current-buffer))))
 789                          (numberp num))
 790                 (setf (car active) num)))))))
 791     t))
 792
 793 (defun nnml-update-file-alist (&optional force)
 794   (when (or (not nnml-article-file-alist)
 795             force)
 796     (setq nnml-article-file-alist
 797           (nnheader-article-to-file-alist nnml-current-directory))))
 798
 799 (provide 'nnml)
 800
 801 ;;; nnml.el ends here