cgit.sxemacs.org Git - gnus/blob - lisp/nnml.el

   1 ;;; nnml.el --- mail spool access for Gnus
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;;; Code:
  32
  33 (require 'nnheader)
  34 (require 'nnmail)
  35 (require 'nnoo)
  36 (require 'cl)
  37
  38 (nnoo-declare nnml)
  39
  40 (defvoo nnml-directory message-directory
  41   "Mail spool directory.")
  42
  43 (defvoo nnml-active-file
  44   (concat (file-name-as-directory nnml-directory) "active")
  45   "Mail active file.")
  46
  47 (defvoo nnml-newsgroups-file
  48   (concat (file-name-as-directory nnml-directory) "newsgroups")
  49   "Mail newsgroups description file.")
  50
  51 (defvoo nnml-get-new-mail t
  52   "If non-nil, nnml will check the incoming mail file and split the mail.")
  53
  54 (defvoo nnml-nov-is-evil nil
  55   "If non-nil, Gnus will never generate and use nov databases for mail groups.
  56 Using nov databases will speed up header fetching considerably.
  57 This variable shouldn't be flipped much.  If you have, for some reason,
  58 set this to t, and want to set it to nil again, you should always run
  59 the `nnml-generate-nov-databases' command.  The function will go
  60 through all nnml directories and generate nov databases for them
  61 all.  This may very well take some time.")
  62
  63 (defvoo nnml-prepare-save-mail-hook nil
  64   "Hook run narrowed to an article before saving.")
  65
  66 (defvoo nnml-inhibit-expiry nil
  67   "If non-nil, inhibit expiry.")
  68
  69
  70 \f
  71
  72 (defconst nnml-version "nnml 1.0"
  73   "nnml version.")
  74
  75 (defvoo nnml-nov-file-name ".overview")
  76
  77 (defvoo nnml-current-directory nil)
  78 (defvoo nnml-current-group nil)
  79 (defvoo nnml-status-string "")
  80 (defvoo nnml-nov-buffer-alist nil)
  81 (defvoo nnml-group-alist nil)
  82 (defvoo nnml-active-timestamp nil)
  83 (defvoo nnml-article-file-alist nil)
  84
  85 (defvoo nnml-generate-active-function 'nnml-generate-active-info)
  86
  87 \f
  88
  89 ;;; Interface functions.
  90
  91 (nnoo-define-basics nnml)
  92
  93 (deffoo nnml-retrieve-headers (sequence &optional group server fetch-old)
  94   (when (nnml-possibly-change-directory group server)
  95     (save-excursion
  96       (set-buffer nntp-server-buffer)
  97       (erase-buffer)
  98       (let ((file nil)
  99             (number (length sequence))
 100             (count 0)
 101             beg article)
 102         (if (stringp (car sequence))
 103             'headers
 104           (unless nnml-article-file-alist
 105             (setq nnml-article-file-alist
 106                   (nnheader-article-to-file-alist nnml-current-directory)))
 107           (if (nnml-retrieve-headers-with-nov sequence fetch-old)
 108               'nov
 109             (while sequence
 110               (setq article (car sequence))
 111               (setq file
 112                     (concat nnml-current-directory
 113                             (or (cdr (assq article nnml-article-file-alist))
 114                                 "")))
 115               (when (and (file-exists-p file)
 116                          (not (file-directory-p file)))
 117                 (insert (format "221 %d Article retrieved.\n" article))
 118                 (setq beg (point))
 119                 (nnheader-insert-head file)
 120                 (goto-char beg)
 121                 (if (search-forward "\n\n" nil t)
 122                     (forward-char -1)
 123                   (goto-char (point-max))
 124                   (insert "\n\n"))
 125                 (insert ".\n")
 126                 (delete-region (point) (point-max)))
 127               (setq sequence (cdr sequence))
 128               (setq count (1+ count))
 129               (and (numberp nnmail-large-newsgroup)
 130                    (> number nnmail-large-newsgroup)
 131                    (zerop (% count 20))
 132                    (nnheader-message 6 "nnml: Receiving headers... %d%%"
 133                                      (/ (* count 100) number))))
 134
 135             (and (numberp nnmail-large-newsgroup)
 136                  (> number nnmail-large-newsgroup)
 137                  (nnheader-message 6 "nnml: Receiving headers...done"))
 138
 139             (nnheader-fold-continuation-lines)
 140             'headers))))))
 141
 142 (deffoo nnml-open-server (server &optional defs)
 143   (nnoo-change-server 'nnml server defs)
 144   (when (not (file-exists-p nnml-directory))
 145     (condition-case ()
 146         (make-directory nnml-directory t)
 147       (error)))
 148   (cond
 149    ((not (file-exists-p nnml-directory))
 150     (nnml-close-server)
 151     (nnheader-report 'nnml "Couldn't create directory: %s" nnml-directory))
 152    ((not (file-directory-p (file-truename nnml-directory)))
 153     (nnml-close-server)
 154     (nnheader-report 'nnml "Not a directory: %s" nnml-directory))
 155    (t
 156     (nnheader-report 'nnml "Opened server %s using directory %s"
 157                      server nnml-directory)
 158     t)))
 159
 160 (defun nnml-request-regenerate (server)
 161   (nnml-possibly-change-directory nil server)
 162   (nnml-generate-nov-databases))
 163
 164 (deffoo nnml-request-article (id &optional group server buffer)
 165   (nnml-possibly-change-directory group server)
 166   (let* ((nntp-server-buffer (or buffer nntp-server-buffer))
 167          path gpath group-num)
 168     (if (stringp id)
 169         (when (and (setq group-num (nnml-find-group-number id))
 170                    (cdr
 171                     (assq (cdr group-num)
 172                           (nnheader-article-to-file-alist
 173                            (setq gpath
 174                                  (nnmail-group-pathname
 175                                   (car group-num)
 176                                   nnml-directory))))))
 177           (setq path (concat gpath (int-to-string (cdr group-num)))))
 178       (setq path (nnml-article-to-file id)))
 179     (cond
 180      ((not path)
 181       (nnheader-report 'nnml "No such article: %s" id))
 182      ((not (file-exists-p path))
 183       (nnheader-report 'nnml "No such file: %s" path))
 184      ((file-directory-p path)
 185       (nnheader-report 'nnml "File is a directory: %s" path))
 186      ((not (save-excursion (nnmail-find-file path)))
 187       (nnheader-report 'nnml "Couldn't read file: %s" path))
 188      (t
 189       (nnheader-report 'nnml "Article %s retrieved" id)
 190       ;; We return the article number.
 191       (cons group (string-to-int (file-name-nondirectory path)))))))
 192
 193 (deffoo nnml-request-group (group &optional server dont-check)
 194   (cond
 195    ((not (nnml-possibly-change-directory group server))
 196     (nnheader-report 'nnml "Invalid group (no such directory)"))
 197    ((not (file-exists-p nnml-current-directory))
 198     (nnheader-report 'nnml "Directory %s does not exist"
 199                      nnml-current-directory))
 200    ((not (file-directory-p nnml-current-directory))
 201     (nnheader-report 'nnml "%s is not a directory" nnml-current-directory))
 202    (dont-check
 203     (nnheader-report 'nnml "Group %s selected" group)
 204     t)
 205    (t
 206     (nnheader-re-read-dir nnml-current-directory)
 207     (nnmail-activate 'nnml)
 208     (let ((active (nth 1 (assoc group nnml-group-alist))))
 209       (if (not active)
 210           (nnheader-report 'nnml "No such group: %s" group)
 211         (nnheader-report 'nnml "Selected group %s" group)
 212         (nnheader-insert "211 %d %d %d %s\n"
 213                          (max (1+ (- (cdr active) (car active))) 0)
 214                          (car active) (cdr active) group))))))
 215
 216 (deffoo nnml-request-scan (&optional group server)
 217   (setq nnml-article-file-alist nil)
 218   (nnml-possibly-change-directory group server)
 219   (nnmail-get-new-mail 'nnml 'nnml-save-nov nnml-directory group))
 220
 221 (deffoo nnml-close-group (group &optional server)
 222   (setq nnml-article-file-alist nil)
 223   t)
 224
 225 (deffoo nnml-request-create-group (group &optional server args)
 226   (nnmail-activate 'nnml)
 227   (unless (assoc group nnml-group-alist)
 228     (let (active)
 229       (push (list group (setq active (cons 1 0)))
 230             nnml-group-alist)
 231       (nnml-possibly-create-directory group)
 232       (nnml-possibly-change-directory group server)
 233       (let ((articles (nnheader-directory-articles nnml-current-directory)))
 234         (when articles
 235           (setcar active (apply 'min articles))
 236           (setcdr active (apply 'max articles))))
 237       (nnmail-save-active nnml-group-alist nnml-active-file)))
 238   t)
 239
 240 (deffoo nnml-request-list (&optional server)
 241   (save-excursion
 242     (nnmail-find-file nnml-active-file)
 243     (setq nnml-group-alist (nnmail-get-active))
 244     t))
 245
 246 (deffoo nnml-request-newgroups (date &optional server)
 247   (nnml-request-list server))
 248
 249 (deffoo nnml-request-list-newsgroups (&optional server)
 250   (save-excursion
 251     (nnmail-find-file nnml-newsgroups-file)))
 252
 253 (deffoo nnml-request-expire-articles (articles group
 254                                                &optional server force)
 255   (nnml-possibly-change-directory group server)
 256   (let* ((active-articles
 257           (nnheader-directory-articles nnml-current-directory))
 258          (is-old t)
 259          article rest mod-time number)
 260     (nnmail-activate 'nnml)
 261
 262     (unless nnml-article-file-alist
 263       (setq nnml-article-file-alist
 264             (nnheader-article-to-file-alist nnml-current-directory)))
 265
 266     (while (and articles is-old)
 267       (when (setq article
 268                   (assq (setq number (pop articles))
 269                         nnml-article-file-alist))
 270         (setq article (concat nnml-current-directory (cdr article)))
 271         (when (setq mod-time (nth 5 (file-attributes article)))
 272           (if (and (nnml-deletable-article-p group number)
 273                    (setq is-old
 274                          (nnmail-expired-article-p group mod-time force
 275                                                    nnml-inhibit-expiry)))
 276               (progn
 277                 (nnheader-message 5 "Deleting article %s in %s"
 278                                   article group)
 279                 (condition-case ()
 280                     (funcall nnmail-delete-file-function article)
 281                   (file-error
 282                    (push number rest)))
 283                 (setq active-articles (delq number active-articles))
 284                 (nnml-nov-delete-article group number))
 285             (push number rest)))))
 286     (let ((active (nth 1 (assoc group nnml-group-alist))))
 287       (when active
 288         (setcar active (or (and active-articles
 289                                 (apply 'min active-articles))
 290                            (1+ (cdr active)))))
 291       (nnmail-save-active nnml-group-alist nnml-active-file))
 292     (nnml-save-nov)
 293     (nconc rest articles)))
 294
 295 (deffoo nnml-request-move-article
 296   (article group server accept-form &optional last)
 297   (let ((buf (get-buffer-create " *nnml move*"))
 298         result)
 299     (nnml-possibly-change-directory group server)
 300     (unless nnml-article-file-alist
 301       (setq nnml-article-file-alist
 302             (nnheader-article-to-file-alist nnml-current-directory)))
 303     (and
 304      (nnml-deletable-article-p group article)
 305      (nnml-request-article article group server)
 306      (save-excursion
 307        (set-buffer buf)
 308        (insert-buffer-substring nntp-server-buffer)
 309        (setq result (eval accept-form))
 310        (kill-buffer (current-buffer))
 311        result)
 312      (progn
 313        (nnml-possibly-change-directory group server)
 314        (condition-case ()
 315            (funcall nnmail-delete-file-function
 316                     (concat nnml-current-directory
 317                             (int-to-string article)))
 318          (file-error nil))
 319        (nnml-nov-delete-article group article)
 320        (and last (nnml-save-nov))))
 321     result))
 322
 323 (deffoo nnml-request-accept-article (group &optional server last)
 324   (nnml-possibly-change-directory group server)
 325   (nnmail-check-syntax)
 326   (let (result)
 327     (if (stringp group)
 328         (and
 329          (nnmail-activate 'nnml)
 330          (setq result (car (nnml-save-mail
 331                             (list (cons group (nnml-active-number group))))))
 332          (progn
 333            (nnmail-save-active nnml-group-alist nnml-active-file)
 334            (and last (nnml-save-nov))))
 335       (and
 336        (nnmail-activate 'nnml)
 337        (setq result (car (nnml-save-mail
 338                           (nnmail-article-group 'nnml-active-number))))
 339        (progn
 340          (nnmail-save-active nnml-group-alist nnml-active-file)
 341          (and last (nnml-save-nov)))))
 342     result))
 343
 344 (deffoo nnml-request-replace-article (article group buffer)
 345   (nnml-possibly-change-directory group)
 346   (save-excursion
 347     (set-buffer buffer)
 348     (nnml-possibly-create-directory group)
 349     (let ((chars (nnmail-insert-lines))
 350           (art (concat (int-to-string article) "\t"))
 351           headers)
 352       (when (condition-case ()
 353                 (progn
 354                   (nnmail-write-region
 355                    (point-min) (point-max)
 356                    (concat nnml-current-directory
 357                            (int-to-string article))
 358                    nil (if (nnheader-be-verbose 5) nil 'nomesg))
 359                   t)
 360               (error nil))
 361         (setq headers (nnml-parse-head chars article))
 362         ;; Replace the NOV line in the NOV file.
 363         (save-excursion
 364           (set-buffer (nnml-open-nov group))
 365           (goto-char (point-min))
 366           (if (or (looking-at art)
 367                   (search-forward (concat "\n" art) nil t))
 368               ;; Delete the old NOV line.
 369               (delete-region (progn (beginning-of-line) (point))
 370                              (progn (forward-line 1) (point)))
 371             ;; The line isn't here, so we have to find out where
 372             ;; we should insert it.  (This situation should never
 373             ;; occur, but one likes to make sure...)
 374             (while (and (looking-at "[0-9]+\t")
 375                         (< (string-to-int
 376                             (buffer-substring
 377                              (match-beginning 0) (match-end 0)))
 378                            article)
 379                         (zerop (forward-line 1)))))
 380           (beginning-of-line)
 381           (nnheader-insert-nov headers)
 382           (nnml-save-nov)
 383           t)))))
 384
 385 (deffoo nnml-request-delete-group (group &optional force server)
 386   (nnml-possibly-change-directory group server)
 387   (when force
 388     ;; Delete all articles in GROUP.
 389     (let ((articles
 390            (directory-files
 391             nnml-current-directory t
 392             (concat nnheader-numerical-short-files
 393                     "\\|" (regexp-quote nnml-nov-file-name) "$")))
 394           article)
 395       (while articles
 396         (setq article (pop articles))
 397         (when (file-writable-p article)
 398           (nnheader-message 5 "Deleting article %s in %s..." article group)
 399           (funcall nnmail-delete-file-function article))))
 400     ;; Try to delete the directory itself.
 401     (condition-case ()
 402         (delete-directory nnml-current-directory)
 403       (error nil)))
 404   ;; Remove the group from all structures.
 405   (setq nnml-group-alist
 406         (delq (assoc group nnml-group-alist) nnml-group-alist)
 407         nnml-current-group nil
 408         nnml-current-directory nil)
 409   ;; Save the active file.
 410   (nnmail-save-active nnml-group-alist nnml-active-file)
 411   t)
 412
 413 (deffoo nnml-request-rename-group (group new-name &optional server)
 414   (nnml-possibly-change-directory group server)
 415   (let ((new-dir (nnmail-group-pathname new-name nnml-directory))
 416         (old-dir (nnmail-group-pathname group nnml-directory)))
 417     (when (condition-case ()
 418               (progn
 419                 (make-directory new-dir t)
 420                 t)
 421             (error nil))
 422       ;; We move the articles file by file instead of renaming
 423       ;; the directory -- there may be subgroups in this group.
 424       ;; One might be more clever, I guess.
 425       (let ((files (nnheader-article-to-file-alist old-dir)))
 426         (while files
 427           (rename-file
 428            (concat old-dir (cdar files))
 429            (concat new-dir (cdar files)))
 430           (pop files)))
 431       ;; Move .overview file.
 432       (let ((overview (concat old-dir nnml-nov-file-name)))
 433         (when (file-exists-p overview)
 434           (rename-file overview (concat new-dir nnml-nov-file-name))))
 435       (when (<= (length (directory-files old-dir)) 2)
 436         (condition-case ()
 437             (delete-directory old-dir)
 438           (error nil)))
 439       ;; That went ok, so we change the internal structures.
 440       (let ((entry (assoc group nnml-group-alist)))
 441         (when entry
 442           (setcar entry new-name))
 443         (setq nnml-current-directory nil
 444               nnml-current-group nil)
 445         ;; Save the new group alist.
 446         (nnmail-save-active nnml-group-alist nnml-active-file)
 447         t))))
 448
 449 (deffoo nnml-set-status (article name value &optional group server)
 450   (nnml-possibly-change-directory group server)
 451   (let ((file (nnml-article-to-file article)))
 452     (cond
 453      ((not (file-exists-p file))
 454       (nnheader-report 'nnml "File %s does not exist" file))
 455      (t
 456       (nnheader-temp-write file
 457         (nnheader-insert-file-contents file)
 458         (nnmail-replace-status name value))
 459       t))))
 460
 461 \f
 462 ;;; Internal functions.
 463
 464 (defun nnml-article-to-file (article)
 465   (unless nnml-article-file-alist
 466     (setq nnml-article-file-alist
 467           (nnheader-article-to-file-alist nnml-current-directory)))
 468   (let (file)
 469     (when (setq file (cdr (assq article nnml-article-file-alist)))
 470       (concat nnml-current-directory file))))
 471
 472 (defun nnml-deletable-article-p (group article)
 473   "Say whether ARTICLE in GROUP can be deleted."
 474   (let (file path)
 475     (when (setq file (cdr (assq article nnml-article-file-alist)))
 476       (setq path (concat nnml-current-directory file))
 477       (when (file-writable-p path)
 478         (or (not nnmail-keep-last-article)
 479             (not (eq (cdr (nth 1 (assoc group nnml-group-alist)))
 480                      article)))))))
 481
 482 ;; Find an article number in the current group given the Message-ID.
 483 (defun nnml-find-group-number (id)
 484   (save-excursion
 485     (set-buffer (get-buffer-create " *nnml id*"))
 486     (buffer-disable-undo (current-buffer))
 487     (let ((alist nnml-group-alist)
 488           number)
 489       ;; We want to look through all .overview files, but we want to
 490       ;; start with the one in the current directory.  It seems most
 491       ;; likely that the article we are looking for is in that group.
 492       (if (setq number (nnml-find-id nnml-current-group id))
 493           (cons nnml-current-group number)
 494         ;; It wasn't there, so we look through the other groups as well.
 495         (while (and (not number)
 496                     alist)
 497           (or (string= (caar alist) nnml-current-group)
 498               (setq number (nnml-find-id (caar alist) id)))
 499           (or number
 500               (setq alist (cdr alist))))
 501         (and number
 502              (cons (caar alist) number))))))
 503
 504 (defun nnml-find-id (group id)
 505   (erase-buffer)
 506   (let ((nov (concat (nnmail-group-pathname group nnml-directory)
 507                      nnml-nov-file-name))
 508         number found)
 509     (when (file-exists-p nov)
 510       (nnheader-insert-file-contents nov)
 511       (while (and (not found)
 512                   (search-forward id nil t)) ; We find the ID.
 513         ;; And the id is in the fourth field.
 514         (if (not (and (search-backward "\t" nil t 4)
 515                       (not (search-backward"\t" (gnus-point-at-bol) t))))
 516             (forward-line 1)
 517           (beginning-of-line)
 518           (setq found t)
 519           ;; We return the article number.
 520           (setq number
 521                 (condition-case ()
 522                     (read (current-buffer))
 523                   (error nil)))))
 524       number)))
 525
 526 (defun nnml-retrieve-headers-with-nov (articles &optional fetch-old)
 527   (if (or gnus-nov-is-evil nnml-nov-is-evil)
 528       nil
 529     (let ((nov (concat nnml-current-directory nnml-nov-file-name)))
 530       (when (file-exists-p nov)
 531         (save-excursion
 532           (set-buffer nntp-server-buffer)
 533           (erase-buffer)
 534           (nnheader-insert-file-contents nov)
 535           (if (and fetch-old
 536                    (not (numberp fetch-old)))
 537               t                         ; Don't remove anything.
 538             (nnheader-nov-delete-outside-range
 539              (if fetch-old (max 1 (- (car articles) fetch-old))
 540                (car articles))
 541              (car (last articles)))
 542             t))))))
 543
 544 (defun nnml-possibly-change-directory (group &optional server)
 545   (when (and server
 546              (not (nnml-server-opened server)))
 547     (nnml-open-server server))
 548   (if (not group)
 549       t
 550     (let ((pathname (nnmail-group-pathname group nnml-directory)))
 551       (when (not (equal pathname nnml-current-directory))
 552         (setq nnml-current-directory pathname
 553               nnml-current-group group
 554               nnml-article-file-alist nil))
 555       (file-exists-p nnml-current-directory))))
 556
 557 (defun nnml-possibly-create-directory (group)
 558   (let (dir dirs)
 559     (setq dir (nnmail-group-pathname group nnml-directory))
 560     (while (not (file-directory-p dir))
 561       (push dir dirs)
 562       (setq dir (file-name-directory (directory-file-name dir))))
 563     (while dirs
 564       (make-directory (directory-file-name (car dirs)))
 565       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 566       (setq dirs (cdr dirs)))))
 567
 568 (defun nnml-save-mail (group-art)
 569   "Called narrowed to an article."
 570   (let (chars headers)
 571     (setq chars (nnmail-insert-lines))
 572     (nnmail-insert-xref group-art)
 573     (run-hooks 'nnmail-prepare-save-mail-hook)
 574     (run-hooks 'nnml-prepare-save-mail-hook)
 575     (goto-char (point-min))
 576     (while (looking-at "From ")
 577       (replace-match "X-From-Line: ")
 578       (forward-line 1))
 579     ;; We save the article in all the groups it belongs in.
 580     (let ((ga group-art)
 581           first)
 582       (while ga
 583         (nnml-possibly-create-directory (caar ga))
 584         (let ((file (concat (nnmail-group-pathname
 585                              (caar ga) nnml-directory)
 586                             (int-to-string (cdar ga)))))
 587           (if first
 588               ;; It was already saved, so we just make a hard link.
 589               (funcall nnmail-crosspost-link-function first file t)
 590             ;; Save the article.
 591             (nnmail-write-region (point-min) (point-max) file nil
 592                                  (if (nnheader-be-verbose 5) nil 'nomesg))
 593             (setq first file)))
 594         (setq ga (cdr ga))))
 595     ;; Generate a nov line for this article.  We generate the nov
 596     ;; line after saving, because nov generation destroys the
 597     ;; header.
 598     (setq headers (nnml-parse-head chars))
 599     ;; Output the nov line to all nov databases that should have it.
 600     (let ((ga group-art))
 601       (while ga
 602         (nnml-add-nov (caar ga) (cdar ga) headers)
 603         (setq ga (cdr ga))))
 604     group-art))
 605
 606 (defun nnml-active-number (group)
 607   "Compute the next article number in GROUP."
 608   (let ((active (cadr (assoc group nnml-group-alist))))
 609     ;; The group wasn't known to nnml, so we just create an active
 610     ;; entry for it.
 611     (unless active
 612       ;; Perhaps the active file was corrupt?  See whether
 613       ;; there are any articles in this group.
 614       (nnml-possibly-create-directory group)
 615       (nnml-possibly-change-directory group)
 616       (unless nnml-article-file-alist
 617         (setq nnml-article-file-alist
 618               (sort
 619                (nnheader-article-to-file-alist nnml-current-directory)
 620                (lambda (a1 a2) (< (car a1) (car a2))))))
 621       (setq active
 622             (if nnml-article-file-alist
 623                 (cons (caar nnml-article-file-alist)
 624                       (caar (last nnml-article-file-alist)))
 625               (cons 1 0)))
 626       (push (list group active) nnml-group-alist))
 627     (setcdr active (1+ (cdr active)))
 628     (while (file-exists-p
 629             (concat (nnmail-group-pathname group nnml-directory)
 630                     (int-to-string (cdr active))))
 631       (setcdr active (1+ (cdr active))))
 632     (cdr active)))
 633
 634 (defun nnml-add-nov (group article headers)
 635   "Add a nov line for the GROUP base."
 636   (save-excursion
 637     (set-buffer (nnml-open-nov group))
 638     (goto-char (point-max))
 639     (mail-header-set-number headers article)
 640     (nnheader-insert-nov headers)))
 641
 642 (defsubst nnml-header-value ()
 643   (buffer-substring (match-end 0) (progn (end-of-line) (point))))
 644
 645 (defun nnml-parse-head (chars &optional number)
 646   "Parse the head of the current buffer."
 647   (save-excursion
 648     (save-restriction
 649       (goto-char (point-min))
 650       (narrow-to-region
 651        (point)
 652        (1- (or (search-forward "\n\n" nil t) (point-max))))
 653       ;; Fold continuation lines.
 654       (goto-char (point-min))
 655       (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
 656         (replace-match " " t t))
 657       ;; Remove any tabs; they are too confusing.
 658       (subst-char-in-region (point-min) (point-max) ?\t ? )
 659       (let ((headers (nnheader-parse-head t)))
 660         (mail-header-set-chars headers chars)
 661         (mail-header-set-number headers number)
 662         headers))))
 663
 664 (defun nnml-open-nov (group)
 665   (or (cdr (assoc group nnml-nov-buffer-alist))
 666       (let ((buffer (nnheader-find-file-noselect
 667                      (concat (nnmail-group-pathname group nnml-directory)
 668                              nnml-nov-file-name))))
 669         (save-excursion
 670           (set-buffer buffer)
 671           (buffer-disable-undo (current-buffer)))
 672         (push (cons group buffer) nnml-nov-buffer-alist)
 673         buffer)))
 674
 675 (defun nnml-save-nov ()
 676   (save-excursion
 677     (while nnml-nov-buffer-alist
 678       (when (buffer-name (cdar nnml-nov-buffer-alist))
 679         (set-buffer (cdar nnml-nov-buffer-alist))
 680         (when (buffer-modified-p)
 681           (nnmail-write-region 1 (point-max) (buffer-file-name) nil 'nomesg))
 682         (set-buffer-modified-p nil)
 683         (kill-buffer (current-buffer)))
 684       (setq nnml-nov-buffer-alist (cdr nnml-nov-buffer-alist)))))
 685
 686 ;;;###autoload
 687 (defun nnml-generate-nov-databases ()
 688   "Generate nov databases in all nnml directories."
 689   (interactive)
 690   ;; Read the active file to make sure we don't re-use articles
 691   ;; numbers in empty groups.
 692   (nnmail-activate 'nnml)
 693   (nnml-open-server (or (nnoo-current-server 'nnml) ""))
 694   (setq nnml-directory (expand-file-name nnml-directory))
 695   ;; Recurse down the directories.
 696   (nnml-generate-nov-databases-1 nnml-directory)
 697   ;; Save the active file.
 698   (nnmail-save-active nnml-group-alist nnml-active-file))
 699
 700 (defun nnml-generate-nov-databases-1 (dir &optional seen)
 701   (setq dir (file-name-as-directory dir))
 702   ;; Only scan this sub-tree if we haven't been here yet.
 703   (unless (member (file-truename dir) seen)
 704     (push (file-truename dir) seen)
 705     ;; We descend recursively
 706     (let ((dirs (directory-files dir t nil t))
 707           dir)
 708       (while (setq dir (pop dirs))
 709         (when (and (not (member (file-name-nondirectory dir) '("." "..")))
 710                    (file-directory-p dir))
 711           (nnml-generate-nov-databases-1 dir seen))))
 712     ;; Do this directory.
 713     (let ((files (nnheader-article-to-file-alist dir)))
 714       (when files
 715         (funcall nnml-generate-active-function dir)
 716         ;; Generate the nov file.
 717         (nnml-generate-nov-file dir files)))))
 718
 719 (defvar files)
 720 (defun nnml-generate-active-info (dir)
 721   ;; Update the active info for this group.
 722   (let ((group (nnheader-file-to-group
 723                 (directory-file-name dir) nnml-directory)))
 724     (setq nnml-group-alist
 725           (delq (assoc group nnml-group-alist) nnml-group-alist))
 726     (push (list group
 727                 (cons (car files)
 728                       (let ((f files))
 729                         (while (cdr f) (setq f (cdr f)))
 730                         (car f))))
 731           nnml-group-alist)))
 732
 733 (defun nnml-generate-nov-file (dir files)
 734   (let* ((dir (file-name-as-directory dir))
 735          (nov (concat dir nnml-nov-file-name))
 736          (nov-buffer (get-buffer-create " *nov*"))
 737          chars file headers)
 738     (save-excursion
 739       ;; Init the nov buffer.
 740       (set-buffer nov-buffer)
 741       (buffer-disable-undo (current-buffer))
 742       (erase-buffer)
 743       (set-buffer nntp-server-buffer)
 744       ;; Delete the old NOV file.
 745       (when (file-exists-p nov)
 746         (funcall nnmail-delete-file-function nov))
 747       (while files
 748         (unless (file-directory-p (setq file (concat dir (cdar files))))
 749           (erase-buffer)
 750           (nnheader-insert-file-contents file)
 751           (narrow-to-region
 752            (goto-char (point-min))
 753            (progn
 754              (search-forward "\n\n" nil t)
 755              (setq chars (- (point-max) (point)))
 756              (max 1 (1- (point)))))
 757           (when (and (not (= 0 chars))  ; none of them empty files...
 758                      (not (= (point-min) (point-max))))
 759             (goto-char (point-min))
 760             (setq headers (nnml-parse-head chars (caar files)))
 761             (save-excursion
 762               (set-buffer nov-buffer)
 763               (goto-char (point-max))
 764               (nnheader-insert-nov headers)))
 765           (widen))
 766         (setq files (cdr files)))
 767       (save-excursion
 768         (set-buffer nov-buffer)
 769         (nnmail-write-region 1 (point-max) nov nil 'nomesg)
 770         (kill-buffer (current-buffer))))))
 771
 772 (defun nnml-nov-delete-article (group article)
 773   (save-excursion
 774     (set-buffer (nnml-open-nov group))
 775     (goto-char (point-min))
 776     (when (re-search-forward (concat "^" (int-to-string article) "\t") nil t)
 777       (delete-region (match-beginning 0) (progn (forward-line 1) (point))))
 778     t))
 779
 780 (provide 'nnml)
 781
 782 ;;; nnml.el ends here