cgit.sxemacs.org Git - gnus/blob - lisp/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;;; Code:
  32
  33 (require 'nnheader)
  34 (require 'nnmail)
  35 (require 'gnus-start)
  36 (require 'nnoo)
  37 (eval-when-compile (require 'cl))
  38
  39 (nnoo-declare nnmh)
  40
  41 (defvoo nnmh-directory message-directory
  42   "*Mail spool directory.")
  43
  44 (defvoo nnmh-get-new-mail t
  45   "*If non-nil, nnmh will check the incoming mail file and split the mail.")
  46
  47 (defvoo nnmh-prepare-save-mail-hook nil
  48   "*Hook run narrowed to an article before saving.")
  49
  50 (defvoo nnmh-be-safe nil
  51   "*If non-nil, nnmh will check all articles to make sure whether they are new or not.")
  52
  53 \f
  54
  55 (defconst nnmh-version "nnmh 1.0"
  56   "nnmh version.")
  57
  58 (defvoo nnmh-current-directory nil
  59   "Current news group directory.")
  60
  61 (defvoo nnmh-status-string "")
  62 (defvoo nnmh-group-alist nil)
  63 (defvoo nnmh-allow-delete-final nil)
  64
  65 \f
  66
  67 ;;; Interface functions.
  68
  69 (nnoo-define-basics nnmh)
  70
  71 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  72   (save-excursion
  73     (set-buffer nntp-server-buffer)
  74     (erase-buffer)
  75     (let* ((file nil)
  76            (number (length articles))
  77            (large (and (numberp nnmail-large-newsgroup)
  78                        (> number nnmail-large-newsgroup)))
  79            (count 0)
  80            (pathname-coding-system 'binary)
  81            beg article)
  82       (nnmh-possibly-change-directory newsgroup server)
  83       ;; We don't support fetching by Message-ID.
  84       (if (stringp (car articles))
  85           'headers
  86         (while articles
  87           (when (and (file-exists-p
  88                       (setq file (concat (file-name-as-directory
  89                                           nnmh-current-directory)
  90                                          (int-to-string
  91                                           (setq article (pop articles))))))
  92                      (not (file-directory-p file)))
  93             (insert (format "221 %d Article retrieved.\n" article))
  94             (setq beg (point))
  95             (nnheader-insert-head file)
  96             (goto-char beg)
  97             (if (search-forward "\n\n" nil t)
  98                 (forward-char -1)
  99               (goto-char (point-max))
 100               (insert "\n\n"))
 101             (insert ".\n")
 102             (delete-region (point) (point-max)))
 103           (setq count (1+ count))
 104
 105           (and large
 106                (zerop (% count 20))
 107                (message "nnmh: Receiving headers... %d%%"
 108                         (/ (* count 100) number))))
 109
 110         (when large
 111           (message "nnmh: Receiving headers...done"))
 112
 113         (nnheader-fold-continuation-lines)
 114         'headers))))
 115
 116 (deffoo nnmh-open-server (server &optional defs)
 117   (nnoo-change-server 'nnmh server defs)
 118   (when (not (file-exists-p nnmh-directory))
 119     (condition-case ()
 120         (make-directory nnmh-directory t)
 121       (error t)))
 122   (cond
 123    ((not (file-exists-p nnmh-directory))
 124     (nnmh-close-server)
 125     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 126    ((not (file-directory-p (file-truename nnmh-directory)))
 127     (nnmh-close-server)
 128     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 129    (t
 130     (nnheader-report 'nnmh "Opened server %s using directory %s"
 131                      server nnmh-directory)
 132     t)))
 133
 134 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 135   (nnmh-possibly-change-directory newsgroup server)
 136   (let ((file (if (stringp id)
 137                   nil
 138                 (concat nnmh-current-directory (int-to-string id))))
 139         (pathname-coding-system 'binary)
 140         (nntp-server-buffer (or buffer nntp-server-buffer)))
 141     (and (stringp file)
 142          (file-exists-p file)
 143          (not (file-directory-p file))
 144          (save-excursion (nnmail-find-file file))
 145          (string-to-int (file-name-nondirectory file)))))
 146
 147 (deffoo nnmh-request-group (group &optional server dont-check)
 148   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 149         (pathname-coding-system 'binary)
 150         dir)
 151     (cond
 152      ((not (file-directory-p pathname))
 153       (nnheader-report
 154        'nnmh "Can't select group (no such directory): %s" group))
 155      (t
 156       (setq nnmh-current-directory pathname)
 157       (and nnmh-get-new-mail
 158            nnmh-be-safe
 159            (nnmh-update-gnus-unreads group))
 160       (cond
 161        (dont-check
 162         (nnheader-report 'nnmh "Selected group %s" group)
 163         t)
 164        (t
 165         ;; Re-scan the directory if it's on a foreign system.
 166         (nnheader-re-read-dir pathname)
 167         (setq dir
 168               (sort
 169                (mapcar (lambda (name) (string-to-int name))
 170                        (directory-files pathname nil "^[0-9]+$" t))
 171                '<))
 172           (cond
 173            (dir
 174             (nnheader-report 'nnmh "Selected group %s" group)
 175             (nnheader-insert
 176              "211 %d %d %d %s\n" (length dir) (car dir)
 177              (progn (while (cdr dir) (setq dir (cdr dir))) (car dir))
 178              group))
 179            (t
 180             (nnheader-report 'nnmh "Empty group %s" group)
 181             (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 182
 183 (deffoo nnmh-request-scan (&optional group server)
 184   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 185
 186 (deffoo nnmh-request-list (&optional server dir)
 187   (nnheader-insert "")
 188   (let ((pathname-coding-system 'binary)
 189         (nnmh-toplev
 190          (file-truename (or dir (file-name-as-directory nnmh-directory)))))
 191     (nnmh-request-list-1 nnmh-toplev))
 192   (setq nnmh-group-alist (nnmail-get-active))
 193   t)
 194
 195 (defvar nnmh-toplev)
 196 (defun nnmh-request-list-1 (dir)
 197   (setq dir (expand-file-name dir))
 198   ;; Recurse down all directories.
 199   (let ((dirs (and (file-readable-p dir)
 200                    (> (nth 1 (file-attributes (file-chase-links dir))) 2)
 201                    (directory-files dir t nil t)))
 202         rdir)
 203     ;; Recurse down directories.
 204     (while (setq rdir (pop dirs))
 205       (when (and (not (member (file-name-nondirectory rdir) '("." "..")))
 206                  (file-directory-p rdir)
 207                  (file-readable-p rdir)
 208                  (equal (file-truename rdir)
 209                         (file-truename dir)))
 210         (nnmh-request-list-1 rdir))))
 211   ;; For each directory, generate an active file line.
 212   (unless (string= (expand-file-name nnmh-toplev) dir)
 213     (let ((files (mapcar
 214                   (lambda (name) (string-to-int name))
 215                   (directory-files dir nil "^[0-9]+$" t))))
 216       (when files
 217         (save-excursion
 218           (set-buffer nntp-server-buffer)
 219           (goto-char (point-max))
 220           (insert
 221            (format
 222             "%s %d %d y\n"
 223             (progn
 224               (string-match
 225                (regexp-quote
 226                 (file-truename (file-name-as-directory
 227                                 (expand-file-name nnmh-toplev))))
 228                dir)
 229               (nnheader-replace-chars-in-string
 230                (gnus-decode-coding-string (substring dir (match-end 0))
 231                                           nnmail-pathname-coding-system)
 232                ?/ ?.))
 233             (apply 'max files)
 234             (apply 'min files)))))))
 235   t)
 236
 237 (deffoo nnmh-request-newgroups (date &optional server)
 238   (nnmh-request-list server))
 239
 240 (deffoo nnmh-request-expire-articles (articles newsgroup
 241                                                &optional server force)
 242   (nnmh-possibly-change-directory newsgroup server)
 243   (let* ((active-articles
 244           (mapcar
 245            (function
 246             (lambda (name)
 247               (string-to-int name)))
 248            (directory-files nnmh-current-directory nil "^[0-9]+$" t)))
 249          (is-old t)
 250          article rest mod-time)
 251     (nnmail-activate 'nnmh)
 252
 253     (while (and articles is-old)
 254       (setq article (concat nnmh-current-directory
 255                             (int-to-string (car articles))))
 256       (when (setq mod-time (nth 5 (file-attributes article)))
 257         (if (and (nnmh-deletable-article-p newsgroup (car articles))
 258                  (setq is-old
 259                        (nnmail-expired-article-p newsgroup mod-time force)))
 260             (progn
 261               (nnheader-message 5 "Deleting article %s in %s..."
 262                                 article newsgroup)
 263               (condition-case ()
 264                   (funcall nnmail-delete-file-function article)
 265                 (file-error
 266                  (nnheader-message 1 "Couldn't delete article %s in %s"
 267                                    article newsgroup)
 268                  (push (car articles) rest))))
 269           (push (car articles) rest)))
 270       (setq articles (cdr articles)))
 271     (message "")
 272     (nconc rest articles)))
 273
 274 (deffoo nnmh-close-group (group &optional server)
 275   t)
 276
 277 (deffoo nnmh-request-move-article
 278   (article group server accept-form &optional last)
 279   (let ((buf (get-buffer-create " *nnmh move*"))
 280         result)
 281     (and
 282      (nnmh-deletable-article-p group article)
 283      (nnmh-request-article article group server)
 284      (save-excursion
 285        (set-buffer buf)
 286        (erase-buffer)
 287        (insert-buffer-substring nntp-server-buffer)
 288        (setq result (eval accept-form))
 289        (kill-buffer (current-buffer))
 290        result)
 291      (progn
 292        (nnmh-possibly-change-directory group server)
 293        (condition-case ()
 294            (funcall nnmail-delete-file-function
 295                     (concat nnmh-current-directory (int-to-string article)))
 296          (file-error nil))))
 297     result))
 298
 299 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 300   (nnmh-possibly-change-directory group server)
 301   (nnmail-check-syntax)
 302   (when nnmail-cache-accepted-message-ids
 303     (nnmail-cache-insert (nnmail-fetch-field "message-id")))
 304   (prog1
 305       (if (stringp group)
 306           (and
 307            (nnmail-activate 'nnmh)
 308            (if noinsert
 309                (nnmh-active-number group)
 310              (car (nnmh-save-mail
 311                    (list (cons group (nnmh-active-number group)))
 312                    noinsert))))
 313         (and
 314          (nnmail-activate 'nnmh)
 315          (let ((res (nnmail-article-group 'nnmh-active-number)))
 316            (if (and (null res)
 317                     (yes-or-no-p "Moved to `junk' group; delete article? "))
 318                'junk
 319              (car (nnmh-save-mail res noinsert))))))
 320     (when (and last nnmail-cache-accepted-message-ids)
 321       (nnmail-cache-close))))
 322
 323 (deffoo nnmh-request-replace-article (article group buffer)
 324   (nnmh-possibly-change-directory group)
 325   (save-excursion
 326     (set-buffer buffer)
 327     (nnmh-possibly-create-directory group)
 328     (ignore-errors
 329       (nnmail-write-region
 330        (point-min) (point-max)
 331        (concat nnmh-current-directory (int-to-string article))
 332        nil (if (nnheader-be-verbose 5) nil 'nomesg))
 333       t)))
 334
 335 (deffoo nnmh-request-create-group (group &optional server args)
 336   (nnmail-activate 'nnmh)
 337   (unless (assoc group nnmh-group-alist)
 338     (let (active)
 339       (push (list group (setq active (cons 1 0)))
 340             nnmh-group-alist)
 341       (nnmh-possibly-create-directory group)
 342       (nnmh-possibly-change-directory group server)
 343       (let ((articles (mapcar
 344                        (lambda (file)
 345                          (string-to-int file))
 346                        (directory-files
 347                         nnmh-current-directory nil "^[0-9]+$"))))
 348         (when articles
 349           (setcar active (apply 'min articles))
 350           (setcdr active (apply 'max articles))))))
 351   t)
 352
 353 (deffoo nnmh-request-delete-group (group &optional force server)
 354   (nnmh-possibly-change-directory group server)
 355   ;; Delete all articles in GROUP.
 356   (if (not force)
 357       ()                                ; Don't delete the articles.
 358     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 359       (while articles
 360         (when (file-writable-p (car articles))
 361           (nnheader-message 5 "Deleting article %s in %s..."
 362                             (car articles) group)
 363           (funcall nnmail-delete-file-function (car articles)))
 364         (setq articles (cdr articles))))
 365     ;; Try to delete the directory itself.
 366     (ignore-errors
 367       (delete-directory nnmh-current-directory)))
 368   ;; Remove the group from all structures.
 369   (setq nnmh-group-alist
 370         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 371         nnmh-current-directory nil)
 372   t)
 373
 374 (deffoo nnmh-request-rename-group (group new-name &optional server)
 375   (nnmh-possibly-change-directory group server)
 376   (let ((new-dir (nnmail-group-pathname new-name nnmh-directory))
 377         (old-dir (nnmail-group-pathname group nnmh-directory)))
 378     (when (ignore-errors
 379             (make-directory new-dir t)
 380             t)
 381       ;; We move the articles file by file instead of renaming
 382       ;; the directory -- there may be subgroups in this group.
 383       ;; One might be more clever, I guess.
 384       (let ((files (nnheader-article-to-file-alist old-dir)))
 385         (while files
 386           (rename-file
 387            (concat old-dir (cdar files))
 388            (concat new-dir (cdar files)))
 389           (pop files)))
 390       (when (<= (length (directory-files old-dir)) 2)
 391         (ignore-errors
 392           (delete-directory old-dir)))
 393       ;; That went ok, so we change the internal structures.
 394       (let ((entry (assoc group nnmh-group-alist)))
 395         (when entry
 396           (setcar entry new-name))
 397         (setq nnmh-current-directory nil)
 398         t))))
 399
 400 (nnoo-define-skeleton nnmh)
 401
 402 \f
 403 ;;; Internal functions.
 404
 405 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 406   (when (and server
 407              (not (nnmh-server-opened server)))
 408     (nnmh-open-server server))
 409   (when newsgroup
 410     (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory))
 411           (pathname-coding-system 'binary))
 412       (if (file-directory-p pathname)
 413           (setq nnmh-current-directory pathname)
 414         (error "No such newsgroup: %s" newsgroup)))))
 415
 416 (defun nnmh-possibly-create-directory (group)
 417   (let (dir dirs)
 418     (setq dir (nnmail-group-pathname group nnmh-directory))
 419     (while (not (file-directory-p dir))
 420       (push dir dirs)
 421       (setq dir (file-name-directory (directory-file-name dir))))
 422     (while dirs
 423       (when (make-directory (directory-file-name (car dirs)))
 424         (error "Could not create directory %s" (car dirs)))
 425       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 426       (setq dirs (cdr dirs)))))
 427
 428 (defun nnmh-save-mail (group-art &optional noinsert)
 429   "Called narrowed to an article."
 430   (unless noinsert
 431     (nnmail-insert-lines)
 432     (nnmail-insert-xref group-art))
 433   (run-hooks 'nnmail-prepare-save-mail-hook)
 434   (run-hooks 'nnmh-prepare-save-mail-hook)
 435   (goto-char (point-min))
 436   (while (looking-at "From ")
 437     (replace-match "X-From-Line: ")
 438     (forward-line 1))
 439   ;; We save the article in all the newsgroups it belongs in.
 440   (let ((ga group-art)
 441         first)
 442     (while ga
 443       (nnmh-possibly-create-directory (caar ga))
 444       (let ((file (concat (nnmail-group-pathname
 445                            (caar ga) nnmh-directory)
 446                           (int-to-string (cdar ga)))))
 447         (if first
 448             ;; It was already saved, so we just make a hard link.
 449             (funcall nnmail-crosspost-link-function first file t)
 450           ;; Save the article.
 451           (nnmail-write-region (point-min) (point-max) file nil nil)
 452           (setq first file)))
 453       (setq ga (cdr ga))))
 454   group-art)
 455
 456 (defun nnmh-active-number (group)
 457   "Compute the next article number in GROUP."
 458   (let ((active (cadr (assoc group nnmh-group-alist)))
 459         (dir (nnmail-group-pathname group nnmh-directory))
 460         (pathname-coding-system 'binary))
 461     (unless active
 462       ;; The group wasn't known to nnmh, so we just create an active
 463       ;; entry for it.
 464       (setq active (cons 1 0))
 465       (push (list group active) nnmh-group-alist)
 466       (unless (file-exists-p dir)
 467         (make-directory dir))
 468       ;; Find the highest number in the group.
 469       (let ((files (sort
 470                     (mapcar
 471                      (lambda (f)
 472                        (string-to-int f))
 473                      (directory-files dir nil "^[0-9]+$"))
 474                     '>)))
 475         (when files
 476           (setcdr active (car files)))))
 477     (setcdr active (1+ (cdr active)))
 478     (while (file-exists-p
 479             (concat (nnmail-group-pathname group nnmh-directory)
 480                     (int-to-string (cdr active))))
 481       (setcdr active (1+ (cdr active))))
 482     (cdr active)))
 483
 484 (defun nnmh-update-gnus-unreads (group)
 485   ;; Go through the .nnmh-articles file and compare with the actual
 486   ;; articles in this folder.  The articles that are "new" will be
 487   ;; marked as unread by Gnus.
 488   (let* ((dir nnmh-current-directory)
 489          (files (sort (mapcar (function (lambda (name) (string-to-int name)))
 490                               (directory-files nnmh-current-directory
 491                                                nil "^[0-9]+$" t))
 492                       '<))
 493          (nnmh-file (concat dir ".nnmh-articles"))
 494          new articles)
 495     ;; Load the .nnmh-articles file.
 496     (when (file-exists-p nnmh-file)
 497       (setq articles
 498             (let (nnmh-newsgroup-articles)
 499               (ignore-errors (load nnmh-file nil t t))
 500               nnmh-newsgroup-articles)))
 501     ;; Add all new articles to the `new' list.
 502     (let ((art files))
 503       (while art
 504         (unless (assq (car art) articles)
 505           (push (car art) new))
 506         (setq art (cdr art))))
 507     ;; Remove all deleted articles.
 508     (let ((art articles))
 509       (while art
 510         (unless (memq (caar art) files)
 511           (setq articles (delq (car art) articles)))
 512         (setq art (cdr art))))
 513     ;; Check whether the articles really are the ones that Gnus thinks
 514     ;; they are by looking at the time-stamps.
 515     (let ((arts articles)
 516           art)
 517       (while (setq art (pop arts))
 518         (when (not (equal
 519                     (nth 5 (file-attributes
 520                             (concat dir (int-to-string (car art)))))
 521                     (cdr art)))
 522           (setq articles (delq art articles))
 523           (push (car art) new))))
 524     ;; Go through all the new articles and add them, and their
 525     ;; time-stamps, to the list.
 526     (setq articles
 527           (nconc articles
 528                  (mapcar
 529                   (lambda (art)
 530                     (cons art
 531                           (nth 5 (file-attributes
 532                                   (concat dir (int-to-string art))))))
 533                   new)))
 534     ;; Make Gnus mark all new articles as unread.
 535     (when new
 536       (gnus-make-articles-unread
 537        (gnus-group-prefixed-name group (list 'nnmh ""))
 538        (setq new (sort new '<))))
 539     ;; Sort the article list with highest numbers first.
 540     (setq articles (sort articles (lambda (art1 art2)
 541                                     (> (car art1) (car art2)))))
 542     ;; Finally write this list back to the .nnmh-articles file.
 543     (nnheader-temp-write nnmh-file
 544       (insert ";; Gnus article active file for " group "\n\n")
 545       (insert "(setq nnmh-newsgroup-articles '")
 546       (gnus-prin1 articles)
 547       (insert ")\n"))))
 548
 549 (defun nnmh-deletable-article-p (group article)
 550   "Say whether ARTICLE in GROUP can be deleted."
 551   (let ((path (concat nnmh-current-directory (int-to-string article))))
 552     ;; Writable.
 553     (and (file-writable-p path)
 554          (or
 555           ;; We can never delete the last article in the group.
 556           (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 557                    article))
 558           ;; Well, we can.
 559           nnmh-allow-delete-final))))
 560
 561 (provide 'nnmh)
 562
 563 ;;; nnmh.el ends here