cgit.sxemacs.org Git - gnus/blob - lisp/nnmbox.el

   1 ;;; nnmbox.el --- mail mbox access for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   4 ;;      Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;; Keywords: news, mail
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  20 ;; Boston, MA 02111-1307, USA.
  21
  22 ;;; Commentary:
  23
  24 ;; For an overview of what the interface functions do, please see the
  25 ;; Gnus sources.
  26
  27 ;;; Code:
  28
  29 (require 'nnheader)
  30 (require 'message)
  31 (require 'nnmail)
  32 (require 'nnoo)
  33 (require 'gnus-range)
  34 (eval-when-compile (require 'cl))
  35
  36 (nnoo-declare nnmbox)
  37
  38 (defvoo nnmbox-mbox-file (expand-file-name "~/mbox")
  39   "The name of the mail box file in the user's home directory.")
  40
  41 (defvoo nnmbox-active-file (expand-file-name "~/.mbox-active")
  42   "The name of the active file for the mail box.")
  43
  44 (defvoo nnmbox-get-new-mail t
  45   "If non-nil, nnmbox will check the incoming mail file and split the mail.")
  46
  47 (defvoo nnmbox-prepare-save-mail-hook nil
  48   "Hook run narrowed to an article before saving.")
  49
  50 \f
  51
  52 (defconst nnmbox-version "nnmbox 1.0"
  53   "nnmbox version.")
  54
  55 (defvoo nnmbox-current-group nil
  56   "Current nnmbox news group directory.")
  57
  58 (defvar nnmbox-mbox-buffer nil)
  59
  60 (defvoo nnmbox-status-string "")
  61
  62 (defvoo nnmbox-group-alist nil)
  63 (defvoo nnmbox-active-timestamp nil)
  64
  65 (defvoo nnmbox-file-coding-system mm-binary-coding-system)
  66 (defvoo nnmbox-file-coding-system-for-write nil)
  67 (defvoo nnmbox-active-file-coding-system mm-binary-coding-system)
  68 (defvoo nnmbox-active-file-coding-system-for-write nil)
  69
  70 (defvar nnmbox-group-building-active-articles nil)
  71 (defvar nnmbox-group-active-articles nil)
  72 \f
  73
  74 ;;; Interface functions
  75
  76 (nnoo-define-basics nnmbox)
  77
  78 (deffoo nnmbox-retrieve-headers (sequence &optional newsgroup server fetch-old)
  79   (save-excursion
  80     (set-buffer nntp-server-buffer)
  81     (erase-buffer)
  82     (let ((number (length sequence))
  83           (count 0)
  84           article start stop)
  85       (nnmbox-possibly-change-newsgroup newsgroup server)
  86       (while sequence
  87         (setq article (car sequence))
  88         (set-buffer nnmbox-mbox-buffer)
  89         (when (nnmbox-find-article article)
  90           (setq start
  91                 (save-excursion
  92                   (re-search-backward
  93                    (concat "^" message-unix-mail-delimiter) nil t)
  94                   (point)))
  95           (search-forward "\n\n" nil t)
  96           (setq stop (1- (point)))
  97           (set-buffer nntp-server-buffer)
  98           (insert (format "221 %d Article retrieved.\n" article))
  99           (insert-buffer-substring nnmbox-mbox-buffer start stop)
 100           (goto-char (point-max))
 101           (insert ".\n"))
 102         (setq sequence (cdr sequence))
 103         (setq count (1+ count))
 104         (and (numberp nnmail-large-newsgroup)
 105              (> number nnmail-large-newsgroup)
 106              (zerop (% count 20))
 107              (nnheader-message 5 "nnmbox: Receiving headers... %d%%"
 108                                (/ (* count 100) number))))
 109
 110       (and (numberp nnmail-large-newsgroup)
 111            (> number nnmail-large-newsgroup)
 112            (nnheader-message 5 "nnmbox: Receiving headers...done"))
 113
 114       (set-buffer nntp-server-buffer)
 115       (nnheader-fold-continuation-lines)
 116       'headers)))
 117
 118 (deffoo nnmbox-open-server (server &optional defs)
 119   (nnoo-change-server 'nnmbox server defs)
 120   (nnmbox-create-mbox)
 121   (cond
 122    ((not (file-exists-p nnmbox-mbox-file))
 123     (nnmbox-close-server)
 124     (nnheader-report 'nnmbox "No such file: %s" nnmbox-mbox-file))
 125    ((file-directory-p nnmbox-mbox-file)
 126     (nnmbox-close-server)
 127     (nnheader-report 'nnmbox "Not a regular file: %s" nnmbox-mbox-file))
 128    (t
 129     (nnheader-report 'nnmbox "Opened server %s using mbox %s" server
 130                      nnmbox-mbox-file)
 131     t)))
 132
 133 (deffoo nnmbox-close-server (&optional server)
 134   (when (and nnmbox-mbox-buffer
 135              (buffer-name nnmbox-mbox-buffer))
 136     (kill-buffer nnmbox-mbox-buffer))
 137   (nnoo-close-server 'nnmbox server)
 138   t)
 139
 140 (deffoo nnmbox-server-opened (&optional server)
 141   (and (nnoo-current-server-p 'nnmbox server)
 142        nnmbox-mbox-buffer
 143        (buffer-name nnmbox-mbox-buffer)
 144        nntp-server-buffer
 145        (buffer-name nntp-server-buffer)))
 146
 147 (deffoo nnmbox-request-article (article &optional newsgroup server buffer)
 148   (nnmbox-possibly-change-newsgroup newsgroup server)
 149   (save-excursion
 150     (set-buffer nnmbox-mbox-buffer)
 151     (when (nnmbox-find-article article)
 152       (let (start stop)
 153         (re-search-backward (concat "^" message-unix-mail-delimiter) nil t)
 154         (setq start (point))
 155         (forward-line 1)
 156         (or (and (re-search-forward
 157                   (concat "^" message-unix-mail-delimiter) nil t)
 158                  (forward-line -1))
 159             (goto-char (point-max)))
 160         (setq stop (point))
 161         (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
 162           (set-buffer nntp-server-buffer)
 163           (erase-buffer)
 164           (insert-buffer-substring nnmbox-mbox-buffer start stop)
 165           (goto-char (point-min))
 166           (while (looking-at "From ")
 167             (delete-char 5)
 168             (insert "X-From-Line: ")
 169             (forward-line 1))
 170           (if (numberp article)
 171               (cons nnmbox-current-group article)
 172             (nnmbox-article-group-number nil)))))))
 173
 174 (deffoo nnmbox-request-group (group &optional server dont-check)
 175   (nnmbox-possibly-change-newsgroup nil server)
 176   (let ((active (cadr (assoc group nnmbox-group-alist))))
 177     (cond
 178      ((or (null active)
 179           (null (nnmbox-possibly-change-newsgroup group server)))
 180       (nnheader-report 'nnmbox "No such group: %s" group))
 181      (dont-check
 182       (nnheader-report 'nnmbox "Selected group %s" group)
 183       (nnheader-insert ""))
 184      (t
 185       (nnheader-report 'nnmbox "Selected group %s" group)
 186       (nnheader-insert "211 %d %d %d %s\n"
 187                        (1+ (- (cdr active) (car active)))
 188                        (car active) (cdr active) group)))))
 189
 190 (defun nnmbox-save-buffer ()
 191   (let ((coding-system-for-write
 192          (or nnmbox-file-coding-system-for-write
 193              nnmbox-file-coding-system)))
 194     (save-buffer)))
 195
 196 (defun nnmbox-save-active (group-alist active-file)
 197   (let ((nnmail-active-file-coding-system
 198          (or nnmbox-active-file-coding-system-for-write
 199              nnmbox-active-file-coding-system)))
 200     (nnmail-save-active group-alist active-file)))
 201
 202 (deffoo nnmbox-request-scan (&optional group server)
 203   (nnmbox-possibly-change-newsgroup group server)
 204   (nnmbox-read-mbox)
 205   (nnmail-get-new-mail
 206    'nnmbox
 207    (lambda ()
 208      (save-excursion
 209        (set-buffer nnmbox-mbox-buffer)
 210        (nnmbox-save-buffer)))
 211    (file-name-directory nnmbox-mbox-file)
 212    group
 213    (lambda ()
 214      (save-excursion
 215        (let ((in-buf (current-buffer)))
 216          (set-buffer nnmbox-mbox-buffer)
 217          (goto-char (point-max))
 218          (insert-buffer-substring in-buf)))
 219      (nnmbox-save-active nnmbox-group-alist nnmbox-active-file))))
 220
 221 (deffoo nnmbox-close-group (group &optional server)
 222   t)
 223
 224 (deffoo nnmbox-request-create-group (group &optional server args)
 225   (nnmail-activate 'nnmbox)
 226   (unless (assoc group nnmbox-group-alist)
 227     (push (list group (cons 1 0))
 228           nnmbox-group-alist)
 229     (nnmbox-save-active nnmbox-group-alist nnmbox-active-file))
 230   t)
 231
 232 (deffoo nnmbox-request-list (&optional server)
 233   (save-excursion
 234     (let ((nnmail-file-coding-system
 235            nnmbox-active-file-coding-system))
 236       (nnmail-find-file nnmbox-active-file))
 237     (setq nnmbox-group-alist (nnmail-get-active))
 238     t))
 239
 240 (deffoo nnmbox-request-newgroups (date &optional server)
 241   (nnmbox-request-list server))
 242
 243 (deffoo nnmbox-request-list-newsgroups (&optional server)
 244   (nnheader-report 'nnmbox "LIST NEWSGROUPS is not implemented."))
 245
 246 (deffoo nnmbox-request-expire-articles
 247     (articles newsgroup &optional server force)
 248   (nnmbox-possibly-change-newsgroup newsgroup server)
 249   (let* ((is-old t)
 250          rest)
 251     (nnmail-activate 'nnmbox)
 252
 253     (save-excursion
 254       (set-buffer nnmbox-mbox-buffer)
 255       (while (and articles is-old)
 256         (when (nnmbox-find-article (car articles))
 257           (if (setq is-old
 258                     (nnmail-expired-article-p
 259                      newsgroup
 260                      (buffer-substring
 261                       (point) (progn (end-of-line) (point))) force))
 262               (progn
 263                 (unless (eq nnmail-expiry-target 'delete)
 264                   (with-temp-buffer
 265                     (nnmbox-request-article (car articles)
 266                                              newsgroup server
 267                                              (current-buffer))
 268                     (let ((nnml-current-directory nil))
 269                       (nnmail-expiry-target-group
 270                        nnmail-expiry-target newsgroup)))
 271                   (nnmbox-possibly-change-newsgroup newsgroup server))
 272                 (nnheader-message 5 "Deleting article %d in %s..."
 273                                   (car articles) newsgroup)
 274                 (nnmbox-delete-mail))
 275             (push (car articles) rest)))
 276         (setq articles (cdr articles)))
 277       (nnmbox-save-buffer)
 278       ;; Find the lowest active article in this group.
 279       (let ((active (nth 1 (assoc newsgroup nnmbox-group-alist))))
 280         (while (and (not (nnmbox-find-article (car active)))
 281                     (<= (car active) (cdr active)))
 282           (setcar active (1+ (car active)))))
 283       (nnmbox-save-active nnmbox-group-alist nnmbox-active-file)
 284       (nconc rest articles))))
 285
 286 (deffoo nnmbox-request-move-article
 287     (article group server accept-form &optional last)
 288   (let ((buf (get-buffer-create " *nnmbox move*"))
 289         result)
 290     (and
 291      (nnmbox-request-article article group server)
 292      (save-excursion
 293        (set-buffer buf)
 294        (erase-buffer)
 295        (insert-buffer-substring nntp-server-buffer)
 296        (goto-char (point-min))
 297        (while (re-search-forward
 298                "^X-Gnus-Newsgroup:"
 299                (save-excursion (search-forward "\n\n" nil t) (point)) t)
 300          (gnus-delete-line))
 301        (setq result (eval accept-form))
 302        (kill-buffer buf)
 303        result)
 304      (save-excursion
 305        (nnmbox-possibly-change-newsgroup group server)
 306        (set-buffer nnmbox-mbox-buffer)
 307        (when (nnmbox-find-article article)
 308          (nnmbox-delete-mail))
 309        (and last (nnmbox-save-buffer))))
 310     result))
 311
 312 (deffoo nnmbox-request-accept-article (group &optional server last)
 313   (nnmbox-possibly-change-newsgroup group server)
 314   (nnmail-check-syntax)
 315   (let ((buf (current-buffer))
 316         result)
 317     (goto-char (point-min))
 318     ;; The From line may have been quoted by movemail.
 319     (when (looking-at (concat ">" message-unix-mail-delimiter))
 320       (delete-char 1))
 321     (if (looking-at "X-From-Line: ")
 322         (replace-match "From ")
 323       (insert "From nobody " (current-time-string) "\n"))
 324     (and
 325      (nnmail-activate 'nnmbox)
 326      (progn
 327        (set-buffer buf)
 328        (goto-char (point-min))
 329        (search-forward "\n\n" nil t)
 330        (forward-line -1)
 331        (while (re-search-backward "^X-Gnus-Newsgroup: " nil t)
 332          (delete-region (point) (progn (forward-line 1) (point))))
 333        (when nnmail-cache-accepted-message-ids
 334          (nnmail-cache-insert (nnmail-fetch-field "message-id")
 335                               group
 336                               (nnmail-fetch-field "subject")))
 337        (setq result (if (stringp group)
 338                         (list (cons group (nnmbox-active-number group)))
 339                       (nnmail-article-group 'nnmbox-active-number)))
 340        (if (and (null result)
 341                 (yes-or-no-p "Moved to `junk' group; delete article? "))
 342            (setq result 'junk)
 343          (setq result (car (nnmbox-save-mail result)))))
 344      (save-excursion
 345        (set-buffer nnmbox-mbox-buffer)
 346        (goto-char (point-max))
 347        (insert-buffer-substring buf)
 348        (when last
 349          (when nnmail-cache-accepted-message-ids
 350            (nnmail-cache-close))
 351          (nnmbox-save-active nnmbox-group-alist nnmbox-active-file)
 352          (nnmbox-save-buffer))))
 353     result))
 354
 355 (deffoo nnmbox-request-replace-article (article group buffer)
 356   (nnmbox-possibly-change-newsgroup group)
 357   (save-excursion
 358     (set-buffer nnmbox-mbox-buffer)
 359     (if (not (nnmbox-find-article article))
 360         nil
 361       (nnmbox-delete-mail t t)
 362       (insert-buffer-substring buffer)
 363       (nnmbox-save-buffer)
 364       t)))
 365
 366 (deffoo nnmbox-request-delete-group (group &optional force server)
 367   (nnmbox-possibly-change-newsgroup group server)
 368   ;; Delete all articles in GROUP.
 369   (if (not force)
 370       ()                                ; Don't delete the articles.
 371     (save-excursion
 372       (set-buffer nnmbox-mbox-buffer)
 373       (goto-char (point-min))
 374       ;; Delete all articles in this group.
 375       (let ((ident (concat "\nX-Gnus-Newsgroup: " nnmbox-current-group ":"))
 376             found)
 377         (while (search-forward ident nil t)
 378           (setq found t)
 379           (nnmbox-delete-mail))
 380         (when found
 381           (nnmbox-save-buffer)))))
 382   ;; Remove the group from all structures.
 383   (setq nnmbox-group-alist
 384         (delq (assoc group nnmbox-group-alist) nnmbox-group-alist)
 385         nnmbox-current-group nil)
 386   ;; Save the active file.
 387   (nnmbox-save-active nnmbox-group-alist nnmbox-active-file)
 388   t)
 389
 390 (deffoo nnmbox-request-rename-group (group new-name &optional server)
 391   (nnmbox-possibly-change-newsgroup group server)
 392   (save-excursion
 393     (set-buffer nnmbox-mbox-buffer)
 394     (goto-char (point-min))
 395     (let ((ident (concat "\nX-Gnus-Newsgroup: " nnmbox-current-group ":"))
 396           (new-ident (concat "\nX-Gnus-Newsgroup: " new-name ":"))
 397           found)
 398       (while (search-forward ident nil t)
 399         (replace-match new-ident t t)
 400         (setq found t))
 401       (when found
 402         (nnmbox-save-buffer))))
 403   (let ((entry (assoc group nnmbox-group-active-articles)))
 404     (when entry
 405       (setcar entry new-name)))
 406   (let ((entry (assoc group nnmbox-group-alist)))
 407     (when entry
 408       (setcar entry new-name))
 409     (setq nnmbox-current-group nil)
 410     ;; Save the new group alist.
 411     (nnmbox-save-active nnmbox-group-alist nnmbox-active-file)
 412     t))
 413
 414 \f
 415 ;;; Internal functions.
 416
 417 ;; If FORCE, delete article no matter how many X-Gnus-Newsgroup
 418 ;; headers there are.  If LEAVE-DELIM, don't delete the Unix mbox
 419 ;; delimiter line.
 420 (defun nnmbox-delete-mail (&optional force leave-delim)
 421   ;; Delete the current X-Gnus-Newsgroup line.
 422   ;; First delete record of active article, unless the article is being
 423   ;; replaced, indicated by FORCE being non-nil.
 424   (if (not force)
 425       (nnmbox-record-deleted-article (nnmbox-article-group-number t)))
 426   (or force
 427       (gnus-delete-line))
 428   ;; Beginning of the article.
 429   (save-excursion
 430     (save-restriction
 431       (narrow-to-region
 432        (save-excursion
 433          (re-search-backward (concat "^" message-unix-mail-delimiter) nil t)
 434          (if leave-delim (progn (forward-line 1) (point))
 435            (match-beginning 0)))
 436        (progn
 437          (forward-line 1)
 438          (or (and (re-search-forward (concat "^" message-unix-mail-delimiter)
 439                                      nil t)
 440                   (if (and (not (bobp)) leave-delim)
 441                       (progn (forward-line -2) (point))
 442                     (match-beginning 0)))
 443              (point-max))))
 444       (goto-char (point-min))
 445       ;; Only delete the article if no other group owns it as well.
 446       (when (or force (not (re-search-forward "^X-Gnus-Newsgroup: " nil t)))
 447         (delete-region (point-min) (point-max))))))
 448
 449 (defun nnmbox-possibly-change-newsgroup (newsgroup &optional server)
 450   (when (and server
 451              (not (nnmbox-server-opened server)))
 452     (nnmbox-open-server server))
 453   (when (or (not nnmbox-mbox-buffer)
 454             (not (buffer-name nnmbox-mbox-buffer)))
 455     (nnmbox-read-mbox))
 456   (when (not nnmbox-group-alist)
 457     (nnmail-activate 'nnmbox))
 458   (if newsgroup
 459       (when (assoc newsgroup nnmbox-group-alist)
 460         (setq nnmbox-current-group newsgroup))
 461     t))
 462
 463 (defun nnmbox-article-string (article)
 464   (if (numberp article)
 465       (concat "\nX-Gnus-Newsgroup: " nnmbox-current-group ":"
 466               (int-to-string article) " ")
 467     (concat "\nMessage-ID: " article)))
 468
 469 (defun nnmbox-article-group-number (this-line)
 470   (save-excursion
 471     (if this-line
 472         (beginning-of-line)
 473       (goto-char (point-min)))
 474     (when (re-search-forward "^X-Gnus-Newsgroup: +\\([^:]+\\):\\([0-9]+\\) "
 475                              nil t)
 476       (cons (buffer-substring (match-beginning 1) (match-end 1))
 477             (string-to-int
 478              (buffer-substring (match-beginning 2) (match-end 2)))))))
 479
 480 (defun nnmbox-in-header-p (pos)
 481   "Return non-nil if POS is in the header of an article."
 482   (save-excursion
 483     (goto-char pos)
 484     (re-search-backward (concat "^" message-unix-mail-delimiter) nil t)
 485     (search-forward "\n\n" nil t)
 486     (< pos (point))))
 487
 488 (defun nnmbox-find-article (article)
 489   "Leaves point on the relevant X-Gnus-Newsgroup line if found."
 490   ;; Check that article is in the active range first, to avoid an
 491   ;; expensive exhaustive search if it isn't.
 492   (if (and (numberp article)
 493            (not (nnmbox-is-article-active-p article)))
 494       nil
 495     (let ((art-string (nnmbox-article-string article))
 496           (found nil))
 497       ;; There is the possibility that the X-Gnus-Newsgroup line appears
 498       ;; in the body of an article (for instance, if an article has been
 499       ;; forwarded from someone using Gnus as their mailer), so check
 500       ;; that the line is actually part of the article header.
 501       (or (and (search-forward art-string nil t)
 502                (nnmbox-in-header-p (point)))
 503           (progn
 504             (goto-char (point-min))
 505             (while (and (not found)
 506                         (search-forward art-string nil t))
 507               (setq found (nnmbox-in-header-p (point))))
 508             found)))))
 509
 510 (defun nnmbox-record-active-article (group-art)
 511   (let* ((group (car group-art))
 512          (article (cdr group-art))
 513          (entry
 514           (or (assoc group nnmbox-group-active-articles)
 515               (progn
 516                 (push (list group)
 517                       nnmbox-group-active-articles)
 518                 (car nnmbox-group-active-articles)))))
 519     ;; add article to index, either by building complete list
 520     ;; in reverse order, or as a list of ranges.
 521     (if (not nnmbox-group-building-active-articles)
 522         (setcdr entry (gnus-add-to-range (cdr entry) (list article)))
 523       (when (memq article (cdr entry))
 524         (switch-to-buffer nnmbox-mbox-buffer)
 525         (error "Article %s:%d already exists!" group article))
 526       (when (and (cadr entry) (< article (cadr entry)))
 527         (switch-to-buffer nnmbox-mbox-buffer)
 528         (error "Article %s:%d out of order" group article))
 529       (setcdr entry (cons article (cdr entry))))))
 530
 531 (defun nnmbox-record-deleted-article (group-art)
 532   (let* ((group (car group-art))
 533          (article (cdr group-art))
 534          (entry
 535           (or (assoc group nnmbox-group-active-articles)
 536               (progn
 537                 (push (list group)
 538                       nnmbox-group-active-articles)
 539                 (car nnmbox-group-active-articles)))))
 540     ;; remove article from index
 541     (setcdr entry (gnus-remove-from-range (cdr entry) (list article)))))
 542
 543 (defun nnmbox-is-article-active-p (article)
 544   (gnus-member-of-range
 545    article
 546    (cdr (assoc nnmbox-current-group
 547                nnmbox-group-active-articles))))
 548
 549 (defun nnmbox-save-mail (group-art)
 550   "Called narrowed to an article."
 551   (let ((delim (concat "^" message-unix-mail-delimiter)))
 552     (goto-char (point-min))
 553     ;; This might come from somewhere else.
 554     (unless (looking-at delim)
 555       (insert "From nobody " (current-time-string) "\n")
 556       (goto-char (point-min)))
 557     ;; Quote all "From " lines in the article.
 558     (forward-line 1)
 559     (while (re-search-forward delim nil t)
 560       (beginning-of-line)
 561       (insert "> "))
 562     (nnmail-insert-lines)
 563     (nnmail-insert-xref group-art)
 564     (nnmbox-insert-newsgroup-line group-art)
 565     (let ((alist group-art))
 566       (while alist
 567         (nnmbox-record-active-article (car alist))
 568         (setq alist (cdr alist))))
 569     (run-hooks 'nnmail-prepare-save-mail-hook)
 570     (run-hooks 'nnmbox-prepare-save-mail-hook)
 571     group-art))
 572
 573 (defun nnmbox-insert-newsgroup-line (group-art)
 574   (save-excursion
 575     (goto-char (point-min))
 576     (when (search-forward "\n\n" nil t)
 577       (forward-char -1)
 578       (while group-art
 579         (insert (format "X-Gnus-Newsgroup: %s:%d   %s\n"
 580                         (caar group-art) (cdar group-art)
 581                         (current-time-string)))
 582         (setq group-art (cdr group-art))))
 583     t))
 584
 585 (defun nnmbox-active-number (group)
 586   ;; Find the next article number in GROUP.
 587   (let ((active (cadr (assoc group nnmbox-group-alist))))
 588     (if active
 589         (setcdr active (1+ (cdr active)))
 590       ;; This group is new, so we create a new entry for it.
 591       ;; This might be a bit naughty... creating groups on the drop of
 592       ;; a hat, but I don't know...
 593       (push (list group (setq active (cons 1 1)))
 594             nnmbox-group-alist))
 595     (cdr active)))
 596
 597 (defun nnmbox-create-mbox ()
 598   (when (not (file-exists-p nnmbox-mbox-file))
 599     (let ((nnmail-file-coding-system
 600            (or nnmbox-file-coding-system-for-write
 601                nnmbox-file-coding-system))
 602           (dir (file-name-directory nnmbox-mbox-file)))
 603       (and dir (gnus-make-directory dir))
 604       (nnmail-write-region (point-min) (point-min)
 605                            nnmbox-mbox-file t 'nomesg))))
 606
 607 (defun nnmbox-read-mbox ()
 608   (nnmail-activate 'nnmbox)
 609   (nnmbox-create-mbox)
 610   (if (and nnmbox-mbox-buffer
 611            (buffer-name nnmbox-mbox-buffer)
 612            (save-excursion
 613              (set-buffer nnmbox-mbox-buffer)
 614              (= (buffer-size) (nnheader-file-size nnmbox-mbox-file))))
 615       ()
 616     (save-excursion
 617       (let ((delim (concat "^" message-unix-mail-delimiter))
 618             (alist nnmbox-group-alist)
 619             (nnmbox-group-building-active-articles t)
 620             start end end-header number)
 621         (set-buffer (setq nnmbox-mbox-buffer
 622                           (let ((nnheader-file-coding-system
 623                                  nnmbox-file-coding-system))
 624                             (nnheader-find-file-noselect
 625                              nnmbox-mbox-file t t))))
 626         (mm-enable-multibyte)
 627         (buffer-disable-undo)
 628
 629         ;; Go through the group alist and compare against the mbox file.
 630         (while alist
 631           (goto-char (point-max))
 632           (when (and (re-search-backward
 633                       (format "^X-Gnus-Newsgroup: %s:\\([0-9]+\\) "
 634                               (caar alist)) nil t)
 635                      (> (setq number
 636                               (string-to-number
 637                                (buffer-substring
 638                                 (match-beginning 1) (match-end 1))))
 639                         (cdadar alist)))
 640             (setcdr (cadar alist) number))
 641           (setq alist (cdr alist)))
 642
 643         ;; Examine all articles for our private X-Gnus-Newsgroup
 644         ;; headers.  This is done primarily as a consistency check, but
 645         ;; it is convenient for building an index of the articles
 646         ;; present, to avoid costly searches for missing articles
 647         ;; (eg. when expiring articles).
 648         (goto-char (point-min))
 649         (setq nnmbox-group-active-articles nil)
 650         (while (re-search-forward delim nil t)
 651           (setq start (match-beginning 0))
 652           (save-excursion
 653             (search-forward "\n\n" nil t)
 654             (setq end-header (point))
 655             (setq end (or (and
 656                            (re-search-forward delim nil t)
 657                            (match-beginning 0))
 658                           (point-max))))
 659           (if (search-forward "\nX-Gnus-Newsgroup: " end-header t)
 660               ;; Build a list of articles in each group, remembering
 661               ;; that each article may be in more than one group.
 662               (progn
 663                 (nnmbox-record-active-article (nnmbox-article-group-number t))
 664                 (while (search-forward "\nX-Gnus-Newsgroup: " end-header t)
 665                   (nnmbox-record-active-article (nnmbox-article-group-number t))))
 666             ;; The article is either new, or for some other reason
 667             ;; hasn't got our private headers, so add them now.  The
 668             ;; only situation I've encountered when the X-Gnus-Newsgroup
 669             ;; header is missing is if the article contains a forwarded
 670             ;; message which does contain that header line (earlier
 671             ;; versions of Gnus didn't restrict their search to the
 672             ;; headers).  In this case, there is an Xref line which
 673             ;; provides the relevant information to construct the
 674             ;; missing header(s).
 675             (save-excursion
 676               (save-restriction
 677                 (narrow-to-region start end)
 678                 (if (re-search-forward "\nXref: [^ ]+" end-header t)
 679                     ;; generate headers from Xref:
 680                     (let (alist)
 681                       (while (re-search-forward " \\([^:]+\\):\\([0-9]+\\)" end-header t)
 682                         (push (cons (match-string 1)
 683                                     (string-to-int (match-string 2))) alist))
 684                       (nnmbox-insert-newsgroup-line alist))
 685                   ;; this is really a new article
 686                   (nnmbox-save-mail
 687                    (nnmail-article-group 'nnmbox-active-number))))))
 688           (goto-char end))
 689         ;; put article lists in order
 690         (setq alist nnmbox-group-active-articles)
 691         (while alist
 692           (setcdr (car alist) (gnus-compress-sequence (nreverse (cdar alist))))
 693           (setq alist (cdr alist)))))))
 694
 695 (provide 'nnmbox)
 696
 697 ;;; nnmbox.el ends here