cgit.sxemacs.org Git - gnus/blob - lisp/nnmbox.el

   1 ;;; nnmbox.el --- mail mbox access for Gnus
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; For an overview of what the interface functions do, please see the
  28 ;; Gnus sources.
  29
  30 ;;; Code:
  31
  32 (require 'nnheader)
  33 (require 'message)
  34 (require 'nnmail)
  35 (require 'nnoo)
  36 (eval-when-compile (require 'cl))
  37
  38 (nnoo-declare nnmbox)
  39
  40 (defvoo nnmbox-mbox-file (expand-file-name "~/mbox")
  41   "The name of the mail box file in the user's home directory.")
  42
  43 (defvoo nnmbox-active-file (expand-file-name "~/.mbox-active")
  44   "The name of the active file for the mail box.")
  45
  46 (defvoo nnmbox-get-new-mail t
  47   "If non-nil, nnmbox will check the incoming mail file and split the mail.")
  48
  49 (defvoo nnmbox-prepare-save-mail-hook nil
  50   "Hook run narrowed to an article before saving.")
  51
  52 \f
  53
  54 (defconst nnmbox-version "nnmbox 1.0"
  55   "nnmbox version.")
  56
  57 (defvoo nnmbox-current-group nil
  58   "Current nnmbox news group directory.")
  59
  60 (defconst nnmbox-mbox-buffer nil)
  61
  62 (defvoo nnmbox-status-string "")
  63
  64 (defvoo nnmbox-group-alist nil)
  65 (defvoo nnmbox-active-timestamp nil)
  66
  67 \f
  68
  69 ;;; Interface functions
  70
  71 (nnoo-define-basics nnmbox)
  72
  73 (deffoo nnmbox-retrieve-headers (sequence &optional newsgroup server fetch-old)
  74   (save-excursion
  75     (set-buffer nntp-server-buffer)
  76     (erase-buffer)
  77     (let ((number (length sequence))
  78           (count 0)
  79           article art-string start stop)
  80       (nnmbox-possibly-change-newsgroup newsgroup server)
  81       (while sequence
  82         (setq article (car sequence))
  83         (setq art-string (nnmbox-article-string article))
  84         (set-buffer nnmbox-mbox-buffer)
  85         (when (or (search-forward art-string nil t)
  86                   (progn (goto-char (point-min))
  87                          (search-forward art-string nil t)))
  88           (setq start
  89                 (save-excursion
  90                   (re-search-backward
  91                    (concat "^" message-unix-mail-delimiter) nil t)
  92                   (point)))
  93           (search-forward "\n\n" nil t)
  94           (setq stop (1- (point)))
  95           (set-buffer nntp-server-buffer)
  96           (insert (format "221 %d Article retrieved.\n" article))
  97           (insert-buffer-substring nnmbox-mbox-buffer start stop)
  98           (goto-char (point-max))
  99           (insert ".\n"))
 100         (setq sequence (cdr sequence))
 101         (setq count (1+ count))
 102         (and (numberp nnmail-large-newsgroup)
 103              (> number nnmail-large-newsgroup)
 104              (zerop (% count 20))
 105              (nnheader-message 5 "nnmbox: Receiving headers... %d%%"
 106                                (/ (* count 100) number))))
 107
 108       (and (numberp nnmail-large-newsgroup)
 109            (> number nnmail-large-newsgroup)
 110            (nnheader-message 5 "nnmbox: Receiving headers...done"))
 111
 112       (set-buffer nntp-server-buffer)
 113       (nnheader-fold-continuation-lines)
 114       'headers)))
 115
 116 (deffoo nnmbox-open-server (server &optional defs)
 117   (nnoo-change-server 'nnmbox server defs)
 118   (nnmbox-create-mbox)
 119   (cond
 120    ((not (file-exists-p nnmbox-mbox-file))
 121     (nnmbox-close-server)
 122     (nnheader-report 'nnmbox "No such file: %s" nnmbox-mbox-file))
 123    ((file-directory-p nnmbox-mbox-file)
 124     (nnmbox-close-server)
 125     (nnheader-report 'nnmbox "Not a regular file: %s" nnmbox-mbox-file))
 126    (t
 127     (nnheader-report 'nnmbox "Opened server %s using mbox %s" server
 128                      nnmbox-mbox-file)
 129     t)))
 130
 131 (deffoo nnmbox-close-server (&optional server)
 132   (when (and nnmbox-mbox-buffer
 133              (buffer-name nnmbox-mbox-buffer))
 134     (kill-buffer nnmbox-mbox-buffer))
 135   (nnoo-close-server 'nnmbox server)
 136   t)
 137
 138 (deffoo nnmbox-server-opened (&optional server)
 139   (and (nnoo-current-server-p 'nnmbox server)
 140        nnmbox-mbox-buffer
 141        (buffer-name nnmbox-mbox-buffer)
 142        nntp-server-buffer
 143        (buffer-name nntp-server-buffer)))
 144
 145 (deffoo nnmbox-request-article (article &optional newsgroup server buffer)
 146   (nnmbox-possibly-change-newsgroup newsgroup server)
 147   (save-excursion
 148     (set-buffer nnmbox-mbox-buffer)
 149     (goto-char (point-min))
 150     (when (search-forward (nnmbox-article-string article) nil t)
 151       (let (start stop)
 152         (re-search-backward (concat "^" message-unix-mail-delimiter) nil t)
 153         (setq start (point))
 154         (forward-line 1)
 155         (or (and (re-search-forward
 156                   (concat "^" message-unix-mail-delimiter) nil t)
 157                  (forward-line -1))
 158             (goto-char (point-max)))
 159         (setq stop (point))
 160         (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
 161           (set-buffer nntp-server-buffer)
 162           (erase-buffer)
 163           (insert-buffer-substring nnmbox-mbox-buffer start stop)
 164           (goto-char (point-min))
 165           (while (looking-at "From ")
 166             (delete-char 5)
 167             (insert "X-From-Line: ")
 168             (forward-line 1))
 169           (if (numberp article)
 170               (cons nnmbox-current-group article)
 171             (nnmbox-article-group-number)))))))
 172
 173 (deffoo nnmbox-request-group (group &optional server dont-check)
 174   (let ((active (cadr (assoc group nnmbox-group-alist))))
 175     (cond
 176      ((or (null active)
 177           (null (nnmbox-possibly-change-newsgroup group server)))
 178       (nnheader-report 'nnmbox "No such group: %s" group))
 179      (dont-check
 180       (nnheader-report 'nnmbox "Selected group %s" group)
 181       (nnheader-insert ""))
 182      (t
 183       (nnheader-report 'nnmbox "Selected group %s" group)
 184       (nnheader-insert "211 %d %d %d %s\n"
 185                        (1+ (- (cdr active) (car active)))
 186                        (car active) (cdr active) group)))))
 187
 188 (deffoo nnmbox-request-scan (&optional group server)
 189   (nnmbox-possibly-change-newsgroup group server)
 190   (nnmbox-read-mbox)
 191   (nnmail-get-new-mail
 192    'nnmbox
 193    (lambda ()
 194      (save-excursion
 195        (set-buffer nnmbox-mbox-buffer)
 196        (save-buffer)))
 197    (file-name-directory nnmbox-mbox-file)
 198    group
 199    (lambda ()
 200      (save-excursion
 201        (let ((in-buf (current-buffer)))
 202          (set-buffer nnmbox-mbox-buffer)
 203          (goto-char (point-max))
 204          (insert-buffer-substring in-buf)))
 205      (nnmail-save-active nnmbox-group-alist nnmbox-active-file))))
 206
 207 (deffoo nnmbox-close-group (group &optional server)
 208   t)
 209
 210 (deffoo nnmbox-request-list (&optional server)
 211   (save-excursion
 212     (nnmail-find-file nnmbox-active-file)
 213     (setq nnmbox-group-alist (nnmail-get-active))
 214     t))
 215
 216 (deffoo nnmbox-request-newgroups (date &optional server)
 217   (nnmbox-request-list server))
 218
 219 (deffoo nnmbox-request-list-newsgroups (&optional server)
 220   (nnheader-report 'nnmbox "LIST NEWSGROUPS is not implemented."))
 221
 222 (deffoo nnmbox-request-expire-articles
 223   (articles newsgroup &optional server force)
 224   (nnmbox-possibly-change-newsgroup newsgroup server)
 225   (let* ((is-old t)
 226          rest)
 227     (nnmail-activate 'nnmbox)
 228
 229     (save-excursion
 230       (set-buffer nnmbox-mbox-buffer)
 231       (while (and articles is-old)
 232         (goto-char (point-min))
 233         (when (search-forward (nnmbox-article-string (car articles)) nil t)
 234           (if (setq is-old
 235                     (nnmail-expired-article-p
 236                      newsgroup
 237                      (buffer-substring
 238                       (point) (progn (end-of-line) (point))) force))
 239               (progn
 240                 (nnheader-message 5 "Deleting article %d in %s..."
 241                                   (car articles) newsgroup)
 242                 (nnmbox-delete-mail))
 243             (push (car articles) rest)))
 244         (setq articles (cdr articles)))
 245       (save-buffer)
 246       ;; Find the lowest active article in this group.
 247       (let ((active (nth 1 (assoc newsgroup nnmbox-group-alist))))
 248         (goto-char (point-min))
 249         (while (and (not (search-forward
 250                           (nnmbox-article-string (car active)) nil t))
 251                     (<= (car active) (cdr active)))
 252           (setcar active (1+ (car active)))
 253           (goto-char (point-min))))
 254       (nnmail-save-active nnmbox-group-alist nnmbox-active-file)
 255       (nconc rest articles))))
 256
 257 (deffoo nnmbox-request-move-article
 258   (article group server accept-form &optional last)
 259   (let ((buf (get-buffer-create " *nnmbox move*"))
 260         result)
 261     (and
 262      (nnmbox-request-article article group server)
 263      (save-excursion
 264        (set-buffer buf)
 265        (buffer-disable-undo (current-buffer))
 266        (erase-buffer)
 267        (insert-buffer-substring nntp-server-buffer)
 268        (goto-char (point-min))
 269        (while (re-search-forward
 270                "^X-Gnus-Newsgroup:"
 271                (save-excursion (search-forward "\n\n" nil t) (point)) t)
 272          (delete-region (progn (beginning-of-line) (point))
 273                         (progn (forward-line 1) (point))))
 274        (setq result (eval accept-form))
 275        (kill-buffer buf)
 276        result)
 277      (save-excursion
 278        (nnmbox-possibly-change-newsgroup group server)
 279        (set-buffer nnmbox-mbox-buffer)
 280        (goto-char (point-min))
 281        (when (search-forward (nnmbox-article-string article) nil t)
 282          (nnmbox-delete-mail))
 283        (and last (save-buffer))))
 284     result))
 285
 286 (deffoo nnmbox-request-accept-article (group &optional server last)
 287   (nnmbox-possibly-change-newsgroup group server)
 288   (nnmail-check-syntax)
 289   (let ((buf (current-buffer))
 290         result)
 291     (goto-char (point-min))
 292     ;; The From line may have been quoted by movemail.
 293     (when (looking-at (concat ">" message-unix-mail-delimiter))
 294       (delete-char 1))
 295     (if (looking-at "X-From-Line: ")
 296         (replace-match "From ")
 297       (insert "From nobody " (current-time-string) "\n"))
 298     (and
 299      (nnmail-activate 'nnmbox)
 300      (progn
 301        (set-buffer buf)
 302        (goto-char (point-min))
 303        (search-forward "\n\n" nil t)
 304        (forward-line -1)
 305        (while (re-search-backward "^X-Gnus-Newsgroup: " nil t)
 306          (delete-region (point) (progn (forward-line 1) (point))))
 307        (nnmail-cache-insert (nnmail-fetch-field "message-id"))
 308        (setq result (nnmbox-save-mail
 309                      (if (stringp group)
 310                          (list (cons group (nnmbox-active-number group)))
 311                        (nnmail-article-group 'nnmbox-active-number)))))
 312      (save-excursion
 313        (set-buffer nnmbox-mbox-buffer)
 314        (goto-char (point-max))
 315        (insert-buffer-substring buf)
 316        (when last
 317          (nnmail-cache-close)
 318          (nnmail-save-active nnmbox-group-alist nnmbox-active-file)
 319          (save-buffer))))
 320     (car result)))
 321
 322 (deffoo nnmbox-request-replace-article (article group buffer)
 323   (nnmbox-possibly-change-newsgroup group)
 324   (save-excursion
 325     (set-buffer nnmbox-mbox-buffer)
 326     (goto-char (point-min))
 327     (if (not (search-forward (nnmbox-article-string article) nil t))
 328         nil
 329       (nnmbox-delete-mail t t)
 330       (insert-buffer-substring buffer)
 331       (save-buffer)
 332       t)))
 333
 334 (deffoo nnmbox-request-delete-group (group &optional force server)
 335   (nnmbox-possibly-change-newsgroup group server)
 336   ;; Delete all articles in GROUP.
 337   (if (not force)
 338       ()                                ; Don't delete the articles.
 339     (save-excursion
 340       (set-buffer nnmbox-mbox-buffer)
 341       (goto-char (point-min))
 342       ;; Delete all articles in this group.
 343       (let ((ident (concat "\nX-Gnus-Newsgroup: " nnmbox-current-group ":"))
 344             found)
 345         (while (search-forward ident nil t)
 346           (setq found t)
 347           (nnmbox-delete-mail))
 348         (when found
 349           (save-buffer)))))
 350   ;; Remove the group from all structures.
 351   (setq nnmbox-group-alist
 352         (delq (assoc group nnmbox-group-alist) nnmbox-group-alist)
 353         nnmbox-current-group nil)
 354   ;; Save the active file.
 355   (nnmail-save-active nnmbox-group-alist nnmbox-active-file)
 356   t)
 357
 358 (deffoo nnmbox-request-rename-group (group new-name &optional server)
 359   (nnmbox-possibly-change-newsgroup group server)
 360   (save-excursion
 361     (set-buffer nnmbox-mbox-buffer)
 362     (goto-char (point-min))
 363     (let ((ident (concat "\nX-Gnus-Newsgroup: " nnmbox-current-group ":"))
 364           (new-ident (concat "\nX-Gnus-Newsgroup: " new-name ":"))
 365           found)
 366       (while (search-forward ident nil t)
 367         (replace-match new-ident t t)
 368         (setq found t))
 369       (when found
 370         (save-buffer))))
 371   (let ((entry (assoc group nnmbox-group-alist)))
 372     (when entry
 373       (setcar entry new-name))
 374     (setq nnmbox-current-group nil)
 375     ;; Save the new group alist.
 376     (nnmail-save-active nnmbox-group-alist nnmbox-active-file)
 377     t))
 378
 379 \f
 380 ;;; Internal functions.
 381
 382 ;; If FORCE, delete article no matter how many X-Gnus-Newsgroup
 383 ;; headers there are.  If LEAVE-DELIM, don't delete the Unix mbox
 384 ;; delimiter line.
 385 (defun nnmbox-delete-mail (&optional force leave-delim)
 386   ;; Delete the current X-Gnus-Newsgroup line.
 387   (or force
 388       (delete-region
 389        (progn (beginning-of-line) (point))
 390        (progn (forward-line 1) (point))))
 391   ;; Beginning of the article.
 392   (save-excursion
 393     (save-restriction
 394       (narrow-to-region
 395        (save-excursion
 396          (re-search-backward (concat "^" message-unix-mail-delimiter) nil t)
 397          (if leave-delim (progn (forward-line 1) (point))
 398            (match-beginning 0)))
 399        (progn
 400          (forward-line 1)
 401          (or (and (re-search-forward (concat "^" message-unix-mail-delimiter)
 402                                      nil t)
 403                   (if (and (not (bobp)) leave-delim)
 404                       (progn (forward-line -2) (point))
 405                     (match-beginning 0)))
 406              (point-max))))
 407       (goto-char (point-min))
 408       ;; Only delete the article if no other groups owns it as well.
 409       (when (or force (not (re-search-forward "^X-Gnus-Newsgroup: " nil t)))
 410         (delete-region (point-min) (point-max))))))
 411
 412 (defun nnmbox-possibly-change-newsgroup (newsgroup &optional server)
 413   (when (and server
 414              (not (nnmbox-server-opened server)))
 415     (nnmbox-open-server server))
 416   (when (or (not nnmbox-mbox-buffer)
 417             (not (buffer-name nnmbox-mbox-buffer)))
 418     (save-excursion
 419       (set-buffer (setq nnmbox-mbox-buffer
 420                         (nnheader-find-file-noselect
 421                          nnmbox-mbox-file nil 'raw)))
 422       (buffer-disable-undo (current-buffer))))
 423   (when (not nnmbox-group-alist)
 424     (nnmail-activate 'nnmbox))
 425   (if newsgroup
 426       (when (assoc newsgroup nnmbox-group-alist)
 427         (setq nnmbox-current-group newsgroup))
 428     t))
 429
 430 (defun nnmbox-article-string (article)
 431   (if (numberp article)
 432       (concat "\nX-Gnus-Newsgroup: " nnmbox-current-group ":"
 433               (int-to-string article) " ")
 434     (concat "\nMessage-ID: " article)))
 435
 436 (defun nnmbox-article-group-number ()
 437   (save-excursion
 438     (goto-char (point-min))
 439     (when (re-search-forward "^X-Gnus-Newsgroup: +\\([^:]+\\):\\([0-9]+\\) "
 440                              nil t)
 441       (cons (buffer-substring (match-beginning 1) (match-end 1))
 442             (string-to-int
 443              (buffer-substring (match-beginning 2) (match-end 2)))))))
 444
 445 (defun nnmbox-save-mail (group-art)
 446   "Called narrowed to an article."
 447   (let ((delim (concat "^" message-unix-mail-delimiter)))
 448     (goto-char (point-min))
 449     ;; This might come from somewhere else.
 450     (unless (looking-at delim)
 451       (insert "From nobody " (current-time-string) "\n")
 452       (goto-char (point-min)))
 453     ;; Quote all "From " lines in the article.
 454     (forward-line 1)
 455     (while (re-search-forward delim nil t)
 456       (beginning-of-line)
 457       (insert "> "))
 458     (nnmail-insert-lines)
 459     (nnmail-insert-xref group-art)
 460     (nnmbox-insert-newsgroup-line group-art)
 461     (run-hooks 'nnmail-prepare-save-mail-hook)
 462     (run-hooks 'nnmbox-prepare-save-mail-hook)
 463     group-art))
 464
 465 (defun nnmbox-insert-newsgroup-line (group-art)
 466   (save-excursion
 467     (goto-char (point-min))
 468     (when (search-forward "\n\n" nil t)
 469       (forward-char -1)
 470       (while group-art
 471         (insert (format "X-Gnus-Newsgroup: %s:%d   %s\n"
 472                         (caar group-art) (cdar group-art)
 473                         (current-time-string)))
 474         (setq group-art (cdr group-art))))
 475     t))
 476
 477 (defun nnmbox-active-number (group)
 478   ;; Find the next article number in GROUP.
 479   (let ((active (cadr (assoc group nnmbox-group-alist))))
 480     (if active
 481         (setcdr active (1+ (cdr active)))
 482       ;; This group is new, so we create a new entry for it.
 483       ;; This might be a bit naughty... creating groups on the drop of
 484       ;; a hat, but I don't know...
 485       (push (list group (setq active (cons 1 1)))
 486             nnmbox-group-alist))
 487     (cdr active)))
 488
 489 (defun nnmbox-create-mbox ()
 490   (when (not (file-exists-p nnmbox-mbox-file))
 491     (nnmail-write-region 1 1 nnmbox-mbox-file t 'nomesg)))
 492
 493 (defun nnmbox-read-mbox ()
 494   (nnmail-activate 'nnmbox)
 495   (nnmbox-create-mbox)
 496   (if (and nnmbox-mbox-buffer
 497            (buffer-name nnmbox-mbox-buffer)
 498            (save-excursion
 499              (set-buffer nnmbox-mbox-buffer)
 500              (= (buffer-size) (nnheader-file-size nnmbox-mbox-file))))
 501       ()
 502     (save-excursion
 503       (let ((delim (concat "^" message-unix-mail-delimiter))
 504             (alist nnmbox-group-alist)
 505             start end number)
 506         (set-buffer (setq nnmbox-mbox-buffer
 507                           (nnheader-find-file-noselect
 508                            nnmbox-mbox-file nil 'raw)))
 509         (buffer-disable-undo (current-buffer))
 510
 511         ;; Go through the group alist and compare against
 512         ;; the mbox file.
 513         (while alist
 514           (goto-char (point-max))
 515           (when (and (re-search-backward
 516                       (format "^X-Gnus-Newsgroup: %s:\\([0-9]+\\) "
 517                               (caar alist)) nil t)
 518                      (>= (setq number
 519                                (string-to-number
 520                                 (buffer-substring
 521                                  (match-beginning 1) (match-end 1))))
 522                          (cdadar alist)))
 523             (setcdr (cadar alist) (1+ number)))
 524           (setq alist (cdr alist)))
 525
 526         (goto-char (point-min))
 527         (while (re-search-forward delim nil t)
 528           (setq start (match-beginning 0))
 529           (when (not (search-forward "\nX-Gnus-Newsgroup: "
 530                                      (save-excursion
 531                                        (setq end
 532                                              (or
 533                                               (and
 534                                                (re-search-forward delim nil t)
 535                                                (match-beginning 0))
 536                                               (point-max))))
 537                                      t))
 538             (save-excursion
 539               (save-restriction
 540                 (narrow-to-region start end)
 541                 (nnmbox-save-mail
 542                  (nnmail-article-group 'nnmbox-active-number)))))
 543           (goto-char end))))))
 544
 545 (provide 'nnmbox)
 546
 547 ;;; nnmbox.el ends here