cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- imap backend for Gnus
   2 ;; Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   3
   4 ;; Author: Simon Josefsson <jas@pdc.kth.se>
   5 ;;         Jim Radford <radford@robby.caltech.edu>
   6 ;; Keywords: mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Todo, major things:
  28 ;;
  29 ;;   o Fix Gnus to view correct number of unread/total articles in group buffer
  30 ;;   o Fix Gnus to handle leading '.' in group names (fixed?)
  31 ;;   o Finish disconnected mode (moving articles between mailboxes unplugged)
  32 ;;   o Sieve
  33 ;;   o MIME (partial article fetches)
  34 ;;   o Split to other backends, different split rules for different
  35 ;;     servers/inboxes
  36 ;;
  37 ;; Todo, minor things:
  38 ;;
  39 ;;   o Don't require half of Gnus -- backends should be standalone
  40 ;;   o Verify that we don't use IMAP4rev1 specific things (RFC2060 App B)
  41 ;;   o Dont uid fetch 1,* in nnimap-retrive-groups (slow)
  42 ;;   o Split up big fetches (1,* header especially) in smaller chunks
  43 ;;   o What do I do with gnus-newsgroup-*?
  44 ;;   o Tell Gnus about new groups (how can we tell?)
  45 ;;   o Respooling (fix Gnus?) (unnecessery?)
  46 ;;   o Add support for the following: (if applicable)
  47 ;;       request-list-newsgroups, request-regenerate
  48 ;;       list-active-group,
  49 ;;       request-associate-buffer, request-restore-buffer,
  50 ;;   o Do The Right Thing when UIDVALIDITY changes (what's the right thing?)
  51 ;;   o Support RFC2221 (Login referrals)
  52 ;;   o IMAP2BIS compatibility? (RFC2061)
  53 ;;   o ACAP stuff (perhaps a different project, would be nice to ACAPify
  54 ;;     .newsrc.eld)
  55 ;;   o What about Gnus's article editing, can we support it?  NO!
  56 ;;   o Use \Draft to support the draft group??
  57 ;;   o Duplicate suppression
  58
  59 ;;; Code:
  60
  61 (eval-and-compile
  62   (require 'cl)
  63   (require 'imap))
  64
  65 (require 'nnoo)
  66 (require 'nnmail)
  67 (require 'nnheader)
  68 (require 'mm-util)
  69 (require 'gnus)
  70 (require 'gnus-range)
  71 (require 'gnus-start)
  72 (require 'gnus-int)
  73
  74 (nnoo-declare nnimap)
  75
  76 (defconst nnimap-version "nnimap 1.0")
  77
  78 (defvoo nnimap-address nil
  79   "Address of physical IMAP server.  If nil, use the virtual server's name.")
  80
  81 (defvoo nnimap-server-port nil
  82   "Port number on physical IMAP server.
  83 If nil, defaults to 993 for SSL connections and 143 otherwise.")
  84
  85 ;; Splitting variables
  86
  87 (defvar nnimap-split-crosspost t
  88   "If non-nil, do crossposting if several split methods match the mail.
  89 If nil, the first match found will be used.")
  90
  91 (defvar nnimap-split-inbox nil
  92   "*Name of mailbox to split mail from.
  93
  94 Mail is read from this mailbox and split according to rules in
  95 `nnimap-split-rule'.
  96
  97 This can be a string or a list of strings.")
  98
  99 (defvar nnimap-split-rule nil
 100   "*Mail will be split according to theese rules.
 101
 102 Mail is read from mailbox(es) specified in `nnimap-split-inbox'.
 103
 104 If you'd like, for instance, one mail group for mail from the
 105 \"gnus-imap\" mailing list, one group for junk mail and leave
 106 everything else in the incoming mailbox, you could do something like
 107 this:
 108
 109 (setq nnimap-split-rule '((\"INBOX.gnus-imap\"   \"From:.*gnus-imap\")
 110                           (\"INBOX.junk\"        \"Subject:.*buy\")))
 111
 112 As you can see, `nnimap-split-rule' is a list of lists, where the first
 113 element in each \"rule\" is the name of the IMAP mailbox, and the
 114 second is a regexp that nnimap will try to match on the header to find
 115 a fit.
 116
 117 The second element can also be a function.  In that case, it will be
 118 called narrowed to the headers with the first element of the rule as
 119 the argument.  It should return a non-nil value if it thinks that the
 120 mail belongs in that group.
 121
 122 This variable can also have a function as its value, the function will
 123 be called with the headers narrowed and should return a group where it
 124 thinks the article should be splitted to.  See `nnimap-split-fancy'.
 125
 126 To allow for different split rules on different virtual servers, and
 127 even different split rules in different inboxes on the same server,
 128 the syntax of this variable have been extended along the lines of:
 129
 130 (setq nnimap-split-rule
 131       '((\"my1server\"    (\".*\"    ((\"ding\"    \"ding@gnus.org\")
 132                                   (\"junk\"    \"From:.*Simon\")))
 133         (\"my2server\"    (\"INBOX\" nnimap-split-fancy))
 134         (\"my[34]server\" (\".*\"    ((\"private\" \"To:.*Simon\")
 135                                   (\"junk\"    my-junk-func)))))
 136
 137 The virtual server name is in fact a regexp, so that the same rules
 138 may apply to several servers.  In the example, the servers
 139 \"my3server\" and \"my4server\" both use the same rules.  Similarly,
 140 the inbox string is also a regexp.  The actual splitting rules are as
 141 before, either a function, or a list with group/regexp or
 142 group/function elements.")
 143
 144 (defvar nnimap-split-predicate "UNSEEN UNDELETED"
 145   "The predicate used to find articles to split.
 146 If you use another IMAP client to peek on articles but always would
 147 like nnimap to split them once it's started, you could change this to
 148 \"UNDELETED\". Other available predicates are available in
 149 RFC2060 section 6.4.4.")
 150
 151 (defvar nnimap-split-fancy nil
 152   "Like `nnmail-split-fancy', which see.")
 153
 154 ;; Authorization / Privacy variables
 155
 156 (defvoo nnimap-auth-method nil
 157   "Obsolete.")
 158
 159 (defvoo nnimap-stream nil
 160   "How nnimap will connect to the server.
 161
 162 The default, nil, will try to use the \"best\" method the server can
 163 handle.
 164
 165 Change this if
 166
 167 1) you want to connect with SSL.  The SSL integration with IMAP is
 168    brain-dead so you'll have to tell it specifically.
 169
 170 2) your server is more capable than your environment -- i.e. your
 171    server accept Kerberos login's but you haven't installed the
 172    `imtest' program or your machine isn't configured for Kerberos.
 173
 174 Possible choices: kerberos4, ssl, network")
 175
 176 (defvoo nnimap-authenticator nil
 177   "How nnimap authenticate itself to the server.
 178
 179 The default, nil, will try to use the \"best\" method the server can
 180 handle.
 181
 182 There is only one reason for fiddling with this variable, and that is
 183 if your server is more capable than your environment -- i.e. you
 184 connect to a server that accept Kerberos login's but you haven't
 185 installed the `imtest' program or your machine isn't configured for
 186 Kerberos.
 187
 188 Possible choices: kerberos4, cram-md5, login, anonymous.")
 189
 190 (defvoo nnimap-directory (nnheader-concat gnus-directory "overview/")
 191   "Directory to keep NOV cache files for nnimap groups.
 192 See also `nnimap-nov-file-name'.")
 193
 194 (defvoo nnimap-nov-file-name "nnimap."
 195   "NOV cache base filename.
 196 The group name and `nnimap-nov-file-name-suffix' will be appended.  A
 197 typical complete file name would be
 198 ~/News/overview/nnimap.pdc.INBOX.ding.nov, or
 199 ~/News/overview/nnimap/pdc/INBOX/ding/nov if
 200 `nnmail-use-long-file-names' is nil")
 201
 202 (defvoo nnimap-nov-file-name-suffix ".novcache"
 203   "Suffix for NOV cache base filename.")
 204
 205 (defvoo nnimap-nov-is-evil nil
 206   "If non-nil, nnimap will never generate or use a local nov database for this backend.
 207 Using nov databases will speed up header fetching considerably.
 208 Unlike other backends, you do not need to take special care if you
 209 flip this variable.")
 210
 211 (defvoo nnimap-expunge-on-close 'always ; 'ask, 'never
 212   "Whether to expunge a group when it is closed.
 213 When a IMAP group with articles marked for deletion is closed, this
 214 variable determine if nnimap should actually remove the articles or
 215 not.
 216
 217 If always, nnimap always perform a expunge when closing the group.
 218 If never, nnimap never expunges articles marked for deletion.
 219 If ask, nnimap will ask you if you wish to expunge marked articles.
 220
 221 When setting this variable to `never', you can only expunge articles
 222 by using `G x' (gnus-group-nnimap-expunge) from the Group buffer.")
 223
 224 (defvoo nnimap-list-pattern "*"
 225   "A string LIMIT or list of strings with mailbox wildcards used to limit available groups.
 226 See below for available wildcards.
 227
 228 The LIMIT string can be a cons cell (REFERENCE . LIMIT), where
 229 REFERENCE will be passed as the first parameter to LIST/LSUB.  The
 230 semantics of this are server specific, on the University of Washington
 231 server you can specify a directory.
 232
 233 Example:
 234  '(\"INBOX\" \"mail/*\" (\"~friend/mail/\" . \"list/*\"))
 235
 236 There are two wildcards * and %. * matches everything, % matches
 237 everything in the current hierarchy.")
 238
 239 (defvoo nnimap-news-groups nil
 240   "IMAP support a news-like mode, also known as bulletin board mode,
 241 where replies is sent via IMAP instead of SMTP.
 242
 243 This variable should contain a regexp matching groups where you wish
 244 replies to be stored to the mailbox directly.
 245
 246 Example:
 247   '(\"^[^I][^N][^B][^O][^X].*$\")
 248
 249 This will match all groups not beginning with \"INBOX\".
 250
 251 Note that there is nothing technically different between mail-like and
 252 news-like mailboxes.  If you wish to have a group with todo items or
 253 similar which you wouldn't want to set up a mailing list for, you can
 254 use this to make replies go directly to the group.")
 255
 256 (defvoo nnimap-expunge-search-string "UID %s NOT SINCE %s"
 257   "*IMAP search command to use for articles that are to be expired.
 258 The first %s is replaced by a UID set of articles to search on,
 259 and the second %s is replaced by a date criterium.
 260
 261 One useful (and perhaps the only useful) value to change this to would
 262 be `UID %s NOT SENTSINCE %s' to make nnimap use the Date: header
 263 instead of the internal date of messages.  See section 6.4.4 of RFC
 264 2060 for more information on valid strings.")
 265
 266 (defvoo nnimap-importantize-dormant t
 267   "*If non-nil, mark \"dormant\" articles as \"ticked\" for other IMAP clients.
 268 Note that within Gnus, dormant articles will still (only) be
 269 marked as ticked.  This is to make \"dormant\" articles stand out,
 270 just like \"ticked\" articles, in other IMAP clients.")
 271
 272 (defvoo nnimap-server-address nil
 273   "Obsolete.  Use `nnimap-address'.")
 274
 275 (defcustom nnimap-authinfo-file "~/.authinfo"
 276   "Authorization information for IMAP servers.  In .netrc format."
 277   :type
 278   '(choice file
 279            (repeat :tag "Entries"
 280                    :menu-tag "Inline"
 281                    (list :format "%v"
 282                          :value ("" ("login" . "") ("password" . ""))
 283                          (string :tag "Host")
 284                          (checklist :inline t
 285                                     (cons :format "%v"
 286                                           (const :format "" "login")
 287                                           (string :format "Login: %v"))
 288                                     (cons :format "%v"
 289                                           (const :format "" "password")
 290                                           (string :format "Password: %v")))))))
 291
 292 (defcustom nnimap-prune-cache t
 293   "If non-nil, nnimap check whether articles still exist on server before using data stored in NOV cache."
 294   :type 'boolean)
 295
 296 (defvar nnimap-request-list-method 'imap-mailbox-list
 297   "Method to use to request a list of all folders from the server.
 298 If this is 'imap-mailbox-lsub, then use a server-side subscription list to
 299 restrict visible folders.")
 300
 301 ;; Internal variables:
 302
 303 (defvar nnimap-debug nil
 304   "Name of buffer to record debugging info.
 305 For example: (setq nnimap-debug \"*nnimap-debug*\")")
 306 (defvar nnimap-current-move-server nil)
 307 (defvar nnimap-current-move-group nil)
 308 (defvar nnimap-current-move-article nil)
 309 (defvar nnimap-length)
 310 (defvar nnimap-progress-chars '(?| ?/ ?- ?\\))
 311 (defvar nnimap-progress-how-often 20)
 312 (defvar nnimap-counter)
 313 (defvar nnimap-callback-callback-function nil
 314   "Gnus callback the nnimap asynchronous callback should call.")
 315 (defvar nnimap-callback-buffer nil
 316   "Which buffer the asynchronous article prefetch callback should work in.")
 317 (defvar nnimap-server-buffer-alist nil) ;; Map server name to buffers.
 318 (defvar nnimap-current-server nil) ;; Current server
 319 (defvar nnimap-server-buffer nil) ;; Current servers' buffer
 320
 321 \f
 322
 323 (nnoo-define-basics nnimap)
 324
 325 ;; Utility functions:
 326
 327 (defsubst nnimap-get-server-buffer (server)
 328   "Return buffer for SERVER, if nil use current server."
 329   (cadr (assoc (or server nnimap-current-server) nnimap-server-buffer-alist)))
 330
 331 (defun nnimap-possibly-change-server (server)
 332   "Return buffer for SERVER, changing the current server as a side-effect.
 333 If SERVER is nil, uses the current server."
 334   (setq nnimap-current-server (or server nnimap-current-server)
 335         nnimap-server-buffer (nnimap-get-server-buffer nnimap-current-server)))
 336
 337 (defun nnimap-verify-uidvalidity (group server)
 338   "Verify stored uidvalidity match current one in GROUP on SERVER."
 339   (let* ((gnusgroup (gnus-group-prefixed-name
 340                      group (gnus-server-to-method
 341                             (format "nnimap:%s" server))))
 342          (new-uidvalidity (imap-mailbox-get 'uidvalidity))
 343          (old-uidvalidity (gnus-group-get-parameter gnusgroup 'uidvalidity))
 344          (dir (file-name-as-directory (expand-file-name nnimap-directory)))
 345          (nameuid (nnheader-translate-file-chars
 346                    (concat nnimap-nov-file-name
 347                            (if (equal server "")
 348                                "unnamed"
 349                              server) "." group "." old-uidvalidity
 350                            nnimap-nov-file-name-suffix) t))
 351          (file (if (or nnmail-use-long-file-names
 352                        (file-exists-p (expand-file-name nameuid dir)))
 353                    (expand-file-name nameuid dir)
 354                  (expand-file-name
 355                   (mm-encode-coding-string
 356                    (nnheader-replace-chars-in-string nameuid ?. ?/)
 357                    nnmail-pathname-coding-system)
 358                   dir))))
 359     (if old-uidvalidity
 360         (if (not (equal old-uidvalidity new-uidvalidity))
 361             ;; uidvalidity clash
 362             (gnus-delete-file file)
 363           (gnus-group-set-parameter gnusgroup 'uidvalidity new-uidvalidity)
 364           t)
 365       (gnus-group-add-parameter gnusgroup (cons 'uidvalidity new-uidvalidity))
 366       t)))
 367
 368 (defun nnimap-before-find-minmax-bugworkaround ()
 369   "Function called before iterating through mailboxes with
 370 `nnimap-find-minmax-uid'."
 371   ;; XXX this is for UoW imapd problem, it doesn't notice new mail in
 372   ;; currently selected mailbox without a re-select/examine.
 373   (or (null (imap-current-mailbox nnimap-server-buffer))
 374       (imap-mailbox-unselect nnimap-server-buffer)))
 375
 376 (defun nnimap-find-minmax-uid (group &optional examine)
 377   "Find lowest and highest active article nummber in GROUP.
 378 If EXAMINE is non-nil the group is selected read-only."
 379   (with-current-buffer nnimap-server-buffer
 380     (when (imap-mailbox-select group examine)
 381       (let (minuid maxuid)
 382         (when (> (imap-mailbox-get 'exists) 0)
 383           (imap-fetch "1,*" "UID" nil 'nouidfetch)
 384           (imap-message-map (lambda (uid Uid)
 385                               (setq minuid (if minuid (min minuid uid) uid)
 386                                     maxuid (if maxuid (max maxuid uid) uid)))
 387                             'UID))
 388         (list (imap-mailbox-get 'exists) minuid maxuid)))))
 389
 390 (defun nnimap-possibly-change-group (group &optional server)
 391   "Make GROUP the current group, and SERVER the current server."
 392   (when (nnimap-possibly-change-server server)
 393     (with-current-buffer nnimap-server-buffer
 394       (if (or (null group) (imap-current-mailbox-p group))
 395           imap-current-mailbox
 396         (if (imap-mailbox-select group)
 397             (if (or (nnimap-verify-uidvalidity
 398                      group (or server nnimap-current-server))
 399                     (zerop (imap-mailbox-get 'exists group))
 400                     t ;; for OGnus to see if ignoring uidvalidity
 401                     ;; changes has any bad effects.
 402                     (yes-or-no-p
 403                      (format
 404                       "nnimap: Group %s is not uidvalid.  Continue? " group)))
 405                 imap-current-mailbox
 406               (imap-mailbox-unselect)
 407               (error "nnimap: Group %s is not uid-valid" group))
 408           (nnheader-report 'nnimap (imap-error-text)))))))
 409
 410 (defun nnimap-replace-whitespace (string)
 411   "Return STRING with all whitespace replaced with space."
 412   (when string
 413     (while (string-match "[\r\n\t]+" string)
 414       (setq string (replace-match " " t t string)))
 415     string))
 416
 417 ;; Required backend functions
 418
 419 (defun nnimap-retrieve-headers-progress ()
 420   "Hook to insert NOV line for current article into `nntp-server-buffer'."
 421   (and (numberp nnmail-large-newsgroup)
 422        (zerop (% (incf nnimap-counter) nnimap-progress-how-often))
 423        (> nnimap-length nnmail-large-newsgroup)
 424        (nnheader-message 6 "nnimap: Retrieving headers... %c"
 425                          (nth (/ (% nnimap-counter
 426                                     (* (length nnimap-progress-chars)
 427                                        nnimap-progress-how-often))
 428                                  nnimap-progress-how-often)
 429                               nnimap-progress-chars)))
 430   (with-current-buffer nntp-server-buffer
 431     (let (headers lines chars uid mbx)
 432       (with-current-buffer nnimap-server-buffer
 433         (setq uid imap-current-message
 434               mbx imap-current-mailbox
 435               headers (nnimap-demule
 436                        (if (imap-capability 'IMAP4rev1)
 437                       ;; xxx don't just use car? alist doesn't contain
 438                            ;; anything else now, but it might...
 439                            (nth 2 (car (imap-message-get uid 'BODYDETAIL)))
 440                          (imap-message-get uid 'RFC822.HEADER)))
 441               lines (imap-body-lines (imap-message-body imap-current-message))
 442               chars (imap-message-get imap-current-message 'RFC822.SIZE)))
 443       (nnheader-insert-nov
 444        (with-temp-buffer
 445          (buffer-disable-undo)
 446          (insert headers)
 447          (nnheader-ms-strip-cr)
 448          (nnheader-fold-continuation-lines)
 449          (subst-char-in-region (point-min) (point-max) ?\t ? )
 450          (let ((head (nnheader-parse-head 'naked)))
 451            (mail-header-set-number head uid)
 452            (mail-header-set-chars head chars)
 453            (mail-header-set-lines head lines)
 454            (mail-header-set-xref
 455             head (format "%s %s:%d" (system-name) mbx uid))
 456            head))))))
 457
 458 (defun nnimap-retrieve-which-headers (articles fetch-old)
 459   "Get a range of articles to fetch based on ARTICLES and FETCH-OLD."
 460   (with-current-buffer nnimap-server-buffer
 461     (if (numberp (car-safe articles))
 462         (imap-search
 463          (concat "UID "
 464                  (imap-range-to-message-set
 465                   (gnus-compress-sequence
 466                    (append (gnus-uncompress-sequence
 467                             (and fetch-old
 468                                  (cons (if (numberp fetch-old)
 469                                            (max 1 (- (car articles) fetch-old))
 470                                          1)
 471                                        (1- (car articles)))))
 472                            articles)))))
 473       (mapcar (lambda (msgid)
 474                 (imap-search
 475                  (format "HEADER Message-Id \"%s\"" msgid)))
 476               articles))))
 477
 478 (defun nnimap-group-overview-filename (group server)
 479   "Make pathname for GROUP on SERVER."
 480   (let* ((dir (file-name-as-directory (expand-file-name nnimap-directory)))
 481          (uidvalidity (gnus-group-get-parameter
 482                        (gnus-group-prefixed-name
 483                         group (gnus-server-to-method
 484                                (format "nnimap:%s" server)))
 485                        'uidvalidity))
 486          (name (nnheader-translate-file-chars
 487                 (concat nnimap-nov-file-name
 488                         (if (equal server "")
 489                             "unnamed"
 490                           server) "." group nnimap-nov-file-name-suffix) t))
 491          (nameuid (nnheader-translate-file-chars
 492                    (concat nnimap-nov-file-name
 493                            (if (equal server "")
 494                                "unnamed"
 495                              server) "." group "." uidvalidity
 496                            nnimap-nov-file-name-suffix) t))
 497          (oldfile (if (or nnmail-use-long-file-names
 498                           (file-exists-p (expand-file-name name dir)))
 499                       (expand-file-name name dir)
 500                     (expand-file-name
 501                      (mm-encode-coding-string
 502                       (nnheader-replace-chars-in-string name ?. ?/)
 503                       nnmail-pathname-coding-system)
 504                      dir)))
 505          (newfile (if (or nnmail-use-long-file-names
 506                           (file-exists-p (expand-file-name nameuid dir)))
 507                       (expand-file-name nameuid dir)
 508                     (expand-file-name
 509                      (mm-encode-coding-string
 510                       (nnheader-replace-chars-in-string nameuid ?. ?/)
 511                       nnmail-pathname-coding-system)
 512                      dir))))
 513     (when (and (file-exists-p oldfile) (not (file-exists-p newfile)))
 514       (message "nnimap: Upgrading novcache filename...")
 515       (sit-for 1)
 516       (gnus-make-directory (file-name-directory newfile))
 517       (unless (ignore-errors (rename-file oldfile newfile) t)
 518         (if (ignore-errors (copy-file oldfile newfile) t)
 519             (delete-file oldfile)
 520           (error "Can't rename `%s' to `%s'" oldfile newfile))))
 521     newfile))
 522
 523 (defun nnimap-retrieve-headers-from-file (group server)
 524   (with-current-buffer nntp-server-buffer
 525     (let ((nov (nnimap-group-overview-filename group server)))
 526       (when (file-exists-p nov)
 527         (mm-insert-file-contents nov)
 528         (set-buffer-modified-p nil)
 529         (let ((min (ignore-errors (goto-char (point-min))
 530                                   (read (current-buffer))))
 531               (max (ignore-errors (goto-char (point-max))
 532                                   (forward-line -1)
 533                                   (read (current-buffer)))))
 534           (if (and (numberp min) (numberp max))
 535               (cons min max)
 536             ;; junk, remove it, it's saved later
 537             (erase-buffer)
 538             nil))))))
 539
 540 (defun nnimap-retrieve-headers-from-server (articles group server)
 541   (with-current-buffer nnimap-server-buffer
 542     (let ((imap-fetch-data-hook '(nnimap-retrieve-headers-progress))
 543           (nnimap-length (gnus-range-length articles))
 544           (nnimap-counter 0))
 545       (imap-fetch (imap-range-to-message-set articles)
 546                   (concat "(UID RFC822.SIZE BODY "
 547                           (let ((headers
 548                                  (append '(Subject From Date Message-Id
 549                                                    References In-Reply-To Xref)
 550                                          (copy-sequence
 551                                           nnmail-extra-headers))))
 552                             (if (imap-capability 'IMAP4rev1)
 553                                 (format "BODY.PEEK[HEADER.FIELDS %s])" headers)
 554                               (format "RFC822.HEADER.LINES %s)" headers)))))
 555       (and (numberp nnmail-large-newsgroup)
 556            (> nnimap-length nnmail-large-newsgroup)
 557            (nnheader-message 6 "nnimap: Retrieving headers...done")))))
 558
 559 (defun nnimap-dont-use-nov-p (group server)
 560   (or gnus-nov-is-evil nnimap-nov-is-evil
 561       (unless (and (gnus-make-directory
 562                     (file-name-directory
 563                      (nnimap-group-overview-filename group server)))
 564                    (file-writable-p
 565                     (nnimap-group-overview-filename group server)))
 566         (message "nnimap: Nov cache not writable, %s"
 567                  (nnimap-group-overview-filename group server)))))
 568
 569 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 570   (when (nnimap-possibly-change-group group server)
 571     (with-current-buffer nntp-server-buffer
 572       (erase-buffer)
 573       (if (nnimap-dont-use-nov-p group server)
 574           (nnimap-retrieve-headers-from-server
 575            (gnus-compress-sequence articles) group server)
 576         (let (uids cached low high)
 577           (when (setq uids (nnimap-retrieve-which-headers articles fetch-old)
 578                       low (car uids)
 579                       high (car (last uids)))
 580             (if (setq cached (nnimap-retrieve-headers-from-file group server))
 581                 (progn
 582                   ;; fetch articles with uids before cache block
 583                   (when (< low (car cached))
 584                     (goto-char (point-min))
 585                     (nnimap-retrieve-headers-from-server
 586                      (cons low (1- (car cached))) group server))
 587                   ;; fetch articles with uids after cache block
 588                   (when (> high (cdr cached))
 589                     (goto-char (point-max))
 590                     (nnimap-retrieve-headers-from-server
 591                      (cons (1+ (cdr cached)) high) group server))
 592                   (when nnimap-prune-cache
 593               ;; remove nov's for articles which has expired on server
 594                     (goto-char (point-min))
 595                     (dolist (uid (gnus-set-difference articles uids))
 596                       (when (re-search-forward (format "^%d\t" uid) nil t)
 597                         (gnus-delete-line)))))
 598               ;; nothing cached, fetch whole range from server
 599               (nnimap-retrieve-headers-from-server
 600                (cons low high) group server))
 601             (when (buffer-modified-p)
 602               (nnmail-write-region
 603                1 (point-max) (nnimap-group-overview-filename group server)
 604                nil 'nomesg))
 605             (nnheader-nov-delete-outside-range low high))))
 606       'nov)))
 607
 608 (defun nnimap-open-connection (server)
 609   (if (not (imap-open nnimap-address nnimap-server-port nnimap-stream
 610                       nnimap-authenticator nnimap-server-buffer))
 611       (nnheader-report 'nnimap "Can't open connection to server %s" server)
 612     (unless (or (imap-capability 'IMAP4 nnimap-server-buffer)
 613                 (imap-capability 'IMAP4rev1 nnimap-server-buffer))
 614       (imap-close nnimap-server-buffer)
 615       (nnheader-report 'nnimap "Server %s is not IMAP4 compliant" server))
 616     (let* ((list (gnus-parse-netrc nnimap-authinfo-file))
 617            (port (if nnimap-server-port
 618                      (int-to-string nnimap-server-port)
 619                    "imap"))
 620            (alist (gnus-netrc-machine list (or nnimap-server-address
 621                                                nnimap-address server)
 622                                       port "imap"))
 623            (user (gnus-netrc-get alist "login"))
 624            (passwd (gnus-netrc-get alist "password")))
 625       (if (imap-authenticate user passwd nnimap-server-buffer)
 626           (prog1
 627               (push (list server nnimap-server-buffer)
 628                     nnimap-server-buffer-alist)
 629             (nnimap-possibly-change-server server))
 630         (imap-close nnimap-server-buffer)
 631         (kill-buffer nnimap-server-buffer)
 632         (nnheader-report 'nnimap "Could not authenticate to %s" server)))))
 633
 634 (deffoo nnimap-open-server (server &optional defs)
 635   (nnheader-init-server-buffer)
 636   (if (nnimap-server-opened server)
 637       t
 638     (unless (assq 'nnimap-server-buffer defs)
 639       (push (list 'nnimap-server-buffer (concat " *nnimap* " server)) defs))
 640     ;; translate `nnimap-server-address' to `nnimap-address' in defs
 641     ;; for people that configured nnimap with a very old version
 642     (unless (assq 'nnimap-address defs)
 643       (if (assq 'nnimap-server-address defs)
 644           (push (list 'nnimap-address
 645                       (cadr (assq 'nnimap-server-address defs))) defs)
 646         (push (list 'nnimap-address server) defs)))
 647     (nnoo-change-server 'nnimap server defs)
 648     (with-current-buffer (get-buffer-create nnimap-server-buffer)
 649       (nnoo-change-server 'nnimap server defs))
 650     (or (and nnimap-server-buffer
 651              (imap-opened nnimap-server-buffer))
 652         (nnimap-open-connection server))))
 653
 654 (deffoo nnimap-server-opened (&optional server)
 655   "Whether SERVER is opened.
 656 If SERVER is the current virtual server, and the connection to the
 657 physical server is alive, this function return a non-nil value.  If
 658 SERVER is nil, it is treated as the current server."
 659   ;; clean up autologouts??
 660   (and (or server nnimap-current-server)
 661        (nnoo-server-opened 'nnimap (or server nnimap-current-server))
 662        (imap-opened (nnimap-get-server-buffer server))))
 663
 664 (deffoo nnimap-close-server (&optional server)
 665   "Close connection to server and free all resources connected to it.
 666 Return nil if the server couldn't be closed for some reason."
 667   (let ((server (or server nnimap-current-server)))
 668     (when (or (nnimap-server-opened server)
 669               (imap-opened (nnimap-get-server-buffer server)))
 670       (imap-close (nnimap-get-server-buffer server))
 671       (kill-buffer (nnimap-get-server-buffer server))
 672       (setq nnimap-server-buffer nil
 673             nnimap-current-server nil
 674             nnimap-server-buffer-alist
 675             (delq server nnimap-server-buffer-alist)))
 676     (nnoo-close-server 'nnimap server)))
 677
 678 (deffoo nnimap-request-close ()
 679   "Close connection to all servers and free all resources that the backend have reserved.
 680 All buffers that have been created by that
 681 backend should be killed.  (Not the nntp-server-buffer, though.) This
 682 function is generally only called when Gnus is shutting down."
 683   (mapcar (lambda (server) (nnimap-close-server (car server)))
 684           nnimap-server-buffer-alist)
 685   (setq nnimap-server-buffer-alist nil))
 686
 687 (deffoo nnimap-status-message (&optional server)
 688   "This function returns the last error message from server."
 689   (when (nnimap-possibly-change-server server)
 690     (nnoo-status-message 'nnimap server)))
 691
 692 (defun nnimap-demule (string)
 693   (funcall (if (and (fboundp 'string-as-multibyte)
 694                     (subrp (symbol-function 'string-as-multibyte)))
 695                'string-as-multibyte
 696              'identity)
 697            (or string "")))
 698
 699 (defun nnimap-callback ()
 700   (remove-hook 'imap-fetch-data-hook 'nnimap-callback)
 701   (with-current-buffer nnimap-callback-buffer
 702     (insert
 703      (with-current-buffer nnimap-server-buffer
 704        (nnimap-demule
 705         (if (imap-capability 'IMAP4rev1)
 706             ;; xxx don't just use car? alist doesn't contain
 707             ;; anything else now, but it might...
 708             (nth 2 (car (imap-message-get (imap-current-message) 'BODYDETAIL)))
 709           (imap-message-get (imap-current-message) 'RFC822)))))
 710     (nnheader-ms-strip-cr)
 711     (funcall nnimap-callback-callback-function t)))
 712
 713 (defun nnimap-request-article-part (article part prop &optional
 714                                             group server to-buffer detail)
 715   (when (nnimap-possibly-change-group group server)
 716     (let ((article (if (stringp article)
 717                        (car-safe (imap-search
 718                                   (format "HEADER Message-Id \"%s\"" article)
 719                                   nnimap-server-buffer))
 720                      article)))
 721       (when article
 722         (gnus-message 10 "nnimap: Fetching (part of) article %d..." article)
 723         (if (not nnheader-callback-function)
 724             (with-current-buffer (or to-buffer nntp-server-buffer)
 725               (erase-buffer)
 726               (let ((data (imap-fetch article part prop nil
 727                                       nnimap-server-buffer)))
 728                 (insert (nnimap-demule (if detail
 729                                            (nth 2 (car data))
 730                                          data))))
 731               (nnheader-ms-strip-cr)
 732               (gnus-message 10 "nnimap: Fetching (part of) article %d...done"
 733                             article)
 734               (if (bobp)
 735                   (nnheader-report 'nnimap "No such article: %s"
 736                                    (imap-error-text nnimap-server-buffer))
 737                 (cons group article)))
 738           (add-hook 'imap-fetch-data-hook 'nnimap-callback)
 739           (setq nnimap-callback-callback-function nnheader-callback-function
 740                 nnimap-callback-buffer nntp-server-buffer)
 741           (imap-fetch-asynch article part nil nnimap-server-buffer)
 742           (cons group article))))))
 743
 744 (deffoo nnimap-asynchronous-p ()
 745   t)
 746
 747 (deffoo nnimap-request-article (article &optional group server to-buffer)
 748   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 749       (nnimap-request-article-part
 750        article "BODY.PEEK[]" 'BODYDETAIL group server to-buffer 'detail)
 751     (nnimap-request-article-part
 752      article "RFC822.PEEK" 'RFC822 group server to-buffer)))
 753
 754 (deffoo nnimap-request-head (article &optional group server to-buffer)
 755   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 756       (nnimap-request-article-part
 757        article "BODY.PEEK[HEADER]" 'BODYDETAIL group server to-buffer 'detail)
 758     (nnimap-request-article-part
 759      article "RFC822.HEADER" 'RFC822.HEADER group server to-buffer)))
 760
 761 (deffoo nnimap-request-body (article &optional group server to-buffer)
 762   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 763       (nnimap-request-article-part
 764        article "BODY.PEEK[TEXT]" 'BODYDETAIL group server to-buffer 'detail)
 765     (nnimap-request-article-part
 766      article "RFC822.TEXT.PEEK" 'RFC822.TEXT group server to-buffer)))
 767
 768 (deffoo nnimap-request-group (group &optional server fast)
 769   (nnimap-request-update-info-internal
 770    group
 771    (gnus-get-info (gnus-group-prefixed-name
 772                    group (gnus-server-to-method (format "nnimap:%s" server))))
 773    server)
 774   (when (nnimap-possibly-change-group group server)
 775     (nnimap-before-find-minmax-bugworkaround)
 776     (let (info)
 777       (cond (fast group)
 778             ((null (setq info (nnimap-find-minmax-uid group t)))
 779              (nnheader-report 'nnimap "Could not get active info for %s"
 780                               group))
 781             (t
 782              (nnheader-insert "211 %d %d %d %s\n" (or (nth 0 info) 0)
 783                               (max 1 (or (nth 1 info) 1))
 784                               (or (nth 2 info) 0) group)
 785              (nnheader-report 'nnimap "Group %s selected" group)
 786              t)))))
 787
 788 (defun nnimap-close-group (group &optional server)
 789   (with-current-buffer nnimap-server-buffer
 790     (when (and (imap-opened)
 791                (nnimap-possibly-change-group group server))
 792       (case nnimap-expunge-on-close
 793         ('always (imap-mailbox-expunge)
 794                  (imap-mailbox-close))
 795         ('ask (if (and (imap-search "DELETED")
 796                        (gnus-y-or-n-p (format
 797                                        "Expunge articles in group `%s'? "
 798                                        imap-current-mailbox)))
 799                   (progn (imap-mailbox-expunge)
 800                          (imap-mailbox-close))
 801                 (imap-mailbox-unselect)))
 802         (t (imap-mailbox-unselect)))
 803       (not imap-current-mailbox))))
 804
 805 (defun nnimap-pattern-to-list-arguments (pattern)
 806   (mapcar (lambda (p)
 807             (cons (car-safe p) (or (cdr-safe p) p)))
 808           (if (and (listp pattern)
 809                    (listp (cdr pattern)))
 810               pattern
 811             (list pattern))))
 812
 813 (deffoo nnimap-request-list (&optional server)
 814   (when (nnimap-possibly-change-server server)
 815     (with-current-buffer nntp-server-buffer
 816       (erase-buffer))
 817     (gnus-message 5 "nnimap: Generating active list%s..."
 818                   (if (> (length server) 0) (concat " for " server) ""))
 819     (nnimap-before-find-minmax-bugworkaround)
 820     (with-current-buffer nnimap-server-buffer
 821       (dolist (pattern (nnimap-pattern-to-list-arguments nnimap-list-pattern))
 822         (dolist (mbx (funcall nnimap-request-list-method
 823                               (cdr pattern) (car pattern)))
 824           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags mbx))
 825               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
 826                 (when info
 827                   (with-current-buffer nntp-server-buffer
 828                     (insert (format "\"%s\" %d %d y\n"
 829                                     mbx (or (nth 2 info) 0)
 830                                     (max 1 (or (nth 1 info) 1)))))))))))
 831     (gnus-message 5 "nnimap: Generating active list%s...done"
 832                   (if (> (length server) 0) (concat " for " server) ""))
 833     t))
 834
 835 (deffoo nnimap-request-post (&optional server)
 836   (let ((success t))
 837     (dolist (mbx (message-unquote-tokens
 838                   (message-tokenize-header
 839                    (message-fetch-field "Newsgroups") ", ")) success)
 840       (let ((to-newsgroup (gnus-group-prefixed-name mbx gnus-command-method)))
 841         (or (gnus-active to-newsgroup)
 842             (gnus-activate-group to-newsgroup)
 843             (if (gnus-y-or-n-p (format "No such group: %s.  Create it? "
 844                                        to-newsgroup))
 845                 (or (and (gnus-request-create-group
 846                           to-newsgroup gnus-command-method)
 847                          (gnus-activate-group to-newsgroup nil nil
 848                                               gnus-command-method))
 849                     (error "Couldn't create group %s" to-newsgroup)))
 850             (error "No such group: %s" to-newsgroup))
 851         (unless (nnimap-request-accept-article mbx (nth 1 gnus-command-method))
 852           (setq success nil))))))
 853
 854 ;; Optional backend functions
 855
 856 (deffoo nnimap-retrieve-groups (groups &optional server)
 857   (when (nnimap-possibly-change-server server)
 858     (gnus-message 5 "nnimap: Checking mailboxes...")
 859     (with-current-buffer nntp-server-buffer
 860       (erase-buffer)
 861       (nnimap-before-find-minmax-bugworkaround)
 862       (dolist (group groups)
 863         (gnus-message 7 "nnimap: Checking mailbox %s" group)
 864         (or (member "\\NoSelect"
 865                     (imap-mailbox-get 'list-flags group nnimap-server-buffer))
 866             (let ((info (nnimap-find-minmax-uid group 'examine)))
 867               (insert (format "\"%s\" %d %d y\n" group
 868                               (or (nth 2 info) 0)
 869                               (max 1 (or (nth 1 info) 1))))))))
 870     (gnus-message 5 "nnimap: Checking mailboxes...done")
 871     'active))
 872
 873 (deffoo nnimap-request-update-info-internal (group info &optional server)
 874   (when (nnimap-possibly-change-group group server)
 875     (when info ;; xxx what does this mean? should we create a info?
 876       (with-current-buffer nnimap-server-buffer
 877         (gnus-message 5 "nnimap: Updating info for %s..."
 878                       (gnus-info-group info))
 879
 880         (when (nnimap-mark-permanent-p 'read)
 881           (let (seen unseen)
 882             ;; read info could contain articles marked unread by other
 883             ;; imap clients!  we correct this
 884             (setq seen (gnus-uncompress-range (gnus-info-read info))
 885                   unseen (imap-search "UNSEEN UNDELETED")
 886                   seen (gnus-set-difference seen unseen)
 887                   ;; seen might lack articles marked as read by other
 888                   ;; imap clients! we correct this
 889                   seen (append seen (imap-search "SEEN"))
 890                   ;; remove dupes
 891                   seen (sort seen '<)
 892                   seen (gnus-compress-sequence seen t)
 893           ;; we can't return '(1) since this isn't a "list of ranges",
 894          ;; and we can't return '((1)) since g-list-of-unread-articles
 895                   ;; is buggy so we return '((1 . 1)).
 896                   seen (if (and (integerp (car seen))
 897                                 (null (cdr seen)))
 898                            (list (cons (car seen) (car seen)))
 899                          seen))
 900             (gnus-info-set-read info seen)))
 901
 902         (mapcar (lambda (pred)
 903                   (when (and (nnimap-mark-permanent-p (cdr pred))
 904                              (member (nnimap-mark-to-flag (cdr pred))
 905                                      (imap-mailbox-get 'flags)))
 906                     (gnus-info-set-marks
 907                      info
 908                      (nnimap-update-alist-soft
 909                       (cdr pred)
 910                       (gnus-compress-sequence
 911                        (imap-search (nnimap-mark-to-predicate (cdr pred))))
 912                       (gnus-info-marks info))
 913                      t)))
 914                 gnus-article-mark-lists)
 915
 916         (when nnimap-importantize-dormant
 917       ;; nnimap mark dormant article as ticked too (for other clients)
 918           ;; so we remove that mark for gnus since we support dormant
 919           (gnus-info-set-marks
 920            info
 921            (nnimap-update-alist-soft
 922             'tick
 923             (gnus-remove-from-range
 924              (cdr-safe (assoc 'tick (gnus-info-marks info)))
 925              (cdr-safe (assoc 'dormant (gnus-info-marks info))))
 926             (gnus-info-marks info))
 927            t))
 928
 929         (gnus-message 5 "nnimap: Updating info for %s...done"
 930                       (gnus-info-group info))
 931
 932         info))))
 933
 934 (deffoo nnimap-request-type (group &optional article)
 935   (if (and nnimap-news-groups (string-match nnimap-news-groups group))
 936       'news
 937     'mail))
 938
 939 (deffoo nnimap-request-set-mark (group actions &optional server)
 940   (when (nnimap-possibly-change-group group server)
 941     (with-current-buffer nnimap-server-buffer
 942       (let (action)
 943         (gnus-message 7 "nnimap: Setting marks in %s..." group)
 944         (while (setq action (pop actions))
 945           (let ((range (nth 0 action))
 946                 (what  (nth 1 action))
 947                 (cmdmarks (nth 2 action))
 948                 marks)
 949             ;; cache flags are pointless on the server
 950             (setq cmdmarks (delq 'cache cmdmarks))
 951             (when nnimap-importantize-dormant
 952               ;; flag dormant articles as ticked
 953               (if (memq 'dormant cmdmarks)
 954                   (setq cmdmarks (cons 'tick cmdmarks))))
 955             ;; remove stuff we are forbidden to store
 956             (mapcar (lambda (mark)
 957                       (if (imap-message-flag-permanent-p
 958                            (nnimap-mark-to-flag mark))
 959                           (setq marks (cons mark marks))))
 960                     cmdmarks)
 961             (when (and range marks)
 962               (cond ((eq what 'del)
 963                      (imap-message-flags-del
 964                       (imap-range-to-message-set range)
 965                       (nnimap-mark-to-flag marks nil t)))
 966                     ((eq what 'add)
 967                      (imap-message-flags-add
 968                       (imap-range-to-message-set range)
 969                       (nnimap-mark-to-flag marks nil t)))
 970                     ((eq what 'set)
 971                      (imap-message-flags-set
 972                       (imap-range-to-message-set range)
 973                       (nnimap-mark-to-flag marks nil t)))))))
 974         (gnus-message 7 "nnimap: Setting marks in %s...done" group))))
 975   nil)
 976
 977 (defun nnimap-split-fancy ()
 978   "Like nnmail-split-fancy, but uses nnimap-split-fancy."
 979   (let ((nnmail-split-fancy nnimap-split-fancy))
 980     (nnmail-split-fancy)))
 981
 982 (defun nnimap-split-to-groups (rules)
 983   ;; tries to match all rules in nnimap-split-rule against content of
 984   ;; nntp-server-buffer, returns a list of groups that matched.
 985   (with-current-buffer nntp-server-buffer
 986     ;; Fold continuation lines.
 987     (goto-char (point-min))
 988     (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
 989       (replace-match " " t t))
 990     (if (functionp rules)
 991         (funcall rules)
 992       (let (to-groups regrepp)
 993         (catch 'split-done
 994           (dolist (rule rules to-groups)
 995             (let ((group (car rule))
 996                   (regexp (cadr rule)))
 997               (goto-char (point-min))
 998               (when (and (if (stringp regexp)
 999                              (progn
1000                                (setq regrepp (string-match "\\\\[0-9&]" group))
1001                                (re-search-forward regexp nil t))
1002                            (funcall regexp group))
1003                  ;; Don't enter the article into the same group twice.
1004                          (not (assoc group to-groups)))
1005                 (push (if regrepp
1006                           (nnmail-expand-newtext group)
1007                         group)
1008                       to-groups)
1009                 (or nnimap-split-crosspost
1010                     (throw 'split-done to-groups))))))))))
1011
1012 (defun nnimap-assoc-match (key alist)
1013   (let (element)
1014     (while (and alist (not element))
1015       (if (string-match (car (car alist)) key)
1016           (setq element (car alist)))
1017       (setq alist (cdr alist)))
1018     element))
1019
1020 (defun nnimap-split-find-rule (server inbox)
1021   (if (and (listp nnimap-split-rule) (listp (car nnimap-split-rule))
1022            (list (cdar nnimap-split-rule)) (listp (cadar nnimap-split-rule)))
1023       ;; extended format
1024       (cadr (nnimap-assoc-match inbox (cdr (nnimap-assoc-match
1025                                             server nnimap-split-rule))))
1026     nnimap-split-rule))
1027
1028 (defun nnimap-split-find-inbox (server)
1029   (if (listp nnimap-split-inbox)
1030       nnimap-split-inbox
1031     (list nnimap-split-inbox)))
1032
1033 (defun nnimap-split-articles (&optional group server)
1034   (when (nnimap-possibly-change-server server)
1035     (with-current-buffer nnimap-server-buffer
1036       (let (rule inbox removeorig (inboxes (nnimap-split-find-inbox server)))
1037         ;; iterate over inboxes
1038         (while (and (setq inbox (pop inboxes))
1039                     (nnimap-possibly-change-group inbox)) ;; SELECT
1040           ;; find split rule for this server / inbox
1041           (when (setq rule (nnimap-split-find-rule server inbox))
1042             ;; iterate over articles
1043             (dolist (article (imap-search nnimap-split-predicate))
1044               (when (nnimap-request-head article)
1045                 ;; copy article to right group(s)
1046                 (setq removeorig nil)
1047                 (dolist (to-group (nnimap-split-to-groups rule))
1048                   (cond ((eq to-group 'junk)
1049                          (message "IMAP split removed %s:%s:%d" server inbox
1050                                   article)
1051                          (setq removeorig t))
1052                         ((imap-message-copy (number-to-string article)
1053                                             to-group nil 'nocopyuid)
1054                          (message "IMAP split moved %s:%s:%d to %s" server
1055                                   inbox article to-group)
1056                          (setq removeorig t)
1057                         ;; Add the group-art list to the history list.
1058                          (push (list (cons to-group 0)) nnmail-split-history))
1059                         (t
1060                          (message "IMAP split failed to move %s:%s:%d to %s"
1061                                   server inbox article to-group))))
1062              ;; remove article if it was successfully copied somewhere
1063                 (and removeorig
1064                      (imap-message-flags-add (format "%d" article)
1065                                              "\\Seen \\Deleted")))))
1066           (when (imap-mailbox-select inbox) ;; just in case
1067        ;; todo: UID EXPUNGE (if available) to remove splitted articles
1068             (imap-mailbox-expunge)
1069             (imap-mailbox-close)))
1070         t))))
1071
1072 (deffoo nnimap-request-scan (&optional group server)
1073   (nnimap-split-articles group server))
1074
1075 (deffoo nnimap-request-newgroups (date &optional server)
1076   (when (nnimap-possibly-change-server server)
1077     (with-current-buffer nntp-server-buffer
1078       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s..."
1079                     (if (> (length server) 0) " on " "") server)
1080       (erase-buffer)
1081       (nnimap-before-find-minmax-bugworkaround)
1082       (dolist (pattern (nnimap-pattern-to-list-arguments
1083                         nnimap-list-pattern))
1084         (dolist (mbx (imap-mailbox-lsub "*" (car pattern) nil
1085                                         nnimap-server-buffer))
1086           (or (catch 'found
1087                 (dolist (mailbox (imap-mailbox-get 'list-flags mbx
1088                                                    nnimap-server-buffer))
1089                   (if (string= (downcase mailbox) "\\noselect")
1090                       (throw 'found t)))
1091                 nil)
1092               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1093                 (when info
1094                   (insert (format "\"%s\" %d %d y\n"
1095                                   mbx (or (nth 2 info) 0)
1096                                   (max 1 (or (nth 1 info) 1)))))))))
1097       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s...done"
1098                     (if (> (length server) 0) " on " "") server))
1099     t))
1100
1101 (deffoo nnimap-request-create-group (group &optional server args)
1102   (when (nnimap-possibly-change-server server)
1103     (or (imap-mailbox-status group 'uidvalidity nnimap-server-buffer)
1104         (imap-mailbox-create group nnimap-server-buffer))))
1105
1106 (defun nnimap-time-substract (time1 time2)
1107   "Return TIME for TIME1 - TIME2."
1108   (let* ((ms (- (car time1) (car time2)))
1109          (ls (- (nth 1 time1) (nth 1 time2))))
1110     (if (< ls 0)
1111         (list (- ms 1) (+ (expt 2 16) ls))
1112       (list ms ls))))
1113
1114 (defun nnimap-date-days-ago (daysago)
1115   "Return date, in format \"3-Aug-1998\", for DAYSAGO days ago."
1116   (let* ((time (nnimap-time-substract (current-time) (days-to-time daysago)))
1117          (date (format-time-string
1118                 (format "%%d-%s-%%Y"
1119                         (capitalize (car (rassoc (nth 4 (decode-time time))
1120                                                  parse-time-months))))
1121                 time)))
1122     (if (eq ?0 (string-to-char date))
1123         (substring date 1)
1124       date)))
1125
1126 (defun nnimap-request-expire-articles-progress ()
1127   (gnus-message 5 "nnimap: Marking article %d for deletion..."
1128                 imap-current-message))
1129
1130
1131 (defun nnimap-expiry-target (arts group server)
1132   (unless (eq nnmail-expiry-target 'delete)
1133     (with-current-buffer nntp-server-buffer
1134       (dolist (art (gnus-uncompress-sequence arts))
1135         (nnimap-request-article art group server)
1136         ;; hints for optimization in `nnimap-request-accept-article'
1137         (let ((nnimap-current-move-article art)
1138               (nnimap-current-move-group group)
1139               (nnimap-current-move-server server))
1140           (nnmail-expiry-target-group nnmail-expiry-target group))))))
1141
1142 ;; Notice that we don't actually delete anything, we just mark them deleted.
1143 (deffoo nnimap-request-expire-articles (articles group &optional server force)
1144   (let ((artseq (gnus-compress-sequence articles)))
1145     (when (and artseq (nnimap-possibly-change-group group server))
1146       (with-current-buffer nnimap-server-buffer
1147         (if force
1148             (progn
1149               (nnimap-expiry-target artseq group server)
1150               (when (imap-message-flags-add (imap-range-to-message-set artseq)
1151                                             "\\Deleted")
1152                 (setq articles nil)))
1153           (let ((days (or (and nnmail-expiry-wait-function
1154                                (funcall nnmail-expiry-wait-function group))
1155                           nnmail-expiry-wait)))
1156             (cond ((eq days 'immediate)
1157                    (nnimap-expiry-target artseq group server)
1158                    (when (imap-message-flags-add
1159                           (imap-range-to-message-set artseq) "\\Deleted")
1160                      (setq articles nil)))
1161                   ((numberp days)
1162                    (let ((oldarts (imap-search
1163                                    (format nnimap-expunge-search-string
1164                                            (imap-range-to-message-set artseq)
1165                                            (nnimap-date-days-ago days))))
1166                          (imap-fetch-data-hook
1167                           '(nnimap-request-expire-articles-progress)))
1168                      (nnimap-expiry-target oldarts group server)
1169                      (and oldarts
1170                           (imap-message-flags-add
1171                            (imap-range-to-message-set
1172                             (gnus-compress-sequence oldarts))
1173                            "\\Deleted")
1174                           (setq articles (gnus-set-difference
1175                                           articles oldarts)))))))))))
1176   ;; return articles not deleted
1177   articles)
1178
1179 (deffoo nnimap-request-move-article (article group server
1180                                              accept-form &optional last)
1181   (when (nnimap-possibly-change-server server)
1182     (save-excursion
1183       (let ((buf (get-buffer-create " *nnimap move*"))
1184             (nnimap-current-move-article article)
1185             (nnimap-current-move-group group)
1186             (nnimap-current-move-server nnimap-current-server)
1187             result)
1188         (and (nnimap-request-article article group server)
1189              (save-excursion
1190                (set-buffer buf)
1191                (buffer-disable-undo (current-buffer))
1192                (insert-buffer-substring nntp-server-buffer)
1193                (setq result (eval accept-form))
1194                (kill-buffer buf)
1195                result)
1196              (nnimap-request-expire-articles (list article) group server t))
1197         result))))
1198
1199 (deffoo nnimap-request-accept-article (group &optional server last)
1200   (when (nnimap-possibly-change-server server)
1201     (let (uid)
1202       (if (setq uid
1203                 (if (string= nnimap-current-server nnimap-current-move-server)
1204                   ;; moving article within same server, speed it up...
1205                     (and (nnimap-possibly-change-group
1206                           nnimap-current-move-group)
1207                          (imap-message-copy (number-to-string
1208                                              nnimap-current-move-article)
1209                                             group 'dontcreate nil
1210                                             nnimap-server-buffer))
1211                   (with-current-buffer (current-buffer)
1212                     (goto-char (point-min))
1213                   ;; remove any 'From blabla' lines, some IMAP servers
1214                     ;; reject the entire message otherwise.
1215                     (when (looking-at "^From[^:]")
1216                       (kill-region (point) (progn (forward-line) (point))))
1217                     ;; turn into rfc822 format (\r\n eol's)
1218                     (while (search-forward "\n" nil t)
1219                       (replace-match "\r\n")))
1220                   ;; this 'or' is for Cyrus server bug
1221                   (or (null (imap-current-mailbox nnimap-server-buffer))
1222                       (imap-mailbox-unselect nnimap-server-buffer))
1223                   (imap-message-append group (current-buffer) nil nil
1224                                        nnimap-server-buffer)))
1225           (cons group (nth 1 uid))
1226         (nnheader-report 'nnimap (imap-error-text nnimap-server-buffer))))))
1227
1228 (deffoo nnimap-request-delete-group (group force &optional server)
1229   (when (nnimap-possibly-change-server server)
1230     (with-current-buffer nnimap-server-buffer
1231       (if force
1232           (or (null (imap-mailbox-status group 'uidvalidity))
1233               (imap-mailbox-delete group))
1234         ;; UNSUBSCRIBE?
1235         t))))
1236
1237 (deffoo nnimap-request-rename-group (group new-name &optional server)
1238   (when (nnimap-possibly-change-server server)
1239     (imap-mailbox-rename group new-name nnimap-server-buffer)))
1240
1241 (defun nnimap-expunge (mailbox server)
1242   (when (nnimap-possibly-change-group mailbox server)
1243     (imap-mailbox-expunge nnimap-server-buffer)))
1244
1245 (defun nnimap-acl-get (mailbox server)
1246   (when (nnimap-possibly-change-server server)
1247     (and (imap-capability 'ACL nnimap-server-buffer)
1248          (imap-mailbox-acl-get mailbox nnimap-server-buffer))))
1249
1250 (defun nnimap-acl-edit (mailbox method old-acls new-acls)
1251   (when (nnimap-possibly-change-server (cadr method))
1252     (unless (imap-capability 'ACL nnimap-server-buffer)
1253       (error "Your server does not support ACL editing"))
1254     (with-current-buffer nnimap-server-buffer
1255       ;; delete all removed identifiers
1256       (mapcar (lambda (old-acl)
1257                 (unless (assoc (car old-acl) new-acls)
1258                   (or (imap-mailbox-acl-delete (car old-acl) mailbox)
1259                       (error "Can't delete ACL for %s" (car old-acl)))))
1260               old-acls)
1261       ;; set all changed acl's
1262       (mapcar (lambda (new-acl)
1263                 (let ((new-rights (cdr new-acl))
1264                       (old-rights (cdr (assoc (car new-acl) old-acls))))
1265                   (unless (and old-rights new-rights
1266                                (string= old-rights new-rights))
1267                     (or (imap-mailbox-acl-set (car new-acl) new-rights mailbox)
1268                         (error "Can't set ACL for %s to %s" (car new-acl)
1269                                new-rights)))))
1270               new-acls)
1271       t)))
1272
1273 \f
1274 ;;; Internal functions
1275
1276 ;;
1277 ;; This is confusing.
1278 ;;
1279 ;; mark      => read, tick, draft, reply etc
1280 ;; flag      => "\\Seen", "\\Flagged", "\\Draft", "gnus-expire" etc
1281 ;; predicate => "SEEN", "FLAGGED", "DRAFT", "KEYWORD gnus-expire" etc
1282 ;;
1283 ;; Mark should not really contain 'read since it's not a "mark" in the Gnus
1284 ;; world, but we cheat.  Mark == gnus-article-mark-lists + '(read . read).
1285 ;;
1286
1287 (defconst nnimap-mark-to-predicate-alist
1288   (mapcar
1289    (lambda (pair)                       ; cdr is the mark
1290      (or (assoc (cdr pair)
1291                 '((read . "SEEN")
1292                   (tick . "FLAGGED")
1293                   (draft . "DRAFT")
1294                   (reply . "ANSWERED")))
1295          (cons (cdr pair)
1296                (format "KEYWORD gnus-%s" (symbol-name (cdr pair))))))
1297    (cons '(read . read) gnus-article-mark-lists)))
1298
1299 (defun nnimap-mark-to-predicate (pred)
1300   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP predicate.
1301 This is a string such as \"SEEN\", \"FLAGGED\", \"KEYWORD gnus-expire\",
1302 to be used within a IMAP SEARCH query."
1303   (cdr (assq pred nnimap-mark-to-predicate-alist)))
1304
1305 (defconst nnimap-mark-to-flag-alist
1306   (mapcar
1307    (lambda (pair)
1308      (or (assoc (cdr pair)
1309                 '((read . "\\Seen")
1310                   (tick . "\\Flagged")
1311                   (draft . "\\Draft")
1312                   (reply . "\\Answered")))
1313          (cons (cdr pair)
1314                (format "gnus-%s" (symbol-name (cdr pair))))))
1315    (cons '(read . read) gnus-article-mark-lists)))
1316
1317 (defun nnimap-mark-to-flag-1 (preds)
1318   (if (and (not (null preds)) (listp preds))
1319       (cons (nnimap-mark-to-flag (car preds))
1320             (nnimap-mark-to-flag (cdr preds)))
1321     (cdr (assoc preds nnimap-mark-to-flag-alist))))
1322
1323 (defun nnimap-mark-to-flag (preds &optional always-list make-string)
1324   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP flag.
1325 This is a string such as \"\\Seen\", \"\\Flagged\", \"gnus-expire\", to
1326 be used in a STORE FLAGS command."
1327   (let ((result (nnimap-mark-to-flag-1 preds)))
1328     (setq result (if (and (or make-string always-list)
1329                           (not (listp result)))
1330                      (list result)
1331                    result))
1332     (if make-string
1333         (mapconcat (lambda (flag)
1334                      (if (listp flag)
1335                          (mapconcat 'identity flag " ")
1336                        flag))
1337                    result " ")
1338       result)))
1339
1340 (defun nnimap-mark-permanent-p (mark &optional group)
1341   "Return t iff MARK can be permanently (between IMAP sessions) saved on articles, in GROUP."
1342   (imap-message-flag-permanent-p (nnimap-mark-to-flag mark)))
1343
1344 (defun nnimap-remassoc (key alist)
1345   "Delete by side effect any elements of LIST whose car is `equal' to KEY.
1346 The modified LIST is returned.  If the first member
1347 of LIST has a car that is `equal' to KEY, there is no way to remove it
1348 by side effect; therefore, write `(setq foo (remassoc key foo))' to be
1349 sure of changing the value of `foo'."
1350   (when alist
1351     (if (equal key (caar alist))
1352         (cdr alist)
1353       (setcdr alist (nnimap-remassoc key (cdr alist)))
1354       alist)))
1355
1356 (defun nnimap-update-alist-soft (key value alist)
1357   (if value
1358       (cons (cons key value) (nnimap-remassoc key alist))
1359     (nnimap-remassoc key alist)))
1360
1361 (when nnimap-debug
1362   (require 'trace)
1363   (buffer-disable-undo (get-buffer-create nnimap-debug))
1364   (mapcar (lambda (f) (trace-function-background f nnimap-debug))
1365           '(
1366             nnimap-possibly-change-server
1367             nnimap-verify-uidvalidity
1368             nnimap-find-minmax-uid
1369             nnimap-before-find-minmax-bugworkaround
1370             nnimap-possibly-change-group
1371             ;;nnimap-replace-whitespace
1372             nnimap-retrieve-headers-progress
1373             nnimap-retrieve-which-headers
1374             nnimap-group-overview-filename
1375             nnimap-retrieve-headers-from-file
1376             nnimap-retrieve-headers-from-server
1377             nnimap-retrieve-headers
1378             nnimap-open-connection
1379             nnimap-open-server
1380             nnimap-server-opened
1381             nnimap-close-server
1382             nnimap-request-close
1383             nnimap-status-message
1384             ;;nnimap-demule
1385             nnimap-request-article-part
1386             nnimap-request-article
1387             nnimap-request-head
1388             nnimap-request-body
1389             nnimap-request-group
1390             nnimap-close-group
1391             nnimap-pattern-to-list-arguments
1392             nnimap-request-list
1393             nnimap-request-post
1394             nnimap-retrieve-groups
1395             nnimap-request-update-info-internal
1396             nnimap-request-type
1397             nnimap-request-set-mark
1398             nnimap-split-to-groups
1399             nnimap-split-find-rule
1400             nnimap-split-find-inbox
1401             nnimap-split-articles
1402             nnimap-request-scan
1403             nnimap-request-newgroups
1404             nnimap-request-create-group
1405             nnimap-time-substract
1406             nnimap-date-days-ago
1407             nnimap-request-expire-articles-progress
1408             nnimap-request-expire-articles
1409             nnimap-request-move-article
1410             nnimap-request-accept-article
1411             nnimap-request-delete-group
1412             nnimap-request-rename-group
1413             gnus-group-nnimap-expunge
1414             gnus-group-nnimap-edit-acl
1415             gnus-group-nnimap-edit-acl-done
1416             nnimap-group-mode-hook
1417             nnimap-mark-to-predicate
1418             nnimap-mark-to-flag-1
1419             nnimap-mark-to-flag
1420             nnimap-mark-permanent-p
1421             nnimap-remassoc
1422             nnimap-update-alist-soft
1423             )))
1424
1425 (provide 'nnimap)
1426
1427 ;;; nnimap.el ends here