cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- imap backend for Gnus
   2 ;; Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   3
   4 ;; Author: Simon Josefsson <jas@pdc.kth.se>
   5 ;;         Jim Radford <radford@robby.caltech.edu>
   6 ;; Keywords: mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Todo, major things:
  28 ;;
  29 ;;   o Fix Gnus to view correct number of unread/total articles in group buffer
  30 ;;   o Fix Gnus to handle leading '.' in group names (fixed?)
  31 ;;   o Finish disconnected mode (moving articles between mailboxes unplugged)
  32 ;;   o Sieve
  33 ;;   o MIME (partial article fetches)
  34 ;;   o Split to other backends, different split rules for different
  35 ;;     servers/inboxes
  36 ;;
  37 ;; Todo, minor things:
  38 ;;
  39 ;;   o Don't require half of Gnus -- backends should be standalone
  40 ;;   o Verify that we don't use IMAP4rev1 specific things (RFC2060 App B)
  41 ;;   o Dont uid fetch 1,* in nnimap-retrive-groups (slow)
  42 ;;   o Split up big fetches (1,* header especially) in smaller chunks
  43 ;;   o What do I do with gnus-newsgroup-*?
  44 ;;   o Tell Gnus about new groups (how can we tell?)
  45 ;;   o Respooling (fix Gnus?) (unnecessery?)
  46 ;;   o Add support for the following: (if applicable)
  47 ;;       request-list-newsgroups, request-regenerate
  48 ;;       list-active-group,
  49 ;;       request-associate-buffer, request-restore-buffer,
  50 ;;   o Do The Right Thing when UIDVALIDITY changes (what's the right thing?)
  51 ;;   o Support RFC2221 (Login referrals)
  52 ;;   o IMAP2BIS compatibility? (RFC2061)
  53 ;;   o ACAP stuff (perhaps a different project, would be nice to ACAPify
  54 ;;     .newsrc.eld)
  55 ;;   o What about Gnus's article editing, can we support it?  NO!
  56 ;;   o Use \Draft to support the draft group??
  57 ;;   o Duplicate suppression
  58 ;;   o Rewrite UID SEARCH UID X as UID FETCH X (UID) for those with slow servers
  59
  60 ;;; Code:
  61
  62 (require 'imap)
  63 (require 'nnoo)
  64 (require 'nnmail)
  65 (require 'nnheader)
  66 (require 'mm-util)
  67 (require 'gnus)
  68 (require 'gnus-range)
  69 (require 'gnus-start)
  70 (require 'gnus-int)
  71
  72 (nnoo-declare nnimap)
  73
  74 (defconst nnimap-version "nnimap 1.0")
  75
  76 (defgroup nnimap nil
  77   "Reading IMAP mail with Gnus."
  78   :group 'gnus)
  79
  80 (defvoo nnimap-address nil
  81   "Address of physical IMAP server.  If nil, use the virtual server's name.")
  82
  83 (defvoo nnimap-server-port nil
  84   "Port number on physical IMAP server.
  85 If nil, defaults to 993 for SSL connections and 143 otherwise.")
  86
  87 ;; Splitting variables
  88
  89 (defcustom nnimap-split-crosspost t
  90   "If non-nil, do crossposting if several split methods match the mail.
  91 If nil, the first match found will be used."
  92   :group 'nnimap
  93   :type 'boolean)
  94
  95 (defcustom nnimap-split-inbox nil
  96   "Name of mailbox to split mail from.
  97
  98 Mail is read from this mailbox and split according to rules in
  99 `nnimap-split-rule'.
 100
 101 This can be a string or a list of strings."
 102   :group 'nnimap
 103   :type '(choice (string)
 104                  (repeat string)))
 105
 106 (define-widget 'nnimap-strict-function 'function
 107   "This widget only matches values that are functionp.
 108
 109 Warning: This means that a value that is the symbol of a not yet
 110 loaded function will not match.  Use with care."
 111   :match 'nnimap-strict-function-match)
 112
 113 (defun nnimap-strict-function-match (widget value)
 114   "Ignoring WIDGET, match if VALUE is a function."
 115   (functionp value))
 116
 117 (defcustom nnimap-split-rule nil
 118   "Mail will be split according to theese rules.
 119
 120 Mail is read from mailbox(es) specified in `nnimap-split-inbox'.
 121
 122 If you'd like, for instance, one mail group for mail from the
 123 \"gnus-imap\" mailing list, one group for junk mail and leave
 124 everything else in the incoming mailbox, you could do something like
 125 this:
 126
 127 \(setq nnimap-split-rule '((\"INBOX.gnus-imap\"   \"From:.*gnus-imap\")
 128                           (\"INBOX.junk\"        \"Subject:.*buy\")))
 129
 130 As you can see, `nnimap-split-rule' is a list of lists, where the
 131 first element in each \"rule\" is the name of the IMAP mailbox (or the
 132 symbol `junk' if you want to remove the mail), and the second is a
 133 regexp that nnimap will try to match on the header to find a fit.
 134
 135 The second element can also be a function.  In that case, it will be
 136 called narrowed to the headers with the first element of the rule as
 137 the argument.  It should return a non-nil value if it thinks that the
 138 mail belongs in that group.
 139
 140 This variable can also have a function as its value, the function will
 141 be called with the headers narrowed and should return a group where it
 142 thinks the article should be splitted to.  See `nnimap-split-fancy'.
 143
 144 To allow for different split rules on different virtual servers, and
 145 even different split rules in different inboxes on the same server,
 146 the syntax of this variable have been extended along the lines of:
 147
 148 \(setq nnimap-split-rule
 149       '((\"my1server\"    (\".*\"    ((\"ding\"    \"ding@gnus.org\")
 150                                   (\"junk\"    \"From:.*Simon\")))
 151         (\"my2server\"    (\"INBOX\" nnimap-split-fancy))
 152         (\"my[34]server\" (\".*\"    ((\"private\" \"To:.*Simon\")
 153                                   (\"junk\"    my-junk-func)))))
 154
 155 The virtual server name is in fact a regexp, so that the same rules
 156 may apply to several servers.  In the example, the servers
 157 \"my3server\" and \"my4server\" both use the same rules.  Similarly,
 158 the inbox string is also a regexp.  The actual splitting rules are as
 159 before, either a function, or a list with group/regexp or
 160 group/function elements."
 161   :group 'nnimap
 162   :type '(choice :tag "Rule type"
 163                  (repeat :menu-tag "Single-server"
 164                          :tag "Single-server list"
 165                          (list (string :tag "Mailbox")
 166                                (choice :tag "Predicate"
 167                                        (regexp :tag "A regexp")
 168                                        (nnimap-strict-function :tag "A function"))))
 169                  (choice :menu-tag "A function"
 170                          :tag "A function"
 171                          (function-item nnimap-split-fancy)
 172                          (function-item nnmail-split-fancy)
 173                          (nnimap-strict-function :tag "User-defined function"))
 174                  (repeat :menu-tag "Multi-server (extended)"
 175                          :tag "Multi-server list"
 176                          (list (regexp :tag "Server regexp")
 177                                (list (regexp :tag "Incoming Mailbox regexp")
 178                                      (repeat :tag "Rules for matching server(s) and mailbox(es)"
 179                                              (list (string :tag "Destination mailbox")
 180                                                    (choice :tag "Predicate"
 181                                                            (regexp :tag "A Regexp")
 182                                                            (nnimap-strict-function :tag "A Function")))))))))
 183
 184 (defcustom nnimap-split-predicate "UNSEEN UNDELETED"
 185   "The predicate used to find articles to split.
 186 If you use another IMAP client to peek on articles but always would
 187 like nnimap to split them once it's started, you could change this to
 188 \"UNDELETED\". Other available predicates are available in
 189 RFC2060 section 6.4.4."
 190   :group 'nnimap
 191   :type 'string)
 192
 193 (defcustom nnimap-split-fancy nil
 194   "Like the variable `nnmail-split-fancy', which see."
 195   :group 'nnimap
 196   :type 'sexp)
 197
 198 ;; Performance / bug workaround variables
 199
 200 (defcustom nnimap-close-asynchronous t
 201   "Close mailboxes asynchronously in `nnimap-close-group'.
 202 This means that errors cought by nnimap when closing the mailbox will
 203 not prevent Gnus from updating the group status, which may be harmful.
 204 However, it increases speed."
 205   :type 'boolean
 206   :group 'nnimap)
 207
 208 (defcustom nnimap-dont-close t
 209   "Never close mailboxes.
 210 This increases the speed of closing mailboxes (quiting group) but may
 211 decrease the speed of selecting another mailbox later.  Re-selecting
 212 the same mailbox will be faster though."
 213   :type 'boolean
 214   :group 'nnimap)
 215
 216 (defcustom nnimap-retrieve-groups-asynchronous t
 217   "Send asynchronous STATUS commands for each mailbox before checking mail.
 218 If you have mailboxes that rarely receives mail, this speeds up new
 219 mail checking.  It works by first sending STATUS commands for each
 220 mailbox, and then only checking groups which has a modified UIDNEXT
 221 more carefully for new mail.
 222
 223 In summary, the default is O((1-p)*k+p*n) and changing it to nil makes
 224 it O(n).  If p is small, then the default is probably faster."
 225   :type 'boolean
 226   :group 'nnimap)
 227
 228 (defvoo nnimap-need-unselect-to-notice-new-mail nil
 229   "Unselect mailboxes before looking for new mail in them.
 230 Some servers seem to need this under some circumstances.")
 231
 232 ;; Authorization / Privacy variables
 233
 234 (defvoo nnimap-auth-method nil
 235   "Obsolete.")
 236
 237 (defvoo nnimap-stream nil
 238   "How nnimap will connect to the server.
 239
 240 The default, nil, will try to use the \"best\" method the server can
 241 handle.
 242
 243 Change this if
 244
 245 1) you want to connect with SSL.  The SSL integration with IMAP is
 246    brain-dead so you'll have to tell it specifically.
 247
 248 2) your server is more capable than your environment -- i.e. your
 249    server accept Kerberos login's but you haven't installed the
 250    `imtest' program or your machine isn't configured for Kerberos.
 251
 252 Possible choices: kerberos4, ssl, network")
 253
 254 (defvoo nnimap-authenticator nil
 255   "How nnimap authenticate itself to the server.
 256
 257 The default, nil, will try to use the \"best\" method the server can
 258 handle.
 259
 260 There is only one reason for fiddling with this variable, and that is
 261 if your server is more capable than your environment -- i.e. you
 262 connect to a server that accept Kerberos login's but you haven't
 263 installed the `imtest' program or your machine isn't configured for
 264 Kerberos.
 265
 266 Possible choices: kerberos4, cram-md5, login, anonymous.")
 267
 268 (defvoo nnimap-directory (nnheader-concat gnus-directory "overview/")
 269   "Directory to keep NOV cache files for nnimap groups.
 270 See also `nnimap-nov-file-name'.")
 271
 272 (defvoo nnimap-nov-file-name "nnimap."
 273   "NOV cache base filename.
 274 The group name and `nnimap-nov-file-name-suffix' will be appended.  A
 275 typical complete file name would be
 276 ~/News/overview/nnimap.pdc.INBOX.ding.nov, or
 277 ~/News/overview/nnimap/pdc/INBOX/ding/nov if
 278 `nnmail-use-long-file-names' is nil")
 279
 280 (defvoo nnimap-nov-file-name-suffix ".novcache"
 281   "Suffix for NOV cache base filename.")
 282
 283 (defvoo nnimap-nov-is-evil gnus-agent
 284   "If non-nil, never generate or use a local nov database for this backend.
 285 Using nov databases should speed up header fetching considerably.
 286 However, it will invoke a UID SEARCH UID command on the server, and
 287 some servers implement this command inefficiently by opening each and
 288 every message in the group, thus making it quite slow.
 289 Unlike other backends, you do not need to take special care if you
 290 flip this variable.")
 291
 292 (defvoo nnimap-expunge-on-close 'always ; 'ask, 'never
 293   "Whether to expunge a group when it is closed.
 294 When a IMAP group with articles marked for deletion is closed, this
 295 variable determine if nnimap should actually remove the articles or
 296 not.
 297
 298 If always, nnimap always perform a expunge when closing the group.
 299 If never, nnimap never expunges articles marked for deletion.
 300 If ask, nnimap will ask you if you wish to expunge marked articles.
 301
 302 When setting this variable to `never', you can only expunge articles
 303 by using `G x' (gnus-group-nnimap-expunge) from the Group buffer.")
 304
 305 (defvoo nnimap-list-pattern "*"
 306   "A string LIMIT or list of strings with mailbox wildcards used to limit available groups.
 307 See below for available wildcards.
 308
 309 The LIMIT string can be a cons cell (REFERENCE . LIMIT), where
 310 REFERENCE will be passed as the first parameter to LIST/LSUB.  The
 311 semantics of this are server specific, on the University of Washington
 312 server you can specify a directory.
 313
 314 Example:
 315  '(\"INBOX\" \"mail/*\" (\"~friend/mail/\" . \"list/*\"))
 316
 317 There are two wildcards * and %. * matches everything, % matches
 318 everything in the current hierarchy.")
 319
 320 (defvoo nnimap-news-groups nil
 321   "IMAP support a news-like mode, also known as bulletin board mode,
 322 where replies is sent via IMAP instead of SMTP.
 323
 324 This variable should contain a regexp matching groups where you wish
 325 replies to be stored to the mailbox directly.
 326
 327 Example:
 328   '(\"^[^I][^N][^B][^O][^X].*$\")
 329
 330 This will match all groups not beginning with \"INBOX\".
 331
 332 Note that there is nothing technically different between mail-like and
 333 news-like mailboxes.  If you wish to have a group with todo items or
 334 similar which you wouldn't want to set up a mailing list for, you can
 335 use this to make replies go directly to the group.")
 336
 337 (defvoo nnimap-expunge-search-string "UID %s NOT SINCE %s"
 338   "IMAP search command to use for articles that are to be expired.
 339 The first %s is replaced by a UID set of articles to search on,
 340 and the second %s is replaced by a date criterium.
 341
 342 One useful (and perhaps the only useful) value to change this to would
 343 be `UID %s NOT SENTSINCE %s' to make nnimap use the Date: header
 344 instead of the internal date of messages.  See section 6.4.4 of RFC
 345 2060 for more information on valid strings.")
 346
 347 (defvoo nnimap-importantize-dormant t
 348   "If non-nil, mark \"dormant\" articles as \"ticked\" for other IMAP clients.
 349 Note that within Gnus, dormant articles will still (only) be
 350 marked as ticked.  This is to make \"dormant\" articles stand out,
 351 just like \"ticked\" articles, in other IMAP clients.")
 352
 353 (defvoo nnimap-server-address nil
 354   "Obsolete.  Use `nnimap-address'.")
 355
 356 (defcustom nnimap-authinfo-file "~/.authinfo"
 357   "Authorization information for IMAP servers.  In .netrc format."
 358   :type
 359   '(choice file
 360            (repeat :tag "Entries"
 361                    :menu-tag "Inline"
 362                    (list :format "%v"
 363                          :value ("" ("login" . "") ("password" . ""))
 364                          (string :tag "Host")
 365                          (checklist :inline t
 366                                     (cons :format "%v"
 367                                           (const :format "" "login")
 368                                           (string :format "Login: %v"))
 369                                     (cons :format "%v"
 370                                           (const :format "" "password")
 371                                           (string :format "Password: %v")))))))
 372
 373 (defcustom nnimap-prune-cache t
 374   "If non-nil, nnimap check whether articles still exist on server before using data stored in NOV cache."
 375   :type 'boolean)
 376
 377 (defvar nnimap-request-list-method 'imap-mailbox-list
 378   "Method to use to request a list of all folders from the server.
 379 If this is 'imap-mailbox-lsub, then use a server-side subscription list to
 380 restrict visible folders.")
 381
 382 ;; Internal variables:
 383
 384 (defvar nnimap-mailbox-info (gnus-make-hashtable 997))
 385 (defvar nnimap-debug nil
 386   "Name of buffer to record debugging info.
 387 For example: (setq nnimap-debug \"*nnimap-debug*\")")
 388 (defvar nnimap-current-move-server nil)
 389 (defvar nnimap-current-move-group nil)
 390 (defvar nnimap-current-move-article nil)
 391 (defvar nnimap-length)
 392 (defvar nnimap-progress-chars '(?| ?/ ?- ?\\))
 393 (defvar nnimap-progress-how-often 20)
 394 (defvar nnimap-counter)
 395 (defvar nnimap-callback-callback-function nil
 396   "Gnus callback the nnimap asynchronous callback should call.")
 397 (defvar nnimap-callback-buffer nil
 398   "Which buffer the asynchronous article prefetch callback should work in.")
 399 (defvar nnimap-server-buffer-alist nil) ;; Map server name to buffers.
 400 (defvar nnimap-current-server nil) ;; Current server
 401 (defvar nnimap-server-buffer nil) ;; Current servers' buffer
 402
 403 \f
 404
 405 (nnoo-define-basics nnimap)
 406
 407 ;; Utility functions:
 408
 409 (defsubst nnimap-get-server-buffer (server)
 410   "Return buffer for SERVER, if nil use current server."
 411   (cadr (assoc (or server nnimap-current-server) nnimap-server-buffer-alist)))
 412
 413 (defun nnimap-possibly-change-server (server)
 414   "Return buffer for SERVER, changing the current server as a side-effect.
 415 If SERVER is nil, uses the current server."
 416   (setq nnimap-current-server (or server nnimap-current-server)
 417         nnimap-server-buffer (nnimap-get-server-buffer nnimap-current-server)))
 418
 419 (defun nnimap-verify-uidvalidity (group server)
 420   "Verify stored uidvalidity match current one in GROUP on SERVER."
 421   (let* ((gnusgroup (gnus-group-prefixed-name
 422                      group (gnus-server-to-method
 423                             (format "nnimap:%s" server))))
 424          (new-uidvalidity (imap-mailbox-get 'uidvalidity))
 425          (old-uidvalidity (gnus-group-get-parameter gnusgroup 'uidvalidity))
 426          (dir (file-name-as-directory (expand-file-name nnimap-directory)))
 427          (nameuid (nnheader-translate-file-chars
 428                    (concat nnimap-nov-file-name
 429                            (if (equal server "")
 430                                "unnamed"
 431                              server) "." group "." old-uidvalidity
 432                            nnimap-nov-file-name-suffix) t))
 433          (file (if (or nnmail-use-long-file-names
 434                        (file-exists-p (expand-file-name nameuid dir)))
 435                    (expand-file-name nameuid dir)
 436                  (expand-file-name
 437                   (mm-encode-coding-string
 438                    (nnheader-replace-chars-in-string nameuid ?. ?/)
 439                    nnmail-pathname-coding-system)
 440                   dir))))
 441     (if old-uidvalidity
 442         (if (not (equal old-uidvalidity new-uidvalidity))
 443             ;; uidvalidity clash
 444             (gnus-delete-file file)
 445           (gnus-group-set-parameter gnusgroup 'uidvalidity new-uidvalidity)
 446           t)
 447       (gnus-group-add-parameter gnusgroup (cons 'uidvalidity new-uidvalidity))
 448       t)))
 449
 450 (defun nnimap-before-find-minmax-bugworkaround ()
 451   "Function called before iterating through mailboxes with
 452 `nnimap-find-minmax-uid'."
 453   (when nnimap-need-unselect-to-notice-new-mail
 454     ;; XXX this is for UoW imapd problem, it doesn't notice new mail in
 455     ;; currently selected mailbox without a re-select/examine.
 456     (or (null (imap-current-mailbox nnimap-server-buffer))
 457         (imap-mailbox-unselect nnimap-server-buffer))))
 458
 459 (defun nnimap-find-minmax-uid (group &optional examine)
 460   "Find lowest and highest active article nummber in GROUP.
 461 If EXAMINE is non-nil the group is selected read-only."
 462   (with-current-buffer nnimap-server-buffer
 463     (when (or (string= group (imap-current-mailbox))
 464               (imap-mailbox-select group examine))
 465       (let (minuid maxuid)
 466         (when (> (imap-mailbox-get 'exists) 0)
 467           (imap-fetch "1,*" "UID" nil 'nouidfetch)
 468           (imap-message-map (lambda (uid Uid)
 469                               (setq minuid (if minuid (min minuid uid) uid)
 470                                     maxuid (if maxuid (max maxuid uid) uid)))
 471                             'UID))
 472         (list (imap-mailbox-get 'exists) minuid maxuid)))))
 473
 474 (defun nnimap-possibly-change-group (group &optional server)
 475   "Make GROUP the current group, and SERVER the current server."
 476   (when (nnimap-possibly-change-server server)
 477     (with-current-buffer nnimap-server-buffer
 478       (if (or (null group) (imap-current-mailbox-p group))
 479           imap-current-mailbox
 480         (if (imap-mailbox-select group)
 481             (if (or (nnimap-verify-uidvalidity
 482                      group (or server nnimap-current-server))
 483                     (zerop (imap-mailbox-get 'exists group))
 484                     t ;; for OGnus to see if ignoring uidvalidity
 485                     ;; changes has any bad effects.
 486                     (yes-or-no-p
 487                      (format
 488                       "nnimap: Group %s is not uidvalid.  Continue? " group)))
 489                 imap-current-mailbox
 490               (imap-mailbox-unselect)
 491               (error "nnimap: Group %s is not uid-valid" group))
 492           (nnheader-report 'nnimap (imap-error-text)))))))
 493
 494 (defun nnimap-replace-whitespace (string)
 495   "Return STRING with all whitespace replaced with space."
 496   (when string
 497     (while (string-match "[\r\n\t]+" string)
 498       (setq string (replace-match " " t t string)))
 499     string))
 500
 501 ;; Required backend functions
 502
 503 (defun nnimap-retrieve-headers-progress ()
 504   "Hook to insert NOV line for current article into `nntp-server-buffer'."
 505   (and (numberp nnmail-large-newsgroup)
 506        (zerop (% (incf nnimap-counter) nnimap-progress-how-often))
 507        (> nnimap-length nnmail-large-newsgroup)
 508        (nnheader-message 6 "nnimap: Retrieving headers... %c"
 509                          (nth (/ (% nnimap-counter
 510                                     (* (length nnimap-progress-chars)
 511                                        nnimap-progress-how-often))
 512                                  nnimap-progress-how-often)
 513                               nnimap-progress-chars)))
 514   (with-current-buffer nntp-server-buffer
 515     (let (headers lines chars uid mbx)
 516       (with-current-buffer nnimap-server-buffer
 517         (setq uid imap-current-message
 518               mbx imap-current-mailbox
 519               headers (nnimap-demule
 520                        (if (imap-capability 'IMAP4rev1)
 521                            ;; xxx don't just use car? alist doesn't contain
 522                            ;; anything else now, but it might...
 523                            (nth 2 (car (imap-message-get uid 'BODYDETAIL)))
 524                          (imap-message-get uid 'RFC822.HEADER)))
 525               lines (imap-body-lines (imap-message-body imap-current-message))
 526               chars (imap-message-get imap-current-message 'RFC822.SIZE)))
 527       (nnheader-insert-nov
 528        (with-temp-buffer
 529          (buffer-disable-undo)
 530          (insert headers)
 531          (let ((head (nnheader-parse-naked-head)))
 532            (mail-header-set-number head uid)
 533            (mail-header-set-chars head chars)
 534            (mail-header-set-lines head lines)
 535            (mail-header-set-xref
 536             head (format "%s %s:%d" (system-name) mbx uid))
 537            head))))))
 538
 539 (defun nnimap-retrieve-which-headers (articles fetch-old)
 540   "Get a range of articles to fetch based on ARTICLES and FETCH-OLD."
 541   (with-current-buffer nnimap-server-buffer
 542     (if (numberp (car-safe articles))
 543         (imap-search
 544          (concat "UID "
 545                  (imap-range-to-message-set
 546                   (gnus-compress-sequence
 547                    (append (gnus-uncompress-sequence
 548                             (and fetch-old
 549                                  (cons (if (numberp fetch-old)
 550                                            (max 1 (- (car articles) fetch-old))
 551                                          1)
 552                                        (1- (car articles)))))
 553                            articles)))))
 554       (mapcar (lambda (msgid)
 555                 (imap-search
 556                  (format "HEADER Message-Id \"%s\"" msgid)))
 557               articles))))
 558
 559 (defun nnimap-group-overview-filename (group server)
 560   "Make pathname for GROUP on SERVER."
 561   (let* ((dir (file-name-as-directory (expand-file-name nnimap-directory)))
 562          (uidvalidity (gnus-group-get-parameter
 563                        (gnus-group-prefixed-name
 564                         group (gnus-server-to-method
 565                                (format "nnimap:%s" server)))
 566                        'uidvalidity))
 567          (name (nnheader-translate-file-chars
 568                 (concat nnimap-nov-file-name
 569                         (if (equal server "")
 570                             "unnamed"
 571                           server) "." group nnimap-nov-file-name-suffix) t))
 572          (nameuid (nnheader-translate-file-chars
 573                    (concat nnimap-nov-file-name
 574                            (if (equal server "")
 575                                "unnamed"
 576                              server) "." group "." uidvalidity
 577                            nnimap-nov-file-name-suffix) t))
 578          (oldfile (if (or nnmail-use-long-file-names
 579                           (file-exists-p (expand-file-name name dir)))
 580                       (expand-file-name name dir)
 581                     (expand-file-name
 582                      (mm-encode-coding-string
 583                       (nnheader-replace-chars-in-string name ?. ?/)
 584                       nnmail-pathname-coding-system)
 585                      dir)))
 586          (newfile (if (or nnmail-use-long-file-names
 587                           (file-exists-p (expand-file-name nameuid dir)))
 588                       (expand-file-name nameuid dir)
 589                     (expand-file-name
 590                      (mm-encode-coding-string
 591                       (nnheader-replace-chars-in-string nameuid ?. ?/)
 592                       nnmail-pathname-coding-system)
 593                      dir))))
 594     (when (and (file-exists-p oldfile) (not (file-exists-p newfile)))
 595       (message "nnimap: Upgrading novcache filename...")
 596       (sit-for 1)
 597       (gnus-make-directory (file-name-directory newfile))
 598       (unless (ignore-errors (rename-file oldfile newfile) t)
 599         (if (ignore-errors (copy-file oldfile newfile) t)
 600             (delete-file oldfile)
 601           (error "Can't rename `%s' to `%s'" oldfile newfile))))
 602     newfile))
 603
 604 (defun nnimap-retrieve-headers-from-file (group server)
 605   (with-current-buffer nntp-server-buffer
 606     (let ((nov (nnimap-group-overview-filename group server)))
 607       (when (file-exists-p nov)
 608         (mm-insert-file-contents nov)
 609         (set-buffer-modified-p nil)
 610         (let ((min (ignore-errors (goto-char (point-min))
 611                                   (read (current-buffer))))
 612               (max (ignore-errors (goto-char (point-max))
 613                                   (forward-line -1)
 614                                   (read (current-buffer)))))
 615           (if (and (numberp min) (numberp max))
 616               (cons min max)
 617             ;; junk, remove it, it's saved later
 618             (erase-buffer)
 619             nil))))))
 620
 621 (defun nnimap-retrieve-headers-from-server (articles group server)
 622   (with-current-buffer nnimap-server-buffer
 623     (let ((imap-fetch-data-hook '(nnimap-retrieve-headers-progress))
 624           (nnimap-length (gnus-range-length articles))
 625           (nnimap-counter 0))
 626       (imap-fetch (imap-range-to-message-set articles)
 627                   (concat "(UID RFC822.SIZE BODY "
 628                           (let ((headers
 629                                  (append '(Subject From Date Message-Id
 630                                                    References In-Reply-To Xref)
 631                                          (copy-sequence
 632                                           nnmail-extra-headers))))
 633                             (if (imap-capability 'IMAP4rev1)
 634                                 (format "BODY.PEEK[HEADER.FIELDS %s])" headers)
 635                               (format "RFC822.HEADER.LINES %s)" headers)))))
 636       (and (numberp nnmail-large-newsgroup)
 637            (> nnimap-length nnmail-large-newsgroup)
 638            (nnheader-message 6 "nnimap: Retrieving headers...done")))))
 639
 640 (defun nnimap-dont-use-nov-p (group server)
 641   (or gnus-nov-is-evil nnimap-nov-is-evil
 642       (unless (and (gnus-make-directory
 643                     (file-name-directory
 644                      (nnimap-group-overview-filename group server)))
 645                    (file-writable-p
 646                     (nnimap-group-overview-filename group server)))
 647         (message "nnimap: Nov cache not writable, %s"
 648                  (nnimap-group-overview-filename group server)))))
 649
 650 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 651   (when (nnimap-possibly-change-group group server)
 652     (with-current-buffer nntp-server-buffer
 653       (erase-buffer)
 654       (if (nnimap-dont-use-nov-p group server)
 655           (nnimap-retrieve-headers-from-server
 656            (gnus-compress-sequence articles) group server)
 657         (let (uids cached low high)
 658           (when (setq uids (nnimap-retrieve-which-headers articles fetch-old)
 659                       low (car uids)
 660                       high (car (last uids)))
 661             (if (setq cached (nnimap-retrieve-headers-from-file group server))
 662                 (progn
 663                   ;; fetch articles with uids before cache block
 664                   (when (< low (car cached))
 665                     (goto-char (point-min))
 666                     (nnimap-retrieve-headers-from-server
 667                      (cons low (1- (car cached))) group server))
 668                   ;; fetch articles with uids after cache block
 669                   (when (> high (cdr cached))
 670                     (goto-char (point-max))
 671                     (nnimap-retrieve-headers-from-server
 672                      (cons (1+ (cdr cached)) high) group server))
 673                   (when nnimap-prune-cache
 674                     ;; remove nov's for articles which has expired on server
 675                     (goto-char (point-min))
 676                     (dolist (uid (gnus-set-difference articles uids))
 677                       (when (re-search-forward (format "^%d\t" uid) nil t)
 678                         (gnus-delete-line)))))
 679               ;; nothing cached, fetch whole range from server
 680               (nnimap-retrieve-headers-from-server
 681                (cons low high) group server))
 682             (when (buffer-modified-p)
 683               (nnmail-write-region
 684                (point-min) (point-max)
 685                (nnimap-group-overview-filename group server) nil 'nomesg))
 686             (nnheader-nov-delete-outside-range low high))))
 687       'nov)))
 688
 689 (defun nnimap-open-connection (server)
 690   (if (not (imap-open nnimap-address nnimap-server-port nnimap-stream
 691                       nnimap-authenticator nnimap-server-buffer))
 692       (nnheader-report 'nnimap "Can't open connection to server %s" server)
 693     (unless (or (imap-capability 'IMAP4 nnimap-server-buffer)
 694                 (imap-capability 'IMAP4rev1 nnimap-server-buffer))
 695       (imap-close nnimap-server-buffer)
 696       (nnheader-report 'nnimap "Server %s is not IMAP4 compliant" server))
 697     (let* ((list (gnus-parse-netrc nnimap-authinfo-file))
 698            (port (if nnimap-server-port
 699                      (int-to-string nnimap-server-port)
 700                    "imap"))
 701            (alist (gnus-netrc-machine list (or nnimap-server-address
 702                                                nnimap-address server)
 703                                       port "imap"))
 704            (user (gnus-netrc-get alist "login"))
 705            (passwd (gnus-netrc-get alist "password")))
 706       (if (imap-authenticate user passwd nnimap-server-buffer)
 707           (prog1
 708               (push (list server nnimap-server-buffer)
 709                     nnimap-server-buffer-alist)
 710             (nnimap-possibly-change-server server))
 711         (imap-close nnimap-server-buffer)
 712         (kill-buffer nnimap-server-buffer)
 713         (nnheader-report 'nnimap "Could not authenticate to %s" server)))))
 714
 715 (deffoo nnimap-open-server (server &optional defs)
 716   (nnheader-init-server-buffer)
 717   (if (nnimap-server-opened server)
 718       t
 719     (unless (assq 'nnimap-server-buffer defs)
 720       (push (list 'nnimap-server-buffer (concat " *nnimap* " server)) defs))
 721     ;; translate `nnimap-server-address' to `nnimap-address' in defs
 722     ;; for people that configured nnimap with a very old version
 723     (unless (assq 'nnimap-address defs)
 724       (if (assq 'nnimap-server-address defs)
 725           (push (list 'nnimap-address
 726                       (cadr (assq 'nnimap-server-address defs))) defs)
 727         (push (list 'nnimap-address server) defs)))
 728     (nnoo-change-server 'nnimap server defs)
 729     (or nnimap-server-buffer
 730         (setq nnimap-server-buffer (cadr (assq 'nnimap-server-buffer defs))))
 731     (with-current-buffer (get-buffer-create nnimap-server-buffer)
 732       (nnoo-change-server 'nnimap server defs))
 733     (or (and nnimap-server-buffer
 734              (imap-opened nnimap-server-buffer)
 735              (if (memq imap-state '(auth select examine))
 736                  t
 737                (imap-close nnimap-server-buffer)
 738                (nnimap-open-connection server)))
 739         (nnimap-open-connection server))))
 740
 741 (deffoo nnimap-server-opened (&optional server)
 742   "Whether SERVER is opened.
 743 If SERVER is the current virtual server, and the connection to the
 744 physical server is alive, this function return a non-nil value.  If
 745 SERVER is nil, it is treated as the current server."
 746   ;; clean up autologouts??
 747   (and (or server nnimap-current-server)
 748        (nnoo-server-opened 'nnimap (or server nnimap-current-server))
 749        (imap-opened (nnimap-get-server-buffer server))))
 750
 751 (deffoo nnimap-close-server (&optional server)
 752   "Close connection to server and free all resources connected to it.
 753 Return nil if the server couldn't be closed for some reason."
 754   (let ((server (or server nnimap-current-server)))
 755     (when (or (nnimap-server-opened server)
 756               (imap-opened (nnimap-get-server-buffer server)))
 757       (imap-close (nnimap-get-server-buffer server))
 758       (kill-buffer (nnimap-get-server-buffer server))
 759       (setq nnimap-server-buffer nil
 760             nnimap-current-server nil
 761             nnimap-server-buffer-alist
 762             (delq server nnimap-server-buffer-alist)))
 763     (nnoo-close-server 'nnimap server)))
 764
 765 (deffoo nnimap-request-close ()
 766   "Close connection to all servers and free all resources that the backend have reserved.
 767 All buffers that have been created by that
 768 backend should be killed.  (Not the nntp-server-buffer, though.) This
 769 function is generally only called when Gnus is shutting down."
 770   (mapcar (lambda (server) (nnimap-close-server (car server)))
 771           nnimap-server-buffer-alist)
 772   (setq nnimap-server-buffer-alist nil))
 773
 774 (deffoo nnimap-status-message (&optional server)
 775   "This function returns the last error message from server."
 776   (when (nnimap-possibly-change-server server)
 777     (nnoo-status-message 'nnimap server)))
 778
 779 (defun nnimap-demule (string)
 780   (funcall (if (and (fboundp 'string-as-multibyte)
 781                     (subrp (symbol-function 'string-as-multibyte)))
 782                'string-as-multibyte
 783              'identity)
 784            (or string "")))
 785
 786 (defun nnimap-callback ()
 787   (remove-hook 'imap-fetch-data-hook 'nnimap-callback)
 788   (with-current-buffer nnimap-callback-buffer
 789     (insert
 790      (with-current-buffer nnimap-server-buffer
 791        (nnimap-demule
 792         (if (imap-capability 'IMAP4rev1)
 793             ;; xxx don't just use car? alist doesn't contain
 794             ;; anything else now, but it might...
 795             (nth 2 (car (imap-message-get (imap-current-message) 'BODYDETAIL)))
 796           (imap-message-get (imap-current-message) 'RFC822)))))
 797     (nnheader-ms-strip-cr)
 798     (funcall nnimap-callback-callback-function t)))
 799
 800 (defun nnimap-request-article-part (article part prop &optional
 801                                             group server to-buffer detail)
 802   (when (nnimap-possibly-change-group group server)
 803     (let ((article (if (stringp article)
 804                        (car-safe (imap-search
 805                                   (format "HEADER Message-Id \"%s\"" article)
 806                                   nnimap-server-buffer))
 807                      article)))
 808       (when article
 809         (gnus-message 10 "nnimap: Fetching (part of) article %d..." article)
 810         (if (not nnheader-callback-function)
 811             (with-current-buffer (or to-buffer nntp-server-buffer)
 812               (erase-buffer)
 813               (let ((data (imap-fetch article part prop nil
 814                                       nnimap-server-buffer)))
 815                 (insert (nnimap-demule (if detail
 816                                            (nth 2 (car data))
 817                                          data))))
 818               (nnheader-ms-strip-cr)
 819               (gnus-message 10 "nnimap: Fetching (part of) article %d...done"
 820                             article)
 821               (if (bobp)
 822                   (nnheader-report 'nnimap "No such article: %s"
 823                                    (imap-error-text nnimap-server-buffer))
 824                 (cons group article)))
 825           (add-hook 'imap-fetch-data-hook 'nnimap-callback)
 826           (setq nnimap-callback-callback-function nnheader-callback-function
 827                 nnimap-callback-buffer nntp-server-buffer)
 828           (imap-fetch-asynch article part nil nnimap-server-buffer)
 829           (cons group article))))))
 830
 831 (deffoo nnimap-asynchronous-p ()
 832   t)
 833
 834 (deffoo nnimap-request-article (article &optional group server to-buffer)
 835   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 836       (nnimap-request-article-part
 837        article "BODY.PEEK[]" 'BODYDETAIL group server to-buffer 'detail)
 838     (nnimap-request-article-part
 839      article "RFC822.PEEK" 'RFC822 group server to-buffer)))
 840
 841 (deffoo nnimap-request-head (article &optional group server to-buffer)
 842   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 843       (nnimap-request-article-part
 844        article "BODY.PEEK[HEADER]" 'BODYDETAIL group server to-buffer 'detail)
 845     (nnimap-request-article-part
 846      article "RFC822.HEADER" 'RFC822.HEADER group server to-buffer)))
 847
 848 (deffoo nnimap-request-body (article &optional group server to-buffer)
 849   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 850       (nnimap-request-article-part
 851        article "BODY.PEEK[TEXT]" 'BODYDETAIL group server to-buffer 'detail)
 852     (nnimap-request-article-part
 853      article "RFC822.TEXT.PEEK" 'RFC822.TEXT group server to-buffer)))
 854
 855 (deffoo nnimap-request-group (group &optional server fast)
 856   (nnimap-request-update-info-internal
 857    group
 858    (gnus-get-info (gnus-group-prefixed-name
 859                    group (gnus-server-to-method (format "nnimap:%s" server))))
 860    server)
 861   (when (nnimap-possibly-change-group group server)
 862     (nnimap-before-find-minmax-bugworkaround)
 863     (let (info)
 864       (cond (fast group)
 865             ((null (setq info (nnimap-find-minmax-uid group t)))
 866              (nnheader-report 'nnimap "Could not get active info for %s"
 867                               group))
 868             (t
 869              (nnheader-insert "211 %d %d %d %s\n" (or (nth 0 info) 0)
 870                               (max 1 (or (nth 1 info) 1))
 871                               (or (nth 2 info) 0) group)
 872              (nnheader-report 'nnimap "Group %s selected" group)
 873              t)))))
 874
 875 (defun nnimap-update-unseen (group &optional server)
 876   "Update the unseen count in `nnimap-mailbox-info'."
 877   (gnus-sethash
 878    (gnus-group-prefixed-name group server)
 879    (let ((old (gnus-gethash-safe (gnus-group-prefixed-name group server)
 880                                  nnimap-mailbox-info)))
 881      (list (nth 0 old) (nth 1 old)
 882            (imap-mailbox-status group 'unseen nnimap-server-buffer)
 883            (nth 3 old)))
 884    nnimap-mailbox-info))
 885
 886 (defun nnimap-close-group (group &optional server)
 887   (with-current-buffer nnimap-server-buffer
 888     (when (and (imap-opened)
 889                (nnimap-possibly-change-group group server))
 890       (nnimap-update-unseen group server)
 891       (case nnimap-expunge-on-close
 892         (always (progn
 893                   (imap-mailbox-expunge nnimap-close-asynchronous)
 894                   (unless nnimap-dont-close
 895                     (imap-mailbox-close nnimap-close-asynchronous))))
 896         (ask (if (and (imap-search "DELETED")
 897                       (gnus-y-or-n-p (format "Expunge articles in group `%s'? "
 898                                              imap-current-mailbox)))
 899                  (progn
 900                    (imap-mailbox-expunge nnimap-close-asynchronous)
 901                    (unless nnimap-dont-close
 902                      (imap-mailbox-close nnimap-close-asynchronous)))
 903                (imap-mailbox-unselect)))
 904         (t (imap-mailbox-unselect)))
 905       (not imap-current-mailbox))))
 906
 907 (defun nnimap-pattern-to-list-arguments (pattern)
 908   (mapcar (lambda (p)
 909             (cons (car-safe p) (or (cdr-safe p) p)))
 910           (if (and (listp pattern)
 911                    (listp (cdr pattern)))
 912               pattern
 913             (list pattern))))
 914
 915 (deffoo nnimap-request-list (&optional server)
 916   (when (nnimap-possibly-change-server server)
 917     (with-current-buffer nntp-server-buffer
 918       (erase-buffer))
 919     (gnus-message 5 "nnimap: Generating active list%s..."
 920                   (if (> (length server) 0) (concat " for " server) ""))
 921     (nnimap-before-find-minmax-bugworkaround)
 922     (with-current-buffer nnimap-server-buffer
 923       (dolist (pattern (nnimap-pattern-to-list-arguments nnimap-list-pattern))
 924         (dolist (mbx (funcall nnimap-request-list-method
 925                               (cdr pattern) (car pattern)))
 926           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags mbx))
 927               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
 928                 (when info
 929                   (with-current-buffer nntp-server-buffer
 930                     (insert (format "\"%s\" %d %d y\n"
 931                                     mbx (or (nth 2 info) 0)
 932                                     (max 1 (or (nth 1 info) 1)))))))))))
 933     (gnus-message 5 "nnimap: Generating active list%s...done"
 934                   (if (> (length server) 0) (concat " for " server) ""))
 935     t))
 936
 937 (deffoo nnimap-request-post (&optional server)
 938   (let ((success t))
 939     (dolist (mbx (message-unquote-tokens
 940                   (message-tokenize-header
 941                    (message-fetch-field "Newsgroups") ", ")) success)
 942       (let ((to-newsgroup (gnus-group-prefixed-name mbx gnus-command-method)))
 943         (or (gnus-active to-newsgroup)
 944             (gnus-activate-group to-newsgroup)
 945             (if (gnus-y-or-n-p (format "No such group: %s.  Create it? "
 946                                        to-newsgroup))
 947                 (or (and (gnus-request-create-group
 948                           to-newsgroup gnus-command-method)
 949                          (gnus-activate-group to-newsgroup nil nil
 950                                               gnus-command-method))
 951                     (error "Couldn't create group %s" to-newsgroup)))
 952             (error "No such group: %s" to-newsgroup))
 953         (unless (nnimap-request-accept-article mbx (nth 1 gnus-command-method))
 954           (setq success nil))))))
 955
 956 ;; Optional backend functions
 957
 958 (defun nnimap-string-lessp-numerical (s1 s2)
 959   "Return t if first arg string is less than second in numerical order."
 960   (cond ((string= s1 s2)
 961          nil)
 962         ((> (length s1) (length s2))
 963          nil)
 964         ((< (length s1) (length s2))
 965          t)
 966         ((< (string-to-number (substring s1 0 1))
 967             (string-to-number (substring s2 0 1)))
 968          t)
 969         ((> (string-to-number (substring s1 0 1))
 970             (string-to-number (substring s2 0 1)))
 971          nil)
 972         (t
 973          (nnimap-string-lessp-numerical (substring s1 1) (substring s2 1)))))
 974
 975 (deffoo nnimap-retrieve-groups (groups &optional server)
 976   (when (nnimap-possibly-change-server server)
 977     (gnus-message 5 "nnimap: Checking mailboxes...")
 978     (with-current-buffer nntp-server-buffer
 979       (erase-buffer)
 980       (nnimap-before-find-minmax-bugworkaround)
 981       (let (asyncgroups slowgroups)
 982         (if (null nnimap-retrieve-groups-asynchronous)
 983             (setq slowgroups groups)
 984           (dolist (group groups)
 985             (gnus-message 9 "nnimap: Quickly checking mailbox %s" group)
 986             (add-to-list (if (gnus-gethash-safe
 987                               (gnus-group-prefixed-name group server)
 988                               nnimap-mailbox-info)
 989                              'asyncgroups
 990                            'slowgroups)
 991                          (list group (imap-mailbox-status-asynch
 992                                       group '(uidvalidity uidnext unseen)
 993                                       nnimap-server-buffer))))
 994           (dolist (asyncgroup asyncgroups)
 995             (let ((group (nth 0 asyncgroup))
 996                   (tag   (nth 1 asyncgroup))
 997                   new old)
 998               (when (imap-ok-p (imap-wait-for-tag tag nnimap-server-buffer))
 999                 (if (or (not (string=
1000                               (nth 0 (gnus-gethash (gnus-group-prefixed-name
1001                                                     group server)
1002                                                    nnimap-mailbox-info))
1003                               (imap-mailbox-get 'uidvalidity group
1004                                                 nnimap-server-buffer)))
1005                         (not (string=
1006                               (nth 1 (gnus-gethash (gnus-group-prefixed-name
1007                                                     group server)
1008                                                    nnimap-mailbox-info))
1009                               (imap-mailbox-get 'uidnext group
1010                                                 nnimap-server-buffer))))
1011                     (push (list group) slowgroups)
1012                   (insert (nth 3 (gnus-gethash (gnus-group-prefixed-name
1013                                                 group server)
1014                                                nnimap-mailbox-info))))))))
1015         (dolist (group slowgroups)
1016           (if nnimap-retrieve-groups-asynchronous
1017               (setq group (car group)))
1018           (gnus-message 7 "nnimap: Mailbox %s modified" group)
1019           (imap-mailbox-put 'uidnext nil group nnimap-server-buffer)
1020           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags group
1021                                                      nnimap-server-buffer))
1022               (let* ((info (nnimap-find-minmax-uid group 'examine))
1023                      (str (format "\"%s\" %d %d y\n" group
1024                                   (or (nth 2 info) 0)
1025                                   (max 1 (or (nth 1 info) 1)))))
1026                 (when (> (or (imap-mailbox-get 'recent group
1027                                                nnimap-server-buffer) 0)
1028                          0)
1029                   (push (list (cons group 0)) nnmail-split-history))
1030                 (insert str)
1031                 (when nnimap-retrieve-groups-asynchronous
1032                   (gnus-sethash
1033                    (gnus-group-prefixed-name group server)
1034                    (list (or (imap-mailbox-get
1035                               'uidvalidity group nnimap-server-buffer)
1036                              (imap-mailbox-status
1037                               group 'uidvalidity nnimap-server-buffer))
1038                          (or (imap-mailbox-get
1039                               'uidnext group nnimap-server-buffer)
1040                              (imap-mailbox-status
1041                               group 'uidnext nnimap-server-buffer))
1042                          (or (imap-mailbox-get
1043                               'unseen group nnimap-server-buffer)
1044                              (imap-mailbox-status
1045                               group 'unseen nnimap-server-buffer))
1046                          str)
1047                    nnimap-mailbox-info)))))))
1048     (gnus-message 5 "nnimap: Checking mailboxes...done")
1049     'active))
1050
1051 (deffoo nnimap-request-update-info-internal (group info &optional server)
1052   (when (nnimap-possibly-change-group group server)
1053     (when info ;; xxx what does this mean? should we create a info?
1054       (with-current-buffer nnimap-server-buffer
1055         (gnus-message 5 "nnimap: Updating info for %s..."
1056                       (gnus-info-group info))
1057
1058         (when (nnimap-mark-permanent-p 'read)
1059           (let (seen unseen)
1060             ;; read info could contain articles marked unread by other
1061             ;; imap clients!  we correct this
1062             (setq seen (gnus-uncompress-range (gnus-info-read info))
1063                   unseen (imap-search "UNSEEN UNDELETED")
1064                   seen (gnus-set-difference seen unseen)
1065                   ;; seen might lack articles marked as read by other
1066                   ;; imap clients! we correct this
1067                   seen (append seen (imap-search "SEEN"))
1068                   ;; remove dupes
1069                   seen (sort seen '<)
1070                   seen (gnus-compress-sequence seen t)
1071                   ;; we can't return '(1) since this isn't a "list of ranges",
1072                   ;; and we can't return '((1)) since g-list-of-unread-articles
1073                   ;; is buggy so we return '((1 . 1)).
1074                   seen (if (and (integerp (car seen))
1075                                 (null (cdr seen)))
1076                            (list (cons (car seen) (car seen)))
1077                          seen))
1078             (gnus-info-set-read info seen)))
1079
1080         (mapcar (lambda (pred)
1081                   (when (or (eq (cdr pred) 'recent)
1082                             (and (nnimap-mark-permanent-p (cdr pred))
1083                                  (member (nnimap-mark-to-flag (cdr pred))
1084                                          (imap-mailbox-get 'flags))))
1085                     (gnus-info-set-marks
1086                      info
1087                      (gnus-update-alist-soft
1088                       (cdr pred)
1089                       (gnus-compress-sequence
1090                        (imap-search (nnimap-mark-to-predicate (cdr pred))))
1091                       (gnus-info-marks info))
1092                      t)))
1093                 gnus-article-mark-lists)
1094
1095         (when nnimap-importantize-dormant
1096           ;; nnimap mark dormant article as ticked too (for other clients)
1097           ;; so we remove that mark for gnus since we support dormant
1098           (gnus-info-set-marks
1099            info
1100            (gnus-update-alist-soft
1101             'tick
1102             (gnus-remove-from-range
1103              (cdr-safe (assoc 'tick (gnus-info-marks info)))
1104              (cdr-safe (assoc 'dormant (gnus-info-marks info))))
1105             (gnus-info-marks info))
1106            t))
1107
1108         (gnus-message 5 "nnimap: Updating info for %s...done"
1109                       (gnus-info-group info))
1110
1111         info))))
1112
1113 (deffoo nnimap-request-type (group &optional article)
1114   (if (and nnimap-news-groups (string-match nnimap-news-groups group))
1115       'news
1116     'mail))
1117
1118 (deffoo nnimap-request-set-mark (group actions &optional server)
1119   (when (nnimap-possibly-change-group group server)
1120     (with-current-buffer nnimap-server-buffer
1121       (let (action)
1122         (gnus-message 7 "nnimap: Setting marks in %s..." group)
1123         (while (setq action (pop actions))
1124           (let ((range (nth 0 action))
1125                 (what  (nth 1 action))
1126                 (cmdmarks (nth 2 action))
1127                 marks)
1128             ;; bookmark can't be stored (not list/range
1129             (setq cmdmarks (delq 'bookmark cmdmarks))
1130             ;; killed can't be stored (not list/range
1131             (setq cmdmarks (delq 'killed cmdmarks))
1132             ;; unsent are for nndraft groups only
1133             (setq cmdmarks (delq 'unsent cmdmarks))
1134             ;; cache flags are pointless on the server
1135             (setq cmdmarks (delq 'cache cmdmarks))
1136             ;; seen flags are local to each gnus
1137             (setq cmdmarks (delq 'seen cmdmarks))
1138             ;; recent marks can't be set
1139             (setq cmdmarks (delq 'recent cmdmarks))
1140             (when nnimap-importantize-dormant
1141               ;; flag dormant articles as ticked
1142               (if (memq 'dormant cmdmarks)
1143                   (setq cmdmarks (cons 'tick cmdmarks))))
1144             ;; remove stuff we are forbidden to store
1145             (mapcar (lambda (mark)
1146                       (if (imap-message-flag-permanent-p
1147                            (nnimap-mark-to-flag mark))
1148                           (setq marks (cons mark marks))))
1149                     cmdmarks)
1150             (when (and range marks)
1151               (cond ((eq what 'del)
1152                      (imap-message-flags-del
1153                       (imap-range-to-message-set range)
1154                       (nnimap-mark-to-flag marks nil t)))
1155                     ((eq what 'add)
1156                      (imap-message-flags-add
1157                       (imap-range-to-message-set range)
1158                       (nnimap-mark-to-flag marks nil t)))
1159                     ((eq what 'set)
1160                      (imap-message-flags-set
1161                       (imap-range-to-message-set range)
1162                       (nnimap-mark-to-flag marks nil t)))))))
1163         (gnus-message 7 "nnimap: Setting marks in %s...done" group))))
1164   nil)
1165
1166 (defun nnimap-split-fancy ()
1167   "Like the function `nnmail-split-fancy', but uses `nnimap-split-fancy'."
1168   (let ((nnmail-split-fancy nnimap-split-fancy))
1169     (nnmail-split-fancy)))
1170
1171 (defun nnimap-split-to-groups (rules)
1172   ;; tries to match all rules in nnimap-split-rule against content of
1173   ;; nntp-server-buffer, returns a list of groups that matched.
1174   (with-current-buffer nntp-server-buffer
1175     ;; Fold continuation lines.
1176     (goto-char (point-min))
1177     (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
1178       (replace-match " " t t))
1179     (if (functionp rules)
1180         (funcall rules)
1181       (let (to-groups regrepp)
1182         (catch 'split-done
1183           (dolist (rule rules to-groups)
1184             (let ((group (car rule))
1185                   (regexp (cadr rule)))
1186               (goto-char (point-min))
1187               (when (and (if (stringp regexp)
1188                              (progn
1189                                (if (not (stringp group))
1190                                    (setq group (eval group))
1191                                  (setq regrepp
1192                                        (string-match "\\\\[0-9&]" group)))
1193                                (re-search-forward regexp nil t))
1194                            (funcall regexp group))
1195                          ;; Don't enter the article into the same group twice.
1196                          (not (assoc group to-groups)))
1197                 (push (if regrepp
1198                           (nnmail-expand-newtext group)
1199                         group)
1200                       to-groups)
1201                 (or nnimap-split-crosspost
1202                     (throw 'split-done to-groups))))))))))
1203
1204 (defun nnimap-assoc-match (key alist)
1205   (let (element)
1206     (while (and alist (not element))
1207       (if (string-match (car (car alist)) key)
1208           (setq element (car alist)))
1209       (setq alist (cdr alist)))
1210     element))
1211
1212 (defun nnimap-split-find-rule (server inbox)
1213   (if (and (listp nnimap-split-rule) (listp (car nnimap-split-rule))
1214            (list (cdar nnimap-split-rule)) (listp (cadar nnimap-split-rule)))
1215       ;; extended format
1216       (cadr (nnimap-assoc-match inbox (cdr (nnimap-assoc-match
1217                                             server nnimap-split-rule))))
1218     nnimap-split-rule))
1219
1220 (defun nnimap-split-find-inbox (server)
1221   (if (listp nnimap-split-inbox)
1222       nnimap-split-inbox
1223     (list nnimap-split-inbox)))
1224
1225 (defun nnimap-split-articles (&optional group server)
1226   (when (nnimap-possibly-change-server server)
1227     (with-current-buffer nnimap-server-buffer
1228       (let (rule inbox removeorig (inboxes (nnimap-split-find-inbox server)))
1229         ;; iterate over inboxes
1230         (while (and (setq inbox (pop inboxes))
1231                     (nnimap-possibly-change-group inbox)) ;; SELECT
1232           ;; find split rule for this server / inbox
1233           (when (setq rule (nnimap-split-find-rule server inbox))
1234             ;; iterate over articles
1235             (dolist (article (imap-search nnimap-split-predicate))
1236               (when (nnimap-request-head article)
1237                 ;; copy article to right group(s)
1238                 (setq removeorig nil)
1239                 (dolist (to-group (nnimap-split-to-groups rule))
1240                   (cond ((eq to-group 'junk)
1241                          (message "IMAP split removed %s:%s:%d" server inbox
1242                                   article)
1243                          (setq removeorig t))
1244                         ((imap-message-copy (number-to-string article)
1245                                             to-group nil 'nocopyuid)
1246                          (message "IMAP split moved %s:%s:%d to %s" server
1247                                   inbox article to-group)
1248                          (setq removeorig t)
1249                          (when nnmail-cache-accepted-message-ids
1250                            (with-current-buffer nntp-server-buffer
1251                              (let (msgid)
1252                                (and (setq msgid
1253                                           (nnmail-fetch-field "message-id"))
1254                                     (nnmail-cache-insert msgid to-group)))))
1255                          ;; Add the group-art list to the history list.
1256                          (push (list (cons to-group 0)) nnmail-split-history))
1257                         (t
1258                          (message "IMAP split failed to move %s:%s:%d to %s"
1259                                   server inbox article to-group))))
1260                 ;; remove article if it was successfully copied somewhere
1261                 (and removeorig
1262                      (imap-message-flags-add (format "%d" article)
1263                                              "\\Seen \\Deleted")))))
1264           (when (imap-mailbox-select inbox) ;; just in case
1265             ;; todo: UID EXPUNGE (if available) to remove splitted articles
1266             (imap-mailbox-expunge)
1267             (imap-mailbox-close)))
1268         (when nnmail-cache-accepted-message-ids
1269           (nnmail-cache-close))
1270         t))))
1271
1272 (deffoo nnimap-request-scan (&optional group server)
1273   (nnimap-split-articles group server))
1274
1275 (deffoo nnimap-request-newgroups (date &optional server)
1276   (when (nnimap-possibly-change-server server)
1277     (with-current-buffer nntp-server-buffer
1278       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s..."
1279                     (if (> (length server) 0) " on " "") server)
1280       (erase-buffer)
1281       (nnimap-before-find-minmax-bugworkaround)
1282       (dolist (pattern (nnimap-pattern-to-list-arguments
1283                         nnimap-list-pattern))
1284         (dolist (mbx (imap-mailbox-lsub "*" (car pattern) nil
1285                                         nnimap-server-buffer))
1286           (or (catch 'found
1287                 (dolist (mailbox (imap-mailbox-get 'list-flags mbx
1288                                                    nnimap-server-buffer))
1289                   (if (string= (downcase mailbox) "\\noselect")
1290                       (throw 'found t)))
1291                 nil)
1292               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1293                 (when info
1294                   (insert (format "\"%s\" %d %d y\n"
1295                                   mbx (or (nth 2 info) 0)
1296                                   (max 1 (or (nth 1 info) 1)))))))))
1297       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s...done"
1298                     (if (> (length server) 0) " on " "") server))
1299     t))
1300
1301 (deffoo nnimap-request-create-group (group &optional server args)
1302   (when (nnimap-possibly-change-server server)
1303     (or (imap-mailbox-status group 'uidvalidity nnimap-server-buffer)
1304         (imap-mailbox-create group nnimap-server-buffer))))
1305
1306 (defun nnimap-time-substract (time1 time2)
1307   "Return TIME for TIME1 - TIME2."
1308   (let* ((ms (- (car time1) (car time2)))
1309          (ls (- (nth 1 time1) (nth 1 time2))))
1310     (if (< ls 0)
1311         (list (- ms 1) (+ (expt 2 16) ls))
1312       (list ms ls))))
1313
1314 (defun nnimap-date-days-ago (daysago)
1315   "Return date, in format \"3-Aug-1998\", for DAYSAGO days ago."
1316   (let* ((time (nnimap-time-substract (current-time) (days-to-time daysago)))
1317          (date (format-time-string
1318                 (format "%%d-%s-%%Y"
1319                         (capitalize (car (rassoc (nth 4 (decode-time time))
1320                                                  parse-time-months))))
1321                 time)))
1322     (if (eq ?0 (string-to-char date))
1323         (substring date 1)
1324       date)))
1325
1326 (defun nnimap-request-expire-articles-progress ()
1327   (gnus-message 5 "nnimap: Marking article %d for deletion..."
1328                 imap-current-message))
1329
1330 (defun nnimap-expiry-target (arts group server)
1331   (unless (eq nnmail-expiry-target 'delete)
1332     (with-temp-buffer
1333       (dolist (art arts)
1334         (nnimap-request-article art group server (current-buffer))
1335         ;; hints for optimization in `nnimap-request-accept-article'
1336         (let ((nnimap-current-move-article art)
1337               (nnimap-current-move-group group)
1338               (nnimap-current-move-server server))
1339           (nnmail-expiry-target-group nnmail-expiry-target group))))
1340     ;; It is not clear if `nnmail-expiry-target' somehow cause the
1341     ;; current group to be changed or not, so we make sure here.
1342     (nnimap-possibly-change-group group server)))
1343
1344 ;; Notice that we don't actually delete anything, we just mark them deleted.
1345 (deffoo nnimap-request-expire-articles (articles group &optional server force)
1346   (let ((artseq (gnus-compress-sequence articles)))
1347     (when (and artseq (nnimap-possibly-change-group group server))
1348       (with-current-buffer nnimap-server-buffer
1349         (let ((days (or (and nnmail-expiry-wait-function
1350                              (funcall nnmail-expiry-wait-function group))
1351                         nnmail-expiry-wait)))
1352           (cond ((or force (eq days 'immediate))
1353                  (let ((oldarts (imap-search
1354                                  (concat "UID "
1355                                          (imap-range-to-message-set artseq)))))
1356                    (when oldarts
1357                      (nnimap-expiry-target oldarts group server)
1358                      (when (imap-message-flags-add
1359                             (imap-range-to-message-set oldarts) "\\Deleted")
1360                        (setq articles (gnus-set-difference
1361                                        articles oldarts))))))
1362                 ((numberp days)
1363                  (let ((oldarts (imap-search
1364                                  (format nnimap-expunge-search-string
1365                                          (imap-range-to-message-set artseq)
1366                                          (nnimap-date-days-ago days))))
1367                        (imap-fetch-data-hook
1368                         '(nnimap-request-expire-articles-progress)))
1369                    (when oldarts
1370                      (nnimap-expiry-target oldarts group server)
1371                      (when (imap-message-flags-add
1372                             (imap-range-to-message-set oldarts) "\\Deleted")
1373                        (setq articles (gnus-set-difference
1374                                        articles oldarts)))))))))))
1375   ;; return articles not deleted
1376   articles)
1377
1378 (deffoo nnimap-request-move-article (article group server
1379                                              accept-form &optional last)
1380   (when (nnimap-possibly-change-server server)
1381     (save-excursion
1382       (let ((buf (get-buffer-create " *nnimap move*"))
1383             (nnimap-current-move-article article)
1384             (nnimap-current-move-group group)
1385             (nnimap-current-move-server nnimap-current-server)
1386             result)
1387         (and (nnimap-request-article article group server)
1388              (save-excursion
1389                (set-buffer buf)
1390                (buffer-disable-undo (current-buffer))
1391                (insert-buffer-substring nntp-server-buffer)
1392                (setq result (eval accept-form))
1393                (kill-buffer buf)
1394                result)
1395              (imap-message-flags-add
1396               (imap-range-to-message-set (list article))
1397               "\\Deleted" 'silent nnimap-server-buffer))
1398         result))))
1399
1400 (deffoo nnimap-request-accept-article (group &optional server last)
1401   (when (nnimap-possibly-change-server server)
1402     (let (uid)
1403       (if (setq uid
1404                 (if (string= nnimap-current-server nnimap-current-move-server)
1405                     ;; moving article within same server, speed it up...
1406                     (and (nnimap-possibly-change-group
1407                           nnimap-current-move-group)
1408                          (imap-message-copy (number-to-string
1409                                              nnimap-current-move-article)
1410                                             group 'dontcreate nil
1411                                             nnimap-server-buffer))
1412                   (with-current-buffer (current-buffer)
1413                     (goto-char (point-min))
1414                     ;; remove any 'From blabla' lines, some IMAP servers
1415                     ;; reject the entire message otherwise.
1416                     (when (looking-at "^From[^:]")
1417                       (kill-region (point) (progn (forward-line) (point))))
1418                     ;; turn into rfc822 format (\r\n eol's)
1419                     (while (search-forward "\n" nil t)
1420                       (replace-match "\r\n"))
1421                     (when nnmail-cache-accepted-message-ids
1422                       (nnmail-cache-insert (nnmail-fetch-field "message-id")
1423                                            group)))
1424                   (when (and last nnmail-cache-accepted-message-ids)
1425                     (nnmail-cache-close))
1426                   ;; this 'or' is for Cyrus server bug
1427                   (or (null (imap-current-mailbox nnimap-server-buffer))
1428                       (imap-mailbox-unselect nnimap-server-buffer))
1429                   (imap-message-append group (current-buffer) nil nil
1430                                        nnimap-server-buffer)))
1431           (cons group (nth 1 uid))
1432         (nnheader-report 'nnimap (imap-error-text nnimap-server-buffer))))))
1433
1434 (deffoo nnimap-request-delete-group (group force &optional server)
1435   (when (nnimap-possibly-change-server server)
1436     (with-current-buffer nnimap-server-buffer
1437       (if force
1438           (or (null (imap-mailbox-status group 'uidvalidity))
1439               (imap-mailbox-delete group))
1440         ;; UNSUBSCRIBE?
1441         t))))
1442
1443 (deffoo nnimap-request-rename-group (group new-name &optional server)
1444   (when (nnimap-possibly-change-server server)
1445     (imap-mailbox-rename group new-name nnimap-server-buffer)))
1446
1447 (defun nnimap-expunge (mailbox server)
1448   (when (nnimap-possibly-change-group mailbox server)
1449     (imap-mailbox-expunge nil nnimap-server-buffer)))
1450
1451 (defun nnimap-acl-get (mailbox server)
1452   (when (nnimap-possibly-change-server server)
1453     (and (imap-capability 'ACL nnimap-server-buffer)
1454          (imap-mailbox-acl-get mailbox nnimap-server-buffer))))
1455
1456 (defun nnimap-acl-edit (mailbox method old-acls new-acls)
1457   (when (nnimap-possibly-change-server (cadr method))
1458     (unless (imap-capability 'ACL nnimap-server-buffer)
1459       (error "Your server does not support ACL editing"))
1460     (with-current-buffer nnimap-server-buffer
1461       ;; delete all removed identifiers
1462       (mapcar (lambda (old-acl)
1463                 (unless (assoc (car old-acl) new-acls)
1464                   (or (imap-mailbox-acl-delete (car old-acl) mailbox)
1465                       (error "Can't delete ACL for %s" (car old-acl)))))
1466               old-acls)
1467       ;; set all changed acl's
1468       (mapcar (lambda (new-acl)
1469                 (let ((new-rights (cdr new-acl))
1470                       (old-rights (cdr (assoc (car new-acl) old-acls))))
1471                   (unless (and old-rights new-rights
1472                                (string= old-rights new-rights))
1473                     (or (imap-mailbox-acl-set (car new-acl) new-rights mailbox)
1474                         (error "Can't set ACL for %s to %s" (car new-acl)
1475                                new-rights)))))
1476               new-acls)
1477       t)))
1478
1479 \f
1480 ;;; Internal functions
1481
1482 ;;
1483 ;; This is confusing.
1484 ;;
1485 ;; mark      => read, tick, draft, reply etc
1486 ;; flag      => "\\Seen", "\\Flagged", "\\Draft", "gnus-expire" etc
1487 ;; predicate => "SEEN", "FLAGGED", "DRAFT", "KEYWORD gnus-expire" etc
1488 ;;
1489 ;; Mark should not really contain 'read since it's not a "mark" in the Gnus
1490 ;; world, but we cheat.  Mark == gnus-article-mark-lists + '(read . read).
1491 ;;
1492
1493 (defconst nnimap-mark-to-predicate-alist
1494   (mapcar
1495    (lambda (pair)                       ; cdr is the mark
1496      (or (assoc (cdr pair)
1497                 '((read . "SEEN")
1498                   (tick . "FLAGGED")
1499                   (draft . "DRAFT")
1500                   (recent . "RECENT")
1501                   (reply . "ANSWERED")))
1502          (cons (cdr pair)
1503                (format "KEYWORD gnus-%s" (symbol-name (cdr pair))))))
1504    (cons '(read . read) gnus-article-mark-lists)))
1505
1506 (defun nnimap-mark-to-predicate (pred)
1507   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP predicate.
1508 This is a string such as \"SEEN\", \"FLAGGED\", \"KEYWORD gnus-expire\",
1509 to be used within a IMAP SEARCH query."
1510   (cdr (assq pred nnimap-mark-to-predicate-alist)))
1511
1512 (defconst nnimap-mark-to-flag-alist
1513   (mapcar
1514    (lambda (pair)
1515      (or (assoc (cdr pair)
1516                 '((read . "\\Seen")
1517                   (tick . "\\Flagged")
1518                   (draft . "\\Draft")
1519                   (recent . "\\Recent")
1520                   (reply . "\\Answered")))
1521          (cons (cdr pair)
1522                (format "gnus-%s" (symbol-name (cdr pair))))))
1523    (cons '(read . read) gnus-article-mark-lists)))
1524
1525 (defun nnimap-mark-to-flag-1 (preds)
1526   (if (and (not (null preds)) (listp preds))
1527       (cons (nnimap-mark-to-flag (car preds))
1528             (nnimap-mark-to-flag (cdr preds)))
1529     (cdr (assoc preds nnimap-mark-to-flag-alist))))
1530
1531 (defun nnimap-mark-to-flag (preds &optional always-list make-string)
1532   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP flag.
1533 This is a string such as \"\\Seen\", \"\\Flagged\", \"gnus-expire\", to
1534 be used in a STORE FLAGS command."
1535   (let ((result (nnimap-mark-to-flag-1 preds)))
1536     (setq result (if (and (or make-string always-list)
1537                           (not (listp result)))
1538                      (list result)
1539                    result))
1540     (if make-string
1541         (mapconcat (lambda (flag)
1542                      (if (listp flag)
1543                          (mapconcat 'identity flag " ")
1544                        flag))
1545                    result " ")
1546       result)))
1547
1548 (defun nnimap-mark-permanent-p (mark &optional group)
1549   "Return t iff MARK can be permanently (between IMAP sessions) saved on articles, in GROUP."
1550   (imap-message-flag-permanent-p (nnimap-mark-to-flag mark)))
1551
1552 (when nnimap-debug
1553   (require 'trace)
1554   (buffer-disable-undo (get-buffer-create nnimap-debug))
1555   (mapcar (lambda (f) (trace-function-background f nnimap-debug))
1556           '(
1557             nnimap-possibly-change-server
1558             nnimap-verify-uidvalidity
1559             nnimap-find-minmax-uid
1560             nnimap-before-find-minmax-bugworkaround
1561             nnimap-possibly-change-group
1562             ;;nnimap-replace-whitespace
1563             nnimap-retrieve-headers-progress
1564             nnimap-retrieve-which-headers
1565             nnimap-group-overview-filename
1566             nnimap-retrieve-headers-from-file
1567             nnimap-retrieve-headers-from-server
1568             nnimap-retrieve-headers
1569             nnimap-open-connection
1570             nnimap-open-server
1571             nnimap-server-opened
1572             nnimap-close-server
1573             nnimap-request-close
1574             nnimap-status-message
1575             ;;nnimap-demule
1576             nnimap-request-article-part
1577             nnimap-request-article
1578             nnimap-request-head
1579             nnimap-request-body
1580             nnimap-request-group
1581             nnimap-close-group
1582             nnimap-pattern-to-list-arguments
1583             nnimap-request-list
1584             nnimap-request-post
1585             nnimap-retrieve-groups
1586             nnimap-request-update-info-internal
1587             nnimap-request-type
1588             nnimap-request-set-mark
1589             nnimap-split-to-groups
1590             nnimap-split-find-rule
1591             nnimap-split-find-inbox
1592             nnimap-split-articles
1593             nnimap-request-scan
1594             nnimap-request-newgroups
1595             nnimap-request-create-group
1596             nnimap-time-substract
1597             nnimap-date-days-ago
1598             nnimap-request-expire-articles-progress
1599             nnimap-request-expire-articles
1600             nnimap-request-move-article
1601             nnimap-request-accept-article
1602             nnimap-request-delete-group
1603             nnimap-request-rename-group
1604             gnus-group-nnimap-expunge
1605             gnus-group-nnimap-edit-acl
1606             gnus-group-nnimap-edit-acl-done
1607             nnimap-group-mode-hook
1608             nnimap-mark-to-predicate
1609             nnimap-mark-to-flag-1
1610             nnimap-mark-to-flag
1611             nnimap-mark-permanent-p
1612             )))
1613
1614 (provide 'nnimap)
1615
1616 ;;; nnimap.el ends here