cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- imap backend for Gnus
   2 ;; Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   3
   4 ;; Author: Simon Josefsson <jas@pdc.kth.se>
   5 ;;         Jim Radford <radford@robby.caltech.edu>
   6 ;; Keywords: mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Todo, major things:
  28 ;;
  29 ;;   o Fix Gnus to view correct number of unread/total articles in group buffer
  30 ;;   o Fix Gnus to handle leading '.' in group names (fixed?)
  31 ;;   o Finish disconnected mode (moving articles between mailboxes unplugged)
  32 ;;   o Sieve
  33 ;;   o MIME (partial article fetches)
  34 ;;   o Split to other backends, different split rules for different
  35 ;;     servers/inboxes
  36 ;;
  37 ;; Todo, minor things:
  38 ;;
  39 ;;   o Don't require half of Gnus -- backends should be standalone
  40 ;;   o Verify that we don't use IMAP4rev1 specific things (RFC2060 App B)
  41 ;;   o Dont uid fetch 1,* in nnimap-retrive-groups (slow)
  42 ;;   o Split up big fetches (1,* header especially) in smaller chunks
  43 ;;   o What do I do with gnus-newsgroup-*?
  44 ;;   o Tell Gnus about new groups (how can we tell?)
  45 ;;   o Respooling (fix Gnus?) (unnecessery?)
  46 ;;   o Add support for the following: (if applicable)
  47 ;;       request-list-newsgroups, request-regenerate
  48 ;;       list-active-group,
  49 ;;       request-associate-buffer, request-restore-buffer,
  50 ;;   o Do The Right Thing when UIDVALIDITY changes (what's the right thing?)
  51 ;;   o Support RFC2221 (Login referrals)
  52 ;;   o IMAP2BIS compatibility? (RFC2061)
  53 ;;   o ACAP stuff (perhaps a different project, would be nice to ACAPify
  54 ;;     .newsrc.eld)
  55 ;;   o What about Gnus's article editing, can we support it?  NO!
  56 ;;   o Use \Draft to support the draft group??
  57 ;;   o Duplicate suppression
  58
  59 ;;; Code:
  60
  61 (eval-and-compile
  62   (require 'cl)
  63   (require 'imap))
  64
  65 (require 'nnoo)
  66 (require 'nnmail)
  67 (require 'nnheader)
  68 (require 'mm-util)
  69 (require 'gnus)
  70 (require 'gnus-range)
  71 (require 'gnus-start)
  72 (require 'gnus-int)
  73
  74 (nnoo-declare nnimap)
  75
  76 (defconst nnimap-version "nnimap 1.0")
  77
  78 (defgroup nnimap nil
  79   "Reading IMAP mail with Gnus."
  80   :group 'gnus)
  81
  82 (defvoo nnimap-address nil
  83   "Address of physical IMAP server.  If nil, use the virtual server's name.")
  84
  85 (defvoo nnimap-server-port nil
  86   "Port number on physical IMAP server.
  87 If nil, defaults to 993 for SSL connections and 143 otherwise.")
  88
  89 ;; Splitting variables
  90
  91 (defcustom nnimap-split-crosspost t
  92   "If non-nil, do crossposting if several split methods match the mail.
  93 If nil, the first match found will be used."
  94   :group 'nnimap
  95   :type 'boolean)
  96
  97 (defcustom nnimap-split-inbox nil
  98   "*Name of mailbox to split mail from.
  99
 100 Mail is read from this mailbox and split according to rules in
 101 `nnimap-split-rule'.
 102
 103 This can be a string or a list of strings."
 104   :group 'nnimap
 105   :type '(choice (string)
 106                  (repeat string)))
 107
 108 (define-widget 'nnimap-strict-function 'function
 109   "This widget only matches values that are functionp.
 110
 111 Warning: This means that a value that is the symbol of a not yet
 112 loaded function will not match.  Use with care."
 113   :match 'nnimap-strict-function-match)
 114
 115 (defun nnimap-strict-function-match (widget value)
 116   "Ignoring WIDGET, match if VALUE is a function."
 117   (functionp value))
 118
 119 (defcustom nnimap-split-rule nil
 120   "Mail will be split according to theese rules.
 121
 122 Mail is read from mailbox(es) specified in `nnimap-split-inbox'.
 123
 124 If you'd like, for instance, one mail group for mail from the
 125 \"gnus-imap\" mailing list, one group for junk mail and leave
 126 everything else in the incoming mailbox, you could do something like
 127 this:
 128
 129 \(setq nnimap-split-rule '((\"INBOX.gnus-imap\"   \"From:.*gnus-imap\")
 130                           (\"INBOX.junk\"        \"Subject:.*buy\")))
 131
 132 As you can see, `nnimap-split-rule' is a list of lists, where the first
 133 element in each \"rule\" is the name of the IMAP mailbox, and the
 134 second is a regexp that nnimap will try to match on the header to find
 135 a fit.
 136
 137 The second element can also be a function.  In that case, it will be
 138 called narrowed to the headers with the first element of the rule as
 139 the argument.  It should return a non-nil value if it thinks that the
 140 mail belongs in that group.
 141
 142 This variable can also have a function as its value, the function will
 143 be called with the headers narrowed and should return a group where it
 144 thinks the article should be splitted to.  See `nnimap-split-fancy'.
 145
 146 To allow for different split rules on different virtual servers, and
 147 even different split rules in different inboxes on the same server,
 148 the syntax of this variable have been extended along the lines of:
 149
 150 \(setq nnimap-split-rule
 151       '((\"my1server\"    (\".*\"    ((\"ding\"    \"ding@gnus.org\")
 152                                   (\"junk\"    \"From:.*Simon\")))
 153         (\"my2server\"    (\"INBOX\" nnimap-split-fancy))
 154         (\"my[34]server\" (\".*\"    ((\"private\" \"To:.*Simon\")
 155                                   (\"junk\"    my-junk-func)))))
 156
 157 The virtual server name is in fact a regexp, so that the same rules
 158 may apply to several servers.  In the example, the servers
 159 \"my3server\" and \"my4server\" both use the same rules.  Similarly,
 160 the inbox string is also a regexp.  The actual splitting rules are as
 161 before, either a function, or a list with group/regexp or
 162 group/function elements."
 163   :group 'nnimap
 164   :type '(choice :tag "Rule type"
 165                  (repeat :menu-tag "Single-server"
 166                          :tag "Single-server list"
 167                          (list (string :tag "Mailbox")
 168                                (choice :tag "Predicate"
 169                                        (regexp :tag "A regexp")
 170                                        (nnimap-strict-function :tag "A function"))))
 171                  (choice :menu-tag "A function"
 172                          :tag "A function"
 173                          (function-item nnimap-split-fancy)
 174                          (function-item nnmail-split-fancy)
 175                          (nnimap-strict-function :tag "User-defined function"))
 176                  (repeat :menu-tag "Multi-server (extended)"
 177                          :tag "Multi-server list"
 178                          (list (regexp :tag "Server regexp")
 179                                (list (regexp :tag "Incoming Mailbox regexp")
 180                                      (repeat :tag "Rules for matching server(s) and mailbox(es)"
 181                                              (list (string :tag "Destination mailbox")
 182                                                    (choice :tag "Predicate"
 183                                                            (regexp :tag "A Regexp")
 184                                                            (nnimap-strict-function :tag "A Function")))))))))
 185
 186 (defcustom nnimap-split-predicate "UNSEEN UNDELETED"
 187   "The predicate used to find articles to split.
 188 If you use another IMAP client to peek on articles but always would
 189 like nnimap to split them once it's started, you could change this to
 190 \"UNDELETED\". Other available predicates are available in
 191 RFC2060 section 6.4.4."
 192   :group 'nnimap
 193   :type 'string)
 194
 195 (defcustom nnimap-split-fancy nil
 196   "Like `nnmail-split-fancy', which see."
 197   :group 'nnimap
 198   :type 'sexp)
 199
 200 ;; Authorization / Privacy variables
 201
 202 (defvoo nnimap-auth-method nil
 203   "Obsolete.")
 204
 205 (defvoo nnimap-stream nil
 206   "How nnimap will connect to the server.
 207
 208 The default, nil, will try to use the \"best\" method the server can
 209 handle.
 210
 211 Change this if
 212
 213 1) you want to connect with SSL.  The SSL integration with IMAP is
 214    brain-dead so you'll have to tell it specifically.
 215
 216 2) your server is more capable than your environment -- i.e. your
 217    server accept Kerberos login's but you haven't installed the
 218    `imtest' program or your machine isn't configured for Kerberos.
 219
 220 Possible choices: kerberos4, ssl, network")
 221
 222 (defvoo nnimap-authenticator nil
 223   "How nnimap authenticate itself to the server.
 224
 225 The default, nil, will try to use the \"best\" method the server can
 226 handle.
 227
 228 There is only one reason for fiddling with this variable, and that is
 229 if your server is more capable than your environment -- i.e. you
 230 connect to a server that accept Kerberos login's but you haven't
 231 installed the `imtest' program or your machine isn't configured for
 232 Kerberos.
 233
 234 Possible choices: kerberos4, cram-md5, login, anonymous.")
 235
 236 (defvoo nnimap-directory (nnheader-concat gnus-directory "overview/")
 237   "Directory to keep NOV cache files for nnimap groups.
 238 See also `nnimap-nov-file-name'.")
 239
 240 (defvoo nnimap-nov-file-name "nnimap."
 241   "NOV cache base filename.
 242 The group name and `nnimap-nov-file-name-suffix' will be appended.  A
 243 typical complete file name would be
 244 ~/News/overview/nnimap.pdc.INBOX.ding.nov, or
 245 ~/News/overview/nnimap/pdc/INBOX/ding/nov if
 246 `nnmail-use-long-file-names' is nil")
 247
 248 (defvoo nnimap-nov-file-name-suffix ".novcache"
 249   "Suffix for NOV cache base filename.")
 250
 251 (defvoo nnimap-nov-is-evil nil
 252   "If non-nil, nnimap will never generate or use a local nov database for this backend.
 253 Using nov databases will speed up header fetching considerably.
 254 Unlike other backends, you do not need to take special care if you
 255 flip this variable.")
 256
 257 (defvoo nnimap-expunge-on-close 'always ; 'ask, 'never
 258   "Whether to expunge a group when it is closed.
 259 When a IMAP group with articles marked for deletion is closed, this
 260 variable determine if nnimap should actually remove the articles or
 261 not.
 262
 263 If always, nnimap always perform a expunge when closing the group.
 264 If never, nnimap never expunges articles marked for deletion.
 265 If ask, nnimap will ask you if you wish to expunge marked articles.
 266
 267 When setting this variable to `never', you can only expunge articles
 268 by using `G x' (gnus-group-nnimap-expunge) from the Group buffer.")
 269
 270 (defvoo nnimap-list-pattern "*"
 271   "A string LIMIT or list of strings with mailbox wildcards used to limit available groups.
 272 See below for available wildcards.
 273
 274 The LIMIT string can be a cons cell (REFERENCE . LIMIT), where
 275 REFERENCE will be passed as the first parameter to LIST/LSUB.  The
 276 semantics of this are server specific, on the University of Washington
 277 server you can specify a directory.
 278
 279 Example:
 280  '(\"INBOX\" \"mail/*\" (\"~friend/mail/\" . \"list/*\"))
 281
 282 There are two wildcards * and %. * matches everything, % matches
 283 everything in the current hierarchy.")
 284
 285 (defvoo nnimap-news-groups nil
 286   "IMAP support a news-like mode, also known as bulletin board mode,
 287 where replies is sent via IMAP instead of SMTP.
 288
 289 This variable should contain a regexp matching groups where you wish
 290 replies to be stored to the mailbox directly.
 291
 292 Example:
 293   '(\"^[^I][^N][^B][^O][^X].*$\")
 294
 295 This will match all groups not beginning with \"INBOX\".
 296
 297 Note that there is nothing technically different between mail-like and
 298 news-like mailboxes.  If you wish to have a group with todo items or
 299 similar which you wouldn't want to set up a mailing list for, you can
 300 use this to make replies go directly to the group.")
 301
 302 (defvoo nnimap-expunge-search-string "UID %s NOT SINCE %s"
 303   "*IMAP search command to use for articles that are to be expired.
 304 The first %s is replaced by a UID set of articles to search on,
 305 and the second %s is replaced by a date criterium.
 306
 307 One useful (and perhaps the only useful) value to change this to would
 308 be `UID %s NOT SENTSINCE %s' to make nnimap use the Date: header
 309 instead of the internal date of messages.  See section 6.4.4 of RFC
 310 2060 for more information on valid strings.")
 311
 312 (defvoo nnimap-importantize-dormant t
 313   "*If non-nil, mark \"dormant\" articles as \"ticked\" for other IMAP clients.
 314 Note that within Gnus, dormant articles will still (only) be
 315 marked as ticked.  This is to make \"dormant\" articles stand out,
 316 just like \"ticked\" articles, in other IMAP clients.")
 317
 318 (defvoo nnimap-server-address nil
 319   "Obsolete.  Use `nnimap-address'.")
 320
 321 (defcustom nnimap-authinfo-file "~/.authinfo"
 322   "Authorization information for IMAP servers.  In .netrc format."
 323   :type
 324   '(choice file
 325            (repeat :tag "Entries"
 326                    :menu-tag "Inline"
 327                    (list :format "%v"
 328                          :value ("" ("login" . "") ("password" . ""))
 329                          (string :tag "Host")
 330                          (checklist :inline t
 331                                     (cons :format "%v"
 332                                           (const :format "" "login")
 333                                           (string :format "Login: %v"))
 334                                     (cons :format "%v"
 335                                           (const :format "" "password")
 336                                           (string :format "Password: %v")))))))
 337
 338 (defcustom nnimap-prune-cache t
 339   "If non-nil, nnimap check whether articles still exist on server before using data stored in NOV cache."
 340   :type 'boolean)
 341
 342 (defvar nnimap-request-list-method 'imap-mailbox-list
 343   "Method to use to request a list of all folders from the server.
 344 If this is 'imap-mailbox-lsub, then use a server-side subscription list to
 345 restrict visible folders.")
 346
 347 ;; Internal variables:
 348
 349 (defvar nnimap-debug nil
 350   "Name of buffer to record debugging info.
 351 For example: (setq nnimap-debug \"*nnimap-debug*\")")
 352 (defvar nnimap-current-move-server nil)
 353 (defvar nnimap-current-move-group nil)
 354 (defvar nnimap-current-move-article nil)
 355 (defvar nnimap-length)
 356 (defvar nnimap-progress-chars '(?| ?/ ?- ?\\))
 357 (defvar nnimap-progress-how-often 20)
 358 (defvar nnimap-counter)
 359 (defvar nnimap-callback-callback-function nil
 360   "Gnus callback the nnimap asynchronous callback should call.")
 361 (defvar nnimap-callback-buffer nil
 362   "Which buffer the asynchronous article prefetch callback should work in.")
 363 (defvar nnimap-server-buffer-alist nil) ;; Map server name to buffers.
 364 (defvar nnimap-current-server nil) ;; Current server
 365 (defvar nnimap-server-buffer nil) ;; Current servers' buffer
 366
 367 \f
 368
 369 (nnoo-define-basics nnimap)
 370
 371 ;; Utility functions:
 372
 373 (defsubst nnimap-get-server-buffer (server)
 374   "Return buffer for SERVER, if nil use current server."
 375   (cadr (assoc (or server nnimap-current-server) nnimap-server-buffer-alist)))
 376
 377 (defun nnimap-possibly-change-server (server)
 378   "Return buffer for SERVER, changing the current server as a side-effect.
 379 If SERVER is nil, uses the current server."
 380   (setq nnimap-current-server (or server nnimap-current-server)
 381         nnimap-server-buffer (nnimap-get-server-buffer nnimap-current-server)))
 382
 383 (defun nnimap-verify-uidvalidity (group server)
 384   "Verify stored uidvalidity match current one in GROUP on SERVER."
 385   (let* ((gnusgroup (gnus-group-prefixed-name
 386                      group (gnus-server-to-method
 387                             (format "nnimap:%s" server))))
 388          (new-uidvalidity (imap-mailbox-get 'uidvalidity))
 389          (old-uidvalidity (gnus-group-get-parameter gnusgroup 'uidvalidity))
 390          (dir (file-name-as-directory (expand-file-name nnimap-directory)))
 391          (nameuid (nnheader-translate-file-chars
 392                    (concat nnimap-nov-file-name
 393                            (if (equal server "")
 394                                "unnamed"
 395                              server) "." group "." old-uidvalidity
 396                            nnimap-nov-file-name-suffix) t))
 397          (file (if (or nnmail-use-long-file-names
 398                        (file-exists-p (expand-file-name nameuid dir)))
 399                    (expand-file-name nameuid dir)
 400                  (expand-file-name
 401                   (mm-encode-coding-string
 402                    (nnheader-replace-chars-in-string nameuid ?. ?/)
 403                    nnmail-pathname-coding-system)
 404                   dir))))
 405     (if old-uidvalidity
 406         (if (not (equal old-uidvalidity new-uidvalidity))
 407             ;; uidvalidity clash
 408             (gnus-delete-file file)
 409           (gnus-group-set-parameter gnusgroup 'uidvalidity new-uidvalidity)
 410           t)
 411       (gnus-group-add-parameter gnusgroup (cons 'uidvalidity new-uidvalidity))
 412       t)))
 413
 414 (defun nnimap-before-find-minmax-bugworkaround ()
 415   "Function called before iterating through mailboxes with
 416 `nnimap-find-minmax-uid'."
 417   ;; XXX this is for UoW imapd problem, it doesn't notice new mail in
 418   ;; currently selected mailbox without a re-select/examine.
 419   (or (null (imap-current-mailbox nnimap-server-buffer))
 420       (imap-mailbox-unselect nnimap-server-buffer)))
 421
 422 (defun nnimap-find-minmax-uid (group &optional examine)
 423   "Find lowest and highest active article nummber in GROUP.
 424 If EXAMINE is non-nil the group is selected read-only."
 425   (with-current-buffer nnimap-server-buffer
 426     (when (imap-mailbox-select group examine)
 427       (let (minuid maxuid)
 428         (when (> (imap-mailbox-get 'exists) 0)
 429           (imap-fetch "1,*" "UID" nil 'nouidfetch)
 430           (imap-message-map (lambda (uid Uid)
 431                               (setq minuid (if minuid (min minuid uid) uid)
 432                                     maxuid (if maxuid (max maxuid uid) uid)))
 433                             'UID))
 434         (list (imap-mailbox-get 'exists) minuid maxuid)))))
 435
 436 (defun nnimap-possibly-change-group (group &optional server)
 437   "Make GROUP the current group, and SERVER the current server."
 438   (when (nnimap-possibly-change-server server)
 439     (with-current-buffer nnimap-server-buffer
 440       (if (or (null group) (imap-current-mailbox-p group))
 441           imap-current-mailbox
 442         (if (imap-mailbox-select group)
 443             (if (or (nnimap-verify-uidvalidity
 444                      group (or server nnimap-current-server))
 445                     (zerop (imap-mailbox-get 'exists group))
 446                     t ;; for OGnus to see if ignoring uidvalidity
 447                     ;; changes has any bad effects.
 448                     (yes-or-no-p
 449                      (format
 450                       "nnimap: Group %s is not uidvalid.  Continue? " group)))
 451                 imap-current-mailbox
 452               (imap-mailbox-unselect)
 453               (error "nnimap: Group %s is not uid-valid" group))
 454           (nnheader-report 'nnimap (imap-error-text)))))))
 455
 456 (defun nnimap-replace-whitespace (string)
 457   "Return STRING with all whitespace replaced with space."
 458   (when string
 459     (while (string-match "[\r\n\t]+" string)
 460       (setq string (replace-match " " t t string)))
 461     string))
 462
 463 ;; Required backend functions
 464
 465 (defun nnimap-retrieve-headers-progress ()
 466   "Hook to insert NOV line for current article into `nntp-server-buffer'."
 467   (and (numberp nnmail-large-newsgroup)
 468        (zerop (% (incf nnimap-counter) nnimap-progress-how-often))
 469        (> nnimap-length nnmail-large-newsgroup)
 470        (nnheader-message 6 "nnimap: Retrieving headers... %c"
 471                          (nth (/ (% nnimap-counter
 472                                     (* (length nnimap-progress-chars)
 473                                        nnimap-progress-how-often))
 474                                  nnimap-progress-how-often)
 475                               nnimap-progress-chars)))
 476   (with-current-buffer nntp-server-buffer
 477     (let (headers lines chars uid mbx)
 478       (with-current-buffer nnimap-server-buffer
 479         (setq uid imap-current-message
 480               mbx imap-current-mailbox
 481               headers (nnimap-demule
 482                        (if (imap-capability 'IMAP4rev1)
 483                       ;; xxx don't just use car? alist doesn't contain
 484                            ;; anything else now, but it might...
 485                            (nth 2 (car (imap-message-get uid 'BODYDETAIL)))
 486                          (imap-message-get uid 'RFC822.HEADER)))
 487               lines (imap-body-lines (imap-message-body imap-current-message))
 488               chars (imap-message-get imap-current-message 'RFC822.SIZE)))
 489       (nnheader-insert-nov
 490        (with-temp-buffer
 491          (buffer-disable-undo)
 492          (insert headers)
 493          (nnheader-ms-strip-cr)
 494          (nnheader-fold-continuation-lines)
 495          (subst-char-in-region (point-min) (point-max) ?\t ? )
 496          (let ((head (nnheader-parse-head 'naked)))
 497            (mail-header-set-number head uid)
 498            (mail-header-set-chars head chars)
 499            (mail-header-set-lines head lines)
 500            (mail-header-set-xref
 501             head (format "%s %s:%d" (system-name) mbx uid))
 502            head))))))
 503
 504 (defun nnimap-retrieve-which-headers (articles fetch-old)
 505   "Get a range of articles to fetch based on ARTICLES and FETCH-OLD."
 506   (with-current-buffer nnimap-server-buffer
 507     (if (numberp (car-safe articles))
 508         (imap-search
 509          (concat "UID "
 510                  (imap-range-to-message-set
 511                   (gnus-compress-sequence
 512                    (append (gnus-uncompress-sequence
 513                             (and fetch-old
 514                                  (cons (if (numberp fetch-old)
 515                                            (max 1 (- (car articles) fetch-old))
 516                                          1)
 517                                        (1- (car articles)))))
 518                            articles)))))
 519       (mapcar (lambda (msgid)
 520                 (imap-search
 521                  (format "HEADER Message-Id \"%s\"" msgid)))
 522               articles))))
 523
 524 (defun nnimap-group-overview-filename (group server)
 525   "Make pathname for GROUP on SERVER."
 526   (let* ((dir (file-name-as-directory (expand-file-name nnimap-directory)))
 527          (uidvalidity (gnus-group-get-parameter
 528                        (gnus-group-prefixed-name
 529                         group (gnus-server-to-method
 530                                (format "nnimap:%s" server)))
 531                        'uidvalidity))
 532          (name (nnheader-translate-file-chars
 533                 (concat nnimap-nov-file-name
 534                         (if (equal server "")
 535                             "unnamed"
 536                           server) "." group nnimap-nov-file-name-suffix) t))
 537          (nameuid (nnheader-translate-file-chars
 538                    (concat nnimap-nov-file-name
 539                            (if (equal server "")
 540                                "unnamed"
 541                              server) "." group "." uidvalidity
 542                            nnimap-nov-file-name-suffix) t))
 543          (oldfile (if (or nnmail-use-long-file-names
 544                           (file-exists-p (expand-file-name name dir)))
 545                       (expand-file-name name dir)
 546                     (expand-file-name
 547                      (mm-encode-coding-string
 548                       (nnheader-replace-chars-in-string name ?. ?/)
 549                       nnmail-pathname-coding-system)
 550                      dir)))
 551          (newfile (if (or nnmail-use-long-file-names
 552                           (file-exists-p (expand-file-name nameuid dir)))
 553                       (expand-file-name nameuid dir)
 554                     (expand-file-name
 555                      (mm-encode-coding-string
 556                       (nnheader-replace-chars-in-string nameuid ?. ?/)
 557                       nnmail-pathname-coding-system)
 558                      dir))))
 559     (when (and (file-exists-p oldfile) (not (file-exists-p newfile)))
 560       (message "nnimap: Upgrading novcache filename...")
 561       (sit-for 1)
 562       (gnus-make-directory (file-name-directory newfile))
 563       (unless (ignore-errors (rename-file oldfile newfile) t)
 564         (if (ignore-errors (copy-file oldfile newfile) t)
 565             (delete-file oldfile)
 566           (error "Can't rename `%s' to `%s'" oldfile newfile))))
 567     newfile))
 568
 569 (defun nnimap-retrieve-headers-from-file (group server)
 570   (with-current-buffer nntp-server-buffer
 571     (let ((nov (nnimap-group-overview-filename group server)))
 572       (when (file-exists-p nov)
 573         (mm-insert-file-contents nov)
 574         (set-buffer-modified-p nil)
 575         (let ((min (ignore-errors (goto-char (point-min))
 576                                   (read (current-buffer))))
 577               (max (ignore-errors (goto-char (point-max))
 578                                   (forward-line -1)
 579                                   (read (current-buffer)))))
 580           (if (and (numberp min) (numberp max))
 581               (cons min max)
 582             ;; junk, remove it, it's saved later
 583             (erase-buffer)
 584             nil))))))
 585
 586 (defun nnimap-retrieve-headers-from-server (articles group server)
 587   (with-current-buffer nnimap-server-buffer
 588     (let ((imap-fetch-data-hook '(nnimap-retrieve-headers-progress))
 589           (nnimap-length (gnus-range-length articles))
 590           (nnimap-counter 0))
 591       (imap-fetch (imap-range-to-message-set articles)
 592                   (concat "(UID RFC822.SIZE BODY "
 593                           (let ((headers
 594                                  (append '(Subject From Date Message-Id
 595                                                    References In-Reply-To Xref)
 596                                          (copy-sequence
 597                                           nnmail-extra-headers))))
 598                             (if (imap-capability 'IMAP4rev1)
 599                                 (format "BODY.PEEK[HEADER.FIELDS %s])" headers)
 600                               (format "RFC822.HEADER.LINES %s)" headers)))))
 601       (and (numberp nnmail-large-newsgroup)
 602            (> nnimap-length nnmail-large-newsgroup)
 603            (nnheader-message 6 "nnimap: Retrieving headers...done")))))
 604
 605 (defun nnimap-dont-use-nov-p (group server)
 606   (or gnus-nov-is-evil nnimap-nov-is-evil
 607       (unless (and (gnus-make-directory
 608                     (file-name-directory
 609                      (nnimap-group-overview-filename group server)))
 610                    (file-writable-p
 611                     (nnimap-group-overview-filename group server)))
 612         (message "nnimap: Nov cache not writable, %s"
 613                  (nnimap-group-overview-filename group server)))))
 614
 615 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 616   (when (nnimap-possibly-change-group group server)
 617     (with-current-buffer nntp-server-buffer
 618       (erase-buffer)
 619       (if (nnimap-dont-use-nov-p group server)
 620           (nnimap-retrieve-headers-from-server
 621            (gnus-compress-sequence articles) group server)
 622         (let (uids cached low high)
 623           (when (setq uids (nnimap-retrieve-which-headers articles fetch-old)
 624                       low (car uids)
 625                       high (car (last uids)))
 626             (if (setq cached (nnimap-retrieve-headers-from-file group server))
 627                 (progn
 628                   ;; fetch articles with uids before cache block
 629                   (when (< low (car cached))
 630                     (goto-char (point-min))
 631                     (nnimap-retrieve-headers-from-server
 632                      (cons low (1- (car cached))) group server))
 633                   ;; fetch articles with uids after cache block
 634                   (when (> high (cdr cached))
 635                     (goto-char (point-max))
 636                     (nnimap-retrieve-headers-from-server
 637                      (cons (1+ (cdr cached)) high) group server))
 638                   (when nnimap-prune-cache
 639               ;; remove nov's for articles which has expired on server
 640                     (goto-char (point-min))
 641                     (dolist (uid (gnus-set-difference articles uids))
 642                       (when (re-search-forward (format "^%d\t" uid) nil t)
 643                         (gnus-delete-line)))))
 644               ;; nothing cached, fetch whole range from server
 645               (nnimap-retrieve-headers-from-server
 646                (cons low high) group server))
 647             (when (buffer-modified-p)
 648               (nnmail-write-region
 649                1 (point-max) (nnimap-group-overview-filename group server)
 650                nil 'nomesg))
 651             (nnheader-nov-delete-outside-range low high))))
 652       'nov)))
 653
 654 (defun nnimap-open-connection (server)
 655   (if (not (imap-open nnimap-address nnimap-server-port nnimap-stream
 656                       nnimap-authenticator nnimap-server-buffer))
 657       (nnheader-report 'nnimap "Can't open connection to server %s" server)
 658     (unless (or (imap-capability 'IMAP4 nnimap-server-buffer)
 659                 (imap-capability 'IMAP4rev1 nnimap-server-buffer))
 660       (imap-close nnimap-server-buffer)
 661       (nnheader-report 'nnimap "Server %s is not IMAP4 compliant" server))
 662     (let* ((list (gnus-parse-netrc nnimap-authinfo-file))
 663            (port (if nnimap-server-port
 664                      (int-to-string nnimap-server-port)
 665                    "imap"))
 666            (alist (gnus-netrc-machine list (or nnimap-server-address
 667                                                nnimap-address server)
 668                                       port "imap"))
 669            (user (gnus-netrc-get alist "login"))
 670            (passwd (gnus-netrc-get alist "password")))
 671       (if (imap-authenticate user passwd nnimap-server-buffer)
 672           (prog1
 673               (push (list server nnimap-server-buffer)
 674                     nnimap-server-buffer-alist)
 675             (nnimap-possibly-change-server server))
 676         (imap-close nnimap-server-buffer)
 677         (kill-buffer nnimap-server-buffer)
 678         (nnheader-report 'nnimap "Could not authenticate to %s" server)))))
 679
 680 (deffoo nnimap-open-server (server &optional defs)
 681   (nnheader-init-server-buffer)
 682   (if (nnimap-server-opened server)
 683       t
 684     (unless (assq 'nnimap-server-buffer defs)
 685       (push (list 'nnimap-server-buffer (concat " *nnimap* " server)) defs))
 686     ;; translate `nnimap-server-address' to `nnimap-address' in defs
 687     ;; for people that configured nnimap with a very old version
 688     (unless (assq 'nnimap-address defs)
 689       (if (assq 'nnimap-server-address defs)
 690           (push (list 'nnimap-address
 691                       (cadr (assq 'nnimap-server-address defs))) defs)
 692         (push (list 'nnimap-address server) defs)))
 693     (nnoo-change-server 'nnimap server defs)
 694     (or nnimap-server-buffer
 695         (setq nnimap-server-buffer (cadr (assq 'nnimap-server-buffer defs))))
 696     (with-current-buffer (get-buffer-create nnimap-server-buffer)
 697       (nnoo-change-server 'nnimap server defs))
 698     (or (and nnimap-server-buffer
 699              (imap-opened nnimap-server-buffer))
 700         (nnimap-open-connection server))))
 701
 702 (deffoo nnimap-server-opened (&optional server)
 703   "Whether SERVER is opened.
 704 If SERVER is the current virtual server, and the connection to the
 705 physical server is alive, this function return a non-nil value.  If
 706 SERVER is nil, it is treated as the current server."
 707   ;; clean up autologouts??
 708   (and (or server nnimap-current-server)
 709        (nnoo-server-opened 'nnimap (or server nnimap-current-server))
 710        (imap-opened (nnimap-get-server-buffer server))))
 711
 712 (deffoo nnimap-close-server (&optional server)
 713   "Close connection to server and free all resources connected to it.
 714 Return nil if the server couldn't be closed for some reason."
 715   (let ((server (or server nnimap-current-server)))
 716     (when (or (nnimap-server-opened server)
 717               (imap-opened (nnimap-get-server-buffer server)))
 718       (imap-close (nnimap-get-server-buffer server))
 719       (kill-buffer (nnimap-get-server-buffer server))
 720       (setq nnimap-server-buffer nil
 721             nnimap-current-server nil
 722             nnimap-server-buffer-alist
 723             (delq server nnimap-server-buffer-alist)))
 724     (nnoo-close-server 'nnimap server)))
 725
 726 (deffoo nnimap-request-close ()
 727   "Close connection to all servers and free all resources that the backend have reserved.
 728 All buffers that have been created by that
 729 backend should be killed.  (Not the nntp-server-buffer, though.) This
 730 function is generally only called when Gnus is shutting down."
 731   (mapcar (lambda (server) (nnimap-close-server (car server)))
 732           nnimap-server-buffer-alist)
 733   (setq nnimap-server-buffer-alist nil))
 734
 735 (deffoo nnimap-status-message (&optional server)
 736   "This function returns the last error message from server."
 737   (when (nnimap-possibly-change-server server)
 738     (nnoo-status-message 'nnimap server)))
 739
 740 (defun nnimap-demule (string)
 741   (funcall (if (and (fboundp 'string-as-multibyte)
 742                     (subrp (symbol-function 'string-as-multibyte)))
 743                'string-as-multibyte
 744              'identity)
 745            (or string "")))
 746
 747 (defun nnimap-callback ()
 748   (remove-hook 'imap-fetch-data-hook 'nnimap-callback)
 749   (with-current-buffer nnimap-callback-buffer
 750     (insert
 751      (with-current-buffer nnimap-server-buffer
 752        (nnimap-demule
 753         (if (imap-capability 'IMAP4rev1)
 754             ;; xxx don't just use car? alist doesn't contain
 755             ;; anything else now, but it might...
 756             (nth 2 (car (imap-message-get (imap-current-message) 'BODYDETAIL)))
 757           (imap-message-get (imap-current-message) 'RFC822)))))
 758     (nnheader-ms-strip-cr)
 759     (funcall nnimap-callback-callback-function t)))
 760
 761 (defun nnimap-request-article-part (article part prop &optional
 762                                             group server to-buffer detail)
 763   (when (nnimap-possibly-change-group group server)
 764     (let ((article (if (stringp article)
 765                        (car-safe (imap-search
 766                                   (format "HEADER Message-Id \"%s\"" article)
 767                                   nnimap-server-buffer))
 768                      article)))
 769       (when article
 770         (gnus-message 10 "nnimap: Fetching (part of) article %d..." article)
 771         (if (not nnheader-callback-function)
 772             (with-current-buffer (or to-buffer nntp-server-buffer)
 773               (erase-buffer)
 774               (let ((data (imap-fetch article part prop nil
 775                                       nnimap-server-buffer)))
 776                 (insert (nnimap-demule (if detail
 777                                            (nth 2 (car data))
 778                                          data))))
 779               (nnheader-ms-strip-cr)
 780               (gnus-message 10 "nnimap: Fetching (part of) article %d...done"
 781                             article)
 782               (if (bobp)
 783                   (nnheader-report 'nnimap "No such article: %s"
 784                                    (imap-error-text nnimap-server-buffer))
 785                 (cons group article)))
 786           (add-hook 'imap-fetch-data-hook 'nnimap-callback)
 787           (setq nnimap-callback-callback-function nnheader-callback-function
 788                 nnimap-callback-buffer nntp-server-buffer)
 789           (imap-fetch-asynch article part nil nnimap-server-buffer)
 790           (cons group article))))))
 791
 792 (deffoo nnimap-asynchronous-p ()
 793   t)
 794
 795 (deffoo nnimap-request-article (article &optional group server to-buffer)
 796   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 797       (nnimap-request-article-part
 798        article "BODY.PEEK[]" 'BODYDETAIL group server to-buffer 'detail)
 799     (nnimap-request-article-part
 800      article "RFC822.PEEK" 'RFC822 group server to-buffer)))
 801
 802 (deffoo nnimap-request-head (article &optional group server to-buffer)
 803   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 804       (nnimap-request-article-part
 805        article "BODY.PEEK[HEADER]" 'BODYDETAIL group server to-buffer 'detail)
 806     (nnimap-request-article-part
 807      article "RFC822.HEADER" 'RFC822.HEADER group server to-buffer)))
 808
 809 (deffoo nnimap-request-body (article &optional group server to-buffer)
 810   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 811       (nnimap-request-article-part
 812        article "BODY.PEEK[TEXT]" 'BODYDETAIL group server to-buffer 'detail)
 813     (nnimap-request-article-part
 814      article "RFC822.TEXT.PEEK" 'RFC822.TEXT group server to-buffer)))
 815
 816 (deffoo nnimap-request-group (group &optional server fast)
 817   (nnimap-request-update-info-internal
 818    group
 819    (gnus-get-info (gnus-group-prefixed-name
 820                    group (gnus-server-to-method (format "nnimap:%s" server))))
 821    server)
 822   (when (nnimap-possibly-change-group group server)
 823     (nnimap-before-find-minmax-bugworkaround)
 824     (let (info)
 825       (cond (fast group)
 826             ((null (setq info (nnimap-find-minmax-uid group t)))
 827              (nnheader-report 'nnimap "Could not get active info for %s"
 828                               group))
 829             (t
 830              (nnheader-insert "211 %d %d %d %s\n" (or (nth 0 info) 0)
 831                               (max 1 (or (nth 1 info) 1))
 832                               (or (nth 2 info) 0) group)
 833              (nnheader-report 'nnimap "Group %s selected" group)
 834              t)))))
 835
 836 (defun nnimap-close-group (group &optional server)
 837   (with-current-buffer nnimap-server-buffer
 838     (when (and (imap-opened)
 839                (nnimap-possibly-change-group group server))
 840       (case nnimap-expunge-on-close
 841         ('always (imap-mailbox-expunge)
 842                  (imap-mailbox-close))
 843         ('ask (if (and (imap-search "DELETED")
 844                        (gnus-y-or-n-p (format
 845                                        "Expunge articles in group `%s'? "
 846                                        imap-current-mailbox)))
 847                   (progn (imap-mailbox-expunge)
 848                          (imap-mailbox-close))
 849                 (imap-mailbox-unselect)))
 850         (t (imap-mailbox-unselect)))
 851       (not imap-current-mailbox))))
 852
 853 (defun nnimap-pattern-to-list-arguments (pattern)
 854   (mapcar (lambda (p)
 855             (cons (car-safe p) (or (cdr-safe p) p)))
 856           (if (and (listp pattern)
 857                    (listp (cdr pattern)))
 858               pattern
 859             (list pattern))))
 860
 861 (deffoo nnimap-request-list (&optional server)
 862   (when (nnimap-possibly-change-server server)
 863     (with-current-buffer nntp-server-buffer
 864       (erase-buffer))
 865     (gnus-message 5 "nnimap: Generating active list%s..."
 866                   (if (> (length server) 0) (concat " for " server) ""))
 867     (nnimap-before-find-minmax-bugworkaround)
 868     (with-current-buffer nnimap-server-buffer
 869       (dolist (pattern (nnimap-pattern-to-list-arguments nnimap-list-pattern))
 870         (dolist (mbx (funcall nnimap-request-list-method
 871                               (cdr pattern) (car pattern)))
 872           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags mbx))
 873               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
 874                 (when info
 875                   (with-current-buffer nntp-server-buffer
 876                     (insert (format "\"%s\" %d %d y\n"
 877                                     mbx (or (nth 2 info) 0)
 878                                     (max 1 (or (nth 1 info) 1)))))))))))
 879     (gnus-message 5 "nnimap: Generating active list%s...done"
 880                   (if (> (length server) 0) (concat " for " server) ""))
 881     t))
 882
 883 (deffoo nnimap-request-post (&optional server)
 884   (let ((success t))
 885     (dolist (mbx (message-unquote-tokens
 886                   (message-tokenize-header
 887                    (message-fetch-field "Newsgroups") ", ")) success)
 888       (let ((to-newsgroup (gnus-group-prefixed-name mbx gnus-command-method)))
 889         (or (gnus-active to-newsgroup)
 890             (gnus-activate-group to-newsgroup)
 891             (if (gnus-y-or-n-p (format "No such group: %s.  Create it? "
 892                                        to-newsgroup))
 893                 (or (and (gnus-request-create-group
 894                           to-newsgroup gnus-command-method)
 895                          (gnus-activate-group to-newsgroup nil nil
 896                                               gnus-command-method))
 897                     (error "Couldn't create group %s" to-newsgroup)))
 898             (error "No such group: %s" to-newsgroup))
 899         (unless (nnimap-request-accept-article mbx (nth 1 gnus-command-method))
 900           (setq success nil))))))
 901
 902 ;; Optional backend functions
 903
 904 (deffoo nnimap-retrieve-groups (groups &optional server)
 905   (when (nnimap-possibly-change-server server)
 906     (gnus-message 5 "nnimap: Checking mailboxes...")
 907     (with-current-buffer nntp-server-buffer
 908       (erase-buffer)
 909       (nnimap-before-find-minmax-bugworkaround)
 910       (dolist (group groups)
 911         (gnus-message 7 "nnimap: Checking mailbox %s" group)
 912         (or (member "\\NoSelect"
 913                     (imap-mailbox-get 'list-flags group nnimap-server-buffer))
 914             (let ((info (nnimap-find-minmax-uid group 'examine)))
 915               (when (> (or (imap-mailbox-get 'recent group
 916                                              nnimap-server-buffer) 0)
 917                        0)
 918                 (push (list (cons group 0)) nnmail-split-history))
 919               (insert (format "\"%s\" %d %d y\n" group
 920                               (or (nth 2 info) 0)
 921                               (max 1 (or (nth 1 info) 1))))))))
 922     (gnus-message 5 "nnimap: Checking mailboxes...done")
 923     'active))
 924
 925 (deffoo nnimap-request-update-info-internal (group info &optional server)
 926   (when (nnimap-possibly-change-group group server)
 927     (when info ;; xxx what does this mean? should we create a info?
 928       (with-current-buffer nnimap-server-buffer
 929         (gnus-message 5 "nnimap: Updating info for %s..."
 930                       (gnus-info-group info))
 931
 932         (when (nnimap-mark-permanent-p 'read)
 933           (let (seen unseen)
 934             ;; read info could contain articles marked unread by other
 935             ;; imap clients!  we correct this
 936             (setq seen (gnus-uncompress-range (gnus-info-read info))
 937                   unseen (imap-search "UNSEEN UNDELETED")
 938                   seen (gnus-set-difference seen unseen)
 939                   ;; seen might lack articles marked as read by other
 940                   ;; imap clients! we correct this
 941                   seen (append seen (imap-search "SEEN"))
 942                   ;; remove dupes
 943                   seen (sort seen '<)
 944                   seen (gnus-compress-sequence seen t)
 945                   ;; we can't return '(1) since this isn't a "list of ranges",
 946                   ;; and we can't return '((1)) since g-list-of-unread-articles
 947                   ;; is buggy so we return '((1 . 1)).
 948                   seen (if (and (integerp (car seen))
 949                                 (null (cdr seen)))
 950                            (list (cons (car seen) (car seen)))
 951                          seen))
 952             (gnus-info-set-read info seen)))
 953
 954         (mapcar (lambda (pred)
 955                   (when (or (eq (cdr pred) 'recent)
 956                             (and (nnimap-mark-permanent-p (cdr pred))
 957                                  (member (nnimap-mark-to-flag (cdr pred))
 958                                          (imap-mailbox-get 'flags))))
 959                     (gnus-info-set-marks
 960                      info
 961                      (gnus-update-alist-soft
 962                       (cdr pred)
 963                       (gnus-compress-sequence
 964                        (imap-search (nnimap-mark-to-predicate (cdr pred))))
 965                       (gnus-info-marks info))
 966                      t)))
 967                 gnus-article-mark-lists)
 968
 969         (when nnimap-importantize-dormant
 970       ;; nnimap mark dormant article as ticked too (for other clients)
 971           ;; so we remove that mark for gnus since we support dormant
 972           (gnus-info-set-marks
 973            info
 974            (gnus-update-alist-soft
 975             'tick
 976             (gnus-remove-from-range
 977              (cdr-safe (assoc 'tick (gnus-info-marks info)))
 978              (cdr-safe (assoc 'dormant (gnus-info-marks info))))
 979             (gnus-info-marks info))
 980            t))
 981
 982         (gnus-message 5 "nnimap: Updating info for %s...done"
 983                       (gnus-info-group info))
 984
 985         info))))
 986
 987 (deffoo nnimap-request-type (group &optional article)
 988   (if (and nnimap-news-groups (string-match nnimap-news-groups group))
 989       'news
 990     'mail))
 991
 992 (deffoo nnimap-request-set-mark (group actions &optional server)
 993   (when (nnimap-possibly-change-group group server)
 994     (with-current-buffer nnimap-server-buffer
 995       (let (action)
 996         (gnus-message 7 "nnimap: Setting marks in %s..." group)
 997         (while (setq action (pop actions))
 998           (let ((range (nth 0 action))
 999                 (what  (nth 1 action))
1000                 (cmdmarks (nth 2 action))
1001                 marks)
1002             ;; bookmark can't be stored (not list/range
1003             (setq cmdmarks (delq 'bookmark cmdmarks))
1004             ;; killed can't be stored (not list/range
1005             (setq cmdmarks (delq 'killed cmdmarks))
1006             ;; unsent are for nndraft groups only
1007             (setq cmdmarks (delq 'unsent cmdmarks))
1008             ;; cache flags are pointless on the server
1009             (setq cmdmarks (delq 'cache cmdmarks))
1010             ;; seen flags are local to each gnus
1011             (setq cmdmarks (delq 'seen cmdmarks))
1012             ;; recent marks can't be set
1013             (setq cmdmarks (delq 'recent cmdmarks))
1014             (when nnimap-importantize-dormant
1015               ;; flag dormant articles as ticked
1016               (if (memq 'dormant cmdmarks)
1017                   (setq cmdmarks (cons 'tick cmdmarks))))
1018             ;; remove stuff we are forbidden to store
1019             (mapcar (lambda (mark)
1020                       (if (imap-message-flag-permanent-p
1021                            (nnimap-mark-to-flag mark))
1022                           (setq marks (cons mark marks))))
1023                     cmdmarks)
1024             (when (and range marks)
1025               (cond ((eq what 'del)
1026                      (imap-message-flags-del
1027                       (imap-range-to-message-set range)
1028                       (nnimap-mark-to-flag marks nil t)))
1029                     ((eq what 'add)
1030                      (imap-message-flags-add
1031                       (imap-range-to-message-set range)
1032                       (nnimap-mark-to-flag marks nil t)))
1033                     ((eq what 'set)
1034                      (imap-message-flags-set
1035                       (imap-range-to-message-set range)
1036                       (nnimap-mark-to-flag marks nil t)))))))
1037         (gnus-message 7 "nnimap: Setting marks in %s...done" group))))
1038   nil)
1039
1040 (defun nnimap-split-fancy ()
1041   "Like nnmail-split-fancy, but uses nnimap-split-fancy."
1042   (let ((nnmail-split-fancy nnimap-split-fancy))
1043     (nnmail-split-fancy)))
1044
1045 (defun nnimap-split-to-groups (rules)
1046   ;; tries to match all rules in nnimap-split-rule against content of
1047   ;; nntp-server-buffer, returns a list of groups that matched.
1048   (with-current-buffer nntp-server-buffer
1049     ;; Fold continuation lines.
1050     (goto-char (point-min))
1051     (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
1052       (replace-match " " t t))
1053     (if (functionp rules)
1054         (funcall rules)
1055       (let (to-groups regrepp)
1056         (catch 'split-done
1057           (dolist (rule rules to-groups)
1058             (let ((group (car rule))
1059                   (regexp (cadr rule)))
1060               (goto-char (point-min))
1061               (when (and (if (stringp regexp)
1062                              (progn
1063                                (setq regrepp (string-match "\\\\[0-9&]" group))
1064                                (re-search-forward regexp nil t))
1065                            (funcall regexp group))
1066                  ;; Don't enter the article into the same group twice.
1067                          (not (assoc group to-groups)))
1068                 (push (if regrepp
1069                           (nnmail-expand-newtext group)
1070                         group)
1071                       to-groups)
1072                 (or nnimap-split-crosspost
1073                     (throw 'split-done to-groups))))))))))
1074
1075 (defun nnimap-assoc-match (key alist)
1076   (let (element)
1077     (while (and alist (not element))
1078       (if (string-match (car (car alist)) key)
1079           (setq element (car alist)))
1080       (setq alist (cdr alist)))
1081     element))
1082
1083 (defun nnimap-split-find-rule (server inbox)
1084   (if (and (listp nnimap-split-rule) (listp (car nnimap-split-rule))
1085            (list (cdar nnimap-split-rule)) (listp (cadar nnimap-split-rule)))
1086       ;; extended format
1087       (cadr (nnimap-assoc-match inbox (cdr (nnimap-assoc-match
1088                                             server nnimap-split-rule))))
1089     nnimap-split-rule))
1090
1091 (defun nnimap-split-find-inbox (server)
1092   (if (listp nnimap-split-inbox)
1093       nnimap-split-inbox
1094     (list nnimap-split-inbox)))
1095
1096 (defun nnimap-split-articles (&optional group server)
1097   (when (nnimap-possibly-change-server server)
1098     (with-current-buffer nnimap-server-buffer
1099       (let (rule inbox removeorig (inboxes (nnimap-split-find-inbox server)))
1100         ;; iterate over inboxes
1101         (while (and (setq inbox (pop inboxes))
1102                     (nnimap-possibly-change-group inbox)) ;; SELECT
1103           ;; find split rule for this server / inbox
1104           (when (setq rule (nnimap-split-find-rule server inbox))
1105             ;; iterate over articles
1106             (dolist (article (imap-search nnimap-split-predicate))
1107               (when (nnimap-request-head article)
1108                 ;; copy article to right group(s)
1109                 (setq removeorig nil)
1110                 (dolist (to-group (nnimap-split-to-groups rule))
1111                   (cond ((eq to-group 'junk)
1112                          (message "IMAP split removed %s:%s:%d" server inbox
1113                                   article)
1114                          (setq removeorig t))
1115                         ((imap-message-copy (number-to-string article)
1116                                             to-group nil 'nocopyuid)
1117                          (message "IMAP split moved %s:%s:%d to %s" server
1118                                   inbox article to-group)
1119                          (setq removeorig t)
1120                          ;; Add the group-art list to the history list.
1121                          (push (list (cons to-group 0)) nnmail-split-history))
1122                         (t
1123                          (message "IMAP split failed to move %s:%s:%d to %s"
1124                                   server inbox article to-group))))
1125                 ;; remove article if it was successfully copied somewhere
1126                 (and removeorig
1127                      (imap-message-flags-add (format "%d" article)
1128                                              "\\Seen \\Deleted")))))
1129           (when (imap-mailbox-select inbox) ;; just in case
1130             ;; todo: UID EXPUNGE (if available) to remove splitted articles
1131             (imap-mailbox-expunge)
1132             (imap-mailbox-close)))
1133         t))))
1134
1135 (deffoo nnimap-request-scan (&optional group server)
1136   (nnimap-split-articles group server))
1137
1138 (deffoo nnimap-request-newgroups (date &optional server)
1139   (when (nnimap-possibly-change-server server)
1140     (with-current-buffer nntp-server-buffer
1141       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s..."
1142                     (if (> (length server) 0) " on " "") server)
1143       (erase-buffer)
1144       (nnimap-before-find-minmax-bugworkaround)
1145       (dolist (pattern (nnimap-pattern-to-list-arguments
1146                         nnimap-list-pattern))
1147         (dolist (mbx (imap-mailbox-lsub "*" (car pattern) nil
1148                                         nnimap-server-buffer))
1149           (or (catch 'found
1150                 (dolist (mailbox (imap-mailbox-get 'list-flags mbx
1151                                                    nnimap-server-buffer))
1152                   (if (string= (downcase mailbox) "\\noselect")
1153                       (throw 'found t)))
1154                 nil)
1155               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1156                 (when info
1157                   (insert (format "\"%s\" %d %d y\n"
1158                                   mbx (or (nth 2 info) 0)
1159                                   (max 1 (or (nth 1 info) 1)))))))))
1160       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s...done"
1161                     (if (> (length server) 0) " on " "") server))
1162     t))
1163
1164 (deffoo nnimap-request-create-group (group &optional server args)
1165   (when (nnimap-possibly-change-server server)
1166     (or (imap-mailbox-status group 'uidvalidity nnimap-server-buffer)
1167         (imap-mailbox-create group nnimap-server-buffer))))
1168
1169 (defun nnimap-time-substract (time1 time2)
1170   "Return TIME for TIME1 - TIME2."
1171   (let* ((ms (- (car time1) (car time2)))
1172          (ls (- (nth 1 time1) (nth 1 time2))))
1173     (if (< ls 0)
1174         (list (- ms 1) (+ (expt 2 16) ls))
1175       (list ms ls))))
1176
1177 (defun nnimap-date-days-ago (daysago)
1178   "Return date, in format \"3-Aug-1998\", for DAYSAGO days ago."
1179   (let* ((time (nnimap-time-substract (current-time) (days-to-time daysago)))
1180          (date (format-time-string
1181                 (format "%%d-%s-%%Y"
1182                         (capitalize (car (rassoc (nth 4 (decode-time time))
1183                                                  parse-time-months))))
1184                 time)))
1185     (if (eq ?0 (string-to-char date))
1186         (substring date 1)
1187       date)))
1188
1189 (defun nnimap-request-expire-articles-progress ()
1190   (gnus-message 5 "nnimap: Marking article %d for deletion..."
1191                 imap-current-message))
1192
1193
1194 (defun nnimap-expiry-target (arts group server)
1195   (unless (eq nnmail-expiry-target 'delete)
1196     (with-temp-buffer
1197       (dolist (art (gnus-uncompress-sequence arts))
1198         (nnimap-request-article art group server  (current-buffer))
1199         ;; hints for optimization in `nnimap-request-accept-article'
1200         (let ((nnimap-current-move-article art)
1201               (nnimap-current-move-group group)
1202               (nnimap-current-move-server server))
1203           (nnmail-expiry-target-group nnmail-expiry-target group))))
1204     ;; It is not clear if `nnmail-expiry-target' somehow cause the
1205     ;; current group to be changed or not, so we make sure here.
1206     (nnimap-possibly-change-group group server)))
1207
1208 ;; Notice that we don't actually delete anything, we just mark them deleted.
1209 (deffoo nnimap-request-expire-articles (articles group &optional server force)
1210   (let ((artseq (gnus-compress-sequence articles)))
1211     (when (and artseq (nnimap-possibly-change-group group server))
1212       (with-current-buffer nnimap-server-buffer
1213         (if force
1214             (progn
1215               (nnimap-expiry-target artseq group server)
1216               (when (imap-message-flags-add (imap-range-to-message-set artseq)
1217                                             "\\Deleted")
1218                 (setq articles nil)))
1219           (let ((days (or (and nnmail-expiry-wait-function
1220                                (funcall nnmail-expiry-wait-function group))
1221                           nnmail-expiry-wait)))
1222             (cond ((eq days 'immediate)
1223                    (nnimap-expiry-target artseq group server)
1224                    (when (imap-message-flags-add
1225                           (imap-range-to-message-set artseq) "\\Deleted")
1226                      (setq articles nil)))
1227                   ((numberp days)
1228                    (let ((oldarts (imap-search
1229                                    (format nnimap-expunge-search-string
1230                                            (imap-range-to-message-set artseq)
1231                                            (nnimap-date-days-ago days))))
1232                          (imap-fetch-data-hook
1233                           '(nnimap-request-expire-articles-progress)))
1234                      (nnimap-expiry-target oldarts group server)
1235                      (and oldarts
1236                           (imap-message-flags-add
1237                            (imap-range-to-message-set
1238                             (gnus-compress-sequence oldarts))
1239                            "\\Deleted")
1240                           (setq articles (gnus-set-difference
1241                                           articles oldarts)))))))))))
1242   ;; return articles not deleted
1243   articles)
1244
1245 (deffoo nnimap-request-move-article (article group server
1246                                              accept-form &optional last)
1247   (when (nnimap-possibly-change-server server)
1248     (save-excursion
1249       (let ((buf (get-buffer-create " *nnimap move*"))
1250             (nnimap-current-move-article article)
1251             (nnimap-current-move-group group)
1252             (nnimap-current-move-server nnimap-current-server)
1253             result)
1254         (and (nnimap-request-article article group server)
1255              (save-excursion
1256                (set-buffer buf)
1257                (buffer-disable-undo (current-buffer))
1258                (insert-buffer-substring nntp-server-buffer)
1259                (setq result (eval accept-form))
1260                (kill-buffer buf)
1261                result)
1262              (imap-message-flags-add
1263               (imap-range-to-message-set (list article))
1264               "\\Deleted" 'silent nnimap-server-buffer))
1265         result))))
1266
1267 (deffoo nnimap-request-accept-article (group &optional server last)
1268   (when (nnimap-possibly-change-server server)
1269     (let (uid)
1270       (if (setq uid
1271                 (if (string= nnimap-current-server nnimap-current-move-server)
1272                   ;; moving article within same server, speed it up...
1273                     (and (nnimap-possibly-change-group
1274                           nnimap-current-move-group)
1275                          (imap-message-copy (number-to-string
1276                                              nnimap-current-move-article)
1277                                             group 'dontcreate nil
1278                                             nnimap-server-buffer))
1279                   (with-current-buffer (current-buffer)
1280                     (goto-char (point-min))
1281                   ;; remove any 'From blabla' lines, some IMAP servers
1282                     ;; reject the entire message otherwise.
1283                     (when (looking-at "^From[^:]")
1284                       (kill-region (point) (progn (forward-line) (point))))
1285                     ;; turn into rfc822 format (\r\n eol's)
1286                     (while (search-forward "\n" nil t)
1287                       (replace-match "\r\n")))
1288                   ;; this 'or' is for Cyrus server bug
1289                   (or (null (imap-current-mailbox nnimap-server-buffer))
1290                       (imap-mailbox-unselect nnimap-server-buffer))
1291                   (imap-message-append group (current-buffer) nil nil
1292                                        nnimap-server-buffer)))
1293           (cons group (nth 1 uid))
1294         (nnheader-report 'nnimap (imap-error-text nnimap-server-buffer))))))
1295
1296 (deffoo nnimap-request-delete-group (group force &optional server)
1297   (when (nnimap-possibly-change-server server)
1298     (with-current-buffer nnimap-server-buffer
1299       (if force
1300           (or (null (imap-mailbox-status group 'uidvalidity))
1301               (imap-mailbox-delete group))
1302         ;; UNSUBSCRIBE?
1303         t))))
1304
1305 (deffoo nnimap-request-rename-group (group new-name &optional server)
1306   (when (nnimap-possibly-change-server server)
1307     (imap-mailbox-rename group new-name nnimap-server-buffer)))
1308
1309 (defun nnimap-expunge (mailbox server)
1310   (when (nnimap-possibly-change-group mailbox server)
1311     (imap-mailbox-expunge nnimap-server-buffer)))
1312
1313 (defun nnimap-acl-get (mailbox server)
1314   (when (nnimap-possibly-change-server server)
1315     (and (imap-capability 'ACL nnimap-server-buffer)
1316          (imap-mailbox-acl-get mailbox nnimap-server-buffer))))
1317
1318 (defun nnimap-acl-edit (mailbox method old-acls new-acls)
1319   (when (nnimap-possibly-change-server (cadr method))
1320     (unless (imap-capability 'ACL nnimap-server-buffer)
1321       (error "Your server does not support ACL editing"))
1322     (with-current-buffer nnimap-server-buffer
1323       ;; delete all removed identifiers
1324       (mapcar (lambda (old-acl)
1325                 (unless (assoc (car old-acl) new-acls)
1326                   (or (imap-mailbox-acl-delete (car old-acl) mailbox)
1327                       (error "Can't delete ACL for %s" (car old-acl)))))
1328               old-acls)
1329       ;; set all changed acl's
1330       (mapcar (lambda (new-acl)
1331                 (let ((new-rights (cdr new-acl))
1332                       (old-rights (cdr (assoc (car new-acl) old-acls))))
1333                   (unless (and old-rights new-rights
1334                                (string= old-rights new-rights))
1335                     (or (imap-mailbox-acl-set (car new-acl) new-rights mailbox)
1336                         (error "Can't set ACL for %s to %s" (car new-acl)
1337                                new-rights)))))
1338               new-acls)
1339       t)))
1340
1341 \f
1342 ;;; Internal functions
1343
1344 ;;
1345 ;; This is confusing.
1346 ;;
1347 ;; mark      => read, tick, draft, reply etc
1348 ;; flag      => "\\Seen", "\\Flagged", "\\Draft", "gnus-expire" etc
1349 ;; predicate => "SEEN", "FLAGGED", "DRAFT", "KEYWORD gnus-expire" etc
1350 ;;
1351 ;; Mark should not really contain 'read since it's not a "mark" in the Gnus
1352 ;; world, but we cheat.  Mark == gnus-article-mark-lists + '(read . read).
1353 ;;
1354
1355 (defconst nnimap-mark-to-predicate-alist
1356   (mapcar
1357    (lambda (pair)                       ; cdr is the mark
1358      (or (assoc (cdr pair)
1359                 '((read . "SEEN")
1360                   (tick . "FLAGGED")
1361                   (draft . "DRAFT")
1362                   (recent . "RECENT")
1363                   (reply . "ANSWERED")))
1364          (cons (cdr pair)
1365                (format "KEYWORD gnus-%s" (symbol-name (cdr pair))))))
1366    (cons '(read . read) gnus-article-mark-lists)))
1367
1368 (defun nnimap-mark-to-predicate (pred)
1369   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP predicate.
1370 This is a string such as \"SEEN\", \"FLAGGED\", \"KEYWORD gnus-expire\",
1371 to be used within a IMAP SEARCH query."
1372   (cdr (assq pred nnimap-mark-to-predicate-alist)))
1373
1374 (defconst nnimap-mark-to-flag-alist
1375   (mapcar
1376    (lambda (pair)
1377      (or (assoc (cdr pair)
1378                 '((read . "\\Seen")
1379                   (tick . "\\Flagged")
1380                   (draft . "\\Draft")
1381                   (recent . "\\Recent")
1382                   (reply . "\\Answered")))
1383          (cons (cdr pair)
1384                (format "gnus-%s" (symbol-name (cdr pair))))))
1385    (cons '(read . read) gnus-article-mark-lists)))
1386
1387 (defun nnimap-mark-to-flag-1 (preds)
1388   (if (and (not (null preds)) (listp preds))
1389       (cons (nnimap-mark-to-flag (car preds))
1390             (nnimap-mark-to-flag (cdr preds)))
1391     (cdr (assoc preds nnimap-mark-to-flag-alist))))
1392
1393 (defun nnimap-mark-to-flag (preds &optional always-list make-string)
1394   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP flag.
1395 This is a string such as \"\\Seen\", \"\\Flagged\", \"gnus-expire\", to
1396 be used in a STORE FLAGS command."
1397   (let ((result (nnimap-mark-to-flag-1 preds)))
1398     (setq result (if (and (or make-string always-list)
1399                           (not (listp result)))
1400                      (list result)
1401                    result))
1402     (if make-string
1403         (mapconcat (lambda (flag)
1404                      (if (listp flag)
1405                          (mapconcat 'identity flag " ")
1406                        flag))
1407                    result " ")
1408       result)))
1409
1410 (defun nnimap-mark-permanent-p (mark &optional group)
1411   "Return t iff MARK can be permanently (between IMAP sessions) saved on articles, in GROUP."
1412   (imap-message-flag-permanent-p (nnimap-mark-to-flag mark)))
1413
1414 (when nnimap-debug
1415   (require 'trace)
1416   (buffer-disable-undo (get-buffer-create nnimap-debug))
1417   (mapcar (lambda (f) (trace-function-background f nnimap-debug))
1418           '(
1419             nnimap-possibly-change-server
1420             nnimap-verify-uidvalidity
1421             nnimap-find-minmax-uid
1422             nnimap-before-find-minmax-bugworkaround
1423             nnimap-possibly-change-group
1424             ;;nnimap-replace-whitespace
1425             nnimap-retrieve-headers-progress
1426             nnimap-retrieve-which-headers
1427             nnimap-group-overview-filename
1428             nnimap-retrieve-headers-from-file
1429             nnimap-retrieve-headers-from-server
1430             nnimap-retrieve-headers
1431             nnimap-open-connection
1432             nnimap-open-server
1433             nnimap-server-opened
1434             nnimap-close-server
1435             nnimap-request-close
1436             nnimap-status-message
1437             ;;nnimap-demule
1438             nnimap-request-article-part
1439             nnimap-request-article
1440             nnimap-request-head
1441             nnimap-request-body
1442             nnimap-request-group
1443             nnimap-close-group
1444             nnimap-pattern-to-list-arguments
1445             nnimap-request-list
1446             nnimap-request-post
1447             nnimap-retrieve-groups
1448             nnimap-request-update-info-internal
1449             nnimap-request-type
1450             nnimap-request-set-mark
1451             nnimap-split-to-groups
1452             nnimap-split-find-rule
1453             nnimap-split-find-inbox
1454             nnimap-split-articles
1455             nnimap-request-scan
1456             nnimap-request-newgroups
1457             nnimap-request-create-group
1458             nnimap-time-substract
1459             nnimap-date-days-ago
1460             nnimap-request-expire-articles-progress
1461             nnimap-request-expire-articles
1462             nnimap-request-move-article
1463             nnimap-request-accept-article
1464             nnimap-request-delete-group
1465             nnimap-request-rename-group
1466             gnus-group-nnimap-expunge
1467             gnus-group-nnimap-edit-acl
1468             gnus-group-nnimap-edit-acl-done
1469             nnimap-group-mode-hook
1470             nnimap-mark-to-predicate
1471             nnimap-mark-to-flag-1
1472             nnimap-mark-to-flag
1473             nnimap-mark-permanent-p
1474             )))
1475
1476 (provide 'nnimap)
1477
1478 ;;; nnimap.el ends here