cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- IMAP interface for Gnus
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;         Simon Josefsson <simon@josefsson.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; nnimap interfaces Gnus with IMAP servers.
  26
  27 ;;; Code:
  28
  29 ;; For Emacs <22.2 and XEmacs.
  30 (eval-and-compile
  31   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  32
  33 (eval-and-compile
  34   (require 'nnheader))
  35
  36 (eval-when-compile
  37   (require 'cl))
  38
  39 (require 'nnheader)
  40 (require 'gnus-util)
  41 (require 'gnus)
  42 (require 'nnoo)
  43 (require 'netrc)
  44 (require 'utf7)
  45 (require 'tls)
  46 (require 'parse-time)
  47 (require 'nnmail)
  48
  49 (eval-when-compile
  50   (require 'gnus-sum))
  51
  52 (autoload 'auth-source-forget-user-or-password "auth-source")
  53 (autoload 'auth-source-user-or-password "auth-source")
  54
  55 (nnoo-declare nnimap)
  56
  57 (defvoo nnimap-address nil
  58   "The address of the IMAP server.")
  59
  60 (defvoo nnimap-server-port nil
  61   "The IMAP port used.
  62 If nnimap-stream is `ssl', this will default to `imaps'.  If not,
  63 it will default to `imap'.")
  64
  65 (defvoo nnimap-stream 'ssl
  66   "How nnimap will talk to the IMAP server.
  67 Values are `ssl', `network', `starttls' or `shell'.")
  68
  69 (defvoo nnimap-shell-program (if (boundp 'imap-shell-program)
  70                                  (if (listp imap-shell-program)
  71                                      (car imap-shell-program)
  72                                    imap-shell-program)
  73                                "ssh %s imapd"))
  74
  75 (defvoo nnimap-inbox nil
  76   "The mail box where incoming mail arrives and should be split out of.")
  77
  78 (defvoo nnimap-split-methods nil
  79   "How mail is split.
  80 Uses the same syntax as nnmail-split-methods")
  81
  82 (defvoo nnimap-split-fancy nil
  83   "Uses the same syntax as nnmail-split-fancy.")
  84
  85 (defvoo nnimap-unsplittable-articles '(%Deleted %Seen)
  86   "Articles with the flags in the list will not be considered when splitting.")
  87
  88 (make-obsolete-variable 'nnimap-split-rule "see `nnimap-split-methods'"
  89                         "Emacs 24.1")
  90
  91 (defvoo nnimap-authenticator nil
  92   "How nnimap authenticate itself to the server.
  93 Possible choices are nil (use default methods) or `anonymous'.")
  94
  95 (defvoo nnimap-expunge t
  96   "If non-nil, expunge articles after deleting them.
  97 This is always done if the server supports UID EXPUNGE, but it's
  98 not done by default on servers that doesn't support that command.")
  99
 100 (defvoo nnimap-streaming t
 101   "If non-nil, try to use streaming commands with IMAP servers.
 102 Switching this off will make nnimap slower, but it helps with
 103 some servers.")
 104
 105 (defvoo nnimap-connection-alist nil)
 106
 107 (defvoo nnimap-current-infos nil)
 108
 109 (defvoo nnimap-fetch-partial-articles nil
 110   "If non-nil, Gnus will fetch partial articles.
 111 If t, nnimap will fetch only the first part.  If a string, it
 112 will fetch all parts that have types that match that string.  A
 113 likely value would be \"text/\" to automatically fetch all
 114 textual parts.")
 115
 116 (defvar nnimap-process nil)
 117
 118 (defvar nnimap-status-string "")
 119
 120 (defvar nnimap-split-download-body-default nil
 121   "Internal variable with default value for `nnimap-split-download-body'.")
 122
 123 (defvar nnimap-keepalive-timer nil)
 124 (defvar nnimap-process-buffers nil)
 125
 126 (defstruct nnimap
 127   group process commands capabilities select-result newlinep server
 128   last-command-time greeting examined)
 129
 130 (defvar nnimap-object nil)
 131
 132 (defvar nnimap-mark-alist
 133   '((read "\\Seen" %Seen)
 134     (tick "\\Flagged" %Flagged)
 135     (reply "\\Answered" %Answered)
 136     (expire "gnus-expire")
 137     (dormant "gnus-dormant")
 138     (score "gnus-score")
 139     (save "gnus-save")
 140     (download "gnus-download")
 141     (forward "gnus-forward")))
 142
 143 (defun nnimap-buffer ()
 144   (nnimap-find-process-buffer nntp-server-buffer))
 145
 146 (defun nnimap-header-parameters ()
 147   (format "(UID RFC822.SIZE BODYSTRUCTURE %s)"
 148           (format
 149            (if (nnimap-ver4-p)
 150                "BODY.PEEK[HEADER.FIELDS %s]"
 151              "RFC822.HEADER.LINES %s")
 152            (append '(Subject From Date Message-Id
 153                              References In-Reply-To Xref)
 154                    nnmail-extra-headers))))
 155
 156 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 157   (with-current-buffer nntp-server-buffer
 158     (erase-buffer)
 159     (when (nnimap-possibly-change-group group server)
 160       (with-current-buffer (nnimap-buffer)
 161         (erase-buffer)
 162         (nnimap-wait-for-response
 163          (nnimap-send-command
 164           "UID FETCH %s %s"
 165           (nnimap-article-ranges (gnus-compress-sequence articles))
 166           (nnimap-header-parameters))
 167          t)
 168         (nnimap-transform-headers))
 169       (insert-buffer-substring
 170        (nnimap-find-process-buffer (current-buffer))))
 171     'headers))
 172
 173 (defun nnimap-transform-headers ()
 174   (goto-char (point-min))
 175   (let (article bytes lines size string)
 176     (block nil
 177       (while (not (eobp))
 178         (while (not (looking-at "^\\* [0-9]+ FETCH.*UID \\([0-9]+\\)"))
 179           (delete-region (point) (progn (forward-line 1) (point)))
 180           (when (eobp)
 181             (return)))
 182         (setq article (match-string 1))
 183         ;; Unfold quoted {number} strings.
 184         (while (re-search-forward "[^]][ (]{\\([0-9]+\\)}\r?\n"
 185                                   (1+ (line-end-position)) t)
 186           (setq size (string-to-number (match-string 1)))
 187           (delete-region (+ (match-beginning 0) 2) (point))
 188           (setq string (buffer-substring (point) (+ (point) size)))
 189           (delete-region (point) (+ (point) size))
 190           (insert (format "%S" string)))
 191         (setq bytes (nnimap-get-length)
 192               lines nil)
 193         (beginning-of-line)
 194         (setq size
 195               (and (re-search-forward "RFC822.SIZE \\([0-9]+\\)"
 196                                       (line-end-position)
 197                                       t)
 198                    (match-string 1)))
 199         (beginning-of-line)
 200         (when (search-forward "BODYSTRUCTURE" (line-end-position) t)
 201           (let ((structure (ignore-errors
 202                              (read (current-buffer)))))
 203             (while (and (consp structure)
 204                         (not (stringp (car structure))))
 205               (setq structure (car structure)))
 206             (setq lines (nth 7 structure))))
 207         (delete-region (line-beginning-position) (line-end-position))
 208         (insert (format "211 %s Article retrieved." article))
 209         (forward-line 1)
 210         (when size
 211           (insert (format "Chars: %s\n" size)))
 212         (when lines
 213           (insert (format "Lines: %s\n" lines)))
 214         (unless (re-search-forward "^\r$" nil t)
 215           (goto-char (point-max)))
 216         (delete-region (line-beginning-position) (line-end-position))
 217         (insert ".")
 218         (forward-line 1)))))
 219
 220 (defun nnimap-unfold-quoted-lines ()
 221   ;; Unfold quoted {number} strings.
 222   (let (size string)
 223     (while (re-search-forward " {\\([0-9]+\\)}\r?\n" nil t)
 224       (setq size (string-to-number (match-string 1)))
 225       (delete-region (1+ (match-beginning 0)) (point))
 226       (setq string (buffer-substring (point) (+ (point) size)))
 227       (delete-region (point) (+ (point) size))
 228       (insert (format "%S" string)))))
 229
 230 (defun nnimap-get-length ()
 231   (and (re-search-forward "{\\([0-9]+\\)}" (line-end-position) t)
 232        (string-to-number (match-string 1))))
 233
 234 (defun nnimap-article-ranges (ranges)
 235   (let (result)
 236     (cond
 237      ((numberp ranges)
 238       (number-to-string ranges))
 239      ((numberp (cdr ranges))
 240       (format "%d:%d" (car ranges) (cdr ranges)))
 241      (t
 242       (dolist (elem ranges)
 243         (push
 244          (if (consp elem)
 245              (format "%d:%d" (car elem) (cdr elem))
 246            (number-to-string elem))
 247          result))
 248       (mapconcat #'identity (nreverse result) ",")))))
 249
 250 (deffoo nnimap-open-server (server &optional defs)
 251   (if (nnimap-server-opened server)
 252       t
 253     (unless (assq 'nnimap-address defs)
 254       (setq defs (append defs (list (list 'nnimap-address server)))))
 255     (nnoo-change-server 'nnimap server defs)
 256     (or (nnimap-find-connection nntp-server-buffer)
 257         (nnimap-open-connection nntp-server-buffer))))
 258
 259 (defun nnimap-make-process-buffer (buffer)
 260   (with-current-buffer
 261       (generate-new-buffer (format "*nnimap %s %s %s*"
 262                                    nnimap-address nnimap-server-port
 263                                    (gnus-buffer-exists-p buffer)))
 264     (mm-disable-multibyte)
 265     (buffer-disable-undo)
 266     (gnus-add-buffer)
 267     (set (make-local-variable 'after-change-functions) nil)
 268     (set (make-local-variable 'nnimap-object)
 269          (make-nnimap :server (nnoo-current-server 'nnimap)))
 270     (push (list buffer (current-buffer)) nnimap-connection-alist)
 271     (push (current-buffer) nnimap-process-buffers)
 272     (current-buffer)))
 273
 274 (defun nnimap-open-shell-stream (name buffer host port)
 275   (let ((process-connection-type nil))
 276     (start-process name buffer shell-file-name
 277                    shell-command-switch
 278                    (format-spec
 279                     nnimap-shell-program
 280                     (format-spec-make
 281                      ?s host
 282                      ?p port)))))
 283
 284 (defun nnimap-credentials (address ports &optional inhibit-create)
 285   (let (port credentials)
 286     ;; Request the credentials from all ports, but only query on the
 287     ;; last port if all the previous ones have failed.
 288     (while (and (null credentials)
 289                 (setq port (pop ports)))
 290       (setq credentials
 291             (auth-source-user-or-password
 292              '("login" "password") address port nil
 293              (if inhibit-create
 294                  nil
 295                (null ports)))))
 296     credentials))
 297
 298 (defun nnimap-keepalive ()
 299   (let ((now (current-time)))
 300     (dolist (buffer nnimap-process-buffers)
 301       (when (buffer-name buffer)
 302         (with-current-buffer buffer
 303           (when (and nnimap-object
 304                      (nnimap-last-command-time nnimap-object)
 305                      (> (gnus-float-time
 306                          (time-subtract
 307                           now
 308                           (nnimap-last-command-time nnimap-object)))
 309                         ;; More than five minutes since the last command.
 310                         (* 5 60)))
 311             (nnimap-send-command "NOOP")))))))
 312
 313 (declare-function gnutls-negotiate "gnutls"
 314                   (proc type &optional priority-string trustfiles keyfiles))
 315
 316 (defun nnimap-open-connection (buffer)
 317   (unless nnimap-keepalive-timer
 318     (setq nnimap-keepalive-timer (run-at-time (* 60 15) (* 60 15)
 319                                               'nnimap-keepalive)))
 320   (block nil
 321     (with-current-buffer (nnimap-make-process-buffer buffer)
 322       (let* ((coding-system-for-read 'binary)
 323              (coding-system-for-write 'binary)
 324              (port nil)
 325              (ports
 326               (cond
 327                ((or (eq nnimap-stream 'network)
 328                     (and (eq nnimap-stream 'starttls)
 329                          (fboundp 'open-gnutls-stream)))
 330                 (nnheader-message 7 "Opening connection to %s..."
 331                                   nnimap-address)
 332                 (open-network-stream
 333                  "*nnimap*" (current-buffer) nnimap-address
 334                  (setq port
 335                        (or nnimap-server-port
 336                            (if (netrc-find-service-number "imap")
 337                                "imap"
 338                              "143"))))
 339                 '("143" "imap"))
 340                ((eq nnimap-stream 'shell)
 341                 (nnheader-message 7 "Opening connection to %s via shell..."
 342                                   nnimap-address)
 343                 (nnimap-open-shell-stream
 344                  "*nnimap*" (current-buffer) nnimap-address
 345                  (setq port (or nnimap-server-port "imap")))
 346                 '("imap"))
 347                ((eq nnimap-stream 'starttls)
 348                 (nnheader-message 7 "Opening connection to %s via starttls..."
 349                          nnimap-address)
 350                 (let ((tls-program
 351                        '("openssl s_client -connect %h:%p -no_ssl2 -ign_eof -starttls imap")))
 352                   (open-tls-stream
 353                    "*nnimap*" (current-buffer) nnimap-address
 354                    (setq port (or nnimap-server-port "imap"))))
 355                 '("imap"))
 356                ((memq nnimap-stream '(ssl tls))
 357                 (nnheader-message 7 "Opening connection to %s via tls..."
 358                                   nnimap-address)
 359                 (funcall (if (fboundp 'open-gnutls-stream)
 360                              'open-gnutls-stream
 361                            'open-tls-stream)
 362                          "*nnimap*" (current-buffer) nnimap-address
 363                          (setq port
 364                                (or nnimap-server-port
 365                                    (if (netrc-find-service-number "imaps")
 366                                        "imaps"
 367                                      "993"))))
 368                 '("143" "993" "imap" "imaps"))
 369                (t
 370                 (error "Unknown stream type: %s" nnimap-stream))))
 371              connection-result login-result credentials)
 372         (setf (nnimap-process nnimap-object)
 373               (get-buffer-process (current-buffer)))
 374         (if (not (and (nnimap-process nnimap-object)
 375                       (memq (process-status (nnimap-process nnimap-object))
 376                             '(open run))))
 377             (nnheader-report 'nnimap "Unable to contact %s:%s via %s"
 378                              nnimap-address port nnimap-stream)
 379           (gnus-set-process-query-on-exit-flag
 380            (nnimap-process nnimap-object) nil)
 381           (if (not (setq connection-result (nnimap-wait-for-connection)))
 382               (nnheader-report 'nnimap
 383                                "%s" (buffer-substring
 384                                      (point) (line-end-position)))
 385             ;; Store the greeting (for debugging purposes).
 386             (setf (nnimap-greeting nnimap-object)
 387                   (buffer-substring (line-beginning-position)
 388                                     (line-end-position)))
 389             (nnimap-get-capabilities)
 390             (when nnimap-server-port
 391               (push (format "%s" nnimap-server-port) ports))
 392             ;; If this is a STARTTLS-capable server, then sever the
 393             ;; connection and start a STARTTLS connection instead.
 394             (cond
 395              ((and (or (and (eq nnimap-stream 'network)
 396                             (nnimap-capability "STARTTLS"))
 397                        (eq nnimap-stream 'starttls))
 398                    (fboundp 'open-gnutls-stream))
 399               (nnimap-command "STARTTLS")
 400               (gnutls-negotiate (nnimap-process nnimap-object) nil)
 401               ;; Get the capabilities again -- they may have changed
 402               ;; after doing STARTTLS.
 403               (nnimap-get-capabilities))
 404              ((and (eq nnimap-stream 'network)
 405                    (nnimap-capability "STARTTLS"))
 406               (let ((nnimap-stream 'starttls))
 407                 (let ((tls-process
 408                        (nnimap-open-connection buffer)))
 409                   ;; If the STARTTLS connection was successful, we
 410                   ;; kill our first non-encrypted connection.  If it
 411                   ;; wasn't successful, we just use our unencrypted
 412                   ;; connection.
 413                   (when (memq (process-status tls-process) '(open run))
 414                     (delete-process (nnimap-process nnimap-object))
 415                     (kill-buffer (current-buffer))
 416                     (return tls-process))))))
 417             (unless (equal connection-result "PREAUTH")
 418               (if (not (setq credentials
 419                              (if (eq nnimap-authenticator 'anonymous)
 420                                  (list "anonymous"
 421                                        (message-make-address))
 422                                (or
 423                                 ;; First look for the credentials based
 424                                 ;; on the virtual server name.
 425                                 (nnimap-credentials
 426                                  (nnoo-current-server 'nnimap) ports t)
 427                                 ;; Then look them up based on the
 428                                 ;; physical address.
 429                                 (nnimap-credentials nnimap-address ports)))))
 430                   (setq nnimap-object nil)
 431                 (setq login-result
 432                       (if (and (nnimap-capability "AUTH=PLAIN")
 433                                (nnimap-capability "LOGINDISABLED"))
 434                           (nnimap-command
 435                            "AUTHENTICATE PLAIN %s"
 436                            (base64-encode-string
 437                             (format "\000%s\000%s"
 438                                     (nnimap-quote-specials (car credentials))
 439                                     (nnimap-quote-specials (cadr credentials)))))
 440                         (nnimap-command "LOGIN %S %S"
 441                                         (car credentials)
 442                                         (cadr credentials))))
 443                 (unless (car login-result)
 444                   ;; If the login failed, then forget the credentials
 445                   ;; that are now possibly cached.
 446                   (dolist (host (list (nnoo-current-server 'nnimap)
 447                                       nnimap-address))
 448                     (dolist (port ports)
 449                       (dolist (element '("login" "password"))
 450                         (auth-source-forget-user-or-password
 451                          element host port))))
 452                   (delete-process (nnimap-process nnimap-object))
 453                   (setq nnimap-object nil))))
 454             (when nnimap-object
 455               (when (nnimap-capability "QRESYNC")
 456                 (nnimap-command "ENABLE QRESYNC"))
 457               (nnimap-process nnimap-object))))))))
 458
 459 (defun nnimap-get-capabilities ()
 460   (setf (nnimap-capabilities nnimap-object)
 461         (mapcar
 462          #'upcase
 463          (nnimap-find-parameter
 464           "CAPABILITY" (cdr (nnimap-command "CAPABILITY"))))))
 465
 466 (defun nnimap-quote-specials (string)
 467   (with-temp-buffer
 468     (insert string)
 469     (goto-char (point-min))
 470     (while (re-search-forward "[\\\"]" nil t)
 471       (forward-char -1)
 472       (insert "\\")
 473       (forward-char 1))
 474     (buffer-string)))
 475
 476 (defun nnimap-find-parameter (parameter elems)
 477   (let (result)
 478     (dolist (elem elems)
 479       (cond
 480        ((equal (car elem) parameter)
 481         (setq result (cdr elem)))
 482        ((and (equal (car elem) "OK")
 483              (consp (cadr elem))
 484              (equal (caadr elem) parameter))
 485         (setq result (cdr (cadr elem))))))
 486     result))
 487
 488 (deffoo nnimap-close-server (&optional server)
 489   (when (nnoo-change-server 'nnimap server nil)
 490     (ignore-errors
 491       (delete-process (get-buffer-process (nnimap-buffer))))
 492     (nnoo-close-server 'nnimap server)
 493     t))
 494
 495 (deffoo nnimap-request-close ()
 496   t)
 497
 498 (deffoo nnimap-server-opened (&optional server)
 499   (and (nnoo-current-server-p 'nnimap server)
 500        nntp-server-buffer
 501        (gnus-buffer-live-p nntp-server-buffer)
 502        (nnimap-find-connection nntp-server-buffer)))
 503
 504 (deffoo nnimap-status-message (&optional server)
 505   nnimap-status-string)
 506
 507 (deffoo nnimap-request-article (article &optional group server to-buffer)
 508   (with-current-buffer nntp-server-buffer
 509     (let ((result (nnimap-possibly-change-group group server))
 510           parts structure)
 511       (when (stringp article)
 512         (setq article (nnimap-find-article-by-message-id group article)))
 513       (when (and result
 514                  article)
 515         (erase-buffer)
 516         (with-current-buffer (nnimap-buffer)
 517           (erase-buffer)
 518           (when nnimap-fetch-partial-articles
 519             (nnimap-command "UID FETCH %d (BODYSTRUCTURE)" article)
 520             (goto-char (point-min))
 521             (when (re-search-forward "FETCH.*BODYSTRUCTURE" nil t)
 522               (setq structure (ignore-errors
 523                                 (let ((start (point)))
 524                                   (forward-sexp 1)
 525                                   (downcase-region start (point))
 526                                   (goto-char start)
 527                                   (read (current-buffer))))
 528                     parts (nnimap-find-wanted-parts structure))))
 529           (when (if parts
 530                     (nnimap-get-partial-article article parts structure)
 531                   (nnimap-get-whole-article article))
 532             (let ((buffer (current-buffer)))
 533               (with-current-buffer (or to-buffer nntp-server-buffer)
 534                 (erase-buffer)
 535                 (insert-buffer-substring buffer)
 536                 (nnheader-ms-strip-cr)
 537                 (cons group article)))))))))
 538
 539 (deffoo nnimap-request-head (article &optional group server to-buffer)
 540   (when (nnimap-possibly-change-group group server)
 541     (with-current-buffer (nnimap-buffer)
 542       (when (stringp article)
 543         (setq article (nnimap-find-article-by-message-id group article)))
 544       (nnimap-get-whole-article
 545        article (format "UID FETCH %%d %s"
 546                        (nnimap-header-parameters)))
 547       (let ((buffer (current-buffer)))
 548         (with-current-buffer (or to-buffer nntp-server-buffer)
 549           (erase-buffer)
 550           (insert-buffer-substring buffer)
 551           (nnheader-ms-strip-cr)
 552           (cons group article))))))
 553
 554 (defun nnimap-get-whole-article (article &optional command)
 555   (let ((result
 556          (nnimap-command
 557           (or command
 558               (if (nnimap-ver4-p)
 559                   "UID FETCH %d BODY.PEEK[]"
 560                 "UID FETCH %d RFC822.PEEK"))
 561           article)))
 562     ;; Check that we really got an article.
 563     (goto-char (point-min))
 564     (unless (re-search-forward "\\* [0-9]+ FETCH" nil t)
 565       (setq result nil))
 566     (when result
 567       ;; Remove any data that may have arrived before the FETCH data.
 568       (beginning-of-line)
 569       (unless (bobp)
 570         (delete-region (point-min) (point)))
 571       (let ((bytes (nnimap-get-length)))
 572         (delete-region (line-beginning-position)
 573                        (progn (forward-line 1) (point)))
 574         (goto-char (+ (point) bytes))
 575         (delete-region (point) (point-max)))
 576       t)))
 577
 578 (defun nnimap-capability (capability)
 579   (member capability (nnimap-capabilities nnimap-object)))
 580
 581 (defun nnimap-ver4-p ()
 582   (nnimap-capability "IMAP4REV1"))
 583
 584 (defun nnimap-get-partial-article (article parts structure)
 585   (let ((result
 586          (nnimap-command
 587           "UID FETCH %d (%s %s)"
 588           article
 589           (if (nnimap-ver4-p)
 590               "BODY.PEEK[HEADER]"
 591             "RFC822.HEADER")
 592           (if (nnimap-ver4-p)
 593               (mapconcat (lambda (part)
 594                            (format "BODY.PEEK[%s]" part))
 595                          parts " ")
 596             (mapconcat (lambda (part)
 597                          (format "RFC822.PEEK[%s]" part))
 598                        parts " ")))))
 599     (when result
 600       (nnimap-convert-partial-article structure))))
 601
 602 (defun nnimap-convert-partial-article (structure)
 603   ;; First just skip past the headers.
 604   (goto-char (point-min))
 605   (let ((bytes (nnimap-get-length))
 606         id parts)
 607     ;; Delete "FETCH" line.
 608     (delete-region (line-beginning-position)
 609                    (progn (forward-line 1) (point)))
 610     (goto-char (+ (point) bytes))
 611     ;; Collect all the body parts.
 612     (while (looking-at ".*BODY\\[\\([.0-9]+\\)\\]")
 613       (setq id (match-string 1)
 614             bytes (nnimap-get-length))
 615       (beginning-of-line)
 616       (delete-region (point) (progn (forward-line 1) (point)))
 617       (push (list id (buffer-substring (point) (+ (point) bytes)))
 618             parts)
 619       (delete-region (point) (+ (point) bytes)))
 620     ;; Delete trailing junk.
 621     (delete-region (point) (point-max))
 622     ;; Now insert all the parts again where they fit in the structure.
 623     (nnimap-insert-partial-structure structure parts)
 624     t))
 625
 626 (defun nnimap-insert-partial-structure (structure parts &optional subp)
 627   (let (type boundary)
 628     (let ((bstruc structure))
 629       (while (consp (car bstruc))
 630         (pop bstruc))
 631       (setq type (car bstruc))
 632       (setq bstruc (car (cdr bstruc)))
 633       (let ((has-boundary (member "boundary" bstruc)))
 634         (when has-boundary
 635           (setq boundary (cadr has-boundary)))))
 636     (when subp
 637       (insert (format "Content-type: multipart/%s; boundary=%S\n\n"
 638                       (downcase type) boundary)))
 639     (while (not (stringp (car structure)))
 640       (insert "\n--" boundary "\n")
 641       (if (consp (caar structure))
 642           (nnimap-insert-partial-structure (pop structure) parts t)
 643         (let ((bit (pop structure)))
 644           (insert (format  "Content-type: %s/%s"
 645                            (downcase (nth 0 bit))
 646                            (downcase (nth 1 bit))))
 647           (if (member "CHARSET" (nth 2 bit))
 648               (insert (format
 649                        "; charset=%S\n" (cadr (member "CHARSET" (nth 2 bit)))))
 650             (insert "\n"))
 651           (insert (format "Content-transfer-encoding: %s\n"
 652                           (nth 5 bit)))
 653           (insert "\n")
 654           (when (assoc (nth 9 bit) parts)
 655             (insert (cadr (assoc (nth 9 bit) parts)))))))
 656     (insert "\n--" boundary "--\n")))
 657
 658 (defun nnimap-find-wanted-parts (structure)
 659   (message-flatten-list (nnimap-find-wanted-parts-1 structure "")))
 660
 661 (defun nnimap-find-wanted-parts-1 (structure prefix)
 662   (let ((num 1)
 663         parts)
 664     (while (consp (car structure))
 665       (let ((sub (pop structure)))
 666         (if (consp (car sub))
 667             (push (nnimap-find-wanted-parts-1
 668                    sub (if (string= prefix "")
 669                            (number-to-string num)
 670                          (format "%s.%s" prefix num)))
 671                   parts)
 672           (let ((type (format "%s/%s" (nth 0 sub) (nth 1 sub)))
 673                 (id (if (string= prefix "")
 674                         (number-to-string num)
 675                       (format "%s.%s" prefix num))))
 676             (setcar (nthcdr 9 sub) id)
 677             (when (if (eq nnimap-fetch-partial-articles t)
 678                       (equal id "1")
 679                     (string-match nnimap-fetch-partial-articles type))
 680               (push id parts))))
 681         (incf num)))
 682     (nreverse parts)))
 683
 684 (deffoo nnimap-request-group (group &optional server dont-check info)
 685   (let ((result (nnimap-possibly-change-group
 686                  ;; Don't SELECT the group if we're going to select it
 687                  ;; later, anyway.
 688                  (if (and dont-check
 689                           (assoc group nnimap-current-infos))
 690                      nil
 691                    group)
 692                  server))
 693         articles active marks high low)
 694     (with-current-buffer nntp-server-buffer
 695       (when result
 696         (if (and dont-check
 697                  (setq active (nth 2 (assoc group nnimap-current-infos))))
 698             (insert (format "211 %d %d %d %S\n"
 699                             (- (cdr active) (car active))
 700                             (car active)
 701                             (cdr active)
 702                             group))
 703           (with-current-buffer (nnimap-buffer)
 704             (erase-buffer)
 705             (let ((group-sequence
 706                    (nnimap-send-command "SELECT %S" (utf7-encode group t)))
 707                   (flag-sequence
 708                    (nnimap-send-command "UID FETCH 1:* FLAGS")))
 709               (setf (nnimap-group nnimap-object) group)
 710               (nnimap-wait-for-response flag-sequence)
 711               (setq marks
 712                     (nnimap-flags-to-marks
 713                      (nnimap-parse-flags
 714                       (list (list group-sequence flag-sequence
 715                                   1 group "SELECT")))))
 716               (when (and info
 717                          marks)
 718                 (nnimap-update-infos marks (list info))
 719                 (nnimap-store-info info (gnus-active (gnus-info-group info))))
 720               (goto-char (point-max))
 721               (let ((uidnext (nth 5 (car marks))))
 722                 (setq high (or (if uidnext
 723                                    (1- uidnext)
 724                                  (nth 3 (car marks)))
 725                                0)
 726                       low (or (nth 4 (car marks)) uidnext 1)))))
 727           (erase-buffer)
 728           (insert
 729            (format
 730             "211 %d %d %d %S\n" (1+ (- high low)) low high group)))
 731         t))))
 732
 733 (deffoo nnimap-request-create-group (group &optional server args)
 734   (when (nnimap-possibly-change-group nil server)
 735     (with-current-buffer (nnimap-buffer)
 736       (car (nnimap-command "CREATE %S" (utf7-encode group t))))))
 737
 738 (deffoo nnimap-request-delete-group (group &optional force server)
 739   (when (nnimap-possibly-change-group nil server)
 740     (with-current-buffer (nnimap-buffer)
 741       (car (nnimap-command "DELETE %S" (utf7-encode group t))))))
 742
 743 (deffoo nnimap-request-rename-group (group new-name &optional server)
 744   (when (nnimap-possibly-change-group nil server)
 745     (with-current-buffer (nnimap-buffer)
 746       (nnimap-unselect-group)
 747       (car (nnimap-command "RENAME %S %S"
 748                            (utf7-encode group t) (utf7-encode new-name t))))))
 749
 750 (defun nnimap-unselect-group ()
 751   ;; Make sure we don't have this group open read/write by asking
 752   ;; to examine a mailbox that doesn't exist.  This seems to be
 753   ;; the only way that allows us to reliably go back to unselected
 754   ;; state on Courier.
 755   (nnimap-command "EXAMINE DOES.NOT.EXIST"))
 756
 757 (deffoo nnimap-request-expunge-group (group &optional server)
 758   (when (nnimap-possibly-change-group group server)
 759     (with-current-buffer (nnimap-buffer)
 760       (car (nnimap-command "EXPUNGE")))))
 761
 762 (defun nnimap-get-flags (spec)
 763   (let ((articles nil)
 764         elems end)
 765     (with-current-buffer (nnimap-buffer)
 766       (erase-buffer)
 767       (nnimap-wait-for-response (nnimap-send-command
 768                                  "UID FETCH %s FLAGS" spec))
 769       (setq end (point))
 770       (subst-char-in-region (point-min) (point-max)
 771                             ?\\ ?% t)
 772       (goto-char (point-min))
 773       (while (search-forward " FETCH " end t)
 774         (setq elems (read (current-buffer)))
 775         (push (cons (cadr (memq 'UID elems))
 776                     (cadr (memq 'FLAGS elems)))
 777               articles)))
 778     (nreverse articles)))
 779
 780 (deffoo nnimap-close-group (group &optional server)
 781   t)
 782
 783 (deffoo nnimap-request-move-article (article group server accept-form
 784                                              &optional last internal-move-group)
 785   (with-temp-buffer
 786     (mm-disable-multibyte)
 787     (when (funcall (if internal-move-group
 788                        'nnimap-request-head
 789                      'nnimap-request-article)
 790                    article group server (current-buffer))
 791       ;; If the move is internal (on the same server), just do it the easy
 792       ;; way.
 793       (let ((message-id (message-field-value "message-id")))
 794         (if internal-move-group
 795             (let ((result
 796                    (with-current-buffer (nnimap-buffer)
 797                      (nnimap-command "UID COPY %d %S"
 798                                      article
 799                                      (utf7-encode internal-move-group t)))))
 800               (when (car result)
 801                 (nnimap-delete-article article)
 802                 (cons internal-move-group
 803                       (or (nnimap-find-uid-response "COPYUID" (cadr result))
 804                           (nnimap-find-article-by-message-id
 805                            internal-move-group message-id)))))
 806           ;; Move the article to a different method.
 807           (let ((result (eval accept-form)))
 808             (when result
 809               (nnimap-delete-article article)
 810               result)))))))
 811
 812 (deffoo nnimap-request-expire-articles (articles group &optional server force)
 813   (cond
 814    ((null articles)
 815     nil)
 816    ((not (nnimap-possibly-change-group group server))
 817     articles)
 818    ((and force
 819          (eq nnmail-expiry-target 'delete))
 820     (unless (nnimap-delete-article (gnus-compress-sequence articles))
 821       (nnheader-message 7 "Article marked for deletion, but not expunged."))
 822     nil)
 823    (t
 824     (let ((deletable-articles
 825            (if (or force
 826                    (eq nnmail-expiry-wait 'immediate))
 827                articles
 828              (gnus-sorted-intersection
 829               articles
 830               (nnimap-find-expired-articles group)))))
 831       (if (null deletable-articles)
 832           articles
 833         (if (eq nnmail-expiry-target 'delete)
 834             (nnimap-delete-article (gnus-compress-sequence deletable-articles))
 835           (setq deletable-articles
 836                 (nnimap-process-expiry-targets
 837                  deletable-articles group server)))
 838         ;; Return the articles we didn't delete.
 839         (gnus-sorted-complement articles deletable-articles))))))
 840
 841 (defun nnimap-process-expiry-targets (articles group server)
 842   (let ((deleted-articles nil))
 843     (dolist (article articles)
 844       (let ((target nnmail-expiry-target))
 845         (with-temp-buffer
 846           (mm-disable-multibyte)
 847           (when (nnimap-request-article article group server (current-buffer))
 848             (nnheader-message 7 "Expiring article %s:%d" group article)
 849             (when (functionp target)
 850               (setq target (funcall target group)))
 851             (when (and target
 852                        (not (eq target 'delete)))
 853               (if (or (gnus-request-group target t)
 854                       (gnus-request-create-group target))
 855                   (nnmail-expiry-target-group target group)
 856                 (setq target nil)))
 857             (when target
 858               (push article deleted-articles))))))
 859     ;; Change back to the current group again.
 860     (nnimap-possibly-change-group group server)
 861     (setq deleted-articles (nreverse deleted-articles))
 862     (nnimap-delete-article (gnus-compress-sequence deleted-articles))
 863     deleted-articles))
 864
 865 (defun nnimap-find-expired-articles (group)
 866   (let ((cutoff (nnmail-expired-article-p group nil nil)))
 867     (with-current-buffer (nnimap-buffer)
 868       (let ((result
 869              (nnimap-command
 870               "UID SEARCH SENTBEFORE %s"
 871               (format-time-string
 872                (format "%%d-%s-%%Y"
 873                        (upcase
 874                         (car (rassoc (nth 4 (decode-time cutoff))
 875                                      parse-time-months))))
 876                cutoff))))
 877         (and (car result)
 878              (delete 0 (mapcar #'string-to-number
 879                                (cdr (assoc "SEARCH" (cdr result))))))))))
 880
 881
 882 (defun nnimap-find-article-by-message-id (group message-id)
 883   (with-current-buffer (nnimap-buffer)
 884     (erase-buffer)
 885     (unless (equal group (nnimap-group nnimap-object))
 886       (setf (nnimap-group nnimap-object) nil)
 887       (setf (nnimap-examined nnimap-object) group)
 888       (nnimap-send-command "EXAMINE %S" (utf7-encode group t)))
 889     (let ((sequence
 890            (nnimap-send-command "UID SEARCH HEADER Message-Id %S" message-id))
 891           article result)
 892       (setq result (nnimap-wait-for-response sequence))
 893       (when (and result
 894                  (car (setq result (nnimap-parse-response))))
 895         ;; Select the last instance of the message in the group.
 896         (and (setq article
 897                    (car (last (assoc "SEARCH" (cdr result)))))
 898              (string-to-number article))))))
 899
 900 (defun nnimap-delete-article (articles)
 901   (with-current-buffer (nnimap-buffer)
 902     (nnimap-command "UID STORE %s +FLAGS.SILENT (\\Deleted)"
 903                     (nnimap-article-ranges articles))
 904     (cond
 905      ((nnimap-capability "UIDPLUS")
 906       (nnimap-command "UID EXPUNGE %s"
 907                       (nnimap-article-ranges articles))
 908       t)
 909      (nnimap-expunge
 910       (nnimap-command "EXPUNGE")
 911       t)
 912      (t (gnus-message 7 (concat "nnimap: nnimap-expunge is not set and the "
 913                                 "server doesn't support UIDPLUS, so we won't "
 914                                 "delete this article now"))))))
 915
 916 (deffoo nnimap-request-scan (&optional group server)
 917   (when (and (nnimap-possibly-change-group nil server)
 918              nnimap-inbox
 919              nnimap-split-methods)
 920     (nnheader-message 7 "nnimap %s splitting mail..." server)
 921     (nnimap-split-incoming-mail)))
 922
 923 (defun nnimap-marks-to-flags (marks)
 924   (let (flags flag)
 925     (dolist (mark marks)
 926       (when (setq flag (cadr (assq mark nnimap-mark-alist)))
 927         (push flag flags)))
 928     flags))
 929
 930 (deffoo nnimap-request-set-mark (group actions &optional server)
 931   (when (nnimap-possibly-change-group group server)
 932     (let (sequence)
 933       (with-current-buffer (nnimap-buffer)
 934         (erase-buffer)
 935         ;; Just send all the STORE commands without waiting for
 936         ;; response.  If they're successful, they're successful.
 937         (dolist (action actions)
 938           (destructuring-bind (range action marks) action
 939             (let ((flags (nnimap-marks-to-flags marks)))
 940               (when flags
 941                 (setq sequence (nnimap-send-command
 942                                 "UID STORE %s %sFLAGS.SILENT (%s)"
 943                                 (nnimap-article-ranges range)
 944                                 (if (eq action 'del)
 945                                     "-"
 946                                   "+")
 947                                 (mapconcat #'identity flags " ")))))))
 948         ;; Wait for the last command to complete to avoid later
 949         ;; syncronisation problems with the stream.
 950         (when sequence
 951           (nnimap-wait-for-response sequence))))))
 952
 953 (deffoo nnimap-request-accept-article (group &optional server last)
 954   (when (nnimap-possibly-change-group nil server)
 955     (nnmail-check-syntax)
 956     (let ((message-id (message-field-value "message-id"))
 957           sequence message)
 958       (nnimap-add-cr)
 959       (setq message (buffer-substring-no-properties (point-min) (point-max)))
 960       (with-current-buffer (nnimap-buffer)
 961         ;; If we have this group open read-only, then unselect it
 962         ;; before appending to it.
 963         (when (equal (nnimap-examined nnimap-object) group)
 964           (nnimap-unselect-group))
 965         (erase-buffer)
 966         (setq sequence (nnimap-send-command
 967                         "APPEND %S {%d}" (utf7-encode group t)
 968                         (length message)))
 969         (unless nnimap-streaming
 970           (nnimap-wait-for-connection "^[+]"))
 971         (process-send-string (get-buffer-process (current-buffer)) message)
 972         (process-send-string (get-buffer-process (current-buffer))
 973                              (if (nnimap-newlinep nnimap-object)
 974                                  "\n"
 975                                "\r\n"))
 976         (let ((result (nnimap-get-response sequence)))
 977           (if (not (car result))
 978               (progn
 979                 (nnheader-message 7 "%s" (nnheader-get-report-string 'nnimap))
 980                 nil)
 981             (cons group
 982                   (or (nnimap-find-uid-response "APPENDUID" (car result))
 983                       (nnimap-find-article-by-message-id
 984                        group message-id)))))))))
 985
 986 (defun nnimap-find-uid-response (name list)
 987   (let ((result (nth 2 (nnimap-find-response-element name list))))
 988     (and result
 989          (string-to-number result))))
 990
 991 (defun nnimap-find-response-element (name list)
 992   (let (result)
 993     (dolist (elem list)
 994       (when (and (consp elem)
 995                  (equal name (car elem)))
 996         (setq result elem)))
 997     result))
 998
 999 (deffoo nnimap-request-replace-article (article group buffer)
1000   (let (group-art)
1001     (when (and (nnimap-possibly-change-group group nil)
1002                ;; Put the article into the group.
1003                (with-current-buffer buffer
1004                  (setq group-art
1005                        (nnimap-request-accept-article group nil t))))
1006       (nnimap-delete-article (list article))
1007       ;; Return the new article number.
1008       (cdr group-art))))
1009
1010 (defun nnimap-add-cr ()
1011   (goto-char (point-min))
1012   (while (re-search-forward "\r?\n" nil t)
1013     (replace-match "\r\n" t t)))
1014
1015 (defun nnimap-get-groups ()
1016   (let ((result (nnimap-command "LIST \"\" \"*\""))
1017         groups)
1018     (when (car result)
1019       (dolist (line (cdr result))
1020         (when (and (equal (car line) "LIST")
1021                    (not (and (caadr line)
1022                              (string-match "noselect" (caadr line)))))
1023           (push (car (last line)) groups)))
1024       (nreverse groups))))
1025
1026 (deffoo nnimap-request-list (&optional server)
1027   (nnimap-possibly-change-group nil server)
1028   (with-current-buffer nntp-server-buffer
1029     (erase-buffer)
1030     (let ((groups
1031            (with-current-buffer (nnimap-buffer)
1032              (nnimap-get-groups)))
1033           sequences responses)
1034       (when groups
1035         (with-current-buffer (nnimap-buffer)
1036           (setf (nnimap-group nnimap-object) nil)
1037           (dolist (group groups)
1038             (setf (nnimap-examined nnimap-object) group)
1039             (push (list (nnimap-send-command "EXAMINE %S" (utf7-encode group t))
1040                         group)
1041                   sequences))
1042           (nnimap-wait-for-response (caar sequences))
1043           (setq responses
1044                 (nnimap-get-responses (mapcar #'car sequences))))
1045         (dolist (response responses)
1046           (let* ((sequence (car response))
1047                  (response (cadr response))
1048                  (group (cadr (assoc sequence sequences))))
1049             (when (and group
1050                        (equal (caar response) "OK"))
1051               (let ((uidnext (nnimap-find-parameter "UIDNEXT" response))
1052                     highest exists)
1053                 (dolist (elem response)
1054                   (when (equal (cadr elem) "EXISTS")
1055                     (setq exists (string-to-number (car elem)))))
1056                 (when uidnext
1057                   (setq highest (1- (string-to-number (car uidnext)))))
1058                 (cond
1059                  ((null highest)
1060                   (insert (format "%S 0 1 y\n" (utf7-decode group t))))
1061                  ((zerop exists)
1062                   ;; Empty group.
1063                   (insert (format "%S %d %d y\n"
1064                                   (utf7-decode group t) highest (1+ highest))))
1065                  (t
1066                   ;; Return the widest possible range.
1067                   (insert (format "%S %d 1 y\n" (utf7-decode group t)
1068                                   (or highest exists)))))))))
1069         t))))
1070
1071 (deffoo nnimap-request-newgroups (date &optional server)
1072   (nnimap-possibly-change-group nil server)
1073   (with-current-buffer nntp-server-buffer
1074     (erase-buffer)
1075     (dolist (group (with-current-buffer (nnimap-buffer)
1076                      (nnimap-get-groups)))
1077       (unless (assoc group nnimap-current-infos)
1078         ;; Insert dummy numbers here -- they don't matter.
1079         (insert (format "%S 0 1 y\n" group))))
1080     t))
1081
1082 (deffoo nnimap-retrieve-group-data-early (server infos)
1083   (when (nnimap-possibly-change-group nil server)
1084     (with-current-buffer (nnimap-buffer)
1085       (erase-buffer)
1086       (setf (nnimap-group nnimap-object) nil)
1087       (let ((qresyncp (nnimap-capability "QRESYNC"))
1088             params groups sequences active uidvalidity modseq group)
1089         ;; Go through the infos and gather the data needed to know
1090         ;; what and how to request the data.
1091         (dolist (info infos)
1092           (setq params (gnus-info-params info)
1093                 group (gnus-group-real-name (gnus-info-group info))
1094                 active (cdr (assq 'active params))
1095                 uidvalidity (cdr (assq 'uidvalidity params))
1096                 modseq (cdr (assq 'modseq params)))
1097           (setf (nnimap-examined nnimap-object) group)
1098           (if (and qresyncp
1099                    uidvalidity
1100                    modseq)
1101               (push
1102                (list (nnimap-send-command "EXAMINE %S (QRESYNC (%s %s))"
1103                                           (utf7-encode group t)
1104                                           uidvalidity modseq)
1105                      'qresync
1106                      nil group 'qresync)
1107                sequences)
1108             (let ((start
1109                    (if (and active uidvalidity)
1110                        ;; Fetch the last 100 flags.
1111                        (max 1 (- (cdr active) 100))
1112                      1))
1113                   (command
1114                    (if uidvalidity
1115                        "EXAMINE"
1116                      ;; If we don't have a UIDVALIDITY, then this is
1117                      ;; the first time we've seen the group, so we
1118                      ;; have to do a SELECT (which is slower than an
1119                      ;; examine), but will tell us whether the group
1120                      ;; is read-only or not.
1121                      "SELECT")))
1122               (push (list (nnimap-send-command "%s %S" command
1123                                                (utf7-encode group t))
1124                           (nnimap-send-command "UID FETCH %d:* FLAGS" start)
1125                           start group command)
1126                     sequences))))
1127         sequences))))
1128
1129 (deffoo nnimap-finish-retrieve-group-infos (server infos sequences)
1130   (when (and sequences
1131              (nnimap-possibly-change-group nil server))
1132     (with-current-buffer (nnimap-buffer)
1133       ;; Wait for the final data to trickle in.
1134       (when (nnimap-wait-for-response (if (eq (cadar sequences) 'qresync)
1135                                           (caar sequences)
1136                                         (cadar sequences))
1137                                       t)
1138         ;; Now we should have most of the data we need, no matter
1139         ;; whether we're QRESYNCING, fetching all the flags from
1140         ;; scratch, or just fetching the last 100 flags per group.
1141         (nnimap-update-infos (nnimap-flags-to-marks
1142                               (nnimap-parse-flags
1143                                (nreverse sequences)))
1144                              infos)
1145         ;; Finally, just return something resembling an active file in
1146         ;; the nntp buffer, so that the agent can save the info, too.
1147         (with-current-buffer nntp-server-buffer
1148           (erase-buffer)
1149           (dolist (info infos)
1150             (let* ((group (gnus-info-group info))
1151                    (active (gnus-active group)))
1152               (when active
1153                 (insert (format "%S %d %d y\n"
1154                                 (gnus-group-real-name group)
1155                                 (cdr active)
1156                                 (car active)))))))))))
1157
1158 (defun nnimap-update-infos (flags infos)
1159   (dolist (info infos)
1160     (let* ((group (gnus-group-real-name (gnus-info-group info)))
1161            (marks (cdr (assoc group flags))))
1162       (when marks
1163         (nnimap-update-info info marks)))))
1164
1165 (defun nnimap-update-info (info marks)
1166   (destructuring-bind (existing flags high low uidnext start-article
1167                                 permanent-flags uidvalidity
1168                                 vanished highestmodseq) marks
1169     (cond
1170      ;; Ignore groups with no UIDNEXT/marks.  This happens for
1171      ;; completely empty groups.
1172      ((and (not existing)
1173            (not uidnext))
1174       (let ((active (cdr (assq 'active (gnus-info-params info)))))
1175         (when active
1176           (gnus-set-active (gnus-info-group info) active))))
1177      ;; We have a mismatch between the old and new UIDVALIDITY
1178      ;; identifiers, so we have to re-request the group info (the next
1179      ;; time).  This virtually never happens.
1180      ((let ((old-uidvalidity
1181              (cdr (assq 'uidvalidity (gnus-info-params info)))))
1182         (and old-uidvalidity
1183              (not (equal old-uidvalidity uidvalidity))
1184              (> start-article 1)))
1185       (gnus-group-remove-parameter info 'uidvalidity)
1186       (gnus-group-remove-parameter info 'modseq))
1187      ;; We have the data needed to update.
1188      (t
1189       (let* ((group (gnus-info-group info))
1190              (completep (and start-article
1191                              (= start-article 1)))
1192              (active (or (gnus-active group)
1193                          (cdr (assq 'active (gnus-info-params info))))))
1194         (when uidnext
1195           (setq high (1- uidnext)))
1196         ;; First set the active ranges based on high/low.
1197         (if (or completep
1198                 (not (gnus-active group)))
1199             (gnus-set-active group
1200                              (cond
1201                               (active
1202                                (cons (min (or low (car active))
1203                                           (car active))
1204                                      (max (or high (cdr active))
1205                                           (cdr active))))
1206                               ((and low high)
1207                                (cons low high))
1208                               (uidnext
1209                                ;; No articles in this group.
1210                                (cons uidnext (1- uidnext)))
1211                               (start-article
1212                                (cons start-article (1- start-article)))
1213                               (t
1214                                ;; No articles and no uidnext.
1215                                nil)))
1216           (gnus-set-active
1217            group
1218            (cons (car active)
1219                  (or high (1- uidnext)))))
1220         ;; See whether this is a read-only group.
1221         (unless (eq permanent-flags 'not-scanned)
1222           (gnus-group-set-parameter
1223            info 'permanent-flags
1224            (and (or (memq '%* permanent-flags)
1225                     (memq '%Seen permanent-flags))
1226                 permanent-flags)))
1227         ;; Update marks and read articles if this isn't a
1228         ;; read-only IMAP group.
1229         (when (setq permanent-flags
1230                     (cdr (assq 'permanent-flags (gnus-info-params info))))
1231           (if (and highestmodseq
1232                    (not start-article))
1233               ;; We've gotten the data by QRESYNCing.
1234               (nnimap-update-qresync-info
1235                info existing (nnimap-imap-ranges-to-gnus-ranges vanished) flags)
1236             ;; Do normal non-QRESYNC flag updates.
1237             ;; Update the list of read articles.
1238             (let* ((unread
1239                     (gnus-compress-sequence
1240                      (gnus-set-difference
1241                       (gnus-set-difference
1242                        existing
1243                        (cdr (assoc '%Seen flags)))
1244                       (cdr (assoc '%Flagged flags)))))
1245                    (read (gnus-range-difference
1246                           (cons start-article high) unread)))
1247               (when (> start-article 1)
1248                 (setq read
1249                       (gnus-range-nconcat
1250                        (if (> start-article 1)
1251                            (gnus-sorted-range-intersection
1252                             (cons 1 (1- start-article))
1253                             (gnus-info-read info))
1254                          (gnus-info-read info))
1255                        read)))
1256               (when (or (not (listp permanent-flags))
1257                         (memq '%Seen permanent-flags))
1258                 (gnus-info-set-read info read))
1259               ;; Update the marks.
1260               (setq marks (gnus-info-marks info))
1261               (dolist (type (cdr nnimap-mark-alist))
1262                 (when (or (not (listp permanent-flags))
1263                           (memq (car (assoc (caddr type) flags))
1264                                 permanent-flags)
1265                           (memq '%* permanent-flags))
1266                   (let ((old-marks (assoc (car type) marks))
1267                         (new-marks
1268                          (gnus-compress-sequence
1269                           (cdr (or (assoc (caddr type) flags) ; %Flagged
1270                                    (assoc (intern (cadr type) obarray) flags)
1271                                    (assoc (cadr type) flags)))))) ; "\Flagged"
1272                     (setq marks (delq old-marks marks))
1273                     (pop old-marks)
1274                     (when (and old-marks
1275                                (> start-article 1))
1276                       (setq old-marks (gnus-range-difference
1277                                        old-marks
1278                                        (cons start-article high)))
1279                       (setq new-marks (gnus-range-nconcat old-marks new-marks)))
1280                     (when new-marks
1281                       (push (cons (car type) new-marks) marks)))))
1282               (gnus-info-set-marks info marks t))))
1283         ;; Note the active level for the next run-through.
1284         (gnus-group-set-parameter info 'active (gnus-active group))
1285         (gnus-group-set-parameter info 'uidvalidity uidvalidity)
1286         (gnus-group-set-parameter info 'modseq highestmodseq)
1287         (nnimap-store-info info (gnus-active group)))))))
1288
1289 (defun nnimap-update-qresync-info (info existing vanished flags)
1290   ;; Add all the vanished articles to the list of read articles.
1291   (gnus-info-set-read
1292    info
1293    (gnus-add-to-range
1294     (gnus-add-to-range
1295      (gnus-range-add (gnus-info-read info)
1296                      vanished)
1297      (cdr (assq '%Flagged flags)))
1298     (cdr (assq '%Seen flags))))
1299   (let ((marks (gnus-info-marks info)))
1300     (dolist (type (cdr nnimap-mark-alist))
1301       (let ((ticks (assoc (car type) marks))
1302             (new-marks
1303              (cdr (or (assoc (caddr type) flags) ; %Flagged
1304                       (assoc (intern (cadr type) obarray) flags)
1305                       (assoc (cadr type) flags))))) ; "\Flagged"
1306         (setq marks (delq ticks marks))
1307         (pop ticks)
1308         ;; Add the new marks we got.
1309         (setq ticks (gnus-add-to-range ticks new-marks))
1310         ;; Remove the marks from messages that don't have them.
1311         (setq ticks (gnus-remove-from-range
1312                      ticks
1313                      (gnus-compress-sequence
1314                       (gnus-sorted-complement existing new-marks))))
1315         (when ticks
1316           (push (cons (car type) ticks) marks)))
1317       (gnus-info-set-marks info marks t))))
1318
1319 (defun nnimap-imap-ranges-to-gnus-ranges (irange)
1320   (if (zerop (length irange))
1321       nil
1322     (let ((result nil))
1323       (dolist (elem (split-string irange ","))
1324         (push
1325          (if (string-match ":" elem)
1326              (let ((numbers (split-string elem ":")))
1327                (cons (string-to-number (car numbers))
1328                      (string-to-number (cadr numbers))))
1329            (string-to-number elem))
1330          result))
1331       (nreverse result))))
1332
1333 (defun nnimap-store-info (info active)
1334   (let* ((group (gnus-group-real-name (gnus-info-group info)))
1335          (entry (assoc group nnimap-current-infos)))
1336     (if entry
1337         (setcdr entry (list info active))
1338       (push (list group info active) nnimap-current-infos))))
1339
1340 (defun nnimap-flags-to-marks (groups)
1341   (let (data group totalp uidnext articles start-article mark permanent-flags
1342              uidvalidity vanished highestmodseq)
1343     (dolist (elem groups)
1344       (setq group (car elem)
1345             uidnext (nth 1 elem)
1346             start-article (nth 2 elem)
1347             permanent-flags (nth 3 elem)
1348             uidvalidity (nth 4 elem)
1349             vanished (nth 5 elem)
1350             highestmodseq (nth 6 elem)
1351             articles (nthcdr 7 elem))
1352       (let ((high (caar articles))
1353             marks low existing)
1354         (dolist (article articles)
1355           (setq low (car article))
1356           (push (car article) existing)
1357           (dolist (flag (cdr article))
1358             (setq mark (assoc flag marks))
1359             (if (not mark)
1360                 (push (list flag (car article)) marks)
1361               (setcdr mark (cons (car article) (cdr mark))))))
1362         (push (list group existing marks high low uidnext start-article
1363                     permanent-flags uidvalidity vanished highestmodseq)
1364               data)))
1365     data))
1366
1367 (defun nnimap-parse-flags (sequences)
1368   (goto-char (point-min))
1369   ;; Change \Delete etc to %Delete, so that the reader can read it.
1370   (subst-char-in-region (point-min) (point-max)
1371                         ?\\ ?% t)
1372   (let (start end articles groups uidnext elems permanent-flags
1373               uidvalidity vanished highestmodseq)
1374     (dolist (elem sequences)
1375       (destructuring-bind (group-sequence flag-sequence totalp group command)
1376           elem
1377         (setq start (point))
1378         (when (and
1379                ;; The EXAMINE was successful.
1380                (search-forward (format "\n%d OK " group-sequence) nil t)
1381                (progn
1382                  (forward-line 1)
1383                  (setq end (point))
1384                  (goto-char start)
1385                  (setq permanent-flags
1386                        (if (equal command "SELECT")
1387                            (and (search-forward "PERMANENTFLAGS "
1388                                                 (or end (point-min)) t)
1389                                 (read (current-buffer)))
1390                          'not-scanned))
1391                  (goto-char start)
1392                  (setq uidnext
1393                        (and (search-forward "UIDNEXT "
1394                                             (or end (point-min)) t)
1395                             (read (current-buffer))))
1396                  (goto-char start)
1397                  (setq uidvalidity
1398                        (and (re-search-forward "UIDVALIDITY \\([0-9]+\\)"
1399                                                (or end (point-min)) t)
1400                             ;; Store UIDVALIDITY as a string, as it's
1401                             ;; too big for 32-bit Emacsen, usually.
1402                             (match-string 1)))
1403                  (goto-char start)
1404                  (setq vanished
1405                        (and (eq flag-sequence 'qresync)
1406                             (re-search-forward "VANISHED.* \\([0-9:,]+\\)"
1407                                                (or end (point-min)) t)
1408                             (match-string 1)))
1409                  (goto-char start)
1410                  (setq highestmodseq
1411                        (and (search-forward "HIGHESTMODSEQ "
1412                                             (or end (point-min)) t)
1413                             (read (current-buffer))))
1414                  (goto-char end)
1415                  (forward-line -1))
1416                ;; The UID FETCH FLAGS was successful.
1417                (or (eq flag-sequence 'qresync)
1418                    (search-forward (format "\n%d OK " flag-sequence) nil t)))
1419           (if (eq flag-sequence 'qresync)
1420               (progn
1421                 (goto-char start)
1422                 (setq start end))
1423             (setq start (point))
1424             (goto-char end))
1425           (while (re-search-forward "^\\* [0-9]+ FETCH " start t)
1426             (setq elems (read (current-buffer)))
1427             (push (cons (cadr (memq 'UID elems))
1428                         (cadr (memq 'FLAGS elems)))
1429                   articles))
1430           (push (nconc (list group uidnext totalp permanent-flags uidvalidity
1431                              vanished highestmodseq)
1432                        articles)
1433                 groups)
1434           (goto-char end)
1435           (setq articles nil))))
1436     groups))
1437
1438 (defun nnimap-find-process-buffer (buffer)
1439   (cadr (assoc buffer nnimap-connection-alist)))
1440
1441 (deffoo nnimap-request-post (&optional server)
1442   (setq nnimap-status-string "Read-only server")
1443   nil)
1444
1445 (deffoo nnimap-request-thread (id)
1446   (let* ((refs (split-string
1447                 (or (mail-header-references (gnus-summary-article-header))
1448                     "")))
1449          (cmd (let ((value
1450                      (format
1451                       "(OR HEADER REFERENCES %s HEADER Message-Id %s)"
1452                       id id)))
1453                 (dolist (refid refs value)
1454                   (setq value (format
1455                                "(OR (OR HEADER Message-Id %s HEADER REFERENCES %s) %s)"
1456                                refid refid value)))))
1457          (result (with-current-buffer (nnimap-buffer)
1458                    (nnimap-command  "UID SEARCH %s" cmd))))
1459     (gnus-fetch-headers
1460      (and (car result) (delete 0 (mapcar #'string-to-number
1461                                          (cdr (assoc "SEARCH" (cdr result))))))
1462      nil t)))
1463
1464 (defun nnimap-possibly-change-group (group server)
1465   (let ((open-result t))
1466     (when (and server
1467                (not (nnimap-server-opened server)))
1468       (setq open-result (nnimap-open-server server)))
1469     (cond
1470      ((not open-result)
1471       nil)
1472      ((not group)
1473       t)
1474      (t
1475       (with-current-buffer (nnimap-buffer)
1476         (if (equal group (nnimap-group nnimap-object))
1477             t
1478           (let ((result (nnimap-command "SELECT %S" (utf7-encode group t))))
1479             (when (car result)
1480               (setf (nnimap-group nnimap-object) group
1481                     (nnimap-select-result nnimap-object) result)
1482               result))))))))
1483
1484 (defun nnimap-find-connection (buffer)
1485   "Find the connection delivering to BUFFER."
1486   (let ((entry (assoc buffer nnimap-connection-alist)))
1487     (when entry
1488       (if (and (buffer-name (cadr entry))
1489                (get-buffer-process (cadr entry))
1490                (memq (process-status (get-buffer-process (cadr entry)))
1491                      '(open run)))
1492           (get-buffer-process (cadr entry))
1493         (setq nnimap-connection-alist (delq entry nnimap-connection-alist))
1494         nil))))
1495
1496 (defvar nnimap-sequence 0)
1497
1498 (defun nnimap-send-command (&rest args)
1499   (process-send-string
1500    (get-buffer-process (current-buffer))
1501    (nnimap-log-command
1502     (format "%d %s%s\n"
1503             (incf nnimap-sequence)
1504             (apply #'format args)
1505             (if (nnimap-newlinep nnimap-object)
1506                 ""
1507               "\r"))))
1508   ;; Some servers apparently can't have many outstanding
1509   ;; commands, so throttle them.
1510   (unless nnimap-streaming
1511     (nnimap-wait-for-response nnimap-sequence))
1512   nnimap-sequence)
1513
1514 (defun nnimap-log-command (command)
1515   (with-current-buffer (get-buffer-create "*imap log*")
1516     (goto-char (point-max))
1517     (insert (format-time-string "%H:%M:%S") " " command))
1518   command)
1519
1520 (defun nnimap-command (&rest args)
1521   (erase-buffer)
1522   (setf (nnimap-last-command-time nnimap-object) (current-time))
1523   (let* ((sequence (apply #'nnimap-send-command args))
1524          (response (nnimap-get-response sequence)))
1525     (if (equal (caar response) "OK")
1526         (cons t response)
1527       (nnheader-report 'nnimap "%s"
1528                        (mapconcat (lambda (a)
1529                                     (format "%s" a))
1530                                   (car response) " "))
1531       nil)))
1532
1533 (defun nnimap-get-response (sequence)
1534   (nnimap-wait-for-response sequence)
1535   (nnimap-parse-response))
1536
1537 (defun nnimap-wait-for-connection (&optional regexp)
1538   (unless regexp
1539     (setq regexp "^[*.] .*\n"))
1540   (let ((process (get-buffer-process (current-buffer))))
1541     (goto-char (point-min))
1542     (while (and (memq (process-status process)
1543                       '(open run))
1544                 (not (re-search-forward regexp nil t)))
1545       (nnheader-accept-process-output process)
1546       (goto-char (point-min)))
1547     (forward-line -1)
1548     (and (looking-at "[*.] \\([A-Z0-9]+\\)")
1549          (match-string 1))))
1550
1551 (defun nnimap-wait-for-response (sequence &optional messagep)
1552   (let ((process (get-buffer-process (current-buffer)))
1553         openp)
1554     (condition-case nil
1555         (progn
1556           (goto-char (point-max))
1557           (while (and (setq openp (memq (process-status process)
1558                                         '(open run)))
1559                       (not (re-search-backward
1560                             (format "^%d .*\n" sequence)
1561                             (if nnimap-streaming
1562                                 (max (point-min) (- (point) 500))
1563                               (point-min))
1564                             t)))
1565             (when messagep
1566               (nnheader-message 7 "nnimap read %dk" (/ (buffer-size) 1000)))
1567             (nnheader-accept-process-output process)
1568             (goto-char (point-max)))
1569           openp)
1570       (quit
1571        ;; The user hit C-g while we were waiting: kill the process, in case
1572        ;; it's a gnutls-cli process that's stuck (tends to happen a lot behind
1573        ;; NAT routers).
1574        (delete-process process)
1575        nil))))
1576
1577 (defun nnimap-parse-response ()
1578   (let ((lines (split-string (nnimap-last-response-string) "\r\n" t))
1579         result)
1580     (dolist (line lines)
1581       (push (cdr (nnimap-parse-line line)) result))
1582     ;; Return the OK/error code first, and then all the "continuation
1583     ;; lines" afterwards.
1584     (cons (pop result)
1585           (nreverse result))))
1586
1587 ;; Parse an IMAP response line lightly.  They look like
1588 ;; "* OK [UIDVALIDITY 1164213559] UIDs valid", typically, so parse
1589 ;; the lines into a list of strings and lists of string.
1590 (defun nnimap-parse-line (line)
1591   (let (char result)
1592     (with-temp-buffer
1593       (mm-disable-multibyte)
1594       (insert line)
1595       (goto-char (point-min))
1596       (while (not (eobp))
1597         (if (eql (setq char (following-char)) ? )
1598             (forward-char 1)
1599           (push
1600            (cond
1601             ((eql char ?\[)
1602              (split-string
1603               (buffer-substring
1604                (1+ (point))
1605                (if (search-forward "]" (line-end-position) 'move)
1606                    (1- (point))
1607                  (point)))))
1608             ((eql char ?\()
1609              (split-string
1610               (buffer-substring
1611                (1+ (point))
1612                (if (search-forward ")" (line-end-position) 'move)
1613                    (1- (point))
1614                  (point)))))
1615             ((eql char ?\")
1616              (forward-char 1)
1617              (buffer-substring
1618               (point)
1619               (1- (or (search-forward "\"" (line-end-position) 'move)
1620                       (point)))))
1621             (t
1622              (buffer-substring (point) (if (search-forward " " nil t)
1623                                            (1- (point))
1624                                          (goto-char (point-max))))))
1625            result)))
1626       (nreverse result))))
1627
1628 (defun nnimap-last-response-string ()
1629   (save-excursion
1630     (forward-line 1)
1631     (let ((end (point)))
1632       (forward-line -1)
1633       (when (not (bobp))
1634         (forward-line -1)
1635         (while (and (not (bobp))
1636                     (eql (following-char) ?*))
1637           (forward-line -1))
1638         (unless (eql (following-char) ?*)
1639           (forward-line 1)))
1640       (buffer-substring (point) end))))
1641
1642 (defun nnimap-get-responses (sequences)
1643   (let (responses)
1644     (dolist (sequence sequences)
1645       (goto-char (point-min))
1646       (when (re-search-forward (format "^%d " sequence) nil t)
1647         (push (list sequence (nnimap-parse-response))
1648               responses)))
1649     responses))
1650
1651 (defvar nnimap-incoming-split-list nil)
1652
1653 (defun nnimap-fetch-inbox (articles)
1654   (erase-buffer)
1655   (nnimap-wait-for-response
1656    (nnimap-send-command
1657     "UID FETCH %s %s"
1658     (nnimap-article-ranges articles)
1659     (format "(UID %s%s)"
1660             (format
1661              (if (nnimap-ver4-p)
1662                  "BODY.PEEK[HEADER] BODY.PEEK"
1663                "RFC822.PEEK"))
1664             (if nnimap-split-download-body-default
1665                 "[]"
1666               "[1]")))
1667    t))
1668
1669 (defun nnimap-split-incoming-mail ()
1670   (with-current-buffer (nnimap-buffer)
1671     (let ((nnimap-incoming-split-list nil)
1672           (nnmail-split-methods (if (eq nnimap-split-methods 'default)
1673                                     nnmail-split-methods
1674                                   nnimap-split-methods))
1675           (nnmail-split-fancy (or nnimap-split-fancy
1676                                   nnmail-split-fancy))
1677           (nnmail-inhibit-default-split-group t)
1678           (groups (nnimap-get-groups))
1679           new-articles)
1680       (erase-buffer)
1681       (nnimap-command "SELECT %S" nnimap-inbox)
1682       (setf (nnimap-group nnimap-object) nnimap-inbox)
1683       (setq new-articles (nnimap-new-articles (nnimap-get-flags "1:*")))
1684       (when new-articles
1685         (nnimap-fetch-inbox new-articles)
1686         (nnimap-transform-split-mail)
1687         (nnheader-ms-strip-cr)
1688         (nnmail-cache-open)
1689         (nnmail-split-incoming (current-buffer)
1690                                #'nnimap-save-mail-spec
1691                                nil nil
1692                                #'nnimap-dummy-active-number
1693                                #'nnimap-save-mail-spec)
1694         (when nnimap-incoming-split-list
1695           (let ((specs (nnimap-make-split-specs nnimap-incoming-split-list))
1696                 sequences junk-articles)
1697             ;; Create any groups that doesn't already exist on the
1698             ;; server first.
1699             (dolist (spec specs)
1700               (when (and (not (member (car spec) groups))
1701                          (not (eq (car spec) 'junk)))
1702                 (nnimap-command "CREATE %S" (utf7-encode (car spec) t))))
1703             ;; Then copy over all the messages.
1704             (erase-buffer)
1705             (dolist (spec specs)
1706               (let ((group (car spec))
1707                     (ranges (cdr spec)))
1708                 (if (eq group 'junk)
1709                     (setq junk-articles ranges)
1710                   (push (list (nnimap-send-command
1711                                "UID COPY %s %S"
1712                                (nnimap-article-ranges ranges)
1713                                (utf7-encode group t))
1714                               ranges)
1715                         sequences))))
1716             ;; Wait for the last COPY response...
1717             (when sequences
1718               (nnimap-wait-for-response (caar sequences))
1719               ;; And then mark the successful copy actions as deleted,
1720               ;; and possibly expunge them.
1721               (nnimap-mark-and-expunge-incoming
1722                (nnimap-parse-copied-articles sequences)))
1723             (nnimap-mark-and-expunge-incoming junk-articles)))))))
1724
1725 (defun nnimap-mark-and-expunge-incoming (range)
1726   (when range
1727     (setq range (nnimap-article-ranges range))
1728     (erase-buffer)
1729     (let ((sequence
1730            (nnimap-send-command
1731             "UID STORE %s +FLAGS.SILENT (\\Deleted)" range)))
1732       (cond
1733        ;; If the server supports it, we now delete the message we have
1734        ;; just copied over.
1735        ((nnimap-capability "UIDPLUS")
1736         (setq sequence (nnimap-send-command "UID EXPUNGE %s" range)))
1737        ;; If it doesn't support UID EXPUNGE, then we only expunge if the
1738        ;; user has configured it.
1739        (nnimap-expunge
1740         (setq sequence (nnimap-send-command "EXPUNGE"))))
1741       (nnimap-wait-for-response sequence))))
1742
1743 (defun nnimap-parse-copied-articles (sequences)
1744   (let (sequence copied range)
1745     (goto-char (point-min))
1746     (while (re-search-forward "^\\([0-9]+\\) OK " nil t)
1747       (setq sequence (string-to-number (match-string 1)))
1748       (when (setq range (cadr (assq sequence sequences)))
1749         (push (gnus-uncompress-range range) copied)))
1750     (gnus-compress-sequence (sort (apply #'nconc copied) #'<))))
1751
1752 (defun nnimap-new-articles (flags)
1753   (let (new)
1754     (dolist (elem flags)
1755       (unless (gnus-list-memq-of-list nnimap-unsplittable-articles
1756                                       (cdr elem))
1757         (push (car elem) new)))
1758     (gnus-compress-sequence (nreverse new))))
1759
1760 (defun nnimap-make-split-specs (list)
1761   (let ((specs nil)
1762         entry)
1763     (dolist (elem list)
1764       (destructuring-bind (article spec) elem
1765         (dolist (group (delete nil (mapcar #'car spec)))
1766           (unless (setq entry (assoc group specs))
1767             (push (setq entry (list group)) specs))
1768           (setcdr entry (cons article (cdr entry))))))
1769     (dolist (entry specs)
1770       (setcdr entry (gnus-compress-sequence (sort (cdr entry) #'<))))
1771     specs))
1772
1773 (defun nnimap-transform-split-mail ()
1774   (goto-char (point-min))
1775   (let (article bytes)
1776     (block nil
1777       (while (not (eobp))
1778         (while (not (looking-at "^\\* [0-9]+ FETCH.*UID \\([0-9]+\\)"))
1779           (delete-region (point) (progn (forward-line 1) (point)))
1780           (when (eobp)
1781             (return)))
1782         (setq article (match-string 1)
1783               bytes (nnimap-get-length))
1784         (delete-region (line-beginning-position) (line-end-position))
1785         ;; Insert MMDF separator, and a way to remember what this
1786         ;; article UID is.
1787         (insert (format "\^A\^A\^A\^A\n\nX-nnimap-article: %s" article))
1788         (forward-char (1+ bytes))
1789         (setq bytes (nnimap-get-length))
1790         (delete-region (line-beginning-position) (line-end-position))
1791         ;; There's a body; skip past that.
1792         (when bytes
1793           (forward-char (1+ bytes))
1794           (delete-region (line-beginning-position) (line-end-position)))))))
1795
1796 (defun nnimap-dummy-active-number (group &optional server)
1797   1)
1798
1799 (defun nnimap-save-mail-spec (group-art &optional server full-nov)
1800   (let (article)
1801     (goto-char (point-min))
1802     (if (not (re-search-forward "X-nnimap-article: \\([0-9]+\\)" nil t))
1803         (error "Invalid nnimap mail")
1804       (setq article (string-to-number (match-string 1))))
1805     (push (list article
1806                 (if (eq group-art 'junk)
1807                     (list (cons 'junk 1))
1808                   group-art))
1809           nnimap-incoming-split-list)))
1810
1811 (provide 'nnimap)
1812
1813 ;;; nnimap.el ends here