cgit.sxemacs.org Git - gnus/blob - lisp/mml.el

   1 ;;; mml.el --- A package for parsing and validating MML documents
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 ;; Boston, MA 02110-1301, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'mm-util)
  29 (require 'mm-bodies)
  30 (require 'mm-encode)
  31 (require 'mm-decode)
  32 (require 'mml-sec)
  33 (eval-when-compile (require 'cl))
  34
  35 (eval-and-compile
  36   (autoload 'message-make-message-id "message")
  37   (autoload 'gnus-setup-posting-charset "gnus-msg")
  38   (autoload 'gnus-make-local-hook "gnus-util")
  39   (autoload 'message-fetch-field "message")
  40   (autoload 'message-mark-active-p "message")
  41   (autoload 'message-info "message")
  42   (autoload 'fill-flowed-encode "flow-fill")
  43   (autoload 'message-posting-charset "message"))
  44
  45 (eval-when-compile
  46   (autoload 'dnd-get-local-file-name "dnd"))
  47
  48 (defvar gnus-article-mime-handles)
  49 (defvar gnus-mouse-2)
  50 (defvar gnus-newsrc-hashtb)
  51 (defvar message-default-charset)
  52 (defvar message-deletable-headers)
  53 (defvar message-options)
  54 (defvar message-posting-charset)
  55 (defvar message-required-mail-headers)
  56 (defvar message-required-news-headers)
  57
  58 (defcustom mml-content-type-parameters
  59   '(name access-type expiration size permission format)
  60   "*A list of acceptable parameters in MML tag.
  61 These parameters are generated in Content-Type header if exists."
  62   :version "22.1"
  63   :type '(repeat (symbol :tag "Parameter"))
  64   :group 'message)
  65
  66 (defcustom mml-content-disposition-parameters
  67   '(filename creation-date modification-date read-date)
  68   "*A list of acceptable parameters in MML tag.
  69 These parameters are generated in Content-Disposition header if exists."
  70   :version "22.1"
  71   :type '(repeat (symbol :tag "Parameter"))
  72   :group 'message)
  73
  74 (defcustom mml-insert-mime-headers-always nil
  75   "If non-nil, always put Content-Type: text/plain at top of empty parts.
  76 It is necessary to work against a bug in certain clients."
  77   :version "22.1"
  78   :type 'boolean
  79   :group 'message)
  80
  81 (defvar mml-tweak-type-alist nil
  82   "A list of (TYPE . FUNCTION) for tweaking MML parts.
  83 TYPE is a string containing a regexp to match the MIME type.  FUNCTION
  84 is a Lisp function which is called with the MML handle to tweak the
  85 part.  This variable is used only when no TWEAK parameter exists in
  86 the MML handle.")
  87
  88 (defvar mml-tweak-function-alist nil
  89   "A list of (NAME . FUNCTION) for tweaking MML parts.
  90 NAME is a string containing the name of the TWEAK parameter in the MML
  91 handle.  FUNCTION is a Lisp function which is called with the MML
  92 handle to tweak the part.")
  93
  94 (defvar mml-tweak-sexp-alist
  95   '((mml-externalize-attachments . mml-tweak-externalize-attachments))
  96   "A list of (SEXP . FUNCTION) for tweaking MML parts.
  97 SEXP is an s-expression.  If the evaluation of SEXP is non-nil, FUNCTION
  98 is called.  FUNCTION is a Lisp function which is called with the MML
  99 handle to tweak the part.")
 100
 101 (defvar mml-externalize-attachments nil
 102   "*If non-nil, local-file attachments are generated as external parts.")
 103
 104 (defvar mml-generate-multipart-alist nil
 105   "*Alist of multipart generation functions.
 106 Each entry has the form (NAME . FUNCTION), where
 107 NAME is a string containing the name of the part (without the
 108 leading \"/multipart/\"),
 109 FUNCTION is a Lisp function which is called to generate the part.
 110
 111 The Lisp function has to supply the appropriate MIME headers and the
 112 contents of this part.")
 113
 114 (defvar mml-syntax-table
 115   (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
 116     (modify-syntax-entry ?\\ "/" table)
 117     (modify-syntax-entry ?< "(" table)
 118     (modify-syntax-entry ?> ")" table)
 119     (modify-syntax-entry ?@ "w" table)
 120     (modify-syntax-entry ?/ "w" table)
 121     (modify-syntax-entry ?= " " table)
 122     (modify-syntax-entry ?* " " table)
 123     (modify-syntax-entry ?\; " " table)
 124     (modify-syntax-entry ?\' " " table)
 125     table))
 126
 127 (defvar mml-boundary-function 'mml-make-boundary
 128   "A function called to suggest a boundary.
 129 The function may be called several times, and should try to make a new
 130 suggestion each time.  The function is called with one parameter,
 131 which is a number that says how many times the function has been
 132 called for this message.")
 133
 134 (defvar mml-confirmation-set nil
 135   "A list of symbols, each of which disables some warning.
 136 `unknown-encoding': always send messages contain characters with
 137 unknown encoding; `use-ascii': always use ASCII for those characters
 138 with unknown encoding; `multipart': always send messages with more than
 139 one charsets.")
 140
 141 (defvar mml-generate-default-type "text/plain"
 142   "Content type by which the Content-Type header can be omitted.
 143 The Content-Type header will not be put in the MIME part if the type
 144 equals the value and there's no parameter (e.g. charset, format, etc.)
 145 and `mml-insert-mime-headers-always' is nil.  The value will be bound
 146 to \"message/rfc822\" when encoding an article to be forwarded as a MIME
 147 part.  This is for the internal use, you should never modify the value.")
 148
 149 (defvar mml-buffer-list nil)
 150
 151 (defun mml-generate-new-buffer (name)
 152   (let ((buf (generate-new-buffer name)))
 153     (push buf mml-buffer-list)
 154     buf))
 155
 156 (defun mml-destroy-buffers ()
 157   (let (kill-buffer-hook)
 158     (mapc 'kill-buffer mml-buffer-list)
 159     (setq mml-buffer-list nil)))
 160
 161 (defun mml-parse ()
 162   "Parse the current buffer as an MML document."
 163   (save-excursion
 164     (goto-char (point-min))
 165     (with-syntax-table mml-syntax-table
 166       (mml-parse-1))))
 167
 168 (defun mml-parse-1 ()
 169   "Parse the current buffer as an MML document."
 170   (let (struct tag point contents charsets warn use-ascii no-markup-p raw)
 171     (while (and (not (eobp))
 172                 (not (looking-at "<#/multipart")))
 173       (cond
 174        ((looking-at "<#secure")
 175         ;; The secure part is essentially a meta-meta tag, which
 176         ;; expands to either a part tag if there are no other parts in
 177         ;; the document or a multipart tag if there are other parts
 178         ;; included in the message
 179         (let* (secure-mode
 180                (taginfo (mml-read-tag))
 181                (keyfile (cdr (assq 'keyfile taginfo)))
 182                (certfile (cdr (assq 'certfile taginfo)))
 183                (recipients (cdr (assq 'recipients taginfo)))
 184                (sender (cdr (assq 'sender taginfo)))
 185                (location (cdr (assq 'tag-location taginfo)))
 186                (mode (cdr (assq 'mode taginfo)))
 187                (method (cdr (assq 'method taginfo)))
 188                tags)
 189           (save-excursion
 190             (if (re-search-forward
 191                  "<#/?\\(multipart\\|part\\|external\\|mml\\)." nil t)
 192                 (setq secure-mode "multipart")
 193               (setq secure-mode "part")))
 194           (save-excursion
 195             (goto-char location)
 196             (re-search-forward "<#secure[^\n]*>\n"))
 197           (delete-region (match-beginning 0) (match-end 0))
 198           (cond ((string= mode "sign")
 199                  (setq tags (list "sign" method)))
 200                 ((string= mode "encrypt")
 201                  (setq tags (list "encrypt" method)))
 202                 ((string= mode "signencrypt")
 203                  (setq tags (list "sign" method "encrypt" method))))
 204           (eval `(mml-insert-tag ,secure-mode
 205                                  ,@tags
 206                                  ,(if keyfile "keyfile")
 207                                  ,keyfile
 208                                  ,(if certfile "certfile")
 209                                  ,certfile
 210                                  ,(if recipients "recipients")
 211                                  ,recipients
 212                                  ,(if sender "sender")
 213                                  ,sender))
 214           ;; restart the parse
 215           (goto-char location)))
 216        ((looking-at "<#multipart")
 217         (push (nconc (mml-read-tag) (mml-parse-1)) struct))
 218        ((looking-at "<#external")
 219         (push (nconc (mml-read-tag) (list (cons 'contents (mml-read-part))))
 220               struct))
 221        (t
 222         (if (or (looking-at "<#part") (looking-at "<#mml"))
 223             (setq tag (mml-read-tag)
 224                   no-markup-p nil
 225                   warn nil)
 226           (setq tag (list 'part '(type . "text/plain"))
 227                 no-markup-p t
 228                 warn t))
 229         (setq raw (cdr (assq 'raw tag))
 230               point (point)
 231               contents (mml-read-part (eq 'mml (car tag)))
 232               charsets (cond
 233                         (raw nil)
 234                         ((assq 'charset tag)
 235                          (list
 236                           (intern (downcase (cdr (assq 'charset tag))))))
 237                         (t
 238                          (mm-find-mime-charset-region point (point)
 239                                                       mm-hack-charsets))))
 240         (when (and (not raw) (memq nil charsets))
 241           (if (or (memq 'unknown-encoding mml-confirmation-set)
 242                   (message-options-get 'unknown-encoding)
 243                   (and (y-or-n-p "\
 244 Message contains characters with unknown encoding.  Really send? ")
 245                        (message-options-set 'unknown-encoding t)))
 246               (if (setq use-ascii
 247                         (or (memq 'use-ascii mml-confirmation-set)
 248                             (message-options-get 'use-ascii)
 249                             (and (y-or-n-p "Use ASCII as charset? ")
 250                                  (message-options-set 'use-ascii t))))
 251                   (setq charsets (delq nil charsets))
 252                 (setq warn nil))
 253             (error "Edit your message to remove those characters")))
 254         (if (or raw
 255                 (eq 'mml (car tag))
 256                 (< (length charsets) 2))
 257             (if (or (not no-markup-p)
 258                     (string-match "[^ \t\r\n]" contents))
 259                 ;; Don't create blank parts.
 260                 (push (nconc tag (list (cons 'contents contents)))
 261                       struct))
 262           (let ((nstruct (mml-parse-singlepart-with-multiple-charsets
 263                           tag point (point) use-ascii)))
 264             (when (and warn
 265                        (not (memq 'multipart mml-confirmation-set))
 266                        (not (message-options-get 'multipart))
 267                        (not (and (y-or-n-p (format "\
 268 A message part needs to be split into %d charset parts.  Really send? "
 269                                                    (length nstruct)))
 270                                  (message-options-set 'multipart t))))
 271               (error "Edit your message to use only one charset"))
 272             (setq struct (nconc nstruct struct)))))))
 273     (unless (eobp)
 274       (forward-line 1))
 275     (nreverse struct)))
 276
 277 (defun mml-parse-singlepart-with-multiple-charsets
 278   (orig-tag beg end &optional use-ascii)
 279   (save-excursion
 280     (save-restriction
 281       (narrow-to-region beg end)
 282       (goto-char (point-min))
 283       (let ((current (or (mm-mime-charset (mm-charset-after))
 284                          (and use-ascii 'us-ascii)))
 285             charset struct space newline paragraph)
 286         (while (not (eobp))
 287           (setq charset (mm-mime-charset (mm-charset-after)))
 288           (cond
 289            ;; The charset remains the same.
 290            ((eq charset 'us-ascii))
 291            ((or (and use-ascii (not charset))
 292                 (eq charset current))
 293             (setq space nil
 294                   newline nil
 295                   paragraph nil))
 296            ;; The initial charset was ascii.
 297            ((eq current 'us-ascii)
 298             (setq current charset
 299                   space nil
 300                   newline nil
 301                   paragraph nil))
 302            ;; We have a change in charsets.
 303            (t
 304             (push (append
 305                    orig-tag
 306                    (list (cons 'contents
 307                                (buffer-substring-no-properties
 308                                 beg (or paragraph newline space (point))))))
 309                   struct)
 310             (setq beg (or paragraph newline space (point))
 311                   current charset
 312                   space nil
 313                   newline nil
 314                   paragraph nil)))
 315           ;; Compute places where it might be nice to break the part.
 316           (cond
 317            ((memq (following-char) '(?  ?\t))
 318             (setq space (1+ (point))))
 319            ((and (eq (following-char) ?\n)
 320                  (not (bobp))
 321                  (eq (char-after (1- (point))) ?\n))
 322             (setq paragraph (point)))
 323            ((eq (following-char) ?\n)
 324             (setq newline (1+ (point)))))
 325           (forward-char 1))
 326         ;; Do the final part.
 327         (unless (= beg (point))
 328           (push (append orig-tag
 329                         (list (cons 'contents
 330                                     (buffer-substring-no-properties
 331                                      beg (point)))))
 332                 struct))
 333         struct))))
 334
 335 (defun mml-read-tag ()
 336   "Read a tag and return the contents."
 337   (let ((orig-point (point))
 338         contents name elem val)
 339     (forward-char 2)
 340     (setq name (buffer-substring-no-properties
 341                 (point) (progn (forward-sexp 1) (point))))
 342     (skip-chars-forward " \t\n")
 343     (while (not (looking-at ">[ \t]*\n?"))
 344       (setq elem (buffer-substring-no-properties
 345                   (point) (progn (forward-sexp 1) (point))))
 346       (skip-chars-forward "= \t\n")
 347       (setq val (buffer-substring-no-properties
 348                  (point) (progn (forward-sexp 1) (point))))
 349       (when (string-match "^\"\\(.*\\)\"$" val)
 350         (setq val (match-string 1 val)))
 351       (push (cons (intern elem) val) contents)
 352       (skip-chars-forward " \t\n"))
 353     (goto-char (match-end 0))
 354     ;; Don't skip the leading space.
 355     ;;(skip-chars-forward " \t\n")
 356     ;; Put the tag location into the returned contents
 357     (setq contents (append (list (cons 'tag-location orig-point)) contents))
 358     (cons (intern name) (nreverse contents))))
 359
 360 (defun mml-buffer-substring-no-properties-except-hard-newlines (start end)
 361   (let ((str (buffer-substring-no-properties start end))
 362         (bufstart start) tmp)
 363     (while (setq tmp (text-property-any start end 'hard 't))
 364       (set-text-properties (- tmp bufstart) (- tmp bufstart -1)
 365                            '(hard t) str)
 366       (setq start (1+ tmp)))
 367     str))
 368
 369 (defun mml-read-part (&optional mml)
 370   "Return the buffer up till the next part, multipart or closing part or multipart.
 371 If MML is non-nil, return the buffer up till the correspondent mml tag."
 372   (let ((beg (point)) (count 1))
 373     ;; If the tag ended at the end of the line, we go to the next line.
 374     (when (looking-at "[ \t]*\n")
 375       (forward-line 1))
 376     (if mml
 377         (progn
 378           (while (and (> count 0) (not (eobp)))
 379             (if (re-search-forward "<#\\(/\\)?mml." nil t)
 380                 (setq count (+ count (if (match-beginning 1) -1 1)))
 381               (goto-char (point-max))))
 382           (mml-buffer-substring-no-properties-except-hard-newlines
 383            beg (if (> count 0)
 384                    (point)
 385                  (match-beginning 0))))
 386       (if (re-search-forward
 387            "<#\\(/\\)?\\(multipart\\|part\\|external\\|mml\\)." nil t)
 388           (prog1
 389               (mml-buffer-substring-no-properties-except-hard-newlines
 390                beg (match-beginning 0))
 391             (if (or (not (match-beginning 1))
 392                     (equal (match-string 2) "multipart"))
 393                 (goto-char (match-beginning 0))
 394               (when (looking-at "[ \t]*\n")
 395                 (forward-line 1))))
 396         (mml-buffer-substring-no-properties-except-hard-newlines
 397          beg (goto-char (point-max)))))))
 398
 399 (defvar mml-boundary nil)
 400 (defvar mml-base-boundary "-=-=")
 401 (defvar mml-multipart-number 0)
 402
 403 (defun mml-generate-mime ()
 404   "Generate a MIME message based on the current MML document."
 405   (let ((cont (mml-parse))
 406         (mml-multipart-number mml-multipart-number))
 407     (if (not cont)
 408         nil
 409       (with-temp-buffer
 410         (if (and (consp (car cont))
 411                  (= (length cont) 1))
 412             (mml-generate-mime-1 (car cont))
 413           (mml-generate-mime-1 (nconc (list 'multipart '(type . "mixed"))
 414                                       cont)))
 415         (buffer-string)))))
 416
 417 (defun mml-generate-mime-1 (cont)
 418   (let ((mm-use-ultra-safe-encoding
 419          (or mm-use-ultra-safe-encoding (assq 'sign cont))))
 420     (save-restriction
 421       (narrow-to-region (point) (point))
 422       (mml-tweak-part cont)
 423       (cond
 424        ((or (eq (car cont) 'part) (eq (car cont) 'mml))
 425         (let* ((raw (cdr (assq 'raw cont)))
 426                (filename (cdr (assq 'filename cont)))
 427                (type (or (cdr (assq 'type cont))
 428                          (if filename
 429                              (or (mm-default-file-encoding filename)
 430                                  "application/octet-stream")
 431                            "text/plain")))
 432                (charset (cdr (assq 'charset cont)))
 433                (coding (mm-charset-to-coding-system charset))
 434                encoding flowed coded)
 435           (cond ((eq coding 'ascii)
 436                  (setq charset nil
 437                        coding nil))
 438                 (charset
 439                  (setq charset (intern (downcase charset)))))
 440           (if (and (not raw)
 441                    (member (car (split-string type "/")) '("text" "message")))
 442               (progn
 443                 (with-temp-buffer
 444                   (cond
 445                    ((cdr (assq 'buffer cont))
 446                     (insert-buffer-substring (cdr (assq 'buffer cont))))
 447                    ((and filename
 448                          (not (equal (cdr (assq 'nofile cont)) "yes")))
 449                     (let ((coding-system-for-read coding))
 450                       (mm-insert-file-contents filename)))
 451                    ((eq 'mml (car cont))
 452                     (insert (cdr (assq 'contents cont))))
 453                    (t
 454                     (save-restriction
 455                       (narrow-to-region (point) (point))
 456                       (insert (cdr (assq 'contents cont)))
 457                       ;; Remove quotes from quoted tags.
 458                       (goto-char (point-min))
 459                       (while (re-search-forward
 460                               "<#!+/?\\(part\\|multipart\\|external\\|mml\\)"
 461                               nil t)
 462                         (delete-region (+ (match-beginning 0) 2)
 463                                        (+ (match-beginning 0) 3))))))
 464                   (cond
 465                    ((eq (car cont) 'mml)
 466                     (let ((mml-boundary (mml-compute-boundary cont))
 467                           ;; It is necessary for the case where this
 468                           ;; function is called recursively since
 469                           ;; `m-g-d-t' will be bound to "message/rfc822"
 470                           ;; when encoding an article to be forwarded.
 471                           (mml-generate-default-type "text/plain"))
 472                       (mml-to-mime))
 473                     (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 474                       ;; ignore 0x1b, it is part of iso-2022-jp
 475                       (setq encoding (mm-body-7-or-8))))
 476                    ((string= (car (split-string type "/")) "message")
 477                     (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 478                       ;; ignore 0x1b, it is part of iso-2022-jp
 479                       (setq encoding (mm-body-7-or-8))))
 480                    (t
 481                     ;; Only perform format=flowed filling on text/plain
 482                     ;; parts where there either isn't a format parameter
 483                     ;; in the mml tag or it says "flowed" and there
 484                     ;; actually are hard newlines in the text.
 485                     (let (use-hard-newlines)
 486                       (when (and (string= type "text/plain")
 487                                  (not (string= (cdr (assq 'sign cont)) "pgp"))
 488                                  (or (null (assq 'format cont))
 489                                      (string= (cdr (assq 'format cont))
 490                                               "flowed"))
 491                                  (setq use-hard-newlines
 492                                        (text-property-any
 493                                         (point-min) (point-max) 'hard 't)))
 494                         (fill-flowed-encode)
 495                         ;; Indicate that `mml-insert-mime-headers' should
 496                         ;; insert a "; format=flowed" string unless the
 497                         ;; user has already specified it.
 498                         (setq flowed (null (assq 'format cont)))))
 499                     (setq charset (mm-encode-body charset))
 500                     (setq encoding (mm-body-encoding
 501                                     charset (cdr (assq 'encoding cont))))))
 502                   (setq coded (buffer-string)))
 503                 (mml-insert-mime-headers cont type charset encoding flowed)
 504                 (insert "\n")
 505                 (insert coded))
 506             (mm-with-unibyte-buffer
 507               (cond
 508                ((cdr (assq 'buffer cont))
 509                 (insert (with-current-buffer (cdr (assq 'buffer cont))
 510                           (mm-with-unibyte-current-buffer
 511                             (buffer-string)))))
 512                ((and filename
 513                      (not (equal (cdr (assq 'nofile cont)) "yes")))
 514                 (let ((coding-system-for-read mm-binary-coding-system))
 515                   (mm-insert-file-contents filename nil nil nil nil t))
 516                 (unless charset
 517                   (setq charset (mm-coding-system-to-mime-charset
 518                                  (mm-find-buffer-file-coding-system
 519                                   filename)))))
 520                (t
 521                 (insert (cdr (assq 'contents cont)))))
 522               (setq encoding (mm-encode-buffer type)
 523                     coded (mm-string-as-multibyte (buffer-string))))
 524             (mml-insert-mime-headers cont type charset encoding nil)
 525             (insert "\n")
 526             (mm-with-unibyte-current-buffer
 527               (insert coded)))))
 528        ((eq (car cont) 'external)
 529         (insert "Content-Type: message/external-body")
 530         (let ((parameters (mml-parameter-string
 531                            cont '(expiration size permission)))
 532               (name (cdr (assq 'name cont)))
 533               (url (cdr (assq 'url cont))))
 534           (when name
 535             (setq name (mml-parse-file-name name))
 536             (if (stringp name)
 537                 (mml-insert-parameter
 538                  (mail-header-encode-parameter "name" name)
 539                  "access-type=local-file")
 540               (mml-insert-parameter
 541                (mail-header-encode-parameter
 542                 "name" (file-name-nondirectory (nth 2 name)))
 543                (mail-header-encode-parameter "site" (nth 1 name))
 544                (mail-header-encode-parameter
 545                 "directory" (file-name-directory (nth 2 name))))
 546               (mml-insert-parameter
 547                (concat "access-type="
 548                        (if (member (nth 0 name) '("ftp@" "anonymous@"))
 549                            "anon-ftp"
 550                          "ftp")))))
 551           (when url
 552             (mml-insert-parameter
 553              (mail-header-encode-parameter "url" url)
 554              "access-type=url"))
 555           (when parameters
 556             (mml-insert-parameter-string
 557              cont '(expiration size permission)))
 558           (insert "\n\n")
 559           (insert "Content-Type: "
 560                   (or (cdr (assq 'type cont))
 561                       (if name
 562                           (or (mm-default-file-encoding name)
 563                               "application/octet-stream")
 564                         "text/plain"))
 565                   "\n")
 566           (insert "Content-ID: " (message-make-message-id) "\n")
 567           (insert "Content-Transfer-Encoding: "
 568                   (or (cdr (assq 'encoding cont)) "binary"))
 569           (insert "\n\n")
 570           (insert (or (cdr (assq 'contents cont))))
 571           (insert "\n")))
 572        ((eq (car cont) 'multipart)
 573         (let* ((type (or (cdr (assq 'type cont)) "mixed"))
 574                (mml-generate-default-type (if (equal type "digest")
 575                                               "message/rfc822"
 576                                             "text/plain"))
 577                (handler (assoc type mml-generate-multipart-alist)))
 578           (if handler
 579               (funcall (cdr handler) cont)
 580             ;; No specific handler.  Use default one.
 581             (let ((mml-boundary (mml-compute-boundary cont)))
 582               (insert (format "Content-Type: multipart/%s; boundary=\"%s\""
 583                               type mml-boundary)
 584                       (if (cdr (assq 'start cont))
 585                           (format "; start=\"%s\"\n" (cdr (assq 'start cont)))
 586                         "\n"))
 587               (let ((cont cont) part)
 588                 (while (setq part (pop cont))
 589                   ;; Skip `multipart' and attributes.
 590                   (when (and (consp part) (consp (cdr part)))
 591                     (insert "\n--" mml-boundary "\n")
 592                     (mml-generate-mime-1 part)
 593                     (goto-char (point-max)))))
 594               (insert "\n--" mml-boundary "--\n")))))
 595        (t
 596         (error "Invalid element: %S" cont)))
 597       ;; handle sign & encrypt tags in a semi-smart way.
 598       (let ((sign-item (assoc (cdr (assq 'sign cont)) mml-sign-alist))
 599             (encrypt-item (assoc (cdr (assq 'encrypt cont))
 600                                  mml-encrypt-alist))
 601             sender recipients)
 602         (when (or sign-item encrypt-item)
 603           (when (setq sender (cdr (assq 'sender cont)))
 604             (message-options-set 'mml-sender sender)
 605             (message-options-set 'message-sender sender))
 606           (if (setq recipients (cdr (assq 'recipients cont)))
 607               (message-options-set 'message-recipients recipients))
 608           (let ((style (mml-signencrypt-style
 609                         (first (or sign-item encrypt-item)))))
 610             ;; check if: we're both signing & encrypting, both methods
 611             ;; are the same (why would they be different?!), and that
 612             ;; the signencrypt style allows for combined operation.
 613             (if (and sign-item encrypt-item (equal (first sign-item)
 614                                                    (first encrypt-item))
 615                      (equal style 'combined))
 616                 (funcall (nth 1 encrypt-item) cont t)
 617               ;; otherwise, revert to the old behavior.
 618               (when sign-item
 619                 (funcall (nth 1 sign-item) cont))
 620               (when encrypt-item
 621                 (funcall (nth 1 encrypt-item) cont)))))))))
 622
 623 (defun mml-compute-boundary (cont)
 624   "Return a unique boundary that does not exist in CONT."
 625   (let ((mml-boundary (funcall mml-boundary-function
 626                                (incf mml-multipart-number))))
 627     ;; This function tries again and again until it has found
 628     ;; a unique boundary.
 629     (while (not (catch 'not-unique
 630                   (mml-compute-boundary-1 cont))))
 631     mml-boundary))
 632
 633 (defun mml-compute-boundary-1 (cont)
 634   (let (filename)
 635     (cond
 636      ((eq (car cont) 'part)
 637       (with-temp-buffer
 638         (cond
 639          ((cdr (assq 'buffer cont))
 640           (insert-buffer-substring (cdr (assq 'buffer cont))))
 641          ((and (setq filename (cdr (assq 'filename cont)))
 642                (not (equal (cdr (assq 'nofile cont)) "yes")))
 643           (mm-insert-file-contents filename nil nil nil nil t))
 644          (t
 645           (insert (cdr (assq 'contents cont)))))
 646         (goto-char (point-min))
 647         (when (re-search-forward (concat "^--" (regexp-quote mml-boundary))
 648                                  nil t)
 649           (setq mml-boundary (funcall mml-boundary-function
 650                                       (incf mml-multipart-number)))
 651           (throw 'not-unique nil))))
 652      ((eq (car cont) 'multipart)
 653       (mapc 'mml-compute-boundary-1 (cddr cont))))
 654     t))
 655
 656 (defun mml-make-boundary (number)
 657   (concat (make-string (% number 60) ?=)
 658           (if (> number 17)
 659               (format "%x" number)
 660             "")
 661           mml-base-boundary))
 662
 663 (defun mml-insert-mime-headers (cont type charset encoding flowed)
 664   (let (parameters id disposition description)
 665     (setq parameters
 666           (mml-parameter-string
 667            cont mml-content-type-parameters))
 668     (when (or charset
 669               parameters
 670               flowed
 671               (not (equal type mml-generate-default-type))
 672               mml-insert-mime-headers-always)
 673       (when (consp charset)
 674         (error
 675          "Can't encode a part with several charsets"))
 676       (insert "Content-Type: " type)
 677       (when charset
 678         (insert "; " (mail-header-encode-parameter
 679                       "charset" (symbol-name charset))))
 680       (when flowed
 681         (insert "; format=flowed"))
 682       (when parameters
 683         (mml-insert-parameter-string
 684          cont mml-content-type-parameters))
 685       (insert "\n"))
 686     (when (setq id (cdr (assq 'id cont)))
 687       (insert "Content-ID: " id "\n"))
 688     (setq parameters
 689           (mml-parameter-string
 690            cont mml-content-disposition-parameters))
 691     (when (or (setq disposition (cdr (assq 'disposition cont)))
 692               parameters)
 693       (insert "Content-Disposition: " (or disposition "inline"))
 694       (when parameters
 695         (mml-insert-parameter-string
 696          cont mml-content-disposition-parameters))
 697       (insert "\n"))
 698     (unless (eq encoding '7bit)
 699       (insert (format "Content-Transfer-Encoding: %s\n" encoding)))
 700     (when (setq description (cdr (assq 'description cont)))
 701       (insert "Content-Description: "
 702               (mail-encode-encoded-word-string description) "\n"))))
 703
 704 (defun mml-parameter-string (cont types)
 705   (let ((string "")
 706         value type)
 707     (while (setq type (pop types))
 708       (when (setq value (cdr (assq type cont)))
 709         ;; Strip directory component from the filename parameter.
 710         (when (eq type 'filename)
 711           (setq value (file-name-nondirectory value)))
 712         (setq string (concat string "; "
 713                              (mail-header-encode-parameter
 714                               (symbol-name type) value)))))
 715     (when (not (zerop (length string)))
 716       string)))
 717
 718 (defun mml-insert-parameter-string (cont types)
 719   (let (value type)
 720     (while (setq type (pop types))
 721       (when (setq value (cdr (assq type cont)))
 722         ;; Strip directory component from the filename parameter.
 723         (when (eq type 'filename)
 724           (setq value (file-name-nondirectory value)))
 725         (mml-insert-parameter
 726          (mail-header-encode-parameter
 727           (symbol-name type) value))))))
 728
 729 (eval-when-compile
 730   (defvar ange-ftp-name-format)
 731   (defvar efs-path-regexp))
 732 (defun mml-parse-file-name (path)
 733   (if (if (boundp 'efs-path-regexp)
 734           (string-match efs-path-regexp path)
 735         (if (boundp 'ange-ftp-name-format)
 736             (string-match (car ange-ftp-name-format) path)))
 737       (list (match-string 1 path) (match-string 2 path)
 738             (substring path (1+ (match-end 2))))
 739     path))
 740
 741 (defun mml-insert-buffer (buffer)
 742   "Insert BUFFER at point and quote any MML markup."
 743   (save-restriction
 744     (narrow-to-region (point) (point))
 745     (insert-buffer-substring buffer)
 746     (mml-quote-region (point-min) (point-max))
 747     (goto-char (point-max))))
 748
 749 ;;;
 750 ;;; Transforming MIME to MML
 751 ;;;
 752
 753 (defun mime-to-mml (&optional handles)
 754   "Translate the current buffer (which should be a message) into MML.
 755 If HANDLES is non-nil, use it instead reparsing the buffer."
 756   ;; First decode the head.
 757   (save-restriction
 758     (message-narrow-to-head)
 759     (let ((rfc2047-quote-decoded-words-containing-tspecials t))
 760       (mail-decode-encoded-word-region (point-min) (point-max))))
 761   (unless handles
 762     (setq handles (mm-dissect-buffer t)))
 763   (goto-char (point-min))
 764   (search-forward "\n\n" nil t)
 765   (delete-region (point) (point-max))
 766   (if (stringp (car handles))
 767       (mml-insert-mime handles)
 768     (mml-insert-mime handles t))
 769   (mm-destroy-parts handles)
 770   (save-restriction
 771     (message-narrow-to-head)
 772     ;; Remove them, they are confusing.
 773     (message-remove-header "Content-Type")
 774     (message-remove-header "MIME-Version")
 775     (message-remove-header "Content-Disposition")
 776     (message-remove-header "Content-Transfer-Encoding")))
 777
 778 (defun mml-to-mime ()
 779   "Translate the current buffer from MML to MIME."
 780   (message-encode-message-body)
 781   (save-restriction
 782     (message-narrow-to-headers-or-head)
 783     ;; Skip past any From_ headers.
 784     (while (looking-at "From ")
 785       (forward-line 1))
 786     (let ((mail-parse-charset message-default-charset))
 787       (mail-encode-encoded-word-buffer))))
 788
 789 (defun mml-insert-mime (handle &optional no-markup)
 790   (let (textp buffer mmlp)
 791     ;; Determine type and stuff.
 792     (unless (stringp (car handle))
 793       (unless (setq textp (equal (mm-handle-media-supertype handle) "text"))
 794         (save-excursion
 795           (set-buffer (setq buffer (mml-generate-new-buffer " *mml*")))
 796           (mm-insert-part handle)
 797           (if (setq mmlp (equal (mm-handle-media-type handle)
 798                                 "message/rfc822"))
 799               (mime-to-mml)))))
 800     (if mmlp
 801         (mml-insert-mml-markup handle nil t t)
 802       (unless (and no-markup
 803                    (equal (mm-handle-media-type handle) "text/plain"))
 804         (mml-insert-mml-markup handle buffer textp)))
 805     (cond
 806      (mmlp
 807       (insert-buffer-substring buffer)
 808       (goto-char (point-max))
 809       (insert "<#/mml>\n"))
 810      ((stringp (car handle))
 811       (mapcar 'mml-insert-mime (cdr handle))
 812       (insert "<#/multipart>\n"))
 813      (textp
 814       (let ((charset (mail-content-type-get
 815                       (mm-handle-type handle) 'charset))
 816             (start (point)))
 817         (if (eq charset 'gnus-decoded)
 818             (mm-insert-part handle)
 819           (insert (mm-decode-string (mm-get-part handle) charset)))
 820         (mml-quote-region start (point)))
 821       (goto-char (point-max)))
 822      (t
 823       (insert "<#/part>\n")))))
 824
 825 (defun mml-insert-mml-markup (handle &optional buffer nofile mmlp)
 826   "Take a MIME handle and insert an MML tag."
 827   (if (stringp (car handle))
 828       (progn
 829         (insert "<#multipart type=" (mm-handle-media-subtype handle))
 830         (let ((start (mm-handle-multipart-ctl-parameter handle 'start)))
 831           (when start
 832             (insert " start=\"" start "\"")))
 833         (insert ">\n"))
 834     (if mmlp
 835         (insert "<#mml type=" (mm-handle-media-type handle))
 836       (insert "<#part type=" (mm-handle-media-type handle)))
 837     (dolist (elem (append (cdr (mm-handle-type handle))
 838                           (cdr (mm-handle-disposition handle))))
 839       (unless (symbolp (cdr elem))
 840         (insert " " (symbol-name (car elem)) "=\"" (cdr elem) "\"")))
 841     (when (mm-handle-id handle)
 842       (insert " id=\"" (mm-handle-id handle) "\""))
 843     (when (mm-handle-disposition handle)
 844       (insert " disposition=" (car (mm-handle-disposition handle))))
 845     (when buffer
 846       (insert " buffer=\"" (buffer-name buffer) "\""))
 847     (when nofile
 848       (insert " nofile=yes"))
 849     (when (mm-handle-description handle)
 850       (insert " description=\"" (mm-handle-description handle) "\""))
 851     (insert ">\n")))
 852
 853 (defun mml-insert-parameter (&rest parameters)
 854   "Insert PARAMETERS in a nice way."
 855   (dolist (param parameters)
 856     (insert ";")
 857     (let ((point (point)))
 858       (insert " " param)
 859       (when (> (current-column) 71)
 860         (goto-char point)
 861         (insert "\n")
 862         (end-of-line)))))
 863
 864 ;;;
 865 ;;; Mode for inserting and editing MML forms
 866 ;;;
 867
 868 (defvar mml-mode-map
 869   (let ((sign (make-sparse-keymap))
 870         (encrypt (make-sparse-keymap))
 871         (signpart (make-sparse-keymap))
 872         (encryptpart (make-sparse-keymap))
 873         (map (make-sparse-keymap))
 874         (main (make-sparse-keymap)))
 875     (define-key map "\C-s" 'mml-secure-message-sign)
 876     (define-key map "\C-c" 'mml-secure-message-encrypt)
 877     (define-key map "\C-e" 'mml-secure-message-sign-encrypt)
 878     (define-key map "\C-p\C-s" 'mml-secure-sign)
 879     (define-key map "\C-p\C-c" 'mml-secure-encrypt)
 880     (define-key sign "p" 'mml-secure-message-sign-pgpmime)
 881     (define-key sign "o" 'mml-secure-message-sign-pgp)
 882     (define-key sign "s" 'mml-secure-message-sign-smime)
 883     (define-key signpart "p" 'mml-secure-sign-pgpmime)
 884     (define-key signpart "o" 'mml-secure-sign-pgp)
 885     (define-key signpart "s" 'mml-secure-sign-smime)
 886     (define-key encrypt "p" 'mml-secure-message-encrypt-pgpmime)
 887     (define-key encrypt "o" 'mml-secure-message-encrypt-pgp)
 888     (define-key encrypt "s" 'mml-secure-message-encrypt-smime)
 889     (define-key encryptpart "p" 'mml-secure-encrypt-pgpmime)
 890     (define-key encryptpart "o" 'mml-secure-encrypt-pgp)
 891     (define-key encryptpart "s" 'mml-secure-encrypt-smime)
 892     (define-key map "\C-n" 'mml-unsecure-message)
 893     (define-key map "f" 'mml-attach-file)
 894     (define-key map "b" 'mml-attach-buffer)
 895     (define-key map "e" 'mml-attach-external)
 896     (define-key map "q" 'mml-quote-region)
 897     (define-key map "m" 'mml-insert-multipart)
 898     (define-key map "p" 'mml-insert-part)
 899     (define-key map "v" 'mml-validate)
 900     (define-key map "P" 'mml-preview)
 901     (define-key map "s" sign)
 902     (define-key map "S" signpart)
 903     (define-key map "c" encrypt)
 904     (define-key map "C" encryptpart)
 905     ;;(define-key map "n" 'mml-narrow-to-part)
 906     ;; `M-m' conflicts with `back-to-indentation'.
 907     ;; (define-key main "\M-m" map)
 908     (define-key main "\C-c\C-m" map)
 909     main))
 910
 911 (easy-menu-define
 912   mml-menu mml-mode-map ""
 913   `("Attachments"
 914     ["Attach File..." mml-attach-file
 915      ,@(if (featurep 'xemacs) '(t)
 916          '(:help "Attach a file at point"))]
 917     ["Attach Buffer..." mml-attach-buffer
 918      ,@(if (featurep 'xemacs) '(t)
 919          '(:help "Attach a buffer to the outgoing MIME message"))]
 920     ["Attach External..." mml-attach-external
 921      ,@(if (featurep 'xemacs) '(t)
 922          '(:help "Attach reference to file"))]
 923     ;;
 924     ("Change Security Method"
 925      ["PGP/MIME"
 926       (lambda () (interactive) (setq mml-secure-method "pgpmime"))
 927       ,@(if (featurep 'xemacs) nil
 928           '(:help "Set Security Method to PGP/MIME"))
 929       :style radio
 930       :selected (equal mml-secure-method "pgpmime") ]
 931      ["S/MIME"
 932       (lambda () (interactive) (setq mml-secure-method "smime"))
 933       ,@(if (featurep 'xemacs) nil
 934           '(:help "Set Security Method to S/MIME"))
 935       :style radio
 936       :selected (equal mml-secure-method "smime") ]
 937      ["Inline PGP"
 938       (lambda () (interactive) (setq mml-secure-method "pgp"))
 939       ,@(if (featurep 'xemacs) nil
 940           '(:help "Set Security Method to inline PGP"))
 941       :style radio
 942       :selected (equal mml-secure-method "pgp") ] )
 943     ;;
 944     ["Sign Message" mml-secure-message-sign t]
 945     ["Encrypt Message" mml-secure-message-encrypt t]
 946     ["Sign and Encrypt Message" mml-secure-message-sign-encrypt t]
 947     ["Encrypt/Sign off" mml-unsecure-message
 948      ,@(if (featurep 'xemacs) '(t)
 949          '(:help "Don't Encrypt/Sign Message"))]
 950     ;; Maybe we could remove these, because people who write MML most probably
 951     ;; don't use the menu:
 952     ["Insert Part..." mml-insert-part
 953      :active (message-in-body-p)]
 954     ["Insert Multipart..." mml-insert-multipart
 955      :active (message-in-body-p)]
 956     ;;
 957     ;; Do we have separate encrypt and encrypt/sign commands for parts?
 958     ["Sign Part" mml-secure-sign t]
 959     ["Encrypt Part" mml-secure-encrypt t]
 960     ;;["Narrow" mml-narrow-to-part t]
 961     ["Quote MML in region" mml-quote-region
 962      :active (message-mark-active-p)
 963      ,@(if (featurep 'xemacs) nil
 964          '(:help "Quote MML tags in region"))]
 965     ["Validate MML" mml-validate t]
 966     ["Preview" mml-preview t]
 967     "----"
 968     ["Emacs MIME manual" (lambda () (interactive) (message-info 4))
 969      ,@(if (featurep 'xemacs) '(t)
 970          '(:help "Display the Emacs MIME manual"))]
 971     ["PGG manual" (lambda () (interactive) (message-info 16))
 972      ,@(if (featurep 'xemacs) '(t)
 973          '(:help "Display the PGG manual"))]))
 974
 975 (defvar mml-mode nil
 976   "Minor mode for editing MML.")
 977
 978 (defun mml-mode (&optional arg)
 979   "Minor mode for editing MML.
 980 MML is the MIME Meta Language, a minor mode for composing MIME articles.
 981 See Info node `(emacs-mime)Composing'.
 982
 983 \\{mml-mode-map}"
 984   (interactive "P")
 985   (when (set (make-local-variable 'mml-mode)
 986              (if (null arg) (not mml-mode)
 987                (> (prefix-numeric-value arg) 0)))
 988     (add-minor-mode 'mml-mode " MML" mml-mode-map)
 989     (easy-menu-add mml-menu mml-mode-map)
 990     (when (boundp 'dnd-protocol-alist)
 991       (set (make-local-variable 'dnd-protocol-alist)
 992            (append mml-dnd-protocol-alist
 993                    (symbol-value 'dnd-protocol-alist))))
 994     (run-hooks 'mml-mode-hook)))
 995
 996 ;;;
 997 ;;; Helper functions for reading MIME stuff from the minibuffer and
 998 ;;; inserting stuff to the buffer.
 999 ;;;
1000
1001 (defun mml-minibuffer-read-file (prompt)
1002   (let* ((completion-ignored-extensions nil)
1003          (file (read-file-name prompt nil nil t)))
1004     ;; Prevent some common errors.  This is inspired by similar code in
1005     ;; VM.
1006     (when (file-directory-p file)
1007       (error "%s is a directory, cannot attach" file))
1008     (unless (file-exists-p file)
1009       (error "No such file: %s" file))
1010     (unless (file-readable-p file)
1011       (error "Permission denied: %s" file))
1012     file))
1013
1014 (defun mml-minibuffer-read-type (name &optional default)
1015   (mailcap-parse-mimetypes)
1016   (let* ((default (or default
1017                       (mm-default-file-encoding name)
1018                       ;; Perhaps here we should check what the file
1019                       ;; looks like, and offer text/plain if it looks
1020                       ;; like text/plain.
1021                       "application/octet-stream"))
1022          (string (completing-read
1023                   (format "Content type (default %s): " default)
1024                   (mapcar 'list (mailcap-mime-types)))))
1025     (if (not (equal string ""))
1026         string
1027       default)))
1028
1029 (defun mml-minibuffer-read-description ()
1030   (let ((description (read-string "One line description: ")))
1031     (when (string-match "\\`[ \t]*\\'" description)
1032       (setq description nil))
1033     description))
1034
1035 (defun mml-minibuffer-read-disposition (type &optional default)
1036   (unless default (setq default
1037                         (if (and (string-match "\\`text/" type)
1038                                  (not (string-match "\\`text/rtf\\'" type)))
1039                             "inline"
1040                           "attachment")))
1041   (let ((disposition (completing-read
1042                       (format "Disposition (default %s): " default)
1043                       '(("attachment") ("inline") (""))
1044                       nil t nil nil default)))
1045     (if (not (equal disposition ""))
1046         disposition
1047       default)))
1048
1049 (defun mml-quote-region (beg end)
1050   "Quote the MML tags in the region."
1051   (interactive "r")
1052   (save-excursion
1053     (save-restriction
1054       ;; Temporarily narrow the region to defend from changes
1055       ;; invalidating END.
1056       (narrow-to-region beg end)
1057       (goto-char (point-min))
1058       ;; Quote parts.
1059       (while (re-search-forward
1060               "<#!*/?\\(multipart\\|part\\|external\\|mml\\)" nil t)
1061         ;; Insert ! after the #.
1062         (goto-char (+ (match-beginning 0) 2))
1063         (insert "!")))))
1064
1065 (defun mml-insert-tag (name &rest plist)
1066   "Insert an MML tag described by NAME and PLIST."
1067   (when (symbolp name)
1068     (setq name (symbol-name name)))
1069   (insert "<#" name)
1070   (while plist
1071     (let ((key (pop plist))
1072           (value (pop plist)))
1073       (when value
1074         ;; Quote VALUE if it contains suspicious characters.
1075         (when (string-match "[\"'\\~/*;() \t\n]" value)
1076           (setq value (with-output-to-string
1077                         (let (print-escape-nonascii)
1078                           (prin1 value)))))
1079         (insert (format " %s=%s" key value)))))
1080   (insert ">\n"))
1081
1082 (defun mml-insert-empty-tag (name &rest plist)
1083   "Insert an empty MML tag described by NAME and PLIST."
1084   (when (symbolp name)
1085     (setq name (symbol-name name)))
1086   (apply #'mml-insert-tag name plist)
1087   (insert "<#/" name ">\n"))
1088
1089 ;;; Attachment functions.
1090
1091 (defcustom mml-dnd-protocol-alist
1092   '(("^file:///" . mml-dnd-attach-file)
1093     ("^file://"  . dnd-open-file)
1094     ("^file:"    . mml-dnd-attach-file))
1095   "The functions to call when a drop in `mml-mode' is made.
1096 See `dnd-protocol-alist' for more information.  When nil, behave
1097 as in other buffers."
1098   :type '(choice (repeat (cons (regexp) (function)))
1099                  (const :tag "Behave as in other buffers" nil))
1100   :version "23.0" ;; No Gnus
1101   :group 'message)
1102
1103 (defcustom mml-dnd-attach-options nil
1104   "Which options should be queried when attaching a file via drag and drop.
1105
1106 If it is a list, valid members are `type', `description' and
1107 `disposition'.  `disposition' implies `type'.  If it is nil,
1108 don't ask for options.  If it is t, ask the user whether or not
1109 to specify options."
1110   :type '(choice
1111           (const :tag "Non" nil)
1112           (const :tag "Query" t)
1113           (list :value (type description disposition)
1114            (set :inline t
1115                 (const type)
1116                 (const description)
1117                 (const disposition))))
1118   :version "23.0" ;; No Gnus
1119   :group 'message)
1120
1121 (defun mml-attach-file (file &optional type description disposition)
1122   "Attach a file to the outgoing MIME message.
1123 The file is not inserted or encoded until you send the message with
1124 `\\[message-send-and-exit]' or `\\[message-send]'.
1125
1126 FILE is the name of the file to attach.  TYPE is its
1127 content-type, a string of the form \"type/subtype\".  DESCRIPTION
1128 is a one-line description of the attachment.  The DISPOSITION
1129 specifies how the attachment is intended to be displayed.  It can
1130 be either \"inline\" (displayed automatically within the message
1131 body) or \"attachment\" (separate from the body)."
1132   (interactive
1133    (let* ((file (mml-minibuffer-read-file "Attach file: "))
1134           (type (mml-minibuffer-read-type file))
1135           (description (mml-minibuffer-read-description))
1136           (disposition (mml-minibuffer-read-disposition type)))
1137      (list file type description disposition)))
1138   (save-excursion
1139     (unless (message-in-body-p) (goto-char (point-max)))
1140     (mml-insert-empty-tag 'part
1141                           'type type
1142                           'filename file
1143                           'disposition (or disposition "attachment")
1144                           'description description)))
1145
1146 (defun mml-dnd-attach-file (uri action)
1147   "Attach a drag and drop file.
1148
1149 Ask for type, description or disposition according to
1150 `mml-dnd-attach-options'."
1151   (let ((file (dnd-get-local-file-name uri t)))
1152     (when (and file (file-regular-p file))
1153       (let ((mml-dnd-attach-options mml-dnd-attach-options)
1154             type description disposition)
1155         (setq mml-dnd-attach-options
1156               (when (and (eq mml-dnd-attach-options t)
1157                          (not
1158                           (y-or-n-p
1159                            "Use default type, disposition and description? ")))
1160                 '(type description disposition)))
1161         (when (or (memq 'type mml-dnd-attach-options)
1162                   (memq 'disposition mml-dnd-attach-options))
1163           (setq type (mml-minibuffer-read-type file)))
1164         (when (memq 'description mml-dnd-attach-options)
1165           (setq description (mml-minibuffer-read-description)))
1166         (when (memq 'disposition mml-dnd-attach-options)
1167           (setq disposition (mml-minibuffer-read-disposition type)))
1168         (mml-attach-file file type description disposition)))))
1169
1170 (defun mml-attach-buffer (buffer &optional type description)
1171   "Attach a buffer to the outgoing MIME message.
1172 See `mml-attach-file' for details of operation."
1173   (interactive
1174    (let* ((buffer (read-buffer "Attach buffer: "))
1175           (type (mml-minibuffer-read-type buffer "text/plain"))
1176           (description (mml-minibuffer-read-description)))
1177      (list buffer type description)))
1178   (save-excursion
1179     (unless (message-in-body-p) (goto-char (point-max)))
1180     (mml-insert-empty-tag 'part 'type type 'buffer buffer
1181                           'disposition "attachment"
1182                           'description description)))
1183
1184 (defun mml-attach-external (file &optional type description)
1185   "Attach an external file into the buffer.
1186 FILE is an ange-ftp/efs specification of the part location.
1187 TYPE is the MIME type to use."
1188   (interactive
1189    (let* ((file (mml-minibuffer-read-file "Attach external file: "))
1190           (type (mml-minibuffer-read-type file))
1191           (description (mml-minibuffer-read-description)))
1192      (list file type description)))
1193   (save-excursion
1194     (unless (message-in-body-p) (goto-char (point-max)))
1195     (mml-insert-empty-tag 'external 'type type 'name file
1196                           'disposition "attachment" 'description description)))
1197
1198 (defun mml-insert-multipart (&optional type)
1199   (interactive (list (completing-read "Multipart type (default mixed): "
1200                                       '(("mixed") ("alternative") ("digest") ("parallel")
1201                                         ("signed") ("encrypted"))
1202                                       nil nil "mixed")))
1203   (or type
1204       (setq type "mixed"))
1205   (mml-insert-empty-tag "multipart" 'type type)
1206   (forward-line -1))
1207
1208 (defun mml-insert-part (&optional type)
1209   (interactive
1210    (list (mml-minibuffer-read-type "")))
1211   (mml-insert-tag 'part 'type type 'disposition "inline")
1212   (forward-line -1))
1213
1214 (defun mml-preview-insert-mail-followup-to ()
1215   "Insert a Mail-Followup-To header before previewing an article.
1216 Should be adopted if code in `message-send-mail' is changed."
1217   (when (and (message-mail-p)
1218              (message-subscribed-p)
1219              (not (mail-fetch-field "mail-followup-to"))
1220              (message-make-mail-followup-to))
1221     (message-position-on-field "Mail-Followup-To" "X-Draft-From")
1222     (insert (message-make-mail-followup-to))))
1223
1224 (defvar mml-preview-buffer nil)
1225
1226 (defun mml-preview (&optional raw)
1227   "Display current buffer with Gnus, in a new buffer.
1228 If RAW, display a raw encoded MIME message.
1229
1230 The window layout for the preview buffer is controled by the variables
1231 `special-display-buffer-names', `special-display-regexps', or
1232 `gnus-buffer-configuration' (the first match made will be used),
1233 or the `pop-to-buffer' function."
1234   (interactive "P")
1235   (setq mml-preview-buffer (generate-new-buffer
1236                             (concat (if raw "*Raw MIME preview of "
1237                                       "*MIME preview of ") (buffer-name))))
1238   (save-excursion
1239     (let* ((buf (current-buffer))
1240            (message-options message-options)
1241            (message-this-is-mail (message-mail-p))
1242            (message-this-is-news (message-news-p))
1243            (message-posting-charset (or (gnus-setup-posting-charset
1244                                          (save-restriction
1245                                            (message-narrow-to-headers-or-head)
1246                                            (message-fetch-field "Newsgroups")))
1247                                         message-posting-charset)))
1248       (message-options-set-recipient)
1249       (when (boundp 'gnus-buffers)
1250         (push mml-preview-buffer gnus-buffers))
1251       (save-restriction
1252         (widen)
1253         (set-buffer mml-preview-buffer)
1254         (erase-buffer)
1255         (insert-buffer-substring buf))
1256       (mml-preview-insert-mail-followup-to)
1257       (let ((message-deletable-headers (if (message-news-p)
1258                                            nil
1259                                          message-deletable-headers)))
1260         (message-generate-headers
1261          (copy-sequence (if (message-news-p)
1262                             message-required-news-headers
1263                           message-required-mail-headers))))
1264       (if (re-search-forward
1265            (concat "^" (regexp-quote mail-header-separator) "\n") nil t)
1266           (replace-match "\n"))
1267       (let ((mail-header-separator ""));; mail-header-separator is removed.
1268         (message-sort-headers)
1269         (mml-to-mime))
1270       (if raw
1271           (when (fboundp 'set-buffer-multibyte)
1272             (let ((s (buffer-string)))
1273               ;; Insert the content into unibyte buffer.
1274               (erase-buffer)
1275               (mm-disable-multibyte)
1276               (insert s)))
1277         (let ((gnus-newsgroup-charset (car message-posting-charset))
1278               gnus-article-prepare-hook gnus-original-article-buffer)
1279           (run-hooks 'gnus-article-decode-hook)
1280           (let ((gnus-newsgroup-name "dummy")
1281                 (gnus-newsrc-hashtb (or gnus-newsrc-hashtb
1282                                         (gnus-make-hashtable 5))))
1283             (gnus-article-prepare-display))))
1284       ;; Disable article-mode-map.
1285       (use-local-map nil)
1286       (gnus-make-local-hook 'kill-buffer-hook)
1287       (add-hook 'kill-buffer-hook
1288                 (lambda ()
1289                   (mm-destroy-parts gnus-article-mime-handles)) nil t)
1290       (setq buffer-read-only t)
1291       (local-set-key "q" (lambda () (interactive) (kill-buffer nil)))
1292       (local-set-key "=" (lambda () (interactive) (delete-other-windows)))
1293       (local-set-key "\r"
1294                      (lambda ()
1295                        (interactive)
1296                        (widget-button-press (point))))
1297       (local-set-key gnus-mouse-2
1298                      (lambda (event)
1299                        (interactive "@e")
1300                        (widget-button-press (widget-event-point event) event)))
1301       (goto-char (point-min))))
1302   (if (and (not (mm-special-display-p (buffer-name mml-preview-buffer)))
1303            (boundp 'gnus-buffer-configuration)
1304            (assq 'mml-preview gnus-buffer-configuration))
1305       (let ((gnus-message-buffer (current-buffer)))
1306         (gnus-configure-windows 'mml-preview))
1307     (pop-to-buffer mml-preview-buffer)))
1308
1309 (defun mml-validate ()
1310   "Validate the current MML document."
1311   (interactive)
1312   (mml-parse))
1313
1314 (defun mml-tweak-part (cont)
1315   "Tweak a MML part."
1316   (let ((tweak (cdr (assq 'tweak cont)))
1317         func)
1318     (cond
1319      (tweak
1320       (setq func
1321             (or (cdr (assoc tweak mml-tweak-function-alist))
1322                 (intern tweak))))
1323      (mml-tweak-type-alist
1324       (let ((alist mml-tweak-type-alist)
1325             (type (or (cdr (assq 'type cont)) "text/plain")))
1326         (while alist
1327           (if (string-match (caar alist) type)
1328               (setq func (cdar alist)
1329                     alist nil)
1330             (setq alist (cdr alist)))))))
1331     (if func
1332         (funcall func cont)
1333       cont)
1334     (let ((alist mml-tweak-sexp-alist))
1335       (while alist
1336         (if (eval (caar alist))
1337             (funcall (cdar alist) cont))
1338         (setq alist (cdr alist)))))
1339   cont)
1340
1341 (defun mml-tweak-externalize-attachments (cont)
1342   "Tweak attached files as external parts."
1343   (let (filename-cons)
1344     (when (and (eq (car cont) 'part)
1345                (not (cdr (assq 'buffer cont)))
1346                (and (setq filename-cons (assq 'filename cont))
1347                     (not (equal (cdr (assq 'nofile cont)) "yes"))))
1348       (setcar cont 'external)
1349       (setcar filename-cons 'name))))
1350
1351 (provide 'mml)
1352
1353 ;;; arch-tag: 583c96cf-1ffe-451b-a5e5-4733ae9ddd12
1354 ;;; mml.el ends here