cgit.sxemacs.org Git - gnus/blob - lisp/mm-util.el

   1 ;;; mm-util.el --- Utility functions for Mule and low level things
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;   Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29 (require 'mail-prsvr)
  30
  31 (eval-and-compile
  32   (mapcar
  33    (lambda (elem)
  34      (let ((nfunc (intern (format "mm-%s" (car elem)))))
  35        (if (fboundp (car elem))
  36            (defalias nfunc (car elem))
  37          (defalias nfunc (cdr elem)))))
  38    '((decode-coding-string . (lambda (s a) s))
  39      (encode-coding-string . (lambda (s a) s))
  40      (encode-coding-region . ignore)
  41      (coding-system-list . ignore)
  42      (decode-coding-region . ignore)
  43      (char-int . identity)
  44      (coding-system-equal . equal)
  45      (annotationp . ignore)
  46      (set-buffer-file-coding-system . ignore)
  47      (read-charset
  48       . (lambda (prompt)
  49           "Return a charset."
  50           (intern
  51            (completing-read
  52             prompt
  53             (mapcar (lambda (e) (list (symbol-name (car e))))
  54                     mm-mime-mule-charset-alist)
  55             nil t))))
  56      (subst-char-in-string
  57       . (lambda (from to string &optional inplace) ;; stolen (and renamed) from nnheader.el
  58           "Replace characters in STRING from FROM to TO.
  59           Unless optional argument INPLACE is non-nil, return a new string."
  60           (let ((string (if inplace string (copy-sequence string)))
  61                 (len (length string))
  62                 (idx 0))
  63             ;; Replace all occurrences of FROM with TO.
  64             (while (< idx len)
  65               (when (= (aref string idx) from)
  66                 (aset string idx to))
  67               (setq idx (1+ idx)))
  68             string)))
  69      (replace-in-string
  70       . (lambda (string regexp rep &optional literal)
  71           "See `replace-regexp-in-string', only the order of args differs."
  72           (replace-regexp-in-string regexp rep string nil literal)))
  73      (string-as-unibyte . identity)
  74      (string-make-unibyte . identity)
  75      (string-as-multibyte . identity)
  76      (multibyte-string-p . ignore)
  77      ;; It is not a MIME function, but some MIME functions use it.
  78      (make-temp-file . (lambda (prefix &optional dir-flag)
  79                          (let ((file (expand-file-name
  80                                       (make-temp-name prefix)
  81                                       (if (fboundp 'temp-directory)
  82                                           (temp-directory)
  83                                         temporary-file-directory))))
  84                            (if dir-flag
  85                                (make-directory file))
  86                            file)))
  87      (insert-byte . insert-char)
  88      (multibyte-char-to-unibyte . identity))))
  89
  90 (eval-and-compile
  91   (defalias 'mm-char-or-char-int-p
  92     (cond
  93      ((fboundp 'char-or-char-int-p) 'char-or-char-int-p)
  94      ((fboundp 'char-valid-p) 'char-valid-p)
  95      (t 'identity))))
  96
  97 ;; Fixme:  This seems always to be used to read a MIME charset, so it
  98 ;; should be re-named and fixed (in Emacs) to offer completion only on
  99 ;; proper charset names (base coding systems which have a
 100 ;; mime-charset defined).  XEmacs doesn't believe in mime-charset;
 101 ;; test with
 102 ;;   `(or (coding-system-get 'iso-8859-1 'mime-charset)
 103 ;;        (coding-system-get 'iso-8859-1 :mime-charset))'
 104 ;; Actually, there should be an `mm-coding-system-mime-charset'.
 105 (eval-and-compile
 106   (defalias 'mm-read-coding-system
 107     (cond
 108      ((fboundp 'read-coding-system)
 109       (if (and (featurep 'xemacs)
 110                (<= (string-to-number emacs-version) 21.1))
 111           (lambda (prompt &optional default-coding-system)
 112             (read-coding-system prompt))
 113         'read-coding-system))
 114      (t (lambda (prompt &optional default-coding-system)
 115           "Prompt the user for a coding system."
 116           (completing-read
 117            prompt (mapcar (lambda (s) (list (symbol-name (car s))))
 118                           mm-mime-mule-charset-alist)))))))
 119
 120 (defvar mm-coding-system-list nil)
 121 (defun mm-get-coding-system-list ()
 122   "Get the coding system list."
 123   (or mm-coding-system-list
 124       (setq mm-coding-system-list (mm-coding-system-list))))
 125
 126 (defun mm-coding-system-p (cs)
 127   "Return non-nil if CS is a symbol naming a coding system.
 128 In XEmacs, also return non-nil if CS is a coding system object.
 129 If CS is available, return CS itself in Emacs, and return a coding
 130 system object in XEmacs."
 131   (if (fboundp 'find-coding-system)
 132       (find-coding-system cs)
 133     (if (fboundp 'coding-system-p)
 134         (when (coding-system-p cs)
 135           cs)
 136       ;; Is this branch ever actually useful?
 137       (car (memq cs (mm-get-coding-system-list))))))
 138
 139 (defvar mm-charset-synonym-alist
 140   `(
 141     ;; Not in XEmacs, but it's not a proper MIME charset anyhow.
 142     ,@(unless (mm-coding-system-p 'x-ctext)
 143        '((x-ctext . ctext)))
 144     ;; ISO-8859-15 is very similar to ISO-8859-1.  But it's _different_!
 145     ,@(unless (mm-coding-system-p 'iso-8859-15)
 146        '((iso-8859-15 . iso-8859-1)))
 147     ;; BIG-5HKSCS is similar to, but different than, BIG-5.
 148     ,@(unless (mm-coding-system-p 'big5-hkscs)
 149         '((big5-hkscs . big5)))
 150     ;; Windows-1252 is actually a superset of Latin-1.  See also
 151     ;; `gnus-article-dumbquotes-map'.
 152     ,@(unless (mm-coding-system-p 'windows-1252)
 153        (if (mm-coding-system-p 'cp1252)
 154            '((windows-1252 . cp1252))
 155          '((windows-1252 . iso-8859-1))))
 156     ;; Windows-1250 is a variant of Latin-2 heavily used by Microsoft
 157     ;; Outlook users in Czech republic. Use this to allow reading of their
 158     ;; e-mails. cp1250 should be defined by M-x codepage-setup.
 159     ,@(if (and (not (mm-coding-system-p 'windows-1250))
 160                (mm-coding-system-p 'cp1250))
 161           '((windows-1250 . cp1250)))
 162     ;; A Microsoft misunderstanding.
 163     ,@(unless (mm-coding-system-p 'ks_c_5601-1987)
 164         (if (mm-coding-system-p 'cp949)
 165             '((ks_c_5601-1987 . cp949))
 166           '((ks_c_5601-1987 . euc-kr))))
 167     )
 168   "A mapping from invalid charset names to the real charset names.")
 169
 170 (defvar mm-binary-coding-system
 171   (cond
 172    ((mm-coding-system-p 'binary) 'binary)
 173    ((mm-coding-system-p 'no-conversion) 'no-conversion)
 174    (t nil))
 175   "100% binary coding system.")
 176
 177 (defvar mm-text-coding-system
 178   (or (if (memq system-type '(windows-nt ms-dos ms-windows))
 179           (and (mm-coding-system-p 'raw-text-dos) 'raw-text-dos)
 180         (and (mm-coding-system-p 'raw-text) 'raw-text))
 181       mm-binary-coding-system)
 182   "Text-safe coding system (For removing ^M).")
 183
 184 (defvar mm-text-coding-system-for-write nil
 185   "Text coding system for write.")
 186
 187 (defvar mm-auto-save-coding-system
 188   (cond
 189    ((mm-coding-system-p 'utf-8-emacs)   ; Mule 7
 190     (if (memq system-type '(windows-nt ms-dos ms-windows))
 191         (if (mm-coding-system-p 'utf-8-emacs-dos)
 192             'utf-8-emacs-dos mm-binary-coding-system)
 193       'utf-8-emacs))
 194    ((mm-coding-system-p 'emacs-mule)
 195     (if (memq system-type '(windows-nt ms-dos ms-windows))
 196         (if (mm-coding-system-p 'emacs-mule-dos)
 197             'emacs-mule-dos mm-binary-coding-system)
 198       'emacs-mule))
 199    ((mm-coding-system-p 'escape-quoted) 'escape-quoted)
 200    (t mm-binary-coding-system))
 201   "Coding system of auto save file.")
 202
 203 (defvar mm-universal-coding-system mm-auto-save-coding-system
 204   "The universal coding system.")
 205
 206 ;; Fixme: some of the cars here aren't valid MIME charsets.  That
 207 ;; should only matter with XEmacs, though.
 208 (defvar mm-mime-mule-charset-alist
 209   `((us-ascii ascii)
 210     (iso-8859-1 latin-iso8859-1)
 211     (iso-8859-2 latin-iso8859-2)
 212     (iso-8859-3 latin-iso8859-3)
 213     (iso-8859-4 latin-iso8859-4)
 214     (iso-8859-5 cyrillic-iso8859-5)
 215     ;; Non-mule (X)Emacs uses the last mule-charset for 8bit characters.
 216     ;; The fake mule-charset, gnus-koi8-r, tells Gnus that the default
 217     ;; charset is koi8-r, not iso-8859-5.
 218     (koi8-r cyrillic-iso8859-5 gnus-koi8-r)
 219     (iso-8859-6 arabic-iso8859-6)
 220     (iso-8859-7 greek-iso8859-7)
 221     (iso-8859-8 hebrew-iso8859-8)
 222     (iso-8859-9 latin-iso8859-9)
 223     (iso-8859-14 latin-iso8859-14)
 224     (iso-8859-15 latin-iso8859-15)
 225     (viscii vietnamese-viscii-lower)
 226     (iso-2022-jp latin-jisx0201 japanese-jisx0208 japanese-jisx0208-1978)
 227     (euc-kr korean-ksc5601)
 228     (gb2312 chinese-gb2312)
 229     (big5 chinese-big5-1 chinese-big5-2)
 230     (tibetan tibetan)
 231     (thai-tis620 thai-tis620)
 232     (windows-1251 cyrillic-iso8859-5)
 233     (iso-2022-7bit ethiopic arabic-1-column arabic-2-column)
 234     (iso-2022-jp-2 latin-iso8859-1 greek-iso8859-7
 235                    latin-jisx0201 japanese-jisx0208-1978
 236                    chinese-gb2312 japanese-jisx0208
 237                    korean-ksc5601 japanese-jisx0212)
 238     (iso-2022-int-1 latin-iso8859-1 greek-iso8859-7
 239                     latin-jisx0201 japanese-jisx0208-1978
 240                     chinese-gb2312 japanese-jisx0208
 241                     korean-ksc5601 japanese-jisx0212
 242                     chinese-cns11643-1 chinese-cns11643-2)
 243     (iso-2022-int-1 latin-iso8859-1 latin-iso8859-2
 244                     cyrillic-iso8859-5 greek-iso8859-7
 245                     latin-jisx0201 japanese-jisx0208-1978
 246                     chinese-gb2312 japanese-jisx0208
 247                     korean-ksc5601 japanese-jisx0212
 248                     chinese-cns11643-1 chinese-cns11643-2
 249                     chinese-cns11643-3 chinese-cns11643-4
 250                     chinese-cns11643-5 chinese-cns11643-6
 251                     chinese-cns11643-7)
 252     (iso-2022-jp-3 latin-jisx0201 japanese-jisx0208-1978 japanese-jisx0208
 253                    japanese-jisx0213-1 japanese-jisx0213-2)
 254     (shift_jis latin-jisx0201 katakana-jisx0201 japanese-jisx0208)
 255     ,(if (or (not (fboundp 'charsetp)) ;; non-Mule case
 256              (charsetp 'unicode-a)
 257              (not (mm-coding-system-p 'mule-utf-8)))
 258          '(utf-8 unicode-a unicode-b unicode-c unicode-d unicode-e)
 259        ;; If we have utf-8 we're in Mule 5+.
 260        (append '(utf-8)
 261                (delete 'ascii
 262                        (coding-system-get 'mule-utf-8 'safe-charsets)))))
 263   "Alist of MIME-charset/MULE-charsets.")
 264
 265 (defun mm-enrich-utf-8-by-mule-ucs ()
 266   "Make the `utf-8' MIME charset usable by the Mule-UCS package.
 267 This function will run when the `un-define' module is loaded under
 268 XEmacs, and fill the `utf-8' entry in `mm-mime-mule-charset-alist'
 269 with Mule charsets.  It is completely useless for Emacs."
 270   (unless (cdr (delete '(mm-enrich-utf-8-by-mule-ucs)
 271                        (assoc "un-define" after-load-alist)))
 272     (setq after-load-alist
 273           (delete '("un-define") after-load-alist)))
 274   (when (boundp 'unicode-basic-translation-charset-order-list)
 275     (condition-case nil
 276         (let ((val (delq
 277                     'ascii
 278                     (copy-sequence
 279                      (symbol-value
 280                       'unicode-basic-translation-charset-order-list))))
 281               (elem (assq 'utf-8 mm-mime-mule-charset-alist)))
 282           (if elem
 283               (setcdr elem val)
 284             (setq mm-mime-mule-charset-alist
 285                   (nconc mm-mime-mule-charset-alist
 286                          (list (cons 'utf-8 val))))))
 287       (error))))
 288
 289 ;; Correct by construction, but should be unnecessary for Emacs:
 290 (if (featurep 'xemacs)
 291     (eval-after-load "un-define" '(mm-enrich-utf-8-by-mule-ucs))
 292   (when (and (fboundp 'coding-system-list)
 293              (fboundp 'sort-coding-systems))
 294     (let ((css (sort-coding-systems (coding-system-list 'base-only)))
 295           cs mime mule alist)
 296       (while css
 297         (setq cs (pop css)
 298               mime (or (coding-system-get cs :mime-charset) ; Emacs 22
 299                        (coding-system-get cs 'mime-charset)))
 300         (when (and mime
 301                    (not (eq t (setq mule
 302                                     (coding-system-get cs 'safe-charsets))))
 303                    (not (assq mime alist)))
 304           (push (cons mime (delq 'ascii mule)) alist)))
 305       (setq mm-mime-mule-charset-alist (nreverse alist)))))
 306
 307 (defvar mm-hack-charsets '(iso-8859-15 iso-2022-jp-2)
 308   "A list of special charsets.
 309 Valid elements include:
 310 `iso-8859-15'    convert ISO-8859-1, -9 to ISO-8859-15 if ISO-8859-15 exists.
 311 `iso-2022-jp-2'  convert ISO-2022-jp to ISO-2022-jp-2 if ISO-2022-jp-2 exists."
 312 )
 313
 314 (defvar mm-iso-8859-15-compatible
 315   '((iso-8859-1 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE")
 316     (iso-8859-9 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE\xD0\xDD\xDE\xF0\xFD\xFE"))
 317   "ISO-8859-15 exchangeable coding systems and inconvertible characters.")
 318
 319 (defvar mm-iso-8859-x-to-15-table
 320   (and (fboundp 'coding-system-p)
 321        (mm-coding-system-p 'iso-8859-15)
 322        (mapcar
 323         (lambda (cs)
 324           (if (mm-coding-system-p (car cs))
 325               (let ((c (string-to-char
 326                         (decode-coding-string "\341" (car cs)))))
 327                 (cons (char-charset c)
 328                       (cons
 329                        (- (string-to-char
 330                            (decode-coding-string "\341" 'iso-8859-15)) c)
 331                        (string-to-list (decode-coding-string (car (cdr cs))
 332                                                              (car cs))))))
 333             '(gnus-charset 0)))
 334         mm-iso-8859-15-compatible))
 335   "A table of the difference character between ISO-8859-X and ISO-8859-15.")
 336
 337 (defcustom mm-coding-system-priorities
 338   (if (boundp 'current-language-environment)
 339       (let ((lang (symbol-value 'current-language-environment)))
 340         (cond ((string= lang "Japanese")
 341                ;; Japanese users may prefer iso-2022-jp to shift_jis.
 342                '(iso-2022-jp iso-2022-jp-2 shift_jis iso-8859-1 utf-8)))))
 343   "Preferred coding systems for encoding outgoing messages.
 344
 345 More than one suitable coding system may be found for some text.
 346 By default, the coding system with the highest priority is used
 347 to encode outgoing messages (see `sort-coding-systems').  If this
 348 variable is set, it overrides the default priority."
 349   :type '(repeat (symbol :tag "Coding system"))
 350   :group 'mime)
 351
 352 ;; ??
 353 (defvar mm-use-find-coding-systems-region
 354   (fboundp 'find-coding-systems-region)
 355   "Use `find-coding-systems-region' to find proper coding systems.
 356
 357 Setting it to nil is useful on Emacsen supporting Unicode if sending
 358 mail with multiple parts is preferred to sending a Unicode one.")
 359
 360 ;;; Internal variables:
 361
 362 ;;; Functions:
 363
 364 (defun mm-mule-charset-to-mime-charset (charset)
 365   "Return the MIME charset corresponding to the given Mule CHARSET."
 366   (if (and (fboundp 'find-coding-systems-for-charsets)
 367            (fboundp 'sort-coding-systems))
 368       (let ((css (sort (sort-coding-systems
 369                         (find-coding-systems-for-charsets (list charset)))
 370                        'mm-sort-coding-systems-predicate))
 371             cs mime)
 372         (while (and (not mime)
 373                     css)
 374           (when (setq cs (pop css))
 375             (setq mime (or (coding-system-get cs :mime-charset)
 376                            (coding-system-get cs 'mime-charset)))))
 377         mime)
 378     (let ((alist (mapcar (lambda (cs)
 379                            (assq cs mm-mime-mule-charset-alist))
 380                          (sort (mapcar 'car mm-mime-mule-charset-alist)
 381                                'mm-sort-coding-systems-predicate)))
 382           out)
 383       (while alist
 384         (when (memq charset (cdar alist))
 385           (setq out (caar alist)
 386                 alist nil))
 387         (pop alist))
 388       out)))
 389
 390 (defun mm-charset-to-coding-system (charset &optional lbt)
 391   "Return coding-system corresponding to CHARSET.
 392 CHARSET is a symbol naming a MIME charset.
 393 If optional argument LBT (`unix', `dos' or `mac') is specified, it is
 394 used as the line break code type of the coding system."
 395   (when (stringp charset)
 396     (setq charset (intern (downcase charset))))
 397   (when lbt
 398     (setq charset (intern (format "%s-%s" charset lbt))))
 399   (cond
 400    ((null charset)
 401     charset)
 402    ;; Running in a non-MULE environment.
 403    ((or (null (mm-get-coding-system-list))
 404         (not (fboundp 'coding-system-get)))
 405     charset)
 406    ;; ascii
 407    ((eq charset 'us-ascii)
 408     'ascii)
 409    ;; Check to see whether we can handle this charset.  (This depends
 410    ;; on there being some coding system matching each `mime-charset'
 411    ;; property defined, as there should be.)
 412    ((and (mm-coding-system-p charset)
 413 ;;; Doing this would potentially weed out incorrect charsets.
 414 ;;;      charset
 415 ;;;      (eq charset (coding-system-get charset 'mime-charset))
 416          )
 417     charset)
 418    ;; Translate invalid charsets.
 419    ((let ((cs (cdr (assq charset mm-charset-synonym-alist))))
 420       (and cs (mm-coding-system-p cs) cs)))
 421    ;; Last resort: search the coding system list for entries which
 422    ;; have the right mime-charset in case the canonical name isn't
 423    ;; defined (though it should be).
 424    ((let (cs)
 425       ;; mm-get-coding-system-list returns a list of cs without lbt.
 426       ;; Do we need -lbt?
 427       (dolist (c (mm-get-coding-system-list))
 428         (if (and (null cs)
 429                  (eq charset (or (coding-system-get c :mime-charset)
 430                                  (coding-system-get c 'mime-charset))))
 431             (setq cs c)))
 432       cs))))
 433
 434 (eval-and-compile
 435   (defvar mm-emacs-mule (and (not (featurep 'xemacs))
 436                              (boundp 'default-enable-multibyte-characters)
 437                              default-enable-multibyte-characters
 438                              (fboundp 'set-buffer-multibyte))
 439     "True in Emacs with Mule.")
 440
 441   (if mm-emacs-mule
 442       (defun mm-enable-multibyte ()
 443         "Set the multibyte flag of the current buffer.
 444 Only do this if the default value of `enable-multibyte-characters' is
 445 non-nil.  This is a no-op in XEmacs."
 446         (set-buffer-multibyte 'to))
 447     (defalias 'mm-enable-multibyte 'ignore))
 448
 449   (if mm-emacs-mule
 450       (defun mm-disable-multibyte ()
 451         "Unset the multibyte flag of in the current buffer.
 452 This is a no-op in XEmacs."
 453         (set-buffer-multibyte nil))
 454     (defalias 'mm-disable-multibyte 'ignore)))
 455
 456 (defun mm-preferred-coding-system (charset)
 457   ;; A typo in some Emacs versions.
 458   (or (get-charset-property charset 'preferred-coding-system)
 459       (get-charset-property charset 'prefered-coding-system)))
 460
 461 ;; Mule charsets shouldn't be used.
 462 (defsubst mm-guess-charset ()
 463   "Guess Mule charset from the language environment."
 464   (or
 465    mail-parse-mule-charset ;; cached mule-charset
 466    (progn
 467      (setq mail-parse-mule-charset
 468            (and (boundp 'current-language-environment)
 469                 (car (last
 470                       (assq 'charset
 471                             (assoc current-language-environment
 472                                    language-info-alist))))))
 473      (if (or (not mail-parse-mule-charset)
 474              (eq mail-parse-mule-charset 'ascii))
 475          (setq mail-parse-mule-charset
 476                (or (car (last (assq mail-parse-charset
 477                                     mm-mime-mule-charset-alist)))
 478                    ;; default
 479                    'latin-iso8859-1)))
 480      mail-parse-mule-charset)))
 481
 482 (defun mm-charset-after (&optional pos)
 483   "Return charset of a character in current buffer at position POS.
 484 If POS is nil, it defauls to the current point.
 485 If POS is out of range, the value is nil.
 486 If the charset is `composition', return the actual one."
 487   (let ((char (char-after pos)) charset)
 488     (if (< (mm-char-int char) 128)
 489         (setq charset 'ascii)
 490       ;; charset-after is fake in some Emacsen.
 491       (setq charset (and (fboundp 'char-charset) (char-charset char)))
 492       (if (eq charset 'composition)     ; Mule 4
 493           (let ((p (or pos (point))))
 494             (cadr (find-charset-region p (1+ p))))
 495         (if (and charset (not (memq charset '(ascii eight-bit-control
 496                                                     eight-bit-graphic))))
 497             charset
 498           (mm-guess-charset))))))
 499
 500 (defun mm-mime-charset (charset)
 501   "Return the MIME charset corresponding to the given Mule CHARSET."
 502   (if (eq charset 'unknown)
 503       (error "The message contains non-printable characters, please use attachment"))
 504   (if (and (fboundp 'coding-system-get) (fboundp 'get-charset-property))
 505       ;; This exists in Emacs 20.
 506       (or
 507        (and (mm-preferred-coding-system charset)
 508             (or (coding-system-get
 509                  (mm-preferred-coding-system charset) :mime-charset)
 510                 (coding-system-get
 511                  (mm-preferred-coding-system charset) 'mime-charset)))
 512        (and (eq charset 'ascii)
 513             'us-ascii)
 514        (mm-preferred-coding-system charset)
 515        (mm-mule-charset-to-mime-charset charset))
 516     ;; This is for XEmacs.
 517     (mm-mule-charset-to-mime-charset charset)))
 518
 519 (defun mm-delete-duplicates (list)
 520   "Simple substitute for CL `delete-duplicates', testing with `equal'."
 521   (let (result head)
 522     (while list
 523       (setq head (car list))
 524       (setq list (delete head list))
 525       (setq result (cons head result)))
 526     (nreverse result)))
 527
 528 ;; Fixme:  This is used in places when it should be testing the
 529 ;; default multibyteness.  See mm-default-multibyte-p.
 530 (eval-and-compile
 531   (if (and (not (featurep 'xemacs))
 532            (boundp 'enable-multibyte-characters))
 533       (defun mm-multibyte-p ()
 534         "Non-nil if multibyte is enabled in the current buffer."
 535         enable-multibyte-characters)
 536     (defun mm-multibyte-p () (featurep 'mule))))
 537
 538 (defun mm-default-multibyte-p ()
 539   "Return non-nil if the session is multibyte.
 540 This affects whether coding conversion should be attempted generally."
 541   (if (featurep 'mule)
 542       (if (boundp 'default-enable-multibyte-characters)
 543           default-enable-multibyte-characters
 544         t)))
 545
 546 (defun mm-iso-8859-x-to-15-region (&optional b e)
 547   (if (fboundp 'char-charset)
 548       (let (charset item c inconvertible)
 549         (save-restriction
 550           (if e (narrow-to-region b e))
 551           (goto-char (point-min))
 552           (skip-chars-forward "\0-\177")
 553           (while (not (eobp))
 554             (cond
 555              ((not (setq item (assq (char-charset (setq c (char-after)))
 556                                     mm-iso-8859-x-to-15-table)))
 557               (forward-char))
 558              ((memq c (cdr (cdr item)))
 559               (setq inconvertible t)
 560               (forward-char))
 561              (t
 562               (insert-before-markers (prog1 (+ c (car (cdr item)))
 563                                        (delete-char 1)))))
 564             (skip-chars-forward "\0-\177")))
 565         (not inconvertible))))
 566
 567 (defun mm-sort-coding-systems-predicate (a b)
 568   (let ((priorities
 569          (mapcar (lambda (cs)
 570                    ;; Note: invalid entries are dropped silently
 571                    (and (setq cs (mm-coding-system-p cs))
 572                         (coding-system-base cs)))
 573                  mm-coding-system-priorities)))
 574     (and (setq a (mm-coding-system-p a))
 575          (if (setq b (mm-coding-system-p b))
 576              (> (length (memq (coding-system-base a) priorities))
 577                 (length (memq (coding-system-base b) priorities)))
 578            t))))
 579
 580 (defun mm-find-mime-charset-region (b e &optional hack-charsets)
 581   "Return the MIME charsets needed to encode the region between B and E.
 582 nil means ASCII, a single-element list represents an appropriate MIME
 583 charset, and a longer list means no appropriate charset."
 584   (let (charsets)
 585     ;; The return possibilities of this function are a mess...
 586     (or (and (mm-multibyte-p)
 587              mm-use-find-coding-systems-region
 588              ;; Find the mime-charset of the most preferred coding
 589              ;; system that has one.
 590              (let ((systems (find-coding-systems-region b e)))
 591                (when mm-coding-system-priorities
 592                  (setq systems
 593                        (sort systems 'mm-sort-coding-systems-predicate)))
 594                (setq systems (delq 'compound-text systems))
 595                (unless (equal systems '(undecided))
 596                  (while systems
 597                    (let* ((head (pop systems))
 598                           (cs (or (coding-system-get head :mime-charset)
 599                                   (coding-system-get head 'mime-charset))))
 600                      ;; The mime-charset (`x-ctext') of
 601                      ;; `compound-text' is not in the IANA list.  We
 602                      ;; shouldn't normally use anything here with a
 603                      ;; mime-charset having an `x-' prefix.
 604                      ;; Fixme:  Allow this to be overridden, since
 605                      ;; there is existing use of x-ctext.
 606                      ;; Also people apparently need the coding system
 607                      ;; `iso-2022-jp-3' (which Mule-UCS defines with
 608                      ;; mime-charset, though it's not valid).
 609                      (if (and cs
 610                               (not (string-match "^[Xx]-" (symbol-name cs)))
 611                               ;; UTF-16 of any variety is invalid for
 612                               ;; text parts and, unfortunately, has
 613                               ;; mime-charset defined both in Mule-UCS
 614                               ;; and versions of Emacs.  (The name
 615                               ;; might be `mule-utf-16...'  or
 616                               ;; `utf-16...'.)
 617                               (not (string-match "utf-16" (symbol-name cs))))
 618                          (setq systems nil
 619                                charsets (list cs))))))
 620                charsets))
 621         ;; Otherwise we're not multibyte, we're XEmacs, or a single
 622         ;; coding system won't cover it.
 623         (setq charsets
 624               (mm-delete-duplicates
 625                (mapcar 'mm-mime-charset
 626                        (delq 'ascii
 627                              (mm-find-charset-region b e))))))
 628     (if (and (> (length charsets) 1)
 629              (memq 'iso-8859-15 charsets)
 630              (memq 'iso-8859-15 hack-charsets)
 631              (save-excursion (mm-iso-8859-x-to-15-region b e)))
 632         (mapcar (lambda (x) (setq charsets (delq (car x) charsets)))
 633                 mm-iso-8859-15-compatible))
 634     (if (and (memq 'iso-2022-jp-2 charsets)
 635              (memq 'iso-2022-jp-2 hack-charsets))
 636         (setq charsets (delq 'iso-2022-jp charsets)))
 637     charsets))
 638
 639 (defmacro mm-with-unibyte-buffer (&rest forms)
 640   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 641 Use unibyte mode for this."
 642   `(let (default-enable-multibyte-characters)
 643      (with-temp-buffer ,@forms)))
 644 (put 'mm-with-unibyte-buffer 'lisp-indent-function 0)
 645 (put 'mm-with-unibyte-buffer 'edebug-form-spec '(body))
 646
 647 (defmacro mm-with-multibyte-buffer (&rest forms)
 648   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 649 Use multibyte mode for this."
 650   `(let ((default-enable-multibyte-characters t))
 651      (with-temp-buffer ,@forms)))
 652 (put 'mm-with-multibyte-buffer 'lisp-indent-function 0)
 653 (put 'mm-with-multibyte-buffer 'edebug-form-spec '(body))
 654
 655 (defmacro mm-with-unibyte-current-buffer (&rest forms)
 656   "Evaluate FORMS with current buffer temporarily made unibyte.
 657 Also bind `default-enable-multibyte-characters' to nil.
 658 Equivalent to `progn' in XEmacs"
 659   (let ((multibyte (make-symbol "multibyte"))
 660         (buffer (make-symbol "buffer")))
 661     `(if mm-emacs-mule
 662          (let ((,multibyte enable-multibyte-characters)
 663                (,buffer (current-buffer)))
 664            (unwind-protect
 665                (let (default-enable-multibyte-characters)
 666                  (set-buffer-multibyte nil)
 667                  ,@forms)
 668              (set-buffer ,buffer)
 669              (set-buffer-multibyte ,multibyte)))
 670        (let (default-enable-multibyte-characters)
 671          ,@forms))))
 672 (put 'mm-with-unibyte-current-buffer 'lisp-indent-function 0)
 673 (put 'mm-with-unibyte-current-buffer 'edebug-form-spec '(body))
 674
 675 (defmacro mm-with-unibyte (&rest forms)
 676   "Eval the FORMS with the default value of `enable-multibyte-characters' nil."
 677   `(let (default-enable-multibyte-characters)
 678      ,@forms))
 679 (put 'mm-with-unibyte 'lisp-indent-function 0)
 680 (put 'mm-with-unibyte 'edebug-form-spec '(body))
 681
 682 (defmacro mm-with-multibyte (&rest forms)
 683   "Eval the FORMS with the default value of `enable-multibyte-characters' t."
 684   `(let ((default-enable-multibyte-characters t))
 685      ,@forms))
 686 (put 'mm-with-multibyte 'lisp-indent-function 0)
 687 (put 'mm-with-multibyte 'edebug-form-spec '(body))
 688
 689 (defun mm-find-charset-region (b e)
 690   "Return a list of Emacs charsets in the region B to E."
 691   (cond
 692    ((and (mm-multibyte-p)
 693          (fboundp 'find-charset-region))
 694     ;; Remove composition since the base charsets have been included.
 695     ;; Remove eight-bit-*, treat them as ascii.
 696     (let ((css (find-charset-region b e)))
 697       (mapcar (lambda (cs) (setq css (delq cs css)))
 698               '(composition eight-bit-control eight-bit-graphic
 699                             control-1))
 700       css))
 701    (t
 702     ;; We are in a unibyte buffer or XEmacs non-mule, so we futz around a bit.
 703     (save-excursion
 704       (save-restriction
 705         (narrow-to-region b e)
 706         (goto-char (point-min))
 707         (skip-chars-forward "\0-\177")
 708         (if (eobp)
 709             '(ascii)
 710           (let (charset)
 711             (setq charset
 712                   (and (boundp 'current-language-environment)
 713                        (car (last (assq 'charset
 714                                         (assoc current-language-environment
 715                                                language-info-alist))))))
 716             (if (eq charset 'ascii) (setq charset nil))
 717             (or charset
 718                 (setq charset
 719                       (car (last (assq mail-parse-charset
 720                                        mm-mime-mule-charset-alist)))))
 721             (list 'ascii (or charset 'latin-iso8859-1)))))))))
 722
 723 (defun mm-auto-mode-alist ()
 724   "Return an `auto-mode-alist' with only the .gz (etc) thingies."
 725   (let ((alist auto-mode-alist)
 726         out)
 727     (while alist
 728       (when (listp (cdar alist))
 729         (push (car alist) out))
 730       (pop alist))
 731     (nreverse out)))
 732
 733 (defvar mm-inhibit-file-name-handlers
 734   '(jka-compr-handler image-file-handler)
 735   "A list of handlers doing (un)compression (etc) thingies.")
 736
 737 (defun mm-insert-file-contents (filename &optional visit beg end replace
 738                                          inhibit)
 739   "Like `insert-file-contents', but only reads in the file.
 740 A buffer may be modified in several ways after reading into the buffer due
 741 to advanced Emacs features, such as file-name-handlers, format decoding,
 742 `find-file-hooks', etc.
 743 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'.
 744   This function ensures that none of these modifications will take place."
 745   (let ((format-alist nil)
 746         (auto-mode-alist (if inhibit nil (mm-auto-mode-alist)))
 747         (default-major-mode 'fundamental-mode)
 748         (enable-local-variables nil)
 749         (after-insert-file-functions nil)
 750         (enable-local-eval nil)
 751         (find-file-hooks nil)
 752         (inhibit-file-name-operation (if inhibit
 753                                          'insert-file-contents
 754                                        inhibit-file-name-operation))
 755         (inhibit-file-name-handlers
 756          (if inhibit
 757              (append mm-inhibit-file-name-handlers
 758                      inhibit-file-name-handlers)
 759            inhibit-file-name-handlers)))
 760     (insert-file-contents filename visit beg end replace)))
 761
 762 (defun mm-append-to-file (start end filename &optional codesys inhibit)
 763   "Append the contents of the region to the end of file FILENAME.
 764 When called from a function, expects three arguments,
 765 START, END and FILENAME.  START and END are buffer positions
 766 saying what text to write.
 767 Optional fourth argument specifies the coding system to use when
 768 encoding the file.
 769 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'."
 770   (let ((coding-system-for-write
 771          (or codesys mm-text-coding-system-for-write
 772              mm-text-coding-system))
 773         (inhibit-file-name-operation (if inhibit
 774                                          'append-to-file
 775                                        inhibit-file-name-operation))
 776         (inhibit-file-name-handlers
 777          (if inhibit
 778              (append mm-inhibit-file-name-handlers
 779                      inhibit-file-name-handlers)
 780            inhibit-file-name-handlers)))
 781     (write-region start end filename t 'no-message)
 782     (message "Appended to %s" filename)))
 783
 784 (defun mm-write-region (start end filename &optional append visit lockname
 785                               coding-system inhibit)
 786
 787   "Like `write-region'.
 788 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'."
 789   (let ((coding-system-for-write
 790          (or coding-system mm-text-coding-system-for-write
 791              mm-text-coding-system))
 792         (inhibit-file-name-operation (if inhibit
 793                                          'write-region
 794                                        inhibit-file-name-operation))
 795         (inhibit-file-name-handlers
 796          (if inhibit
 797              (append mm-inhibit-file-name-handlers
 798                      inhibit-file-name-handlers)
 799            inhibit-file-name-handlers)))
 800     (write-region start end filename append visit lockname)))
 801
 802 (defun mm-image-load-path (&optional package)
 803   (let (dir result)
 804     (dolist (path load-path (nreverse result))
 805       (when (and path
 806                  (file-directory-p
 807                   (setq dir (concat (file-name-directory
 808                                      (directory-file-name path))
 809                                     "etc/" (or package "gnus/")))))
 810         (push dir result))
 811       (push path result))))
 812
 813 ;; Fixme: This doesn't look useful where it's used.
 814 (if (fboundp 'detect-coding-region)
 815     (defun mm-detect-coding-region (start end)
 816       "Like `detect-coding-region' except returning the best one."
 817       (let ((coding-systems
 818              (detect-coding-region (point) (point-max))))
 819         (or (car-safe coding-systems)
 820             coding-systems)))
 821   (defun mm-detect-coding-region (start end)
 822     (let ((point (point)))
 823       (goto-char start)
 824       (skip-chars-forward "\0-\177" end)
 825       (prog1
 826           (if (eq (point) end) 'ascii (mm-guess-charset))
 827         (goto-char point)))))
 828
 829 (if (fboundp 'coding-system-get)
 830     (defun mm-detect-mime-charset-region (start end)
 831       "Detect MIME charset of the text in the region between START and END."
 832       (let ((cs (mm-detect-coding-region start end)))
 833         (coding-system-get cs 'mime-charset)))
 834   (defun mm-detect-mime-charset-region (start end)
 835     "Detect MIME charset of the text in the region between START and END."
 836     (let ((cs (mm-detect-coding-region start end)))
 837       cs)))
 838
 839
 840 (provide 'mm-util)
 841
 842 ;;; arch-tag: 94dc5388-825d-4fd1-bfa5-2100aa351238
 843 ;;; mm-util.el ends here