cgit.sxemacs.org Git - gnus/blob - lisp/mm-util.el

   1 ;;; mm-util.el --- Utility functions for Mule and low level things
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003
   3 ;;   Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29 (require 'mail-prsvr)
  30
  31 (eval-and-compile
  32   (mapcar
  33    (lambda (elem)
  34      (let ((nfunc (intern (format "mm-%s" (car elem)))))
  35        (if (fboundp (car elem))
  36            (defalias nfunc (car elem))
  37          (defalias nfunc (cdr elem)))))
  38    '((decode-coding-string . (lambda (s a) s))
  39      (encode-coding-string . (lambda (s a) s))
  40      (encode-coding-region . ignore)
  41      (coding-system-list . ignore)
  42      (decode-coding-region . ignore)
  43      (char-int . identity)
  44      (coding-system-equal . equal)
  45      (annotationp . ignore)
  46      (set-buffer-file-coding-system . ignore)
  47      (make-char
  48       . (lambda (charset int)
  49           (int-to-char int)))
  50      (read-charset
  51       . (lambda (prompt)
  52           "Return a charset."
  53           (intern
  54            (completing-read
  55             prompt
  56             (mapcar (lambda (e) (list (symbol-name (car e))))
  57                     mm-mime-mule-charset-alist)
  58             nil t))))
  59      (subst-char-in-string
  60       . (lambda (from to string) ;; stolen (and renamed) from nnheader.el
  61           "Replace characters in STRING from FROM to TO."
  62           (let ((string (substring string 0)) ;Copy string.
  63                 (len (length string))
  64                 (idx 0))
  65             ;; Replace all occurrences of FROM with TO.
  66             (while (< idx len)
  67               (when (= (aref string idx) from)
  68                 (aset string idx to))
  69               (setq idx (1+ idx)))
  70             string)))
  71      (string-as-unibyte . identity)
  72      (string-make-unibyte . identity)
  73      (string-as-multibyte . identity)
  74      (multibyte-string-p . ignore))))
  75
  76 (eval-and-compile
  77   (defalias 'mm-char-or-char-int-p
  78     (cond
  79      ((fboundp 'char-or-char-int-p) 'char-or-char-int-p)
  80      ((fboundp 'char-valid-p) 'char-valid-p)
  81      (t 'identity))))
  82
  83 (eval-and-compile
  84   (defalias 'mm-read-coding-system
  85     (cond
  86      ((fboundp 'read-coding-system)
  87       (if (and (featurep 'xemacs)
  88                (<= (string-to-number emacs-version) 21.1))
  89           (lambda (prompt &optional default-coding-system)
  90             (read-coding-system prompt))
  91         'read-coding-system))
  92      (t (lambda (prompt &optional default-coding-system)
  93           "Prompt the user for a coding system."
  94           (completing-read
  95            prompt (mapcar (lambda (s) (list (symbol-name (car s))))
  96                           mm-mime-mule-charset-alist)))))))
  97
  98 (defvar mm-coding-system-list nil)
  99 (defun mm-get-coding-system-list ()
 100   "Get the coding system list."
 101   (or mm-coding-system-list
 102       (setq mm-coding-system-list (mm-coding-system-list))))
 103
 104 (defun mm-coding-system-p (sym)
 105   "Return non-nil if SYM is a coding system."
 106   (or (and (fboundp 'coding-system-p) (coding-system-p sym))
 107       (memq sym (mm-get-coding-system-list))))
 108
 109 (defvar mm-charset-synonym-alist
 110   `(
 111     ;; Perfectly fine?  A valid MIME name, anyhow.
 112     ,@(unless (mm-coding-system-p 'big5)
 113        '((big5 . cn-big5)))
 114     ;; Not in XEmacs, but it's not a proper MIME charset anyhow.
 115     ,@(unless (mm-coding-system-p 'x-ctext)
 116        '((x-ctext . ctext)))
 117     ;; Apparently not defined in Emacs 20, but is a valid MIME name.
 118     ,@(unless (mm-coding-system-p 'gb2312)
 119        '((gb2312 . cn-gb-2312)))
 120     ;; ISO-8859-15 is very similar to ISO-8859-1.
 121     ,@(unless (mm-coding-system-p 'iso-8859-15) ; Emacs 21 defines it.
 122        '((iso-8859-15 . iso-8859-1)))
 123     ;; Windows-1252 is actually a superset of Latin-1.  See also
 124     ;; `gnus-article-dumbquotes-map'.
 125     ,@(unless (mm-coding-system-p 'windows-1252)
 126        (if (mm-coding-system-p 'cp1252)
 127            '((windows-1252 . cp1252))
 128          '((windows-1252 . iso-8859-1))))
 129     ;; Windows-1250 is a variant of Latin-2 heavily used by Microsoft
 130     ;; Outlook users in Czech republic. Use this to allow reading of their
 131     ;; e-mails. cp1250 should be defined by M-x codepage-setup.
 132     ,@(if (and (not (mm-coding-system-p 'windows-1250))
 133                (mm-coding-system-p 'cp1250))
 134           '((windows-1250 . cp1250)))
 135     )
 136   "A mapping from invalid charset names to the real charset names.")
 137
 138 (defvar mm-binary-coding-system
 139   (cond
 140    ((mm-coding-system-p 'binary) 'binary)
 141    ((mm-coding-system-p 'no-conversion) 'no-conversion)
 142    (t nil))
 143   "100% binary coding system.")
 144
 145 (defvar mm-text-coding-system
 146   (or (if (memq system-type '(windows-nt ms-dos ms-windows))
 147           (and (mm-coding-system-p 'raw-text-dos) 'raw-text-dos)
 148         (and (mm-coding-system-p 'raw-text) 'raw-text))
 149       mm-binary-coding-system)
 150   "Text-safe coding system (For removing ^M).")
 151
 152 (defvar mm-text-coding-system-for-write nil
 153   "Text coding system for write.")
 154
 155 (defvar mm-auto-save-coding-system
 156   (cond
 157    ((mm-coding-system-p 'emacs-mule)
 158     (if (memq system-type '(windows-nt ms-dos ms-windows))
 159         (if (mm-coding-system-p 'emacs-mule-dos)
 160             'emacs-mule-dos mm-binary-coding-system)
 161       'emacs-mule))
 162    ((mm-coding-system-p 'escape-quoted) 'escape-quoted)
 163    (t mm-binary-coding-system))
 164   "Coding system of auto save file.")
 165
 166 (defvar mm-universal-coding-system mm-auto-save-coding-system
 167   "The universal coding system.")
 168
 169 ;; Fixme: some of the cars here aren't valid MIME charsets.  That
 170 ;; should only matter with XEmacs, though.
 171 (defvar mm-mime-mule-charset-alist
 172   `((us-ascii ascii)
 173     (iso-8859-1 latin-iso8859-1)
 174     (iso-8859-2 latin-iso8859-2)
 175     (iso-8859-3 latin-iso8859-3)
 176     (iso-8859-4 latin-iso8859-4)
 177     (iso-8859-5 cyrillic-iso8859-5)
 178     ;; Non-mule (X)Emacs uses the last mule-charset for 8bit characters.
 179     ;; The fake mule-charset, gnus-koi8-r, tells Gnus that the default
 180     ;; charset is koi8-r, not iso-8859-5.
 181     (koi8-r cyrillic-iso8859-5 gnus-koi8-r)
 182     (iso-8859-6 arabic-iso8859-6)
 183     (iso-8859-7 greek-iso8859-7)
 184     (iso-8859-8 hebrew-iso8859-8)
 185     (iso-8859-9 latin-iso8859-9)
 186     (iso-8859-14 latin-iso8859-14)
 187     (iso-8859-15 latin-iso8859-15)
 188     (viscii vietnamese-viscii-lower)
 189     (iso-2022-jp latin-jisx0201 japanese-jisx0208 japanese-jisx0208-1978)
 190     (euc-kr korean-ksc5601)
 191     (gb2312 chinese-gb2312)
 192     (big5 chinese-big5-1 chinese-big5-2)
 193     (tibetan tibetan)
 194     (thai-tis620 thai-tis620)
 195     (iso-2022-7bit ethiopic arabic-1-column arabic-2-column)
 196     (iso-2022-jp-2 latin-iso8859-1 greek-iso8859-7
 197                    latin-jisx0201 japanese-jisx0208-1978
 198                    chinese-gb2312 japanese-jisx0208
 199                    korean-ksc5601 japanese-jisx0212
 200                    katakana-jisx0201)
 201     (iso-2022-int-1 latin-iso8859-1 greek-iso8859-7
 202                     latin-jisx0201 japanese-jisx0208-1978
 203                     chinese-gb2312 japanese-jisx0208
 204                     korean-ksc5601 japanese-jisx0212
 205                     chinese-cns11643-1 chinese-cns11643-2)
 206     (iso-2022-int-1 latin-iso8859-1 latin-iso8859-2
 207                     cyrillic-iso8859-5 greek-iso8859-7
 208                     latin-jisx0201 japanese-jisx0208-1978
 209                     chinese-gb2312 japanese-jisx0208
 210                     korean-ksc5601 japanese-jisx0212
 211                     chinese-cns11643-1 chinese-cns11643-2
 212                     chinese-cns11643-3 chinese-cns11643-4
 213                     chinese-cns11643-5 chinese-cns11643-6
 214                     chinese-cns11643-7)
 215     ,(if (or (not (fboundp 'charsetp)) ;; non-Mule case
 216              (charsetp 'unicode-a)
 217              (not (mm-coding-system-p 'mule-utf-8)))
 218          '(utf-8 unicode-a unicode-b unicode-c unicode-d unicode-e)
 219        ;; If we have utf-8 we're in Mule 5+.
 220        (append '(utf-8)
 221                (delete 'ascii
 222                        (coding-system-get 'mule-utf-8 'safe-charsets)))))
 223   "Alist of MIME-charset/MULE-charsets.")
 224
 225 ;; Correct by construction, but should be unnecessary:
 226 ;; XEmacs hates it.
 227 (when (and (not (featurep 'xemacs))
 228            (fboundp 'coding-system-list)
 229            (fboundp 'sort-coding-systems))
 230   (setq mm-mime-mule-charset-alist
 231         (apply
 232          'nconc
 233          (mapcar
 234           (lambda (cs)
 235             (when (and (coding-system-get cs 'mime-charset)
 236                        (not (eq t (coding-system-get cs 'safe-charsets))))
 237               (list (cons (coding-system-get cs 'mime-charset)
 238                           (delq 'ascii
 239                                 (coding-system-get cs 'safe-charsets))))))
 240           (sort-coding-systems (coding-system-list 'base-only))))))
 241
 242 (defvar mm-hack-charsets '(iso-8859-15 iso-2022-jp-2)
 243   "A list of special charsets.
 244 Valid elements include:
 245 `iso-8859-15'    convert ISO-8859-1, -9 to ISO-8859-15 if ISO-8859-15 exists.
 246 `iso-2022-jp-2'  convert ISO-2022-jp to ISO-2022-jp-2 if ISO-2022-jp-2 exists."
 247 )
 248
 249 (defvar mm-iso-8859-15-compatible
 250   '((iso-8859-1 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE")
 251     (iso-8859-9 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE\xD0\xDD\xDE\xF0\xFD\xFE"))
 252   "ISO-8859-15 exchangeable coding systems and inconvertible characters.")
 253
 254 (defvar mm-iso-8859-x-to-15-table
 255   (and (fboundp 'coding-system-p)
 256        (mm-coding-system-p 'iso-8859-15)
 257        (mapcar
 258         (lambda (cs)
 259           (if (mm-coding-system-p (car cs))
 260               (let ((c (string-to-char
 261                         (decode-coding-string "\341" (car cs)))))
 262                 (cons (char-charset c)
 263                       (cons
 264                        (- (string-to-char
 265                            (decode-coding-string "\341" 'iso-8859-15)) c)
 266                        (string-to-list (decode-coding-string (car (cdr cs))
 267                                                              (car cs))))))
 268             '(gnus-charset 0)))
 269         mm-iso-8859-15-compatible))
 270   "A table of the difference character between ISO-8859-X and ISO-8859-15.")
 271
 272 (defcustom mm-coding-system-priorities
 273   (if (boundp 'current-language-environment)
 274       (let ((lang (symbol-value 'current-language-environment)))
 275         (cond ((string= lang "Japanese")
 276                ;; Japanese users may prefer iso-2022-jp to shift-jis.
 277                '(iso-2022-jp iso-2022-jp-2 japanese-shift-jis
 278                              iso-latin-1 utf-8)))))
 279   "Preferred coding systems for encoding outgoing mails.
 280
 281 More than one suitable coding systems may be found for some texts.  By
 282 default, a coding system with the highest priority is used to encode
 283 outgoing mails (see `sort-coding-systems').  If this variable is set,
 284 it overrides the default priority."
 285   :type '(repeat (symbol :tag "Coding system"))
 286   :group 'mime)
 287
 288 (defvar mm-use-find-coding-systems-region
 289   (fboundp 'find-coding-systems-region)
 290   "Use `find-coding-systems-region' to find proper coding systems.
 291
 292 Setting it to nil is useful on Emacsen supporting Unicode if sending
 293 mail with multiple parts is preferred to sending a Unicode one.")
 294
 295 ;;; Internal variables:
 296
 297 ;;; Functions:
 298
 299 (defun mm-mule-charset-to-mime-charset (charset)
 300   "Return the MIME charset corresponding to the given Mule CHARSET."
 301   (if (and (fboundp 'find-coding-systems-for-charsets)
 302            (fboundp 'sort-coding-systems))
 303       (let (mime)
 304         (dolist (cs (sort-coding-systems
 305                      (copy-sequence
 306                       (find-coding-systems-for-charsets (list charset)))))
 307           (unless mime
 308             (when cs
 309               (setq mime (coding-system-get cs 'mime-charset)))))
 310         mime)
 311     (let ((alist mm-mime-mule-charset-alist)
 312           out)
 313       (while alist
 314         (when (memq charset (cdar alist))
 315           (setq out (caar alist)
 316                 alist nil))
 317         (pop alist))
 318       out)))
 319
 320 (defun mm-charset-to-coding-system (charset &optional lbt)
 321   "Return coding-system corresponding to CHARSET.
 322 CHARSET is a symbol naming a MIME charset.
 323 If optional argument LBT (`unix', `dos' or `mac') is specified, it is
 324 used as the line break code type of the coding system."
 325   (when (stringp charset)
 326     (setq charset (intern (downcase charset))))
 327   (when lbt
 328     (setq charset (intern (format "%s-%s" charset lbt))))
 329   (cond
 330    ((null charset)
 331     charset)
 332    ;; Running in a non-MULE environment.
 333    ((null (mm-get-coding-system-list))
 334     charset)
 335    ;; ascii
 336    ((eq charset 'us-ascii)
 337     'ascii)
 338    ;; Check to see whether we can handle this charset.  (This depends
 339    ;; on there being some coding system matching each `mime-charset'
 340    ;; property defined, as there should be.)
 341    ((and (mm-coding-system-p charset)
 342 ;;; Doing this would potentially weed out incorrect charsets.
 343 ;;;      charset
 344 ;;;      (eq charset (coding-system-get charset 'mime-charset))
 345          )
 346     charset)
 347    ;; Translate invalid charsets.
 348    ((let ((cs (cdr (assq charset mm-charset-synonym-alist))))
 349       (and cs (mm-coding-system-p cs) cs)))
 350    ;; Last resort: search the coding system list for entries which
 351    ;; have the right mime-charset in case the canonical name isn't
 352    ;; defined (though it should be).
 353    ((let (cs)
 354       ;; mm-get-coding-system-list returns a list of cs without lbt.
 355       ;; Do we need -lbt?
 356       (dolist (c (mm-get-coding-system-list))
 357         (if (and (null cs)
 358                  (eq charset (coding-system-get c 'mime-charset)))
 359             (setq cs c)))
 360       cs))))
 361
 362 (defsubst mm-replace-chars-in-string (string from to)
 363   (mm-subst-char-in-string from to string))
 364
 365 (eval-and-compile
 366   (defvar mm-emacs-mule (and (not (featurep 'xemacs))
 367                              (boundp 'default-enable-multibyte-characters)
 368                              default-enable-multibyte-characters
 369                              (fboundp 'set-buffer-multibyte))
 370     "Emacs mule.")
 371
 372   (defvar mm-mule4-p (and mm-emacs-mule
 373                           (fboundp 'charsetp)
 374                           (not (charsetp 'eight-bit-control)))
 375     "Mule version 4.")
 376
 377   (if mm-emacs-mule
 378       (defun mm-enable-multibyte ()
 379         "Set the multibyte flag of the current buffer.
 380 Only do this if the default value of `enable-multibyte-characters' is
 381 non-nil.  This is a no-op in XEmacs."
 382         (set-buffer-multibyte t))
 383     (defalias 'mm-enable-multibyte 'ignore))
 384
 385   (if mm-emacs-mule
 386       (defun mm-disable-multibyte ()
 387         "Unset the multibyte flag of in the current buffer.
 388 This is a no-op in XEmacs."
 389         (set-buffer-multibyte nil))
 390     (defalias 'mm-disable-multibyte 'ignore))
 391
 392   (if mm-mule4-p
 393       (defun mm-enable-multibyte-mule4  ()
 394         "Enable multibyte in the current buffer.
 395 Only used in Emacs Mule 4."
 396         (set-buffer-multibyte t))
 397     (defalias 'mm-enable-multibyte-mule4 'ignore))
 398
 399   (if mm-mule4-p
 400       (defun mm-disable-multibyte-mule4 ()
 401         "Disable multibyte in the current buffer.
 402 Only used in Emacs Mule 4."
 403         (set-buffer-multibyte nil))
 404     (defalias 'mm-disable-multibyte-mule4 'ignore)))
 405
 406 (defun mm-preferred-coding-system (charset)
 407   ;; A typo in some Emacs versions.
 408   (or (get-charset-property charset 'preferred-coding-system)
 409       (get-charset-property charset 'prefered-coding-system)))
 410
 411 (defsubst mm-guess-charset ()
 412   "Guess Mule charset from the language environment."
 413   (or
 414    mail-parse-mule-charset ;; cached mule-charset
 415    (progn
 416      (setq mail-parse-mule-charset
 417            (and (boundp 'current-language-environment)
 418                 (car (last
 419                       (assq 'charset
 420                             (assoc current-language-environment
 421                                    language-info-alist))))))
 422      (if (or (not mail-parse-mule-charset)
 423              (eq mail-parse-mule-charset 'ascii))
 424          (setq mail-parse-mule-charset
 425                (or (car (last (assq mail-parse-charset
 426                                     mm-mime-mule-charset-alist)))
 427                    ;; default
 428                    'latin-iso8859-1)))
 429      mail-parse-mule-charset)))
 430
 431 (defun mm-charset-after (&optional pos)
 432   "Return charset of a character in current buffer at position POS.
 433 If POS is nil, it defauls to the current point.
 434 If POS is out of range, the value is nil.
 435 If the charset is `composition', return the actual one."
 436   (let ((char (char-after pos)) charset)
 437     (if (< (mm-char-int char) 128)
 438         (setq charset 'ascii)
 439       ;; charset-after is fake in some Emacsen.
 440       (setq charset (and (fboundp 'char-charset) (char-charset char)))
 441       (if (eq charset 'composition)
 442           (let ((p (or pos (point))))
 443             (cadr (find-charset-region p (1+ p))))
 444         (if (and charset (not (memq charset '(ascii eight-bit-control
 445                                                     eight-bit-graphic))))
 446             charset
 447           (mm-guess-charset))))))
 448
 449 (defun mm-mime-charset (charset)
 450   "Return the MIME charset corresponding to the given Mule CHARSET."
 451   (if (eq charset 'unknown)
 452       (error "The message contains non-printable characters, please use attachment"))
 453   (if (and (fboundp 'coding-system-get) (fboundp 'get-charset-property))
 454       ;; This exists in Emacs 20.
 455       (or
 456        (and (mm-preferred-coding-system charset)
 457             (coding-system-get
 458              (mm-preferred-coding-system charset) 'mime-charset))
 459        (and (eq charset 'ascii)
 460             'us-ascii)
 461        (mm-preferred-coding-system charset)
 462        (mm-mule-charset-to-mime-charset charset))
 463     ;; This is for XEmacs.
 464     (mm-mule-charset-to-mime-charset charset)))
 465
 466 (defun mm-delete-duplicates (list)
 467   "Simple substitute for CL `delete-duplicates', testing with `equal'."
 468   (let (result head)
 469     (while list
 470       (setq head (car list))
 471       (setq list (delete head list))
 472       (setq result (cons head result)))
 473     (nreverse result)))
 474
 475 (if (and (not (featurep 'xemacs))
 476          (boundp 'enable-multibyte-characters))
 477     (defalias 'mm-multibyte-p
 478       (lambda ()
 479         "Say whether multibyte is enabled in the current buffer."
 480         enable-multibyte-characters))
 481   (defalias 'mm-multibyte-p (lambda () (featurep 'mule))))
 482
 483 (defun mm-iso-8859-x-to-15-region (&optional b e)
 484   (if (fboundp 'char-charset)
 485       (let (charset item c inconvertible)
 486         (save-restriction
 487           (if e (narrow-to-region b e))
 488           (goto-char (point-min))
 489           (skip-chars-forward "\0-\177")
 490           (while (not (eobp))
 491             (cond
 492              ((not (setq item (assq (char-charset (setq c (char-after)))
 493                                     mm-iso-8859-x-to-15-table)))
 494               (forward-char))
 495              ((memq c (cdr (cdr item)))
 496               (setq inconvertible t)
 497               (forward-char))
 498              (t
 499               (insert-before-markers (prog1 (+ c (car (cdr item)))
 500                                        (delete-char 1)))))
 501             (skip-chars-forward "\0-\177")))
 502         (not inconvertible))))
 503
 504 (defun mm-sort-coding-systems-predicate (a b)
 505   (> (length (memq a mm-coding-system-priorities))
 506      (length (memq b mm-coding-system-priorities))))
 507
 508 (defun mm-find-mime-charset-region (b e &optional hack-charsets)
 509   "Return the MIME charsets needed to encode the region between B and E.
 510 nil means ASCII, a single-element list represents an appropriate MIME
 511 charset, and a longer list means no appropriate charset."
 512   (let (charsets)
 513     ;; The return possibilities of this function are a mess...
 514     (or (and (mm-multibyte-p)
 515              mm-use-find-coding-systems-region
 516              ;; Find the mime-charset of the most preferred coding
 517              ;; system that has one.
 518              (let ((systems (find-coding-systems-region b e)))
 519                (when mm-coding-system-priorities
 520                  (setq systems
 521                        (sort systems 'mm-sort-coding-systems-predicate)))
 522                ;; Fixme: The `mime-charset' (`x-ctext') of `compound-text'
 523                ;; is not in the IANA list.
 524                (setq systems (delq 'compound-text systems))
 525                (unless (equal systems '(undecided))
 526                  (while systems
 527                    (let ((cs (coding-system-get (pop systems) 'mime-charset)))
 528                      (if cs
 529                          (setq systems nil
 530                                charsets (list cs))))))
 531                charsets))
 532         ;; Otherwise we're not multibyte, XEmacs or a single coding
 533         ;; system won't cover it.
 534         (setq charsets
 535               (mm-delete-duplicates
 536                (mapcar 'mm-mime-charset
 537                        (delq 'ascii
 538                              (mm-find-charset-region b e))))))
 539     (if (and (> (length charsets) 1)
 540              (memq 'iso-8859-15 charsets)
 541              (memq 'iso-8859-15 hack-charsets)
 542              (save-excursion (mm-iso-8859-x-to-15-region b e)))
 543         (mapcar (lambda (x) (setq charsets (delq (car x) charsets)))
 544                 mm-iso-8859-15-compatible))
 545     (if (and (memq 'iso-2022-jp-2 charsets)
 546              (memq 'iso-2022-jp-2 hack-charsets))
 547         (setq charsets (delq 'iso-2022-jp charsets)))
 548     charsets))
 549
 550 (defmacro mm-with-unibyte-buffer (&rest forms)
 551   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 552 Use unibyte mode for this."
 553   `(let (default-enable-multibyte-characters)
 554      (with-temp-buffer ,@forms)))
 555 (put 'mm-with-unibyte-buffer 'lisp-indent-function 0)
 556 (put 'mm-with-unibyte-buffer 'edebug-form-spec '(body))
 557
 558 (defmacro mm-with-unibyte-current-buffer (&rest forms)
 559   "Evaluate FORMS with current current buffer temporarily made unibyte.
 560 Also bind `default-enable-multibyte-characters' to nil.
 561 Equivalent to `progn' in XEmacs"
 562   (let ((multibyte (make-symbol "multibyte"))
 563         (buffer (make-symbol "buffer")))
 564     `(if mm-emacs-mule
 565          (let ((,multibyte enable-multibyte-characters)
 566                (,buffer (current-buffer)))
 567            (unwind-protect
 568                (let (default-enable-multibyte-characters)
 569                  (set-buffer-multibyte nil)
 570                  ,@forms)
 571              (set-buffer ,buffer)
 572              (set-buffer-multibyte ,multibyte)))
 573        (let (default-enable-multibyte-characters)
 574          ,@forms))))
 575 (put 'mm-with-unibyte-current-buffer 'lisp-indent-function 0)
 576 (put 'mm-with-unibyte-current-buffer 'edebug-form-spec '(body))
 577
 578 (defmacro mm-with-unibyte-current-buffer-mule4 (&rest forms)
 579   "Evaluate FORMS there like `progn' in current buffer.
 580 Mule4 only."
 581   (let ((multibyte (make-symbol "multibyte"))
 582         (buffer (make-symbol "buffer")))
 583     `(if mm-mule4-p
 584          (let ((,multibyte enable-multibyte-characters)
 585                (,buffer (current-buffer)))
 586            (unwind-protect
 587                (let (default-enable-multibyte-characters)
 588                  (set-buffer-multibyte nil)
 589                  ,@forms)
 590              (set-buffer ,buffer)
 591              (set-buffer-multibyte ,multibyte)))
 592        (let (default-enable-multibyte-characters)
 593          ,@forms))))
 594 (put 'mm-with-unibyte-current-buffer-mule4 'lisp-indent-function 0)
 595 (put 'mm-with-unibyte-current-buffer-mule4 'edebug-form-spec '(body))
 596
 597 (defmacro mm-with-unibyte (&rest forms)
 598   "Eval the FORMS with the default value of `enable-multibyte-characters' nil, ."
 599   `(let (default-enable-multibyte-characters)
 600      ,@forms))
 601 (put 'mm-with-unibyte 'lisp-indent-function 0)
 602 (put 'mm-with-unibyte 'edebug-form-spec '(body))
 603
 604 (defun mm-find-charset-region (b e)
 605   "Return a list of Emacs charsets in the region B to E."
 606   (cond
 607    ((and (mm-multibyte-p)
 608          (fboundp 'find-charset-region))
 609     ;; Remove composition since the base charsets have been included.
 610     ;; Remove eight-bit-*, treat them as ascii.
 611     (let ((css (find-charset-region b e)))
 612       (mapcar (lambda (cs) (setq css (delq cs css)))
 613               '(composition eight-bit-control eight-bit-graphic
 614                             control-1))
 615       css))
 616    (t
 617     ;; We are in a unibyte buffer or XEmacs non-mule, so we futz around a bit.
 618     (save-excursion
 619       (save-restriction
 620         (narrow-to-region b e)
 621         (goto-char (point-min))
 622         (skip-chars-forward "\0-\177")
 623         (if (eobp)
 624             '(ascii)
 625           (let (charset)
 626             (setq charset
 627                   (and (boundp 'current-language-environment)
 628                        (car (last (assq 'charset
 629                                         (assoc current-language-environment
 630                                                language-info-alist))))))
 631             (if (eq charset 'ascii) (setq charset nil))
 632             (or charset
 633                 (setq charset
 634                       (car (last (assq mail-parse-charset
 635                                        mm-mime-mule-charset-alist)))))
 636             (list 'ascii (or charset 'latin-iso8859-1)))))))))
 637
 638 (if (fboundp 'shell-quote-argument)
 639     (defalias 'mm-quote-arg 'shell-quote-argument)
 640   (defun mm-quote-arg (arg)
 641     "Return a version of ARG that is safe to evaluate in a shell."
 642     (let ((pos 0) new-pos accum)
 643       ;; *** bug: we don't handle newline characters properly
 644       (while (setq new-pos (string-match "[]*[;!'`\"$\\& \t{} |()<>]" arg pos))
 645         (push (substring arg pos new-pos) accum)
 646         (push "\\" accum)
 647         (push (list (aref arg new-pos)) accum)
 648         (setq pos (1+ new-pos)))
 649       (if (= pos 0)
 650           arg
 651         (apply 'concat (nconc (nreverse accum) (list (substring arg pos))))))))
 652
 653 (defun mm-auto-mode-alist ()
 654   "Return an `auto-mode-alist' with only the .gz (etc) thingies."
 655   (let ((alist auto-mode-alist)
 656         out)
 657     (while alist
 658       (when (listp (cdar alist))
 659         (push (car alist) out))
 660       (pop alist))
 661     (nreverse out)))
 662
 663 (defvar mm-inhibit-file-name-handlers
 664   '(jka-compr-handler image-file-handler)
 665   "A list of handlers doing (un)compression (etc) thingies.")
 666
 667 (defun mm-insert-file-contents (filename &optional visit beg end replace
 668                                          inhibit)
 669   "Like `insert-file-contents', q.v., but only reads in the file.
 670 A buffer may be modified in several ways after reading into the buffer due
 671 to advanced Emacs features, such as file-name-handlers, format decoding,
 672 find-file-hooks, etc.
 673 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers.
 674   This function ensures that none of these modifications will take place."
 675   (let ((format-alist nil)
 676         (auto-mode-alist (if inhibit nil (mm-auto-mode-alist)))
 677         (default-major-mode 'fundamental-mode)
 678         (enable-local-variables nil)
 679         (after-insert-file-functions nil)
 680         (enable-local-eval nil)
 681         (find-file-hooks nil)
 682         (inhibit-file-name-operation (if inhibit
 683                                          'insert-file-contents
 684                                        inhibit-file-name-operation))
 685         (inhibit-file-name-handlers
 686          (if inhibit
 687              (append mm-inhibit-file-name-handlers
 688                      inhibit-file-name-handlers)
 689            inhibit-file-name-handlers)))
 690     (insert-file-contents filename visit beg end replace)))
 691
 692 (defun mm-append-to-file (start end filename &optional codesys inhibit)
 693   "Append the contents of the region to the end of file FILENAME.
 694 When called from a function, expects three arguments,
 695 START, END and FILENAME.  START and END are buffer positions
 696 saying what text to write.
 697 Optional fourth argument specifies the coding system to use when
 698 encoding the file.
 699 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'."
 700   (let ((coding-system-for-write
 701          (or codesys mm-text-coding-system-for-write
 702              mm-text-coding-system))
 703         (inhibit-file-name-operation (if inhibit
 704                                          'append-to-file
 705                                        inhibit-file-name-operation))
 706         (inhibit-file-name-handlers
 707          (if inhibit
 708              (append mm-inhibit-file-name-handlers
 709                      inhibit-file-name-handlers)
 710            inhibit-file-name-handlers)))
 711     (append-to-file start end filename)))
 712
 713 (defun mm-write-region (start end filename &optional append visit lockname
 714                               coding-system inhibit)
 715
 716   "Like `write-region'.
 717 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'."
 718   (let ((coding-system-for-write
 719          (or coding-system mm-text-coding-system-for-write
 720              mm-text-coding-system))
 721         (inhibit-file-name-operation (if inhibit
 722                                          'write-region
 723                                        inhibit-file-name-operation))
 724         (inhibit-file-name-handlers
 725          (if inhibit
 726              (append mm-inhibit-file-name-handlers
 727                      inhibit-file-name-handlers)
 728            inhibit-file-name-handlers)))
 729     (write-region start end filename append visit lockname)))
 730
 731 (defun mm-image-load-path (&optional package)
 732   (let (dir result)
 733     (dolist (path load-path (nreverse result))
 734       (if (file-directory-p
 735            (setq dir (concat (file-name-directory
 736                               (directory-file-name path))
 737                              "etc/" (or package "gnus/"))))
 738           (push dir result))
 739       (push path result))))
 740
 741 (if (fboundp 'detect-coding-region)
 742     (defun mm-detect-coding-region (start end)
 743       "Like `detect-coding-region' except returning the best one."
 744       (let ((coding-systems
 745              (detect-coding-region (point) (point-max))))
 746         (or (car-safe coding-systems)
 747             coding-systems)))
 748   (defun mm-detect-coding-region (start end)
 749     (let ((point (point)))
 750       (goto-char start)
 751       (skip-chars-forward "\0-\177" end)
 752       (prog1
 753           (if (eq (point) end) 'ascii (mm-guess-charset))
 754         (goto-char point)))))
 755
 756 (if (fboundp 'coding-system-get)
 757     (defun mm-detect-mime-charset-region (start end)
 758       "Detect MIME charset of the text in the region between START and END."
 759       (let ((cs (mm-detect-coding-region start end)))
 760         (coding-system-get cs 'mime-charset)))
 761   (defun mm-detect-mime-charset-region (start end)
 762     "Detect MIME charset of the text in the region between START and END."
 763     (let ((cs (mm-detect-coding-region start end)))
 764       cs)))
 765
 766 (defun mm-guess-mime-charset ()
 767   "Guess the default MIME charset from the language environment."
 768   (let ((language-info
 769          (and (boundp 'current-language-environment)
 770               (assoc current-language-environment
 771                      language-info-alist)))
 772         item)
 773     (cond
 774      ((null language-info)
 775       'iso-8859-1)
 776      ((setq item
 777             (cadr
 778              (or (assq 'coding-priority language-info)
 779                  (assq 'coding-system language-info))))
 780       (if (fboundp 'coding-system-get)
 781           (or (coding-system-get item 'mime-charset)
 782               item)
 783         item))
 784      ((setq item (car (last (assq 'charset language-info))))
 785       (if (eq item 'ascii)
 786           'iso-8859-1
 787         (mm-mime-charset item)))
 788      (t
 789       'iso-8859-1))))
 790
 791 ;; It is not a MIME function, but some MIME functions use it.
 792 (defalias 'mm-make-temp-file
 793   (if (fboundp 'make-temp-file)
 794       'make-temp-file
 795     (lambda (prefix &optional dir-flag)
 796       (let ((file (expand-file-name
 797                    (make-temp-name prefix)
 798                    (if (fboundp 'temp-directory)
 799                        (temp-directory)
 800                      temporary-file-directory))))
 801         (if dir-flag
 802             (make-directory file))
 803         file))))
 804
 805 (provide 'mm-util)
 806
 807 ;;; mm-util.el ends here