cgit.sxemacs.org Git - gnus/blob - lisp/mm-util.el

   1 ;;; mm-util.el --- Utility functions for MIME things
   2 ;; Copyright (C) 1998,99 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (defvar mm-mime-mule-charset-alist
  28   '((us-ascii ascii)
  29     (iso-8859-1 latin-iso8859-1)
  30     (iso-8859-2 latin-iso8859-2)
  31     (iso-8859-3 latin-iso8859-3)
  32     (iso-8859-4 latin-iso8859-4)
  33     (iso-8859-5 cyrillic-iso8859-5)
  34     (koi8-r cyrillic-iso8859-5)
  35     (iso-8859-6 arabic-iso8859-6)
  36     (iso-8859-7 greek-iso8859-7)
  37     (iso-8859-8 hebrew-iso8859-8)
  38     (iso-8859-9 latin-iso8859-9)
  39     (viscii vietnamese-viscii-lower)
  40     (iso-2022-jp latin-jisx0201 japanese-jisx0208 japanese-jisx0208-1978)
  41     (euc-kr korean-ksc5601)
  42     (cn-gb-2312 chinese-gb2312)
  43     (cn-big5 chinese-big5-1 chinese-big5-2)
  44     (tibetan tibetan)
  45     (thai-tis620 thai-tis620)
  46     (iso-2022-7bit ethiopic arabic-1-column arabic-2-column)
  47     (iso-2022-jp-2 latin-iso8859-1 greek-iso8859-7
  48                    latin-jisx0201 japanese-jisx0208-1978
  49                    chinese-gb2312 japanese-jisx0208
  50                    korean-ksc5601 japanese-jisx0212
  51                    katakana-jisx0201)
  52     (iso-2022-int-1 latin-iso8859-1 greek-iso8859-7
  53                     latin-jisx0201 japanese-jisx0208-1978
  54                     chinese-gb2312 japanese-jisx0208
  55                     korean-ksc5601 japanese-jisx0212
  56                     chinese-cns11643-1 chinese-cns11643-2)
  57     (iso-2022-int-1 latin-iso8859-1 latin-iso8859-2
  58                     cyrillic-iso8859-5 greek-iso8859-7
  59                     latin-jisx0201 japanese-jisx0208-1978
  60                     chinese-gb2312 japanese-jisx0208
  61                     korean-ksc5601 japanese-jisx0212
  62                     chinese-cns11643-1 chinese-cns11643-2
  63                     chinese-cns11643-3 chinese-cns11643-4
  64                     chinese-cns11643-5 chinese-cns11643-6
  65                     chinese-cns11643-7))
  66   "Alist of MIME-charset/MULE-charsets.")
  67
  68
  69 (eval-and-compile
  70   (mapcar
  71    (lambda (elem)
  72      (let ((nfunc (intern (format "mm-%s" (car elem)))))
  73        (if (fboundp (car elem))
  74            (defalias nfunc (car elem))
  75          (defalias nfunc (cdr elem)))))
  76    '((decode-coding-string . (lambda (s a) s))
  77      (encode-coding-string . (lambda (s a) s))
  78      (encode-coding-region . ignore)
  79      (coding-system-list . ignore)
  80      (decode-coding-region . ignore)
  81      (char-int . identity)
  82      (device-type . ignore)
  83      (coding-system-equal . equal)
  84      (annotationp . ignore)
  85      (set-buffer-file-coding-system . ignore)
  86      (make-char
  87       . (lambda (charset int)
  88           (int-to-char int)))
  89      (read-coding-system
  90       . (lambda (prompt)
  91           "Prompt the user for a coding system."
  92           (completing-read
  93            prompt (mapcar (lambda (s) (list (symbol-name (car s))))
  94                           mm-mime-mule-charset-alist)))))))
  95
  96 (defvar mm-coding-system-list nil)
  97 (defun mm-get-coding-system-list ()
  98   "Get the coding system list."
  99   (or mm-coding-system-list
 100       (setq mm-coding-system-list (mm-coding-system-list))))
 101
 102 (defvar mm-charset-synonym-alist
 103   '((big5 . cn-big5)
 104     (gb2312 . cn-gb-2312)
 105     (x-ctext . ctext))
 106   "A mapping from invalid charset names to the real charset names.")
 107
 108 (defun mm-coding-system-p (sym)
 109   "Return non-nil if SYM is a coding system."
 110   (or (and (fboundp 'coding-system-p) (coding-system-p sym))
 111       (memq sym (mm-get-coding-system-list))))
 112
 113 (defvar mm-binary-coding-system
 114   (cond
 115    ((mm-coding-system-p 'binary) 'binary)
 116    ((mm-coding-system-p 'no-conversion) 'no-conversion)
 117    (t nil))
 118   "100% binary coding system.")
 119
 120 (defvar mm-text-coding-system
 121   (or (if (memq system-type '(windows-nt ms-dos ms-windows))
 122           (and (mm-coding-system-p 'raw-text-dos) 'raw-text-dos)
 123         (and (mm-coding-system-p 'raw-text) 'raw-text))
 124       mm-binary-coding-system)
 125   "Text-safe coding system (For removing ^M).")
 126
 127 (defvar mm-text-coding-system-for-write nil
 128   "Text coding system for write.")
 129
 130 (defvar mm-auto-save-coding-system
 131   (cond
 132    ((mm-coding-system-p 'emacs-mule)
 133     (if (memq system-type '(windows-nt ms-dos ms-windows))
 134         (if (mm-coding-system-p 'emacs-mule-dos)
 135             'emacs-mule-dos mm-binary-coding-system)
 136       'emacs-mule))
 137    ((mm-coding-system-p 'escape-quoted) 'escape-quoted)
 138    (t mm-binary-coding-system))
 139   "Coding system of auto save file.")
 140
 141 ;;; Internal variables:
 142
 143 ;;; Functions:
 144
 145 (defun mm-mule-charset-to-mime-charset (charset)
 146   "Return the MIME charset corresponding to MULE CHARSET."
 147   (let ((alist mm-mime-mule-charset-alist)
 148         out)
 149     (while alist
 150       (when (memq charset (cdar alist))
 151         (setq out (caar alist)
 152               alist nil))
 153       (pop alist))
 154     out))
 155
 156 (defun mm-charset-to-coding-system (charset &optional lbt)
 157   "Return coding-system corresponding to CHARSET.
 158 CHARSET is a symbol naming a MIME charset.
 159 If optional argument LBT (`unix', `dos' or `mac') is specified, it is
 160 used as the line break code type of the coding system."
 161   (when (stringp charset)
 162     (setq charset (intern (downcase charset))))
 163   (setq charset
 164         (or (cdr (assq charset mm-charset-synonym-alist))
 165             charset))
 166   (when lbt
 167     (setq charset (intern (format "%s-%s" charset lbt))))
 168   (cond
 169    ;; Running in a non-MULE environment.
 170    ((null (mm-get-coding-system-list))
 171     charset)
 172    ;; ascii
 173    ((eq charset 'us-ascii)
 174     'ascii)
 175    ;; Check to see whether we can handle this charset.
 176    ((memq charset (mm-get-coding-system-list))
 177     charset)
 178    ;; Nope.
 179    (t
 180     nil)))
 181
 182 (defun mm-replace-chars-in-string (string from to)
 183   "Replace characters in STRING from FROM to TO."
 184   (let ((string (substring string 0))   ;Copy string.
 185         (len (length string))
 186         (idx 0))
 187     ;; Replace all occurrences of FROM with TO.
 188     (while (< idx len)
 189       (when (= (aref string idx) from)
 190         (aset string idx to))
 191       (setq idx (1+ idx)))
 192     string))
 193
 194 (defsubst mm-enable-multibyte ()
 195   "Enable multibyte in the current buffer."
 196   (when (and (fboundp 'set-buffer-multibyte)
 197              (boundp 'enable-multibyte-characters)
 198              (default-value 'enable-multibyte-characters))
 199     (set-buffer-multibyte t)))
 200
 201 (defsubst mm-disable-multibyte ()
 202   "Disable multibyte in the current buffer."
 203   (when (fboundp 'set-buffer-multibyte)
 204     (set-buffer-multibyte nil)))
 205
 206 (defun mm-preferred-coding-system (charset)
 207   ;; A typo in some Emacs versions.
 208   (or (get-charset-property charset 'prefered-coding-system)
 209       (get-charset-property charset 'preferred-coding-system)))
 210
 211 (defun mm-mime-charset (charset)
 212   "Return the MIME charset corresponding to the MULE CHARSET."
 213   (if (fboundp 'coding-system-get)
 214       ;; This exists in Emacs 20.
 215       (or
 216        (and (mm-preferred-coding-system charset)
 217             (coding-system-get
 218              (mm-preferred-coding-system charset) 'mime-charset))
 219        (and (eq charset 'ascii)
 220             'us-ascii)
 221        (mm-preferred-coding-system charset)
 222        (mm-mule-charset-to-mime-charset charset))
 223     ;; This is for XEmacs.
 224     (mm-mule-charset-to-mime-charset charset)))
 225
 226 (defun mm-find-mime-charset-region (b e)
 227   "Return the MIME charsets needed to encode the region between B and E."
 228   (let ((charsets
 229          (delq nil (mapcar 'mm-mime-charset
 230                            (delq 'ascii
 231                                  (mm-find-charset-region b e))))))
 232     (when (memq 'iso-2022-jp-2 charsets)
 233       (setq charsets (delq 'iso-2022-jp charsets)))
 234     (delete-duplicates charsets)
 235     (if (and (> (length charsets) 1)
 236              (fboundp 'find-coding-systems-for-charsets)
 237              (memq 'utf-8 (find-coding-systems-for-charsets charsets)))
 238         '(utf-8)
 239       charsets)))
 240
 241 (defsubst mm-multibyte-p ()
 242   "Say whether multibyte is enabled."
 243   (or (string-match "XEmacs\\|Lucid" emacs-version)
 244       (and (boundp 'enable-multibyte-characters)
 245            enable-multibyte-characters)))
 246
 247 (defmacro mm-with-unibyte-buffer (&rest forms)
 248   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 249 See also `with-temp-file' and `with-output-to-string'."
 250   (let ((temp-buffer (make-symbol "temp-buffer"))
 251         (multibyte (make-symbol "multibyte")))
 252     `(if (or (string-match "XEmacs\\|Lucid" emacs-version)
 253              (not (boundp 'enable-multibyte-characters)))
 254          (with-temp-buffer ,@forms)
 255        (let ((,multibyte (default-value 'enable-multibyte-characters))
 256              ,temp-buffer)
 257          (unwind-protect
 258              (progn
 259                (setq-default enable-multibyte-characters nil)
 260                (setq ,temp-buffer
 261                      (get-buffer-create (generate-new-buffer-name " *temp*")))
 262                (unwind-protect
 263                    (with-current-buffer ,temp-buffer
 264                      (let ((buffer-file-coding-system mm-binary-coding-system)
 265                            (coding-system-for-read mm-binary-coding-system)
 266                            (coding-system-for-write mm-binary-coding-system))
 267                        ,@forms))
 268                  (and (buffer-name ,temp-buffer)
 269                       (kill-buffer ,temp-buffer))))
 270            (setq-default enable-multibyte-characters ,multibyte))))))
 271 (put 'mm-with-unibyte-buffer 'lisp-indent-function 0)
 272 (put 'mm-with-unibyte-buffer 'edebug-form-spec '(body))
 273
 274 (defmacro mm-with-unibyte-current-buffer (&rest forms)
 275   "Evaluate FORMS there like `progn' in current buffer."
 276   (let ((multibyte (make-symbol "multibyte")))
 277     `(if (or (string-match "XEmacs\\|Lucid" emacs-version)
 278              (not (fboundp 'set-buffer-multibyte)))
 279          (progn
 280            ,@forms)
 281        (let ((,multibyte (default-value 'enable-multibyte-characters)))
 282          (unwind-protect
 283              (let ((buffer-file-coding-system mm-binary-coding-system)
 284                    (coding-system-for-read mm-binary-coding-system)
 285                    (coding-system-for-write mm-binary-coding-system))
 286                (set-buffer-multibyte nil)
 287                ,@forms)
 288            (set-buffer-multibyte ,multibyte))))))
 289 (put 'mm-with-unibyte-current-buffer 'lisp-indent-function 0)
 290 (put 'mm-with-unibyte-current-buffer 'edebug-form-spec '(body))
 291
 292 (defun mm-find-charset-region (b e)
 293   "Return a list of charsets in the region."
 294   (cond
 295    ((and (mm-multibyte-p)
 296          (fboundp 'find-charset-region))
 297     (find-charset-region b e))
 298    ((not (boundp 'current-language-environment))
 299     (save-excursion
 300       (save-restriction
 301         (narrow-to-region b e)
 302         (goto-char (point-min))
 303         (skip-chars-forward "\0-\177")
 304         (if (eobp)
 305             '(ascii)
 306           (delq nil (list 'ascii mail-parse-charset))))))
 307    (t
 308     ;; We are in a unibyte buffer, so we futz around a bit.
 309     (save-excursion
 310       (save-restriction
 311         (narrow-to-region b e)
 312         (goto-char (point-min))
 313         (let ((entry (assoc current-language-environment
 314                             language-info-alist)))
 315           (skip-chars-forward "\0-\177")
 316           (if (eobp)
 317               '(ascii)
 318             (delq nil (list 'ascii (car (last (assq 'charset entry))))))))))))
 319
 320 (defun mm-read-charset (prompt)
 321   "Return a charset."
 322   (intern
 323    (completing-read
 324     prompt
 325     (mapcar (lambda (e) (list (symbol-name (car e))))
 326             mm-mime-mule-charset-alist)
 327     nil t)))
 328
 329 (defun mm-quote-arg (arg)
 330   "Return a version of ARG that is safe to evaluate in a shell."
 331   (let ((pos 0) new-pos accum)
 332     ;; *** bug: we don't handle newline characters properly
 333     (while (setq new-pos (string-match "[]*[;!'`\"$\\& \t{} |()<>]" arg pos))
 334       (push (substring arg pos new-pos) accum)
 335       (push "\\" accum)
 336       (push (list (aref arg new-pos)) accum)
 337       (setq pos (1+ new-pos)))
 338     (if (= pos 0)
 339         arg
 340       (apply 'concat (nconc (nreverse accum) (list (substring arg pos)))))))
 341
 342 (defun mm-auto-mode-alist ()
 343   "Return an `auto-mode-alist' with only the .gz (etc) thingies."
 344   (let ((alist auto-mode-alist)
 345         out)
 346     (while alist
 347       (when (listp (cdar alist))
 348         (push (car alist) out))
 349       (pop alist))
 350     (nreverse out)))
 351
 352 (defvar mm-inhibit-file-name-handlers
 353   '(jka-compr-handler)
 354   "A list of handlers doing (un)compression (etc) thingies.")
 355
 356 (defun mm-insert-file-contents (filename &optional visit beg end replace
 357                                          inhibit)
 358   "Like `insert-file-contents', q.v., but only reads in the file.
 359 A buffer may be modified in several ways after reading into the buffer due
 360 to advanced Emacs features, such as file-name-handlers, format decoding,
 361 find-file-hooks, etc.
 362 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers.
 363   This function ensures that none of these modifications will take place."
 364   (let ((format-alist nil)
 365         (auto-mode-alist (if inhibit nil (mm-auto-mode-alist)))
 366         (default-major-mode 'fundamental-mode)
 367         (enable-local-variables nil)
 368         (after-insert-file-functions nil)
 369         (enable-local-eval nil)
 370         (find-file-hooks nil)
 371         (inhibit-file-name-operation (if inhibit
 372                                          'insert-file-contents
 373                                        inhibit-file-name-operation))
 374         (inhibit-file-name-handlers
 375          (if inhibit
 376              (append mm-inhibit-file-name-handlers
 377                      inhibit-file-name-handlers)
 378            inhibit-file-name-handlers)))
 379     (insert-file-contents filename visit beg end replace)))
 380
 381 (defun mm-append-to-file (start end filename &optional codesys inhibit)
 382   "Append the contents of the region to the end of file FILENAME.
 383 When called from a function, expects three arguments,
 384 START, END and FILENAME.  START and END are buffer positions
 385 saying what text to write.
 386 Optional fourth argument specifies the coding system to use when
 387 encoding the file.
 388 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers."
 389   (let ((coding-system-for-write
 390          (or codesys mm-text-coding-system-for-write
 391              mm-text-coding-system))
 392         (inhibit-file-name-operation (if inhibit
 393                                          'append-to-file
 394                                        inhibit-file-name-operation))
 395         (inhibit-file-name-handlers
 396          (if inhibit
 397              (append mm-inhibit-file-name-handlers
 398                      inhibit-file-name-handlers)
 399            inhibit-file-name-handlers)))
 400     (append-to-file start end filename)))
 401
 402 (defun mm-write-region (start end filename &optional append visit lockname
 403                               coding-system inhibit)
 404
 405   "Like `write-region'.
 406 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers."
 407   (let ((coding-system-for-write
 408          (or coding-system mm-text-coding-system-for-write
 409              mm-text-coding-system))
 410         (inhibit-file-name-operation (if inhibit
 411                                          'write-region
 412                                        inhibit-file-name-operation))
 413         (inhibit-file-name-handlers
 414          (if inhibit
 415              (append mm-inhibit-file-name-handlers
 416                      inhibit-file-name-handlers)
 417            inhibit-file-name-handlers)))
 418     (write-region start end filename append visit lockname)))
 419
 420 (provide 'mm-util)
 421
 422 ;;; mm-util.el ends here