cgit.sxemacs.org Git - gnus/blob - lisp/mm-util.el

   1 ;;; mm-util.el --- Utility functions for MIME things
   2 ;; Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'mail-prsvr)
  28
  29 (defvar mm-mime-mule-charset-alist
  30   '((us-ascii ascii)
  31     (iso-8859-1 latin-iso8859-1)
  32     (iso-8859-2 latin-iso8859-2)
  33     (iso-8859-3 latin-iso8859-3)
  34     (iso-8859-4 latin-iso8859-4)
  35     (iso-8859-5 cyrillic-iso8859-5)
  36     ;; Non-mule (X)Emacs uses the last mule-charset for 8bit characters.
  37     ;; The fake mule-charset, gnus-koi8-r, tells Gnus that the default
  38     ;; charset is koi8-r, not iso-8859-5.
  39     (koi8-r cyrillic-iso8859-5 gnus-koi8-r)
  40     (iso-8859-6 arabic-iso8859-6)
  41     (iso-8859-7 greek-iso8859-7)
  42     (iso-8859-8 hebrew-iso8859-8)
  43     (iso-8859-9 latin-iso8859-9)
  44     (viscii vietnamese-viscii-lower)
  45     (iso-2022-jp latin-jisx0201 japanese-jisx0208 japanese-jisx0208-1978)
  46     (euc-kr korean-ksc5601)
  47     (cn-gb-2312 chinese-gb2312)
  48     (cn-big5 chinese-big5-1 chinese-big5-2)
  49     (tibetan tibetan)
  50     (thai-tis620 thai-tis620)
  51     (iso-2022-7bit ethiopic arabic-1-column arabic-2-column)
  52     (iso-2022-jp-2 latin-iso8859-1 greek-iso8859-7
  53                    latin-jisx0201 japanese-jisx0208-1978
  54                    chinese-gb2312 japanese-jisx0208
  55                    korean-ksc5601 japanese-jisx0212
  56                    katakana-jisx0201)
  57     (iso-2022-int-1 latin-iso8859-1 greek-iso8859-7
  58                     latin-jisx0201 japanese-jisx0208-1978
  59                     chinese-gb2312 japanese-jisx0208
  60                     korean-ksc5601 japanese-jisx0212
  61                     chinese-cns11643-1 chinese-cns11643-2)
  62     (iso-2022-int-1 latin-iso8859-1 latin-iso8859-2
  63                     cyrillic-iso8859-5 greek-iso8859-7
  64                     latin-jisx0201 japanese-jisx0208-1978
  65                     chinese-gb2312 japanese-jisx0208
  66                     korean-ksc5601 japanese-jisx0212
  67                     chinese-cns11643-1 chinese-cns11643-2
  68                     chinese-cns11643-3 chinese-cns11643-4
  69                     chinese-cns11643-5 chinese-cns11643-6
  70                     chinese-cns11643-7)
  71     (utf-8 unicode-a unicode-b unicode-c unicode-d unicode-e))
  72   "Alist of MIME-charset/MULE-charsets.")
  73
  74 (eval-and-compile
  75   (mapcar
  76    (lambda (elem)
  77      (let ((nfunc (intern (format "mm-%s" (car elem)))))
  78        (if (fboundp (car elem))
  79            (defalias nfunc (car elem))
  80          (defalias nfunc (cdr elem)))))
  81    '((decode-coding-string . (lambda (s a) s))
  82      (encode-coding-string . (lambda (s a) s))
  83      (encode-coding-region . ignore)
  84      (coding-system-list . ignore)
  85      (decode-coding-region . ignore)
  86      (char-int . identity)
  87      (device-type . ignore)
  88      (coding-system-equal . equal)
  89      (annotationp . ignore)
  90      (set-buffer-file-coding-system . ignore)
  91      (make-char
  92       . (lambda (charset int)
  93           (int-to-char int)))
  94      (read-coding-system
  95       . (lambda (prompt)
  96           "Prompt the user for a coding system."
  97           (completing-read
  98            prompt (mapcar (lambda (s) (list (symbol-name (car s))))
  99                           mm-mime-mule-charset-alist)))))))
 100
 101 (eval-and-compile
 102   (defalias 'mm-char-or-char-int-p
 103     (cond
 104      ((fboundp 'char-or-char-int-p) 'char-or-char-int-p)
 105      ((fboundp 'char-valid-p) 'char-valid-p)
 106      (t 'identity))))
 107
 108 (defvar mm-coding-system-list nil)
 109 (defun mm-get-coding-system-list ()
 110   "Get the coding system list."
 111   (or mm-coding-system-list
 112       (setq mm-coding-system-list (mm-coding-system-list))))
 113
 114 (defvar mm-charset-synonym-alist
 115   '((big5 . cn-big5)
 116     (gb2312 . cn-gb-2312)
 117     (x-ctext . ctext))
 118   "A mapping from invalid charset names to the real charset names.")
 119
 120 (defun mm-coding-system-p (sym)
 121   "Return non-nil if SYM is a coding system."
 122   (or (and (fboundp 'coding-system-p) (coding-system-p sym))
 123       (memq sym (mm-get-coding-system-list))))
 124
 125 (defvar mm-binary-coding-system
 126   (cond
 127    ((mm-coding-system-p 'binary) 'binary)
 128    ((mm-coding-system-p 'no-conversion) 'no-conversion)
 129    (t nil))
 130   "100% binary coding system.")
 131
 132 (defvar mm-text-coding-system
 133   (or (if (memq system-type '(windows-nt ms-dos ms-windows))
 134           (and (mm-coding-system-p 'raw-text-dos) 'raw-text-dos)
 135         (and (mm-coding-system-p 'raw-text) 'raw-text))
 136       mm-binary-coding-system)
 137   "Text-safe coding system (For removing ^M).")
 138
 139 (defvar mm-text-coding-system-for-write nil
 140   "Text coding system for write.")
 141
 142 (defvar mm-auto-save-coding-system
 143   (cond
 144    ((mm-coding-system-p 'emacs-mule)
 145     (if (memq system-type '(windows-nt ms-dos ms-windows))
 146         (if (mm-coding-system-p 'emacs-mule-dos)
 147             'emacs-mule-dos mm-binary-coding-system)
 148       'emacs-mule))
 149    ((mm-coding-system-p 'escape-quoted) 'escape-quoted)
 150    (t mm-binary-coding-system))
 151   "Coding system of auto save file.")
 152
 153 ;;; Internal variables:
 154
 155 ;;; Functions:
 156
 157 (defun mm-mule-charset-to-mime-charset (charset)
 158   "Return the MIME charset corresponding to MULE CHARSET."
 159   (let ((alist mm-mime-mule-charset-alist)
 160         out)
 161     (while alist
 162       (when (memq charset (cdar alist))
 163         (setq out (caar alist)
 164               alist nil))
 165       (pop alist))
 166     out))
 167
 168 (defun mm-charset-to-coding-system (charset &optional lbt)
 169   "Return coding-system corresponding to CHARSET.
 170 CHARSET is a symbol naming a MIME charset.
 171 If optional argument LBT (`unix', `dos' or `mac') is specified, it is
 172 used as the line break code type of the coding system."
 173   (when (stringp charset)
 174     (setq charset (intern (downcase charset))))
 175   (setq charset
 176         (or (cdr (assq charset mm-charset-synonym-alist))
 177             charset))
 178   (when lbt
 179     (setq charset (intern (format "%s-%s" charset lbt))))
 180   (cond
 181    ;; Running in a non-MULE environment.
 182    ((null (mm-get-coding-system-list))
 183     charset)
 184    ;; ascii
 185    ((eq charset 'us-ascii)
 186     'ascii)
 187    ;; Check to see whether we can handle this charset.
 188    ((memq charset (mm-get-coding-system-list))
 189     charset)
 190    ;; Nope.
 191    (t
 192     nil)))
 193
 194 (defun mm-replace-chars-in-string (string from to)
 195   "Replace characters in STRING from FROM to TO."
 196   (let ((string (substring string 0))   ;Copy string.
 197         (len (length string))
 198         (idx 0))
 199     ;; Replace all occurrences of FROM with TO.
 200     (while (< idx len)
 201       (when (= (aref string idx) from)
 202         (aset string idx to))
 203       (setq idx (1+ idx)))
 204     string))
 205
 206 (defsubst mm-enable-multibyte ()
 207   "Enable multibyte in the current buffer."
 208   (when (and (fboundp 'set-buffer-multibyte)
 209              (boundp 'enable-multibyte-characters)
 210              (default-value 'enable-multibyte-characters))
 211     (set-buffer-multibyte t)))
 212
 213 (defsubst mm-disable-multibyte ()
 214   "Disable multibyte in the current buffer."
 215   (when (fboundp 'set-buffer-multibyte)
 216     (set-buffer-multibyte nil)))
 217
 218 (defun mm-preferred-coding-system (charset)
 219   ;; A typo in some Emacs versions.
 220   (or (get-charset-property charset 'prefered-coding-system)
 221       (get-charset-property charset 'preferred-coding-system)))
 222
 223 (defun mm-charset-after (&optional pos)
 224   "Return charset of a character in current buffer at position POS.
 225 If POS is nil, it defauls to the current point.
 226 If POS is out of range, the value is nil.
 227 If the charset is `composition', return the actual one."
 228   (let ((charset (cond
 229                   ((fboundp 'charset-after)
 230                    (charset-after pos))
 231                   ((fboundp 'char-charset)
 232                    (char-charset (char-after pos)))
 233                   ((< (mm-char-int (char-after pos)) 128)
 234                    'ascii)
 235                   (mail-parse-mule-charset ;; cached mule-charset
 236                    mail-parse-mule-charset)
 237                   ((boundp 'current-language-environment)
 238                    (let ((entry (assoc current-language-environment
 239                                        language-info-alist)))
 240                      (setq mail-parse-mule-charset
 241                            (or (car (last (assq 'charset entry)))
 242                                'latin-iso8859-1))))
 243                   (t                       ;; figure out the charset
 244                    (setq mail-parse-mule-charset
 245                          (or (car (last (assq mail-parse-charset
 246                                               mm-mime-mule-charset-alist)))
 247                              'latin-iso8859-1))))))
 248     (if (eq charset 'composition)
 249         (let ((p (or pos (point))))
 250           (cadr (find-charset-region p (1+ p))))
 251       charset)))
 252
 253 (defun mm-mime-charset (charset)
 254   "Return the MIME charset corresponding to the MULE CHARSET."
 255   (if (and (fboundp 'coding-system-get) (fboundp 'get-charset-property))
 256       ;; This exists in Emacs 20.
 257       (or
 258        (and (mm-preferred-coding-system charset)
 259             (coding-system-get
 260              (mm-preferred-coding-system charset) 'mime-charset))
 261        (and (eq charset 'ascii)
 262             'us-ascii)
 263        (mm-preferred-coding-system charset)
 264        (mm-mule-charset-to-mime-charset charset))
 265     ;; This is for XEmacs.
 266     (mm-mule-charset-to-mime-charset charset)))
 267
 268 (defun mm-delete-duplicates (list)
 269   "Simple  substitute for CL `delete-duplicates', testing with `equal'."
 270   (let (result head)
 271     (while list
 272       (setq head (car list))
 273       (setq list (delete head list))
 274       (setq result (cons head result)))
 275     (nreverse result)))
 276
 277 (defun mm-find-mime-charset-region (b e)
 278   "Return the MIME charsets needed to encode the region between B and E."
 279   (let ((charsets (mapcar 'mm-mime-charset
 280                           (delq 'ascii
 281                                 (mm-find-charset-region b e)))))
 282     (when (memq 'iso-2022-jp-2 charsets)
 283       (setq charsets (delq 'iso-2022-jp charsets)))
 284     (setq charsets (mm-delete-duplicates charsets))
 285     (if (and (> (length charsets) 1)
 286              (fboundp 'find-coding-systems-region)
 287              (memq 'utf-8 (find-coding-systems-region b e)))
 288         '(utf-8)
 289       charsets)))
 290
 291 (defsubst mm-multibyte-p ()
 292   "Say whether multibyte is enabled."
 293   (or (string-match "XEmacs\\|Lucid" emacs-version)
 294       (and (boundp 'enable-multibyte-characters)
 295            enable-multibyte-characters)))
 296
 297 (defmacro mm-with-unibyte-buffer (&rest forms)
 298   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 299 See also `with-temp-file' and `with-output-to-string'."
 300   (let ((temp-buffer (make-symbol "temp-buffer"))
 301         (multibyte (make-symbol "multibyte")))
 302     `(if (or (string-match "XEmacs\\|Lucid" emacs-version)
 303              (not (boundp 'enable-multibyte-characters)))
 304          (with-temp-buffer ,@forms)
 305        (let ((,multibyte (default-value 'enable-multibyte-characters))
 306              ,temp-buffer)
 307          (unwind-protect
 308              (progn
 309                (setq-default enable-multibyte-characters nil)
 310                (setq ,temp-buffer
 311                      (get-buffer-create (generate-new-buffer-name " *temp*")))
 312                (unwind-protect
 313                    (with-current-buffer ,temp-buffer
 314                      (let ((buffer-file-coding-system mm-binary-coding-system)
 315                            (coding-system-for-read mm-binary-coding-system)
 316                            (coding-system-for-write mm-binary-coding-system))
 317                        ,@forms))
 318                  (and (buffer-name ,temp-buffer)
 319                       (kill-buffer ,temp-buffer))))
 320            (setq-default enable-multibyte-characters ,multibyte))))))
 321 (put 'mm-with-unibyte-buffer 'lisp-indent-function 0)
 322 (put 'mm-with-unibyte-buffer 'edebug-form-spec '(body))
 323
 324 (defmacro mm-with-unibyte-current-buffer (&rest forms)
 325   "Evaluate FORMS there like `progn' in current buffer."
 326   (let ((multibyte (make-symbol "multibyte")))
 327     `(if (or (string-match "XEmacs\\|Lucid" emacs-version)
 328              (not (fboundp 'set-buffer-multibyte)))
 329          (progn
 330            ,@forms)
 331        (let ((,multibyte (default-value 'enable-multibyte-characters)))
 332          (unwind-protect
 333              (let ((buffer-file-coding-system mm-binary-coding-system)
 334                    (coding-system-for-read mm-binary-coding-system)
 335                    (coding-system-for-write mm-binary-coding-system))
 336                (set-buffer-multibyte nil)
 337                (setq-default enable-multibyte-characters nil)
 338                ,@forms)
 339            (setq-default enable-multibyte-characters ,multibyte)
 340            (set-buffer-multibyte ,multibyte))))))
 341 (put 'mm-with-unibyte-current-buffer 'lisp-indent-function 0)
 342 (put 'mm-with-unibyte-current-buffer 'edebug-form-spec '(body))
 343
 344 (defmacro mm-with-unibyte (&rest forms)
 345   "Set default `enable-multibyte-characters' to `nil', eval the FORMS."
 346   (let ((multibyte (make-symbol "multibyte")))
 347     `(if (or (string-match "XEmacs\\|Lucid" emacs-version)
 348              (not (boundp 'enable-multibyte-characters)))
 349          (progn ,@forms)
 350        (let ((,multibyte (default-value 'enable-multibyte-characters)))
 351          (unwind-protect
 352              (progn
 353                (setq-default enable-multibyte-characters nil)
 354                ,@forms)
 355            (setq-default enable-multibyte-characters ,multibyte))))))
 356 (put 'mm-with-unibyte 'lisp-indent-function 0)
 357 (put 'mm-with-unibyte 'edebug-form-spec '(body))
 358
 359 (defun mm-find-charset-region (b e)
 360   "Return a list of charsets in the region."
 361   (cond
 362    ((and (mm-multibyte-p)
 363          (fboundp 'find-charset-region))
 364     ;; Remove composition since the base charsets have been included.
 365     (delq 'composition (find-charset-region b e)))
 366    ((not (boundp 'current-language-environment))
 367     (save-excursion
 368       (save-restriction
 369         (narrow-to-region b e)
 370         (goto-char (point-min))
 371         (skip-chars-forward "\0-\177")
 372         (if (eobp)
 373             '(ascii)
 374           (delq nil (list 'ascii
 375                           (or (car (last (assq mail-parse-charset
 376                                                mm-mime-mule-charset-alist)))
 377                               'latin-iso8859-1)))))))
 378    (t
 379     ;; We are in a unibyte buffer, so we futz around a bit.
 380     (save-excursion
 381       (save-restriction
 382         (narrow-to-region b e)
 383         (goto-char (point-min))
 384         (let ((entry (assoc current-language-environment
 385                             language-info-alist)))
 386           (skip-chars-forward "\0-\177")
 387           (if (eobp)
 388               '(ascii)
 389             (delq nil (list 'ascii
 390                             (or (car (last (assq 'charset entry)))
 391                                 'latin-iso8859-1))))))))))
 392
 393 (defun mm-read-charset (prompt)
 394   "Return a charset."
 395   (intern
 396    (completing-read
 397     prompt
 398     (mapcar (lambda (e) (list (symbol-name (car e))))
 399             mm-mime-mule-charset-alist)
 400     nil t)))
 401
 402 (defun mm-quote-arg (arg)
 403   "Return a version of ARG that is safe to evaluate in a shell."
 404   (let ((pos 0) new-pos accum)
 405     ;; *** bug: we don't handle newline characters properly
 406     (while (setq new-pos (string-match "[]*[;!'`\"$\\& \t{} |()<>]" arg pos))
 407       (push (substring arg pos new-pos) accum)
 408       (push "\\" accum)
 409       (push (list (aref arg new-pos)) accum)
 410       (setq pos (1+ new-pos)))
 411     (if (= pos 0)
 412         arg
 413       (apply 'concat (nconc (nreverse accum) (list (substring arg pos)))))))
 414
 415 (defun mm-auto-mode-alist ()
 416   "Return an `auto-mode-alist' with only the .gz (etc) thingies."
 417   (let ((alist auto-mode-alist)
 418         out)
 419     (while alist
 420       (when (listp (cdar alist))
 421         (push (car alist) out))
 422       (pop alist))
 423     (nreverse out)))
 424
 425 (defvar mm-inhibit-file-name-handlers
 426   '(jka-compr-handler)
 427   "A list of handlers doing (un)compression (etc) thingies.")
 428
 429 (defun mm-insert-file-contents (filename &optional visit beg end replace
 430                                          inhibit)
 431   "Like `insert-file-contents', q.v., but only reads in the file.
 432 A buffer may be modified in several ways after reading into the buffer due
 433 to advanced Emacs features, such as file-name-handlers, format decoding,
 434 find-file-hooks, etc.
 435 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers.
 436   This function ensures that none of these modifications will take place."
 437   (let ((format-alist nil)
 438         (auto-mode-alist (if inhibit nil (mm-auto-mode-alist)))
 439         (default-major-mode 'fundamental-mode)
 440         (enable-local-variables nil)
 441         (after-insert-file-functions nil)
 442         (enable-local-eval nil)
 443         (find-file-hooks nil)
 444         (inhibit-file-name-operation (if inhibit
 445                                          'insert-file-contents
 446                                        inhibit-file-name-operation))
 447         (inhibit-file-name-handlers
 448          (if inhibit
 449              (append mm-inhibit-file-name-handlers
 450                      inhibit-file-name-handlers)
 451            inhibit-file-name-handlers)))
 452     (insert-file-contents filename visit beg end replace)))
 453
 454 (defun mm-append-to-file (start end filename &optional codesys inhibit)
 455   "Append the contents of the region to the end of file FILENAME.
 456 When called from a function, expects three arguments,
 457 START, END and FILENAME.  START and END are buffer positions
 458 saying what text to write.
 459 Optional fourth argument specifies the coding system to use when
 460 encoding the file.
 461 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers."
 462   (let ((coding-system-for-write
 463          (or codesys mm-text-coding-system-for-write
 464              mm-text-coding-system))
 465         (inhibit-file-name-operation (if inhibit
 466                                          'append-to-file
 467                                        inhibit-file-name-operation))
 468         (inhibit-file-name-handlers
 469          (if inhibit
 470              (append mm-inhibit-file-name-handlers
 471                      inhibit-file-name-handlers)
 472            inhibit-file-name-handlers)))
 473     (append-to-file start end filename)))
 474
 475 (defun mm-write-region (start end filename &optional append visit lockname
 476                               coding-system inhibit)
 477
 478   "Like `write-region'.
 479 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers."
 480   (let ((coding-system-for-write
 481          (or coding-system mm-text-coding-system-for-write
 482              mm-text-coding-system))
 483         (inhibit-file-name-operation (if inhibit
 484                                          'write-region
 485                                        inhibit-file-name-operation))
 486         (inhibit-file-name-handlers
 487          (if inhibit
 488              (append mm-inhibit-file-name-handlers
 489                      inhibit-file-name-handlers)
 490            inhibit-file-name-handlers)))
 491     (write-region start end filename append visit lockname)))
 492
 493 (provide 'mm-util)
 494
 495 ;;; mm-util.el ends here