cgit.sxemacs.org Git - gnus/blob - lisp/mm-decode.el

   1 ;;; mm-decode.el --- Functions for decoding MIME things
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002,
   3 ;;        2003 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'mail-parse)
  29 (require 'mailcap)
  30 (require 'mm-bodies)
  31 (eval-when-compile (require 'cl)
  32                    (require 'term))
  33
  34 (eval-and-compile
  35   (autoload 'executable-find "executable")
  36   (autoload 'mm-inline-partial "mm-partial")
  37   (autoload 'mm-inline-external-body "mm-extern")
  38   (autoload 'mm-insert-inline "mm-view"))
  39
  40 (add-hook 'gnus-exit-gnus-hook 'mm-destroy-postponed-undisplay-list)
  41
  42 (defgroup mime-display ()
  43   "Display of MIME in mail and news articles."
  44   :link '(custom-manual "(emacs-mime)Customization")
  45   :version "21.1"
  46   :group 'mail
  47   :group 'news
  48   :group 'multimedia)
  49
  50 (defgroup mime-security ()
  51   "MIME security in mail and news articles."
  52   :link '(custom-manual "(emacs-mime)Customization")
  53   :group 'mail
  54   :group 'news
  55   :group 'multimedia)
  56
  57 ;;; Convenience macros.
  58
  59 (defmacro mm-handle-buffer (handle)
  60   `(nth 0 ,handle))
  61 (defmacro mm-handle-type (handle)
  62   `(nth 1 ,handle))
  63 (defsubst mm-handle-media-type (handle)
  64   (if (stringp (car handle))
  65       (car handle)
  66     (car (mm-handle-type handle))))
  67 (defsubst mm-handle-media-supertype (handle)
  68   (car (split-string (mm-handle-media-type handle) "/")))
  69 (defsubst mm-handle-media-subtype (handle)
  70   (cadr (split-string (mm-handle-media-type handle) "/")))
  71 (defmacro mm-handle-encoding (handle)
  72   `(nth 2 ,handle))
  73 (defmacro mm-handle-undisplayer (handle)
  74   `(nth 3 ,handle))
  75 (defmacro mm-handle-set-undisplayer (handle function)
  76   `(setcar (nthcdr 3 ,handle) ,function))
  77 (defmacro mm-handle-disposition (handle)
  78   `(nth 4 ,handle))
  79 (defmacro mm-handle-description (handle)
  80   `(nth 5 ,handle))
  81 (defmacro mm-handle-cache (handle)
  82   `(nth 6 ,handle))
  83 (defmacro mm-handle-set-cache (handle contents)
  84   `(setcar (nthcdr 6 ,handle) ,contents))
  85 (defmacro mm-handle-id (handle)
  86   `(nth 7 ,handle))
  87 (defmacro mm-handle-multipart-original-buffer (handle)
  88   `(get-text-property 0 'buffer (car ,handle)))
  89 (defmacro mm-handle-multipart-from (handle)
  90   `(get-text-property 0 'from (car ,handle)))
  91 (defmacro mm-handle-multipart-ctl-parameter (handle parameter)
  92   `(get-text-property 0 ,parameter (car ,handle)))
  93
  94 (defmacro mm-make-handle (&optional buffer type encoding undisplayer
  95                                     disposition description cache
  96                                     id)
  97   `(list ,buffer ,type ,encoding ,undisplayer
  98          ,disposition ,description ,cache ,id))
  99
 100 (defcustom mm-text-html-renderer
 101   (cond ((locate-library "w3") 'w3)
 102         ((locate-library "w3m") 'w3m)
 103         ((executable-find "links") 'links)
 104         ((executable-find "lynx") 'lynx)
 105         (t 'html2text))
 106   "Render of HTML contents.
 107 It is one of defined renderer types, or a rendering function.
 108 The defined renderer types are:
 109 `w3'   : using Emacs/W3;
 110 `w3m'  : using emacs-w3m;
 111 `links': using links;
 112 `lynx' : using lynx;
 113 `html2text' : using html2text;
 114 nil    : using external viewer."
 115   :type '(choice (const w3)
 116                  (const w3m)
 117                  (const links)
 118                  (const lynx)
 119                  (const html2text)
 120                  (const nil)
 121                  (function))
 122   :version "21.3"
 123   :group 'mime-display)
 124
 125 (defvar mm-inline-text-html-renderer nil
 126   "Function used for rendering inline HTML contents.
 127 It is suggested to customize `mm-text-html-renderer' instead.")
 128
 129 (defcustom mm-inline-text-html-with-images nil
 130   "If non-nil, Gnus will allow retrieving images in the HTML contents
 131 with <img> tags.  It has no effect on Emacs/w3.  See also
 132 the documentation for the option `mm-w3m-safe-url-regexp'."
 133   :type 'boolean
 134   :group 'mime-display)
 135
 136 (defcustom mm-w3m-safe-url-regexp "\\`cid:"
 137   "Regexp that matches safe url names.
 138 Some HTML mails might have a trick of spammers using <img> tags.
 139 It is likely to be intended to verify whether you have read the
 140 mail.  You can prevent your personal informations from leaking by
 141 setting this to the regexp which matches the safe url names.  The
 142 value of the variable `w3m-safe-url-regexp' will be bound with
 143 this value.  You may set this value to nil if you consider all
 144 urls to be safe."
 145   :type '(choice (regexp :tag "Regexp")
 146                  (const :tag "All URLs are safe" nil))
 147   :group 'mime-display)
 148
 149 (defcustom mm-inline-text-html-with-w3m-keymap t
 150   "If non-nil, use emacs-w3m command keys in the article buffer."
 151   :type 'boolean
 152   :group 'mime-display)
 153
 154 (defcustom mm-inline-media-tests
 155   '(("image/jpeg"
 156      mm-inline-image
 157      (lambda (handle)
 158        (mm-valid-and-fit-image-p 'jpeg handle)))
 159     ("image/png"
 160      mm-inline-image
 161      (lambda (handle)
 162        (mm-valid-and-fit-image-p 'png handle)))
 163     ("image/gif"
 164      mm-inline-image
 165      (lambda (handle)
 166        (mm-valid-and-fit-image-p 'gif handle)))
 167     ("image/tiff"
 168      mm-inline-image
 169      (lambda (handle)
 170        (mm-valid-and-fit-image-p 'tiff handle)) )
 171     ("image/xbm"
 172      mm-inline-image
 173      (lambda (handle)
 174        (mm-valid-and-fit-image-p 'xbm handle)))
 175     ("image/x-xbitmap"
 176      mm-inline-image
 177      (lambda (handle)
 178        (mm-valid-and-fit-image-p 'xbm handle)))
 179     ("image/xpm"
 180      mm-inline-image
 181      (lambda (handle)
 182        (mm-valid-and-fit-image-p 'xpm handle)))
 183     ("image/x-xpixmap"
 184      mm-inline-image
 185      (lambda (handle)
 186        (mm-valid-and-fit-image-p 'xpm handle)))
 187     ("image/bmp"
 188      mm-inline-image
 189      (lambda (handle)
 190        (mm-valid-and-fit-image-p 'bmp handle)))
 191     ("image/x-portable-bitmap"
 192      mm-inline-image
 193      (lambda (handle)
 194        (mm-valid-and-fit-image-p 'pbm handle)))
 195     ("text/plain" mm-inline-text identity)
 196     ("text/enriched" mm-inline-text identity)
 197     ("text/richtext" mm-inline-text identity)
 198     ("text/x-patch" mm-display-patch-inline
 199      (lambda (handle)
 200        (locate-library "diff-mode")))
 201     ("application/emacs-lisp" mm-display-elisp-inline identity)
 202     ("application/x-emacs-lisp" mm-display-elisp-inline identity)
 203     ("text/html"
 204      mm-inline-text-html
 205      (lambda (handle)
 206        (or mm-inline-text-html-renderer
 207            mm-text-html-renderer)))
 208     ("text/x-vcard"
 209      mm-inline-text-vcard
 210      (lambda (handle)
 211        (or (featurep 'vcard)
 212            (locate-library "vcard"))))
 213     ("message/delivery-status" mm-inline-text identity)
 214     ("message/rfc822" mm-inline-message identity)
 215     ("message/partial" mm-inline-partial identity)
 216     ("message/external-body" mm-inline-external-body identity)
 217     ("text/.*" mm-inline-text identity)
 218     ("audio/wav" mm-inline-audio
 219      (lambda (handle)
 220        (and (or (featurep 'nas-sound) (featurep 'native-sound))
 221             (device-sound-enabled-p))))
 222     ("audio/au"
 223      mm-inline-audio
 224      (lambda (handle)
 225        (and (or (featurep 'nas-sound) (featurep 'native-sound))
 226             (device-sound-enabled-p))))
 227     ("application/pgp-signature" ignore identity)
 228     ("application/x-pkcs7-signature" ignore identity)
 229     ("application/pkcs7-signature" ignore identity)
 230     ("application/x-pkcs7-mime" ignore identity)
 231     ("application/pkcs7-mime" ignore identity)
 232     ("multipart/alternative" ignore identity)
 233     ("multipart/mixed" ignore identity)
 234     ("multipart/related" ignore identity)
 235     ;; Disable audio and image
 236     ("audio/.*" ignore ignore)
 237     ("image/.*" ignore ignore)
 238     ;; Default to displaying as text
 239     (".*" mm-inline-text mm-readable-p))
 240   "Alist of media types/tests saying whether types can be displayed inline."
 241   :type '(repeat (list (string :tag "MIME type")
 242                        (function :tag "Display function")
 243                        (function :tag "Display test")))
 244   :group 'mime-display)
 245
 246 (defcustom mm-inlined-types
 247   '("image/.*" "text/.*" "message/delivery-status" "message/rfc822"
 248     "message/partial" "message/external-body" "application/emacs-lisp"
 249     "application/x-emacs-lisp"
 250     "application/pgp-signature" "application/x-pkcs7-signature"
 251     "application/pkcs7-signature" "application/x-pkcs7-mime"
 252     "application/pkcs7-mime")
 253   "List of media types that are to be displayed inline.
 254 See also `mm-inline-media-tests', which says how to display a media
 255 type inline."
 256   :type '(repeat string)
 257   :group 'mime-display)
 258
 259 (defcustom mm-keep-viewer-alive-types
 260   '("application/postscript" "application/msword" "application/vnd.ms-excel"
 261     "application/pdf" "application/x-dvi")
 262   "List of media types for which the external viewer will not be killed
 263 when selecting a different article."
 264   :type '(repeat string)
 265   :group 'mime-display)
 266
 267 (defcustom mm-automatic-display
 268   '("text/plain" "text/enriched" "text/richtext" "text/html"
 269     "text/x-vcard" "image/.*" "message/delivery-status" "multipart/.*"
 270     "message/rfc822" "text/x-patch" "application/pgp-signature"
 271     "application/emacs-lisp" "application/x-emacs-lisp"
 272     "application/x-pkcs7-signature"
 273     "application/pkcs7-signature" "application/x-pkcs7-mime"
 274     "application/pkcs7-mime")
 275   "A list of MIME types to be displayed automatically."
 276   :type '(repeat string)
 277   :group 'mime-display)
 278
 279 (defcustom mm-attachment-override-types '("text/x-vcard"
 280                                           "application/pkcs7-mime"
 281                                           "application/x-pkcs7-mime"
 282                                           "application/pkcs7-signature"
 283                                           "application/x-pkcs7-signature")
 284   "Types to have \"attachment\" ignored if they can be displayed inline."
 285   :type '(repeat string)
 286   :group 'mime-display)
 287
 288 (defcustom mm-inline-override-types nil
 289   "Types to be treated as attachments even if they can be displayed inline."
 290   :type '(repeat string)
 291   :group 'mime-display)
 292
 293 (defcustom mm-automatic-external-display nil
 294   "List of MIME type regexps that will be displayed externally automatically."
 295   :type '(repeat string)
 296   :group 'mime-display)
 297
 298 (defcustom mm-discouraged-alternatives nil
 299   "List of MIME types that are discouraged when viewing multipart/alternative.
 300 Viewing agents are supposed to view the last possible part of a message,
 301 as that is supposed to be the richest.  However, users may prefer other
 302 types instead, and this list says what types are most unwanted.  If,
 303 for instance, text/html parts are very unwanted, and text/richtext are
 304 somewhat unwanted, then the value of this variable should be set
 305 to:
 306
 307  (\"text/html\" \"text/richtext\")"
 308   :type '(repeat string)
 309   :group 'mime-display)
 310
 311 (defcustom mm-tmp-directory
 312   (if (fboundp 'temp-directory)
 313       (temp-directory)
 314     (if (boundp 'temporary-file-directory)
 315         temporary-file-directory
 316       "/tmp/"))
 317   "Where mm will store its temporary files."
 318   :type 'directory
 319   :group 'mime-display)
 320
 321 (defcustom mm-inline-large-images nil
 322   "If non-nil, then all images fit in the buffer."
 323   :type 'boolean
 324   :group 'mime-display)
 325
 326 (defvar mm-file-name-rewrite-functions nil
 327   "*List of functions used for rewriting file names of MIME parts.
 328 Each function takes a file name as input and returns a file name.
 329
 330 Ready-made functions include
 331 `mm-file-name-delete-whitespace',
 332 `mm-file-name-trim-whitespace',
 333 `mm-file-name-collapse-whitespace',
 334 `mm-file-name-replace-whitespace',
 335 `capitalize', `downcase', `upcase', and
 336 `upcase-initials'.")
 337
 338 (defvar mm-path-name-rewrite-functions nil
 339   "*List of functions for rewriting the full file names of MIME parts.
 340 This is used when viewing parts externally, and is meant for
 341 transforming the absolute name so that non-compliant programs can find
 342 the file where it's saved.
 343
 344 Each function takes a file name as input and returns a file name.")
 345
 346 (defvar mm-file-name-replace-whitespace nil
 347   "String used for replacing whitespace characters; default is `\"_\"'.")
 348
 349 (defcustom mm-default-directory nil
 350   "The default directory where mm will save files.
 351 If not set, `default-directory' will be used."
 352   :type '(choice directory (const :tag "Default" nil))
 353   :group 'mime-display)
 354
 355 (defcustom mm-external-terminal-program "xterm"
 356   "The program to start an external terminal."
 357   :type 'string
 358   :group 'mime-display)
 359
 360 ;;; Internal variables.
 361
 362 (defvar mm-last-shell-command "")
 363 (defvar mm-content-id-alist nil)
 364 (defvar mm-postponed-undisplay-list nil)
 365
 366 ;; According to RFC2046, in particular, in a digest, the default
 367 ;; Content-Type value for a body part is changed from "text/plain" to
 368 ;; "message/rfc822".
 369 (defvar mm-dissect-default-type "text/plain")
 370
 371 (autoload 'mml2015-verify "mml2015")
 372 (autoload 'mml2015-verify-test "mml2015")
 373 (autoload 'mml-smime-verify "mml-smime")
 374 (autoload 'mml-smime-verify-test "mml-smime")
 375
 376 (defvar mm-verify-function-alist
 377   '(("application/pgp-signature" mml2015-verify "PGP" mml2015-verify-test)
 378     ("application/x-gnus-pgp-signature" mm-uu-pgp-signed-extract-1 "PGP"
 379      mm-uu-pgp-signed-test)
 380     ("application/pkcs7-signature" mml-smime-verify "S/MIME"
 381      mml-smime-verify-test)
 382     ("application/x-pkcs7-signature" mml-smime-verify "S/MIME"
 383      mml-smime-verify-test)))
 384
 385 (defcustom mm-verify-option 'never
 386   "Option of verifying signed parts.
 387 `never', not verify; `always', always verify;
 388 `known', only verify known protocols.  Otherwise, ask user."
 389   :type '(choice (item always)
 390                  (item never)
 391                  (item :tag "only known protocols" known)
 392                  (item :tag "ask" nil))
 393   :group 'mime-security)
 394
 395 (autoload 'mml2015-decrypt "mml2015")
 396 (autoload 'mml2015-decrypt-test "mml2015")
 397
 398 (defvar mm-decrypt-function-alist
 399   '(("application/pgp-encrypted" mml2015-decrypt "PGP" mml2015-decrypt-test)
 400     ("application/x-gnus-pgp-encrypted" mm-uu-pgp-encrypted-extract-1 "PGP"
 401      mm-uu-pgp-encrypted-test)))
 402
 403 (defcustom mm-decrypt-option nil
 404   "Option of decrypting encrypted parts.
 405 `never', not decrypt; `always', always decrypt;
 406 `known', only decrypt known protocols.  Otherwise, ask user."
 407   :type '(choice (item always)
 408                  (item never)
 409                  (item :tag "only known protocols" known)
 410                  (item :tag "ask" nil))
 411   :group 'mime-security)
 412
 413 (defvar mm-viewer-completion-map
 414   (let ((map (make-sparse-keymap 'mm-viewer-completion-map)))
 415     (set-keymap-parent map minibuffer-local-completion-map)
 416     map)
 417   "Keymap for input viewer with completion.")
 418
 419 ;; Should we bind other key to minibuffer-complete-word?
 420 (define-key mm-viewer-completion-map " " 'self-insert-command)
 421
 422 (defvar mm-viewer-completion-map
 423   (let ((map (make-sparse-keymap 'mm-viewer-completion-map)))
 424     (set-keymap-parent map minibuffer-local-completion-map)
 425     map)
 426   "Keymap for input viewer with completion.")
 427
 428 ;; Should we bind other key to minibuffer-complete-word?
 429 (define-key mm-viewer-completion-map " " 'self-insert-command)
 430
 431 ;;; The functions.
 432
 433 (defun mm-alist-to-plist (alist)
 434   "Convert association list ALIST into the equivalent property-list form.
 435 The plist is returned.  This converts from
 436
 437 \((a . 1) (b . 2) (c . 3))
 438
 439 into
 440
 441 \(a 1 b 2 c 3)
 442
 443 The original alist is not modified.  See also `destructive-alist-to-plist'."
 444   (let (plist)
 445     (while alist
 446       (let ((el (car alist)))
 447         (setq plist (cons (cdr el) (cons (car el) plist))))
 448       (setq alist (cdr alist)))
 449     (nreverse plist)))
 450
 451 (defun mm-keep-viewer-alive-p (handle)
 452   "Say whether external viewer for HANDLE should stay alive."
 453   (let ((types mm-keep-viewer-alive-types)
 454         (type (mm-handle-media-type handle))
 455         ty)
 456     (catch 'found
 457       (while (setq ty (pop types))
 458         (when (string-match ty type)
 459           (throw 'found t))))))
 460
 461 (defun mm-handle-set-external-undisplayer (handle function)
 462   "Set the undisplayer for HANDLE to FUNCTION.
 463 Postpone undisplaying of viewers for types in
 464 `mm-keep-viewer-alive-types'."
 465   (if (mm-keep-viewer-alive-p handle)
 466       (let ((new-handle (copy-sequence handle)))
 467         (mm-handle-set-undisplayer new-handle function)
 468         (mm-handle-set-undisplayer handle nil)
 469         (push new-handle mm-postponed-undisplay-list))
 470     (mm-handle-set-undisplayer handle function)))
 471
 472 (defun mm-destroy-postponed-undisplay-list ()
 473   (when mm-postponed-undisplay-list
 474     (message "Destroying external MIME viewers")
 475     (mm-destroy-parts mm-postponed-undisplay-list)))
 476
 477 (defun mm-dissect-buffer (&optional no-strict-mime loose-mime)
 478   "Dissect the current buffer and return a list of MIME handles."
 479   (save-excursion
 480     (let (ct ctl type subtype cte cd description id result from)
 481       (save-restriction
 482         (mail-narrow-to-head)
 483         (when (or no-strict-mime
 484                   loose-mime
 485                   (mail-fetch-field "mime-version"))
 486           (setq ct (mail-fetch-field "content-type")
 487                 ctl (ignore-errors (mail-header-parse-content-type ct))
 488                 cte (mail-fetch-field "content-transfer-encoding")
 489                 cd (mail-fetch-field "content-disposition")
 490                 description (mail-fetch-field "content-description")
 491                 from (mail-fetch-field "from")
 492                 id (mail-fetch-field "content-id"))
 493           ;; FIXME: In some circumstances, this code is running within
 494           ;; an unibyte macro.  mail-extract-address-components
 495           ;; creates unibyte buffers. This `if', though not a perfect
 496           ;; solution, avoids most of them.
 497           (if from
 498               (setq from (cadr (mail-extract-address-components from))))))
 499       (when cte
 500         (setq cte (mail-header-strip cte)))
 501       (if (or (not ctl)
 502               (not (string-match "/" (car ctl))))
 503           (mm-dissect-singlepart
 504            (list mm-dissect-default-type)
 505            (and cte (intern (downcase (mail-header-remove-whitespace
 506                                        (mail-header-remove-comments
 507                                         cte)))))
 508            no-strict-mime
 509            (and cd (ignore-errors (mail-header-parse-content-disposition cd)))
 510            description)
 511         (setq type (split-string (car ctl) "/"))
 512         (setq subtype (cadr type)
 513               type (pop type))
 514         (setq
 515          result
 516          (cond
 517           ((equal type "multipart")
 518            (let ((mm-dissect-default-type (if (equal subtype "digest")
 519                                               "message/rfc822"
 520                                             "text/plain")))
 521              (add-text-properties 0 (length (car ctl))
 522                                   (mm-alist-to-plist (cdr ctl)) (car ctl))
 523
 524              ;; what really needs to be done here is a way to link a
 525              ;; MIME handle back to it's parent MIME handle (in a multilevel
 526              ;; MIME article).  That would probably require changing
 527              ;; the mm-handle API so we simply store the multipart buffert
 528              ;; name as a text property of the "multipart/whatever" string.
 529              (add-text-properties 0 (length (car ctl))
 530                                   (list 'buffer (mm-copy-to-buffer))
 531                                   (car ctl))
 532              (add-text-properties 0 (length (car ctl))
 533                                   (list 'from from)
 534                                   (car ctl))
 535              (cons (car ctl) (mm-dissect-multipart ctl))))
 536           (t
 537            (mm-possibly-verify-or-decrypt
 538             (mm-dissect-singlepart
 539              ctl
 540              (and cte (intern (downcase (mail-header-remove-whitespace
 541                                          (mail-header-remove-comments
 542                                           cte)))))
 543              no-strict-mime
 544              (and cd (ignore-errors
 545                        (mail-header-parse-content-disposition cd)))
 546              description id)
 547             ctl))))
 548         (when id
 549           (when (string-match " *<\\(.*\\)> *" id)
 550             (setq id (match-string 1 id)))
 551           (push (cons id result) mm-content-id-alist))
 552         result))))
 553
 554 (defun mm-dissect-singlepart (ctl cte &optional force cdl description id)
 555   (when (or force
 556             (if (equal "text/plain" (car ctl))
 557                 (assoc 'format ctl)
 558               t))
 559     (mm-make-handle
 560      (mm-copy-to-buffer) ctl cte nil cdl description nil id)))
 561
 562 (defun mm-dissect-multipart (ctl)
 563   (goto-char (point-min))
 564   (let* ((boundary (concat "\n--" (mail-content-type-get ctl 'boundary)))
 565          (close-delimiter (concat (regexp-quote boundary) "--[ \t]*$"))
 566          start parts
 567          (end (save-excursion
 568                 (goto-char (point-max))
 569                 (if (re-search-backward close-delimiter nil t)
 570                     (match-beginning 0)
 571                   (point-max)))))
 572     (setq boundary (concat (regexp-quote boundary) "[ \t]*$"))
 573     (while (and (< (point) end) (re-search-forward boundary end t))
 574       (goto-char (match-beginning 0))
 575       (when start
 576         (save-excursion
 577           (save-restriction
 578             (narrow-to-region start (point))
 579             (setq parts (nconc (list (mm-dissect-buffer t)) parts)))))
 580       (end-of-line 2)
 581       (or (looking-at boundary)
 582           (forward-line 1))
 583       (setq start (point)))
 584     (when (and start (< start end))
 585       (save-excursion
 586         (save-restriction
 587           (narrow-to-region start end)
 588           (setq parts (nconc (list (mm-dissect-buffer t)) parts)))))
 589     (mm-possibly-verify-or-decrypt (nreverse parts) ctl)))
 590
 591 (defun mm-copy-to-buffer ()
 592   "Copy the contents of the current buffer to a fresh buffer."
 593   (save-excursion
 594     (let ((obuf (current-buffer))
 595           beg)
 596       (goto-char (point-min))
 597       (search-forward-regexp "^\n" nil t)
 598       (setq beg (point))
 599       (set-buffer (generate-new-buffer " *mm*"))
 600       (insert-buffer-substring obuf beg)
 601       (current-buffer))))
 602
 603 (defun mm-display-parts (handle &optional no-default)
 604   (if (stringp (car handle))
 605       (mapcar 'mm-display-parts (cdr handle))
 606     (if (bufferp (car handle))
 607         (save-restriction
 608           (narrow-to-region (point) (point))
 609           (mm-display-part handle)
 610           (goto-char (point-max)))
 611       (mapcar 'mm-display-parts handle))))
 612
 613 (defun mm-display-part (handle &optional no-default)
 614   "Display the MIME part represented by HANDLE.
 615 Returns nil if the part is removed; inline if displayed inline;
 616 external if displayed external."
 617   (save-excursion
 618     (mailcap-parse-mailcaps)
 619     (if (mm-handle-displayed-p handle)
 620         (mm-remove-part handle)
 621       (let* ((type (mm-handle-media-type handle))
 622              (method (mailcap-mime-info type)))
 623         (if (and (mm-inlinable-p handle)
 624                  (mm-inlined-p handle))
 625             (progn
 626               (forward-line 1)
 627               (mm-display-inline handle)
 628               'inline)
 629           (when (or method
 630                     (not no-default))
 631             (if (and (not method)
 632                      (equal "text" (car (split-string type))))
 633                 (progn
 634                   (forward-line 1)
 635                   (mm-insert-inline handle (mm-get-part handle))
 636                   'inline)
 637               (mm-display-external
 638                handle (or method 'mailcap-save-binary-file)))))))))
 639
 640 (defun mm-display-external (handle method)
 641   "Display HANDLE using METHOD."
 642   (let ((outbuf (current-buffer)))
 643     (mm-with-unibyte-buffer
 644       (if (functionp method)
 645           (let ((cur (current-buffer)))
 646             (if (eq method 'mailcap-save-binary-file)
 647                 (progn
 648                   (set-buffer (generate-new-buffer " *mm*"))
 649                   (setq method nil))
 650               (mm-insert-part handle)
 651               (let ((win (get-buffer-window cur t)))
 652                 (when win
 653                   (select-window win)))
 654               (switch-to-buffer (generate-new-buffer " *mm*")))
 655             (buffer-disable-undo)
 656             (mm-set-buffer-file-coding-system mm-binary-coding-system)
 657             (insert-buffer-substring cur)
 658             (goto-char (point-min))
 659             (message "Viewing with %s" method)
 660             (let ((mm (current-buffer))
 661                   (non-viewer (assq 'non-viewer
 662                                     (mailcap-mime-info
 663                                      (mm-handle-media-type handle) t))))
 664               (unwind-protect
 665                   (if method
 666                       (funcall method)
 667                     (mm-save-part handle))
 668                 (when (and (not non-viewer)
 669                            method)
 670                   (mm-handle-set-undisplayer handle mm)))))
 671         ;; The function is a string to be executed.
 672         (mm-insert-part handle)
 673         (let* ((dir (mm-make-temp-file
 674                      (expand-file-name "emm." mm-tmp-directory) 'dir))
 675                (filename (or
 676                           (mail-content-type-get
 677                            (mm-handle-disposition handle) 'filename)
 678                           (mail-content-type-get
 679                            (mm-handle-type handle) 'name)))
 680                (mime-info (mailcap-mime-info
 681                            (mm-handle-media-type handle) t))
 682                (needsterm (or (assoc "needsterm" mime-info)
 683                               (assoc "needsterminal" mime-info)))
 684                (copiousoutput (assoc "copiousoutput" mime-info))
 685                file buffer)
 686           ;; We create a private sub-directory where we store our files.
 687           (set-file-modes dir 448)
 688           (if filename
 689               (setq file (expand-file-name
 690                           (gnus-map-function mm-file-name-rewrite-functions
 691                                              (file-name-nondirectory filename))
 692                           dir))
 693             (setq file (mm-make-temp-file (expand-file-name "mm." dir))))
 694           (let ((coding-system-for-write mm-binary-coding-system))
 695             (write-region (point-min) (point-max) file nil 'nomesg))
 696           (message "Viewing with %s" method)
 697           (cond
 698            (needsterm
 699             (let ((command (mm-mailcap-command
 700                             method file (mm-handle-type handle))))
 701               (unwind-protect
 702                   (if window-system
 703                       (start-process "*display*" nil
 704                                      mm-external-terminal-program
 705                                      "-e" shell-file-name
 706                                      shell-command-switch command)
 707                     (require 'term)
 708                     (require 'gnus-win)
 709                     (set-buffer
 710                      (setq buffer
 711                            (make-term "display"
 712                                       shell-file-name
 713                                       nil
 714                                       shell-command-switch command)))
 715                     (term-mode)
 716                     (term-char-mode)
 717                     (set-process-sentinel
 718                      (get-buffer-process buffer)
 719                      `(lambda (process state)
 720                         (if (eq 'exit (process-status process))
 721                             (gnus-configure-windows
 722                              ',gnus-current-window-configuration))))
 723                     (gnus-configure-windows 'display-term))
 724                 (mm-handle-set-external-undisplayer handle (cons file buffer)))
 725               (message "Displaying %s..." command))
 726             'external)
 727            (copiousoutput
 728             (with-current-buffer outbuf
 729               (forward-line 1)
 730               (mm-insert-inline
 731                handle
 732                (unwind-protect
 733                    (progn
 734                      (call-process shell-file-name nil
 735                                    (setq buffer
 736                                          (generate-new-buffer " *mm*"))
 737                                    nil
 738                                    shell-command-switch
 739                                    (mm-mailcap-command
 740                                     method file (mm-handle-type handle)))
 741                      (if (buffer-live-p buffer)
 742                          (save-excursion
 743                            (set-buffer buffer)
 744                            (buffer-string))))
 745                  (progn
 746                    (ignore-errors (delete-file file))
 747                    (ignore-errors (delete-directory
 748                                    (file-name-directory file)))
 749                    (ignore-errors (kill-buffer buffer))))))
 750             'inline)
 751            (t
 752             (let ((command (mm-mailcap-command
 753                             method file (mm-handle-type handle))))
 754               (unwind-protect
 755                   (start-process "*display*"
 756                                  (setq buffer
 757                                        (generate-new-buffer " *mm*"))
 758                                  shell-file-name
 759                                  shell-command-switch command)
 760                 (mm-handle-set-external-undisplayer
 761                  handle (cons file buffer)))
 762               (message "Displaying %s..." command))
 763             'external)))))))
 764
 765 (defun mm-mailcap-command (method file type-list)
 766   (let ((ctl (cdr type-list))
 767         (beg 0)
 768         (uses-stdin t)
 769         out sub total)
 770     (while (string-match "%{\\([^}]+\\)}\\|'%s'\\|\"%s\"\\|%s\\|%t\\|%%"
 771                          method beg)
 772       (push (substring method beg (match-beginning 0)) out)
 773       (setq beg (match-end 0)
 774             total (match-string 0 method)
 775             sub (match-string 1 method))
 776       (cond
 777        ((string= total "%%")
 778         (push "%" out))
 779        ((or (string= total "%s")
 780             ;; We do our own quoting.
 781             (string= total "'%s'")
 782             (string= total "\"%s\""))
 783         (setq uses-stdin nil)
 784         (push (mm-quote-arg
 785                (gnus-map-function mm-path-name-rewrite-functions file)) out))
 786        ((string= total "%t")
 787         (push (mm-quote-arg (car type-list)) out))
 788        (t
 789         (push (mm-quote-arg (or (cdr (assq (intern sub) ctl)) "")) out))))
 790     (push (substring method beg (length method)) out)
 791     (when uses-stdin
 792       (push "<" out)
 793       (push (mm-quote-arg
 794              (gnus-map-function mm-path-name-rewrite-functions file))
 795             out))
 796     (mapconcat 'identity (nreverse out) "")))
 797
 798 (defun mm-remove-parts (handles)
 799   "Remove the displayed MIME parts represented by HANDLES."
 800   (if (and (listp handles)
 801            (bufferp (car handles)))
 802       (mm-remove-part handles)
 803     (let (handle)
 804       (while (setq handle (pop handles))
 805         (cond
 806          ((stringp handle)
 807           (when (buffer-live-p (get-text-property 0 'buffer handle))
 808             (kill-buffer (get-text-property 0 'buffer handle))))
 809          ((and (listp handle)
 810                (stringp (car handle)))
 811           (mm-remove-parts (cdr handle)))
 812          (t
 813           (mm-remove-part handle)))))))
 814
 815 (defun mm-destroy-parts (handles)
 816   "Remove the displayed MIME parts represented by HANDLES."
 817   (if (and (listp handles)
 818            (bufferp (car handles)))
 819       (mm-destroy-part handles)
 820     (let (handle)
 821       (while (setq handle (pop handles))
 822         (cond
 823          ((stringp handle)
 824           (when (buffer-live-p (get-text-property 0 'buffer handle))
 825             (kill-buffer (get-text-property 0 'buffer handle))))
 826          ((and (listp handle)
 827                (stringp (car handle)))
 828           (mm-destroy-parts handle))
 829          (t
 830           (mm-destroy-part handle)))))))
 831
 832 (defun mm-remove-part (handle)
 833   "Remove the displayed MIME part represented by HANDLE."
 834   (when (listp handle)
 835     (let ((object (mm-handle-undisplayer handle)))
 836       (ignore-errors
 837         (cond
 838          ;; Internally displayed part.
 839          ((mm-annotationp object)
 840           (delete-annotation object))
 841          ((or (functionp object)
 842               (and (listp object)
 843                    (eq (car object) 'lambda)))
 844           (funcall object))
 845          ;; Externally displayed part.
 846          ((consp object)
 847           (condition-case ()
 848               (while (get-buffer-process (cdr object))
 849                 (interrupt-process (get-buffer-process (cdr object)))
 850                 (message "Waiting for external displayer to die...")
 851                 (sit-for 1))
 852             (quit)
 853             (error))
 854           (ignore-errors (and (cdr object) (kill-buffer (cdr object))))
 855           (message "Waiting for external displayer to die...done")
 856           (ignore-errors (delete-file (car object)))
 857           (ignore-errors (delete-directory (file-name-directory
 858                                             (car object)))))
 859          ((bufferp object)
 860           (when (buffer-live-p object)
 861             (kill-buffer object)))))
 862       (mm-handle-set-undisplayer handle nil))))
 863
 864 (defun mm-display-inline (handle)
 865   (let* ((type (mm-handle-media-type handle))
 866          (function (cadr (mm-assoc-string-match mm-inline-media-tests type))))
 867     (funcall function handle)
 868     (goto-char (point-min))))
 869
 870 (defun mm-assoc-string-match (alist type)
 871   (dolist (elem alist)
 872     (when (string-match (car elem) type)
 873       (return elem))))
 874
 875 (defun mm-automatic-display-p (handle)
 876   "Say whether the user wants HANDLE to be displayed automatically."
 877   (let ((methods mm-automatic-display)
 878         (type (mm-handle-media-type handle))
 879         method result)
 880     (while (setq method (pop methods))
 881       (when (and (not (mm-inline-override-p handle))
 882                  (string-match method type))
 883         (setq result t
 884               methods nil)))
 885     result))
 886
 887 (defun mm-inlinable-p (handle)
 888   "Say whether HANDLE can be displayed inline."
 889   (let ((alist mm-inline-media-tests)
 890         (type (mm-handle-media-type handle))
 891         test)
 892     (while alist
 893       (when (string-match (caar alist) type)
 894         (setq test (caddar alist)
 895               alist nil)
 896         (setq test (funcall test handle)))
 897       (pop alist))
 898     test))
 899
 900 (defun mm-inlined-p (handle)
 901   "Say whether the user wants HANDLE to be displayed inline."
 902   (let ((methods mm-inlined-types)
 903         (type (mm-handle-media-type handle))
 904         method result)
 905     (while (setq method (pop methods))
 906       (when (and (not (mm-inline-override-p handle))
 907                  (string-match method type))
 908         (setq result t
 909               methods nil)))
 910     result))
 911
 912 (defun mm-attachment-override-p (handle)
 913   "Say whether HANDLE should have attachment behavior overridden."
 914   (let ((types mm-attachment-override-types)
 915         (type (mm-handle-media-type handle))
 916         ty)
 917     (catch 'found
 918       (while (setq ty (pop types))
 919         (when (and (string-match ty type)
 920                    (mm-inlinable-p handle))
 921           (throw 'found t))))))
 922
 923 (defun mm-inline-override-p (handle)
 924   "Say whether HANDLE should have inline behavior overridden."
 925   (let ((types mm-inline-override-types)
 926         (type (mm-handle-media-type handle))
 927         ty)
 928     (catch 'found
 929       (while (setq ty (pop types))
 930         (when (string-match ty type)
 931           (throw 'found t))))))
 932
 933 (defun mm-automatic-external-display-p (type)
 934   "Return the user-defined method for TYPE."
 935   (let ((methods mm-automatic-external-display)
 936         method result)
 937     (while (setq method (pop methods))
 938       (when (string-match method type)
 939         (setq result t
 940               methods nil)))
 941     result))
 942
 943 (defun mm-destroy-part (handle)
 944   "Destroy the data structures connected to HANDLE."
 945   (when (listp handle)
 946     (mm-remove-part handle)
 947     (when (buffer-live-p (mm-handle-buffer handle))
 948       (kill-buffer (mm-handle-buffer handle)))))
 949
 950 (defun mm-handle-displayed-p (handle)
 951   "Say whether HANDLE is displayed or not."
 952   (mm-handle-undisplayer handle))
 953
 954 ;;;
 955 ;;; Functions for outputting parts
 956 ;;;
 957
 958 (defun mm-get-part (handle)
 959   "Return the contents of HANDLE as a string."
 960   (mm-with-unibyte-buffer
 961     (insert (with-current-buffer (mm-handle-buffer handle)
 962               (mm-with-unibyte-current-buffer
 963                 (buffer-string))))
 964     (mm-decode-content-transfer-encoding
 965      (mm-handle-encoding handle)
 966      (mm-handle-media-type handle))
 967     (buffer-string)))
 968
 969 (defun mm-insert-part (handle)
 970   "Insert the contents of HANDLE in the current buffer."
 971   (let ((cur (current-buffer)))
 972     (save-excursion
 973       (if (member (mm-handle-media-supertype handle) '("text" "message"))
 974           (with-temp-buffer
 975             (insert-buffer-substring (mm-handle-buffer handle))
 976             (prog1
 977                 (mm-decode-content-transfer-encoding
 978                  (mm-handle-encoding handle)
 979                  (mm-handle-media-type handle))
 980               (let ((temp (current-buffer)))
 981                 (set-buffer cur)
 982                 (insert-buffer-substring temp))))
 983         (mm-with-unibyte-buffer
 984           (insert-buffer-substring (mm-handle-buffer handle))
 985           (prog1
 986               (mm-decode-content-transfer-encoding
 987                (mm-handle-encoding handle)
 988                (mm-handle-media-type handle))
 989             (let ((temp (current-buffer)))
 990               (set-buffer cur)
 991               (insert-buffer-substring temp))))))))
 992
 993 (defun mm-file-name-delete-whitespace (file-name)
 994   "Remove all whitespace characters from FILE-NAME."
 995   (while (string-match "\\s-+" file-name)
 996     (setq file-name (replace-match "" t t file-name)))
 997   file-name)
 998
 999 (defun mm-file-name-trim-whitespace (file-name)
1000   "Remove leading and trailing whitespace characters from FILE-NAME."
1001   (when (string-match "\\`\\s-+" file-name)
1002     (setq file-name (substring file-name (match-end 0))))
1003   (when (string-match "\\s-+\\'" file-name)
1004     (setq file-name (substring file-name 0 (match-beginning 0))))
1005   file-name)
1006
1007 (defun mm-file-name-collapse-whitespace (file-name)
1008   "Collapse multiple whitespace characters in FILE-NAME."
1009   (while (string-match "\\s-\\s-+" file-name)
1010     (setq file-name (replace-match " " t t file-name)))
1011   file-name)
1012
1013 (defun mm-file-name-replace-whitespace (file-name)
1014   "Replace whitespace characters in FILE-NAME with underscores.
1015 Set the option `mm-file-name-replace-whitespace' to any other
1016 string if you do not like underscores."
1017   (let ((s (or mm-file-name-replace-whitespace "_")))
1018     (while (string-match "\\s-" file-name)
1019       (setq file-name (replace-match s t t file-name))))
1020   file-name)
1021
1022 (defun mm-save-part (handle)
1023   "Write HANDLE to a file."
1024   (let* ((name (mail-content-type-get (mm-handle-type handle) 'name))
1025          (filename (mail-content-type-get
1026                     (mm-handle-disposition handle) 'filename))
1027          file)
1028     (when filename
1029       (setq filename (gnus-map-function mm-file-name-rewrite-functions
1030                                         (file-name-nondirectory filename))))
1031     (setq file
1032           (read-file-name "Save MIME part to: "
1033                           (or mm-default-directory default-directory)
1034                           nil nil (or filename name "")))
1035     (setq mm-default-directory (file-name-directory file))
1036     (and (or (not (file-exists-p file))
1037              (yes-or-no-p (format "File %s already exists; overwrite? "
1038                                   file)))
1039          (progn
1040            (mm-save-part-to-file handle file)
1041            file))))
1042
1043 (defun mm-save-part-to-file (handle file)
1044   (mm-with-unibyte-buffer
1045     (mm-insert-part handle)
1046     (let ((coding-system-for-write 'binary)
1047           ;; Don't re-compress .gz & al.  Arguably we should make
1048           ;; `file-name-handler-alist' nil, but that would chop
1049           ;; ange-ftp, which is reasonable to use here.
1050           (inhibit-file-name-operation 'write-region)
1051           (inhibit-file-name-handlers
1052            (cons 'jka-compr-handler inhibit-file-name-handlers)))
1053       (write-region (point-min) (point-max) file))))
1054
1055 (defun mm-pipe-part (handle)
1056   "Pipe HANDLE to a process."
1057   (let* ((name (mail-content-type-get (mm-handle-type handle) 'name))
1058          (command
1059           (read-string "Shell command on MIME part: " mm-last-shell-command)))
1060     (mm-with-unibyte-buffer
1061       (mm-insert-part handle)
1062       (let ((coding-system-for-write 'binary))
1063         (shell-command-on-region (point-min) (point-max) command nil)))))
1064
1065 (defun mm-interactively-view-part (handle)
1066   "Display HANDLE using METHOD."
1067   (let* ((type (mm-handle-media-type handle))
1068          (methods
1069           (mapcar (lambda (i) (list (cdr (assoc 'viewer i))))
1070                   (mailcap-mime-info type 'all)))
1071          (method (let ((minibuffer-local-completion-map
1072                         mm-viewer-completion-map))
1073                    (completing-read "Viewer: " methods))))
1074     (when (string= method "")
1075       (error "No method given"))
1076     (if (string-match "^[^% \t]+$" method)
1077         (setq method (concat method " %s")))
1078     (mm-display-external handle method)))
1079
1080 (defun mm-preferred-alternative (handles &optional preferred)
1081   "Say which of HANDLES are preferred."
1082   (let ((prec (if preferred (list preferred)
1083                 (mm-preferred-alternative-precedence handles)))
1084         p h result type handle)
1085     (while (setq p (pop prec))
1086       (setq h handles)
1087       (while h
1088         (setq handle (car h))
1089         (setq type (mm-handle-media-type handle))
1090         (when (and (equal p type)
1091                    (mm-automatic-display-p handle)
1092                    (or (stringp (car handle))
1093                        (not (mm-handle-disposition handle))
1094                        (equal (car (mm-handle-disposition handle))
1095                               "inline")))
1096           (setq result handle
1097                 h nil
1098                 prec nil))
1099         (pop h)))
1100     result))
1101
1102 (defun mm-preferred-alternative-precedence (handles)
1103   "Return the precedence based on HANDLES and `mm-discouraged-alternatives'."
1104   (let ((seq (nreverse (mapcar #'mm-handle-media-type
1105                                handles))))
1106     (dolist (disc (reverse mm-discouraged-alternatives))
1107       (dolist (elem (copy-sequence seq))
1108         (when (string-match disc elem)
1109           (setq seq (nconc (delete elem seq) (list elem))))))
1110     seq))
1111
1112 (defun mm-get-content-id (id)
1113   "Return the handle(s) referred to by ID."
1114   (cdr (assoc id mm-content-id-alist)))
1115
1116 (defconst mm-image-type-regexps
1117   '(("/\\*.*XPM.\\*/" . xpm)
1118     ("P[1-6]" . pbm)
1119     ("GIF8" . gif)
1120     ("\377\330" . jpeg)
1121     ("\211PNG\r\n" . png)
1122     ("#define" . xbm)
1123     ("\\(MM\0\\*\\)\\|\\(II\\*\0\\)" . tiff)
1124     ("%!PS" . postscript))
1125   "Alist of (REGEXP . IMAGE-TYPE) pairs used to auto-detect image types.
1126 When the first bytes of an image file match REGEXP, it is assumed to
1127 be of image type IMAGE-TYPE.")
1128
1129 ;; Steal from image.el. image-type-from-data suffers multi-line matching bug.
1130 (defun mm-image-type-from-buffer ()
1131   "Determine the image type from data in the current buffer.
1132 Value is a symbol specifying the image type or nil if type cannot
1133 be determined."
1134   (let ((types mm-image-type-regexps)
1135         type)
1136     (goto-char (point-min))
1137     (while (and types (null type))
1138       (let ((regexp (car (car types)))
1139             (image-type (cdr (car types))))
1140         (when (looking-at regexp)
1141           (setq type image-type))
1142         (setq types (cdr types))))
1143     type))
1144
1145 (defun mm-get-image (handle)
1146   "Return an image instance based on HANDLE."
1147   (let ((type (mm-handle-media-subtype handle))
1148         spec)
1149     ;; Allow some common translations.
1150     (setq type
1151           (cond
1152            ((equal type "x-pixmap")
1153             "xpm")
1154            ((equal type "x-xbitmap")
1155             "xbm")
1156            ((equal type "x-portable-bitmap")
1157             "pbm")
1158            (t type)))
1159     (or (mm-handle-cache handle)
1160         (mm-with-unibyte-buffer
1161           (mm-insert-part handle)
1162           (prog1
1163               (setq spec
1164                     (ignore-errors
1165                       ;; Avoid testing `make-glyph' since W3 may define
1166                       ;; a bogus version of it.
1167                       (if (fboundp 'create-image)
1168                           (create-image (buffer-string)
1169                                         (or (mm-image-type-from-buffer)
1170                                             (intern type))
1171                                         'data-p)
1172                         (mm-create-image-xemacs type))))
1173             (mm-handle-set-cache handle spec))))))
1174
1175 (defun mm-create-image-xemacs (type)
1176   (cond
1177    ((equal type "xbm")
1178     ;; xbm images require special handling, since
1179     ;; the only way to create glyphs from these
1180     ;; (without a ton of work) is to write them
1181     ;; out to a file, and then create a file
1182     ;; specifier.
1183     (let ((file (mm-make-temp-file
1184                  (expand-file-name "emm.xbm"
1185                                    mm-tmp-directory))))
1186       (unwind-protect
1187           (progn
1188             (write-region (point-min) (point-max) file)
1189             (make-glyph (list (cons 'x file))))
1190         (ignore-errors
1191           (delete-file file)))))
1192    (t
1193     (make-glyph
1194      (vector
1195       (or (mm-image-type-from-buffer)
1196           (intern type))
1197       :data (buffer-string))))))
1198
1199 (defun mm-image-fit-p (handle)
1200   "Say whether the image in HANDLE will fit the current window."
1201   (let ((image (mm-get-image handle)))
1202     (if (fboundp 'glyph-width)
1203         ;; XEmacs' glyphs can actually tell us about their width, so
1204         ;; lets be nice and smart about them.
1205         (or mm-inline-large-images
1206             (and (< (glyph-width image) (window-pixel-width))
1207                  (< (glyph-height image) (window-pixel-height))))
1208       (let* ((size (image-size image))
1209              (w (car size))
1210              (h (cdr size)))
1211         (or mm-inline-large-images
1212             (and (< h (1- (window-height))) ; Don't include mode line.
1213                  (< w (window-width))))))))
1214
1215 (defun mm-valid-image-format-p (format)
1216   "Say whether FORMAT can be displayed natively by Emacs."
1217   (cond
1218    ;; Handle XEmacs
1219    ((fboundp 'valid-image-instantiator-format-p)
1220     (valid-image-instantiator-format-p format))
1221    ;; Handle Emacs 21
1222    ((fboundp 'image-type-available-p)
1223     (and (display-graphic-p)
1224          (image-type-available-p format)))
1225    ;; Nobody else can do images yet.
1226    (t
1227     nil)))
1228
1229 (defun mm-valid-and-fit-image-p (format handle)
1230   "Say whether FORMAT can be displayed natively and HANDLE fits the window."
1231   (and (mm-valid-image-format-p format)
1232        (mm-image-fit-p handle)))
1233
1234 (defun mm-find-part-by-type (handles type &optional notp recursive)
1235   "Search in HANDLES for part with TYPE.
1236 If NOTP, returns first non-matching part.
1237 If RECURSIVE, search recursively."
1238   (let (handle)
1239     (while handles
1240       (if (and recursive (stringp (caar handles)))
1241           (if (setq handle (mm-find-part-by-type (cdar handles) type
1242                                                  notp recursive))
1243               (setq handles nil))
1244         (if (if notp
1245                 (not (equal (mm-handle-media-type (car handles)) type))
1246               (equal (mm-handle-media-type (car handles)) type))
1247             (setq handle (car handles)
1248                   handles nil)))
1249       (setq handles (cdr handles)))
1250     handle))
1251
1252 (defun mm-find-raw-part-by-type (ctl type &optional notp)
1253   (goto-char (point-min))
1254   (let* ((boundary (concat "--" (mm-handle-multipart-ctl-parameter ctl
1255                                                                    'boundary)))
1256          (close-delimiter (concat "^" (regexp-quote boundary) "--[ \t]*$"))
1257          start
1258          (end (save-excursion
1259                 (goto-char (point-max))
1260                 (if (re-search-backward close-delimiter nil t)
1261                     (match-beginning 0)
1262                   (point-max))))
1263          result)
1264     (setq boundary (concat "^" (regexp-quote boundary) "[ \t]*$"))
1265     (while (and (not result)
1266                 (re-search-forward boundary end t))
1267       (goto-char (match-beginning 0))
1268       (when start
1269         (save-excursion
1270           (save-restriction
1271             (narrow-to-region start (1- (point)))
1272             (when (let ((ctl (ignore-errors
1273                                (mail-header-parse-content-type
1274                                 (mail-fetch-field "content-type")))))
1275                     (if notp
1276                         (not (equal (car ctl) type))
1277                       (equal (car ctl) type)))
1278               (setq result (buffer-string))))))
1279       (forward-line 1)
1280       (setq start (point)))
1281     (when (and (not result) start)
1282       (save-excursion
1283         (save-restriction
1284           (narrow-to-region start end)
1285           (when (let ((ctl (ignore-errors
1286                              (mail-header-parse-content-type
1287                               (mail-fetch-field "content-type")))))
1288                   (if notp
1289                       (not (equal (car ctl) type))
1290                     (equal (car ctl) type)))
1291             (setq result (buffer-string))))))
1292     result))
1293
1294 (defvar mm-security-handle nil)
1295
1296 (defsubst mm-set-handle-multipart-parameter (handle parameter value)
1297   ;; HANDLE could be a CTL.
1298   (when handle
1299     (put-text-property 0 (length (car handle)) parameter value
1300                        (car handle))))
1301
1302 (defun mm-possibly-verify-or-decrypt (parts ctl)
1303   (let ((type (car ctl))
1304         (subtype (cadr (split-string (car ctl) "/")))
1305         (mm-security-handle ctl) ;; (car CTL) is the type.
1306         protocol func functest)
1307     (cond
1308      ((or (equal type "application/x-pkcs7-mime")
1309           (equal type "application/pkcs7-mime"))
1310       (with-temp-buffer
1311         (when (and (cond
1312                     ((eq mm-decrypt-option 'never) nil)
1313                     ((eq mm-decrypt-option 'always) t)
1314                     ((eq mm-decrypt-option 'known) t)
1315                     (t (y-or-n-p
1316                         (format "Decrypt (S/MIME) part? "))))
1317                    (mm-view-pkcs7 parts))
1318           (setq parts (mm-dissect-buffer t)))))
1319      ((equal subtype "signed")
1320       (unless (and (setq protocol
1321                          (mm-handle-multipart-ctl-parameter ctl 'protocol))
1322                    (not (equal protocol "multipart/mixed")))
1323         ;; The message is broken or draft-ietf-openpgp-multsig-01.
1324         (let ((protocols mm-verify-function-alist))
1325           (while protocols
1326             (if (and (or (not (setq functest (nth 3 (car protocols))))
1327                          (funcall functest parts ctl))
1328                      (mm-find-part-by-type parts (caar protocols) nil t))
1329                 (setq protocol (caar protocols)
1330                       protocols nil)
1331               (setq protocols (cdr protocols))))))
1332       (setq func (nth 1 (assoc protocol mm-verify-function-alist)))
1333       (when (cond
1334              ((eq mm-verify-option 'never) nil)
1335              ((eq mm-verify-option 'always) t)
1336              ((eq mm-verify-option 'known)
1337               (and func
1338                    (or (not (setq functest
1339                                   (nth 3 (assoc protocol
1340                                                 mm-verify-function-alist))))
1341                        (funcall functest parts ctl))))
1342              (t
1343               (y-or-n-p
1344                (format "Verify signed (%s) part? "
1345                        (or (nth 2 (assoc protocol mm-verify-function-alist))
1346                            (format "protocol=%s" protocol))))))
1347         (save-excursion
1348           (if func
1349               (funcall func parts ctl)
1350             (mm-set-handle-multipart-parameter
1351              mm-security-handle 'gnus-details
1352              (format "Unknown sign protocol (%s)" protocol))))))
1353      ((equal subtype "encrypted")
1354       (unless (setq protocol
1355                     (mm-handle-multipart-ctl-parameter ctl 'protocol))
1356         ;; The message is broken.
1357         (let ((parts parts))
1358           (while parts
1359             (if (assoc (mm-handle-media-type (car parts))
1360                        mm-decrypt-function-alist)
1361                 (setq protocol (mm-handle-media-type (car parts))
1362                       parts nil)
1363               (setq parts (cdr parts))))))
1364       (setq func (nth 1 (assoc protocol mm-decrypt-function-alist)))
1365       (when (cond
1366              ((eq mm-decrypt-option 'never) nil)
1367              ((eq mm-decrypt-option 'always) t)
1368              ((eq mm-decrypt-option 'known)
1369               (and func
1370                    (or (not (setq functest
1371                                   (nth 3 (assoc protocol
1372                                                 mm-decrypt-function-alist))))
1373                        (funcall functest parts ctl))))
1374              (t
1375               (y-or-n-p
1376                (format "Decrypt (%s) part? "
1377                        (or (nth 2 (assoc protocol mm-decrypt-function-alist))
1378                            (format "protocol=%s" protocol))))))
1379         (save-excursion
1380           (if func
1381               (setq parts (funcall func parts ctl))
1382             (mm-set-handle-multipart-parameter
1383              mm-security-handle 'gnus-details
1384              (format "Unknown encrypt protocol (%s)" protocol))))))
1385      (t nil))
1386     parts))
1387
1388 (defun mm-multiple-handles (handles)
1389   (and (listp (car handles))
1390        (> (length handles) 1)))
1391
1392 (defun mm-merge-handles (handles1 handles2)
1393   (append
1394    (if (listp (car handles1))
1395        handles1
1396      (list handles1))
1397    (if (listp (car handles2))
1398        handles2
1399      (list handles2))))
1400
1401 (defun mm-readable-p (handle)
1402   "Say whether the content of HANDLE is readable."
1403   (and (< (with-current-buffer (mm-handle-buffer handle)
1404             (buffer-size)) 10000)
1405        (mm-with-unibyte-buffer
1406          (mm-insert-part handle)
1407          (and (eq (mm-body-7-or-8) '7bit)
1408               (not (mm-long-lines-p 76))))))
1409
1410 (provide 'mm-decode)
1411
1412 ;;; mm-decode.el ends here