cgit.sxemacs.org Git - gnus/blob - lisp/gnus-xmas.el

   1 ;;; gnus-xmas.el --- Gnus functions for XEmacs
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'text-props)
  29 (eval-when-compile (require 'cl))
  30 (defvar menu-bar-mode t)
  31
  32 (defvar gnus-xmas-glyph-directory nil
  33   "*Directory where Gnus logos and icons are located.
  34 If this variable is nil, Gnus will try to locate the directory
  35 automatically.")
  36
  37 ;;; Internal variables.
  38
  39 (defvar gnus-xmas-logo (make-glyph (make-specifier 'image)))
  40
  41 ;; Don't warn about these undefined variables.
  42
  43 (defvar gnus-group-mode-hook)
  44 (defvar gnus-summary-mode-hook)
  45 (defvar gnus-article-mode-hook)
  46
  47 ;;defined in gnus.el
  48 (defvar gnus-active-hashtb)
  49 (defvar gnus-article-buffer)
  50 (defvar gnus-auto-center-summary)
  51 (defvar gnus-buffer-list)
  52 (defvar gnus-current-headers)
  53 (defvar gnus-level-killed)
  54 (defvar gnus-level-zombie)
  55 (defvar gnus-newsgroup-bookmarks)
  56 (defvar gnus-newsgroup-dependencies)
  57 (defvar gnus-newsgroup-selected-overlay)
  58 (defvar gnus-newsrc-hashtb)
  59 (defvar gnus-read-mark)
  60 (defvar gnus-refer-article-method)
  61 (defvar gnus-reffed-article-number)
  62 (defvar gnus-unread-mark)
  63 (defvar gnus-version)
  64 (defvar gnus-view-pseudos)
  65 (defvar gnus-view-pseudos-separately)
  66 (defvar gnus-visual)
  67 (defvar gnus-zombie-list)
  68 ;;defined in gnus-msg.el
  69 (defvar gnus-article-copy)
  70 (defvar gnus-check-before-posting)
  71 ;;defined in gnus-vis.el
  72 (defvar gnus-article-button-face)
  73 (defvar gnus-article-mouse-face)
  74 (defvar gnus-summary-selected-face)
  75 (defvar gnus-group-reading-menu)
  76 (defvar gnus-group-group-menu)
  77 (defvar gnus-group-misc-menu)
  78 (defvar gnus-summary-article-menu)
  79 (defvar gnus-summary-thread-menu)
  80 (defvar gnus-summary-misc-menu)
  81 (defvar gnus-summary-post-menu)
  82 (defvar gnus-summary-kill-menu)
  83 (defvar gnus-article-article-menu)
  84 (defvar gnus-article-treatment-menu)
  85 (defvar gnus-mouse-2)
  86 (defvar standard-display-table)
  87
  88 (defun gnus-xmas-set-text-properties (start end props &optional buffer)
  89   "You should NEVER use this function.  It is ideologically blasphemous.
  90 It is provided only to ease porting of broken FSF Emacs programs."
  91   (if (stringp buffer)
  92       nil
  93     (map-extents (lambda (extent ignored)
  94                    (remove-text-properties
  95                     start end
  96                     (list (extent-property extent 'text-prop) nil)
  97                     buffer))
  98                  buffer start end nil nil 'text-prop)
  99     (add-text-properties start end props buffer)))
 100
 101 (defun gnus-xmas-highlight-selected-summary ()
 102   ;; Highlight selected article in summary buffer
 103   (if gnus-summary-selected-face
 104       (progn
 105         (if gnus-newsgroup-selected-overlay
 106             (delete-extent gnus-newsgroup-selected-overlay))
 107         (setq gnus-newsgroup-selected-overlay
 108               (make-extent (gnus-point-at-bol) (gnus-point-at-eol)))
 109         (set-extent-face gnus-newsgroup-selected-overlay
 110                          gnus-summary-selected-face))))
 111
 112 (defun gnus-xmas-summary-recenter ()
 113   (let* ((top (cond ((< (window-height) 4) 0)
 114                     ((< (window-height) 7) 1)
 115                     (t 2)))
 116          (height (- (window-height) 2))
 117          (bottom (save-excursion (goto-char (point-max))
 118                                  (forward-line (- height))
 119                                  (point)))
 120          (window (get-buffer-window (current-buffer))))
 121     (and
 122      ;; The user has to want it,
 123      gnus-auto-center-summary
 124      ;; the article buffer must be displayed,
 125      (get-buffer-window gnus-article-buffer)
 126      ;; Set the window start to either `bottom', which is the biggest
 127      ;; possible valid number, or the second line from the top,
 128      ;; whichever is the least.
 129      (set-window-start
 130       window (min bottom (save-excursion
 131                            (forward-line (- top)) (point)))))))
 132
 133 (defun gnus-xmas-group-remove-excess-properties ()
 134   (let ((end (point))
 135         (beg (progn (forward-line -1) (point))))
 136     (remove-text-properties (1+ beg) end '(gnus-group nil))
 137     (remove-text-properties
 138      beg end
 139      '(gnus-topic nil gnus-topic-level nil gnus-topic-visible nil))
 140     (goto-char end)))
 141
 142 (defun gnus-xmas-topic-remove-excess-properties ()
 143   (let ((end (point))
 144         (beg (progn (forward-line -1) (point))))
 145     (remove-text-properties beg end '(gnus-group nil))
 146     (goto-char end)))
 147
 148 (defun gnus-xmas-extent-start-open (point)
 149   (map-extents (lambda (extent arg)
 150                  (set-extent-property extent 'start-open t))
 151                nil point (min (1+ (point)) (point-max))))
 152
 153 (defun gnus-xmas-copy-article-buffer (&optional article-buffer)
 154   (setq gnus-article-copy (get-buffer-create " *gnus article copy*"))
 155   (buffer-disable-undo gnus-article-copy)
 156   (or (memq gnus-article-copy gnus-buffer-list)
 157       (setq gnus-buffer-list (cons gnus-article-copy gnus-buffer-list)))
 158   (let ((article-buffer (or article-buffer gnus-article-buffer))
 159         buf)
 160     (if (and (get-buffer article-buffer)
 161              (buffer-name (get-buffer article-buffer)))
 162         (save-excursion
 163           (set-buffer article-buffer)
 164           (widen)
 165           (setq buf (buffer-substring (point-min) (point-max)))
 166           (set-buffer gnus-article-copy)
 167           (erase-buffer)
 168           (insert (format "%s" buf))))))
 169
 170 (defun gnus-xmas-article-push-button (event)
 171   "Check text under the mouse pointer for a callback function.
 172 If the text under the mouse pointer has a `gnus-callback' property,
 173 call it with the value of the `gnus-data' text property."
 174   (interactive "e")
 175   (set-buffer (window-buffer (event-window event)))
 176   (let* ((pos (event-closest-point event))
 177          (data (get-text-property pos 'gnus-data))
 178          (fun (get-text-property pos 'gnus-callback)))
 179     (if fun (funcall fun data))))
 180
 181 (defun gnus-xmas-move-overlay (extent start end &optional buffer)
 182   (set-extent-endpoints extent start end))
 183
 184 ;; Fixed by Christopher Davis <ckd@loiosh.kei.com>.
 185 (defun gnus-xmas-article-add-button (from to fun &optional data)
 186   "Create a button between FROM and TO with callback FUN and data DATA."
 187   (and gnus-article-button-face
 188        (gnus-overlay-put (gnus-make-overlay from to)
 189                          'face gnus-article-button-face))
 190   (add-text-properties
 191    from to
 192    (nconc
 193     (and gnus-article-mouse-face
 194          (list 'mouse-face gnus-article-mouse-face))
 195     (list 'gnus-callback fun)
 196     (and data (list 'gnus-data data))
 197     (list 'highlight t))))
 198
 199 (defun gnus-xmas-window-top-edge (&optional window)
 200   (nth 1 (window-pixel-edges window)))
 201
 202 (defun gnus-xmas-tree-minimize ()
 203   (when (and gnus-tree-minimize-window
 204              (not (one-window-p)))
 205     (let* ((window-min-height 2)
 206            (height (1+ (count-lines (point-min) (point-max))))
 207            (min (max (1- window-min-height) height))
 208            (tot (if (numberp gnus-tree-minimize-window)
 209                     (min gnus-tree-minimize-window min)
 210                   min))
 211            (win (get-buffer-window (current-buffer)))
 212            (wh (and win (1- (window-height win)))))
 213       (when (and win
 214                  (not (eq tot wh)))
 215         (let ((selected (selected-window)))
 216           (select-window win)
 217           (enlarge-window (- tot wh))
 218           (select-window selected))))))
 219
 220 ;; Select the lowest window on the frame.
 221 (defun gnus-xmas-appt-select-lowest-window ()
 222   (let* ((lowest-window (selected-window))
 223          (bottom-edge (car (cdr (cdr (cdr (window-pixel-edges))))))
 224          (last-window (previous-window))
 225          (window-search t))
 226     (while window-search
 227       (let* ((this-window (next-window))
 228              (next-bottom-edge (car (cdr (cdr (cdr
 229                                                (window-pixel-edges
 230                                                 this-window)))))))
 231         (if (< bottom-edge next-bottom-edge)
 232             (progn
 233               (setq bottom-edge next-bottom-edge)
 234               (setq lowest-window this-window)))
 235
 236         (select-window this-window)
 237         (if (eq last-window this-window)
 238             (progn
 239               (select-window lowest-window)
 240               (setq window-search nil)))))))
 241
 242 (defun gnus-xmas-group-menu-add ()
 243   (easy-menu-add gnus-group-reading-menu)
 244   (easy-menu-add gnus-group-group-menu)
 245   (easy-menu-add gnus-group-misc-menu))
 246
 247 (defun gnus-xmas-summary-menu-add ()
 248   (easy-menu-add gnus-summary-article-menu)
 249   (easy-menu-add gnus-summary-thread-menu)
 250   (easy-menu-add gnus-summary-misc-menu)
 251   (easy-menu-add gnus-summary-post-menu)
 252   (easy-menu-add gnus-summary-kill-menu))
 253
 254 (defun gnus-xmas-article-menu-add ()
 255   (easy-menu-add gnus-article-article-menu)
 256   (easy-menu-add gnus-article-treatment-menu))
 257
 258 (defun gnus-xmas-pick-menu-add ()
 259   (easy-menu-add gnus-pich-menu))
 260
 261 (defun gnus-xmas-binary-menu-add ()
 262   (easy-menu-add gnus-binary-menu))
 263
 264 (defun gnus-xmas-tree-menu-add ()
 265   (easy-menu-add gnus-tree-menu))
 266
 267 (defun gnus-xmas-grouplens-menu-add ()
 268   (easy-menu-add gnus-grouplens-menu))
 269
 270 (defun gnus-xmas-read-event-char ()
 271   "Get the next event."
 272   (let ((event (next-event)))
 273     ;; We junk all non-key events.  Is this naughty?
 274     (while (not (key-press-event-p event))
 275       (setq event (next-event)))
 276     (cons (and (key-press-event-p event)
 277               ; (numberp (event-key event))
 278                (event-to-character event))
 279           event)))
 280
 281 (defun gnus-xmas-seconds-since-epoch (date)
 282   "Return a floating point number that says how many seconds have lapsed between Jan 1 12:00:00 1970 and DATE."
 283   (let* ((tdate (mapcar (lambda (ti) (and ti (string-to-int ti)))
 284                         (timezone-parse-date date)))
 285          (ttime (mapcar (lambda (ti) (and ti (string-to-int ti)))
 286                         (timezone-parse-time
 287                          (aref (timezone-parse-date date) 3))))
 288          (edate (mapcar (lambda (ti) (and ti (string-to-int ti)))
 289                         (timezone-parse-date "Jan 1 12:00:00 1970")))
 290          (tday (- (timezone-absolute-from-gregorian
 291                    (nth 1 tdate) (nth 2 tdate) (nth 0 tdate))
 292                   (timezone-absolute-from-gregorian
 293                    (nth 1 edate) (nth 2 edate) (nth 0 edate)))))
 294     (+ (nth 2 ttime)
 295        (* (nth 1 ttime) 60)
 296        (* (float (nth 0 ttime)) 60 60)
 297        (* (float tday) 60 60 24))))
 298
 299 (defun gnus-xmas-define ()
 300   (setq gnus-mouse-2 [button2])
 301
 302   (or (memq 'underline (list-faces))
 303       (and (fboundp 'make-face)
 304            (funcall (intern "make-face") 'underline)))
 305   ;; Must avoid calling set-face-underline-p directly, because it
 306   ;; is a defsubst in emacs19, and will make the .elc files non
 307   ;; portable!
 308   (or (face-differs-from-default-p 'underline)
 309       (funcall (intern "set-face-underline-p") 'underline t))
 310
 311   (fset 'gnus-make-overlay 'make-extent)
 312   (fset 'gnus-overlay-put 'set-extent-property)
 313   (fset 'gnus-move-overlay 'gnus-xmas-move-overlay)
 314   (fset 'gnus-overlay-end 'extent-end-position)
 315   (fset 'gnus-extent-detached-p 'extent-detached-p)
 316
 317   (require 'text-props)
 318   (if (< emacs-minor-version 14)
 319       (fset 'gnus-set-text-properties 'gnus-xmas-set-text-properties))
 320
 321   (fset 'nnheader-find-file-noselect 'gnus-xmas-find-file-noselect)
 322
 323   (or (boundp 'standard-display-table) (setq standard-display-table nil))
 324
 325   (defvar gnus-mouse-face-prop 'highlight)
 326
 327   (unless (fboundp 'encode-time)
 328     (defun encode-time (sec minute hour day month year &optional zone)
 329       (let ((seconds
 330              (gnus-xmas-seconds-since-epoch
 331               (timezone-make-arpa-date
 332                year month day (timezone-make-time-string hour minute sec)
 333                zone))))
 334         (list (floor (/ seconds (expt 2 16)))
 335               (round (mod seconds (expt 2 16)))))))
 336
 337   (defun gnus-byte-code (func)
 338     "Return a form that can be `eval'ed based on FUNC."
 339     (let ((fval (symbol-function func)))
 340       (if (byte-code-function-p fval)
 341           (list 'funcall fval)
 342         (cons 'progn (cdr (cdr fval))))))
 343
 344   ;; Fix by "jeff (j.d.) sparkes" <jsparkes@bnr.ca>.
 345   (defvar gnus-display-type (device-class)
 346     "A symbol indicating the display Emacs is running under.
 347 The symbol should be one of `color', `grayscale' or `mono'. If Emacs
 348 guesses this display attribute wrongly, either set this variable in
 349 your `~/.emacs' or set the resource `Emacs.displayType' in your
 350 `~/.Xdefaults'. See also `gnus-background-mode'.
 351
 352 This is a meta-variable that will affect what default values other
 353 variables get.  You would normally not change this variable, but
 354 pounce directly on the real variables themselves.")
 355
 356
 357   (fset 'gnus-x-color-values
 358         (if (fboundp 'x-color-values)
 359             'x-color-values
 360           (lambda (color)
 361             (color-instance-rgb-components
 362              (make-color-instance color)))))
 363
 364   (defvar gnus-background-mode
 365     (let ((bg-resource
 366            (condition-case ()
 367                (x-get-resource ".backgroundMode" "BackgroundMode" 'string)
 368              (error nil)))
 369           (params (frame-parameters)))
 370       (cond (bg-resource (intern (downcase bg-resource)))
 371             ((and (assq 'background-color params)
 372                   (< (apply '+ (gnus-x-color-values
 373                                 (cdr (assq 'background-color params))))
 374                      (/ (apply '+ (gnus-x-color-values "white")) 3)))
 375              'dark)
 376             (t 'light)))
 377     "A symbol indicating the Emacs background brightness.
 378 The symbol should be one of `light' or `dark'.
 379 If Emacs guesses this frame attribute wrongly, either set this variable in
 380 your `~/.emacs' or set the resource `Emacs.backgroundMode' in your
 381 `~/.Xdefaults'.
 382 See also `gnus-display-type'.
 383
 384 This is a meta-variable that will affect what default values other
 385 variables get.  You would normally not change this variable, but
 386 pounce directly on the real variables themselves.")
 387   )
 388
 389
 390
 391 (defun gnus-xmas-redefine ()
 392   "Redefine lots of Gnus functions for XEmacs."
 393   (fset 'gnus-summary-make-display-table (lambda () nil))
 394   (fset 'gnus-visual-turn-off-edit-menu 'identity)
 395   (fset 'gnus-highlight-selected-summary
 396         'gnus-xmas-highlight-selected-summary)
 397   (fset 'gnus-summary-recenter 'gnus-xmas-summary-recenter)
 398   (fset 'gnus-group-remove-excess-properties
 399         'gnus-xmas-group-remove-excess-properties)
 400   (fset 'gnus-topic-remove-excess-properties
 401         'gnus-xmas-topic-remove-excess-properties)
 402   (fset 'gnus-extent-start-open 'gnus-xmas-extent-start-open)
 403   (fset 'gnus-copy-article-buffer 'gnus-xmas-copy-article-buffer)
 404   (fset 'gnus-article-push-button 'gnus-xmas-article-push-button)
 405   (fset 'gnus-article-add-button 'gnus-xmas-article-add-button)
 406   (fset 'gnus-window-top-edge 'gnus-xmas-window-top-edge)
 407   (fset 'gnus-read-event-char 'gnus-xmas-read-event-char)
 408   (fset 'gnus-group-startup-message 'gnus-xmas-group-startup-message)
 409   (fset 'gnus-tree-minimize 'gnus-xmas-tree-minimize)
 410   (fset 'gnus-appt-select-lowest-window
 411         'gnus-xmas-appt-select-lowest-window)
 412   (fset 'gnus-mail-strip-quoted-names 'gnus-xmas-mail-strip-quoted-names)
 413
 414   (add-hook 'gnus-group-mode-hook 'gnus-xmas-group-menu-add)
 415   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-summary-menu-add)
 416   (add-hook 'gnus-article-mode-hook 'gnus-xmas-article-menu-add)
 417
 418   (add-hook 'gnus-pick-mode-hook 'gnus-xmas-pick-menu-add)
 419   (add-hook 'gnus-tree-mode-hook 'gnus-xmas-tree-menu-add)
 420   (add-hook 'gnus-binary-mode-hook 'gnus-xmas-binary-menu-add)
 421   (add-hook 'gnus-grouplens-mode-hook 'gnus-xmas-grouplens-menu-add)
 422
 423   (add-hook 'gnus-group-mode-hook 'gnus-xmas-setup-group-toolbar)
 424   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-setup-summary-toolbar))
 425
 426
 427 ;;; XEmacs logo and toolbar.
 428
 429 (defun gnus-xmas-find-glyph-directory ()
 430   (or gnus-xmas-glyph-directory ; We have a dir already...
 431       (let ((path load-path)
 432             dir)
 433         ;; We try to find the dir by looking at the load path,
 434         ;; stripping away the last component and adding "etc/".
 435         (while path
 436           (setq dir (concat
 437                      (file-name-directory (directory-file-name (car path)))
 438                      "etc/gnus/"))
 439           (if (and (file-exists-p dir)
 440                    (file-directory-p dir)
 441                    (file-exists-p (concat dir "gnus-group-exit-icon-up.xpm")))
 442               (setq gnus-xmas-glyph-directory dir
 443                     path nil)
 444             (setq path (cdr path))))
 445         gnus-xmas-glyph-directory)))
 446
 447 (defun gnus-xmas-group-startup-message (&optional x y)
 448   "Insert startup message in current buffer."
 449   ;; Insert the message.
 450   (gnus-xmas-find-glyph-directory)
 451   (erase-buffer)
 452   (let ((file (and gnus-xmas-glyph-directory
 453                    (concat
 454                     (file-name-as-directory gnus-xmas-glyph-directory)
 455                     "gnus.xpm"))))
 456     (if (and (featurep 'xpm)
 457              (not (equal (device-type) 'tty))
 458              file (file-exists-p file))
 459         (progn
 460           (set-glyph-property gnus-xmas-logo 'image file)
 461           (set-glyph-image gnus-xmas-logo file 'global 'x)
 462
 463           (insert " ")
 464           (set-extent-begin-glyph (make-extent (point) (point)) gnus-xmas-logo)
 465           (goto-char (point-min))
 466           (while (not (eobp))
 467             (insert (make-string (/ (max (- (window-width) (or x 35)) 0) 2)
 468                                  ? ))
 469             (forward-line 1))
 470           (goto-char (point-min))
 471           (let* ((pheight (+ 20 (count-lines (point-min) (point-max))))
 472                  (wheight (window-height))
 473                  (rest (- wheight pheight)))
 474             (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n))))
 475
 476       (insert
 477        (format "              %s
 478           _    ___ _             _
 479           _ ___ __ ___  __    _ ___
 480           __   _     ___    __  ___
 481               _           ___     _
 482              _  _ __             _
 483              ___   __            _
 484                    __           _
 485                     _      _   _
 486                    _      _    _
 487                       _  _    _
 488                   __  ___
 489                  _   _ _     _
 490                 _   _
 491               _    _
 492              _    _
 493             _
 494           __
 495
 496 "
 497                ""))
 498       ;; And then hack it.
 499       (gnus-indent-rigidly (point-min) (point-max)
 500                            (/ (max (- (window-width) (or x 46)) 0) 2))
 501       (goto-char (point-min))
 502       (forward-line 1)
 503       (let* ((pheight (count-lines (point-min) (point-max)))
 504              (wheight (window-height))
 505              (rest (- wheight pheight)))
 506         (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n))))
 507     ;; Fontify some.
 508     (goto-char (point-min))
 509     (and (search-forward "Praxis" nil t)
 510          (put-text-property (match-beginning 0) (match-end 0) 'face 'bold))
 511     (goto-char (point-min))
 512     (let* ((mode-string (gnus-group-set-mode-line)))
 513       (setq mode-line-buffer-identification
 514             (list (concat gnus-version (substring (car mode-string) 4))))
 515       (set-buffer-modified-p t))))
 516
 517
 518 ;;; The toolbar.
 519
 520 (defvar gnus-use-toolbar 'default-toolbar
 521   "*If nil, do not use a toolbar.
 522 If it is non-nil, it must be a toolbar.  The five legal values are
 523 `default-toolbar', `top-toolbar', `bottom-toolbar',
 524 `right-toolbar', and `left-toolbar'.")
 525
 526 (defvar gnus-group-toolbar
 527   '([gnus-group-exit-icon gnus-group-exit t "Exit Gnus"]
 528     [gnus-group-kill-group-icon gnus-group-kill-group t "Kill group"]
 529     [gnus-group-get-new-news-icon gnus-group-get-new-news t "Get new news"]
 530     [gnus-group-get-new-news-this-group-icon
 531      gnus-group-get-new-news-this-group t "Get new news in this group"]
 532     [gnus-group-catchup-current-icon
 533      gnus-group-catchup-current t "Catchup group"]
 534     [gnus-group-describe-group-icon
 535      gnus-group-describe-group t "Describe group"])
 536   "The group buffer toolbar.")
 537
 538 (defvar gnus-summary-toolbar
 539   '([gnus-summary-post-news-icon
 540      gnus-summary-post-news t "Post an article"]
 541     [gnus-summary-save-article-file-icon
 542      gnus-summary-save-article-file t "Save article in file"]
 543     [gnus-summary-save-article-icon
 544      gnus-summary-save-article t "Save article"]
 545     [gnus-summary-reply-icon
 546      gnus-summary-reply t "Mail a reply"]
 547     [gnus-summary-reply-with-original-icon
 548      gnus-summary-reply-with-original t "Mail a reply and yank the original"]
 549     [gnus-summary-followup-icon
 550      gnus-summary-followup t "Post a followup"]
 551     [gnus-summary-followup-with-original-icon
 552      gnus-summary-followup-with-original t
 553      "Post a followup and yank the original"]
 554     [gnus-uu-decode-uu-icon
 555      gnus-uu-decode-uu t "Decode uuencoded articles"]
 556     [gnus-uu-post-news-icon
 557      gnus-uu-post-news t "Post an uuencoded article"]
 558     [gnus-summary-caesar-message-icon
 559      gnus-summary-caesar-message t "Rot 13"]
 560     [gnus-summary-cancel-article-icon
 561      gnus-summary-cancel-article t "Cancel article"])
 562   "The summary buffer toolbar.")
 563
 564 (defun gnus-xmas-setup-toolbar (bar &optional force)
 565   (let ((dir (gnus-xmas-find-glyph-directory))
 566         icon up down disabled name)
 567     (if (not dir)
 568         ()
 569       (if (and (not force)
 570                (boundp (aref (car bar) 0)))
 571           dir
 572         (while bar
 573           (setq icon (aref (car bar) 0)
 574                 name (symbol-name icon)
 575                 bar (cdr bar))
 576           (setq up (concat dir name "-up.xpm"))
 577           (setq down (concat dir name "-down.xpm"))
 578           (setq disabled (concat dir name "-disabled.xpm"))
 579           (if (not (file-exists-p up))
 580               (set icon nil)
 581             (set icon (toolbar-make-button-list
 582                        up (and (file-exists-p down) down)
 583                        (and (file-exists-p disabled) disabled)))))
 584         dir))))
 585
 586 (defun gnus-xmas-setup-group-toolbar ()
 587   (and gnus-use-toolbar
 588        (gnus-xmas-setup-toolbar gnus-group-toolbar)
 589        (set-specifier (symbol-value gnus-use-toolbar)
 590                       (cons (current-buffer) gnus-group-toolbar))))
 591
 592 (defun gnus-xmas-setup-summary-toolbar ()
 593   (and gnus-use-toolbar
 594        (gnus-xmas-setup-toolbar gnus-summary-toolbar)
 595        (set-specifier (symbol-value gnus-use-toolbar)
 596                       (cons (current-buffer) gnus-summary-toolbar))))
 597
 598 ;; Written by Erik Naggum <erik@naggum.no>.
 599 ;; Saved by Steve Baur <steve@miranova.com>.
 600 (or (fboundp 'insert-file-contents-literally)
 601 (defun insert-file-contents-literally (filename &optional visit beg end replace)
 602   "Like `insert-file-contents', q.v., but only reads in the file.
 603 A buffer may be modified in several ways after reading into the buffer due
 604 to advanced Emacs features, such as file-name-handlers, format decoding,
 605 find-file-hooks, etc.
 606   This function ensures that none of these modifications will take place."
 607   (let (                                ; (file-name-handler-alist nil)
 608         (format-alist nil)
 609         (after-insert-file-functions nil)
 610         (find-buffer-file-type-function
 611          (if (fboundp 'find-buffer-file-type)
 612              (symbol-function 'find-buffer-file-type)
 613            nil)))
 614     (unwind-protect
 615         (progn
 616           (fset 'find-buffer-file-type (lambda (filename) t))
 617           (insert-file-contents filename visit beg end replace))
 618       (if find-buffer-file-type-function
 619           (fset 'find-buffer-file-type find-buffer-file-type-function)
 620         (fmakunbound 'find-buffer-file-type))))))
 621
 622 (defun gnus-xmas-find-file-noselect (filename &optional nowarn rawfile)
 623   "Read file FILENAME into a buffer and return the buffer.
 624 If a buffer exists visiting FILENAME, return that one, but
 625 verify that the file has not changed since visited or saved.
 626 The buffer is not selected, just returned to the caller."
 627   (setq filename
 628         (abbreviate-file-name
 629          (expand-file-name filename)))
 630   (if (file-directory-p filename)
 631       (if find-file-run-dired
 632           (dired-noselect filename)
 633         (error "%s is a directory." filename))
 634     (let* ((buf (get-file-buffer filename))
 635            (truename (abbreviate-file-name (file-truename filename)))
 636            (number (nthcdr 10 (file-attributes truename)))
 637            ;; Find any buffer for a file which has same truename.
 638            (other (and (not buf)
 639                        (if (fboundp 'find-buffer-visiting)
 640                            (find-buffer-visiting filename)
 641                          (get-file-buffer filename))))
 642            error)
 643       ;; Let user know if there is a buffer with the same truename.
 644       (if other
 645           (progn
 646             (or nowarn
 647                 (string-equal filename (buffer-file-name other))
 648                 (message "%s and %s are the same file"
 649                          filename (buffer-file-name other)))
 650             ;; Optionally also find that buffer.
 651             (if (or (and (boundp 'find-file-existing-other-name)
 652                          find-file-existing-other-name)
 653                     find-file-visit-truename)
 654                 (setq buf other))))
 655       (if buf
 656           (or nowarn
 657               (verify-visited-file-modtime buf)
 658               (cond ((not (file-exists-p filename))
 659                      (error "File %s no longer exists!" filename))
 660                     ((yes-or-no-p
 661                       (if (string= (file-name-nondirectory filename)
 662                                    (buffer-name buf))
 663                           (format
 664                            (if (buffer-modified-p buf)
 665                                "File %s changed on disk.  Discard your edits? "
 666                              "File %s changed on disk.  Reread from disk? ")
 667                            (file-name-nondirectory filename))
 668                         (format
 669                          (if (buffer-modified-p buf)
 670                              "File %s changed on disk.  Discard your edits in %s? "
 671                            "File %s changed on disk.  Reread from disk into %s? ")
 672                          (file-name-nondirectory filename)
 673                          (buffer-name buf))))
 674                      (save-excursion
 675                        (set-buffer buf)
 676                        (revert-buffer t t)))))
 677         (save-excursion
 678 ;;; The truename stuff makes this obsolete.
 679 ;;;       (let* ((link-name (car (file-attributes filename)))
 680 ;;;              (linked-buf (and (stringp link-name)
 681 ;;;                               (get-file-buffer link-name))))
 682 ;;;         (if (bufferp linked-buf)
 683 ;;;             (message "Symbolic link to file in buffer %s"
 684 ;;;                      (buffer-name linked-buf))))
 685           (setq buf (create-file-buffer filename))
 686           ;;      (set-buffer-major-mode buf)
 687           (set-buffer buf)
 688           (erase-buffer)
 689           (if rawfile
 690               (condition-case ()
 691                   (insert-file-contents-literally filename t)
 692                 (file-error
 693                  ;; Unconditionally set error
 694                  (setq error t)))
 695             (condition-case ()
 696                 (insert-file-contents filename t)
 697               (file-error
 698                ;; Run find-file-not-found-hooks until one returns non-nil.
 699                (or t                    ; (run-hook-with-args-until-success 'find-file-not-found-hooks)
 700                    ;; If they fail too, set error.
 701                    (setq error t)))))
 702           ;; Find the file's truename, and maybe use that as visited name.
 703           (setq buffer-file-truename truename)
 704           (setq buffer-file-number number)
 705           ;; On VMS, we may want to remember which directory in a search list
 706           ;; the file was found in.
 707           (and (eq system-type 'vax-vms)
 708                (let (logical)
 709                  (if (string-match ":" (file-name-directory filename))
 710                      (setq logical (substring (file-name-directory filename)
 711                                               0 (match-beginning 0))))
 712                  (not (member logical find-file-not-true-dirname-list)))
 713                (setq buffer-file-name buffer-file-truename))
 714           (if find-file-visit-truename
 715               (setq buffer-file-name
 716                     (setq filename
 717                           (expand-file-name buffer-file-truename))))
 718           ;; Set buffer's default directory to that of the file.
 719           (setq default-directory (file-name-directory filename))
 720           ;; Turn off backup files for certain file names.  Since
 721           ;; this is a permanent local, the major mode won't eliminate it.
 722           (and (not (funcall backup-enable-predicate buffer-file-name))
 723                (progn
 724                  (make-local-variable 'backup-inhibited)
 725                  (setq backup-inhibited t)))
 726           (if rawfile
 727               nil
 728             (after-find-file error (not nowarn)))))
 729       buf)))
 730
 731 (defun gnus-xmas-mail-strip-quoted-names (address)
 732   "Protect mail-strip-quoted-names from NIL input.
 733 XEmacs compatibility workaround."
 734   (if (null address)
 735       nil
 736     (mail-strip-quoted-names address)))
 737
 738 ;;; gnus-xmas.el ends here