cgit.sxemacs.org Git - gnus/blob - lisp/gnus-xmas.el

   1 ;;; gnus-xmas.el --- Gnus functions for XEmacs
   2 ;; Copyright (C) 1995 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'text-props)
  28 (defvar menu-bar-mode t)
  29
  30 (defvar gnus-xmas-glyph-directory nil
  31   "*Directory where Gnus logos and icons are located.
  32 If this variable is nil, Gnus will try to locate the directory
  33 automatically.")
  34
  35 ;;; Internal variables.
  36
  37 (defvar gnus-xmas-logo (make-glyph (make-specifier 'image)))
  38
  39 ;; Don't warn about these undefined variables.
  40
  41 (defvar gnus-group-mode-hook)
  42 (defvar gnus-summary-mode-hook)
  43 (defvar gnus-article-mode-hook)
  44
  45 ;;defined in gnus.el
  46 (defvar gnus-active-hashtb)
  47 (defvar gnus-article-buffer)
  48 (defvar gnus-auto-center-summary)
  49 (defvar gnus-buffer-list)
  50 (defvar gnus-current-headers)
  51 (defvar gnus-level-killed)
  52 (defvar gnus-level-zombie)
  53 (defvar gnus-newsgroup-bookmarks)
  54 (defvar gnus-newsgroup-dependencies)
  55 (defvar gnus-newsgroup-selected-overlay)
  56 (defvar gnus-newsrc-hashtb)
  57 (defvar gnus-read-mark)
  58 (defvar gnus-refer-article-method)
  59 (defvar gnus-reffed-article-number)
  60 (defvar gnus-unread-mark)
  61 (defvar gnus-version)
  62 (defvar gnus-view-pseudos)
  63 (defvar gnus-view-pseudos-separately)
  64 (defvar gnus-visual)
  65 (defvar gnus-zombie-list)
  66 ;;defined in gnus-msg.el
  67 (defvar gnus-article-copy)
  68 (defvar gnus-check-before-posting)
  69 ;;defined in gnus-vis.el
  70 (defvar gnus-article-button-face)
  71 (defvar gnus-article-mouse-face)
  72 (defvar gnus-summary-selected-face)
  73 (defvar gnus-group-reading-menu)
  74 (defvar gnus-group-group-menu)
  75 (defvar gnus-group-misc-menu)
  76 (defvar gnus-summary-article-menu)
  77 (defvar gnus-summary-thread-menu)
  78 (defvar gnus-summary-misc-menu)
  79 (defvar gnus-summary-post-menu)
  80 (defvar gnus-summary-kill-menu)
  81 (defvar gnus-article-article-menu)
  82 (defvar gnus-article-treatment-menu)
  83 (defvar gnus-mouse-2)
  84 (defvar standard-display-table)
  85
  86 (defun gnus-xmas-set-text-properties (start end props &optional buffer)
  87   "You should NEVER use this function.  It is ideologically blasphemous.
  88 It is provided only to ease porting of broken FSF Emacs programs."
  89   (if (and (stringp buffer) (not (setq buffer (get-buffer buffer))))
  90       nil
  91     (map-extents (lambda (extent ignored)
  92                    (remove-text-properties
  93                     start end
  94                     (list (extent-property extent 'text-prop) nil)
  95                     buffer))
  96                  buffer start end nil nil 'text-prop)
  97     (add-text-properties start end props buffer)))
  98
  99 (defun gnus-xmas-highlight-selected-summary ()
 100   ;; Highlight selected article in summary buffer
 101   (if gnus-summary-selected-face
 102       (progn
 103         (if gnus-newsgroup-selected-overlay
 104             (delete-extent gnus-newsgroup-selected-overlay))
 105         (setq gnus-newsgroup-selected-overlay
 106               (make-extent (gnus-point-at-bol) (gnus-point-at-eol)))
 107         (set-extent-face gnus-newsgroup-selected-overlay
 108                          gnus-summary-selected-face))))
 109
 110 (defun gnus-xmas-summary-recenter ()
 111   (let* ((top (cond ((< (window-height) 4) 0)
 112                     ((< (window-height) 7) 1)
 113                     (t 2)))
 114          (height (- (window-height) 2))
 115          (bottom (save-excursion (goto-char (point-max))
 116                                  (forward-line (- height))
 117                                  (point)))
 118          (window (get-buffer-window (current-buffer))))
 119     (and
 120      ;; The user has to want it,
 121      gnus-auto-center-summary
 122      ;; the article buffer must be displayed,
 123      (get-buffer-window gnus-article-buffer)
 124      ;; Set the window start to either `bottom', which is the biggest
 125      ;; possible valid number, or the second line from the top,
 126      ;; whichever is the least.
 127      (set-window-start
 128       window (min bottom (save-excursion
 129                            (forward-line (- top)) (point)))))))
 130
 131 (defun gnus-xmas-group-remove-excess-properties ()
 132   (let ((end (point))
 133         (beg (progn (forward-line -1) (point))))
 134     (remove-text-properties (1+ beg) end '(gnus-group nil))
 135     (remove-text-properties
 136      beg end
 137      '(gnus-topic nil gnus-topic-level nil gnus-topic-visible nil))
 138     (goto-char end)))
 139
 140 (defun gnus-xmas-copy-article-buffer (&optional article-buffer)
 141   (setq gnus-article-copy (get-buffer-create " *gnus article copy*"))
 142   (buffer-disable-undo gnus-article-copy)
 143   (or (memq gnus-article-copy gnus-buffer-list)
 144       (setq gnus-buffer-list (cons gnus-article-copy gnus-buffer-list)))
 145   (let ((article-buffer (or article-buffer gnus-article-buffer))
 146         buf)
 147     (if (and (get-buffer article-buffer)
 148              (buffer-name (get-buffer article-buffer)))
 149         (save-excursion
 150           (set-buffer article-buffer)
 151           (widen)
 152           (setq buf (buffer-substring (point-min) (point-max)))
 153           (set-buffer gnus-article-copy)
 154           (erase-buffer)
 155           (insert (format "%s" buf))))))
 156
 157 (defun gnus-xmas-article-push-button (event)
 158   "Check text under the mouse pointer for a callback function.
 159 If the text under the mouse pointer has a `gnus-callback' property,
 160 call it with the value of the `gnus-data' text property."
 161   (interactive "e")
 162   (set-buffer (window-buffer (event-window event)))
 163   (let* ((pos (event-closest-point event))
 164          (data (get-text-property pos 'gnus-data))
 165          (fun (get-text-property pos 'gnus-callback)))
 166     (if fun (funcall fun data))))
 167
 168 (defun gnus-xmas-move-overlay (extent start end &optional buffer)
 169   (set-extent-endpoints extent start end))
 170
 171 ;; Fixed by Christopher Davis <ckd@loiosh.kei.com>.
 172 (defun gnus-xmas-article-add-button (from to fun &optional data)
 173   "Create a button between FROM and TO with callback FUN and data DATA."
 174   (and gnus-article-button-face
 175        (gnus-overlay-put (gnus-make-overlay from to)
 176                          'face gnus-article-button-face))
 177   (add-text-properties
 178    from to
 179    (nconc
 180     (and gnus-article-mouse-face
 181          (list 'mouse-face gnus-article-mouse-face))
 182     (list 'gnus-callback fun)
 183     (and data (list 'gnus-data data))
 184     (list 'highlight t))))
 185
 186 (defun gnus-xmas-window-top-edge (&optional window)
 187   (nth 1 (window-pixel-edges window)))
 188
 189 ;; Select the lowest window on the frame.
 190 (defun gnus-xmas-appt-select-lowest-window ()
 191   (let* ((lowest-window (selected-window))
 192          (bottom-edge (car (cdr (cdr (cdr (window-pixel-edges))))))
 193          (last-window (previous-window))
 194          (window-search t))
 195     (while window-search
 196       (let* ((this-window (next-window))
 197              (next-bottom-edge (car (cdr (cdr (cdr
 198                                                (window-pixel-edges
 199                                                 this-window)))))))
 200         (if (< bottom-edge next-bottom-edge)
 201             (progn
 202               (setq bottom-edge next-bottom-edge)
 203               (setq lowest-window this-window)))
 204
 205         (select-window this-window)
 206         (if (eq last-window this-window)
 207             (progn
 208               (select-window lowest-window)
 209               (setq window-search nil)))))))
 210
 211 (defun gnus-xmas-group-menu-add ()
 212   (easy-menu-add gnus-group-reading-menu)
 213   (easy-menu-add gnus-group-group-menu)
 214   (easy-menu-add gnus-group-misc-menu))
 215
 216 (defun gnus-xmas-summary-menu-add ()
 217   (easy-menu-add gnus-summary-article-menu)
 218   (easy-menu-add gnus-summary-thread-menu)
 219   (easy-menu-add gnus-summary-misc-menu)
 220   (easy-menu-add gnus-summary-post-menu)
 221   (easy-menu-add gnus-summary-kill-menu))
 222
 223 (defun gnus-xmas-article-menu-add ()
 224   (easy-menu-add gnus-article-article-menu)
 225   (easy-menu-add gnus-article-treatment-menu))
 226
 227 (defun gnus-xmas-read-event-char ()
 228   "Get the next event."
 229   (let ((event (next-event)))
 230     ;; We junk all non-key events.  Is this naughty?
 231     (while (not (key-press-even-p event))
 232       (setq event (next-event)))
 233     (cons (and (key-press-event-p event)
 234                (numberp (event-key event))
 235                (event-to-character event))
 236           event)))
 237
 238 (defun gnus-xmas-define ()
 239   (setq gnus-mouse-2 [button2])
 240
 241   (or (memq 'underline (list-faces))
 242       (and (fboundp 'make-face)
 243            (funcall (intern "make-face") 'underline)))
 244   ;; Must avoid calling set-face-underline-p directly, because it
 245   ;; is a defsubst in emacs19, and will make the .elc files non
 246   ;; portable!
 247   (or (face-differs-from-default-p 'underline)
 248       (funcall (intern "set-face-underline-p") 'underline t))
 249
 250   (fset 'gnus-make-overlay 'make-extent)
 251   (fset 'gnus-overlay-put 'set-extent-property)
 252   (fset 'gnus-move-overlay 'gnus-xmas-move-overlay)
 253
 254   (fset 'set-text-properties 'gnus-xmas-set-text-properties)
 255
 256   (or (boundp 'standard-display-table) (setq standard-display-table nil))
 257
 258   (defvar gnus-mouse-face-prop 'highlight)
 259
 260   (defun gnus-byte-code (func)
 261     "Return a form that can be `eval'ed based on FUNC."
 262     (let ((fval (symbol-function func)))
 263       (if (byte-code-function-p fval)
 264           (list 'funcall fval)
 265         (cons 'progn (cdr (cdr fval))))))
 266
 267   ;; Fix by "jeff (j.d.) sparkes" <jsparkes@bnr.ca>.
 268   (defvar gnus-display-type (device-class)
 269     "A symbol indicating the display Emacs is running under.
 270 The symbol should be one of `color', `grayscale' or `mono'. If Emacs
 271 guesses this display attribute wrongly, either set this variable in
 272 your `~/.emacs' or set the resource `Emacs.displayType' in your
 273 `~/.Xdefaults'. See also `gnus-background-mode'.
 274
 275 This is a meta-variable that will affect what default values other
 276 variables get.  You would normally not change this variable, but
 277 pounce directly on the real variables themselves.")
 278
 279
 280   (or (fboundp 'x-color-values)
 281       (fset 'x-color-values
 282             (lambda (color)
 283               (color-instance-rgb-components
 284                (make-color-instance color)))))
 285
 286   (defvar gnus-background-mode
 287     (let ((bg-resource
 288            (condition-case ()
 289                (x-get-resource ".backgroundMode" "BackgroundMode" 'string)
 290              (error nil)))
 291           (params (frame-parameters)))
 292       (cond (bg-resource (intern (downcase bg-resource)))
 293             ((and (assq 'background-color params)
 294                   (< (apply '+ (x-color-values
 295                                 (cdr (assq 'background-color params))))
 296                      (/ (apply '+ (x-color-values "white")) 3)))
 297              'dark)
 298             (t 'light)))
 299     "A symbol indicating the Emacs background brightness.
 300 The symbol should be one of `light' or `dark'.
 301 If Emacs guesses this frame attribute wrongly, either set this variable in
 302 your `~/.emacs' or set the resource `Emacs.backgroundMode' in your
 303 `~/.Xdefaults'.
 304 See also `gnus-display-type'.
 305
 306 This is a meta-variable that will affect what default values other
 307 variables get.  You would normally not change this variable, but
 308 pounce directly on the real variables themselves.")
 309   )
 310
 311
 312
 313 (defun gnus-xmas-redefine ()
 314   "Redefine lots of Gnus functions for XEmacs."
 315   (fset 'gnus-summary-make-display-table (lambda () nil))
 316   (fset 'gnus-visual-turn-off-edit-menu 'identity)
 317   (fset 'gnus-highlight-selected-summary
 318         'gnus-xmas-highlight-selected-summary)
 319   (fset 'gnus-summary-recenter 'gnus-xmas-summary-recenter)
 320   (fset 'gnus-group-remove-excess-properties
 321         'gnus-xmas-group-remove-excess-properties)
 322   (fset 'gnus-copy-article-buffer 'gnus-xmas-copy-article-buffer)
 323   (fset 'gnus-article-push-button 'gnus-xmas-article-push-button)
 324   (fset 'gnus-article-add-button 'gnus-xmas-article-add-button)
 325   (fset 'gnus-window-top-edge 'gnus-xmas-window-top-edge)
 326   (fset 'set-text-properties 'gnus-xmas-set-text-properties)
 327   (fset 'gnus-read-event-char 'gnus-xmas-read-event-char)
 328   (fset 'gnus-group-startup-message 'gnus-xmas-group-startup-message)
 329
 330   (or (fboundp 'appt-select-lowest-window)
 331       (fset 'appt-select-lowest-window
 332             'gnus-xmas-appt-select-lowest-window))
 333
 334   (add-hook 'gnus-group-mode-hook 'gnus-xmas-group-menu-add)
 335   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-summary-menu-add)
 336   (add-hook 'gnus-article-mode-hook 'gnus-xmas-article-menu-add)
 337
 338   (add-hook 'gnus-group-mode-hook 'gnus-xmas-setup-group-toolbar)
 339   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-setup-summary-toolbar))
 340
 341
 342 ;;; XEmacs logo and toolbar.
 343
 344 (defun gnus-xmas-find-glyph-directory ()
 345   (or gnus-xmas-glyph-directory ; We have a dir already...
 346       (let ((path load-path)
 347             dir)
 348         ;; We try to find the dir by looking at the load path,
 349         ;; stripping away the last component and adding "etc/".
 350         (while path
 351           (setq dir (concat
 352                      (file-name-directory (directory-file-name (car path)))
 353                      "etc/"))
 354           (if (and (file-exists-p dir)
 355                    (file-directory-p dir)
 356                    (file-exists-p (concat dir "gnus-group-exit-icon-up.xpm")))
 357               (setq gnus-xmas-glyph-directory dir
 358                     path nil)
 359             (setq path (cdr path))))
 360         gnus-xmas-glyph-directory)))
 361
 362 (defun gnus-xmas-group-startup-message (&optional x y)
 363   "Insert startup message in current buffer."
 364   ;; Insert the message.
 365   (gnus-xmas-find-glyph-directory)
 366   (erase-buffer)
 367   (let ((file (and gnus-xmas-glyph-directory
 368                    (concat
 369                     (file-name-as-directory gnus-xmas-glyph-directory)
 370                     "gnus.xpm"))))
 371     (if (and (featurep 'xpm)
 372              (not (equal (device-type) 'tty))
 373              file (file-exists-p file))
 374         (progn
 375           (set-glyph-property gnus-xmas-logo 'image file)
 376           (set-glyph-image gnus-xmas-logo file 'global 'x)
 377
 378           (insert " ")
 379           (set-extent-begin-glyph (make-extent (point) (point)) gnus-xmas-logo)
 380           (goto-char (point-min))
 381           (while (not (eobp))
 382             (insert (make-string (/ (max (- (window-width) (or x 35)) 0) 2)
 383                                  ? ))
 384             (forward-line 1))
 385           (goto-char (point-min))
 386           (let* ((pheight (+ 20 (count-lines (point-min) (point-max))))
 387                  (wheight (window-height))
 388                  (rest (- wheight pheight)))
 389             (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n))))
 390
 391       (insert
 392        (format "              %s
 393           _    ___ _             _
 394           _ ___ __ ___  __    _ ___
 395           __   _     ___    __  ___
 396               _           ___     _
 397              _  _ __             _
 398              ___   __            _
 399                    __           _
 400                     _      _   _
 401                    _      _    _
 402                       _  _    _
 403                   __  ___
 404                  _   _ _     _
 405                 _   _
 406               _    _
 407              _    _
 408             _
 409           __
 410
 411 "
 412                ""))
 413       ;; And then hack it.
 414       (gnus-indent-rigidly (point-min) (point-max)
 415                            (/ (max (- (window-width) (or x 46)) 0) 2))
 416       (goto-char (point-min))
 417       (forward-line 1)
 418       (let* ((pheight (count-lines (point-min) (point-max)))
 419              (wheight (window-height))
 420              (rest (- wheight pheight)))
 421         (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n))))
 422     ;; Fontify some.
 423     (goto-char (point-min))
 424     (and (search-forward "Praxis" nil t)
 425          (put-text-property (match-beginning 0) (match-end 0) 'face 'bold))
 426     (goto-char (point-min))
 427     (let* ((mode-string (gnus-group-set-mode-line)))
 428       (setq mode-line-buffer-identification
 429             (list (concat gnus-version (substring (car mode-string) 4))))
 430       (set-buffer-modified-p t))))
 431
 432
 433 ;;; The toolbar.
 434
 435 (defvar gnus-use-toolbar 'default-toolbar
 436   "*If nil, do not use a toolbar.
 437 If it is non-nil, it must be a toolbar.  The five legal values are
 438 `default-toolbar', `top-toolbar', `bottom-toolbar',
 439 `right-toolbar', and `left-toolbar'.")
 440
 441 (defvar gnus-group-toolbar
 442   '([gnus-group-exit-icon gnus-group-exit t "Exit Gnus"]
 443     [gnus-group-kill-group-icon gnus-group-kill-group t "Kill group"]
 444     [gnus-group-get-new-news-icon gnus-group-get-new-news t "Get new news"]
 445     [gnus-group-get-new-news-this-group-icon
 446      gnus-group-get-new-news-this-group t "Get new news in this group"]
 447     [gnus-group-catchup-current-icon
 448      gnus-group-catchup-current t "Catchup group"]
 449     [gnus-group-describe-group-icon
 450      gnus-group-describe-group t "Describe group"])
 451   "The group buffer toolbar.")
 452
 453 (defvar gnus-summary-toolbar
 454   '([gnus-summary-post-news-icon
 455      gnus-summary-post-news t "Post an article"]
 456     [gnus-summary-save-article-file-icon
 457      gnus-summary-save-article-file t "Save article in file"]
 458     [gnus-summary-save-article-icon
 459      gnus-summary-save-article t "Save article"]
 460     [gnus-summary-reply-icon
 461      gnus-summary-reply t "Mail a reply"]
 462     [gnus-summary-reply-with-original-icon
 463      gnus-summary-reply-with-original t "Mail a reply and yank the original"]
 464     [gnus-summary-followup-icon
 465      gnus-summary-followup t "Post a followup"]
 466     [gnus-summary-followup-with-original-icon
 467      gnus-summary-followup-with-original t
 468      "Post a followup and yank the original"]
 469     [gnus-uu-decode-uu-icon
 470      gnus-uu-decode-uu t "Decode uuencoded articles"]
 471     [gnus-uu-post-news-icon
 472      gnus-uu-post-news t "Post an uuencoded article"]
 473     [gnus-summary-caesar-message-icon
 474      gnus-summary-caesar-message t "Rot 13"]
 475     [gnus-summary-cancel-article-icon
 476      gnus-summary-cancel-article t "Cancel article"])
 477   "The summary buffer toolbar.")
 478
 479 (defun gnus-xmas-setup-toolbar (bar &optional force)
 480   (let ((dir (gnus-xmas-find-glyph-directory))
 481         icon up down disabled name)
 482     (if (not dir)
 483         ()
 484       (if (and (not force)
 485                (boundp (aref (car bar) 0)))
 486           dir
 487         (while bar
 488           (setq icon (aref (car bar) 0)
 489                 name (symbol-name icon)
 490                 bar (cdr bar))
 491           (setq up (concat dir name "-up.xpm"))
 492           (setq down (concat dir name "-down.xpm"))
 493           (setq disabled (concat dir name "-disabled.xpm"))
 494           (if (not (file-exists-p up))
 495               (set icon nil)
 496             (set icon (toolbar-make-button-list
 497                        up (and (file-exists-p down) down)
 498                        (and (file-exists-p disabled) disabled)))))
 499         dir))))
 500
 501 (defun gnus-xmas-setup-group-toolbar ()
 502   (and gnus-use-toolbar
 503        (gnus-xmas-setup-toolbar gnus-group-toolbar)
 504        (set-specifier (symbol-value gnus-use-toolbar)
 505                       (cons (current-buffer) gnus-group-toolbar))))
 506
 507 (defun gnus-xmas-setup-summary-toolbar ()
 508   (and gnus-use-toolbar
 509        (gnus-xmas-setup-toolbar gnus-summary-toolbar)
 510        (set-specifier (symbol-value gnus-use-toolbar)
 511                       (cons (current-buffer) gnus-summary-toolbar))))
 512
 513 ;;; gnus-xmas.el ends here