cgit.sxemacs.org Git - gnus/blob - lisp/gnus-xmas.el

   1 ;;; gnus-xmal.el --- Gnus functions for XEmacs
   2 ;; Copyright (C) 1995 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'mode-motion)
  28 (require 'text-props)
  29
  30 (defvar gnus-xmas-glyph-directory nil
  31   "*Directory where Gnus logos and icons are located.
  32 If this variable is nil, Gnus will try to locate the directory
  33 automatically.")
  34
  35 ;;; Internal variables.
  36
  37 (defvar gnus-xmas-logo (make-glyph (make-specifier 'image)))
  38
  39 ;; Don't warn about these undefined variables.
  40
  41 (defvar gnus-group-mode-hook)
  42 (defvar gnus-summary-mode-hook)
  43 (defvar gnus-article-mode-hook)
  44
  45 ;;defined in gnus.el
  46 (defvar gnus-active-hashtb)
  47 (defvar gnus-article-buffer)
  48 (defvar gnus-auto-center-summary)
  49 (defvar gnus-buffer-list)
  50 (defvar gnus-current-headers)
  51 (defvar gnus-level-killed)
  52 (defvar gnus-level-zombie)
  53 (defvar gnus-newsgroup-bookmarks)
  54 (defvar gnus-newsgroup-dependencies)
  55 (defvar gnus-newsgroup-selected-overlay)
  56 (defvar gnus-newsrc-hashtb)
  57 (defvar gnus-read-mark)
  58 (defvar gnus-refer-article-method)
  59 (defvar gnus-reffed-article-number)
  60 (defvar gnus-unread-mark)
  61 (defvar gnus-version)
  62 (defvar gnus-view-pseudos)
  63 (defvar gnus-view-pseudos-separately)
  64 (defvar gnus-visual)
  65 (defvar gnus-zombie-list)
  66 ;;defined in gnus-msg.el
  67 (defvar gnus-article-copy)
  68 (defvar gnus-check-before-posting)
  69 ;;defined in gnus-vis.el
  70 (defvar gnus-article-button-face)
  71 (defvar gnus-article-mouse-face)
  72 (defvar gnus-summary-selected-face)
  73 (defvar gnus-group-reading-menu)
  74 (defvar gnus-group-group-menu)
  75 (defvar gnus-group-misc-menu)
  76 (defvar gnus-summary-article-menu)
  77 (defvar gnus-summary-thread-menu)
  78 (defvar gnus-summary-misc-menu)
  79 (defvar gnus-summary-post-menu)
  80 (defvar gnus-summary-kill-menu)
  81 (defvar gnus-article-article-menu)
  82 (defvar gnus-article-treatment-menu)
  83 (defvar gnus-mouse-2)
  84 (defvar standard-display-table)
  85
  86 (defun gnus-xmas-install-mouse-tracker ()
  87   (add-hook 'mode-motion-hook 'mode-motion-highlight-line))
  88
  89 (defun gnus-xmas-set-text-properties (start end props &optional buffer)
  90   "You should NEVER use this function.  It is ideologically blasphemous.
  91 It is provided only to ease porting of broken FSF Emacs programs."
  92   (if (and (stringp buffer) (not (setq buffer (get-buffer buffer))))
  93       nil
  94     (map-extents (lambda (extent ignored)
  95                    (remove-text-properties
  96                     start end
  97                     (list (extent-property extent 'text-prop) nil)
  98                     buffer))
  99                  buffer start end nil nil 'text-prop)
 100     (add-text-properties start end props buffer)))
 101
 102 (defun gnus-xmas-highlight-selected-summary ()
 103   ;; Highlight selected article in summary buffer
 104   (if gnus-summary-selected-face
 105       (progn
 106         (if gnus-newsgroup-selected-overlay
 107             (delete-extent gnus-newsgroup-selected-overlay))
 108         (setq gnus-newsgroup-selected-overlay
 109               (make-extent (gnus-point-at-bol) (gnus-point-at-eol)))
 110         (set-extent-face gnus-newsgroup-selected-overlay
 111                          gnus-summary-selected-face))))
 112
 113 (defun gnus-xmas-summary-recenter ()
 114   (let* ((top (cond ((< (window-height) 4) 0)
 115                     ((< (window-height) 7) 1)
 116                     (t 2)))
 117          (height (- (window-height) 2))
 118          (bottom (save-excursion (goto-char (point-max))
 119                                  (forward-line (- height))
 120                                  (point)))
 121          (window (get-buffer-window (current-buffer))))
 122     (and
 123      ;; The user has to want it,
 124      gnus-auto-center-summary
 125      ;; the article buffer must be displayed,
 126      (get-buffer-window gnus-article-buffer)
 127      ;; Set the window start to either `bottom', which is the biggest
 128      ;; possible valid number, or the second line from the top,
 129      ;; whichever is the least.
 130      (set-window-start
 131       window (min bottom (save-excursion (forward-line (- top))
 132                                          (point)))))))
 133
 134 (defun gnus-xmas-group-insert-group-line-info (group)
 135   (let ((entry (gnus-gethash group gnus-newsrc-hashtb))
 136         (beg (point))
 137         active info)
 138     (if entry
 139         (progn
 140           (setq info (nth 2 entry))
 141           (gnus-group-insert-group-line
 142            nil group (nth 1 info) (nth 3 info) (car entry) (nth 4 info)))
 143       (setq active (gnus-gethash group gnus-active-hashtb))
 144
 145       (gnus-group-insert-group-line
 146        nil group (if (member group gnus-zombie-list) gnus-level-zombie
 147                    gnus-level-killed)
 148        nil (if active (- (1+ (cdr active)) (car active)) 0) nil))
 149     (save-excursion
 150       (goto-char beg)
 151       (remove-text-properties
 152        (1+ (gnus-point-at-bol)) (1+ (gnus-point-at-eol))
 153        '(gnus-group nil)))))
 154
 155 (defun gnus-xmas-copy-article-buffer (&optional article-buffer)
 156   (setq gnus-article-copy (get-buffer-create " *gnus article copy*"))
 157   (buffer-disable-undo gnus-article-copy)
 158   (or (memq gnus-article-copy gnus-buffer-list)
 159       (setq gnus-buffer-list (cons gnus-article-copy gnus-buffer-list)))
 160   (let ((article-buffer (or article-buffer gnus-article-buffer))
 161         buf)
 162     (if (and (get-buffer article-buffer)
 163              (buffer-name (get-buffer article-buffer)))
 164         (save-excursion
 165           (set-buffer article-buffer)
 166           (widen)
 167           (setq buf (buffer-substring (point-min) (point-max)))
 168           (set-buffer gnus-article-copy)
 169           (erase-buffer)
 170           (insert (format "%s" buf))))))
 171
 172 (defun gnus-xmas-article-push-button (event)
 173   "Check text under the mouse pointer for a callback function.
 174 If the text under the mouse pointer has a `gnus-callback' property,
 175 call it with the value of the `gnus-data' text property."
 176   (interactive "e")
 177   (set-buffer (window-buffer (event-window event)))
 178   (let* ((pos (event-closest-point event))
 179          (data (get-text-property pos 'gnus-data))
 180          (fun (get-text-property pos 'gnus-callback)))
 181     (if fun (funcall fun data))))
 182
 183 (defun gnus-xmas-move-overlay (extent start end &optional buffer)
 184   (set-extent-endpoints extent start end))
 185
 186 ;; Fixed by Christopher Davis <ckd@loiosh.kei.com>.
 187 (defun gnus-xmas-article-add-button (from to fun &optional data)
 188   "Create a button between FROM and TO with callback FUN and data DATA."
 189   (and gnus-article-button-face
 190        (gnus-overlay-put (gnus-make-overlay from to)
 191                          'face gnus-article-button-face))
 192   (add-text-properties
 193    from to
 194    (nconc
 195     (and gnus-article-mouse-face
 196          (list 'mouse-face gnus-article-mouse-face))
 197     (list 'gnus-callback fun)
 198     (and data (list 'gnus-data data))
 199     (list 'highlight t))))
 200
 201 (defun gnus-xmas-window-top-edge (&optional window)
 202   (nth 1 (window-pixel-edges window)))
 203
 204 ;; Select the lowest window on the frame.
 205 (defun gnus-xmas-appt-select-lowest-window ()
 206   (let* ((lowest-window (selected-window))
 207          (bottom-edge (car (cdr (cdr (cdr (window-pixel-edges))))))
 208          (last-window (previous-window))
 209          (window-search t))
 210     (while window-search
 211       (let* ((this-window (next-window))
 212              (next-bottom-edge (car (cdr (cdr (cdr
 213                                                (window-pixel-edges
 214                                                 this-window)))))))
 215         (if (< bottom-edge next-bottom-edge)
 216             (progn
 217               (setq bottom-edge next-bottom-edge)
 218               (setq lowest-window this-window)))
 219
 220         (select-window this-window)
 221         (if (eq last-window this-window)
 222             (progn
 223               (select-window lowest-window)
 224               (setq window-search nil)))))))
 225
 226 (defun gnus-xmas-group-menu-add ()
 227   (easy-menu-add gnus-group-reading-menu)
 228   (easy-menu-add gnus-group-group-menu)
 229   (easy-menu-add gnus-group-misc-menu)
 230   (gnus-xmas-install-mouse-tracker))
 231
 232 (defun gnus-xmas-summary-menu-add ()
 233   (easy-menu-add gnus-summary-article-menu)
 234   (easy-menu-add gnus-summary-thread-menu)
 235   (easy-menu-add gnus-summary-misc-menu)
 236   (easy-menu-add gnus-summary-post-menu)
 237   (easy-menu-add gnus-summary-kill-menu)
 238   (gnus-xmas-install-mouse-tracker))
 239
 240 (defun gnus-xmas-article-menu-add ()
 241   (easy-menu-add gnus-article-article-menu)
 242   (easy-menu-add gnus-article-treatment-menu))
 243
 244
 245 (defun gnus-xmas-define ()
 246   (setq gnus-mouse-2 [button2])
 247
 248   (or (memq 'underline (list-faces))
 249       (and (fboundp 'make-face)
 250            (funcall (intern "make-face") 'underline)))
 251   ;; Must avoid calling set-face-underline-p directly, because it
 252   ;; is a defsubst in emacs19, and will make the .elc files non
 253   ;; portable!
 254   (or (face-differs-from-default-p 'underline)
 255       (funcall (intern "set-face-underline-p") 'underline t))
 256
 257   (fset 'gnus-make-overlay 'make-extent)
 258   (fset 'gnus-overlay-put 'set-extent-property)
 259   (fset 'gnus-move-overlay 'gnus-xmas-move-overlay)
 260
 261   (fset 'set-text-properties 'gnus-xmas-set-text-properties)
 262
 263   (or (boundp 'standard-display-table) (setq standard-display-table nil))
 264   (or (boundp 'read-event) (fset 'read-event 'next-command-event))
 265
 266   ;; Fix by "jeff (j.d.) sparkes" <jsparkes@bnr.ca>.
 267   (defvar gnus-display-type (device-class)
 268     "A symbol indicating the display Emacs is running under.
 269 The symbol should be one of `color', `grayscale' or `mono'. If Emacs
 270 guesses this display attribute wrongly, either set this variable in
 271 your `~/.emacs' or set the resource `Emacs.displayType' in your
 272 `~/.Xdefaults'. See also `gnus-background-mode'.
 273
 274 This is a meta-variable that will affect what default values other
 275 variables get.  You would normally not change this variable, but
 276 pounce directly on the real variables themselves.")
 277
 278
 279   (or (fboundp 'x-color-values)
 280       (fset 'x-color-values
 281             (lambda (color)
 282               (color-instance-rgb-components
 283                (make-color-instance color)))))
 284
 285   (defvar gnus-background-mode
 286     (let ((bg-resource
 287            (condition-case ()
 288                (x-get-resource ".backgroundMode" "BackgroundMode" 'string)
 289              (error nil)))
 290           (params (frame-parameters)))
 291       (cond (bg-resource (intern (downcase bg-resource)))
 292             ((and (assq 'background-color params)
 293                   (< (apply '+ (x-color-values
 294                                 (cdr (assq 'background-color params))))
 295                      (/ (apply '+ (x-color-values "white")) 3)))
 296              'dark)
 297             (t 'light)))
 298     "A symbol indicating the Emacs background brightness.
 299 The symbol should be one of `light' or `dark'.
 300 If Emacs guesses this frame attribute wrongly, either set this variable in
 301 your `~/.emacs' or set the resource `Emacs.backgroundMode' in your
 302 `~/.Xdefaults'.
 303 See also `gnus-display-type'.
 304
 305 This is a meta-variable that will affect what default values other
 306 variables get.  You would normally not change this variable, but
 307 pounce directly on the real variables themselves."))
 308
 309
 310
 311 (defun gnus-xmas-redefine ()
 312   (fset 'gnus-mouse-face-function 'identity)
 313   (fset 'gnus-summary-make-display-table (lambda () nil))
 314   (fset 'gnus-visual-turn-off-edit-menu 'identity)
 315   (fset 'gnus-highlight-selected-summary
 316         'gnus-xmas-highlight-selected-summary)
 317   (fset 'gnus-summary-recenter 'gnus-xmas-summary-recenter)
 318   (fset 'gnus-group-insert-group-line-info
 319         'gnus-xmas-group-insert-group-line-info)
 320   (fset 'gnus-copy-article-buffer 'gnus-xmas-copy-article-buffer)
 321   (fset 'gnus-article-push-button 'gnus-xmas-article-push-button)
 322   (fset 'gnus-article-add-button 'gnus-xmas-article-add-button)
 323   (fset 'gnus-window-top-edge 'gnus-xmas-window-top-edge)
 324   (fset 'set-text-properties 'gnus-xmas-set-text-properties)
 325
 326   (or (fboundp 'appt-select-lowest-window)
 327       (fset 'appt-select-lowest-window
 328             'gnus-xnas-appt-select-lowest-window))
 329
 330   (add-hook 'gnus-group-menu-hook 'gnus-xmas-group-menu-add)
 331   (add-hook 'gnus-summary-menu-hook 'gnus-xmas-summary-menu-add)
 332   (add-hook 'gnus-article-menu-hook 'gnus-xmas-article-menu-add)
 333
 334   (add-hook 'gnus-group-mode-hook 'gnus-xmas-setup-group-toolbar)
 335   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-setup-summary-toolbar)
 336
 337   )
 338
 339
 340 ;;; XEmacs logo and toolbar.
 341
 342 (defun gnus-xmas-find-glyph-directory ()
 343   (or gnus-xmas-glyph-directory ; We have a dir already...
 344       (let ((path load-path)
 345             dir)
 346         ;; We try to find the dir by looking at the load path,
 347         ;; stripping away the last component and adding "etc/".
 348         (while path
 349           (setq dir (concat
 350                      (file-name-directory (directory-file-name (car path)))
 351                      "etc/"))
 352           (if (and (file-exists-p dir)
 353                    (file-directory-p dir))
 354               (setq gnus-xmas-glyph-directory dir
 355                     path nil)
 356             (setq path (cdr path))))
 357         gnus-xmas-glyph-directory)))
 358
 359 (defun gnus-xmas-group-startup (&optional x y)
 360   "Insert startup message in current buffer."
 361   ;; Insert the message.
 362   (erase-buffer)
 363   (if (featurep 'xpm)
 364       (progn
 365         (set-glyph-property gnus-xmas-logo 'image  "~/tmp/gnus.xpm")
 366         (set-glyph-image gnus-xmas-logo "~/tmp/gnus.xpm" 'global 'x)
 367
 368         (insert " ")
 369         (set-extent-begin-glyph (make-extent (point) (point)) gnus-xmas-logo)
 370         (insert "
 371    Gnus * A newsreader for Emacsen
 372  A Praxis Release * larsi@ifi.uio.no")
 373         (goto-char (point-min))
 374         (while (not (eobp))
 375           (insert (make-string (/ (max (- (window-width) (or x 35)) 0) 2)
 376                                ? ))
 377           (forward-line 1))
 378         (goto-char (point-min))
 379         ;; +4 is fuzzy factor.
 380         (insert-char ?\n (/ (max (- (window-height) (or y 24)) 0) 2)))
 381
 382     (insert
 383      (format "
 384      %s
 385            A newsreader
 386       for GNU Emacs
 387
 388         Based on GNUS
 389              written by
 390      Masanobu UMEDA
 391
 392        A Praxis Release
 393       larsi@ifi.uio.no
 394 "
 395              gnus-version))
 396     ;; And then hack it.
 397     ;; 18 is the longest line.
 398     (indent-rigidly (point-min) (point-max)
 399                     (/ (max (- (window-width) (or x 28)) 0) 2))
 400     (goto-char (point-min))
 401     ;; +4 is fuzzy factor.
 402     (insert-char ?\n (/ (max (- (window-height) (or y 12)) 0) 2)))
 403
 404   ;; Fontify some.
 405   (goto-char (point-min))
 406   (search-forward "Praxis")
 407   (put-text-property (match-beginning 0) (match-end 0) 'face 'bold)
 408   (goto-char (point-min)))
 409
 410 ;;; The toolbar.
 411
 412 (defvar gnus-use-toolbar 'default-toolbar
 413   "*If nil, do not use a toolbar.
 414 If it is non-nil, it must be a toolbar.  The five legal values are
 415 `default-toolbar', `top-toolbar', `bottom-toolbar',
 416 `right-toolbar', and `left-toolbar'.")
 417
 418 (defvar gnus-group-toolbar
 419   '([gnus-group-exit-icon gnus-group-exit t "Exit Gnus"]
 420     [gnus-group-kill-group-icon gnus-group-kill-group t "Kill group"]
 421     [gnus-group-get-new-news-icon gnus-group-get-new-news t "Get new news"]
 422     [gnus-group-get-new-news-this-group-icon
 423      gnus-group-get-new-news-this-group t "Get new new in this group"]
 424     [gnus-group-catchup-current-icon
 425      gnus-group-catchup-current t "Catchup group"]
 426     [gnus-group-describe-group-icon
 427      gnus-group-describe-group t "Describe group"])
 428   "The group buffer toolbar.")
 429
 430 (defvar gnus-summary-toolbar
 431   '([gnus-summary-post-news-icon
 432      gnus-summary-post-news t "Post an article"]
 433     [gnus-summary-save-article-file-icon
 434      gnus-summary-save-article-file t "Save article in file"]
 435     [gnus-summary-save-article-icon
 436      gnus-summary-save-article t "Save article"]
 437     [gnus-summary-reply-icon
 438      gnus-summary-reply t "Mail a reply"]
 439     [gnus-summary-reply-with-original-icon
 440      gnus-summary-reply-with-original t "Mail a reply and yank the original"]
 441     [gnus-summary-followup-icon
 442      gnus-summary-followup t "Post a followup"]
 443     [gnus-summary-followup-with-original-icon
 444      gnus-summary-followup-with-original t
 445      "Post a followup and yank the original"]
 446     [gnus-uu-decode-uu-icon
 447      gnus-uu-decode-uu t "Decode uuencoded articles"]
 448     [gnus-uu-post-news-icon
 449      gnus-uu-post-news t "Post an uuencoded article"]
 450     [gnus-summary-caesar-message-icon
 451      gnus-summary-caesar-message t "Rot 13"]
 452     [gnus-summary-cancel-article-icon
 453      gnus-summary-cancel-article t "Cancel article"])
 454   "The summary buffer toolbar.")
 455
 456 (defun gnus-xmas-setup-toolbar (bar &optional force)
 457   (let ((dir (file-name-as-directory (gnus-xmas-find-glyph-directory)))
 458         icon up down disabled name)
 459     (if (or (not dir)
 460             (and (not force)
 461                  (boundp (aref (car bar) 0))))
 462         ()
 463       (while bar
 464         (setq icon (aref (car bar) 0)
 465               name (symbol-name icon)
 466               bar (cdr bar))
 467         (setq up (concat dir name "-up.xpm"))
 468         (setq down (concat dir name "-down.xpm"))
 469         (setq disabled (concat dir name "-disabled.xpm"))
 470         (if (not (file-exists-p up))
 471             (set icon nil)
 472           (set icon (toolbar-make-button-list
 473                      up (and (file-exists-p down) down)
 474                      (and (file-exists-p disabled) disabled))))
 475         dir))))
 476
 477 (defun gnus-xmas-setup-group-toolbar ()
 478   (and gnus-use-toolbar
 479        (gnus-xmas-setup-toolbar gnus-group-toolbar)
 480        (set-specifier (symbol-value gnus-use-toolbar)
 481                       (cons (current-buffer) gnus-group-toolbar))))
 482
 483 (defun gnus-xmas-setup-summary-toolbar ()
 484   (and gnus-use-toolbar
 485        (gnus-xmas-setup-toolbar gnus-summary-toolbar)
 486        (set-specifier (symbol-value gnus-use-toolbar)
 487                       (cons (current-buffer) gnus-summary-toolbar))))
 488
 489
 490 ;;; gnus-xmas.el ends here