cgit.sxemacs.org Git - gnus/blob - lisp/gnus-util.el

   1 ;;; gnus-util.el --- utility functions for Gnus
   2 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Nothing in this file depends on any other parts of Gnus -- all
  28 ;; functions and macros in this file are utility functions that are
  29 ;; used by Gnus and may be used by any other package without loading
  30 ;; Gnus first.
  31
  32 ;;; Code:
  33
  34 (require 'custom)
  35 (eval-when-compile (require 'cl))
  36 (require 'nnheader)
  37 (require 'message)
  38 (require 'time-date)
  39
  40 (eval-and-compile
  41   (autoload 'rmail-insert-rmail-file-header "rmail")
  42   (autoload 'rmail-count-new-messages "rmail")
  43   (autoload 'rmail-show-message "rmail"))
  44
  45 (defun gnus-boundp (variable)
  46   "Return non-nil if VARIABLE is bound and non-nil."
  47   (and (boundp variable)
  48        (symbol-value variable)))
  49
  50 (defmacro gnus-eval-in-buffer-window (buffer &rest forms)
  51   "Pop to BUFFER, evaluate FORMS, and then return to the original window."
  52   (let ((tempvar (make-symbol "GnusStartBufferWindow"))
  53         (w (make-symbol "w"))
  54         (buf (make-symbol "buf")))
  55     `(let* ((,tempvar (selected-window))
  56             (,buf ,buffer)
  57             (,w (get-buffer-window ,buf 'visible)))
  58        (unwind-protect
  59            (progn
  60              (if ,w
  61                  (progn
  62                    (select-window ,w)
  63                    (set-buffer (window-buffer ,w)))
  64                (pop-to-buffer ,buf))
  65              ,@forms)
  66          (select-window ,tempvar)))))
  67
  68 (put 'gnus-eval-in-buffer-window 'lisp-indent-function 1)
  69 (put 'gnus-eval-in-buffer-window 'edebug-form-spec '(form body))
  70
  71 (defmacro gnus-intern-safe (string hashtable)
  72   "Set hash value.  Arguments are STRING, VALUE, and HASHTABLE."
  73   `(let ((symbol (intern ,string ,hashtable)))
  74      (or (boundp symbol)
  75          (set symbol nil))
  76      symbol))
  77
  78 ;; Added by Geoffrey T. Dairiki <dairiki@u.washington.edu>.  A safe way
  79 ;; to limit the length of a string.  This function is necessary since
  80 ;; `(substr "abc" 0 30)' pukes with "Args out of range".
  81 (defsubst gnus-limit-string (str width)
  82   (if (> (length str) width)
  83       (substring str 0 width)
  84     str))
  85
  86 (defsubst gnus-functionp (form)
  87   "Return non-nil if FORM is funcallable."
  88   (or (and (symbolp form) (fboundp form))
  89       (and (listp form) (eq (car form) 'lambda))
  90       (byte-code-function-p form)))
  91
  92 (defsubst gnus-goto-char (point)
  93   (and point (goto-char point)))
  94
  95 (defmacro gnus-buffer-exists-p (buffer)
  96   `(let ((buffer ,buffer))
  97      (when buffer
  98        (funcall (if (stringp buffer) 'get-buffer 'buffer-name)
  99                 buffer))))
 100
 101 (defmacro gnus-kill-buffer (buffer)
 102   `(let ((buf ,buffer))
 103      (when (gnus-buffer-exists-p buf)
 104        (kill-buffer buf))))
 105
 106 (fset 'gnus-point-at-bol
 107       (if (fboundp 'point-at-bol)
 108           'point-at-bol
 109         'line-beginning-position))
 110
 111 (fset 'gnus-point-at-eol
 112       (if (fboundp 'point-at-eol)
 113           'point-at-eol
 114         'line-end-position))
 115
 116 (defun gnus-delete-first (elt list)
 117   "Delete by side effect the first occurrence of ELT as a member of LIST."
 118   (if (equal (car list) elt)
 119       (cdr list)
 120     (let ((total list))
 121       (while (and (cdr list)
 122                   (not (equal (cadr list) elt)))
 123         (setq list (cdr list)))
 124       (when (cdr list)
 125         (setcdr list (cddr list)))
 126       total)))
 127
 128 ;; Delete the current line (and the next N lines).
 129 (defmacro gnus-delete-line (&optional n)
 130   `(delete-region (progn (beginning-of-line) (point))
 131                   (progn (forward-line ,(or n 1)) (point))))
 132
 133 (defun gnus-byte-code (func)
 134   "Return a form that can be `eval'ed based on FUNC."
 135   (let ((fval (indirect-function func)))
 136     (if (byte-code-function-p fval)
 137         (let ((flist (append fval nil)))
 138           (setcar flist 'byte-code)
 139           flist)
 140       (cons 'progn (cddr fval)))))
 141
 142 (defun gnus-extract-address-components (from)
 143   (let (name address)
 144     ;; First find the address - the thing with the @ in it.  This may
 145     ;; not be accurate in mail addresses, but does the trick most of
 146     ;; the time in news messages.
 147     (when (string-match "\\b[^@ \t<>]+[!@][^@ \t<>]+\\b" from)
 148       (setq address (substring from (match-beginning 0) (match-end 0))))
 149     ;; Then we check whether the "name <address>" format is used.
 150     (and address
 151          ;; Linear white space is not required.
 152          (string-match (concat "[ \t]*<" (regexp-quote address) ">") from)
 153          (and (setq name (substring from 0 (match-beginning 0)))
 154               ;; Strip any quotes from the name.
 155               (string-match "\".*\"" name)
 156               (setq name (substring name 1 (1- (match-end 0))))))
 157     ;; If not, then "address (name)" is used.
 158     (or name
 159         (and (string-match "(.+)" from)
 160              (setq name (substring from (1+ (match-beginning 0))
 161                                    (1- (match-end 0)))))
 162         (and (string-match "()" from)
 163              (setq name address))
 164         ;; XOVER might not support folded From headers.
 165         (and (string-match "(.*" from)
 166              (setq name (substring from (1+ (match-beginning 0))
 167                                    (match-end 0)))))
 168     (list (if (string= name "") nil name) (or address from))))
 169
 170
 171 (defun gnus-fetch-field (field)
 172   "Return the value of the header FIELD of current article."
 173   (save-excursion
 174     (save-restriction
 175       (let ((case-fold-search t)
 176             (inhibit-point-motion-hooks t))
 177         (nnheader-narrow-to-headers)
 178         (message-fetch-field field)))))
 179
 180 (defun gnus-goto-colon ()
 181   (beginning-of-line)
 182   (search-forward ":" (gnus-point-at-eol) t))
 183
 184 (defun gnus-remove-text-with-property (prop)
 185   "Delete all text in the current buffer with text property PROP."
 186   (save-excursion
 187     (goto-char (point-min))
 188     (while (not (eobp))
 189       (while (get-text-property (point) prop)
 190         (delete-char 1))
 191       (goto-char (next-single-property-change (point) prop nil (point-max))))))
 192
 193 (defun gnus-newsgroup-directory-form (newsgroup)
 194   "Make hierarchical directory name from NEWSGROUP name."
 195   (let ((newsgroup (gnus-newsgroup-savable-name newsgroup))
 196         (len (length newsgroup))
 197         idx)
 198     ;; If this is a foreign group, we don't want to translate the
 199     ;; entire name.
 200     (if (setq idx (string-match ":" newsgroup))
 201         (aset newsgroup idx ?/)
 202       (setq idx 0))
 203     ;; Replace all occurrences of `.' with `/'.
 204     (while (< idx len)
 205       (when (= (aref newsgroup idx) ?.)
 206         (aset newsgroup idx ?/))
 207       (setq idx (1+ idx)))
 208     newsgroup))
 209
 210 (defun gnus-newsgroup-savable-name (group)
 211   ;; Replace any slashes in a group name (eg. an ange-ftp nndoc group)
 212   ;; with dots.
 213   (nnheader-replace-chars-in-string group ?/ ?.))
 214
 215 (defun gnus-string> (s1 s2)
 216   (not (or (string< s1 s2)
 217            (string= s1 s2))))
 218
 219 ;;; Time functions.
 220
 221 (defun gnus-file-newer-than (file date)
 222   (let ((fdate (nth 5 (file-attributes file))))
 223     (or (> (car fdate) (car date))
 224         (and (= (car fdate) (car date))
 225              (> (nth 1 fdate) (nth 1 date))))))
 226
 227 ;;; Keymap macros.
 228
 229 (defmacro gnus-local-set-keys (&rest plist)
 230   "Set the keys in PLIST in the current keymap."
 231   `(gnus-define-keys-1 (current-local-map) ',plist))
 232
 233 (defmacro gnus-define-keys (keymap &rest plist)
 234   "Define all keys in PLIST in KEYMAP."
 235   `(gnus-define-keys-1 (quote ,keymap) (quote ,plist)))
 236
 237 (defmacro gnus-define-keys-safe (keymap &rest plist)
 238   "Define all keys in PLIST in KEYMAP without overwriting previous definitions."
 239   `(gnus-define-keys-1 (quote ,keymap) (quote ,plist) t))
 240
 241 (put 'gnus-define-keys 'lisp-indent-function 1)
 242 (put 'gnus-define-keys-safe 'lisp-indent-function 1)
 243 (put 'gnus-local-set-keys 'lisp-indent-function 1)
 244
 245 (defmacro gnus-define-keymap (keymap &rest plist)
 246   "Define all keys in PLIST in KEYMAP."
 247   `(gnus-define-keys-1 ,keymap (quote ,plist)))
 248
 249 (put 'gnus-define-keymap 'lisp-indent-function 1)
 250
 251 (defun gnus-define-keys-1 (keymap plist &optional safe)
 252   (when (null keymap)
 253     (error "Can't set keys in a null keymap"))
 254   (cond ((symbolp keymap)
 255          (setq keymap (symbol-value keymap)))
 256         ((keymapp keymap))
 257         ((listp keymap)
 258          (set (car keymap) nil)
 259          (define-prefix-command (car keymap))
 260          (define-key (symbol-value (caddr keymap)) (cadr keymap) (car keymap))
 261          (setq keymap (symbol-value (car keymap)))))
 262   (let (key)
 263     (while plist
 264       (when (symbolp (setq key (pop plist)))
 265         (setq key (symbol-value key)))
 266       (if (or (not safe)
 267               (eq (lookup-key keymap key) 'undefined))
 268           (define-key keymap key (pop plist))
 269         (pop plist)))))
 270
 271 (defun gnus-completing-read (default prompt &rest args)
 272   ;; Like `completing-read', except that DEFAULT is the default argument.
 273   (let* ((prompt (if default
 274                      (concat prompt " (default " default ") ")
 275                    (concat prompt " ")))
 276          (answer (apply 'completing-read prompt args)))
 277     (if (or (null answer) (zerop (length answer)))
 278         default
 279       answer)))
 280
 281 ;; Two silly functions to ensure that all `y-or-n-p' questions clear
 282 ;; the echo area.
 283 (defun gnus-y-or-n-p (prompt)
 284   (prog1
 285       (y-or-n-p prompt)
 286     (message "")))
 287
 288 (defun gnus-yes-or-no-p (prompt)
 289   (prog1
 290       (yes-or-no-p prompt)
 291     (message "")))
 292
 293 (defun gnus-dd-mmm (messy-date)
 294   "Return a string like DD-MMM from a big messy string."
 295   (condition-case ()
 296       (format-time-string "%d-%b" (safe-date-to-time messy-date))
 297     (error "  -   ")))
 298
 299 (defmacro gnus-date-get-time (date)
 300   "Convert DATE string to Emacs time.
 301 Cache the result as a text property stored in DATE."
 302   ;; Either return the cached value...
 303   `(let ((d ,date))
 304      (if (equal "" d)
 305          '(0 0)
 306        (or (get-text-property 0 'gnus-time d)
 307            ;; or compute the value...
 308            (let ((time (safe-date-to-time d)))
 309              ;; and store it back in the string.
 310              (put-text-property 0 1 'gnus-time time d)
 311              time)))))
 312
 313 (defsubst gnus-time-iso8601 (time)
 314   "Return a string of TIME in YYMMDDTHHMMSS format."
 315   (format-time-string "%Y%m%dT%H%M%S" time))
 316
 317 (defun gnus-date-iso8601 (date)
 318   "Convert the DATE to YYMMDDTHHMMSS."
 319   (condition-case ()
 320       (gnus-time-iso8601 (gnus-date-get-time date))
 321     (error "")))
 322
 323 (defun gnus-mode-string-quote (string)
 324   "Quote all \"%\"'s in STRING."
 325   (save-excursion
 326     (gnus-set-work-buffer)
 327     (insert string)
 328     (goto-char (point-min))
 329     (while (search-forward "%" nil t)
 330       (insert "%"))
 331     (buffer-string)))
 332
 333 ;; Make a hash table (default and minimum size is 256).
 334 ;; Optional argument HASHSIZE specifies the table size.
 335 (defun gnus-make-hashtable (&optional hashsize)
 336   (make-vector (if hashsize (max (gnus-create-hash-size hashsize) 256) 256) 0))
 337
 338 ;; Make a number that is suitable for hashing; bigger than MIN and
 339 ;; equal to some 2^x.  Many machines (such as sparcs) do not have a
 340 ;; hardware modulo operation, so they implement it in software.  On
 341 ;; many sparcs over 50% of the time to intern is spent in the modulo.
 342 ;; Yes, it's slower than actually computing the hash from the string!
 343 ;; So we use powers of 2 so people can optimize the modulo to a mask.
 344 (defun gnus-create-hash-size (min)
 345   (let ((i 1))
 346     (while (< i min)
 347       (setq i (* 2 i)))
 348     i))
 349
 350 (defcustom gnus-verbose 7
 351   "*Integer that says how verbose Gnus should be.
 352 The higher the number, the more messages Gnus will flash to say what
 353 it's doing.  At zero, Gnus will be totally mute; at five, Gnus will
 354 display most important messages; and at ten, Gnus will keep on
 355 jabbering all the time."
 356   :group 'gnus-start
 357   :type 'integer)
 358
 359 ;; Show message if message has a lower level than `gnus-verbose'.
 360 ;; Guideline for numbers:
 361 ;; 1 - error messages, 3 - non-serious error messages, 5 - messages
 362 ;; for things that take a long time, 7 - not very important messages
 363 ;; on stuff, 9 - messages inside loops.
 364 (defun gnus-message (level &rest args)
 365   (if (<= level gnus-verbose)
 366       (apply 'message args)
 367     ;; We have to do this format thingy here even if the result isn't
 368     ;; shown - the return value has to be the same as the return value
 369     ;; from `message'.
 370     (apply 'format args)))
 371
 372 (defun gnus-error (level &rest args)
 373   "Beep an error if LEVEL is equal to or less than `gnus-verbose'."
 374   (when (<= (floor level) gnus-verbose)
 375     (apply 'message args)
 376     (ding)
 377     (let (duration)
 378       (when (and (floatp level)
 379                  (not (zerop (setq duration (* 10 (- level (floor level)))))))
 380         (sit-for duration))))
 381   nil)
 382
 383 (defun gnus-split-references (references)
 384   "Return a list of Message-IDs in REFERENCES."
 385   (let ((beg 0)
 386         ids)
 387     (while (string-match "<[^>]+>" references beg)
 388       (push (substring references (match-beginning 0) (setq beg (match-end 0)))
 389             ids))
 390     (nreverse ids)))
 391
 392 (defsubst gnus-parent-id (references &optional n)
 393   "Return the last Message-ID in REFERENCES.
 394 If N, return the Nth ancestor instead."
 395   (when references
 396     (let ((ids (inline (gnus-split-references references))))
 397       (while (nthcdr (or n 1) ids)
 398         (setq ids (cdr ids)))
 399       (car ids))))
 400
 401 (defsubst gnus-buffer-live-p (buffer)
 402   "Say whether BUFFER is alive or not."
 403   (and buffer
 404        (get-buffer buffer)
 405        (buffer-name (get-buffer buffer))))
 406
 407 (defun gnus-horizontal-recenter ()
 408   "Recenter the current buffer horizontally."
 409   (if (< (current-column) (/ (window-width) 2))
 410       (set-window-hscroll (get-buffer-window (current-buffer) t) 0)
 411     (let* ((orig (point))
 412            (end (window-end (get-buffer-window (current-buffer) t)))
 413            (max 0))
 414       (when end
 415         ;; Find the longest line currently displayed in the window.
 416         (goto-char (window-start))
 417         (while (and (not (eobp))
 418                     (< (point) end))
 419           (end-of-line)
 420           (setq max (max max (current-column)))
 421           (forward-line 1))
 422         (goto-char orig)
 423         ;; Scroll horizontally to center (sort of) the point.
 424         (if (> max (window-width))
 425             (set-window-hscroll
 426              (get-buffer-window (current-buffer) t)
 427              (min (- (current-column) (/ (window-width) 3))
 428                   (+ 2 (- max (window-width)))))
 429           (set-window-hscroll (get-buffer-window (current-buffer) t) 0))
 430         max))))
 431
 432 (defun gnus-read-event-char ()
 433   "Get the next event."
 434   (let ((event (read-event)))
 435     ;; should be gnus-characterp, but this can't be called in XEmacs anyway
 436     (cons (and (numberp event) event) event)))
 437
 438 (defun gnus-sortable-date (date)
 439   "Make string suitable for sorting from DATE."
 440   (gnus-time-iso8601 (date-to-time date)))
 441
 442 (defun gnus-copy-file (file &optional to)
 443   "Copy FILE to TO."
 444   (interactive
 445    (list (read-file-name "Copy file: " default-directory)
 446          (read-file-name "Copy file to: " default-directory)))
 447   (unless to
 448     (setq to (read-file-name "Copy file to: " default-directory)))
 449   (when (file-directory-p to)
 450     (setq to (concat (file-name-as-directory to)
 451                      (file-name-nondirectory file))))
 452   (copy-file file to))
 453
 454 (defun gnus-kill-all-overlays ()
 455   "Delete all overlays in the current buffer."
 456   (let* ((overlayss (overlay-lists))
 457          (buffer-read-only nil)
 458          (overlays (delq nil (nconc (car overlayss) (cdr overlayss)))))
 459     (while overlays
 460       (delete-overlay (pop overlays)))))
 461
 462 (defvar gnus-work-buffer " *gnus work*")
 463
 464 (defun gnus-set-work-buffer ()
 465   "Put point in the empty Gnus work buffer."
 466   (if (get-buffer gnus-work-buffer)
 467       (progn
 468         (set-buffer gnus-work-buffer)
 469         (erase-buffer))
 470     (set-buffer (gnus-get-buffer-create gnus-work-buffer))
 471     (kill-all-local-variables)
 472     (mm-enable-multibyte)))
 473
 474 (defmacro gnus-group-real-name (group)
 475   "Find the real name of a foreign newsgroup."
 476   `(let ((gname ,group))
 477      (if (string-match "^[^:]+:" gname)
 478          (substring gname (match-end 0))
 479        gname)))
 480
 481 (defun gnus-make-sort-function (funs)
 482   "Return a composite sort condition based on the functions in FUNC."
 483   (cond
 484    ;; Just a simple function.
 485    ((gnus-functionp funs) funs)
 486    ;; No functions at all.
 487    ((null funs) funs)
 488    ;; A list of functions.
 489    ((or (cdr funs)
 490         (listp (car funs)))
 491     `(lambda (t1 t2)
 492        ,(gnus-make-sort-function-1 (reverse funs))))
 493    ;; A list containing just one function.
 494    (t
 495     (car funs))))
 496
 497 (defun gnus-make-sort-function-1 (funs)
 498   "Return a composite sort condition based on the functions in FUNC."
 499   (let ((function (car funs))
 500         (first 't1)
 501         (last 't2))
 502     (when (consp function)
 503       (cond
 504        ;; Reversed spec.
 505        ((eq (car function) 'not)
 506         (setq function (cadr function)
 507               first 't2
 508               last 't1))
 509        ((gnus-functionp function)
 510         ;; Do nothing.
 511         )
 512        (t
 513         (error "Invalid sort spec: %s" function))))
 514     (if (cdr funs)
 515         `(or (,function ,first ,last)
 516              (and (not (,function ,last ,first))
 517                   ,(gnus-make-sort-function-1 (cdr funs))))
 518       `(,function ,first ,last))))
 519
 520 (defun gnus-turn-off-edit-menu (type)
 521   "Turn off edit menu in `gnus-TYPE-mode-map'."
 522   (define-key (symbol-value (intern (format "gnus-%s-mode-map" type)))
 523     [menu-bar edit] 'undefined))
 524
 525 (defun gnus-prin1 (form)
 526   "Use `prin1' on FORM in the current buffer.
 527 Bind `print-quoted' and `print-readably' to t while printing."
 528   (let ((print-quoted t)
 529         (print-readably t)
 530         (print-escape-multibyte nil)
 531         print-level print-length)
 532     (prin1 form (current-buffer))))
 533
 534 (defun gnus-prin1-to-string (form)
 535   "The same as `prin1', but bind `print-quoted' and `print-readably' to t."
 536   (let ((print-quoted t)
 537         (print-readably t))
 538     (prin1-to-string form)))
 539
 540 (defun gnus-make-directory (directory)
 541   "Make DIRECTORY (and all its parents) if it doesn't exist."
 542   (when (and directory
 543              (not (file-exists-p directory)))
 544     (make-directory directory t))
 545   t)
 546
 547 (defun gnus-write-buffer (file)
 548   "Write the current buffer's contents to FILE."
 549   ;; Make sure the directory exists.
 550   (gnus-make-directory (file-name-directory file))
 551   ;; Write the buffer.
 552   (write-region (point-min) (point-max) file nil 'quietly))
 553
 554 (defun gnus-delete-file (file)
 555   "Delete FILE if it exists."
 556   (when (file-exists-p file)
 557     (delete-file file)))
 558
 559 (defun gnus-strip-whitespace (string)
 560   "Return STRING stripped of all whitespace."
 561   (while (string-match "[\r\n\t ]+" string)
 562     (setq string (replace-match "" t t string)))
 563   string)
 564
 565 (defsubst gnus-put-text-property-excluding-newlines (beg end prop val)
 566   "The same as `put-text-property', but don't put this prop on any newlines in the region."
 567   (save-match-data
 568     (save-excursion
 569       (save-restriction
 570         (goto-char beg)
 571         (while (re-search-forward "[ \t]*\n" end 'move)
 572           (gnus-put-text-property beg (match-beginning 0) prop val)
 573           (setq beg (point)))
 574         (gnus-put-text-property beg (point) prop val)))))
 575
 576 (defun gnus-put-text-property-excluding-characters-with-faces (beg end
 577                                                                    prop val)
 578   "The same as `put-text-property', but don't put props on characters with the `gnus-face' property."
 579   (let ((b beg))
 580     (while (/= b end)
 581       (when (get-text-property b 'gnus-face)
 582         (setq b (next-single-property-change b 'gnus-face nil end)))
 583       (when (/= b end)
 584         (gnus-put-text-property
 585          b (setq b (next-single-property-change b 'gnus-face nil end))
 586          prop val)))))
 587
 588 ;;; Protected and atomic operations.  dmoore@ucsd.edu 21.11.1996
 589 ;;; The primary idea here is to try to protect internal datastructures
 590 ;;; from becoming corrupted when the user hits C-g, or if a hook or
 591 ;;; similar blows up.  Often in Gnus multiple tables/lists need to be
 592 ;;; updated at the same time, or information can be lost.
 593
 594 (defvar gnus-atomic-be-safe t
 595   "If t, certain operations will be protected from interruption by C-g.")
 596
 597 (defmacro gnus-atomic-progn (&rest forms)
 598   "Evaluate FORMS atomically, which means to protect the evaluation
 599 from being interrupted by the user.  An error from the forms themselves
 600 will return without finishing the operation.  Since interrupts from
 601 the user are disabled, it is recommended that only the most minimal
 602 operations are performed by FORMS.  If you wish to assign many
 603 complicated values atomically, compute the results into temporary
 604 variables and then do only the assignment atomically."
 605   `(let ((inhibit-quit gnus-atomic-be-safe))
 606      ,@forms))
 607
 608 (put 'gnus-atomic-progn 'lisp-indent-function 0)
 609
 610 (defmacro gnus-atomic-progn-assign (protect &rest forms)
 611   "Evaluate FORMS, but insure that the variables listed in PROTECT
 612 are not changed if anything in FORMS signals an error or otherwise
 613 non-locally exits.  The variables listed in PROTECT are updated atomically.
 614 It is safe to use gnus-atomic-progn-assign with long computations.
 615
 616 Note that if any of the symbols in PROTECT were unbound, they will be
 617 set to nil on a sucessful assignment.  In case of an error or other
 618 non-local exit, it will still be unbound."
 619   (let* ((temp-sym-map (mapcar (lambda (x) (list (make-symbol
 620                                                   (concat (symbol-name x)
 621                                                           "-tmp"))
 622                                                  x))
 623                                protect))
 624          (sym-temp-map (mapcar (lambda (x) (list (cadr x) (car x)))
 625                                temp-sym-map))
 626          (temp-sym-let (mapcar (lambda (x) (list (car x)
 627                                                  `(and (boundp ',(cadr x))
 628                                                        ,(cadr x))))
 629                                temp-sym-map))
 630          (sym-temp-let sym-temp-map)
 631          (temp-sym-assign (apply 'append temp-sym-map))
 632          (sym-temp-assign (apply 'append sym-temp-map))
 633          (result (make-symbol "result-tmp")))
 634     `(let (,@temp-sym-let
 635            ,result)
 636        (let ,sym-temp-let
 637          (setq ,result (progn ,@forms))
 638          (setq ,@temp-sym-assign))
 639        (let ((inhibit-quit gnus-atomic-be-safe))
 640          (setq ,@sym-temp-assign))
 641        ,result)))
 642
 643 (put 'gnus-atomic-progn-assign 'lisp-indent-function 1)
 644 ;(put 'gnus-atomic-progn-assign 'edebug-form-spec '(sexp body))
 645
 646 (defmacro gnus-atomic-setq (&rest pairs)
 647   "Similar to setq, except that the real symbols are only assigned when
 648 there are no errors.  And when the real symbols are assigned, they are
 649 done so atomically.  If other variables might be changed via side-effect,
 650 see gnus-atomic-progn-assign.  It is safe to use gnus-atomic-setq
 651 with potentially long computations."
 652   (let ((tpairs pairs)
 653         syms)
 654     (while tpairs
 655       (push (car tpairs) syms)
 656       (setq tpairs (cddr tpairs)))
 657     `(gnus-atomic-progn-assign ,syms
 658        (setq ,@pairs))))
 659
 660 ;(put 'gnus-atomic-setq 'edebug-form-spec '(body))
 661
 662
 663 ;;; Functions for saving to babyl/mail files.
 664
 665 (defvar rmail-default-rmail-file)
 666 (defun gnus-output-to-rmail (filename &optional ask)
 667   "Append the current article to an Rmail file named FILENAME."
 668   (require 'rmail)
 669   ;; Most of these codes are borrowed from rmailout.el.
 670   (setq filename (expand-file-name filename))
 671   (setq rmail-default-rmail-file filename)
 672   (let ((artbuf (current-buffer))
 673         (tmpbuf (get-buffer-create " *Gnus-output*")))
 674     (save-excursion
 675       (or (get-file-buffer filename)
 676           (file-exists-p filename)
 677           (if (or (not ask)
 678                   (gnus-yes-or-no-p
 679                    (concat "\"" filename "\" does not exist, create it? ")))
 680               (let ((file-buffer (create-file-buffer filename)))
 681                 (save-excursion
 682                   (set-buffer file-buffer)
 683                   (rmail-insert-rmail-file-header)
 684                   (let ((require-final-newline nil))
 685                     (gnus-write-buffer filename)))
 686                 (kill-buffer file-buffer))
 687             (error "Output file does not exist")))
 688       (set-buffer tmpbuf)
 689       (erase-buffer)
 690       (insert-buffer-substring artbuf)
 691       (gnus-convert-article-to-rmail)
 692       ;; Decide whether to append to a file or to an Emacs buffer.
 693       (let ((outbuf (get-file-buffer filename)))
 694         (if (not outbuf)
 695             (mm-append-to-file (point-min) (point-max) filename)
 696           ;; File has been visited, in buffer OUTBUF.
 697           (set-buffer outbuf)
 698           (let ((buffer-read-only nil)
 699                 (msg (and (boundp 'rmail-current-message)
 700                           (symbol-value 'rmail-current-message))))
 701             ;; If MSG is non-nil, buffer is in RMAIL mode.
 702             (when msg
 703               (widen)
 704               (narrow-to-region (point-max) (point-max)))
 705             (insert-buffer-substring tmpbuf)
 706             (when msg
 707               (goto-char (point-min))
 708               (widen)
 709               (search-backward "\n\^_")
 710               (narrow-to-region (point) (point-max))
 711               (rmail-count-new-messages t)
 712               (when (rmail-summary-exists)
 713                 (rmail-select-summary
 714                  (rmail-update-summary)))
 715               (rmail-count-new-messages t)
 716               (rmail-show-message msg))
 717             (save-buffer)))))
 718     (kill-buffer tmpbuf)))
 719
 720 (defun gnus-output-to-mail (filename &optional ask)
 721   "Append the current article to a mail file named FILENAME."
 722   (setq filename (expand-file-name filename))
 723   (let ((artbuf (current-buffer))
 724         (tmpbuf (get-buffer-create " *Gnus-output*")))
 725     (save-excursion
 726       ;; Create the file, if it doesn't exist.
 727       (when (and (not (get-file-buffer filename))
 728                  (not (file-exists-p filename)))
 729         (if (or (not ask)
 730                 (gnus-y-or-n-p
 731                  (concat "\"" filename "\" does not exist, create it? ")))
 732             (let ((file-buffer (create-file-buffer filename)))
 733               (save-excursion
 734                 (set-buffer file-buffer)
 735                 (let ((require-final-newline nil))
 736                   (gnus-write-buffer filename)))
 737               (kill-buffer file-buffer))
 738           (error "Output file does not exist")))
 739       (set-buffer tmpbuf)
 740       (erase-buffer)
 741       (insert-buffer-substring artbuf)
 742       (goto-char (point-min))
 743       (if (looking-at "From ")
 744           (forward-line 1)
 745         (insert "From nobody " (current-time-string) "\n"))
 746       (let (case-fold-search)
 747         (while (re-search-forward "^From " nil t)
 748           (beginning-of-line)
 749           (insert ">")))
 750       ;; Decide whether to append to a file or to an Emacs buffer.
 751       (let ((outbuf (get-file-buffer filename)))
 752         (if (not outbuf)
 753             (let ((buffer-read-only nil))
 754               (save-excursion
 755                 (goto-char (point-max))
 756                 (forward-char -2)
 757                 (unless (looking-at "\n\n")
 758                   (goto-char (point-max))
 759                   (unless (bolp)
 760                     (insert "\n"))
 761                   (insert "\n"))
 762                 (goto-char (point-max))
 763                 (mm-append-to-file (point-min) (point-max) filename)))
 764           ;; File has been visited, in buffer OUTBUF.
 765           (set-buffer outbuf)
 766           (let ((buffer-read-only nil))
 767             (goto-char (point-max))
 768             (unless (eobp)
 769               (insert "\n"))
 770             (insert "\n")
 771             (insert-buffer-substring tmpbuf)))))
 772     (kill-buffer tmpbuf)))
 773
 774 (defun gnus-convert-article-to-rmail ()
 775   "Convert article in current buffer to Rmail message format."
 776   (let ((buffer-read-only nil))
 777     ;; Convert article directly into Babyl format.
 778     (goto-char (point-min))
 779     (insert "\^L\n0, unseen,,\n*** EOOH ***\n")
 780     (while (search-forward "\n\^_" nil t) ;single char
 781       (replace-match "\n^_" t t))       ;2 chars: "^" and "_"
 782     (goto-char (point-max))
 783     (insert "\^_")))
 784
 785 (defun gnus-map-function (funs arg)
 786   "Applies the result of the first function in FUNS to the second, and so on.
 787 ARG is passed to the first function."
 788   (let ((myfuns funs))
 789     (while myfuns
 790       (setq arg (funcall (pop myfuns) arg)))
 791     arg))
 792
 793 (defun gnus-run-hooks (&rest funcs)
 794   "Does the same as `run-hooks', but saves excursion."
 795   (let ((buf (current-buffer)))
 796     (unwind-protect
 797         (apply 'run-hooks funcs)
 798       (set-buffer buf))))
 799
 800 ;;;
 801 ;;; .netrc and .authinforc parsing
 802 ;;;
 803
 804 (defun gnus-parse-netrc (file)
 805   "Parse FILE and return an list of all entries in the file."
 806   (when (file-exists-p file)
 807     (with-temp-buffer
 808       (let ((tokens '("machine" "default" "login"
 809                       "password" "account" "macdef" "force"
 810                       "port"))
 811             alist elem result pair)
 812         (insert-file-contents file)
 813         (goto-char (point-min))
 814         ;; Go through the file, line by line.
 815         (while (not (eobp))
 816           (narrow-to-region (point) (gnus-point-at-eol))
 817           ;; For each line, get the tokens and values.
 818           (while (not (eobp))
 819             (skip-chars-forward "\t ")
 820             ;; Skip lines that begin with a "#".
 821             (if (eq (char-after) ?#)
 822                 (goto-char (point-max))
 823               (unless (eobp)
 824                 (setq elem
 825                       (if (= (following-char) ?\")
 826                           (read (current-buffer))
 827                         (buffer-substring
 828                          (point) (progn (skip-chars-forward "^\t ")
 829                                         (point)))))
 830                 (cond
 831                  ((equal elem "macdef")
 832                   ;; We skip past the macro definition.
 833                   (widen)
 834                   (while (and (zerop (forward-line 1))
 835                               (looking-at "$")))
 836                   (narrow-to-region (point) (point)))
 837                  ((member elem tokens)
 838                   ;; Tokens that don't have a following value are ignored,
 839                   ;; except "default".
 840                   (when (and pair (or (cdr pair)
 841                                       (equal (car pair) "default")))
 842                     (push pair alist))
 843                   (setq pair (list elem)))
 844                  (t
 845                   ;; Values that haven't got a preceding token are ignored.
 846                   (when pair
 847                     (setcdr pair elem)
 848                     (push pair alist)
 849                     (setq pair nil)))))))
 850           (when alist
 851             (push (nreverse alist) result))
 852           (setq alist nil
 853                 pair nil)
 854           (widen)
 855           (forward-line 1))
 856         (nreverse result)))))
 857
 858 (defun gnus-netrc-machine (list machine &optional port)
 859   "Return the netrc values from LIST for MACHINE or for the default entry."
 860   (let ((rest list)
 861         result)
 862     (while list
 863       (when (equal (cdr (assoc "machine" (car list))) machine)
 864         (push (car list) result))
 865       (pop list))
 866     (unless result
 867       ;; No machine name matches, so we look for default entries.
 868       (while rest
 869         (when (assoc "default" (car rest))
 870           (push (car rest) result))
 871         (pop rest)))
 872     (when result
 873       (setq result (nreverse result))
 874       (while (and result
 875                   (not (equal (or port "nntp")
 876                               (or (gnus-netrc-get (car result) "port")
 877                                   "nntp"))))
 878         (pop result))
 879       (car result))))
 880
 881 (defun gnus-netrc-get (alist type)
 882   "Return the value of token TYPE from ALIST."
 883   (cdr (assoc type alist)))
 884
 885 ;;; Various
 886
 887 (defvar gnus-group-buffer)              ; Compiler directive
 888 (defun gnus-alive-p ()
 889   "Say whether Gnus is running or not."
 890   (and (boundp 'gnus-group-buffer)
 891        (get-buffer gnus-group-buffer)
 892        (save-excursion
 893          (set-buffer gnus-group-buffer)
 894          (eq major-mode 'gnus-group-mode))))
 895
 896 (defun gnus-remove-duplicates (list)
 897   (let (new (tail list))
 898     (while tail
 899       (or (member (car tail) new)
 900           (setq new (cons (car tail) new)))
 901       (setq tail (cdr tail)))
 902     (nreverse new)))
 903
 904 (defun gnus-delete-if (predicate list)
 905   "Delete elements from LIST that satisfy PREDICATE."
 906   (let (out)
 907     (while list
 908       (unless (funcall predicate (car list))
 909         (push (car list) out))
 910       (pop list))
 911     (nreverse out)))
 912
 913 (defun gnus-delete-alist (key alist)
 914   "Delete all entries in ALIST that have a key eq to KEY."
 915   (let (entry)
 916     (while (setq entry (assq key alist))
 917       (setq alist (delq entry alist)))
 918     alist))
 919
 920 (defmacro gnus-pull (key alist &optional assoc-p)
 921   "Modify ALIST to be without KEY."
 922   (unless (symbolp alist)
 923     (error "Not a symbol: %s" alist))
 924   (let ((fun (if assoc-p 'assoc 'assq)))
 925     `(setq ,alist (delq (,fun ,key ,alist) ,alist))))
 926
 927 (defun gnus-globalify-regexp (re)
 928   "Returns a regexp that matches a whole line, iff RE matches a part of it."
 929   (concat (unless (string-match "^\\^" re) "^.*")
 930           re
 931           (unless (string-match "\\$$" re) ".*$")))
 932
 933 (defun gnus-set-window-start (&optional point)
 934   "Set the window start to POINT, or (point) if nil."
 935   (let ((win (get-buffer-window (current-buffer) t)))
 936     (when win
 937       (set-window-start win (or point (point))))))
 938
 939 (defun gnus-annotation-in-region-p (b e)
 940   (if (= b e)
 941       (eq (cadr (memq 'gnus-undeletable (text-properties-at b))) t)
 942     (text-property-any b e 'gnus-undeletable t)))
 943
 944 (defun gnus-or (&rest elems)
 945   "Return non-nil if any of the elements are non-nil."
 946   (catch 'found
 947     (while elems
 948       (when (pop elems)
 949         (throw 'found t)))))
 950
 951 (defun gnus-and (&rest elems)
 952   "Return non-nil if all of the elements are non-nil."
 953   (catch 'found
 954     (while elems
 955       (unless (pop elems)
 956         (throw 'found nil)))
 957     t))
 958
 959 (defun gnus-write-active-file (file hashtb &optional full-names)
 960   (with-temp-file file
 961     (mapatoms
 962      (lambda (sym)
 963        (when (and sym
 964                   (boundp sym)
 965                   (symbol-value sym))
 966          (insert (format "%S %d %d y\n"
 967                          (if full-names
 968                              sym
 969                            (intern (gnus-group-real-name (symbol-name sym))))
 970                          (or (cdr (symbol-value sym))
 971                              (car (symbol-value sym)))
 972                          (car (symbol-value sym))))))
 973      hashtb)
 974     (goto-char (point-max))
 975     (while (search-backward "\\." nil t)
 976       (delete-char 1))))
 977
 978 (provide 'gnus-util)
 979
 980 ;;; gnus-util.el ends here