cgit.sxemacs.org Git - gnus/blob - lisp/gnus-util.el

   1 ;;; gnus-util.el --- utility functions for Gnus
   2 ;; Copyright (C) 1996,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; Nothing in this file depends on any other parts of Gnus -- all
  27 ;; functions and macros in this file are utility functions that are
  28 ;; used by Gnus and may be used by any other package without loading
  29 ;; Gnus first.
  30
  31 ;;; Code:
  32
  33 (require 'custom)
  34 (eval-when-compile (require 'cl))
  35 (require 'nnheader)
  36 (require 'timezone)
  37 (require 'message)
  38
  39 (eval-and-compile
  40   (autoload 'nnmail-date-to-time "nnmail")
  41   (autoload 'rmail-insert-rmail-file-header "rmail")
  42   (autoload 'rmail-count-new-messages "rmail")
  43   (autoload 'rmail-show-message "rmail"))
  44
  45 (defun gnus-boundp (variable)
  46   "Return non-nil if VARIABLE is bound and non-nil."
  47   (and (boundp variable)
  48        (symbol-value variable)))
  49
  50 (defmacro gnus-eval-in-buffer-window (buffer &rest forms)
  51   "Pop to BUFFER, evaluate FORMS, and then return to the original window."
  52   (let ((tempvar (make-symbol "GnusStartBufferWindow"))
  53         (w (make-symbol "w"))
  54         (buf (make-symbol "buf")))
  55     `(let* ((,tempvar (selected-window))
  56             (,buf ,buffer)
  57             (,w (get-buffer-window ,buf 'visible)))
  58        (unwind-protect
  59            (progn
  60              (if ,w
  61                  (progn
  62                    (select-window ,w)
  63                    (set-buffer (window-buffer ,w)))
  64                (pop-to-buffer ,buf))
  65              ,@forms)
  66          (select-window ,tempvar)))))
  67
  68 (put 'gnus-eval-in-buffer-window 'lisp-indent-function 1)
  69 (put 'gnus-eval-in-buffer-window 'edebug-form-spec '(form body))
  70
  71 (defmacro gnus-intern-safe (string hashtable)
  72   "Set hash value.  Arguments are STRING, VALUE, and HASHTABLE."
  73   `(let ((symbol (intern ,string ,hashtable)))
  74      (or (boundp symbol)
  75          (set symbol nil))
  76      symbol))
  77
  78 (defun gnus-truncate-string (str width)
  79   (substring str 0 width))
  80
  81 ;; Added by Geoffrey T. Dairiki <dairiki@u.washington.edu>.  A safe way
  82 ;; to limit the length of a string.  This function is necessary since
  83 ;; `(substr "abc" 0 30)' pukes with "Args out of range".
  84 (defsubst gnus-limit-string (str width)
  85   (if (> (length str) width)
  86       (substring str 0 width)
  87     str))
  88
  89 (defsubst gnus-functionp (form)
  90   "Return non-nil if FORM is funcallable."
  91   (or (and (symbolp form) (fboundp form))
  92       (and (listp form) (eq (car form) 'lambda))
  93       (byte-code-function-p form)))
  94
  95 (defsubst gnus-goto-char (point)
  96   (and point (goto-char point)))
  97
  98 (defmacro gnus-buffer-exists-p (buffer)
  99   `(let ((buffer ,buffer))
 100      (when buffer
 101        (funcall (if (stringp buffer) 'get-buffer 'buffer-name)
 102                 buffer))))
 103
 104 (defmacro gnus-kill-buffer (buffer)
 105   `(let ((buf ,buffer))
 106      (when (gnus-buffer-exists-p buf)
 107        (kill-buffer buf))))
 108
 109 (if (fboundp 'point-at-bol)
 110     (fset 'gnus-point-at-bol 'point-at-bol)
 111   (defun gnus-point-at-bol ()
 112     "Return point at the beginning of the line."
 113     (let ((p (point)))
 114       (beginning-of-line)
 115       (prog1
 116           (point)
 117         (goto-char p)))))
 118
 119 (if (fboundp 'point-at-eol)
 120     (fset 'gnus-point-at-eol 'point-at-eol)
 121   (defun gnus-point-at-eol ()
 122     "Return point at the end of the line."
 123     (let ((p (point)))
 124       (end-of-line)
 125       (prog1
 126           (point)
 127         (goto-char p)))))
 128
 129 (defun gnus-delete-first (elt list)
 130   "Delete by side effect the first occurrence of ELT as a member of LIST."
 131   (if (equal (car list) elt)
 132       (cdr list)
 133     (let ((total list))
 134       (while (and (cdr list)
 135                   (not (equal (cadr list) elt)))
 136         (setq list (cdr list)))
 137       (when (cdr list)
 138         (setcdr list (cddr list)))
 139       total)))
 140
 141 ;; Delete the current line (and the next N lines).
 142 (defmacro gnus-delete-line (&optional n)
 143   `(delete-region (progn (beginning-of-line) (point))
 144                   (progn (forward-line ,(or n 1)) (point))))
 145
 146 (defun gnus-byte-code (func)
 147   "Return a form that can be `eval'ed based on FUNC."
 148   (let ((fval (indirect-function func)))
 149     (if (byte-code-function-p fval)
 150         (let ((flist (append fval nil)))
 151           (setcar flist 'byte-code)
 152           flist)
 153       (cons 'progn (cddr fval)))))
 154
 155 (defun gnus-extract-address-components (from)
 156   (let (name address)
 157     ;; First find the address - the thing with the @ in it.  This may
 158     ;; not be accurate in mail addresses, but does the trick most of
 159     ;; the time in news messages.
 160     (when (string-match "\\b[^@ \t<>]+[!@][^@ \t<>]+\\b" from)
 161       (setq address (substring from (match-beginning 0) (match-end 0))))
 162     ;; Then we check whether the "name <address>" format is used.
 163     (and address
 164          ;; Linear white space is not required.
 165          (string-match (concat "[ \t]*<" (regexp-quote address) ">") from)
 166          (and (setq name (substring from 0 (match-beginning 0)))
 167               ;; Strip any quotes from the name.
 168               (string-match "\".*\"" name)
 169               (setq name (substring name 1 (1- (match-end 0))))))
 170     ;; If not, then "address (name)" is used.
 171     (or name
 172         (and (string-match "(.+)" from)
 173              (setq name (substring from (1+ (match-beginning 0))
 174                                    (1- (match-end 0)))))
 175         (and (string-match "()" from)
 176              (setq name address))
 177         ;; XOVER might not support folded From headers.
 178         (and (string-match "(.*" from)
 179              (setq name (substring from (1+ (match-beginning 0))
 180                                    (match-end 0)))))
 181     ;; Fix by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>.
 182     (list (or name from) (or address from))))
 183
 184 (defun gnus-fetch-field (field)
 185   "Return the value of the header FIELD of current article."
 186   (save-excursion
 187     (save-restriction
 188       (let ((case-fold-search t)
 189             (inhibit-point-motion-hooks t))
 190         (nnheader-narrow-to-headers)
 191         (message-fetch-field field)))))
 192
 193 (defun gnus-goto-colon ()
 194   (beginning-of-line)
 195   (search-forward ":" (gnus-point-at-eol) t))
 196
 197 (defun gnus-remove-text-with-property (prop)
 198   "Delete all text in the current buffer with text property PROP."
 199   (save-excursion
 200     (goto-char (point-min))
 201     (while (not (eobp))
 202       (while (get-text-property (point) prop)
 203         (delete-char 1))
 204       (goto-char (next-single-property-change (point) prop nil (point-max))))))
 205
 206 (defun gnus-newsgroup-directory-form (newsgroup)
 207   "Make hierarchical directory name from NEWSGROUP name."
 208   (let ((newsgroup (gnus-newsgroup-savable-name newsgroup))
 209         (len (length newsgroup))
 210         idx)
 211     ;; If this is a foreign group, we don't want to translate the
 212     ;; entire name.
 213     (if (setq idx (string-match ":" newsgroup))
 214         (aset newsgroup idx ?/)
 215       (setq idx 0))
 216     ;; Replace all occurrences of `.' with `/'.
 217     (while (< idx len)
 218       (when (= (aref newsgroup idx) ?.)
 219         (aset newsgroup idx ?/))
 220       (setq idx (1+ idx)))
 221     newsgroup))
 222
 223 (defun gnus-newsgroup-savable-name (group)
 224   ;; Replace any slashes in a group name (eg. an ange-ftp nndoc group)
 225   ;; with dots.
 226   (nnheader-replace-chars-in-string group ?/ ?.))
 227
 228 (defun gnus-string> (s1 s2)
 229   (not (or (string< s1 s2)
 230            (string= s1 s2))))
 231
 232 ;;; Time functions.
 233
 234 (defun gnus-days-between (date1 date2)
 235   ;; Return the number of days between date1 and date2.
 236   (- (gnus-day-number date1) (gnus-day-number date2)))
 237
 238 (defun gnus-day-number (date)
 239   (let ((dat (mapcar (lambda (s) (and s (string-to-int s)) )
 240                      (timezone-parse-date date))))
 241     (timezone-absolute-from-gregorian
 242      (nth 1 dat) (nth 2 dat) (car dat))))
 243
 244 (defun gnus-time-to-day (time)
 245   "Convert TIME to day number."
 246   (let ((tim (decode-time time)))
 247     (timezone-absolute-from-gregorian
 248      (nth 4 tim) (nth 3 tim) (nth 5 tim))))
 249
 250 (defun gnus-encode-date (date)
 251   "Convert DATE to internal time."
 252   (let* ((parse (timezone-parse-date date))
 253          (date (mapcar (lambda (d) (and d (string-to-int d))) parse))
 254          (time (mapcar 'string-to-int (timezone-parse-time (aref parse 3)))))
 255     (encode-time (caddr time) (cadr time) (car time)
 256                  (caddr date) (cadr date) (car date)
 257                  (* 60 (timezone-zone-to-minute (nth 4 date))))))
 258
 259 (defun gnus-time-minus (t1 t2)
 260   "Subtract two internal times."
 261   (let ((borrow (< (cadr t1) (cadr t2))))
 262     (list (- (car t1) (car t2) (if borrow 1 0))
 263           (- (+ (if borrow 65536 0) (cadr t1)) (cadr t2)))))
 264
 265 (defun gnus-time-less (t1 t2)
 266   "Say whether time T1 is less than time T2."
 267   (or (< (car t1) (car t2))
 268       (and (= (car t1) (car t2))
 269            (< (nth 1 t1) (nth 1 t2)))))
 270
 271 (defun gnus-file-newer-than (file date)
 272   (let ((fdate (nth 5 (file-attributes file))))
 273     (or (> (car fdate) (car date))
 274         (and (= (car fdate) (car date))
 275              (> (nth 1 fdate) (nth 1 date))))))
 276
 277 ;;; Keymap macros.
 278
 279 (defmacro gnus-local-set-keys (&rest plist)
 280   "Set the keys in PLIST in the current keymap."
 281   `(gnus-define-keys-1 (current-local-map) ',plist))
 282
 283 (defmacro gnus-define-keys (keymap &rest plist)
 284   "Define all keys in PLIST in KEYMAP."
 285   `(gnus-define-keys-1 (quote ,keymap) (quote ,plist)))
 286
 287 (defmacro gnus-define-keys-safe (keymap &rest plist)
 288   "Define all keys in PLIST in KEYMAP without overwriting previous definitions."
 289   `(gnus-define-keys-1 (quote ,keymap) (quote ,plist) t))
 290
 291 (put 'gnus-define-keys 'lisp-indent-function 1)
 292 (put 'gnus-define-keys-safe 'lisp-indent-function 1)
 293 (put 'gnus-local-set-keys 'lisp-indent-function 1)
 294
 295 (defmacro gnus-define-keymap (keymap &rest plist)
 296   "Define all keys in PLIST in KEYMAP."
 297   `(gnus-define-keys-1 ,keymap (quote ,plist)))
 298
 299 (put 'gnus-define-keymap 'lisp-indent-function 1)
 300
 301 (defun gnus-define-keys-1 (keymap plist &optional safe)
 302   (when (null keymap)
 303     (error "Can't set keys in a null keymap"))
 304   (cond ((symbolp keymap)
 305          (setq keymap (symbol-value keymap)))
 306         ((keymapp keymap))
 307         ((listp keymap)
 308          (set (car keymap) nil)
 309          (define-prefix-command (car keymap))
 310          (define-key (symbol-value (caddr keymap)) (cadr keymap) (car keymap))
 311          (setq keymap (symbol-value (car keymap)))))
 312   (let (key)
 313     (while plist
 314       (when (symbolp (setq key (pop plist)))
 315         (setq key (symbol-value key)))
 316       (if (or (not safe)
 317               (eq (lookup-key keymap key) 'undefined))
 318           (define-key keymap key (pop plist))
 319         (pop plist)))))
 320
 321 (defun gnus-completing-read (default prompt &rest args)
 322   ;; Like `completing-read', except that DEFAULT is the default argument.
 323   (let* ((prompt (if default
 324                      (concat prompt " (default " default ") ")
 325                    (concat prompt " ")))
 326          (answer (apply 'completing-read prompt args)))
 327     (if (or (null answer) (zerop (length answer)))
 328         default
 329       answer)))
 330
 331 ;; Two silly functions to ensure that all `y-or-n-p' questions clear
 332 ;; the echo area.
 333 (defun gnus-y-or-n-p (prompt)
 334   (prog1
 335       (y-or-n-p prompt)
 336     (message "")))
 337
 338 (defun gnus-yes-or-no-p (prompt)
 339   (prog1
 340       (yes-or-no-p prompt)
 341     (message "")))
 342
 343 ;; I suspect there's a better way, but I haven't taken the time to do
 344 ;; it yet.  -erik selberg@cs.washington.edu
 345 (defun gnus-dd-mmm (messy-date)
 346   "Return a string like DD-MMM from a big messy string"
 347   (if (equal messy-date "")
 348       "??-???"
 349     (let ((datevec (ignore-errors (timezone-parse-date messy-date))))
 350       (if (not datevec)
 351           "??-???"
 352         (format "%2s-%s"
 353                 (condition-case ()
 354                     ;; Make sure leading zeroes are stripped.
 355                     (number-to-string (string-to-number (aref datevec 2)))
 356                   (error "??"))
 357                 (capitalize
 358                  (or (car
 359                       (nth (1- (string-to-number (aref datevec 1)))
 360                            timezone-months-assoc))
 361                      "???")))))))
 362
 363 (defmacro gnus-date-get-time (date)
 364   "Convert DATE string to Emacs time.
 365 Cache the result as a text property stored in DATE."
 366   ;; Either return the cached value...
 367   `(let ((d ,date))
 368      (if (equal "" d)
 369          '(0 0)
 370        (or (get-text-property 0 'gnus-time d)
 371            ;; or compute the value...
 372            (let ((time (nnmail-date-to-time d)))
 373              ;; and store it back in the string.
 374              (put-text-property 0 1 'gnus-time time d)
 375              time)))))
 376
 377 (defsubst gnus-time-iso8601 (time)
 378   "Return a string of TIME in YYMMDDTHHMMSS format."
 379   (format-time-string "%Y%m%dT%H%M%S" time))
 380
 381 (defun gnus-date-iso8601 (date)
 382   "Convert the DATE to YYMMDDTHHMMSS"
 383   (condition-case ()
 384       (gnus-time-iso8601 (gnus-date-get-time date))
 385     (error "")))
 386
 387 (defun gnus-mode-string-quote (string)
 388   "Quote all \"%\"'s in STRING."
 389   (save-excursion
 390     (gnus-set-work-buffer)
 391     (insert string)
 392     (goto-char (point-min))
 393     (while (search-forward "%" nil t)
 394       (insert "%"))
 395     (buffer-string)))
 396
 397 ;; Make a hash table (default and minimum size is 256).
 398 ;; Optional argument HASHSIZE specifies the table size.
 399 (defun gnus-make-hashtable (&optional hashsize)
 400   (make-vector (if hashsize (max (gnus-create-hash-size hashsize) 256) 256) 0))
 401
 402 ;; Make a number that is suitable for hashing; bigger than MIN and
 403 ;; equal to some 2^x.  Many machines (such as sparcs) do not have a
 404 ;; hardware modulo operation, so they implement it in software.  On
 405 ;; many sparcs over 50% of the time to intern is spent in the modulo.
 406 ;; Yes, it's slower than actually computing the hash from the string!
 407 ;; So we use powers of 2 so people can optimize the modulo to a mask.
 408 (defun gnus-create-hash-size (min)
 409   (let ((i 1))
 410     (while (< i min)
 411       (setq i (* 2 i)))
 412     i))
 413
 414 (defcustom gnus-verbose 7
 415   "*Integer that says how verbose Gnus should be.
 416 The higher the number, the more messages Gnus will flash to say what
 417 it's doing.  At zero, Gnus will be totally mute; at five, Gnus will
 418 display most important messages; and at ten, Gnus will keep on
 419 jabbering all the time."
 420   :group 'gnus-start
 421   :type 'integer)
 422
 423 ;; Show message if message has a lower level than `gnus-verbose'.
 424 ;; Guideline for numbers:
 425 ;; 1 - error messages, 3 - non-serious error messages, 5 - messages
 426 ;; for things that take a long time, 7 - not very important messages
 427 ;; on stuff, 9 - messages inside loops.
 428 (defun gnus-message (level &rest args)
 429   (if (<= level gnus-verbose)
 430       (apply 'message args)
 431     ;; We have to do this format thingy here even if the result isn't
 432     ;; shown - the return value has to be the same as the return value
 433     ;; from `message'.
 434     (apply 'format args)))
 435
 436 (defun gnus-error (level &rest args)
 437   "Beep an error if LEVEL is equal to or less than `gnus-verbose'."
 438   (when (<= (floor level) gnus-verbose)
 439     (apply 'message args)
 440     (ding)
 441     (let (duration)
 442       (when (and (floatp level)
 443                  (not (zerop (setq duration (* 10 (- level (floor level)))))))
 444         (sit-for duration))))
 445   nil)
 446
 447 (defun gnus-split-references (references)
 448   "Return a list of Message-IDs in REFERENCES."
 449   (let ((beg 0)
 450         ids)
 451     (while (string-match "<[^>]+>" references beg)
 452       (push (substring references (match-beginning 0) (setq beg (match-end 0)))
 453             ids))
 454     (nreverse ids)))
 455
 456 (defun gnus-parent-id (references &optional n)
 457   "Return the last Message-ID in REFERENCES.
 458 If N, return the Nth ancestor instead."
 459   (when references
 460     (let ((ids (inline (gnus-split-references references))))
 461       (while (nthcdr (or n 1) ids)
 462         (setq ids (cdr ids)))
 463       (car ids))))
 464
 465 (defsubst gnus-buffer-live-p (buffer)
 466   "Say whether BUFFER is alive or not."
 467   (and buffer
 468        (get-buffer buffer)
 469        (buffer-name (get-buffer buffer))))
 470
 471 (defun gnus-horizontal-recenter ()
 472   "Recenter the current buffer horizontally."
 473   (if (< (current-column) (/ (window-width) 2))
 474       (set-window-hscroll (get-buffer-window (current-buffer) t) 0)
 475     (let* ((orig (point))
 476            (end (window-end (get-buffer-window (current-buffer) t)))
 477            (max 0))
 478       (when end
 479         ;; Find the longest line currently displayed in the window.
 480         (goto-char (window-start))
 481         (while (and (not (eobp))
 482                     (< (point) end))
 483           (end-of-line)
 484           (setq max (max max (current-column)))
 485           (forward-line 1))
 486         (goto-char orig)
 487         ;; Scroll horizontally to center (sort of) the point.
 488         (if (> max (window-width))
 489             (set-window-hscroll
 490              (get-buffer-window (current-buffer) t)
 491              (min (- (current-column) (/ (window-width) 3))
 492                   (+ 2 (- max (window-width)))))
 493           (set-window-hscroll (get-buffer-window (current-buffer) t) 0))
 494         max))))
 495
 496 (defun gnus-read-event-char ()
 497   "Get the next event."
 498   (let ((event (read-event)))
 499     ;; should be gnus-characterp, but this can't be called in XEmacs anyway
 500     (cons (and (numberp event) event) event)))
 501
 502 (defun gnus-sortable-date (date)
 503   "Make sortable string by string-lessp from DATE.
 504 Timezone package is used."
 505   (condition-case ()
 506       (progn
 507         (setq date (inline (timezone-fix-time
 508                             date nil
 509                             (aref (inline (timezone-parse-date date)) 4))))
 510         (inline
 511           (timezone-make-sortable-date
 512            (aref date 0) (aref date 1) (aref date 2)
 513            (inline
 514              (timezone-make-time-string
 515               (aref date 3) (aref date 4) (aref date 5))))))
 516     (error "")))
 517
 518 (defun gnus-copy-file (file &optional to)
 519   "Copy FILE to TO."
 520   (interactive
 521    (list (read-file-name "Copy file: " default-directory)
 522          (read-file-name "Copy file to: " default-directory)))
 523   (unless to
 524     (setq to (read-file-name "Copy file to: " default-directory)))
 525   (when (file-directory-p to)
 526     (setq to (concat (file-name-as-directory to)
 527                      (file-name-nondirectory file))))
 528   (copy-file file to))
 529
 530 (defun gnus-kill-all-overlays ()
 531   "Delete all overlays in the current buffer."
 532   (let* ((overlayss (overlay-lists))
 533          (buffer-read-only nil)
 534          (overlays (delq nil (nconc (car overlayss) (cdr overlayss)))))
 535     (while overlays
 536       (delete-overlay (pop overlays)))))
 537
 538 (defvar gnus-work-buffer " *gnus work*")
 539
 540 (defun gnus-set-work-buffer ()
 541   "Put point in the empty Gnus work buffer."
 542   (if (get-buffer gnus-work-buffer)
 543       (progn
 544         (set-buffer gnus-work-buffer)
 545         (erase-buffer))
 546     (set-buffer (get-buffer-create gnus-work-buffer))
 547     (kill-all-local-variables)
 548     (buffer-disable-undo (current-buffer))))
 549
 550 (defmacro gnus-group-real-name (group)
 551   "Find the real name of a foreign newsgroup."
 552   `(let ((gname ,group))
 553      (if (string-match "^[^:]+:" gname)
 554          (substring gname (match-end 0))
 555        gname)))
 556
 557 (defun gnus-make-sort-function (funs)
 558   "Return a composite sort condition based on the functions in FUNC."
 559   (cond
 560    ((not (listp funs)) funs)
 561    ((null funs) funs)
 562    ((cdr funs)
 563     `(lambda (t1 t2)
 564        ,(gnus-make-sort-function-1 (reverse funs))))
 565    (t
 566     (car funs))))
 567
 568 (defun gnus-make-sort-function-1 (funs)
 569   "Return a composite sort condition based on the functions in FUNC."
 570   (if (cdr funs)
 571       `(or (,(car funs) t1 t2)
 572            (and (not (,(car funs) t2 t1))
 573                 ,(gnus-make-sort-function-1 (cdr funs))))
 574     `(,(car funs) t1 t2)))
 575
 576 (defun gnus-turn-off-edit-menu (type)
 577   "Turn off edit menu in `gnus-TYPE-mode-map'."
 578   (define-key (symbol-value (intern (format "gnus-%s-mode-map" type)))
 579     [menu-bar edit] 'undefined))
 580
 581 (defun gnus-prin1 (form)
 582   "Use `prin1' on FORM in the current buffer.
 583 Bind `print-quoted' and `print-readably' to t while printing."
 584   (let ((print-quoted t)
 585         (print-readably t)
 586         print-level print-length)
 587     (prin1 form (current-buffer))))
 588
 589 (defun gnus-prin1-to-string (form)
 590   "The same as `prin1', but bind `print-quoted' and `print-readably' to t."
 591   (let ((print-quoted t)
 592         (print-readably t))
 593     (prin1-to-string form)))
 594
 595 (defun gnus-make-directory (directory)
 596   "Make DIRECTORY (and all its parents) if it doesn't exist."
 597   (when (and directory
 598              (not (file-exists-p directory)))
 599     (make-directory directory t))
 600   t)
 601
 602 (defun gnus-write-buffer (file)
 603   "Write the current buffer's contents to FILE."
 604   ;; Make sure the directory exists.
 605   (gnus-make-directory (file-name-directory file))
 606   ;; Write the buffer.
 607   (write-region (point-min) (point-max) file nil 'quietly))
 608
 609 (defmacro gnus-delete-assq (key list)
 610   `(let ((listval (eval ,list)))
 611      (setq ,list (delq (assq ,key listval) listval))))
 612
 613 (defmacro gnus-delete-assoc (key list)
 614   `(let ((listval ,list))
 615      (setq ,list (delq (assoc ,key listval) listval))))
 616
 617 (defun gnus-delete-file (file)
 618   "Delete FILE if it exists."
 619   (when (file-exists-p file)
 620     (delete-file file)))
 621
 622 (defun gnus-strip-whitespace (string)
 623   "Return STRING stripped of all whitespace."
 624   (while (string-match "[\r\n\t ]+" string)
 625     (setq string (replace-match "" t t string)))
 626   string)
 627
 628 (defun gnus-put-text-property-excluding-newlines (beg end prop val)
 629   "The same as `put-text-property', but don't put this prop on any newlines in the region."
 630   (save-match-data
 631     (save-excursion
 632       (save-restriction
 633         (goto-char beg)
 634         (while (re-search-forward "[ \t]*\n" end 'move)
 635           (put-text-property beg (match-beginning 0) prop val)
 636           (setq beg (point)))
 637         (put-text-property beg (point) prop val)))))
 638
 639 ;;; Protected and atomic operations.  dmoore@ucsd.edu 21.11.1996
 640 ;;; The primary idea here is to try to protect internal datastructures
 641 ;;; from becoming corrupted when the user hits C-g, or if a hook or
 642 ;;; similar blows up.  Often in Gnus multiple tables/lists need to be
 643 ;;; updated at the same time, or information can be lost.
 644
 645 (defvar gnus-atomic-be-safe t
 646   "If t, certain operations will be protected from interruption by C-g.")
 647
 648 (defmacro gnus-atomic-progn (&rest forms)
 649   "Evaluate FORMS atomically, which means to protect the evaluation
 650 from being interrupted by the user.  An error from the forms themselves
 651 will return without finishing the operation.  Since interrupts from
 652 the user are disabled, it is recommended that only the most minimal
 653 operations are performed by FORMS.  If you wish to assign many
 654 complicated values atomically, compute the results into temporary
 655 variables and then do only the assignment atomically."
 656   `(let ((inhibit-quit gnus-atomic-be-safe))
 657      ,@forms))
 658
 659 (put 'gnus-atomic-progn 'lisp-indent-function 0)
 660
 661 (defmacro gnus-atomic-progn-assign (protect &rest forms)
 662   "Evaluate FORMS, but insure that the variables listed in PROTECT
 663 are not changed if anything in FORMS signals an error or otherwise
 664 non-locally exits.  The variables listed in PROTECT are updated atomically.
 665 It is safe to use gnus-atomic-progn-assign with long computations.
 666
 667 Note that if any of the symbols in PROTECT were unbound, they will be
 668 set to nil on a sucessful assignment.  In case of an error or other
 669 non-local exit, it will still be unbound."
 670   (let* ((temp-sym-map (mapcar (lambda (x) (list (make-symbol
 671                                                   (concat (symbol-name x)
 672                                                           "-tmp"))
 673                                                  x))
 674                                protect))
 675          (sym-temp-map (mapcar (lambda (x) (list (cadr x) (car x)))
 676                                temp-sym-map))
 677          (temp-sym-let (mapcar (lambda (x) (list (car x)
 678                                                  `(and (boundp ',(cadr x))
 679                                                        ,(cadr x))))
 680                                temp-sym-map))
 681          (sym-temp-let sym-temp-map)
 682          (temp-sym-assign (apply 'append temp-sym-map))
 683          (sym-temp-assign (apply 'append sym-temp-map))
 684          (result (make-symbol "result-tmp")))
 685     `(let (,@temp-sym-let
 686            ,result)
 687        (let ,sym-temp-let
 688          (setq ,result (progn ,@forms))
 689          (setq ,@temp-sym-assign))
 690        (let ((inhibit-quit gnus-atomic-be-safe))
 691          (setq ,@sym-temp-assign))
 692        ,result)))
 693
 694 (put 'gnus-atomic-progn-assign 'lisp-indent-function 1)
 695 ;(put 'gnus-atomic-progn-assign 'edebug-form-spec '(sexp body))
 696
 697 (defmacro gnus-atomic-setq (&rest pairs)
 698   "Similar to setq, except that the real symbols are only assigned when
 699 there are no errors.  And when the real symbols are assigned, they are
 700 done so atomically.  If other variables might be changed via side-effect,
 701 see gnus-atomic-progn-assign.  It is safe to use gnus-atomic-setq
 702 with potentially long computations."
 703   (let ((tpairs pairs)
 704         syms)
 705     (while tpairs
 706       (push (car tpairs) syms)
 707       (setq tpairs (cddr tpairs)))
 708     `(gnus-atomic-progn-assign ,syms
 709        (setq ,@pairs))))
 710
 711 ;(put 'gnus-atomic-setq 'edebug-form-spec '(body))
 712
 713
 714 ;;; Functions for saving to babyl/mail files.
 715
 716 (defvar rmail-default-rmail-file)
 717 (defun gnus-output-to-rmail (filename &optional ask)
 718   "Append the current article to an Rmail file named FILENAME."
 719   (require 'rmail)
 720   ;; Most of these codes are borrowed from rmailout.el.
 721   (setq filename (expand-file-name filename))
 722   (setq rmail-default-rmail-file filename)
 723   (let ((artbuf (current-buffer))
 724         (tmpbuf (get-buffer-create " *Gnus-output*")))
 725     (save-excursion
 726       (or (get-file-buffer filename)
 727           (file-exists-p filename)
 728           (if (or (not ask)
 729                   (gnus-yes-or-no-p
 730                    (concat "\"" filename "\" does not exist, create it? ")))
 731               (let ((file-buffer (create-file-buffer filename)))
 732                 (save-excursion
 733                   (set-buffer file-buffer)
 734                   (rmail-insert-rmail-file-header)
 735                   (let ((require-final-newline nil))
 736                     (gnus-write-buffer filename)))
 737                 (kill-buffer file-buffer))
 738             (error "Output file does not exist")))
 739       (set-buffer tmpbuf)
 740       (erase-buffer)
 741       (insert-buffer-substring artbuf)
 742       (gnus-convert-article-to-rmail)
 743       ;; Decide whether to append to a file or to an Emacs buffer.
 744       (let ((outbuf (get-file-buffer filename)))
 745         (if (not outbuf)
 746             (append-to-file (point-min) (point-max) filename)
 747           ;; File has been visited, in buffer OUTBUF.
 748           (set-buffer outbuf)
 749           (let ((buffer-read-only nil)
 750                 (msg (and (boundp 'rmail-current-message)
 751                           (symbol-value 'rmail-current-message))))
 752             ;; If MSG is non-nil, buffer is in RMAIL mode.
 753             (when msg
 754               (widen)
 755               (narrow-to-region (point-max) (point-max)))
 756             (insert-buffer-substring tmpbuf)
 757             (when msg
 758               (goto-char (point-min))
 759               (widen)
 760               (search-backward "\^_")
 761               (narrow-to-region (point) (point-max))
 762               (goto-char (1+ (point-min)))
 763               (rmail-count-new-messages t)
 764               (rmail-show-message msg))
 765             (save-buffer)))))
 766     (kill-buffer tmpbuf)))
 767
 768 (defun gnus-output-to-mail (filename &optional ask)
 769   "Append the current article to a mail file named FILENAME."
 770   (setq filename (expand-file-name filename))
 771   (let ((artbuf (current-buffer))
 772         (tmpbuf (get-buffer-create " *Gnus-output*")))
 773     (save-excursion
 774       ;; Create the file, if it doesn't exist.
 775       (when (and (not (get-file-buffer filename))
 776                  (not (file-exists-p filename)))
 777         (if (or (not ask)
 778                 (gnus-y-or-n-p
 779                  (concat "\"" filename "\" does not exist, create it? ")))
 780             (let ((file-buffer (create-file-buffer filename)))
 781               (save-excursion
 782                 (set-buffer file-buffer)
 783                 (let ((require-final-newline nil))
 784                   (gnus-write-buffer filename)))
 785               (kill-buffer file-buffer))
 786           (error "Output file does not exist")))
 787       (set-buffer tmpbuf)
 788       (erase-buffer)
 789       (insert-buffer-substring artbuf)
 790       (goto-char (point-min))
 791       (if (looking-at "From ")
 792           (forward-line 1)
 793         (insert "From nobody " (current-time-string) "\n"))
 794       (let (case-fold-search)
 795         (while (re-search-forward "^From " nil t)
 796           (beginning-of-line)
 797           (insert ">")))
 798       ;; Decide whether to append to a file or to an Emacs buffer.
 799       (let ((outbuf (get-file-buffer filename)))
 800         (if (not outbuf)
 801             (let ((buffer-read-only nil))
 802               (save-excursion
 803                 (goto-char (point-max))
 804                 (forward-char -2)
 805                 (unless (looking-at "\n\n")
 806                   (goto-char (point-max))
 807                   (unless (bolp)
 808                     (insert "\n"))
 809                   (insert "\n"))
 810                 (goto-char (point-max))
 811                 (append-to-file (point-min) (point-max) filename)))
 812           ;; File has been visited, in buffer OUTBUF.
 813           (set-buffer outbuf)
 814           (let ((buffer-read-only nil))
 815             (goto-char (point-max))
 816             (unless (eobp)
 817               (insert "\n"))
 818             (insert "\n")
 819             (insert-buffer-substring tmpbuf)))))
 820     (kill-buffer tmpbuf)))
 821
 822 (defun gnus-convert-article-to-rmail ()
 823   "Convert article in current buffer to Rmail message format."
 824   (let ((buffer-read-only nil))
 825     ;; Convert article directly into Babyl format.
 826     (goto-char (point-min))
 827     (insert "\^L\n0, unseen,,\n*** EOOH ***\n")
 828     (while (search-forward "\n\^_" nil t) ;single char
 829       (replace-match "\n^_" t t))       ;2 chars: "^" and "_"
 830     (goto-char (point-max))
 831     (insert "\^_")))
 832
 833 (defun gnus-map-function (funs arg)
 834   "Applies the result of the first function in FUNS to the second, and so on.
 835 ARG is passed to the first function."
 836   (let ((myfuns funs)
 837         (myarg arg))
 838     (while myfuns
 839       (setq arg (funcall (pop myfuns) arg)))
 840     arg))
 841
 842 (defun gnus-run-hooks (&rest funcs)
 843   "Does the same as `run-hooks', but saves excursion."
 844   (let ((buf (current-buffer)))
 845     (unwind-protect
 846         (apply 'run-hooks funcs)
 847       (set-buffer buf))))
 848
 849 ;;;
 850 ;;; .netrc and .authinforc parsing
 851 ;;;
 852
 853 (defvar gnus-netrc-syntax-table
 854   (let ((table (copy-syntax-table text-mode-syntax-table)))
 855     (modify-syntax-entry ?- "w" table)
 856     (modify-syntax-entry ?_ "w" table)
 857     (modify-syntax-entry ?! "w" table)
 858     (modify-syntax-entry ?. "w" table)
 859     (modify-syntax-entry ?, "w" table)
 860     (modify-syntax-entry ?: "w" table)
 861     (modify-syntax-entry ?\; "w" table)
 862     (modify-syntax-entry ?% "w" table)
 863     (modify-syntax-entry ?) "w" table)
 864     (modify-syntax-entry ?( "w" table)
 865     table)
 866   "Syntax table when parsing .netrc files.")
 867
 868 (defun gnus-parse-netrc (file)
 869   "Parse FILE and return an list of all entries in the file."
 870   (if (not (file-exists-p file))
 871       ()
 872     (save-excursion
 873       (let ((tokens '("machine" "default" "login"
 874                       "password" "account" "macdef" "force"))
 875             alist elem result pair)
 876         (nnheader-set-temp-buffer " *netrc*")
 877         (set-syntax-table gnus-netrc-syntax-table)
 878         (insert-file-contents file)
 879         (goto-char (point-min))
 880         ;; Go through the file, line by line.
 881         (while (not (eobp))
 882           (narrow-to-region (point) (gnus-point-at-eol))
 883           ;; For each line, get the tokens and values.
 884           (while (not (eobp))
 885             (skip-chars-forward "\t ")
 886             (unless (eobp)
 887               (setq elem (buffer-substring
 888                           (point) (progn (forward-sexp 1) (point))))
 889               (cond
 890                ((equal elem "macdef")
 891                 ;; We skip past the macro definition.
 892                 (widen)
 893                 (while (and (zerop (forward-line 1))
 894                             (looking-at "$")))
 895                 (narrow-to-region (point) (point)))
 896                ((member elem tokens)
 897                 ;; Tokens that don't have a following value are ignored.
 898                 (when (and pair (cdr pair))
 899                   (push pair alist))
 900                 (setq pair (list elem)))
 901                (t
 902                 ;; Values that haven't got a preceding token are ignored.
 903                 (when pair
 904                   (setcdr pair elem)
 905                   (push pair alist)
 906                   (setq pair nil))))))
 907           (push alist result)
 908           (setq alist nil
 909                 pair nil)
 910           (widen)
 911           (forward-line 1))
 912         result))))
 913
 914 (defun gnus-netrc-machine (list machine)
 915   "Return the netrc values from LIST for MACHINE."
 916   (while (and list
 917               (not (equal (cdr (assoc "machine" (car list))) machine)))
 918     (pop list))
 919   (when list
 920     (car list)))
 921
 922 (defun gnus-netrc-get (alist type)
 923   "Return the value of token TYPE from ALIST."
 924   (cdr (assoc type alist)))
 925
 926 ;;; Various
 927
 928 (defun gnus-alive-p ()
 929   "Say whether Gnus is running or not."
 930   (and (boundp 'gnus-group-buffer)
 931        (get-buffer gnus-group-buffer)
 932        (save-excursion
 933          (set-buffer gnus-group-buffer)
 934          (eq major-mode 'gnus-group-mode))))
 935
 936
 937 (provide 'gnus-util)
 938
 939 ;;; gnus-util.el ends here