cgit.sxemacs.org Git - gnus/blob - lisp/gnus-util.el

   1 ;;; gnus-util.el --- utility functions for Gnus
   2 ;; Copyright (C) 1996,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; Nothing in this file depends on any other parts of Gnus -- all
  27 ;; functions and macros in this file are utility functions that are
  28 ;; used by Gnus and may be used by any other package without loading
  29 ;; Gnus first.
  30
  31 ;;; Code:
  32
  33 (require 'custom)
  34 (eval-when-compile (require 'cl))
  35 (require 'nnheader)
  36 (require 'timezone)
  37 (require 'message)
  38
  39 (eval-and-compile
  40   (autoload 'nnmail-date-to-time "nnmail")
  41   (autoload 'rmail-insert-rmail-file-header "rmail")
  42   (autoload 'rmail-count-new-messages "rmail")
  43   (autoload 'rmail-show-message "rmail"))
  44
  45 (defun gnus-boundp (variable)
  46   "Return non-nil if VARIABLE is bound and non-nil."
  47   (and (boundp variable)
  48        (symbol-value variable)))
  49
  50 (defmacro gnus-eval-in-buffer-window (buffer &rest forms)
  51   "Pop to BUFFER, evaluate FORMS, and then return to the original window."
  52   (let ((tempvar (make-symbol "GnusStartBufferWindow"))
  53         (w (make-symbol "w"))
  54         (buf (make-symbol "buf")))
  55     `(let* ((,tempvar (selected-window))
  56             (,buf ,buffer)
  57             (,w (get-buffer-window ,buf 'visible)))
  58        (unwind-protect
  59            (progn
  60              (if ,w
  61                  (progn
  62                    (select-window ,w)
  63                    (set-buffer (window-buffer ,w)))
  64                (pop-to-buffer ,buf))
  65              ,@forms)
  66          (select-window ,tempvar)))))
  67
  68 (put 'gnus-eval-in-buffer-window 'lisp-indent-function 1)
  69 (put 'gnus-eval-in-buffer-window 'edebug-form-spec '(form body))
  70
  71 (defmacro gnus-intern-safe (string hashtable)
  72   "Set hash value.  Arguments are STRING, VALUE, and HASHTABLE."
  73   `(let ((symbol (intern ,string ,hashtable)))
  74      (or (boundp symbol)
  75          (set symbol nil))
  76      symbol))
  77
  78 (defun gnus-truncate-string (str width)
  79   (substring str 0 width))
  80
  81 ;; Added by Geoffrey T. Dairiki <dairiki@u.washington.edu>.  A safe way
  82 ;; to limit the length of a string.  This function is necessary since
  83 ;; `(substr "abc" 0 30)' pukes with "Args out of range".
  84 (defsubst gnus-limit-string (str width)
  85   (if (> (length str) width)
  86       (substring str 0 width)
  87     str))
  88
  89 (defsubst gnus-functionp (form)
  90   "Return non-nil if FORM is funcallable."
  91   (or (and (symbolp form) (fboundp form))
  92       (and (listp form) (eq (car form) 'lambda))
  93       (byte-code-function-p form)))
  94
  95 (defsubst gnus-goto-char (point)
  96   (and point (goto-char point)))
  97
  98 (defmacro gnus-buffer-exists-p (buffer)
  99   `(let ((buffer ,buffer))
 100      (when buffer
 101        (funcall (if (stringp buffer) 'get-buffer 'buffer-name)
 102                 buffer))))
 103
 104 (defmacro gnus-kill-buffer (buffer)
 105   `(let ((buf ,buffer))
 106      (when (gnus-buffer-exists-p buf)
 107        (kill-buffer buf))))
 108
 109 (if (fboundp 'point-at-bol)
 110     (fset 'gnus-point-at-bol 'point-at-bol)
 111   (defun gnus-point-at-bol ()
 112     "Return point at the beginning of the line."
 113     (let ((p (point)))
 114       (beginning-of-line)
 115       (prog1
 116           (point)
 117         (goto-char p)))))
 118
 119 (if (fboundp 'point-at-eol)
 120     (fset 'gnus-point-at-eol 'point-at-eol)
 121   (defun gnus-point-at-eol ()
 122     "Return point at the end of the line."
 123     (let ((p (point)))
 124       (end-of-line)
 125       (prog1
 126           (point)
 127         (goto-char p)))))
 128
 129 (defun gnus-delete-first (elt list)
 130   "Delete by side effect the first occurrence of ELT as a member of LIST."
 131   (if (equal (car list) elt)
 132       (cdr list)
 133     (let ((total list))
 134       (while (and (cdr list)
 135                   (not (equal (cadr list) elt)))
 136         (setq list (cdr list)))
 137       (when (cdr list)
 138         (setcdr list (cddr list)))
 139       total)))
 140
 141 ;; Delete the current line (and the next N lines).
 142 (defmacro gnus-delete-line (&optional n)
 143   `(delete-region (progn (beginning-of-line) (point))
 144                   (progn (forward-line ,(or n 1)) (point))))
 145
 146 (defun gnus-byte-code (func)
 147   "Return a form that can be `eval'ed based on FUNC."
 148   (let ((fval (indirect-function func)))
 149     (if (byte-code-function-p fval)
 150         (let ((flist (append fval nil)))
 151           (setcar flist 'byte-code)
 152           flist)
 153       (cons 'progn (cddr fval)))))
 154
 155 (defun gnus-extract-address-components (from)
 156   (let (name address)
 157     ;; First find the address - the thing with the @ in it.  This may
 158     ;; not be accurate in mail addresses, but does the trick most of
 159     ;; the time in news messages.
 160     (when (string-match "\\b[^@ \t<>]+[!@][^@ \t<>]+\\b" from)
 161       (setq address (substring from (match-beginning 0) (match-end 0))))
 162     ;; Then we check whether the "name <address>" format is used.
 163     (and address
 164          ;; Linear white space is not required.
 165          (string-match (concat "[ \t]*<" (regexp-quote address) ">") from)
 166          (and (setq name (substring from 0 (match-beginning 0)))
 167               ;; Strip any quotes from the name.
 168               (string-match "\".*\"" name)
 169               (setq name (substring name 1 (1- (match-end 0))))))
 170     ;; If not, then "address (name)" is used.
 171     (or name
 172         (and (string-match "(.+)" from)
 173              (setq name (substring from (1+ (match-beginning 0))
 174                                    (1- (match-end 0)))))
 175         (and (string-match "()" from)
 176              (setq name address))
 177         ;; XOVER might not support folded From headers.
 178         (and (string-match "(.*" from)
 179              (setq name (substring from (1+ (match-beginning 0))
 180                                    (match-end 0)))))
 181     ;; Fix by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>.
 182     (list (or name from) (or address from))))
 183
 184 (defun gnus-fetch-field (field)
 185   "Return the value of the header FIELD of current article."
 186   (save-excursion
 187     (save-restriction
 188       (let ((case-fold-search t)
 189             (inhibit-point-motion-hooks t))
 190         (nnheader-narrow-to-headers)
 191         (message-fetch-field field)))))
 192
 193 (defun gnus-goto-colon ()
 194   (beginning-of-line)
 195   (search-forward ":" (gnus-point-at-eol) t))
 196
 197 (defun gnus-remove-text-with-property (prop)
 198   "Delete all text in the current buffer with text property PROP."
 199   (save-excursion
 200     (goto-char (point-min))
 201     (while (not (eobp))
 202       (while (get-text-property (point) prop)
 203         (delete-char 1))
 204       (goto-char (next-single-property-change (point) prop nil (point-max))))))
 205
 206 (defun gnus-newsgroup-directory-form (newsgroup)
 207   "Make hierarchical directory name from NEWSGROUP name."
 208   (let ((newsgroup (gnus-newsgroup-savable-name newsgroup))
 209         (len (length newsgroup))
 210         idx)
 211     ;; If this is a foreign group, we don't want to translate the
 212     ;; entire name.
 213     (if (setq idx (string-match ":" newsgroup))
 214         (aset newsgroup idx ?/)
 215       (setq idx 0))
 216     ;; Replace all occurrences of `.' with `/'.
 217     (while (< idx len)
 218       (when (= (aref newsgroup idx) ?.)
 219         (aset newsgroup idx ?/))
 220       (setq idx (1+ idx)))
 221     newsgroup))
 222
 223 (defun gnus-newsgroup-savable-name (group)
 224   ;; Replace any slashes in a group name (eg. an ange-ftp nndoc group)
 225   ;; with dots.
 226   (nnheader-replace-chars-in-string group ?/ ?.))
 227
 228 (defun gnus-string> (s1 s2)
 229   (not (or (string< s1 s2)
 230            (string= s1 s2))))
 231
 232 ;;; Time functions.
 233
 234 (defun gnus-days-between (date1 date2)
 235   ;; Return the number of days between date1 and date2.
 236   (- (gnus-day-number date1) (gnus-day-number date2)))
 237
 238 (defun gnus-day-number (date)
 239   (let ((dat (mapcar (lambda (s) (and s (string-to-int s)) )
 240                      (timezone-parse-date date))))
 241     (timezone-absolute-from-gregorian
 242      (nth 1 dat) (nth 2 dat) (car dat))))
 243
 244 (defun gnus-time-to-day (time)
 245   "Convert TIME to day number."
 246   (let ((tim (decode-time time)))
 247     (timezone-absolute-from-gregorian
 248      (nth 4 tim) (nth 3 tim) (nth 5 tim))))
 249
 250 (defun gnus-encode-date (date)
 251   "Convert DATE to internal time."
 252   (let* ((parse (timezone-parse-date date))
 253          (date (mapcar (lambda (d) (and d (string-to-int d))) parse))
 254          (time (mapcar 'string-to-int (timezone-parse-time (aref parse 3)))))
 255     (encode-time (caddr time) (cadr time) (car time)
 256                  (caddr date) (cadr date) (car date)
 257                  (* 60 (timezone-zone-to-minute (nth 4 date))))))
 258
 259 (defun gnus-time-minus (t1 t2)
 260   "Subtract two internal times."
 261   (let ((borrow (< (cadr t1) (cadr t2))))
 262     (list (- (car t1) (car t2) (if borrow 1 0))
 263           (- (+ (if borrow 65536 0) (cadr t1)) (cadr t2)))))
 264
 265 (defun gnus-time-less (t1 t2)
 266   "Say whether time T1 is less than time T2."
 267   (or (< (car t1) (car t2))
 268       (and (= (car t1) (car t2))
 269            (< (nth 1 t1) (nth 1 t2)))))
 270
 271 (defun gnus-file-newer-than (file date)
 272   (let ((fdate (nth 5 (file-attributes file))))
 273     (or (> (car fdate) (car date))
 274         (and (= (car fdate) (car date))
 275              (> (nth 1 fdate) (nth 1 date))))))
 276
 277 ;;; Keymap macros.
 278
 279 (defmacro gnus-local-set-keys (&rest plist)
 280   "Set the keys in PLIST in the current keymap."
 281   `(gnus-define-keys-1 (current-local-map) ',plist))
 282
 283 (defmacro gnus-define-keys (keymap &rest plist)
 284   "Define all keys in PLIST in KEYMAP."
 285   `(gnus-define-keys-1 (quote ,keymap) (quote ,plist)))
 286
 287 (defmacro gnus-define-keys-safe (keymap &rest plist)
 288   "Define all keys in PLIST in KEYMAP without overwriting previous definitions."
 289   `(gnus-define-keys-1 (quote ,keymap) (quote ,plist) t))
 290
 291 (put 'gnus-define-keys 'lisp-indent-function 1)
 292 (put 'gnus-define-keys-safe 'lisp-indent-function 1)
 293 (put 'gnus-local-set-keys 'lisp-indent-function 1)
 294
 295 (defmacro gnus-define-keymap (keymap &rest plist)
 296   "Define all keys in PLIST in KEYMAP."
 297   `(gnus-define-keys-1 ,keymap (quote ,plist)))
 298
 299 (put 'gnus-define-keymap 'lisp-indent-function 1)
 300
 301 (defun gnus-define-keys-1 (keymap plist &optional safe)
 302   (when (null keymap)
 303     (error "Can't set keys in a null keymap"))
 304   (cond ((symbolp keymap)
 305          (setq keymap (symbol-value keymap)))
 306         ((keymapp keymap))
 307         ((listp keymap)
 308          (set (car keymap) nil)
 309          (define-prefix-command (car keymap))
 310          (define-key (symbol-value (caddr keymap)) (cadr keymap) (car keymap))
 311          (setq keymap (symbol-value (car keymap)))))
 312   (let (key)
 313     (while plist
 314       (when (symbolp (setq key (pop plist)))
 315         (setq key (symbol-value key)))
 316       (if (or (not safe)
 317               (eq (lookup-key keymap key) 'undefined))
 318           (define-key keymap key (pop plist))
 319         (pop plist)))))
 320
 321 (defun gnus-completing-read (default prompt &rest args)
 322   ;; Like `completing-read', except that DEFAULT is the default argument.
 323   (let* ((prompt (if default
 324                      (concat prompt " (default " default ") ")
 325                    (concat prompt " ")))
 326          (answer (apply 'completing-read prompt args)))
 327     (if (or (null answer) (zerop (length answer)))
 328         default
 329       answer)))
 330
 331 ;; Two silly functions to ensure that all `y-or-n-p' questions clear
 332 ;; the echo area.
 333 (defun gnus-y-or-n-p (prompt)
 334   (prog1
 335       (y-or-n-p prompt)
 336     (message "")))
 337
 338 (defun gnus-yes-or-no-p (prompt)
 339   (prog1
 340       (yes-or-no-p prompt)
 341     (message "")))
 342
 343 ;; I suspect there's a better way, but I haven't taken the time to do
 344 ;; it yet.  -erik selberg@cs.washington.edu
 345 (defun gnus-dd-mmm (messy-date)
 346   "Return a string like DD-MMM from a big messy string"
 347   (let ((datevec (ignore-errors (timezone-parse-date messy-date))))
 348     (if (not datevec)
 349         "??-???"
 350       (format "%2s-%s"
 351               (condition-case ()
 352                   ;; Make sure leading zeroes are stripped.
 353                   (number-to-string (string-to-number (aref datevec 2)))
 354                 (error "??"))
 355               (capitalize
 356                (or (car
 357                     (nth (1- (string-to-number (aref datevec 1)))
 358                          timezone-months-assoc))
 359                    "???"))))))
 360
 361 (defmacro gnus-date-get-time (date)
 362   "Convert DATE string to Emacs time.
 363 Cache the result as a text property stored in DATE."
 364   ;; Either return the cached value...
 365   `(let ((d ,date))
 366      (if (equal "" d)
 367          '(0 0)
 368        (or (get-text-property 0 'gnus-time d)
 369            ;; or compute the value...
 370            (let ((time (nnmail-date-to-time d)))
 371              ;; and store it back in the string.
 372              (put-text-property 0 1 'gnus-time time d)
 373              time)))))
 374
 375 (defsubst gnus-time-iso8601 (time)
 376   "Return a string of TIME in YYMMDDTHHMMSS format."
 377   (format-time-string "%Y%m%dT%H%M%S" time))
 378
 379 (defun gnus-date-iso8601 (header)
 380   "Convert the date field in HEADER to YYMMDDTHHMMSS"
 381   (condition-case ()
 382       (gnus-time-iso8601 (gnus-date-get-time (mail-header-date header)))
 383     (error "")))
 384
 385 (defun gnus-mode-string-quote (string)
 386   "Quote all \"%\"'s in STRING."
 387   (save-excursion
 388     (gnus-set-work-buffer)
 389     (insert string)
 390     (goto-char (point-min))
 391     (while (search-forward "%" nil t)
 392       (insert "%"))
 393     (buffer-string)))
 394
 395 ;; Make a hash table (default and minimum size is 256).
 396 ;; Optional argument HASHSIZE specifies the table size.
 397 (defun gnus-make-hashtable (&optional hashsize)
 398   (make-vector (if hashsize (max (gnus-create-hash-size hashsize) 256) 256) 0))
 399
 400 ;; Make a number that is suitable for hashing; bigger than MIN and
 401 ;; equal to some 2^x.  Many machines (such as sparcs) do not have a
 402 ;; hardware modulo operation, so they implement it in software.  On
 403 ;; many sparcs over 50% of the time to intern is spent in the modulo.
 404 ;; Yes, it's slower than actually computing the hash from the string!
 405 ;; So we use powers of 2 so people can optimize the modulo to a mask.
 406 (defun gnus-create-hash-size (min)
 407   (let ((i 1))
 408     (while (< i min)
 409       (setq i (* 2 i)))
 410     i))
 411
 412 (defcustom gnus-verbose 7
 413   "*Integer that says how verbose Gnus should be.
 414 The higher the number, the more messages Gnus will flash to say what
 415 it's doing.  At zero, Gnus will be totally mute; at five, Gnus will
 416 display most important messages; and at ten, Gnus will keep on
 417 jabbering all the time."
 418   :group 'gnus-start
 419   :type 'integer)
 420
 421 ;; Show message if message has a lower level than `gnus-verbose'.
 422 ;; Guideline for numbers:
 423 ;; 1 - error messages, 3 - non-serious error messages, 5 - messages
 424 ;; for things that take a long time, 7 - not very important messages
 425 ;; on stuff, 9 - messages inside loops.
 426 (defun gnus-message (level &rest args)
 427   (if (<= level gnus-verbose)
 428       (apply 'message args)
 429     ;; We have to do this format thingy here even if the result isn't
 430     ;; shown - the return value has to be the same as the return value
 431     ;; from `message'.
 432     (apply 'format args)))
 433
 434 (defun gnus-error (level &rest args)
 435   "Beep an error if LEVEL is equal to or less than `gnus-verbose'."
 436   (when (<= (floor level) gnus-verbose)
 437     (apply 'message args)
 438     (ding)
 439     (let (duration)
 440       (when (and (floatp level)
 441                  (not (zerop (setq duration (* 10 (- level (floor level)))))))
 442         (sit-for duration))))
 443   nil)
 444
 445 (defun gnus-split-references (references)
 446   "Return a list of Message-IDs in REFERENCES."
 447   (let ((beg 0)
 448         ids)
 449     (while (string-match "<[^>]+>" references beg)
 450       (push (substring references (match-beginning 0) (setq beg (match-end 0)))
 451             ids))
 452     (nreverse ids)))
 453
 454 (defun gnus-parent-id (references &optional n)
 455   "Return the last Message-ID in REFERENCES.
 456 If N, return the Nth ancestor instead."
 457   (when references
 458     (let ((ids (inline (gnus-split-references references))))
 459       (while (nthcdr (or n 1) ids)
 460         (setq ids (cdr ids)))
 461       (car ids))))
 462
 463 (defsubst gnus-buffer-live-p (buffer)
 464   "Say whether BUFFER is alive or not."
 465   (and buffer
 466        (get-buffer buffer)
 467        (buffer-name (get-buffer buffer))))
 468
 469 (defun gnus-horizontal-recenter ()
 470   "Recenter the current buffer horizontally."
 471   (if (< (current-column) (/ (window-width) 2))
 472       (set-window-hscroll (get-buffer-window (current-buffer) t) 0)
 473     (let* ((orig (point))
 474            (end (window-end (get-buffer-window (current-buffer) t)))
 475            (max 0))
 476       ;; Find the longest line currently displayed in the window.
 477       (goto-char (window-start))
 478       (while (and (not (eobp))
 479                   (< (point) end))
 480         (end-of-line)
 481         (setq max (max max (current-column)))
 482         (forward-line 1))
 483       (goto-char orig)
 484       ;; Scroll horizontally to center (sort of) the point.
 485       (if (> max (window-width))
 486           (set-window-hscroll
 487            (get-buffer-window (current-buffer) t)
 488            (min (- (current-column) (/ (window-width) 3))
 489                 (+ 2 (- max (window-width)))))
 490         (set-window-hscroll (get-buffer-window (current-buffer) t) 0))
 491       max)))
 492
 493 (defun gnus-read-event-char ()
 494   "Get the next event."
 495   (let ((event (read-event)))
 496     ;; should be gnus-characterp, but this can't be called in XEmacs anyway
 497     (cons (and (numberp event) event) event)))
 498
 499 (defun gnus-sortable-date (date)
 500   "Make sortable string by string-lessp from DATE.
 501 Timezone package is used."
 502   (condition-case ()
 503       (progn
 504         (setq date (inline (timezone-fix-time
 505                             date nil
 506                             (aref (inline (timezone-parse-date date)) 4))))
 507         (inline
 508           (timezone-make-sortable-date
 509            (aref date 0) (aref date 1) (aref date 2)
 510            (inline
 511              (timezone-make-time-string
 512               (aref date 3) (aref date 4) (aref date 5))))))
 513     (error "")))
 514
 515 (defun gnus-copy-file (file &optional to)
 516   "Copy FILE to TO."
 517   (interactive
 518    (list (read-file-name "Copy file: " default-directory)
 519          (read-file-name "Copy file to: " default-directory)))
 520   (unless to
 521     (setq to (read-file-name "Copy file to: " default-directory)))
 522   (when (file-directory-p to)
 523     (setq to (concat (file-name-as-directory to)
 524                      (file-name-nondirectory file))))
 525   (copy-file file to))
 526
 527 (defun gnus-kill-all-overlays ()
 528   "Delete all overlays in the current buffer."
 529   (let* ((overlayss (overlay-lists))
 530          (buffer-read-only nil)
 531          (overlays (delq nil (nconc (car overlayss) (cdr overlayss)))))
 532     (while overlays
 533       (delete-overlay (pop overlays)))))
 534
 535 (defvar gnus-work-buffer " *gnus work*")
 536
 537 (defun gnus-set-work-buffer ()
 538   "Put point in the empty Gnus work buffer."
 539   (if (get-buffer gnus-work-buffer)
 540       (progn
 541         (set-buffer gnus-work-buffer)
 542         (erase-buffer))
 543     (set-buffer (get-buffer-create gnus-work-buffer))
 544     (kill-all-local-variables)
 545     (buffer-disable-undo (current-buffer))))
 546
 547 (defmacro gnus-group-real-name (group)
 548   "Find the real name of a foreign newsgroup."
 549   `(let ((gname ,group))
 550      (if (string-match "^[^:]+:" gname)
 551          (substring gname (match-end 0))
 552        gname)))
 553
 554 (defun gnus-make-sort-function (funs)
 555   "Return a composite sort condition based on the functions in FUNC."
 556   (cond
 557    ((not (listp funs)) funs)
 558    ((null funs) funs)
 559    ((cdr funs)
 560     `(lambda (t1 t2)
 561        ,(gnus-make-sort-function-1 (reverse funs))))
 562    (t
 563     (car funs))))
 564
 565 (defun gnus-make-sort-function-1 (funs)
 566   "Return a composite sort condition based on the functions in FUNC."
 567   (if (cdr funs)
 568       `(or (,(car funs) t1 t2)
 569            (and (not (,(car funs) t2 t1))
 570                 ,(gnus-make-sort-function-1 (cdr funs))))
 571     `(,(car funs) t1 t2)))
 572
 573 (defun gnus-turn-off-edit-menu (type)
 574   "Turn off edit menu in `gnus-TYPE-mode-map'."
 575   (define-key (symbol-value (intern (format "gnus-%s-mode-map" type)))
 576     [menu-bar edit] 'undefined))
 577
 578 (defun gnus-prin1 (form)
 579   "Use `prin1' on FORM in the current buffer.
 580 Bind `print-quoted' and `print-readably' to t while printing."
 581   (let ((print-quoted t)
 582         (print-readably t)
 583         print-level print-length)
 584     (prin1 form (current-buffer))))
 585
 586 (defun gnus-prin1-to-string (form)
 587   "The same as `prin1', but bind `print-quoted' and `print-readably' to t."
 588   (let ((print-quoted t)
 589         (print-readably t))
 590     (prin1-to-string form)))
 591
 592 (defun gnus-make-directory (directory)
 593   "Make DIRECTORY (and all its parents) if it doesn't exist."
 594   (when (and directory
 595              (not (file-exists-p directory)))
 596     (make-directory directory t))
 597   t)
 598
 599 (defun gnus-write-buffer (file)
 600   "Write the current buffer's contents to FILE."
 601   ;; Make sure the directory exists.
 602   (gnus-make-directory (file-name-directory file))
 603   ;; Write the buffer.
 604   (write-region (point-min) (point-max) file nil 'quietly))
 605
 606 (defmacro gnus-delete-assq (key list)
 607   `(let ((listval (eval ,list)))
 608      (setq ,list (delq (assq ,key listval) listval))))
 609
 610 (defmacro gnus-delete-assoc (key list)
 611   `(let ((listval ,list))
 612      (setq ,list (delq (assoc ,key listval) listval))))
 613
 614 (defun gnus-delete-file (file)
 615   "Delete FILE if it exists."
 616   (when (file-exists-p file)
 617     (delete-file file)))
 618
 619 (defun gnus-strip-whitespace (string)
 620   "Return STRING stripped of all whitespace."
 621   (while (string-match "[\r\n\t ]+" string)
 622     (setq string (replace-match "" t t string)))
 623   string)
 624
 625 (defun gnus-put-text-property-excluding-newlines (beg end prop val)
 626   "The same as `put-text-property', but don't put this prop on any newlines in the region."
 627   (save-match-data
 628     (save-excursion
 629       (save-restriction
 630         (goto-char beg)
 631         (while (re-search-forward "[ \t]*\n" end 'move)
 632           (put-text-property beg (match-beginning 0) prop val)
 633           (setq beg (point)))
 634         (put-text-property beg (point) prop val)))))
 635
 636 ;;; Protected and atomic operations.  dmoore@ucsd.edu 21.11.1996
 637 ;;; The primary idea here is to try to protect internal datastructures
 638 ;;; from becoming corrupted when the user hits C-g, or if a hook or
 639 ;;; similar blows up.  Often in Gnus multiple tables/lists need to be
 640 ;;; updated at the same time, or information can be lost.
 641
 642 (defvar gnus-atomic-be-safe t
 643   "If t, certain operations will be protected from interruption by C-g.")
 644
 645 (defmacro gnus-atomic-progn (&rest forms)
 646   "Evaluate FORMS atomically, which means to protect the evaluation
 647 from being interrupted by the user.  An error from the forms themselves
 648 will return without finishing the operation.  Since interrupts from
 649 the user are disabled, it is recommended that only the most minimal
 650 operations are performed by FORMS.  If you wish to assign many
 651 complicated values atomically, compute the results into temporary
 652 variables and then do only the assignment atomically."
 653   `(let ((inhibit-quit gnus-atomic-be-safe))
 654      ,@forms))
 655
 656 (put 'gnus-atomic-progn 'lisp-indent-function 0)
 657
 658 (defmacro gnus-atomic-progn-assign (protect &rest forms)
 659   "Evaluate FORMS, but insure that the variables listed in PROTECT
 660 are not changed if anything in FORMS signals an error or otherwise
 661 non-locally exits.  The variables listed in PROTECT are updated atomically.
 662 It is safe to use gnus-atomic-progn-assign with long computations.
 663
 664 Note that if any of the symbols in PROTECT were unbound, they will be
 665 set to nil on a sucessful assignment.  In case of an error or other
 666 non-local exit, it will still be unbound."
 667   (let* ((temp-sym-map (mapcar (lambda (x) (list (make-symbol
 668                                                   (concat (symbol-name x)
 669                                                           "-tmp"))
 670                                                  x))
 671                                protect))
 672          (sym-temp-map (mapcar (lambda (x) (list (cadr x) (car x)))
 673                                temp-sym-map))
 674          (temp-sym-let (mapcar (lambda (x) (list (car x)
 675                                                  `(and (boundp ',(cadr x))
 676                                                        ,(cadr x))))
 677                                temp-sym-map))
 678          (sym-temp-let sym-temp-map)
 679          (temp-sym-assign (apply 'append temp-sym-map))
 680          (sym-temp-assign (apply 'append sym-temp-map))
 681          (result (make-symbol "result-tmp")))
 682     `(let (,@temp-sym-let
 683            ,result)
 684        (let ,sym-temp-let
 685          (setq ,result (progn ,@forms))
 686          (setq ,@temp-sym-assign))
 687        (let ((inhibit-quit gnus-atomic-be-safe))
 688          (setq ,@sym-temp-assign))
 689        ,result)))
 690
 691 (put 'gnus-atomic-progn-assign 'lisp-indent-function 1)
 692 ;(put 'gnus-atomic-progn-assign 'edebug-form-spec '(sexp body))
 693
 694 (defmacro gnus-atomic-setq (&rest pairs)
 695   "Similar to setq, except that the real symbols are only assigned when
 696 there are no errors.  And when the real symbols are assigned, they are
 697 done so atomically.  If other variables might be changed via side-effect,
 698 see gnus-atomic-progn-assign.  It is safe to use gnus-atomic-setq
 699 with potentially long computations."
 700   (let ((tpairs pairs)
 701         syms)
 702     (while tpairs
 703       (push (car tpairs) syms)
 704       (setq tpairs (cddr tpairs)))
 705     `(gnus-atomic-progn-assign ,syms
 706        (setq ,@pairs))))
 707
 708 ;(put 'gnus-atomic-setq 'edebug-form-spec '(body))
 709
 710
 711 ;;; Functions for saving to babyl/mail files.
 712
 713 (defvar rmail-default-rmail-file)
 714 (defun gnus-output-to-rmail (filename &optional ask)
 715   "Append the current article to an Rmail file named FILENAME."
 716   (require 'rmail)
 717   ;; Most of these codes are borrowed from rmailout.el.
 718   (setq filename (expand-file-name filename))
 719   (setq rmail-default-rmail-file filename)
 720   (let ((artbuf (current-buffer))
 721         (tmpbuf (get-buffer-create " *Gnus-output*")))
 722     (save-excursion
 723       (or (get-file-buffer filename)
 724           (file-exists-p filename)
 725           (if (or (not ask)
 726                   (gnus-yes-or-no-p
 727                    (concat "\"" filename "\" does not exist, create it? ")))
 728               (let ((file-buffer (create-file-buffer filename)))
 729                 (save-excursion
 730                   (set-buffer file-buffer)
 731                   (rmail-insert-rmail-file-header)
 732                   (let ((require-final-newline nil))
 733                     (gnus-write-buffer filename)))
 734                 (kill-buffer file-buffer))
 735             (error "Output file does not exist")))
 736       (set-buffer tmpbuf)
 737       (erase-buffer)
 738       (insert-buffer-substring artbuf)
 739       (gnus-convert-article-to-rmail)
 740       ;; Decide whether to append to a file or to an Emacs buffer.
 741       (let ((outbuf (get-file-buffer filename)))
 742         (if (not outbuf)
 743             (append-to-file (point-min) (point-max) filename)
 744           ;; File has been visited, in buffer OUTBUF.
 745           (set-buffer outbuf)
 746           (let ((buffer-read-only nil)
 747                 (msg (and (boundp 'rmail-current-message)
 748                           (symbol-value 'rmail-current-message))))
 749             ;; If MSG is non-nil, buffer is in RMAIL mode.
 750             (when msg
 751               (widen)
 752               (narrow-to-region (point-max) (point-max)))
 753             (insert-buffer-substring tmpbuf)
 754             (when msg
 755               (goto-char (point-min))
 756               (widen)
 757               (search-backward "\^_")
 758               (narrow-to-region (point) (point-max))
 759               (goto-char (1+ (point-min)))
 760               (rmail-count-new-messages t)
 761               (rmail-show-message msg))
 762             (save-buffer)))))
 763     (kill-buffer tmpbuf)))
 764
 765 (defun gnus-output-to-mail (filename &optional ask)
 766   "Append the current article to a mail file named FILENAME."
 767   (setq filename (expand-file-name filename))
 768   (let ((artbuf (current-buffer))
 769         (tmpbuf (get-buffer-create " *Gnus-output*")))
 770     (save-excursion
 771       ;; Create the file, if it doesn't exist.
 772       (when (and (not (get-file-buffer filename))
 773                  (not (file-exists-p filename)))
 774         (if (or (not ask)
 775                 (gnus-y-or-n-p
 776                  (concat "\"" filename "\" does not exist, create it? ")))
 777             (let ((file-buffer (create-file-buffer filename)))
 778               (save-excursion
 779                 (set-buffer file-buffer)
 780                 (let ((require-final-newline nil))
 781                   (gnus-write-buffer filename)))
 782               (kill-buffer file-buffer))
 783           (error "Output file does not exist")))
 784       (set-buffer tmpbuf)
 785       (erase-buffer)
 786       (insert-buffer-substring artbuf)
 787       (goto-char (point-min))
 788       (if (looking-at "From ")
 789           (forward-line 1)
 790         (insert "From nobody " (current-time-string) "\n"))
 791       (let (case-fold-search)
 792         (while (re-search-forward "^From " nil t)
 793           (beginning-of-line)
 794           (insert ">")))
 795       ;; Decide whether to append to a file or to an Emacs buffer.
 796       (let ((outbuf (get-file-buffer filename)))
 797         (if (not outbuf)
 798             (let ((buffer-read-only nil))
 799               (save-excursion
 800                 (goto-char (point-max))
 801                 (forward-char -2)
 802                 (unless (looking-at "\n\n")
 803                   (goto-char (point-max))
 804                   (unless (bolp)
 805                     (insert "\n"))
 806                   (insert "\n"))
 807                 (goto-char (point-max))
 808                 (append-to-file (point-min) (point-max) filename)))
 809           ;; File has been visited, in buffer OUTBUF.
 810           (set-buffer outbuf)
 811           (let ((buffer-read-only nil))
 812             (goto-char (point-max))
 813             (unless (eobp)
 814               (insert "\n"))
 815             (insert "\n")
 816             (insert-buffer-substring tmpbuf)))))
 817     (kill-buffer tmpbuf)))
 818
 819 (defun gnus-convert-article-to-rmail ()
 820   "Convert article in current buffer to Rmail message format."
 821   (let ((buffer-read-only nil))
 822     ;; Convert article directly into Babyl format.
 823     (goto-char (point-min))
 824     (insert "\^L\n0, unseen,,\n*** EOOH ***\n")
 825     (while (search-forward "\n\^_" nil t) ;single char
 826       (replace-match "\n^_" t t))       ;2 chars: "^" and "_"
 827     (goto-char (point-max))
 828     (insert "\^_")))
 829
 830 (defun gnus-map-function (funs arg)
 831   "Applies the result of the first function in FUNS to the second, and so on.
 832 ARG is passed to the first function."
 833   (let ((myfuns funs)
 834         (myarg arg))
 835     (while myfuns
 836       (setq arg (funcall (pop myfuns) arg)))
 837     arg))
 838
 839 (defun gnus-run-hooks (&rest funcs)
 840   "Does the same as `run-hooks', but saves excursion."
 841   (let ((buf (current-buffer)))
 842     (unwind-protect
 843         (apply 'run-hooks funcs)
 844       (set-buffer buf))))
 845
 846 ;;;
 847 ;;; .netrc and .authinforc parsing
 848 ;;;
 849
 850 (defvar gnus-netrc-syntax-table
 851   (let ((table (copy-syntax-table text-mode-syntax-table)))
 852     (modify-syntax-entry ?- "w" table)
 853     (modify-syntax-entry ?_ "w" table)
 854     (modify-syntax-entry ?! "w" table)
 855     (modify-syntax-entry ?. "w" table)
 856     (modify-syntax-entry ?, "w" table)
 857     (modify-syntax-entry ?: "w" table)
 858     (modify-syntax-entry ?\; "w" table)
 859     (modify-syntax-entry ?% "w" table)
 860     (modify-syntax-entry ?) "w" table)
 861     (modify-syntax-entry ?( "w" table)
 862     table)
 863   "Syntax table when parsing .netrc files.")
 864
 865 (defun gnus-parse-netrc (file)
 866   "Parse FILE and return an list of all entries in the file."
 867   (if (not (file-exists-p file))
 868       ()
 869     (save-excursion
 870       (let ((tokens '("machine" "default" "login"
 871                       "password" "account" "macdef"))
 872             alist elem result pair)
 873         (nnheader-set-temp-buffer " *netrc*")
 874         (set-syntax-table gnus-netrc-syntax-table)
 875         (insert-file-contents file)
 876         (goto-char (point-min))
 877         ;; Go through the file, line by line.
 878         (while (not (eobp))
 879           (narrow-to-region (point) (gnus-point-at-eol))
 880           ;; For each line, get the tokens and values.
 881           (while (not (eobp))
 882             (skip-chars-forward "\t ")
 883             (unless (eobp)
 884               (setq elem (buffer-substring
 885                           (point) (progn (forward-sexp 1) (point))))
 886               (cond
 887                ((equal elem "macdef")
 888                 ;; We skip past the macro definition.
 889                 (widen)
 890                 (while (and (zerop (forward-line 1))
 891                             (looking-at "$")))
 892                 (narrow-to-region (point) (point)))
 893                ((member elem tokens)
 894                 ;; Tokens that don't have a following value are ignored.
 895                 (when (and pair (cdr pair))
 896                   (push pair alist))
 897                 (setq pair (list elem)))
 898                (t
 899                 ;; Values that haven't got a preceding token are ignored.
 900                 (when pair
 901                   (setcdr pair elem)
 902                   (push pair alist)
 903                   (setq pair nil))))))
 904           (push alist result)
 905           (setq alist nil
 906                 pair nil)
 907           (widen)
 908           (forward-line 1))
 909         result))))
 910
 911 (defun gnus-netrc-machine (list machine)
 912   "Return the netrc values from LIST for MACHINE."
 913   (while (and list
 914               (not (equal (cdr (assoc "machine" (car list))) machine)))
 915     (pop list))
 916   (when list
 917     (car list)))
 918
 919 (defun gnus-netrc-get (alist type)
 920   "Return the value of token TYPE from ALIST."
 921   (cdr (assoc type alist)))
 922
 923 (provide 'gnus-util)
 924
 925 ;;; gnus-util.el ends here