cgit.sxemacs.org Git - gnus/blob - lisp/gnus-util.el

   1 ;;; gnus-util.el --- utility functions for Gnus
   2 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Nothing in this file depends on any other parts of Gnus -- all
  28 ;; functions and macros in this file are utility functions that are
  29 ;; used by Gnus and may be used by any other package without loading
  30 ;; Gnus first.
  31
  32 ;; [Unfortunately, it does depend on other parts of Gnus, e.g. the
  33 ;; autoloads below...]
  34
  35 ;;; Code:
  36
  37 (require 'custom)
  38 (eval-when-compile
  39   (require 'cl)
  40   ;; Fixme: this should be a gnus variable, not nnmail-.
  41   (defvar nnmail-pathname-coding-system))
  42 (require 'time-date)
  43 (require 'netrc)
  44
  45 (eval-and-compile
  46   (autoload 'message-fetch-field "message")
  47   (autoload 'gnus-get-buffer-window "gnus-win")
  48   (autoload 'rmail-insert-rmail-file-header "rmail")
  49   (autoload 'rmail-count-new-messages "rmail")
  50   (autoload 'rmail-show-message "rmail")
  51   (autoload 'nnheader-narrow-to-headers "nnheader")
  52   (autoload 'nnheader-replace-chars-in-string "nnheader"))
  53
  54 (eval-and-compile
  55   (cond
  56    ((fboundp 'replace-in-string)
  57     (defalias 'gnus-replace-in-string 'replace-in-string))
  58    ((fboundp 'replace-regexp-in-string)
  59     (defun gnus-replace-in-string  (string regexp newtext &optional literal)
  60       (replace-regexp-in-string regexp newtext string nil literal)))
  61    (t
  62     (defun gnus-replace-in-string (string regexp newtext &optional literal)
  63       (let ((start 0) tail)
  64         (while (string-match regexp string start)
  65           (setq tail (- (length string) (match-end 0)))
  66           (setq string (replace-match newtext nil literal string))
  67           (setq start (- (length string) tail))))
  68       string))))
  69
  70 ;;; bring in the netrc functions as aliases
  71 (defalias 'gnus-netrc-get 'netrc-get)
  72 (defalias 'gnus-netrc-machine 'netrc-machine)
  73 (defalias 'gnus-parse-netrc 'netrc-parse)
  74
  75 (defun gnus-boundp (variable)
  76   "Return non-nil if VARIABLE is bound and non-nil."
  77   (and (boundp variable)
  78        (symbol-value variable)))
  79
  80 (defmacro gnus-eval-in-buffer-window (buffer &rest forms)
  81   "Pop to BUFFER, evaluate FORMS, and then return to the original window."
  82   (let ((tempvar (make-symbol "GnusStartBufferWindow"))
  83         (w (make-symbol "w"))
  84         (buf (make-symbol "buf")))
  85     `(let* ((,tempvar (selected-window))
  86             (,buf ,buffer)
  87             (,w (gnus-get-buffer-window ,buf 'visible)))
  88        (unwind-protect
  89            (progn
  90              (if ,w
  91                  (progn
  92                    (select-window ,w)
  93                    (set-buffer (window-buffer ,w)))
  94                (pop-to-buffer ,buf))
  95              ,@forms)
  96          (select-window ,tempvar)))))
  97
  98 (put 'gnus-eval-in-buffer-window 'lisp-indent-function 1)
  99 (put 'gnus-eval-in-buffer-window 'edebug-form-spec '(form body))
 100
 101 (defmacro gnus-intern-safe (string hashtable)
 102   "Set hash value.  Arguments are STRING, VALUE, and HASHTABLE."
 103   `(let ((symbol (intern ,string ,hashtable)))
 104      (or (boundp symbol)
 105          (set symbol nil))
 106      symbol))
 107
 108 ;; Added by Geoffrey T. Dairiki <dairiki@u.washington.edu>.  A safe way
 109 ;; to limit the length of a string.  This function is necessary since
 110 ;; `(substr "abc" 0 30)' pukes with "Args out of range".
 111 ;; Fixme: Why not `truncate-string-to-width'?
 112 (defsubst gnus-limit-string (str width)
 113   (if (> (length str) width)
 114       (substring str 0 width)
 115     str))
 116
 117 (defsubst gnus-goto-char (point)
 118   (and point (goto-char point)))
 119
 120 (defmacro gnus-buffer-exists-p (buffer)
 121   `(let ((buffer ,buffer))
 122      (when buffer
 123        (funcall (if (stringp buffer) 'get-buffer 'buffer-name)
 124                 buffer))))
 125
 126 ;; The LOCAL arg to `add-hook' is interpreted differently in Emacs and
 127 ;; XEmacs.  In Emacs we don't need to call `make-local-hook' first.
 128 ;; It's harmless, though, so the main purpose of this alias is to shut
 129 ;; up the byte compiler.
 130 (defalias 'gnus-make-local-hook
 131   (if (eq (get 'make-local-hook 'byte-compile)
 132           'byte-compile-obsolete)
 133       'ignore                           ; Emacs
 134     'make-local-hook))                  ; XEmacs
 135
 136 (defun gnus-delete-first (elt list)
 137   "Delete by side effect the first occurrence of ELT as a member of LIST."
 138   (if (equal (car list) elt)
 139       (cdr list)
 140     (let ((total list))
 141       (while (and (cdr list)
 142                   (not (equal (cadr list) elt)))
 143         (setq list (cdr list)))
 144       (when (cdr list)
 145         (setcdr list (cddr list)))
 146       total)))
 147
 148 ;; Delete the current line (and the next N lines).
 149 (defmacro gnus-delete-line (&optional n)
 150   `(delete-region (point-at-bol)
 151                   (progn (forward-line ,(or n 1)) (point))))
 152
 153 (defun gnus-byte-code (func)
 154   "Return a form that can be `eval'ed based on FUNC."
 155   (let ((fval (indirect-function func)))
 156     (if (byte-code-function-p fval)
 157         (let ((flist (append fval nil)))
 158           (setcar flist 'byte-code)
 159           flist)
 160       (cons 'progn (cddr fval)))))
 161
 162 (defun gnus-extract-address-components (from)
 163   "Extract address components from a From header.
 164 Given an RFC-822 address FROM, extract full name and canonical address.
 165 Returns a list of the form (FULL-NAME CANONICAL-ADDRESS).  Much more simple
 166 solution than `mail-extract-address-components', which works much better, but
 167 is slower."
 168   (let (name address)
 169     ;; First find the address - the thing with the @ in it.  This may
 170     ;; not be accurate in mail addresses, but does the trick most of
 171     ;; the time in news messages.
 172     (when (string-match "\\b[^@ \t<>]+[!@][^@ \t<>]+\\b" from)
 173       (setq address (substring from (match-beginning 0) (match-end 0))))
 174     ;; Then we check whether the "name <address>" format is used.
 175     (and address
 176          ;; Linear white space is not required.
 177          (string-match (concat "[ \t]*<" (regexp-quote address) ">") from)
 178          (and (setq name (substring from 0 (match-beginning 0)))
 179               ;; Strip any quotes from the name.
 180               (string-match "^\".*\"$" name)
 181               (setq name (substring name 1 (1- (match-end 0))))))
 182     ;; If not, then "address (name)" is used.
 183     (or name
 184         (and (string-match "(.+)" from)
 185              (setq name (substring from (1+ (match-beginning 0))
 186                                    (1- (match-end 0)))))
 187         (and (string-match "()" from)
 188              (setq name address))
 189         ;; XOVER might not support folded From headers.
 190         (and (string-match "(.*" from)
 191              (setq name (substring from (1+ (match-beginning 0))
 192                                    (match-end 0)))))
 193     (list (if (string= name "") nil name) (or address from))))
 194
 195
 196 (defun gnus-fetch-field (field)
 197   "Return the value of the header FIELD of current article."
 198   (save-excursion
 199     (save-restriction
 200       (let ((case-fold-search t)
 201             (inhibit-point-motion-hooks t))
 202         (nnheader-narrow-to-headers)
 203         (message-fetch-field field)))))
 204
 205 (defun gnus-fetch-original-field (field)
 206   "Fetch FIELD from the original version of the current article."
 207   (with-current-buffer gnus-original-article-buffer
 208     (gnus-fetch-field field)))
 209
 210
 211 (defun gnus-goto-colon ()
 212   (beginning-of-line)
 213   (let ((eol (point-at-eol)))
 214     (goto-char (or (text-property-any (point) eol 'gnus-position t)
 215                    (search-forward ":" eol t)
 216                    (point)))))
 217
 218 (defun gnus-decode-newsgroups (newsgroups group &optional method)
 219   (let ((method (or method (gnus-find-method-for-group group))))
 220     (mapconcat (lambda (group)
 221                  (gnus-group-name-decode group (gnus-group-name-charset
 222                                                 method group)))
 223                (message-tokenize-header newsgroups)
 224                ",")))
 225
 226 (defun gnus-remove-text-with-property (prop)
 227   "Delete all text in the current buffer with text property PROP."
 228   (save-excursion
 229     (goto-char (point-min))
 230     (while (not (eobp))
 231       (while (get-text-property (point) prop)
 232         (delete-char 1))
 233       (goto-char (next-single-property-change (point) prop nil (point-max))))))
 234
 235 (defun gnus-newsgroup-directory-form (newsgroup)
 236   "Make hierarchical directory name from NEWSGROUP name."
 237   (let* ((newsgroup (gnus-newsgroup-savable-name newsgroup))
 238          (idx (string-match ":" newsgroup)))
 239     (concat
 240      (if idx (substring newsgroup 0 idx))
 241      (if idx "/")
 242      (nnheader-replace-chars-in-string
 243       (if idx (substring newsgroup (1+ idx)) newsgroup)
 244       ?. ?/))))
 245
 246 (defun gnus-newsgroup-savable-name (group)
 247   ;; Replace any slashes in a group name (eg. an ange-ftp nndoc group)
 248   ;; with dots.
 249   (nnheader-replace-chars-in-string group ?/ ?.))
 250
 251 (defun gnus-string> (s1 s2)
 252   (not (or (string< s1 s2)
 253            (string= s1 s2))))
 254
 255 ;;; Time functions.
 256
 257 (defun gnus-file-newer-than (file date)
 258   (let ((fdate (nth 5 (file-attributes file))))
 259     (or (> (car fdate) (car date))
 260         (and (= (car fdate) (car date))
 261              (> (nth 1 fdate) (nth 1 date))))))
 262
 263 ;;; Keymap macros.
 264
 265 (defmacro gnus-local-set-keys (&rest plist)
 266   "Set the keys in PLIST in the current keymap."
 267   `(gnus-define-keys-1 (current-local-map) ',plist))
 268
 269 (defmacro gnus-define-keys (keymap &rest plist)
 270   "Define all keys in PLIST in KEYMAP."
 271   `(gnus-define-keys-1 (quote ,keymap) (quote ,plist)))
 272
 273 (defmacro gnus-define-keys-safe (keymap &rest plist)
 274   "Define all keys in PLIST in KEYMAP without overwriting previous definitions."
 275   `(gnus-define-keys-1 (quote ,keymap) (quote ,plist) t))
 276
 277 (put 'gnus-define-keys 'lisp-indent-function 1)
 278 (put 'gnus-define-keys-safe 'lisp-indent-function 1)
 279 (put 'gnus-local-set-keys 'lisp-indent-function 1)
 280
 281 (defmacro gnus-define-keymap (keymap &rest plist)
 282   "Define all keys in PLIST in KEYMAP."
 283   `(gnus-define-keys-1 ,keymap (quote ,plist)))
 284
 285 (put 'gnus-define-keymap 'lisp-indent-function 1)
 286
 287 (defun gnus-define-keys-1 (keymap plist &optional safe)
 288   (when (null keymap)
 289     (error "Can't set keys in a null keymap"))
 290   (cond ((symbolp keymap)
 291          (setq keymap (symbol-value keymap)))
 292         ((keymapp keymap))
 293         ((listp keymap)
 294          (set (car keymap) nil)
 295          (define-prefix-command (car keymap))
 296          (define-key (symbol-value (caddr keymap)) (cadr keymap) (car keymap))
 297          (setq keymap (symbol-value (car keymap)))))
 298   (let (key)
 299     (while plist
 300       (when (symbolp (setq key (pop plist)))
 301         (setq key (symbol-value key)))
 302       (if (or (not safe)
 303               (eq (lookup-key keymap key) 'undefined))
 304           (define-key keymap key (pop plist))
 305         (pop plist)))))
 306
 307 (defun gnus-completing-read-with-default (default prompt &rest args)
 308   ;; Like `completing-read', except that DEFAULT is the default argument.
 309   (let* ((prompt (if default
 310                      (concat prompt " (default " default ") ")
 311                    (concat prompt " ")))
 312          (answer (apply 'completing-read prompt args)))
 313     (if (or (null answer) (zerop (length answer)))
 314         default
 315       answer)))
 316
 317 ;; Two silly functions to ensure that all `y-or-n-p' questions clear
 318 ;; the echo area.
 319 (defun gnus-y-or-n-p (prompt)
 320   (prog1
 321       (y-or-n-p prompt)
 322     (message "")))
 323
 324 (defun gnus-yes-or-no-p (prompt)
 325   (prog1
 326       (yes-or-no-p prompt)
 327     (message "")))
 328
 329 ;; By Frank Schmitt <ich@Frank-Schmitt.net>. Allows to have
 330 ;; age-depending date representations. (e.g. just the time if it's
 331 ;; from today, the day of the week if it's within the last 7 days and
 332 ;; the full date if it's older)
 333
 334 (defun gnus-seconds-today ()
 335   "Return the number of seconds passed today."
 336   (let ((now (decode-time (current-time))))
 337     (+ (car now) (* (car (cdr now)) 60) (* (car (nthcdr 2 now)) 3600))))
 338
 339 (defun gnus-seconds-month ()
 340   "Return the number of seconds passed this month."
 341   (let ((now (decode-time (current-time))))
 342     (+ (car now) (* (car (cdr now)) 60) (* (car (nthcdr 2 now)) 3600)
 343        (* (- (car (nthcdr 3 now)) 1) 3600 24))))
 344
 345 (defun gnus-seconds-year ()
 346   "Return the number of seconds passed this year."
 347   (let ((now (decode-time (current-time)))
 348         (days (format-time-string "%j" (current-time))))
 349     (+ (car now) (* (car (cdr now)) 60) (* (car (nthcdr 2 now)) 3600)
 350        (* (- (string-to-number days) 1) 3600 24))))
 351
 352 (defvar gnus-user-date-format-alist
 353   '(((gnus-seconds-today) . "%k:%M")
 354     (604800 . "%a %k:%M")                   ;;that's one week
 355     ((gnus-seconds-month) . "%a %d")
 356     ((gnus-seconds-year) . "%b %d")
 357     (t . "%b %d '%y"))                      ;;this one is used when no
 358                                             ;;other does match
 359   "Specifies date format depending on age of article.
 360 This is an alist of items (AGE . FORMAT).  AGE can be a number (of
 361 seconds) or a Lisp expression evaluating to a number.  When the age of
 362 the article is less than this number, then use `format-time-string'
 363 with the corresponding FORMAT for displaying the date of the article.
 364 If AGE is not a number or a Lisp expression evaluating to a
 365 non-number, then the corresponding FORMAT is used as a default value.
 366
 367 Note that the list is processed from the beginning, so it should be
 368 sorted by ascending AGE.  Also note that items following the first
 369 non-number AGE will be ignored.
 370
 371 You can use the functions `gnus-seconds-today', `gnus-seconds-month'
 372 and `gnus-seconds-year' in the AGE spec.  They return the number of
 373 seconds passed since the start of today, of this month, of this year,
 374 respectively.")
 375
 376 (defun gnus-user-date (messy-date)
 377   "Format the messy-date according to gnus-user-date-format-alist.
 378 Returns \"  ?  \" if there's bad input or if an other error occurs.
 379 Input should look like this: \"Sun, 14 Oct 2001 13:34:39 +0200\"."
 380   (condition-case ()
 381       (let* ((messy-date (time-to-seconds (safe-date-to-time messy-date)))
 382              (now (time-to-seconds (current-time)))
 383              ;;If we don't find something suitable we'll use this one
 384              (my-format "%b %d '%y"))
 385         (let* ((difference (- now messy-date))
 386                (templist gnus-user-date-format-alist)
 387                (top (eval (caar templist))))
 388           (while (if (numberp top) (< top difference) (not top))
 389             (progn
 390               (setq templist (cdr templist))
 391               (setq top (eval (caar templist)))))
 392           (if (stringp (cdr (car templist)))
 393               (setq my-format (cdr (car templist)))))
 394         (format-time-string (eval my-format) (seconds-to-time messy-date)))
 395     (error "  ?   ")))
 396
 397 (defun gnus-dd-mmm (messy-date)
 398   "Return a string like DD-MMM from a big messy string."
 399   (condition-case ()
 400       (format-time-string "%d-%b" (safe-date-to-time messy-date))
 401     (error "  -   ")))
 402
 403 (defmacro gnus-date-get-time (date)
 404   "Convert DATE string to Emacs time.
 405 Cache the result as a text property stored in DATE."
 406   ;; Either return the cached value...
 407   `(let ((d ,date))
 408      (if (equal "" d)
 409          '(0 0)
 410        (or (get-text-property 0 'gnus-time d)
 411            ;; or compute the value...
 412            (let ((time (safe-date-to-time d)))
 413              ;; and store it back in the string.
 414              (put-text-property 0 1 'gnus-time time d)
 415              time)))))
 416
 417 (defsubst gnus-time-iso8601 (time)
 418   "Return a string of TIME in YYYYMMDDTHHMMSS format."
 419   (format-time-string "%Y%m%dT%H%M%S" time))
 420
 421 (defun gnus-date-iso8601 (date)
 422   "Convert the DATE to YYYYMMDDTHHMMSS."
 423   (condition-case ()
 424       (gnus-time-iso8601 (gnus-date-get-time date))
 425     (error "")))
 426
 427 (defun gnus-mode-string-quote (string)
 428   "Quote all \"%\"'s in STRING."
 429   (gnus-replace-in-string string "%" "%%"))
 430
 431 ;; Make a hash table (default and minimum size is 256).
 432 ;; Optional argument HASHSIZE specifies the table size.
 433 (defun gnus-make-hashtable (&optional hashsize)
 434   (make-vector (if hashsize (max (gnus-create-hash-size hashsize) 256) 256) 0))
 435
 436 ;; Make a number that is suitable for hashing; bigger than MIN and
 437 ;; equal to some 2^x.  Many machines (such as sparcs) do not have a
 438 ;; hardware modulo operation, so they implement it in software.  On
 439 ;; many sparcs over 50% of the time to intern is spent in the modulo.
 440 ;; Yes, it's slower than actually computing the hash from the string!
 441 ;; So we use powers of 2 so people can optimize the modulo to a mask.
 442 (defun gnus-create-hash-size (min)
 443   (let ((i 1))
 444     (while (< i min)
 445       (setq i (* 2 i)))
 446     i))
 447
 448 (defcustom gnus-verbose 7
 449   "*Integer that says how verbose Gnus should be.
 450 The higher the number, the more messages Gnus will flash to say what
 451 it's doing.  At zero, Gnus will be totally mute; at five, Gnus will
 452 display most important messages; and at ten, Gnus will keep on
 453 jabbering all the time."
 454   :group 'gnus-start
 455   :type 'integer)
 456
 457 (defun gnus-message (level &rest args)
 458   "If LEVEL is lower than `gnus-verbose' print ARGS using `message'.
 459
 460 Guideline for numbers:
 461 1 - error messages, 3 - non-serious error messages, 5 - messages for things
 462 that take a long time, 7 - not very important messages on stuff, 9 - messages
 463 inside loops."
 464   (if (<= level gnus-verbose)
 465       (apply 'message args)
 466     ;; We have to do this format thingy here even if the result isn't
 467     ;; shown - the return value has to be the same as the return value
 468     ;; from `message'.
 469     (apply 'format args)))
 470
 471 (defun gnus-error (level &rest args)
 472   "Beep an error if LEVEL is equal to or less than `gnus-verbose'."
 473   (when (<= (floor level) gnus-verbose)
 474     (apply 'message args)
 475     (ding)
 476     (let (duration)
 477       (when (and (floatp level)
 478                  (not (zerop (setq duration (* 10 (- level (floor level)))))))
 479         (sit-for duration))))
 480   nil)
 481
 482 (defun gnus-split-references (references)
 483   "Return a list of Message-IDs in REFERENCES."
 484   (let ((beg 0)
 485         ids)
 486     (while (string-match "<[^<]+[^< \t]" references beg)
 487       (push (substring references (match-beginning 0) (setq beg (match-end 0)))
 488             ids))
 489     (nreverse ids)))
 490
 491 (defsubst gnus-parent-id (references &optional n)
 492   "Return the last Message-ID in REFERENCES.
 493 If N, return the Nth ancestor instead."
 494   (when (and references
 495              (not (zerop (length references))))
 496     (if n
 497         (let ((ids (inline (gnus-split-references references))))
 498           (while (nthcdr n ids)
 499             (setq ids (cdr ids)))
 500           (car ids))
 501       (when (string-match "\\(<[^<]+>\\)[ \t]*\\'" references)
 502         (match-string 1 references)))))
 503
 504 (defun gnus-buffer-live-p (buffer)
 505   "Say whether BUFFER is alive or not."
 506   (and buffer
 507        (get-buffer buffer)
 508        (buffer-name (get-buffer buffer))))
 509
 510 (defun gnus-horizontal-recenter ()
 511   "Recenter the current buffer horizontally."
 512   (if (< (current-column) (/ (window-width) 2))
 513       (set-window-hscroll (gnus-get-buffer-window (current-buffer) t) 0)
 514     (let* ((orig (point))
 515            (end (window-end (gnus-get-buffer-window (current-buffer) t)))
 516            (max 0))
 517       (when end
 518         ;; Find the longest line currently displayed in the window.
 519         (goto-char (window-start))
 520         (while (and (not (eobp))
 521                     (< (point) end))
 522           (end-of-line)
 523           (setq max (max max (current-column)))
 524           (forward-line 1))
 525         (goto-char orig)
 526         ;; Scroll horizontally to center (sort of) the point.
 527         (if (> max (window-width))
 528             (set-window-hscroll
 529              (gnus-get-buffer-window (current-buffer) t)
 530              (min (- (current-column) (/ (window-width) 3))
 531                   (+ 2 (- max (window-width)))))
 532           (set-window-hscroll (gnus-get-buffer-window (current-buffer) t) 0))
 533         max))))
 534
 535 (defun gnus-read-event-char (&optional prompt)
 536   "Get the next event."
 537   (let ((event (read-event prompt)))
 538     ;; should be gnus-characterp, but this can't be called in XEmacs anyway
 539     (cons (and (numberp event) event) event)))
 540
 541 (defun gnus-sortable-date (date)
 542   "Make string suitable for sorting from DATE."
 543   (gnus-time-iso8601 (date-to-time date)))
 544
 545 (defun gnus-copy-file (file &optional to)
 546   "Copy FILE to TO."
 547   (interactive
 548    (list (read-file-name "Copy file: " default-directory)
 549          (read-file-name "Copy file to: " default-directory)))
 550   (unless to
 551     (setq to (read-file-name "Copy file to: " default-directory)))
 552   (when (file-directory-p to)
 553     (setq to (concat (file-name-as-directory to)
 554                      (file-name-nondirectory file))))
 555   (copy-file file to))
 556
 557 (defvar gnus-work-buffer " *gnus work*")
 558
 559 (defun gnus-set-work-buffer ()
 560   "Put point in the empty Gnus work buffer."
 561   (if (get-buffer gnus-work-buffer)
 562       (progn
 563         (set-buffer gnus-work-buffer)
 564         (erase-buffer))
 565     (set-buffer (gnus-get-buffer-create gnus-work-buffer))
 566     (kill-all-local-variables)
 567     (mm-enable-multibyte)))
 568
 569 (defmacro gnus-group-real-name (group)
 570   "Find the real name of a foreign newsgroup."
 571   `(let ((gname ,group))
 572      (if (string-match "^[^:]+:" gname)
 573          (substring gname (match-end 0))
 574        gname)))
 575
 576 (defun gnus-make-sort-function (funs)
 577   "Return a composite sort condition based on the functions in FUNS."
 578   (cond
 579    ;; Just a simple function.
 580    ((functionp funs) funs)
 581    ;; No functions at all.
 582    ((null funs) funs)
 583    ;; A list of functions.
 584    ((or (cdr funs)
 585         (listp (car funs)))
 586     (gnus-byte-compile
 587      `(lambda (t1 t2)
 588         ,(gnus-make-sort-function-1 (reverse funs)))))
 589    ;; A list containing just one function.
 590    (t
 591     (car funs))))
 592
 593 (defun gnus-make-sort-function-1 (funs)
 594   "Return a composite sort condition based on the functions in FUNS."
 595   (let ((function (car funs))
 596         (first 't1)
 597         (last 't2))
 598     (when (consp function)
 599       (cond
 600        ;; Reversed spec.
 601        ((eq (car function) 'not)
 602         (setq function (cadr function)
 603               first 't2
 604               last 't1))
 605        ((functionp function)
 606         ;; Do nothing.
 607         )
 608        (t
 609         (error "Invalid sort spec: %s" function))))
 610     (if (cdr funs)
 611         `(or (,function ,first ,last)
 612              (and (not (,function ,last ,first))
 613                   ,(gnus-make-sort-function-1 (cdr funs))))
 614       `(,function ,first ,last))))
 615
 616 (defun gnus-turn-off-edit-menu (type)
 617   "Turn off edit menu in `gnus-TYPE-mode-map'."
 618   (define-key (symbol-value (intern (format "gnus-%s-mode-map" type)))
 619     [menu-bar edit] 'undefined))
 620
 621 (defun gnus-prin1 (form)
 622   "Use `prin1' on FORM in the current buffer.
 623 Bind `print-quoted' and `print-readably' to t while printing."
 624   (let ((print-quoted t)
 625         (print-readably t)
 626         (print-escape-multibyte nil)
 627         print-level print-length)
 628     (prin1 form (current-buffer))))
 629
 630 (defun gnus-prin1-to-string (form)
 631   "The same as `prin1'.
 632 Bind `print-quoted' and `print-readably' to t, and `print-length'
 633 and `print-level' to nil."
 634   (let ((print-quoted t)
 635         (print-readably t)
 636         (print-length nil)
 637         (print-level nil))
 638     (prin1-to-string form)))
 639
 640 (defun gnus-make-directory (directory)
 641   "Make DIRECTORY (and all its parents) if it doesn't exist."
 642   (require 'nnmail)
 643   (let ((file-name-coding-system nnmail-pathname-coding-system))
 644     (when (and directory
 645                (not (file-exists-p directory)))
 646       (make-directory directory t)))
 647   t)
 648
 649 (defun gnus-write-buffer (file)
 650   "Write the current buffer's contents to FILE."
 651   ;; Make sure the directory exists.
 652   (gnus-make-directory (file-name-directory file))
 653   (let ((file-name-coding-system nnmail-pathname-coding-system))
 654     ;; Write the buffer.
 655     (write-region (point-min) (point-max) file nil 'quietly)))
 656
 657 (defun gnus-delete-file (file)
 658   "Delete FILE if it exists."
 659   (when (file-exists-p file)
 660     (delete-file file)))
 661
 662 (defun gnus-strip-whitespace (string)
 663   "Return STRING stripped of all whitespace."
 664   (while (string-match "[\r\n\t ]+" string)
 665     (setq string (replace-match "" t t string)))
 666   string)
 667
 668 (defsubst gnus-put-text-property-excluding-newlines (beg end prop val)
 669   "The same as `put-text-property', but don't put this prop on any newlines in the region."
 670   (save-match-data
 671     (save-excursion
 672       (save-restriction
 673         (goto-char beg)
 674         (while (re-search-forward gnus-emphasize-whitespace-regexp end 'move)
 675           (gnus-put-text-property beg (match-beginning 0) prop val)
 676           (setq beg (point)))
 677         (gnus-put-text-property beg (point) prop val)))))
 678
 679 (defsubst gnus-put-overlay-excluding-newlines (beg end prop val)
 680   "The same as `put-text-property', but don't put this prop on any newlines in the region."
 681   (save-match-data
 682     (save-excursion
 683       (save-restriction
 684         (goto-char beg)
 685         (while (re-search-forward gnus-emphasize-whitespace-regexp end 'move)
 686           (gnus-overlay-put
 687            (gnus-make-overlay beg (match-beginning 0))
 688            prop val)
 689           (setq beg (point)))
 690         (gnus-overlay-put (gnus-make-overlay beg (point)) prop val)))))
 691
 692 (defun gnus-put-text-property-excluding-characters-with-faces (beg end
 693                                                                    prop val)
 694   "The same as `put-text-property', but don't put props on characters with the `gnus-face' property."
 695   (let ((b beg))
 696     (while (/= b end)
 697       (when (get-text-property b 'gnus-face)
 698         (setq b (next-single-property-change b 'gnus-face nil end)))
 699       (when (/= b end)
 700         (inline
 701           (gnus-put-text-property
 702            b (setq b (next-single-property-change b 'gnus-face nil end))
 703            prop val))))))
 704
 705 (defmacro gnus-faces-at (position)
 706   "Return a list of faces at POSITION."
 707   (if (featurep 'xemacs)
 708       `(let ((pos ,position))
 709          (mapcar-extents 'extent-face
 710                          nil (current-buffer) pos pos nil 'face))
 711     `(let ((pos ,position))
 712        (delq nil (cons (get-text-property pos 'face)
 713                        (mapcar
 714                         (lambda (overlay)
 715                           (overlay-get overlay 'face))
 716                         (overlays-at pos)))))))
 717
 718 ;;; Protected and atomic operations.  dmoore@ucsd.edu 21.11.1996
 719 ;;; The primary idea here is to try to protect internal datastructures
 720 ;;; from becoming corrupted when the user hits C-g, or if a hook or
 721 ;;; similar blows up.  Often in Gnus multiple tables/lists need to be
 722 ;;; updated at the same time, or information can be lost.
 723
 724 (defvar gnus-atomic-be-safe t
 725   "If t, certain operations will be protected from interruption by C-g.")
 726
 727 (defmacro gnus-atomic-progn (&rest forms)
 728   "Evaluate FORMS atomically, which means to protect the evaluation
 729 from being interrupted by the user.  An error from the forms themselves
 730 will return without finishing the operation.  Since interrupts from
 731 the user are disabled, it is recommended that only the most minimal
 732 operations are performed by FORMS.  If you wish to assign many
 733 complicated values atomically, compute the results into temporary
 734 variables and then do only the assignment atomically."
 735   `(let ((inhibit-quit gnus-atomic-be-safe))
 736      ,@forms))
 737
 738 (put 'gnus-atomic-progn 'lisp-indent-function 0)
 739
 740 (defmacro gnus-atomic-progn-assign (protect &rest forms)
 741   "Evaluate FORMS, but insure that the variables listed in PROTECT
 742 are not changed if anything in FORMS signals an error or otherwise
 743 non-locally exits.  The variables listed in PROTECT are updated atomically.
 744 It is safe to use gnus-atomic-progn-assign with long computations.
 745
 746 Note that if any of the symbols in PROTECT were unbound, they will be
 747 set to nil on a successful assignment.  In case of an error or other
 748 non-local exit, it will still be unbound."
 749   (let* ((temp-sym-map (mapcar (lambda (x) (list (make-symbol
 750                                                   (concat (symbol-name x)
 751                                                           "-tmp"))
 752                                                  x))
 753                                protect))
 754          (sym-temp-map (mapcar (lambda (x) (list (cadr x) (car x)))
 755                                temp-sym-map))
 756          (temp-sym-let (mapcar (lambda (x) (list (car x)
 757                                                  `(and (boundp ',(cadr x))
 758                                                        ,(cadr x))))
 759                                temp-sym-map))
 760          (sym-temp-let sym-temp-map)
 761          (temp-sym-assign (apply 'append temp-sym-map))
 762          (sym-temp-assign (apply 'append sym-temp-map))
 763          (result (make-symbol "result-tmp")))
 764     `(let (,@temp-sym-let
 765            ,result)
 766        (let ,sym-temp-let
 767          (setq ,result (progn ,@forms))
 768          (setq ,@temp-sym-assign))
 769        (let ((inhibit-quit gnus-atomic-be-safe))
 770          (setq ,@sym-temp-assign))
 771        ,result)))
 772
 773 (put 'gnus-atomic-progn-assign 'lisp-indent-function 1)
 774 ;(put 'gnus-atomic-progn-assign 'edebug-form-spec '(sexp body))
 775
 776 (defmacro gnus-atomic-setq (&rest pairs)
 777   "Similar to setq, except that the real symbols are only assigned when
 778 there are no errors.  And when the real symbols are assigned, they are
 779 done so atomically.  If other variables might be changed via side-effect,
 780 see gnus-atomic-progn-assign.  It is safe to use gnus-atomic-setq
 781 with potentially long computations."
 782   (let ((tpairs pairs)
 783         syms)
 784     (while tpairs
 785       (push (car tpairs) syms)
 786       (setq tpairs (cddr tpairs)))
 787     `(gnus-atomic-progn-assign ,syms
 788        (setq ,@pairs))))
 789
 790 ;(put 'gnus-atomic-setq 'edebug-form-spec '(body))
 791
 792
 793 ;;; Functions for saving to babyl/mail files.
 794
 795 (eval-when-compile
 796   (condition-case nil
 797       (progn
 798         (require 'rmail)
 799         (autoload 'rmail-update-summary "rmailsum"))
 800     (error
 801      (define-compiler-macro rmail-select-summary (&rest body)
 802        ;; Rmail of the XEmacs version is supplied by the package, and
 803        ;; requires tm and apel packages.  However, there may be those
 804        ;; who haven't installed those packages.  This macro helps such
 805        ;; people even if they install those packages later.
 806        `(eval '(rmail-select-summary ,@body)))
 807      ;; If there's rmail but there's no tm (or there's apel of the
 808      ;; mainstream, not the XEmacs version), loading rmail of the XEmacs
 809      ;; version fails halfway, however it provides the rmail-select-summary
 810      ;; macro which uses the following functions:
 811      (autoload 'rmail-summary-displayed "rmail")
 812      (autoload 'rmail-maybe-display-summary "rmail")))
 813   (defvar rmail-default-rmail-file)
 814   (defvar mm-text-coding-system))
 815
 816 (defun gnus-output-to-rmail (filename &optional ask)
 817   "Append the current article to an Rmail file named FILENAME."
 818   (require 'rmail)
 819   (require 'mm-util)
 820   ;; Most of these codes are borrowed from rmailout.el.
 821   (setq filename (expand-file-name filename))
 822   (setq rmail-default-rmail-file filename)
 823   (let ((artbuf (current-buffer))
 824         (tmpbuf (get-buffer-create " *Gnus-output*")))
 825     (save-excursion
 826       (or (get-file-buffer filename)
 827           (file-exists-p filename)
 828           (if (or (not ask)
 829                   (gnus-yes-or-no-p
 830                    (concat "\"" filename "\" does not exist, create it? ")))
 831               (let ((file-buffer (create-file-buffer filename)))
 832                 (save-excursion
 833                   (set-buffer file-buffer)
 834                   (rmail-insert-rmail-file-header)
 835                   (let ((require-final-newline nil)
 836                         (coding-system-for-write mm-text-coding-system))
 837                     (gnus-write-buffer filename)))
 838                 (kill-buffer file-buffer))
 839             (error "Output file does not exist")))
 840       (set-buffer tmpbuf)
 841       (erase-buffer)
 842       (insert-buffer-substring artbuf)
 843       (gnus-convert-article-to-rmail)
 844       ;; Decide whether to append to a file or to an Emacs buffer.
 845       (let ((outbuf (get-file-buffer filename)))
 846         (if (not outbuf)
 847             (let ((file-name-coding-system nnmail-pathname-coding-system))
 848               (mm-append-to-file (point-min) (point-max) filename))
 849           ;; File has been visited, in buffer OUTBUF.
 850           (set-buffer outbuf)
 851           (let ((buffer-read-only nil)
 852                 (msg (and (boundp 'rmail-current-message)
 853                           (symbol-value 'rmail-current-message))))
 854             ;; If MSG is non-nil, buffer is in RMAIL mode.
 855             (when msg
 856               (widen)
 857               (narrow-to-region (point-max) (point-max)))
 858             (insert-buffer-substring tmpbuf)
 859             (when msg
 860               (goto-char (point-min))
 861               (widen)
 862               (search-backward "\n\^_")
 863               (narrow-to-region (point) (point-max))
 864               (rmail-count-new-messages t)
 865               (when (rmail-summary-exists)
 866                 (rmail-select-summary
 867                  (rmail-update-summary)))
 868               (rmail-count-new-messages t)
 869               (rmail-show-message msg))
 870             (save-buffer)))))
 871     (kill-buffer tmpbuf)))
 872
 873 (defun gnus-output-to-mail (filename &optional ask)
 874   "Append the current article to a mail file named FILENAME."
 875   (setq filename (expand-file-name filename))
 876   (let ((artbuf (current-buffer))
 877         (tmpbuf (get-buffer-create " *Gnus-output*")))
 878     (save-excursion
 879       ;; Create the file, if it doesn't exist.
 880       (when (and (not (get-file-buffer filename))
 881                  (not (file-exists-p filename)))
 882         (if (or (not ask)
 883                 (gnus-y-or-n-p
 884                  (concat "\"" filename "\" does not exist, create it? ")))
 885             (let ((file-buffer (create-file-buffer filename)))
 886               (save-excursion
 887                 (set-buffer file-buffer)
 888                 (let ((require-final-newline nil)
 889                       (coding-system-for-write mm-text-coding-system))
 890                   (gnus-write-buffer filename)))
 891               (kill-buffer file-buffer))
 892           (error "Output file does not exist")))
 893       (set-buffer tmpbuf)
 894       (erase-buffer)
 895       (insert-buffer-substring artbuf)
 896       (goto-char (point-min))
 897       (if (looking-at "From ")
 898           (forward-line 1)
 899         (insert "From nobody " (current-time-string) "\n"))
 900       (let (case-fold-search)
 901         (while (re-search-forward "^From " nil t)
 902           (beginning-of-line)
 903           (insert ">")))
 904       ;; Decide whether to append to a file or to an Emacs buffer.
 905       (let ((outbuf (get-file-buffer filename)))
 906         (if (not outbuf)
 907             (let ((buffer-read-only nil))
 908               (save-excursion
 909                 (goto-char (point-max))
 910                 (forward-char -2)
 911                 (unless (looking-at "\n\n")
 912                   (goto-char (point-max))
 913                   (unless (bolp)
 914                     (insert "\n"))
 915                   (insert "\n"))
 916                 (goto-char (point-max))
 917                 (let ((file-name-coding-system nnmail-pathname-coding-system))
 918                   (mm-append-to-file (point-min) (point-max) filename))))
 919           ;; File has been visited, in buffer OUTBUF.
 920           (set-buffer outbuf)
 921           (let ((buffer-read-only nil))
 922             (goto-char (point-max))
 923             (unless (eobp)
 924               (insert "\n"))
 925             (insert "\n")
 926             (insert-buffer-substring tmpbuf)))))
 927     (kill-buffer tmpbuf)))
 928
 929 (defun gnus-convert-article-to-rmail ()
 930   "Convert article in current buffer to Rmail message format."
 931   (let ((buffer-read-only nil))
 932     ;; Convert article directly into Babyl format.
 933     (goto-char (point-min))
 934     (insert "\^L\n0, unseen,,\n*** EOOH ***\n")
 935     (while (search-forward "\n\^_" nil t) ;single char
 936       (replace-match "\n^_" t t))       ;2 chars: "^" and "_"
 937     (goto-char (point-max))
 938     (insert "\^_")))
 939
 940 (defun gnus-map-function (funs arg)
 941   "Apply the result of the first function in FUNS to the second, and so on.
 942 ARG is passed to the first function."
 943   (while funs
 944     (setq arg (funcall (pop funs) arg)))
 945   arg)
 946
 947 (defun gnus-run-hooks (&rest funcs)
 948   "Does the same as `run-hooks', but saves the current buffer."
 949   (save-current-buffer
 950     (apply 'run-hooks funcs)))
 951
 952 ;;; Various
 953
 954 (defvar gnus-group-buffer)              ; Compiler directive
 955 (defun gnus-alive-p ()
 956   "Say whether Gnus is running or not."
 957   (and (boundp 'gnus-group-buffer)
 958        (get-buffer gnus-group-buffer)
 959        (save-excursion
 960          (set-buffer gnus-group-buffer)
 961          (eq major-mode 'gnus-group-mode))))
 962
 963 (defun gnus-remove-duplicates (list)
 964   (let (new)
 965     (while list
 966       (or (member (car list) new)
 967           (setq new (cons (car list) new)))
 968       (setq list (cdr list)))
 969     (nreverse new)))
 970
 971 (defun gnus-remove-if (predicate list)
 972   "Return a copy of LIST with all items satisfying PREDICATE removed."
 973   (let (out)
 974     (while list
 975       (unless (funcall predicate (car list))
 976         (push (car list) out))
 977       (setq list (cdr list)))
 978     (nreverse out)))
 979
 980 (if (fboundp 'assq-delete-all)
 981     (defalias 'gnus-delete-alist 'assq-delete-all)
 982   (defun gnus-delete-alist (key alist)
 983     "Delete from ALIST all elements whose car is KEY.
 984 Return the modified alist."
 985     (let (entry)
 986       (while (setq entry (assq key alist))
 987         (setq alist (delq entry alist)))
 988       alist)))
 989
 990 (defmacro gnus-pull (key alist &optional assoc-p)
 991   "Modify ALIST to be without KEY."
 992   (unless (symbolp alist)
 993     (error "Not a symbol: %s" alist))
 994   (let ((fun (if assoc-p 'assoc 'assq)))
 995     `(setq ,alist (delq (,fun ,key ,alist) ,alist))))
 996
 997 (defun gnus-globalify-regexp (re)
 998   "Return a regexp that matches a whole line, iff RE matches a part of it."
 999   (concat (unless (string-match "^\\^" re) "^.*")
1000           re
1001           (unless (string-match "\\$$" re) ".*$")))
1002
1003 (defun gnus-set-window-start (&optional point)
1004   "Set the window start to POINT, or (point) if nil."
1005   (let ((win (gnus-get-buffer-window (current-buffer) t)))
1006     (when win
1007       (set-window-start win (or point (point))))))
1008
1009 (defun gnus-annotation-in-region-p (b e)
1010   (if (= b e)
1011       (eq (cadr (memq 'gnus-undeletable (text-properties-at b))) t)
1012     (text-property-any b e 'gnus-undeletable t)))
1013
1014 (defun gnus-or (&rest elems)
1015   "Return non-nil if any of the elements are non-nil."
1016   (catch 'found
1017     (while elems
1018       (when (pop elems)
1019         (throw 'found t)))))
1020
1021 (defun gnus-and (&rest elems)
1022   "Return non-nil if all of the elements are non-nil."
1023   (catch 'found
1024     (while elems
1025       (unless (pop elems)
1026         (throw 'found nil)))
1027     t))
1028
1029 (defun gnus-write-active-file (file hashtb &optional full-names)
1030   (let ((coding-system-for-write nnmail-active-file-coding-system))
1031     (with-temp-file file
1032       (mapatoms
1033        (lambda (sym)
1034          (when (and sym
1035                     (boundp sym)
1036                     (symbol-value sym))
1037            (insert (format "%S %d %d y\n"
1038                            (if full-names
1039                                sym
1040                              (intern (gnus-group-real-name (symbol-name sym))))
1041                            (or (cdr (symbol-value sym))
1042                                (car (symbol-value sym)))
1043                            (car (symbol-value sym))))))
1044        hashtb)
1045       (goto-char (point-max))
1046       (while (search-backward "\\." nil t)
1047         (delete-char 1)))))
1048
1049 ;; Fixme: Why not use `with-output-to-temp-buffer'?
1050 (defmacro gnus-with-output-to-file (file &rest body)
1051   (let ((buffer (make-symbol "output-buffer"))
1052         (size (make-symbol "output-buffer-size"))
1053         (leng (make-symbol "output-buffer-length"))
1054         (append (make-symbol "output-buffer-append")))
1055     `(let* ((,size 131072)
1056             (,buffer (make-string ,size 0))
1057             (,leng 0)
1058             (,append nil)
1059             (standard-output
1060              (lambda (c)
1061                (aset ,buffer ,leng c)
1062
1063                (if (= ,size (setq ,leng (1+ ,leng)))
1064                    (progn (write-region ,buffer nil ,file ,append 'no-msg)
1065                           (setq ,leng 0
1066                                 ,append t))))))
1067        ,@body
1068        (when (> ,leng 0)
1069          (let ((coding-system-for-write 'no-conversion))
1070          (write-region (substring ,buffer 0 ,leng) nil ,file
1071                        ,append 'no-msg))))))
1072
1073 (put 'gnus-with-output-to-file 'lisp-indent-function 1)
1074 (put 'gnus-with-output-to-file 'edebug-form-spec '(form body))
1075
1076 (if (fboundp 'union)
1077     (defalias 'gnus-union 'union)
1078   (defun gnus-union (l1 l2)
1079     "Set union of lists L1 and L2."
1080     (cond ((null l1) l2)
1081           ((null l2) l1)
1082           ((equal l1 l2) l1)
1083           (t
1084            (or (>= (length l1) (length l2))
1085                (setq l1 (prog1 l2 (setq l2 l1))))
1086            (while l2
1087              (or (member (car l2) l1)
1088                  (push (car l2) l1))
1089              (pop l2))
1090            l1))))
1091
1092 (defun gnus-add-text-properties-when
1093   (property value start end properties &optional object)
1094   "Like `gnus-add-text-properties', only applied on where PROPERTY is VALUE."
1095   (let (point)
1096     (while (and start
1097                 (< start end) ;; XEmacs will loop for every when start=end.
1098                 (setq point (text-property-not-all start end property value)))
1099       (gnus-add-text-properties start point properties object)
1100       (setq start (text-property-any point end property value)))
1101     (if start
1102         (gnus-add-text-properties start end properties object))))
1103
1104 (defun gnus-remove-text-properties-when
1105   (property value start end properties &optional object)
1106   "Like `remove-text-properties', only applied on where PROPERTY is VALUE."
1107   (let (point)
1108     (while (and start
1109                 (< start end)
1110                 (setq point (text-property-not-all start end property value)))
1111       (remove-text-properties start point properties object)
1112       (setq start (text-property-any point end property value)))
1113     (if start
1114         (remove-text-properties start end properties object))
1115     t))
1116
1117 ;; This might use `compare-strings' to reduce consing in the
1118 ;; case-insensitive case, but it has to cope with null args.
1119 ;; (`string-equal' uses symbol print names.)
1120 (defun gnus-string-equal (x y)
1121   "Like `string-equal', except it compares case-insensitively."
1122   (and (= (length x) (length y))
1123        (or (string-equal x y)
1124            (string-equal (downcase x) (downcase y)))))
1125
1126 (defcustom gnus-use-byte-compile t
1127   "If non-nil, byte-compile crucial run-time code.
1128 Setting it to nil has no effect after the first time `gnus-byte-compile'
1129 is run."
1130   :type 'boolean
1131   :version "21.1"
1132   :group 'gnus-various)
1133
1134 (defun gnus-byte-compile (form)
1135   "Byte-compile FORM if `gnus-use-byte-compile' is non-nil."
1136   (if gnus-use-byte-compile
1137       (progn
1138         (condition-case nil
1139             ;; Work around a bug in XEmacs 21.4
1140             (require 'byte-optimize)
1141           (error))
1142         (require 'bytecomp)
1143         (defalias 'gnus-byte-compile
1144           (lambda (form)
1145             (let ((byte-compile-warnings '(unresolved callargs redefine)))
1146               (byte-compile form))))
1147         (gnus-byte-compile form))
1148     form))
1149
1150 (defun gnus-remassoc (key alist)
1151   "Delete by side effect any elements of LIST whose car is `equal' to KEY.
1152 The modified LIST is returned.  If the first member
1153 of LIST has a car that is `equal' to KEY, there is no way to remove it
1154 by side effect; therefore, write `(setq foo (remassoc key foo))' to be
1155 sure of changing the value of `foo'."
1156   (when alist
1157     (if (equal key (caar alist))
1158         (cdr alist)
1159       (setcdr alist (gnus-remassoc key (cdr alist)))
1160       alist)))
1161
1162 (defun gnus-update-alist-soft (key value alist)
1163   (if value
1164       (cons (cons key value) (gnus-remassoc key alist))
1165     (gnus-remassoc key alist)))
1166
1167 (defun gnus-create-info-command (node)
1168   "Create a command that will go to info NODE."
1169   `(lambda ()
1170      (interactive)
1171      ,(concat "Enter the info system at node " node)
1172      (Info-goto-node ,node)
1173      (setq gnus-info-buffer (current-buffer))
1174      (gnus-configure-windows 'info)))
1175
1176 (defun gnus-not-ignore (&rest args)
1177   t)
1178
1179 (defvar gnus-directory-sep-char-regexp "/"
1180   "The regexp of directory separator character.
1181 If you find some problem with the directory separator character, try
1182 \"[/\\\\\]\" for some systems.")
1183
1184 (defun gnus-url-unhex (x)
1185   (if (> x ?9)
1186       (if (>= x ?a)
1187           (+ 10 (- x ?a))
1188         (+ 10 (- x ?A)))
1189     (- x ?0)))
1190
1191 ;; Fixme: Do it like QP.
1192 (defun gnus-url-unhex-string (str &optional allow-newlines)
1193   "Remove %XX, embedded spaces, etc in a url.
1194 If optional second argument ALLOW-NEWLINES is non-nil, then allow the
1195 decoding of carriage returns and line feeds in the string, which is normally
1196 forbidden in URL encoding."
1197   (let ((tmp "")
1198         (case-fold-search t))
1199     (while (string-match "%[0-9a-f][0-9a-f]" str)
1200       (let* ((start (match-beginning 0))
1201              (ch1 (gnus-url-unhex (elt str (+ start 1))))
1202              (code (+ (* 16 ch1)
1203                       (gnus-url-unhex (elt str (+ start 2))))))
1204         (setq tmp (concat
1205                    tmp (substring str 0 start)
1206                    (cond
1207                     (allow-newlines
1208                      (char-to-string code))
1209                     ((or (= code ?\n) (= code ?\r))
1210                      " ")
1211                     (t (char-to-string code))))
1212               str (substring str (match-end 0)))))
1213     (setq tmp (concat tmp str))
1214     tmp))
1215
1216 (defun gnus-make-predicate (spec)
1217   "Transform SPEC into a function that can be called.
1218 SPEC is a predicate specifier that contains stuff like `or', `and',
1219 `not', lists and functions.  The functions all take one parameter."
1220   `(lambda (elem) ,(gnus-make-predicate-1 spec)))
1221
1222 (defun gnus-make-predicate-1 (spec)
1223   (cond
1224    ((symbolp spec)
1225     `(,spec elem))
1226    ((listp spec)
1227     (if (memq (car spec) '(or and not))
1228         `(,(car spec) ,@(mapcar 'gnus-make-predicate-1 (cdr spec)))
1229       (error "Invalid predicate specifier: %s" spec)))))
1230
1231 (defun gnus-local-map-property (map)
1232   "Return a list suitable for a text property list specifying keymap MAP."
1233   (cond
1234    ((featurep 'xemacs)
1235     (list 'keymap map))
1236    ((>= emacs-major-version 21)
1237     (list 'keymap map))
1238    (t
1239     (list 'local-map map))))
1240
1241 (defmacro gnus-completing-read-maybe-default (prompt table &optional predicate
1242                                               require-match initial-contents
1243                                               history default)
1244   "Like `completing-read', allowing for non-existent 7th arg in older XEmacsen."
1245   `(completing-read ,prompt ,table ,predicate ,require-match
1246                     ,initial-contents ,history
1247                     ,@(if (and (featurep 'xemacs) (< emacs-minor-version 2))
1248                           ()
1249                         (list default))))
1250
1251 (defun gnus-completing-read (prompt table &optional predicate require-match
1252                                     history)
1253   (when (and history
1254              (not (boundp history)))
1255     (set history nil))
1256   (gnus-completing-read-maybe-default
1257    (if (symbol-value history)
1258        (concat prompt " (" (car (symbol-value history)) "): ")
1259      (concat prompt ": "))
1260    table
1261    predicate
1262    require-match
1263    nil
1264    history
1265    (car (symbol-value history))))
1266
1267 (defun gnus-graphic-display-p ()
1268   (or (and (fboundp 'display-graphic-p)
1269            (display-graphic-p))
1270       ;;;!!!This is bogus.  Fixme!
1271       (and (featurep 'xemacs)
1272            t)))
1273
1274 (put 'gnus-parse-without-error 'lisp-indent-function 0)
1275 (put 'gnus-parse-without-error 'edebug-form-spec '(body))
1276
1277 (defmacro gnus-parse-without-error (&rest body)
1278   "Allow continuing onto the next line even if an error occurs."
1279   `(while (not (eobp))
1280      (condition-case ()
1281          (progn
1282            ,@body
1283            (goto-char (point-max)))
1284        (error
1285         (gnus-error 4 "Invalid data on line %d"
1286                     (count-lines (point-min) (point)))
1287         (forward-line 1)))))
1288
1289 (defun gnus-cache-file-contents (file variable function)
1290   "Cache the contents of FILE in VARIABLE.  The contents come from FUNCTION."
1291   (let ((time (nth 5 (file-attributes file)))
1292         contents value)
1293     (if (or (null (setq value (symbol-value variable)))
1294             (not (equal (car value) file))
1295             (not (equal (nth 1 value) time)))
1296         (progn
1297           (setq contents (funcall function file))
1298           (set variable (list file time contents))
1299           contents)
1300       (nth 2 value))))
1301
1302 (defun gnus-multiple-choice (prompt choice &optional idx)
1303   "Ask user a multiple choice question.
1304 CHOICE is a list of the choice char and help message at IDX."
1305   (let (tchar buf)
1306     (save-window-excursion
1307       (save-excursion
1308         (while (not tchar)
1309           (message "%s (%s): "
1310                    prompt
1311                    (concat
1312                     (mapconcat (lambda (s) (char-to-string (car s)))
1313                                choice ", ") ", ?"))
1314           (setq tchar (read-char))
1315           (when (not (assq tchar choice))
1316             (setq tchar nil)
1317             (setq buf (get-buffer-create "*Gnus Help*"))
1318             (pop-to-buffer buf)
1319             (fundamental-mode)          ; for Emacs 20.4+
1320             (buffer-disable-undo)
1321             (erase-buffer)
1322             (insert prompt ":\n\n")
1323             (let ((max -1)
1324                   (list choice)
1325                   (alist choice)
1326                   (idx (or idx 1))
1327                   (i 0)
1328                   n width pad format)
1329               ;; find the longest string to display
1330               (while list
1331                 (setq n (length (nth idx (car list))))
1332                 (unless (> max n)
1333                   (setq max n))
1334                 (setq list (cdr list)))
1335               (setq max (+ max 4))      ; %c, `:', SPACE, a SPACE at end
1336               (setq n (/ (1- (window-width)) max)) ; items per line
1337               (setq width (/ (1- (window-width)) n)) ; width of each item
1338               ;; insert `n' items, each in a field of width `width'
1339               (while alist
1340                 (if (< i n)
1341                     ()
1342                   (setq i 0)
1343                   (delete-char -1)              ; the `\n' takes a char
1344                   (insert "\n"))
1345                 (setq pad (- width 3))
1346                 (setq format (concat "%c: %-" (int-to-string pad) "s"))
1347                 (insert (format format (caar alist) (nth idx (car alist))))
1348                 (setq alist (cdr alist))
1349                 (setq i (1+ i))))))))
1350     (if (buffer-live-p buf)
1351         (kill-buffer buf))
1352     tchar))
1353
1354 (defun gnus-select-frame-set-input-focus (frame)
1355   "Select FRAME, raise it, and set input focus, if possible."
1356   (cond ((featurep 'xemacs)
1357          (raise-frame frame)
1358          (select-frame frame)
1359          (focus-frame frame))
1360         ;; The function `select-frame-set-input-focus' won't set
1361         ;; the input focus under Emacs 21.2 and X window system.
1362         ;;((fboundp 'select-frame-set-input-focus)
1363         ;; (defalias 'gnus-select-frame-set-input-focus
1364         ;;   'select-frame-set-input-focus)
1365         ;; (select-frame-set-input-focus frame))
1366         (t
1367          (raise-frame frame)
1368          (select-frame frame)
1369          (cond ((and (eq window-system 'x)
1370                      (fboundp 'x-focus-frame))
1371                 (x-focus-frame frame))
1372                ((eq window-system 'w32)
1373                 (w32-focus-frame frame)))
1374          (when focus-follows-mouse
1375            (set-mouse-position frame (1- (frame-width frame)) 0)))))
1376
1377 (defun gnus-frame-or-window-display-name (object)
1378   "Given a frame or window, return the associated display name.
1379 Return nil otherwise."
1380   (if (featurep 'xemacs)
1381       (device-connection (dfw-device object))
1382     (if (or (framep object)
1383             (and (windowp object)
1384                  (setq object (window-frame object))))
1385         (let ((display (frame-parameter object 'display)))
1386           (if (and (stringp display)
1387                    ;; Exclude invalid display names.
1388                    (string-match "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'"
1389                                  display))
1390               display)))))
1391
1392 ;; Fixme: This has only one use (in gnus-agent), which isn't worthwhile.
1393 (defmacro gnus-mapcar (function seq1 &rest seqs2_n)
1394   "Apply FUNCTION to each element of the sequences, and make a list of the results.
1395 If there are several sequences, FUNCTION is called with that many arguments,
1396 and mapping stops as soon as the shortest sequence runs out.  With just one
1397 sequence, this is like `mapcar'.  With several, it is like the Common Lisp
1398 `mapcar' function extended to arbitrary sequence types."
1399
1400   (if seqs2_n
1401       (let* ((seqs (cons seq1 seqs2_n))
1402              (cnt 0)
1403              (heads (mapcar (lambda (seq)
1404                               (make-symbol (concat "head"
1405                                                    (int-to-string
1406                                                     (setq cnt (1+ cnt))))))
1407                             seqs))
1408              (result (make-symbol "result"))
1409              (result-tail (make-symbol "result-tail")))
1410         `(let* ,(let* ((bindings (cons nil nil))
1411                        (heads heads))
1412                   (nconc bindings (list (list result '(cons nil nil))))
1413                   (nconc bindings (list (list result-tail result)))
1414                   (while heads
1415                     (nconc bindings (list (list (pop heads) (pop seqs)))))
1416                   (cdr bindings))
1417            (while (and ,@heads)
1418              (setcdr ,result-tail (cons (funcall ,function
1419                                                  ,@(mapcar (lambda (h) (list 'car h))
1420                                                            heads))
1421                                         nil))
1422              (setq ,result-tail (cdr ,result-tail)
1423                    ,@(apply 'nconc (mapcar (lambda (h) (list h (list 'cdr h))) heads))))
1424            (cdr ,result)))
1425     `(mapcar ,function ,seq1)))
1426
1427 (if (fboundp 'merge)
1428     (defalias 'gnus-merge 'merge)
1429   ;; Adapted from cl-seq.el
1430   (defun gnus-merge (type list1 list2 pred)
1431     "Destructively merge lists LIST1 and LIST2 to produce a new list.
1432 Argument TYPE is for compatibility and ignored.
1433 Ordering of the elements is preserved according to PRED, a `less-than'
1434 predicate on the elements."
1435     (let ((res nil))
1436       (while (and list1 list2)
1437         (if (funcall pred (car list2) (car list1))
1438             (push (pop list2) res)
1439           (push (pop list1) res)))
1440       (nconc (nreverse res) list1 list2))))
1441
1442 (eval-when-compile
1443   (defvar xemacs-codename))
1444
1445 (defun gnus-emacs-version ()
1446   "Stringified Emacs version."
1447   (let ((system-v
1448          (cond
1449           ((eq gnus-user-agent 'emacs-gnus-config)
1450            system-configuration)
1451           ((eq gnus-user-agent 'emacs-gnus-type)
1452            (symbol-name system-type))
1453           (t nil))))
1454     (cond
1455      ((eq gnus-user-agent 'gnus)
1456       nil)
1457      ((string-match "^\\(\\([.0-9]+\\)*\\)\\.[0-9]+$" emacs-version)
1458       (concat "Emacs/" (match-string 1 emacs-version)
1459               (if system-v
1460                   (concat " (" system-v ")")
1461                 "")))
1462      ((string-match
1463        "\\([A-Z]*[Mm][Aa][Cc][Ss]\\)[^(]*\\(\\((beta.*)\\|'\\)\\)?"
1464        emacs-version)
1465       (concat
1466        (match-string 1 emacs-version)
1467        (format "/%d.%d" emacs-major-version emacs-minor-version)
1468        (if (match-beginning 3)
1469            (match-string 3 emacs-version)
1470          "")
1471        (if (boundp 'xemacs-codename)
1472            (concat
1473             " (" xemacs-codename
1474             (if system-v
1475                 (concat ", " system-v ")")
1476               ")"))
1477          "")))
1478      (t emacs-version))))
1479
1480 (provide 'gnus-util)
1481
1482 ;;; gnus-util.el ends here