cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (eval-when-compile (require 'cl))
  30
  31 (defvar gnus-server-mode-hook nil
  32   "Hook run in `gnus-server-mode' buffers.")
  33
  34 (defconst gnus-server-line-format "     {%(%h:%w%)} %s\n"
  35   "Format of server lines.
  36 It works along the same lines as a normal formatting string,
  37 with some simple extensions.")
  38
  39 (defvar gnus-server-mode-line-format "Gnus  List of servers"
  40   "The format specification for the server mode line.")
  41
  42 ;;; Internal variables.
  43
  44 (defvar gnus-inserted-opened-servers nil)
  45
  46 (defvar gnus-server-line-format-alist
  47   `((?h how ?s)
  48     (?n name ?s)
  49     (?w where ?s)
  50     (?s status ?s)))
  51
  52 (defvar gnus-server-mode-line-format-alist
  53   `((?S news-server ?s)
  54     (?M news-method ?s)
  55     (?u user-defined ?s)))
  56
  57 (defvar gnus-server-line-format-spec nil)
  58 (defvar gnus-server-mode-line-format-spec nil)
  59 (defvar gnus-server-killed-servers nil)
  60
  61 (defvar gnus-server-mode-map)
  62
  63 (defvar gnus-server-menu-hook nil
  64   "*Hook run after the creation of the server mode menu.")
  65
  66 (defun gnus-server-make-menu-bar ()
  67   (gnus-visual-turn-off-edit-menu 'server)
  68   (or
  69    (boundp 'gnus-server-menu)
  70    (progn
  71      (easy-menu-define
  72       gnus-server-menu gnus-server-mode-map ""
  73       '("Server"
  74         ["Add" gnus-server-add-server t]
  75         ["Browse" gnus-server-read-server t]
  76         ["List" gnus-server-list-servers t]
  77         ["Kill" gnus-server-kill-server t]
  78         ["Yank" gnus-server-yank-server t]
  79         ["Copy" gnus-server-copy-server t]
  80         ["Edit" gnus-server-edit-server t]
  81         ["Exit" gnus-server-exit t]
  82         ))
  83
  84      (easy-menu-define
  85       gnus-server-menu gnus-server-mode-map ""
  86       '("Connections"
  87         ["Open" gnus-server-open-server t]
  88         ["Close" gnus-server-close-server t]
  89         ["Deny" gnus-server-deny-servers t]
  90         ["Reset" gnus-server-remove-denials t]
  91         ))
  92
  93      (run-hooks 'gnus-server-menu-hook))))
  94
  95 (defvar gnus-server-mode-map nil)
  96 (put 'gnus-server-mode 'mode-class 'special)
  97
  98 (unless gnus-server-mode-map
  99   (setq gnus-server-mode-map (make-sparse-keymap))
 100   (suppress-keymap gnus-server-mode-map)
 101
 102   (gnus-define-keys
 103    gnus-server-mode-map
 104    " " gnus-server-read-server
 105    "\r" gnus-server-read-server
 106    gnus-mouse-2 gnus-server-pick-server
 107    "q" gnus-server-exit
 108    "l" gnus-server-list-servers
 109    "k" gnus-server-kill-server
 110    "y" gnus-server-yank-server
 111    "c" gnus-server-copy-server
 112    "a" gnus-server-add-server
 113    "e" gnus-server-edit-server
 114
 115    "O" gnus-server-open-server
 116    "C" gnus-server-close-server
 117    "D" gnus-server-deny-server
 118    "R" gnus-server-remove-denials))
 119
 120 (defun gnus-server-mode ()
 121   "Major mode for listing and editing servers.
 122
 123 All normal editing commands are switched off.
 124 \\<gnus-server-mode-map>
 125 For more in-depth information on this mode, read the manual
 126 (`\\[gnus-info-find-node]').
 127
 128 The following commands are available:
 129
 130 \\{gnus-server-mode-map}"
 131   (interactive)
 132   (when (and menu-bar-mode
 133              (gnus-visual-p 'server-menu 'menu))
 134     (gnus-server-make-menu-bar))
 135   (kill-all-local-variables)
 136   (gnus-simplify-mode-line)
 137   (setq major-mode 'gnus-server-mode)
 138   (setq mode-name "Server")
 139                                         ;  (gnus-group-set-mode-line)
 140   (setq mode-line-process nil)
 141   (use-local-map gnus-server-mode-map)
 142   (buffer-disable-undo (current-buffer))
 143   (setq truncate-lines t)
 144   (setq buffer-read-only t)
 145   (run-hooks 'gnus-server-mode-hook))
 146
 147 (defun gnus-server-insert-server-line (name method)
 148   (let* ((how (car method))
 149          (where (nth 1 method))
 150          (elem (assoc method gnus-opened-servers))
 151          (status (cond ((eq (nth 1 elem) 'denied)
 152                         "(denied)")
 153                        ((or (gnus-server-opened method)
 154                             (eq (nth 1 elem) 'ok))
 155                         "(opened)")
 156                        (t
 157                         "(closed)"))))
 158     (beginning-of-line)
 159     (add-text-properties
 160      (point)
 161      (prog1 (1+ (point))
 162        ;; Insert the text.
 163        (eval gnus-server-line-format-spec))
 164      (list 'gnus-server (intern name)))))
 165
 166 (defun gnus-enter-server-buffer ()
 167   "Set up the server buffer."
 168   (gnus-server-setup-buffer)
 169   (gnus-configure-windows 'server)
 170   (gnus-server-prepare))
 171
 172 (defun gnus-server-setup-buffer ()
 173   "Initialize the server buffer."
 174   (unless (get-buffer gnus-server-buffer)
 175     (save-excursion
 176       (set-buffer (get-buffer-create gnus-server-buffer))
 177       (gnus-server-mode)
 178       (when gnus-carpal
 179         (gnus-carpal-setup-buffer 'server)))))
 180
 181 (defun gnus-server-prepare ()
 182   (setq gnus-server-mode-line-format-spec
 183         (gnus-parse-format gnus-server-mode-line-format
 184                            gnus-server-mode-line-format-alist))
 185   (setq gnus-server-line-format-spec
 186         (gnus-parse-format gnus-server-line-format
 187                            gnus-server-line-format-alist t))
 188   (let ((alist gnus-server-alist)
 189         (buffer-read-only nil)
 190         (opened gnus-opened-servers)
 191         done server op-ser)
 192     (erase-buffer)
 193     (setq gnus-inserted-opened-servers nil)
 194     ;; First we do the real list of servers.
 195     (while alist
 196       (push (cdr (setq server (pop alist))) done)
 197       (when (and server (car server))
 198         (gnus-server-insert-server-line (car server) (cdr server))))
 199     ;; Then we insert the list of servers that have been opened in
 200     ;; this session.
 201     (while opened
 202       (unless (member (caar opened) done)
 203         (gnus-server-insert-server-line
 204          (setq op-ser (format "%s:%s" (car (car (car opened)))
 205                               (nth 1 (car (car opened)))))
 206          (car (car opened)))
 207         (push (list op-ser (caar opened)) gnus-inserted-opened-servers))
 208       (setq opened (cdr opened))))
 209   (goto-char (point-min))
 210   (gnus-server-position-point))
 211
 212 (defun gnus-server-server-name ()
 213   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-server)))
 214     (and server (symbol-name server))))
 215
 216 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 217
 218 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 219
 220 (defun gnus-server-update-server (server)
 221   (save-excursion
 222     (set-buffer gnus-server-buffer)
 223     (let* ((buffer-read-only nil)
 224            (entry (assoc server gnus-server-alist)))
 225       (when entry
 226         (gnus-dribble-enter
 227          (concat "(gnus-server-set-info \"" server "\" '"
 228                  (prin1-to-string (cdr entry)) ")"))
 229         ;; Buffer may be narrowed.
 230         (save-restriction
 231           (widen)
 232           (when (gnus-server-goto-server server)
 233             (gnus-delete-line))
 234           (gnus-server-insert-server-line (car entry) (cdr entry))
 235           (gnus-server-position-point))))))
 236
 237 (defun gnus-server-set-info (server info)
 238   ;; Enter a select method into the virtual server alist.
 239   (when (and server info)
 240     (gnus-dribble-enter
 241      (concat "(gnus-server-set-info \"" server "\" '"
 242              (prin1-to-string info) ")"))
 243     (let* ((server (nth 1 info))
 244            (entry (assoc server gnus-server-alist)))
 245       (if entry (setcdr entry info)
 246         (setq gnus-server-alist
 247               (nconc gnus-server-alist (list (cons server info))))))))
 248
 249 ;;; Interactive server functions.
 250
 251 (defun gnus-server-kill-server (server)
 252   "Kill the server on the current line."
 253   (interactive (list (gnus-server-server-name)))
 254   (unless (gnus-server-goto-server server)
 255     (if server (error "No such server: %s" server)
 256       (error "No server on the current line")))
 257   (unless (assoc server gnus-server-alist)
 258     (error "Read-only server %s" server))
 259   (gnus-dribble-enter "")
 260   (let ((buffer-read-only nil))
 261     (gnus-delete-line))
 262   (setq gnus-server-killed-servers
 263         (cons (assoc server gnus-server-alist) gnus-server-killed-servers))
 264   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 265                                 gnus-server-alist))
 266   (gnus-server-position-point))
 267
 268 (defun gnus-server-yank-server ()
 269   "Yank the previously killed server."
 270   (interactive)
 271   (or gnus-server-killed-servers
 272       (error "No killed servers to be yanked"))
 273   (let ((alist gnus-server-alist)
 274         (server (gnus-server-server-name))
 275         (killed (car gnus-server-killed-servers)))
 276     (if (not server)
 277         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 278       (if (string= server (car (car gnus-server-alist)))
 279           (setq gnus-server-alist (cons killed gnus-server-alist))
 280         (while (and (cdr alist)
 281                     (not (string= server (car (car (cdr alist))))))
 282           (setq alist (cdr alist)))
 283         (if alist
 284             (setcdr alist (cons killed (cdr alist)))
 285           (setq gnus-server-alist (list killed)))))
 286     (gnus-server-update-server (car killed))
 287     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 288     (gnus-server-position-point)))
 289
 290 (defun gnus-server-exit ()
 291   "Return to the group buffer."
 292   (interactive)
 293   (kill-buffer (current-buffer))
 294   (switch-to-buffer gnus-group-buffer))
 295
 296 (defun gnus-server-list-servers ()
 297   "List all available servers."
 298   (interactive)
 299   (let ((cur (gnus-server-server-name)))
 300     (gnus-server-prepare)
 301     (if cur (gnus-server-goto-server cur)
 302       (goto-char (point-max))
 303       (forward-line -1))
 304     (gnus-server-position-point)))
 305
 306 (defun gnus-opened-servers-remove (method)
 307   "Remove METHOD from the list of opened servers."
 308   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 309                                   gnus-opened-servers)))
 310
 311 (defun gnus-server-open-server (server)
 312   "Force an open of SERVER."
 313   (interactive (list (gnus-server-server-name)))
 314   (let ((method (gnus-server-to-method server)))
 315     (or method (error "No such server: %s" server))
 316     (gnus-opened-servers-remove method)
 317     (prog1
 318         (or (gnus-open-server method)
 319             (progn (message "Couldn't open %s" server) nil))
 320       (gnus-server-update-server server)
 321       (gnus-server-position-point))))
 322
 323 (defun gnus-server-close-server (server)
 324   "Close SERVER."
 325   (interactive (list (gnus-server-server-name)))
 326   (let ((method (gnus-server-to-method server)))
 327     (or method (error "No such server: %s" server))
 328     (gnus-opened-servers-remove method)
 329     (prog1
 330         (gnus-close-server method)
 331       (gnus-server-update-server server)
 332       (gnus-server-position-point))))
 333
 334 (defun gnus-server-deny-server (server)
 335   "Make sure SERVER will never be attempted opened."
 336   (interactive (list (gnus-server-server-name)))
 337   (let ((method (gnus-server-to-method server)))
 338     (or method (error "No such server: %s" server))
 339     (gnus-opened-servers-remove method)
 340     (setq gnus-opened-servers
 341           (cons (list method 'denied) gnus-opened-servers)))
 342   (gnus-server-update-server server)
 343   (gnus-server-position-point))
 344
 345 (defun gnus-server-remove-denials ()
 346   "Make all denied servers into closed servers."
 347   (interactive)
 348   (let ((servers gnus-opened-servers))
 349     (while servers
 350       (when (eq (nth 1 (car servers)) 'denied)
 351         (setcar (nthcdr 1 (car servers)) 'closed))
 352       (setq servers (cdr servers))))
 353   (gnus-server-list-servers))
 354
 355 (defun gnus-server-copy-server (from to)
 356   (interactive
 357    (list
 358     (or (gnus-server-server-name)
 359         (error "No server on the current line"))
 360     (read-string "Copy to: ")))
 361   (or from (error "No server on current line"))
 362   (or (and to (not (string= to ""))) (error "No name to copy to"))
 363   (and (assoc to gnus-server-alist) (error "%s already exists" to))
 364   (or (assoc from gnus-server-alist)
 365       (error "%s: no such server" from))
 366   (let ((to-entry (gnus-copy-sequence (assoc from gnus-server-alist))))
 367     (setcar to-entry to)
 368     (setcar (nthcdr 2 to-entry) to)
 369     (setq gnus-server-killed-servers
 370           (cons to-entry gnus-server-killed-servers))
 371     (gnus-server-yank-server)))
 372
 373 (defun gnus-server-add-server (how where)
 374   (interactive
 375    (list (intern (completing-read "Server method: "
 376                                   gnus-valid-select-methods nil t))
 377          (read-string "Server name: ")))
 378   (setq gnus-server-killed-servers
 379         (cons (list where how where) gnus-server-killed-servers))
 380   (gnus-server-yank-server))
 381
 382 (defun gnus-server-goto-server (server)
 383   "Jump to a server line."
 384   (interactive
 385    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 386   (let ((to (text-property-any (point-min) (point-max)
 387                                'gnus-server (intern server))))
 388     (and to
 389          (progn
 390            (goto-char to)
 391            (gnus-server-position-point)))))
 392
 393 (defun gnus-server-edit-server (server)
 394   "Edit the server on the current line."
 395   (interactive (list (gnus-server-server-name)))
 396   (unless server
 397     (error "No server on current line"))
 398   (unless (assoc server gnus-server-alist)
 399     (error "This server can't be edited"))
 400   (let ((winconf (current-window-configuration))
 401         (info (cdr (assoc server gnus-server-alist))))
 402     (gnus-close-server info)
 403     (get-buffer-create gnus-server-edit-buffer)
 404     (gnus-configure-windows 'edit-server)
 405     (gnus-add-current-to-buffer-list)
 406     (emacs-lisp-mode)
 407     (make-local-variable 'gnus-prev-winconf)
 408     (setq gnus-prev-winconf winconf)
 409     (use-local-map (copy-keymap (current-local-map)))
 410     (let ((done-func '(lambda ()
 411                         "Exit editing mode and update the information."
 412                         (interactive)
 413                         (gnus-server-edit-server-done 'group))))
 414       (setcar (cdr (nth 4 done-func)) server)
 415       (local-set-key "\C-c\C-c" done-func))
 416     (erase-buffer)
 417     (insert ";; Type `C-c C-c' after you have edited the server.\n\n")
 418     (insert (pp-to-string info))))
 419
 420 (defun gnus-server-edit-server-done (server)
 421   (interactive)
 422   (set-buffer (get-buffer-create gnus-server-edit-buffer))
 423   (goto-char (point-min))
 424   (let ((form (read (current-buffer)))
 425         (winconf gnus-prev-winconf))
 426     (gnus-server-set-info server form)
 427     (kill-buffer (current-buffer))
 428     (and winconf (set-window-configuration winconf))
 429     (set-buffer gnus-server-buffer)
 430     (gnus-server-update-server server)
 431     (gnus-server-list-servers)
 432     (gnus-server-position-point)))
 433
 434 (defun gnus-server-read-server (server)
 435   "Browse a server."
 436   (interactive (list (gnus-server-server-name)))
 437   (let ((buf (current-buffer)))
 438     (prog1
 439         (gnus-browse-foreign-server (gnus-server-to-method server) buf)
 440       (save-excursion
 441         (set-buffer buf)
 442         (gnus-server-update-server (gnus-server-server-name))
 443         (gnus-server-position-point)))))
 444
 445 (defun gnus-server-pick-server (e)
 446   (interactive "e")
 447   (mouse-set-point e)
 448   (gnus-server-read-server (gnus-server-server-name)))
 449
 450 \f
 451 ;;;
 452 ;;; Browse Server Mode
 453 ;;;
 454
 455 (defvar gnus-browse-menu-hook nil
 456   "*Hook run after the creation of the browse mode menu.")
 457
 458 (defvar gnus-browse-mode-hook nil)
 459 (defvar gnus-browse-mode-map nil)
 460 (put 'gnus-browse-mode 'mode-class 'special)
 461
 462 (unless gnus-browse-mode-map
 463   (setq gnus-browse-mode-map (make-keymap))
 464   (suppress-keymap gnus-browse-mode-map)
 465
 466   (gnus-define-keys
 467    gnus-browse-mode-map
 468    " " gnus-browse-read-group
 469    "=" gnus-browse-select-group
 470    "n" gnus-browse-next-group
 471    "p" gnus-browse-prev-group
 472    "\177" gnus-browse-prev-group
 473    "N" gnus-browse-next-group
 474    "P" gnus-browse-prev-group
 475    "\M-n" gnus-browse-next-group
 476    "\M-p" gnus-browse-prev-group
 477    "\r" gnus-browse-select-group
 478    "u" gnus-browse-unsubscribe-current-group
 479    "l" gnus-browse-exit
 480    "L" gnus-browse-exit
 481    "q" gnus-browse-exit
 482    "Q" gnus-browse-exit
 483    "\C-c\C-c" gnus-browse-exit
 484    "?" gnus-browse-describe-briefly
 485    "\C-c\C-i" gnus-info-find-node))
 486
 487 (defun gnus-browse-make-menu-bar ()
 488   (gnus-visual-turn-off-edit-menu 'browse)
 489   (or
 490    (boundp 'gnus-browse-menu)
 491    (progn
 492      (easy-menu-define
 493       gnus-browse-menu gnus-browse-mode-map ""
 494       '("Browse"
 495         ["Subscribe" gnus-browse-unsubscribe-current-group t]
 496         ["Read" gnus-browse-read-group t]
 497         ["Select" gnus-browse-read-group t]
 498         ["Next" gnus-browse-next-group t]
 499         ["Prev" gnus-browse-next-group t]
 500         ["Exit" gnus-browse-exit t]
 501         ))
 502       (run-hooks 'gnus-browse-menu-hook))))
 503
 504 (defvar gnus-browse-current-method nil)
 505 (defvar gnus-browse-return-buffer nil)
 506
 507 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 508
 509 (defun gnus-browse-foreign-server (method &optional return-buffer)
 510   "Browse the server METHOD."
 511   (setq gnus-browse-current-method method)
 512   (setq gnus-browse-return-buffer return-buffer)
 513   (let ((gnus-select-method method)
 514         groups group)
 515     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 516     (cond
 517      ((not (gnus-check-server method))
 518       (gnus-message
 519        1 "Unable to contact server: %s" (gnus-status-message method))
 520       nil)
 521      ((not (gnus-request-list method))
 522       (gnus-message
 523        1 "Couldn't request list: %s" (gnus-status-message method))
 524       nil)
 525      (t
 526       (get-buffer-create gnus-browse-buffer)
 527       (gnus-add-current-to-buffer-list)
 528       (and gnus-carpal (gnus-carpal-setup-buffer 'browse))
 529       (gnus-configure-windows 'browse)
 530       (buffer-disable-undo (current-buffer))
 531       (let ((buffer-read-only nil))
 532         (erase-buffer))
 533       (gnus-browse-mode)
 534       (setq mode-line-buffer-identification
 535             (list
 536              (format
 537               "Gnus: %%b {%s:%s}" (car method) (car (cdr method)))))
 538       (save-excursion
 539         (set-buffer nntp-server-buffer)
 540         (let ((cur (current-buffer)))
 541           (goto-char (point-min))
 542           (or (string= gnus-ignored-newsgroups "")
 543               (delete-matching-lines gnus-ignored-newsgroups))
 544           (while (re-search-forward
 545                   "\\(^[^ \t]+\\)[ \t]+[0-9]+[ \t]+[0-9]+" nil t)
 546             (goto-char (match-end 1))
 547             (setq groups (cons (cons (match-string 1)
 548                                      (max 0 (- (1+ (read cur)) (read cur))))
 549                                groups)))))
 550       (setq groups (sort groups
 551                          (lambda (l1 l2)
 552                            (string< (car l1) (car l2)))))
 553       (let ((buffer-read-only nil))
 554         (while groups
 555           (setq group (car groups))
 556           (insert
 557            (format "K%7d: %s\n" (cdr group) (car group)))
 558           (setq groups (cdr groups))))
 559       (switch-to-buffer (current-buffer))
 560       (goto-char (point-min))
 561       (gnus-group-position-point)
 562       t))))
 563
 564 (defun gnus-browse-mode ()
 565   "Major mode for browsing a foreign server.
 566
 567 All normal editing commands are switched off.
 568
 569 \\<gnus-browse-mode-map>
 570 The only things you can do in this buffer is
 571
 572 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 573 The group will be inserted into the group buffer upon exit from this
 574 buffer.
 575
 576 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 577
 578 3) `\\[gnus-browse-exit]' to return to the group buffer."
 579   (interactive)
 580   (kill-all-local-variables)
 581   (when (and menu-bar-mode
 582              (gnus-visual-p 'browse-menu 'menu))
 583     (gnus-browse-make-menu-bar))
 584   (gnus-simplify-mode-line)
 585   (setq major-mode 'gnus-browse-mode)
 586   (setq mode-name "Browse Server")
 587   (setq mode-line-process nil)
 588   (use-local-map gnus-browse-mode-map)
 589   (buffer-disable-undo (current-buffer))
 590   (setq truncate-lines t)
 591   (setq buffer-read-only t)
 592   (run-hooks 'gnus-browse-mode-hook))
 593
 594 (defun gnus-browse-read-group (&optional no-article)
 595   "Enter the group at the current line."
 596   (interactive)
 597   (let ((group (gnus-browse-group-name)))
 598     (or (gnus-group-read-ephemeral-group
 599          group gnus-browse-current-method nil
 600          (cons (current-buffer) 'browse))
 601         (error "Couldn't enter %s" group))))
 602
 603 (defun gnus-browse-select-group ()
 604   "Select the current group."
 605   (interactive)
 606   (gnus-browse-read-group 'no))
 607
 608 (defun gnus-browse-next-group (n)
 609   "Go to the next group."
 610   (interactive "p")
 611   (prog1
 612       (forward-line n)
 613     (gnus-group-position-point)))
 614
 615 (defun gnus-browse-prev-group (n)
 616   "Go to the next group."
 617   (interactive "p")
 618   (gnus-browse-next-group (- n)))
 619
 620 (defun gnus-browse-unsubscribe-current-group (arg)
 621   "(Un)subscribe to the next ARG groups."
 622   (interactive "p")
 623   (when (eobp)
 624     (error "No group at current line."))
 625   (let ((ward (if (< arg 0) -1 1))
 626         (arg (abs arg)))
 627     (while (and (> arg 0)
 628                 (not (eobp))
 629                 (gnus-browse-unsubscribe-group)
 630                 (zerop (gnus-browse-next-group ward)))
 631       (decf arg))
 632     (gnus-group-position-point)
 633     (if (/= 0 arg) (gnus-message 7 "No more newsgroups"))
 634     arg))
 635
 636 (defun gnus-browse-group-name ()
 637   (save-excursion
 638     (beginning-of-line)
 639     (when (re-search-forward ": \\(.*\\)$" (gnus-point-at-eol) t)
 640       (gnus-group-prefixed-name (match-string 1) gnus-browse-current-method))))
 641
 642 (defun gnus-browse-unsubscribe-group ()
 643   "Toggle subscription of the current group in the browse buffer."
 644   (let ((sub nil)
 645         (buffer-read-only nil)
 646         group)
 647     (save-excursion
 648       (beginning-of-line)
 649       ;; If this group it killed, then we want to subscribe it.
 650       (if (= (following-char) ?K) (setq sub t))
 651       (setq group (gnus-browse-group-name))
 652       (delete-char 1)
 653       (if sub
 654           (progn
 655             (gnus-group-change-level
 656              (list t group gnus-level-default-subscribed
 657                    nil nil gnus-browse-current-method)
 658              gnus-level-default-subscribed gnus-level-killed
 659              (and (car (nth 1 gnus-newsrc-alist))
 660                   (gnus-gethash (car (nth 1 gnus-newsrc-alist))
 661                                 gnus-newsrc-hashtb))
 662              t)
 663             (insert ? ))
 664         (gnus-group-change-level
 665          group gnus-level-killed gnus-level-default-subscribed)
 666         (insert ?K)))
 667     t))
 668
 669 (defun gnus-browse-exit ()
 670   "Quit browsing and return to the group buffer."
 671   (interactive)
 672   (when (eq major-mode 'gnus-browse-mode)
 673     (kill-buffer (current-buffer)))
 674   ;; Insert the newly subscribed groups in the group buffer.
 675   (save-excursion
 676     (set-buffer gnus-group-buffer)
 677     (gnus-group-list-groups nil))
 678   (if gnus-browse-return-buffer
 679       (gnus-configure-windows 'server 'force)
 680     (gnus-configure-windows 'group 'force)))
 681
 682 (defun gnus-browse-describe-briefly ()
 683   "Give a one line description of the group mode commands."
 684   (interactive)
 685   (gnus-message 6
 686                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 687
 688 (provide 'gnus-srvr)
 689
 690 ;;; gnus-srvr.el ends here.