cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gnus)
  28 (eval-when-compile (require 'cl))
  29
  30 (defvar gnus-server-mode-hook nil
  31   "Hook run in `gnus-server-mode' buffers.")
  32
  33 (defconst gnus-server-line-format "     {%(%h:%w%)} %s\n"
  34   "Format of server lines.
  35 It works along the same lines as a normal formatting string,
  36 with some simple extensions.")
  37
  38 (defvar gnus-server-mode-line-format "Gnus  List of servers"
  39   "The format specification for the server mode line.")
  40
  41 ;;; Internal variables.
  42
  43 (defconst gnus-server-line-format-alist
  44   (` ((?h how ?s)
  45       (?n name ?s)
  46       (?w where ?s)
  47       (?s status ?s))))
  48
  49 (defconst gnus-server-mode-line-format-alist
  50   (` ((?S news-server ?s)
  51       (?M news-method ?s)
  52       (?u user-defined ?s))))
  53
  54 (defvar gnus-server-line-format-spec nil)
  55 (defvar gnus-server-mode-line-format-spec nil)
  56 (defvar gnus-server-killed-servers nil)
  57
  58 (defvar gnus-server-mode-map)
  59
  60 (defvar gnus-server-menu-hook nil
  61   "*Hook run after the creation of the server mode menu.")
  62
  63 (defun gnus-server-make-menu-bar ()
  64   (gnus-visual-turn-off-edit-menu 'server)
  65   (or
  66    (boundp 'gnus-server-menu)
  67    (progn
  68      (easy-menu-define
  69       gnus-server-menu gnus-server-mode-map ""
  70       '("Server"
  71         ["Add" gnus-server-add-server t]
  72         ["Browse" gnus-server-read-server t]
  73         ["List" gnus-server-list-servers t]
  74         ["Kill" gnus-server-kill-server t]
  75         ["Yank" gnus-server-yank-server t]
  76         ["Copy" gnus-server-copy-server t]
  77         ["Edit" gnus-server-edit-server t]
  78         ["Exit" gnus-server-exit t]
  79         ))
  80
  81      (easy-menu-define
  82       gnus-server-menu gnus-server-mode-map ""
  83       '("Connections"
  84         ["Open" gnus-server-open-server t]
  85         ["Close" gnus-server-close-server t]
  86         ["Deny" gnus-server-deny-servers t]
  87         ["Reset" gnus-server-remove-denials t]
  88         ))
  89
  90      (run-hooks 'gnus-server-menu-hook))))
  91
  92 (defvar gnus-server-mode-map nil)
  93 (put 'gnus-server-mode 'mode-class 'special)
  94
  95 (unless gnus-server-mode-map
  96   (setq gnus-server-mode-map (make-sparse-keymap))
  97   (suppress-keymap gnus-server-mode-map)
  98
  99   (gnus-define-keys
 100    gnus-server-mode-map
 101    " " gnus-server-read-server
 102    "\r" gnus-server-read-server
 103    gnus-mouse-2 gnus-server-pick-server
 104    "q" gnus-server-exit
 105    "l" gnus-server-list-servers
 106    "k" gnus-server-kill-server
 107    "y" gnus-server-yank-server
 108    "c" gnus-server-copy-server
 109    "a" gnus-server-add-server
 110    "e" gnus-server-edit-server
 111
 112    "O" gnus-server-open-server
 113    "C" gnus-server-close-server
 114    "D" gnus-server-deny-server
 115    "R" gnus-server-remove-denials))
 116
 117 (defun gnus-server-mode ()
 118   "Major mode for listing and editing servers.
 119
 120 All normal editing commands are switched off.
 121 \\<gnus-server-mode-map>
 122
 123 For more in-depth information on this mode, read the manual (`\\[gnus-info-find-node]').
 124
 125 The following commands are available:
 126
 127 \\{gnus-server-mode-map}"
 128   (interactive)
 129   (when (and menu-bar-mode
 130              (gnus-visual-p 'server-menu 'menu))
 131     (gnus-server-make-menu-bar))
 132   (kill-all-local-variables)
 133   (gnus-simplify-mode-line)
 134   (setq major-mode 'gnus-server-mode)
 135   (setq mode-name "Server")
 136                                         ;  (gnus-group-set-mode-line)
 137   (setq mode-line-process nil)
 138   (use-local-map gnus-server-mode-map)
 139   (buffer-disable-undo (current-buffer))
 140   (setq truncate-lines t)
 141   (setq buffer-read-only t)
 142   (run-hooks 'gnus-server-mode-hook))
 143
 144 (defun gnus-server-insert-server-line (name method)
 145   (let* ((how (car method))
 146          (where (nth 1 method))
 147          (elem (assoc method gnus-opened-servers))
 148          (status (cond ((eq (nth 1 elem) 'denied)
 149                         "(denied)")
 150                        ((or (gnus-server-opened method)
 151                             (eq (nth 1 elem) 'ok))
 152                         "(open)")
 153                        (t
 154                         "(closed)"))))
 155     (beginning-of-line)
 156     (add-text-properties
 157      (point)
 158      (prog1 (1+ (point))
 159        ;; Insert the text.
 160        (eval gnus-server-line-format-spec))
 161      (list 'gnus-server (intern name)))))
 162
 163 (defun gnus-enter-server-buffer ()
 164   "Set up the server buffer."
 165   (gnus-server-setup-buffer)
 166   (gnus-configure-windows 'server)
 167   (gnus-server-prepare))
 168
 169 (defun gnus-server-setup-buffer ()
 170   "Initialize the server buffer."
 171   (unless (get-buffer gnus-server-buffer)
 172     (save-excursion
 173       (set-buffer (get-buffer-create gnus-server-buffer))
 174       (gnus-server-mode)
 175       (when gnus-carpal
 176         (gnus-carpal-setup-buffer 'server)))))
 177
 178 (fset 'gnus-server-position-point 'gnus-goto-colon)
 179
 180 (defun gnus-server-prepare ()
 181   (setq gnus-server-mode-line-format-spec
 182         (gnus-parse-format gnus-server-mode-line-format
 183                            gnus-server-mode-line-format-alist))
 184   (setq gnus-server-line-format-spec
 185         (gnus-parse-format gnus-server-line-format
 186                            gnus-server-line-format-alist t))
 187   (let ((alist gnus-server-alist)
 188         (buffer-read-only nil)
 189         (opened gnus-opened-servers)
 190         done server)
 191     (erase-buffer)
 192     ;; First we do the real list of servers.
 193     (while alist
 194       (push (cdr (setq server (pop alist))) done)
 195       (when server
 196         (gnus-server-insert-server-line (car server) (cdr server))))
 197     ;; Then we insert the list of servers that have been opened in
 198     ;; this session.
 199     (while opened
 200       (unless (member (car (car opened)) done)
 201         (gnus-server-insert-server-line
 202          (format "%s:%s" (car (car (car opened))) (nth 1 (car (car opened))))
 203          (car (car opened))))
 204       (setq opened (cdr opened))))
 205   (goto-char (point-min))
 206   (gnus-server-position-point))
 207
 208 (defun gnus-server-server-name ()
 209   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-server)))
 210     (and server (symbol-name server))))
 211
 212 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 213
 214 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 215
 216 (defun gnus-server-update-server (server)
 217   (save-excursion
 218     (set-buffer gnus-server-buffer)
 219     (let ((buffer-read-only nil)
 220           (info (cdr (assoc server gnus-server-alist))))
 221       (gnus-dribble-enter
 222        (concat "(gnus-server-set-info \"" server "\" '"
 223                (prin1-to-string info) ")"))
 224       ;; Buffer may be narrowed.
 225       (save-restriction
 226         (widen)
 227         (if (gnus-server-goto-server server)
 228             (delete-region (progn (beginning-of-line) (point))
 229                            (progn (forward-line 1) (point))))
 230         (let ((entry (assoc server gnus-server-alist)))
 231           (gnus-server-insert-server-line (car entry) (cdr entry))
 232           (gnus-server-position-point))))))
 233
 234 (defun gnus-server-set-info (server info)
 235   ;; Enter a select method into the virtual server alist.
 236   (gnus-dribble-enter
 237    (concat "(gnus-server-set-info \"" server "\" '"
 238            (prin1-to-string info) ")"))
 239   (let* ((server (nth 1 info))
 240          (entry (assoc server gnus-server-alist)))
 241     (if entry (setcdr entry info)
 242       (setq gnus-server-alist
 243             (nconc gnus-server-alist (list (cons server info)))))))
 244
 245 ;;; Interactive server functions.
 246
 247 (defun gnus-server-kill-server (server)
 248   "Kill the server on the current line."
 249   (interactive (list (gnus-server-server-name)))
 250   (or (gnus-server-goto-server server)
 251       (if server (error "No such server: %s" server)
 252         (error "No server on the current line")))
 253   (gnus-dribble-enter "")
 254   (let ((buffer-read-only nil))
 255     (delete-region (progn (beginning-of-line) (point))
 256                    (progn (forward-line 1) (point))))
 257   (setq gnus-server-killed-servers
 258         (cons (assoc server gnus-server-alist) gnus-server-killed-servers))
 259   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 260                                 gnus-server-alist))
 261   (gnus-server-position-point))
 262
 263 (defun gnus-server-yank-server ()
 264   "Yank the previously killed server."
 265   (interactive)
 266   (or gnus-server-killed-servers
 267       (error "No killed servers to be yanked"))
 268   (let ((alist gnus-server-alist)
 269         (server (gnus-server-server-name))
 270         (killed (car gnus-server-killed-servers)))
 271     (if (not server)
 272         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 273       (if (string= server (car (car gnus-server-alist)))
 274           (setq gnus-server-alist (cons killed gnus-server-alist))
 275         (while (and (cdr alist)
 276                     (not (string= server (car (car (cdr alist))))))
 277           (setq alist (cdr alist)))
 278         (setcdr alist (cons killed (cdr alist)))
 279         (if alist
 280             (setcdr alist (cons killed (cdr alist)))
 281           (setq gnus-server-alist (list killed)))))
 282     (gnus-server-update-server (car killed))
 283     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 284     (gnus-server-position-point)))
 285
 286 (defun gnus-server-exit ()
 287   "Return to the group buffer."
 288   (interactive)
 289   (kill-buffer (current-buffer))
 290   (switch-to-buffer gnus-group-buffer))
 291
 292 (defun gnus-server-list-servers ()
 293   "List all available servers."
 294   (interactive)
 295   (let ((cur (gnus-server-server-name)))
 296     (gnus-server-prepare)
 297     (if cur (gnus-server-goto-server cur)
 298       (goto-char (point-max))
 299       (forward-line -1))
 300     (gnus-server-position-point)))
 301
 302 (defun gnus-opened-servers-remove (method)
 303   "Remove METHOD from the list of opened servers."
 304   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 305                                   gnus-opened-servers)))
 306
 307 (defun gnus-server-open-server (server)
 308   "Force an open of SERVER."
 309   (interactive (list (gnus-server-server-name)))
 310   (let ((method (gnus-server-to-method server)))
 311     (or method (error "No such server: %s" server))
 312     (gnus-opened-servers-remove method)
 313     (prog1
 314         (or (gnus-open-server method)
 315             (progn (message "Couldn't open %s" server) nil))
 316       (gnus-server-update-server server)
 317       (gnus-server-position-point))))
 318
 319 (defun gnus-server-close-server (server)
 320   "Close SERVER."
 321   (interactive (list (gnus-server-server-name)))
 322   (let ((method (gnus-server-to-method server)))
 323     (or method (error "No such server: %s" server))
 324     (gnus-opened-servers-remove method)
 325     (prog1
 326         (gnus-close-server method)
 327       (gnus-server-update-server server)
 328       (gnus-server-position-point))))
 329
 330 (defun gnus-server-deny-server (server)
 331   "Make sure SERVER will never be attempted opened."
 332   (interactive (list (gnus-server-server-name)))
 333   (let ((method (gnus-server-to-method server)))
 334     (or method (error "No such server: %s" server))
 335     (gnus-opened-servers-remove method)
 336     (setq gnus-opened-servers
 337           (cons (list method 'denied) gnus-opened-servers)))
 338   (gnus-server-update-server server)
 339   (gnus-server-position-point))
 340
 341 (defun gnus-server-remove-denials ()
 342   "Make all denied servers into closed servers."
 343   (interactive)
 344   (let ((servers gnus-opened-servers))
 345     (while servers
 346       (when (eq (nth 1 (car servers)) 'denied)
 347         (setcar (nthcdr 1 (car servers)) 'closed))
 348       (setq servers (cdr servers))))
 349   (gnus-server-list-servers))
 350
 351 (defun gnus-server-copy-server (from to)
 352   (interactive
 353    (list
 354     (or (gnus-server-server-name)
 355         (error "No server on the current line"))
 356     (read-string "Copy to: ")))
 357   (or from (error "No server on current line"))
 358   (or (and to (not (string= to ""))) (error "No name to copy to"))
 359   (and (assoc to gnus-server-alist) (error "%s already exists" to))
 360   (or (assoc from gnus-server-alist)
 361       (error "%s: no such server" from))
 362   (let ((to-entry (gnus-copy-sequence (assoc from gnus-server-alist))))
 363     (setcar to-entry to)
 364     (setcar (nthcdr 2 to-entry) to)
 365     (setq gnus-server-killed-servers
 366           (cons to-entry gnus-server-killed-servers))
 367     (gnus-server-yank-server)))
 368
 369 (defun gnus-server-add-server (how where)
 370   (interactive
 371    (list (intern (completing-read "Server method: "
 372                                   gnus-valid-select-methods nil t))
 373          (read-string "Server name: ")))
 374   (setq gnus-server-killed-servers
 375         (cons (list where how where) gnus-server-killed-servers))
 376   (gnus-server-yank-server))
 377
 378 (defun gnus-server-goto-server (server)
 379   "Jump to a server line."
 380   (interactive
 381    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 382   (let ((to (text-property-any (point-min) (point-max)
 383                                'gnus-server (intern server))))
 384     (and to
 385          (progn
 386            (goto-char to)
 387            (gnus-server-position-point)))))
 388
 389 (defun gnus-server-edit-server (server)
 390   "Edit the server on the current line."
 391   (interactive (list (gnus-server-server-name)))
 392   (or server
 393       (error "No server on current line"))
 394   (let ((winconf (current-window-configuration)))
 395     (get-buffer-create gnus-server-edit-buffer)
 396     (gnus-configure-windows 'edit-server)
 397     (gnus-add-current-to-buffer-list)
 398     (emacs-lisp-mode)
 399     (make-local-variable 'gnus-prev-winconf)
 400     (setq gnus-prev-winconf winconf)
 401     (use-local-map (copy-keymap (current-local-map)))
 402     (let ((done-func '(lambda ()
 403                         "Exit editing mode and update the information."
 404                         (interactive)
 405                         (gnus-server-edit-server-done 'group))))
 406       (setcar (cdr (nth 4 done-func)) server)
 407       (local-set-key "\C-c\C-c" done-func))
 408     (erase-buffer)
 409     (insert ";; Type `C-c C-c' after you have edited the server.\n\n")
 410     (insert (pp-to-string (cdr (assoc server gnus-server-alist))))))
 411
 412 (defun gnus-server-edit-server-done (server)
 413   (interactive)
 414   (set-buffer (get-buffer-create gnus-server-edit-buffer))
 415   (goto-char (point-min))
 416   (let ((form (read (current-buffer)))
 417         (winconf gnus-prev-winconf))
 418     (gnus-server-set-info server form)
 419     (kill-buffer (current-buffer))
 420     (and winconf (set-window-configuration winconf))
 421     (set-buffer gnus-server-buffer)
 422     (gnus-server-update-server (gnus-server-server-name))
 423     (gnus-server-list-servers)
 424     (gnus-server-position-point)))
 425
 426 (defun gnus-server-read-server (server)
 427   "Browse a server."
 428   (interactive (list (gnus-server-server-name)))
 429   (let ((buf (current-buffer)))
 430     (prog1
 431         (gnus-browse-foreign-server (gnus-server-to-method server) buf)
 432       (save-excursion
 433         (set-buffer buf)
 434         (gnus-server-update-server (gnus-server-server-name))
 435         (gnus-server-position-point)))))
 436
 437 (defun gnus-server-pick-server (e)
 438   (interactive "e")
 439   (mouse-set-point e)
 440   (gnus-server-read-server (gnus-server-server-name)))
 441
 442 \f
 443 ;;;
 444 ;;; Browse Server Mode
 445 ;;;
 446
 447 (defvar gnus-browse-menu-hook nil
 448   "*Hook run after the creation of the browse mode menu.")
 449
 450 (defvar gnus-browse-mode-hook nil)
 451 (defvar gnus-browse-mode-map nil)
 452 (put 'gnus-browse-mode 'mode-class 'special)
 453
 454 (unless gnus-browse-mode-map
 455   (setq gnus-browse-mode-map (make-keymap))
 456   (suppress-keymap gnus-browse-mode-map)
 457
 458   (gnus-define-keys
 459    gnus-browse-mode-map
 460    " " gnus-browse-read-group
 461    "=" gnus-browse-select-group
 462    "n" gnus-browse-next-group
 463    "p" gnus-browse-prev-group
 464    "\177" gnus-browse-prev-group
 465    "N" gnus-browse-next-group
 466    "P" gnus-browse-prev-group
 467    "\M-n" gnus-browse-next-group
 468    "\M-p" gnus-browse-prev-group
 469    "\r" gnus-browse-select-group
 470    "u" gnus-browse-unsubscribe-current-group
 471    "l" gnus-browse-exit
 472    "L" gnus-browse-exit
 473    "q" gnus-browse-exit
 474    "Q" gnus-browse-exit
 475    "\C-c\C-c" gnus-browse-exit
 476    "?" gnus-browse-describe-briefly
 477    "\C-c\C-i" gnus-info-find-node))
 478
 479 (defun gnus-browse-make-menu-bar ()
 480   (gnus-visual-turn-off-edit-menu 'browse)
 481   (or
 482    (boundp 'gnus-browse-menu)
 483    (progn
 484      (easy-menu-define
 485       gnus-browse-menu gnus-browse-mode-map ""
 486       '("Browse"
 487         ["Subscribe" gnus-browse-unsubscribe-current-group t]
 488         ["Read" gnus-browse-read-group t]
 489         ["Select" gnus-browse-read-group t]
 490         ["Next" gnus-browse-next-group t]
 491         ["Prev" gnus-browse-next-group t]
 492         ["Exit" gnus-browse-exit t]
 493         ))
 494       (run-hooks 'gnus-browse-menu-hook))))
 495
 496 (defvar gnus-browse-current-method nil)
 497 (defvar gnus-browse-return-buffer nil)
 498
 499 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 500
 501 (defun gnus-browse-foreign-server (method &optional return-buffer)
 502   "Browse the server METHOD."
 503   (setq gnus-browse-current-method method)
 504   (setq gnus-browse-return-buffer return-buffer)
 505   (let ((gnus-select-method method)
 506         groups group)
 507     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 508     (cond
 509      ((not (gnus-check-server method))
 510       (gnus-message
 511        1 "Unable to contact server: %s" (gnus-status-message method))
 512       nil)
 513      ((not (gnus-request-list method))
 514       (gnus-message
 515        1 "Couldn't request list: %s" (gnus-status-message method))
 516       nil)
 517      (t
 518       (get-buffer-create gnus-browse-buffer)
 519       (gnus-add-current-to-buffer-list)
 520       (and gnus-carpal (gnus-carpal-setup-buffer 'browse))
 521       (gnus-configure-windows 'browse)
 522       (buffer-disable-undo (current-buffer))
 523       (let ((buffer-read-only nil))
 524         (erase-buffer))
 525       (gnus-browse-mode)
 526       (setq mode-line-buffer-identification
 527             (list
 528              (format
 529               "Gnus: %%b {%s:%s}" (car method) (car (cdr method)))))
 530       (save-excursion
 531         (set-buffer nntp-server-buffer)
 532         (let ((cur (current-buffer)))
 533           (goto-char (point-min))
 534           (or (string= gnus-ignored-newsgroups "")
 535               (delete-matching-lines gnus-ignored-newsgroups))
 536           (while (re-search-forward
 537                   "\\(^[^ \t]+\\)[ \t]+[0-9]+[ \t]+[0-9]+" nil t)
 538             (goto-char (match-end 1))
 539             (setq groups (cons (cons (match-string 1)
 540                                      (max 0 (- (1+ (read cur)) (read cur))))
 541                                groups)))))
 542       (setq groups (sort groups
 543                          (lambda (l1 l2)
 544                            (string< (car l1) (car l2)))))
 545       (let ((buffer-read-only nil))
 546         (while groups
 547           (setq group (car groups))
 548           (insert
 549            (format "K%7d: %s\n" (cdr group) (car group)))
 550           (setq groups (cdr groups))))
 551       (switch-to-buffer (current-buffer))
 552       (goto-char (point-min))
 553       (gnus-group-position-point)
 554       t))))
 555
 556 (defun gnus-browse-mode ()
 557   "Major mode for browsing a foreign server.
 558
 559 All normal editing commands are switched off.
 560
 561 \\<gnus-browse-mode-map>
 562 The only things you can do in this buffer is
 563
 564 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 565 The group will be inserted into the group buffer upon exit from this
 566 buffer.
 567
 568 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 569
 570 3) `\\[gnus-browse-exit]' to return to the group buffer."
 571   (interactive)
 572   (kill-all-local-variables)
 573   (when (and menu-bar-mode
 574              (gnus-visual-p 'browse-menu 'menu))
 575     (gnus-browse-make-menu-bar))
 576   (gnus-simplify-mode-line)
 577   (setq major-mode 'gnus-browse-mode)
 578   (setq mode-name "Browse Server")
 579   (setq mode-line-process nil)
 580   (use-local-map gnus-browse-mode-map)
 581   (buffer-disable-undo (current-buffer))
 582   (setq truncate-lines t)
 583   (setq buffer-read-only t)
 584   (run-hooks 'gnus-browse-mode-hook))
 585
 586 (defun gnus-browse-read-group (&optional no-article)
 587   "Enter the group at the current line."
 588   (interactive)
 589   (let ((group (gnus-browse-group-name)))
 590     (or (gnus-group-read-ephemeral-group
 591          group gnus-browse-current-method nil
 592          (cons (current-buffer) 'browse))
 593         (error "Couldn't enter %s" group))))
 594
 595 (defun gnus-browse-select-group ()
 596   "Select the current group."
 597   (interactive)
 598   (gnus-browse-read-group 'no))
 599
 600 (defun gnus-browse-next-group (n)
 601   "Go to the next group."
 602   (interactive "p")
 603   (prog1
 604       (forward-line n)
 605     (gnus-group-position-point)))
 606
 607 (defun gnus-browse-prev-group (n)
 608   "Go to the next group."
 609   (interactive "p")
 610   (gnus-browse-next-group (- n)))
 611
 612 (defun gnus-browse-unsubscribe-current-group (arg)
 613   "(Un)subscribe to the next ARG groups."
 614   (interactive "p")
 615   (and (eobp)
 616        (error "No group at current line."))
 617   (let ((ward (if (< arg 0) -1 1))
 618         (arg (abs arg)))
 619     (while (and (> arg 0)
 620                 (not (eobp))
 621                 (gnus-browse-unsubscribe-group)
 622                 (zerop (gnus-browse-next-group ward)))
 623       (setq arg (1- arg)))
 624     (gnus-group-position-point)
 625     (if (/= 0 arg) (gnus-message 7 "No more newsgroups"))
 626     arg))
 627
 628 (defun gnus-browse-group-name ()
 629   (save-excursion
 630     (beginning-of-line)
 631     (when (re-search-forward ": \\(.*\\)$" (gnus-point-at-eol) t)
 632       (gnus-group-prefixed-name (match-string 1) gnus-browse-current-method))))
 633
 634 (defun gnus-browse-unsubscribe-group ()
 635   "Toggle subscription of the current group in the browse buffer."
 636   (let ((sub nil)
 637         (buffer-read-only nil)
 638         group)
 639     (save-excursion
 640       (beginning-of-line)
 641       ;; If this group it killed, then we want to subscribe it.
 642       (if (= (following-char) ?K) (setq sub t))
 643       (setq group (gnus-browse-group-name))
 644       (delete-char 1)
 645       (if sub
 646           (progn
 647             (gnus-group-change-level
 648              (list t group gnus-level-default-subscribed
 649                    nil nil gnus-browse-current-method)
 650              gnus-level-default-subscribed gnus-level-killed
 651              (and (car (nth 1 gnus-newsrc-alist))
 652                   (gnus-gethash (car (nth 1 gnus-newsrc-alist))
 653                                 gnus-newsrc-hashtb))
 654              t)
 655             (insert ? ))
 656         (gnus-group-change-level
 657          group gnus-level-killed gnus-level-default-subscribed)
 658         (insert ?K)))
 659     t))
 660
 661 (defun gnus-browse-exit ()
 662   "Quit browsing and return to the group buffer."
 663   (interactive)
 664   (if (eq major-mode 'gnus-browse-mode)
 665       (kill-buffer (current-buffer)))
 666   (if gnus-browse-return-buffer
 667       (gnus-configure-windows 'server 'force)
 668     (gnus-configure-windows 'group 'force)
 669     (gnus-group-list-groups nil)))
 670
 671 (defun gnus-browse-describe-briefly ()
 672   "Give a one line description of the group mode commands."
 673   (interactive)
 674   (gnus-message 6
 675                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 676
 677
 678 ;;; gnus-srvr.el ends here.