cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-spec)
  33 (require 'gnus-group)
  34 (require 'gnus-int)
  35 (require 'gnus-range)
  36
  37 (defcustom gnus-server-mode-hook nil
  38   "Hook run in `gnus-server-mode' buffers."
  39   :group 'gnus-server
  40   :type 'hook)
  41
  42 (defcustom gnus-server-exit-hook nil
  43   "Hook run when exiting the server buffer."
  44   :group 'gnus-server
  45   :type 'hook)
  46
  47 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a\n"
  48   "Format of server lines.
  49 It works along the same lines as a normal formatting string,
  50 with some simple extensions.
  51
  52 The following specs are understood:
  53
  54 %h backend
  55 %n name
  56 %w address
  57 %s status
  58 %a agent covered"
  59   :group 'gnus-server-visual
  60   :type 'string)
  61
  62 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  63   "The format specification for the server mode line."
  64   :group 'gnus-server-visual
  65   :type 'string)
  66
  67 (defcustom gnus-server-browse-in-group-buffer nil
  68   "Whether browse server in group buffer."
  69   :group 'gnus-server-visual
  70   :type 'string)
  71
  72 ;;; Internal variables.
  73
  74 (defvar gnus-inserted-opened-servers nil)
  75
  76 (defvar gnus-server-line-format-alist
  77   `((?h gnus-tmp-how ?s)
  78     (?n gnus-tmp-name ?s)
  79     (?w gnus-tmp-where ?s)
  80     (?s gnus-tmp-status ?s)
  81     (?a gnus-tmp-agent ?s)))
  82
  83 (defvar gnus-server-mode-line-format-alist
  84   `((?S gnus-tmp-news-server ?s)
  85     (?M gnus-tmp-news-method ?s)
  86     (?u gnus-tmp-user-defined ?s)))
  87
  88 (defvar gnus-server-line-format-spec nil)
  89 (defvar gnus-server-mode-line-format-spec nil)
  90 (defvar gnus-server-killed-servers nil)
  91
  92 (defvar gnus-server-mode-map)
  93
  94 (defvar gnus-server-menu-hook nil
  95   "*Hook run after the creation of the server mode menu.")
  96
  97 (defun gnus-server-make-menu-bar ()
  98   (gnus-turn-off-edit-menu 'server)
  99   (unless (boundp 'gnus-server-server-menu)
 100     (easy-menu-define
 101      gnus-server-server-menu gnus-server-mode-map ""
 102      '("Server"
 103        ["Add" gnus-server-add-server t]
 104        ["Browse" gnus-server-read-server t]
 105        ["Scan" gnus-server-scan-server t]
 106        ["List" gnus-server-list-servers t]
 107        ["Kill" gnus-server-kill-server t]
 108        ["Yank" gnus-server-yank-server t]
 109        ["Copy" gnus-server-copy-server t]
 110        ["Edit" gnus-server-edit-server t]
 111        ["Regenerate" gnus-server-regenerate-server t]
 112        ["Exit" gnus-server-exit t]))
 113
 114     (easy-menu-define
 115      gnus-server-connections-menu gnus-server-mode-map ""
 116      '("Connections"
 117        ["Open" gnus-server-open-server t]
 118        ["Close" gnus-server-close-server t]
 119        ["Deny" gnus-server-deny-server t]
 120        "---"
 121        ["Open All" gnus-server-open-all-servers t]
 122        ["Close All" gnus-server-close-all-servers t]
 123        ["Reset All" gnus-server-remove-denials t]))
 124
 125     (gnus-run-hooks 'gnus-server-menu-hook)))
 126
 127 (defvar gnus-server-mode-map nil)
 128 (put 'gnus-server-mode 'mode-class 'special)
 129
 130 (unless gnus-server-mode-map
 131   (setq gnus-server-mode-map (make-sparse-keymap))
 132   (suppress-keymap gnus-server-mode-map)
 133
 134   (gnus-define-keys gnus-server-mode-map
 135     " " gnus-server-read-server-in-server-buffer
 136     "\r" gnus-server-read-server
 137     gnus-mouse-2 gnus-server-pick-server
 138     "q" gnus-server-exit
 139     "l" gnus-server-list-servers
 140     "k" gnus-server-kill-server
 141     "y" gnus-server-yank-server
 142     "c" gnus-server-copy-server
 143     "a" gnus-server-add-server
 144     "e" gnus-server-edit-server
 145     "s" gnus-server-scan-server
 146
 147     "O" gnus-server-open-server
 148     "\M-o" gnus-server-open-all-servers
 149     "C" gnus-server-close-server
 150     "\M-c" gnus-server-close-all-servers
 151     "D" gnus-server-deny-server
 152     "R" gnus-server-remove-denials
 153
 154     "n" next-line
 155     "p" previous-line
 156
 157     "g" gnus-server-regenerate-server
 158
 159     "\C-c\C-i" gnus-info-find-node
 160     "\C-c\C-b" gnus-bug))
 161
 162 (defface gnus-server-agent-face
 163   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 164     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 165     (t (:bold t)))
 166   "Face used for displaying AGENTIZED servers"
 167   :group 'gnus-server-visual)
 168
 169 (defface gnus-server-opened-face
 170   '((((class color) (background light)) (:foreground "Green3" :bold t))
 171     (((class color) (background dark)) (:foreground "Green1" :bold t))
 172     (t (:bold t)))
 173   "Face used for displaying OPENED servers"
 174   :group 'gnus-server-visual)
 175
 176 (defface gnus-server-closed-face
 177   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 178     (((class color) (background dark))
 179      (:foreground "Light Steel Blue" :italic t))
 180     (t (:italic t)))
 181   "Face used for displaying CLOSED servers"
 182   :group 'gnus-server-visual)
 183
 184 (defface gnus-server-denied-face
 185   '((((class color) (background light)) (:foreground "Red" :bold t))
 186     (((class color) (background dark)) (:foreground "Pink" :bold t))
 187     (t (:inverse-video t :bold t)))
 188   "Face used for displaying DENIED servers"
 189   :group 'gnus-server-visual)
 190
 191 (defcustom gnus-server-agent-face 'gnus-server-agent-face
 192   "Face name to use on AGENTIZED servers."
 193   :group 'gnus-server-visual
 194   :type 'face)
 195
 196 (defcustom gnus-server-opened-face 'gnus-server-opened-face
 197   "Face name to use on OPENED servers."
 198   :group 'gnus-server-visual
 199   :type 'face)
 200
 201 (defcustom gnus-server-closed-face 'gnus-server-closed-face
 202   "Face name to use on CLOSED servers."
 203   :group 'gnus-server-visual
 204   :type 'face)
 205
 206 (defcustom gnus-server-denied-face 'gnus-server-denied-face
 207   "Face name to use on DENIED servers."
 208   :group 'gnus-server-visual
 209   :type 'face)
 210
 211 (defvar gnus-server-font-lock-keywords
 212   (list
 213    '("(\\(agent\\))" 1 gnus-server-agent-face)
 214    '("(\\(opened\\))" 1 gnus-server-opened-face)
 215    '("(\\(closed\\))" 1 gnus-server-closed-face)
 216    '("(\\(denied\\))" 1 gnus-server-denied-face)))
 217
 218 (defun gnus-server-mode ()
 219   "Major mode for listing and editing servers.
 220
 221 All normal editing commands are switched off.
 222 \\<gnus-server-mode-map>
 223 For more in-depth information on this mode, read the manual
 224 (`\\[gnus-info-find-node]').
 225
 226 The following commands are available:
 227
 228 \\{gnus-server-mode-map}"
 229   (interactive)
 230   (when (gnus-visual-p 'server-menu 'menu)
 231     (gnus-server-make-menu-bar))
 232   (kill-all-local-variables)
 233   (gnus-simplify-mode-line)
 234   (setq major-mode 'gnus-server-mode)
 235   (setq mode-name "Server")
 236   (gnus-set-default-directory)
 237   (setq mode-line-process nil)
 238   (use-local-map gnus-server-mode-map)
 239   (buffer-disable-undo)
 240   (setq truncate-lines t)
 241   (setq buffer-read-only t)
 242   (if (featurep 'xemacs)
 243       (put 'gnus-server-mode 'font-lock-defaults '(gnus-server-font-lock-keywords t))
 244     (set (make-local-variable 'font-lock-defaults)
 245          '(gnus-server-font-lock-keywords t)))
 246   (gnus-run-hooks 'gnus-server-mode-hook))
 247
 248 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 249   (let* ((gnus-tmp-how (car method))
 250          (gnus-tmp-where (nth 1 method))
 251          (elem (assoc method gnus-opened-servers))
 252          (gnus-tmp-status (cond ((eq (nth 1 elem) 'denied)
 253                                  "(denied)")
 254                                 ((or (gnus-server-opened method)
 255                                      (eq (nth 1 elem) 'ok))
 256                                  "(opened)")
 257                                 (t
 258                                  "(closed)")))
 259          (gnus-tmp-agent (if (and gnus-agent
 260                                   (member method
 261                                           gnus-agent-covered-methods))
 262                              " (agent)"
 263                            "")))
 264     (beginning-of-line)
 265     (gnus-add-text-properties
 266      (point)
 267      (prog1 (1+ (point))
 268        ;; Insert the text.
 269        (eval gnus-server-line-format-spec))
 270      (list 'gnus-server (intern gnus-tmp-name)))))
 271
 272 (defun gnus-enter-server-buffer ()
 273   "Set up the server buffer."
 274   (gnus-server-setup-buffer)
 275   (gnus-configure-windows 'server)
 276   (gnus-server-prepare))
 277
 278 (defun gnus-server-setup-buffer ()
 279   "Initialize the server buffer."
 280   (unless (get-buffer gnus-server-buffer)
 281     (save-excursion
 282       (set-buffer (gnus-get-buffer-create gnus-server-buffer))
 283       (gnus-server-mode)
 284       (when gnus-carpal
 285         (gnus-carpal-setup-buffer 'server)))))
 286
 287 (defun gnus-server-prepare ()
 288   (gnus-set-format 'server-mode)
 289   (gnus-set-format 'server t)
 290   (let ((alist gnus-server-alist)
 291         (buffer-read-only nil)
 292         (opened gnus-opened-servers)
 293         done server op-ser)
 294     (erase-buffer)
 295     (setq gnus-inserted-opened-servers nil)
 296     ;; First we do the real list of servers.
 297     (while alist
 298       (unless (member (cdar alist) done)
 299         (push (cdar alist) done)
 300         (cdr (setq server (pop alist)))
 301         (when (and server (car server) (cdr server))
 302           (gnus-server-insert-server-line (car server) (cdr server))))
 303       (when (member (cdar alist) done)
 304         (pop alist)))
 305     ;; Then we insert the list of servers that have been opened in
 306     ;; this session.
 307     (while opened
 308       (when (and (not (member (caar opened) done))
 309                  ;; Just ignore ephemeral servers.
 310                  (not (member (caar opened) gnus-ephemeral-servers)))
 311         (push (caar opened) done)
 312         (gnus-server-insert-server-line
 313          (setq op-ser (format "%s:%s" (caaar opened) (nth 1 (caar opened))))
 314          (caar opened))
 315         (push (list op-ser (caar opened)) gnus-inserted-opened-servers))
 316       (setq opened (cdr opened))))
 317   (goto-char (point-min))
 318   (gnus-server-position-point))
 319
 320 (defun gnus-server-server-name ()
 321   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-server)))
 322     (and server (symbol-name server))))
 323
 324 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 325
 326 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 327
 328 (defun gnus-server-update-server (server)
 329   (save-excursion
 330     (set-buffer gnus-server-buffer)
 331     (let* ((buffer-read-only nil)
 332            (entry (assoc server gnus-server-alist))
 333            (oentry (assoc (gnus-server-to-method server)
 334                           gnus-opened-servers)))
 335       (when entry
 336         (gnus-dribble-enter
 337          (concat "(gnus-server-set-info \"" server "\" '"
 338                  (prin1-to-string (cdr entry)) ")\n")))
 339       (when (or entry oentry)
 340         ;; Buffer may be narrowed.
 341         (save-restriction
 342           (widen)
 343           (when (gnus-server-goto-server server)
 344             (gnus-delete-line))
 345           (if entry
 346               (gnus-server-insert-server-line (car entry) (cdr entry))
 347             (gnus-server-insert-server-line
 348              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 349              (car oentry)))
 350           (gnus-server-position-point))))))
 351
 352 (defun gnus-server-set-info (server info)
 353   ;; Enter a select method into the virtual server alist.
 354   (when (and server info)
 355     (gnus-dribble-enter
 356      (concat "(gnus-server-set-info \"" server "\" '"
 357              (prin1-to-string info) ")"))
 358     (let* ((server (nth 1 info))
 359            (entry (assoc server gnus-server-alist)))
 360       (if entry (setcdr entry info)
 361         (setq gnus-server-alist
 362               (nconc gnus-server-alist (list (cons server info))))))))
 363
 364 ;;; Interactive server functions.
 365
 366 (defun gnus-server-kill-server (server)
 367   "Kill the server on the current line."
 368   (interactive (list (gnus-server-server-name)))
 369   (unless (gnus-server-goto-server server)
 370     (if server (error "No such server: %s" server)
 371       (error "No server on the current line")))
 372   (unless (assoc server gnus-server-alist)
 373     (error "Read-only server %s" server))
 374   (gnus-dribble-touch)
 375   (let ((buffer-read-only nil))
 376     (gnus-delete-line))
 377   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 378   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 379                                 gnus-server-alist))
 380   (let ((groups (gnus-groups-from-server server)))
 381     (when (and groups
 382                (gnus-yes-or-no-p
 383                 (format "Kill all %s groups from this server? "
 384                         (length groups))))
 385       (dolist (group groups)
 386         (setq gnus-newsrc-alist
 387               (delq (assoc group gnus-newsrc-alist)
 388                     gnus-newsrc-alist))
 389         (when gnus-group-change-level-function
 390           (funcall gnus-group-change-level-function
 391                    group gnus-level-killed 3)))))
 392   (gnus-server-position-point))
 393
 394 (defun gnus-server-yank-server ()
 395   "Yank the previously killed server."
 396   (interactive)
 397   (unless gnus-server-killed-servers
 398     (error "No killed servers to be yanked"))
 399   (let ((alist gnus-server-alist)
 400         (server (gnus-server-server-name))
 401         (killed (car gnus-server-killed-servers)))
 402     (if (not server)
 403         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 404       (if (string= server (caar gnus-server-alist))
 405           (push killed gnus-server-alist)
 406         (while (and (cdr alist)
 407                     (not (string= server (caadr alist))))
 408           (setq alist (cdr alist)))
 409         (if alist
 410             (setcdr alist (cons killed (cdr alist)))
 411           (setq gnus-server-alist (list killed)))))
 412     (gnus-server-update-server (car killed))
 413     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 414     (gnus-server-position-point)))
 415
 416 (defun gnus-server-exit ()
 417   "Return to the group buffer."
 418   (interactive)
 419   (gnus-run-hooks 'gnus-server-exit-hook)
 420   (kill-buffer (current-buffer))
 421   (gnus-configure-windows 'group t))
 422
 423 (defun gnus-server-list-servers ()
 424   "List all available servers."
 425   (interactive)
 426   (let ((cur (gnus-server-server-name)))
 427     (gnus-server-prepare)
 428     (if cur (gnus-server-goto-server cur)
 429       (goto-char (point-max))
 430       (forward-line -1))
 431     (gnus-server-position-point)))
 432
 433 (defun gnus-server-set-status (method status)
 434   "Make METHOD have STATUS."
 435   (let ((entry (assoc method gnus-opened-servers)))
 436     (if entry
 437         (setcar (cdr entry) status)
 438       (push (list method status) gnus-opened-servers))))
 439
 440 (defun gnus-opened-servers-remove (method)
 441   "Remove METHOD from the list of opened servers."
 442   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 443                                   gnus-opened-servers)))
 444
 445 (defun gnus-server-open-server (server)
 446   "Force an open of SERVER."
 447   (interactive (list (gnus-server-server-name)))
 448   (let ((method (gnus-server-to-method server)))
 449     (unless method
 450       (error "No such server: %s" server))
 451     (gnus-server-set-status method 'ok)
 452     (prog1
 453         (or (gnus-open-server method)
 454             (progn (message "Couldn't open %s" server) nil))
 455       (gnus-server-update-server server)
 456       (gnus-server-position-point))))
 457
 458 (defun gnus-server-open-all-servers ()
 459   "Open all servers."
 460   (interactive)
 461   (let ((servers gnus-inserted-opened-servers))
 462     (while servers
 463       (gnus-server-open-server (car (pop servers))))))
 464
 465 (defun gnus-server-close-server (server)
 466   "Close SERVER."
 467   (interactive (list (gnus-server-server-name)))
 468   (let ((method (gnus-server-to-method server)))
 469     (unless method
 470       (error "No such server: %s" server))
 471     (gnus-server-set-status method 'closed)
 472     (prog1
 473         (gnus-close-server method)
 474       (gnus-server-update-server server)
 475       (gnus-server-position-point))))
 476
 477 (defun gnus-server-close-all-servers ()
 478   "Close all servers."
 479   (interactive)
 480   (dolist (server gnus-inserted-opened-servers)
 481     (gnus-server-close-server (car server))))
 482
 483 (defun gnus-server-deny-server (server)
 484   "Make sure SERVER will never be attempted opened."
 485   (interactive (list (gnus-server-server-name)))
 486   (let ((method (gnus-server-to-method server)))
 487     (unless method
 488       (error "No such server: %s" server))
 489     (gnus-server-set-status method 'denied))
 490   (gnus-server-update-server server)
 491   (gnus-server-position-point)
 492   t)
 493
 494 (defun gnus-server-remove-denials ()
 495   "Make all denied servers into closed servers."
 496   (interactive)
 497   (dolist (server gnus-opened-servers)
 498     (when (eq (nth 1 server) 'denied)
 499       (setcar (nthcdr 1 server) 'closed)))
 500   (gnus-server-list-servers))
 501
 502 (defun gnus-server-copy-server (from to)
 503   (interactive
 504    (list
 505     (or (gnus-server-server-name)
 506         (error "No server on the current line"))
 507     (read-string "Copy to: ")))
 508   (unless from
 509     (error "No server on current line"))
 510   (unless (and to (not (string= to "")))
 511     (error "No name to copy to"))
 512   (when (assoc to gnus-server-alist)
 513     (error "%s already exists" to))
 514   (unless (gnus-server-to-method from)
 515     (error "%s: no such server" from))
 516   (let ((to-entry (cons from (gnus-copy-sequence
 517                               (gnus-server-to-method from)))))
 518     (setcar to-entry to)
 519     (setcar (nthcdr 2 to-entry) to)
 520     (push to-entry gnus-server-killed-servers)
 521     (gnus-server-yank-server)))
 522
 523 (defun gnus-server-add-server (how where)
 524   (interactive
 525    (list (intern (completing-read "Server method: "
 526                                   gnus-valid-select-methods nil t))
 527          (read-string "Server name: ")))
 528   (when (assq where gnus-server-alist)
 529     (error "Server with that name already defined"))
 530   (push (list where how where) gnus-server-killed-servers)
 531   (gnus-server-yank-server))
 532
 533 (defun gnus-server-goto-server (server)
 534   "Jump to a server line."
 535   (interactive
 536    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 537   (let ((to (text-property-any (point-min) (point-max)
 538                                'gnus-server (intern server))))
 539     (when to
 540       (goto-char to)
 541       (gnus-server-position-point))))
 542
 543 (defun gnus-server-edit-server (server)
 544   "Edit the server on the current line."
 545   (interactive (list (gnus-server-server-name)))
 546   (unless server
 547     (error "No server on current line"))
 548   (unless (assoc server gnus-server-alist)
 549     (error "This server can't be edited"))
 550   (let ((info (cdr (assoc server gnus-server-alist))))
 551     (gnus-close-server info)
 552     (gnus-edit-form
 553      info "Editing the server."
 554      `(lambda (form)
 555         (gnus-server-set-info ,server form)
 556         (gnus-server-list-servers)
 557         (gnus-server-position-point)))))
 558
 559 (defun gnus-server-scan-server (server)
 560   "Request a scan from the current server."
 561   (interactive (list (gnus-server-server-name)))
 562   (let ((method (gnus-server-to-method server)))
 563     (if (not (gnus-get-function method 'request-scan))
 564         (error "Server %s can't scan" (car method))
 565       (gnus-message 3 "Scanning %s..." server)
 566       (gnus-request-scan nil method)
 567       (gnus-message 3 "Scanning %s...done" server))))
 568
 569 (defun gnus-server-read-server-in-server-buffer (server)
 570   "Browse a server in server buffer."
 571   (interactive (list (gnus-server-server-name)))
 572   (let (gnus-server-browse-in-group-buffer)
 573     (gnus-server-read-server server)))
 574
 575 (defun gnus-server-read-server (server)
 576   "Browse a server."
 577   (interactive (list (gnus-server-server-name)))
 578   (let ((buf (current-buffer)))
 579     (prog1
 580         (gnus-browse-foreign-server server buf)
 581       (save-excursion
 582         (set-buffer buf)
 583         (gnus-server-update-server (gnus-server-server-name))
 584         (gnus-server-position-point)))))
 585
 586 (defun gnus-server-pick-server (e)
 587   (interactive "e")
 588   (mouse-set-point e)
 589   (gnus-server-read-server (gnus-server-server-name)))
 590
 591 \f
 592 ;;;
 593 ;;; Browse Server Mode
 594 ;;;
 595
 596 (defvar gnus-browse-menu-hook nil
 597   "*Hook run after the creation of the browse mode menu.")
 598
 599 (defvar gnus-browse-mode-hook nil)
 600 (defvar gnus-browse-mode-map nil)
 601 (put 'gnus-browse-mode 'mode-class 'special)
 602
 603 (unless gnus-browse-mode-map
 604   (setq gnus-browse-mode-map (make-keymap))
 605   (suppress-keymap gnus-browse-mode-map)
 606
 607   (gnus-define-keys
 608       gnus-browse-mode-map
 609     " " gnus-browse-read-group
 610     "=" gnus-browse-select-group
 611     "n" gnus-browse-next-group
 612     "p" gnus-browse-prev-group
 613     "\177" gnus-browse-prev-group
 614     [delete] gnus-browse-prev-group
 615     "N" gnus-browse-next-group
 616     "P" gnus-browse-prev-group
 617     "\M-n" gnus-browse-next-group
 618     "\M-p" gnus-browse-prev-group
 619     "\r" gnus-browse-select-group
 620     "u" gnus-browse-unsubscribe-current-group
 621     "l" gnus-browse-exit
 622     "L" gnus-browse-exit
 623     "q" gnus-browse-exit
 624     "Q" gnus-browse-exit
 625     "\C-c\C-c" gnus-browse-exit
 626     "?" gnus-browse-describe-briefly
 627
 628     "\C-c\C-i" gnus-info-find-node
 629     "\C-c\C-b" gnus-bug))
 630
 631 (defun gnus-browse-make-menu-bar ()
 632   (gnus-turn-off-edit-menu 'browse)
 633   (unless (boundp 'gnus-browse-menu)
 634     (easy-menu-define
 635      gnus-browse-menu gnus-browse-mode-map ""
 636      '("Browse"
 637        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 638        ["Read" gnus-browse-read-group t]
 639        ["Select" gnus-browse-select-group t]
 640        ["Next" gnus-browse-next-group t]
 641        ["Prev" gnus-browse-prev-group t]
 642        ["Exit" gnus-browse-exit t]))
 643     (gnus-run-hooks 'gnus-browse-menu-hook)))
 644
 645 (defvar gnus-browse-current-method nil)
 646 (defvar gnus-browse-return-buffer nil)
 647
 648 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 649
 650 (defun gnus-browse-foreign-server (server &optional return-buffer)
 651   "Browse the server SERVER."
 652   (setq gnus-browse-current-method (gnus-server-to-method server))
 653   (setq gnus-browse-return-buffer return-buffer)
 654   (let* ((method gnus-browse-current-method)
 655          (orig-select-method gnus-select-method)
 656          (gnus-select-method method)
 657          groups group)
 658     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 659     (cond
 660      ((not (gnus-check-server method))
 661       (gnus-message
 662        1 "Unable to contact server %s: %s" (nth 1 method)
 663        (gnus-status-message method))
 664       nil)
 665      ((not
 666        (prog2
 667            (gnus-message 6 "Reading active file...")
 668            (gnus-request-list method)
 669          (gnus-message 6 "Reading active file...done")))
 670       (gnus-message
 671        1 "Couldn't request list: %s" (gnus-status-message method))
 672       nil)
 673      (t
 674       (save-excursion
 675         (set-buffer nntp-server-buffer)
 676         (let ((cur (current-buffer)))
 677           (goto-char (point-min))
 678           (unless (string= gnus-ignored-newsgroups "")
 679             (delete-matching-lines gnus-ignored-newsgroups))
 680           (while (not (eobp))
 681             (ignore-errors
 682               (push (cons
 683                      (if (eq (char-after) ?\")
 684                          (read cur)
 685                        (let ((p (point)) (name ""))
 686                          (skip-chars-forward "^ \t\\\\")
 687                          (setq name (buffer-substring p (point)))
 688                          (while (eq (char-after) ?\\)
 689                            (setq p (1+ (point)))
 690                            (forward-char 2)
 691                            (skip-chars-forward "^ \t\\\\")
 692                            (setq name (concat name (buffer-substring
 693                                                     p (point)))))
 694                          name))
 695                      (let ((last (read cur)))
 696                        (cons (read cur) last)))
 697                     groups))
 698             (forward-line))))
 699       (setq groups (sort groups
 700                          (lambda (l1 l2)
 701                            (string< (car l1) (car l2)))))
 702       (if gnus-server-browse-in-group-buffer
 703           (let* ((gnus-select-method orig-select-method)
 704                  (gnus-group-listed-groups
 705                   (mapcar (lambda (group)
 706                             (let ((name
 707                                    (gnus-group-prefixed-name
 708                                     (car group) method)))
 709                               (gnus-set-active name (cdr group))
 710                               name))
 711                           groups)))
 712             (gnus-configure-windows 'group)
 713             (funcall gnus-group-prepare-function
 714                      gnus-level-killed 'ignore 1 'ingore))
 715         (gnus-get-buffer-create gnus-browse-buffer)
 716         (when gnus-carpal
 717           (gnus-carpal-setup-buffer 'browse))
 718         (gnus-configure-windows 'browse)
 719         (buffer-disable-undo)
 720         (let ((buffer-read-only nil))
 721           (erase-buffer))
 722         (gnus-browse-mode)
 723         (setq mode-line-buffer-identification
 724               (list
 725                (format
 726                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 727         (let ((buffer-read-only nil) charset)
 728           (while groups
 729             (setq group (car groups))
 730             (setq charset (gnus-group-name-charset method group))
 731             (gnus-add-text-properties
 732              (point)
 733              (prog1 (1+ (point))
 734                (insert
 735                 (format "%c%7d: %s\n"
 736                         (let ((level
 737                                (let ((gnus-select-method orig-select-method))
 738                                  (gnus-group-level
 739                                   (gnus-group-prefixed-name (car group)
 740                                                             method)))))
 741                               (cond
 742                                ((<= level gnus-level-subscribed) ? )
 743                                ((<= level gnus-level-unsubscribed) ?U)
 744                                ((= level gnus-level-zombie) ?Z)
 745                                (t ?K)))
 746                         (max 0 (- (1+ (cddr group)) (cadr group)))
 747                         (gnus-group-name-decode (car group) charset))))
 748              (list 'gnus-group (car group)))
 749             (setq groups (cdr groups))))
 750         (switch-to-buffer (current-buffer)))
 751       (goto-char (point-min))
 752       (gnus-group-position-point)
 753       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 754       t))))
 755
 756 (defun gnus-browse-mode ()
 757   "Major mode for browsing a foreign server.
 758
 759 All normal editing commands are switched off.
 760
 761 \\<gnus-browse-mode-map>
 762 The only things you can do in this buffer is
 763
 764 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 765 The group will be inserted into the group buffer upon exit from this
 766 buffer.
 767
 768 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 769
 770 3) `\\[gnus-browse-exit]' to return to the group buffer."
 771   (interactive)
 772   (kill-all-local-variables)
 773   (when (gnus-visual-p 'browse-menu 'menu)
 774     (gnus-browse-make-menu-bar))
 775   (gnus-simplify-mode-line)
 776   (setq major-mode 'gnus-browse-mode)
 777   (setq mode-name "Browse Server")
 778   (setq mode-line-process nil)
 779   (use-local-map gnus-browse-mode-map)
 780   (buffer-disable-undo)
 781   (setq truncate-lines t)
 782   (gnus-set-default-directory)
 783   (setq buffer-read-only t)
 784   (gnus-run-hooks 'gnus-browse-mode-hook))
 785
 786 (defun gnus-browse-read-group (&optional no-article)
 787   "Enter the group at the current line."
 788   (interactive)
 789   (let ((group (gnus-browse-group-name)))
 790     (if (or (not (gnus-get-info group))
 791             (gnus-ephemeral-group-p group))
 792         (unless (gnus-group-read-ephemeral-group
 793                  (gnus-group-real-name group) gnus-browse-current-method nil
 794                  (cons (current-buffer) 'browse))
 795           (error "Couldn't enter %s" group))
 796       (unless (gnus-group-read-group nil no-article group)
 797         (error "Couldn't enter %s" group)))))
 798
 799 (defun gnus-browse-select-group ()
 800   "Select the current group."
 801   (interactive)
 802   (gnus-browse-read-group 'no))
 803
 804 (defun gnus-browse-next-group (n)
 805   "Go to the next group."
 806   (interactive "p")
 807   (prog1
 808       (forward-line n)
 809     (gnus-group-position-point)))
 810
 811 (defun gnus-browse-prev-group (n)
 812   "Go to the next group."
 813   (interactive "p")
 814   (gnus-browse-next-group (- n)))
 815
 816 (defun gnus-browse-unsubscribe-current-group (arg)
 817   "(Un)subscribe to the next ARG groups."
 818   (interactive "p")
 819   (when (eobp)
 820     (error "No group at current line"))
 821   (let ((ward (if (< arg 0) -1 1))
 822         (arg (abs arg)))
 823     (while (and (> arg 0)
 824                 (not (eobp))
 825                 (gnus-browse-unsubscribe-group)
 826                 (zerop (gnus-browse-next-group ward)))
 827       (decf arg))
 828     (gnus-group-position-point)
 829     (when (/= 0 arg)
 830       (gnus-message 7 "No more newsgroups"))
 831     arg))
 832
 833 (defun gnus-browse-group-name ()
 834   (save-excursion
 835     (beginning-of-line)
 836     (let ((name (get-text-property (point) 'gnus-group)))
 837       (when (re-search-forward ": \\(.*\\)$" (gnus-point-at-eol) t)
 838         (gnus-group-prefixed-name
 839          (or name
 840              (match-string-no-properties 1))
 841          gnus-browse-current-method)))))
 842
 843 (defun gnus-browse-unsubscribe-group ()
 844   "Toggle subscription of the current group in the browse buffer."
 845   (let ((sub nil)
 846         (buffer-read-only nil)
 847         group)
 848     (save-excursion
 849       (beginning-of-line)
 850       ;; If this group it killed, then we want to subscribe it.
 851       (unless (eq (char-after) ? )
 852         (setq sub t))
 853       (setq group (gnus-browse-group-name))
 854       ;;;;
 855       ;;(when (and sub
 856       ;;                 (cadr (gnus-gethash group gnus-newsrc-hashtb)))
 857       ;;(error "Group already subscribed"))
 858       (if sub
 859           (progn
 860             ;; Make sure the group has been properly removed before we
 861             ;; subscribe to it.
 862             (gnus-kill-ephemeral-group group)
 863             (gnus-group-change-level
 864              (list t group gnus-level-default-subscribed
 865                    nil nil (if (gnus-server-equal
 866                                 gnus-browse-current-method "native")
 867                                nil
 868                              (gnus-method-simplify
 869                               gnus-browse-current-method)))
 870              gnus-level-default-subscribed (gnus-group-level group)
 871              (and (car (nth 1 gnus-newsrc-alist))
 872                   (gnus-gethash (car (nth 1 gnus-newsrc-alist))
 873                                 gnus-newsrc-hashtb))
 874              t)
 875             (delete-char 1)
 876             (insert ? ))
 877         (gnus-group-change-level
 878          group gnus-level-unsubscribed gnus-level-default-subscribed)
 879         (delete-char 1)
 880         (insert ?U)))
 881     t))
 882
 883 (defun gnus-browse-exit ()
 884   "Quit browsing and return to the group buffer."
 885   (interactive)
 886   (when (eq major-mode 'gnus-browse-mode)
 887     (kill-buffer (current-buffer)))
 888   ;; Insert the newly subscribed groups in the group buffer.
 889   (save-excursion
 890     (set-buffer gnus-group-buffer)
 891     (gnus-group-list-groups nil))
 892   (if gnus-browse-return-buffer
 893       (gnus-configure-windows 'server 'force)
 894     (gnus-configure-windows 'group 'force)))
 895
 896 (defun gnus-browse-describe-briefly ()
 897   "Give a one line description of the group mode commands."
 898   (interactive)
 899   (gnus-message 6
 900                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 901
 902 (defun gnus-server-regenerate-server ()
 903   "Issue a command to the server to regenerate all its data structures."
 904   (interactive)
 905   (let ((server (gnus-server-server-name)))
 906     (unless server
 907       (error "No server on the current line"))
 908     (condition-case ()
 909         (gnus-get-function (gnus-server-to-method server)
 910                            'request-regenerate)
 911       (error
 912         (error "This backend doesn't support regeneration")))
 913     (gnus-message 5 "Requesting regeneration of %s..." server)
 914     (unless (gnus-open-server server)
 915       (error "Couldn't open server"))
 916     (if (gnus-request-regenerate server)
 917         (gnus-message 5 "Requesting regeneration of %s...done" server)
 918       (gnus-message 5 "Couldn't regenerate %s" server))))
 919
 920 (provide 'gnus-srvr)
 921
 922 ;;; gnus-srvr.el ends here