cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31 (require 'gnus-start)
  32 (require 'gnus-spec)
  33 (require 'gnus-group)
  34 (require 'gnus-int)
  35 (require 'gnus-range)
  36
  37 (defcustom gnus-server-mode-hook nil
  38   "Hook run in `gnus-server-mode' buffers."
  39   :group 'gnus-server
  40   :type 'hook)
  41
  42 (defcustom gnus-server-exit-hook nil
  43   "Hook run when exiting the server buffer."
  44   :group 'gnus-server
  45   :type 'hook)
  46
  47 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a\n"
  48   "Format of server lines.
  49 It works along the same lines as a normal formatting string,
  50 with some simple extensions.
  51
  52 The following specs are understood:
  53
  54 %h back end
  55 %n name
  56 %w address
  57 %s status
  58 %a agent covered
  59
  60 General format specifiers can also be used.
  61 See Info node `(gnus)Formatting Variables'."
  62   :link '(custom-manual "(gnus)Formatting Variables")
  63   :group 'gnus-server-visual
  64   :type 'string)
  65
  66 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  67   "The format specification for the server mode line."
  68   :group 'gnus-server-visual
  69   :type 'string)
  70
  71 (defcustom gnus-server-browse-in-group-buffer nil
  72   "Whether server browsing should take place in the group buffer.
  73 If nil, a faster, but more primitive, buffer is used instead."
  74   :version "22.1"
  75   :group 'gnus-server-visual
  76   :type 'boolean)
  77
  78 ;;; Internal variables.
  79
  80 (defvar gnus-inserted-opened-servers nil)
  81
  82 (defvar gnus-server-line-format-alist
  83   `((?h gnus-tmp-how ?s)
  84     (?n gnus-tmp-name ?s)
  85     (?w gnus-tmp-where ?s)
  86     (?s gnus-tmp-status ?s)
  87     (?a gnus-tmp-agent ?s)))
  88
  89 (defvar gnus-server-mode-line-format-alist
  90   `((?S gnus-tmp-news-server ?s)
  91     (?M gnus-tmp-news-method ?s)
  92     (?u gnus-tmp-user-defined ?s)))
  93
  94 (defvar gnus-server-line-format-spec nil)
  95 (defvar gnus-server-mode-line-format-spec nil)
  96 (defvar gnus-server-killed-servers nil)
  97
  98 (defvar gnus-server-mode-map)
  99
 100 (defvar gnus-server-menu-hook nil
 101   "*Hook run after the creation of the server mode menu.")
 102
 103 (defun gnus-server-make-menu-bar ()
 104   (gnus-turn-off-edit-menu 'server)
 105   (unless (boundp 'gnus-server-server-menu)
 106     (easy-menu-define
 107      gnus-server-server-menu gnus-server-mode-map ""
 108      '("Server"
 109        ["Add..." gnus-server-add-server t]
 110        ["Browse" gnus-server-read-server t]
 111        ["Scan" gnus-server-scan-server t]
 112        ["List" gnus-server-list-servers t]
 113        ["Kill" gnus-server-kill-server t]
 114        ["Yank" gnus-server-yank-server t]
 115        ["Copy" gnus-server-copy-server t]
 116        ["Edit" gnus-server-edit-server t]
 117        ["Regenerate" gnus-server-regenerate-server t]
 118        ["Compact" gnus-server-compact-server t]
 119        ["Exit" gnus-server-exit t]))
 120
 121     (easy-menu-define
 122      gnus-server-connections-menu gnus-server-mode-map ""
 123      '("Connections"
 124        ["Open" gnus-server-open-server t]
 125        ["Close" gnus-server-close-server t]
 126        ["Offline" gnus-server-offline-server t]
 127        ["Deny" gnus-server-deny-server t]
 128        "---"
 129        ["Open All" gnus-server-open-all-servers t]
 130        ["Close All" gnus-server-close-all-servers t]
 131        ["Reset All" gnus-server-remove-denials t]))
 132
 133     (gnus-run-hooks 'gnus-server-menu-hook)))
 134
 135 (defvar gnus-server-mode-map nil)
 136 (put 'gnus-server-mode 'mode-class 'special)
 137
 138 (unless gnus-server-mode-map
 139   (setq gnus-server-mode-map (make-sparse-keymap))
 140   (suppress-keymap gnus-server-mode-map)
 141
 142   (gnus-define-keys gnus-server-mode-map
 143     " " gnus-server-read-server-in-server-buffer
 144     "\r" gnus-server-read-server
 145     gnus-mouse-2 gnus-server-pick-server
 146     "q" gnus-server-exit
 147     "l" gnus-server-list-servers
 148     "k" gnus-server-kill-server
 149     "y" gnus-server-yank-server
 150     "c" gnus-server-copy-server
 151     "a" gnus-server-add-server
 152     "e" gnus-server-edit-server
 153     "s" gnus-server-scan-server
 154
 155     "O" gnus-server-open-server
 156     "\M-o" gnus-server-open-all-servers
 157     "C" gnus-server-close-server
 158     "\M-c" gnus-server-close-all-servers
 159     "D" gnus-server-deny-server
 160     "L" gnus-server-offline-server
 161     "R" gnus-server-remove-denials
 162
 163     "n" next-line
 164     "p" previous-line
 165
 166     "g" gnus-server-regenerate-server
 167
 168     "z" gnus-server-compact-server
 169
 170     "\C-c\C-i" gnus-info-find-node
 171     "\C-c\C-b" gnus-bug))
 172
 173 (defface gnus-server-agent
 174   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 175     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 176     (t (:bold t)))
 177   "Face used for displaying AGENTIZED servers"
 178   :group 'gnus-server-visual)
 179 ;; backward-compatibility alias
 180 (put 'gnus-server-agent-face 'face-alias 'gnus-server-agent)
 181 (put 'gnus-server-agent-face 'obsolete-face "22.1")
 182
 183 (defface gnus-server-opened
 184   '((((class color) (background light)) (:foreground "Green3" :bold t))
 185     (((class color) (background dark)) (:foreground "Green1" :bold t))
 186     (t (:bold t)))
 187   "Face used for displaying OPENED servers"
 188   :group 'gnus-server-visual)
 189 ;; backward-compatibility alias
 190 (put 'gnus-server-opened-face 'face-alias 'gnus-server-opened)
 191 (put 'gnus-server-opened-face 'obsolete-face "22.1")
 192
 193 (defface gnus-server-closed
 194   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 195     (((class color) (background dark))
 196      (:foreground "LightBlue" :italic t))
 197     (t (:italic t)))
 198   "Face used for displaying CLOSED servers"
 199   :group 'gnus-server-visual)
 200 ;; backward-compatibility alias
 201 (put 'gnus-server-closed-face 'face-alias 'gnus-server-closed)
 202 (put 'gnus-server-closed-face 'obsolete-face "22.1")
 203
 204 (defface gnus-server-denied
 205   '((((class color) (background light)) (:foreground "Red" :bold t))
 206     (((class color) (background dark)) (:foreground "Pink" :bold t))
 207     (t (:inverse-video t :bold t)))
 208   "Face used for displaying DENIED servers"
 209   :group 'gnus-server-visual)
 210 ;; backward-compatibility alias
 211 (put 'gnus-server-denied-face 'face-alias 'gnus-server-denied)
 212 (put 'gnus-server-denied-face 'obsolete-face "22.1")
 213
 214 (defface gnus-server-offline
 215   '((((class color) (background light)) (:foreground "Orange" :bold t))
 216     (((class color) (background dark)) (:foreground "Yellow" :bold t))
 217     (t (:inverse-video t :bold t)))
 218   "Face used for displaying OFFLINE servers"
 219   :group 'gnus-server-visual)
 220 ;; backward-compatibility alias
 221 (put 'gnus-server-offline-face 'face-alias 'gnus-server-offline)
 222 (put 'gnus-server-offline-face 'obsolete-face "22.1")
 223
 224 (defvar gnus-server-font-lock-keywords
 225   '(("(\\(agent\\))" 1 'gnus-server-agent)
 226     ("(\\(opened\\))" 1 'gnus-server-opened)
 227     ("(\\(closed\\))" 1 'gnus-server-closed)
 228     ("(\\(offline\\))" 1 'gnus-server-offline)
 229     ("(\\(denied\\))" 1 'gnus-server-denied)))
 230
 231 (defun gnus-server-mode ()
 232   "Major mode for listing and editing servers.
 233
 234 All normal editing commands are switched off.
 235 \\<gnus-server-mode-map>
 236 For more in-depth information on this mode, read the manual
 237 \(`\\[gnus-info-find-node]').
 238
 239 The following commands are available:
 240
 241 \\{gnus-server-mode-map}"
 242   (interactive)
 243   (when (gnus-visual-p 'server-menu 'menu)
 244     (gnus-server-make-menu-bar))
 245   (kill-all-local-variables)
 246   (gnus-simplify-mode-line)
 247   (setq major-mode 'gnus-server-mode)
 248   (setq mode-name "Server")
 249   (gnus-set-default-directory)
 250   (setq mode-line-process nil)
 251   (use-local-map gnus-server-mode-map)
 252   (buffer-disable-undo)
 253   (setq truncate-lines t)
 254   (setq buffer-read-only t)
 255   (if (featurep 'xemacs)
 256       (put 'gnus-server-mode 'font-lock-defaults '(gnus-server-font-lock-keywords t))
 257     (set (make-local-variable 'font-lock-defaults)
 258          '(gnus-server-font-lock-keywords t)))
 259   (gnus-run-mode-hooks 'gnus-server-mode-hook))
 260
 261 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 262   (let* ((gnus-tmp-how (car method))
 263          (gnus-tmp-where (nth 1 method))
 264          (elem (assoc method gnus-opened-servers))
 265          (gnus-tmp-status
 266           (cond
 267            ((eq (nth 1 elem) 'denied) "(denied)")
 268            ((eq (nth 1 elem) 'offline) "(offline)")
 269            (t
 270             (condition-case nil
 271                 (if (or (gnus-server-opened method)
 272                         (eq (nth 1 elem) 'ok))
 273                     "(opened)"
 274                   "(closed)")
 275               ((error) "(error)")))))
 276          (gnus-tmp-agent (if (and gnus-agent
 277                                   (gnus-agent-method-p method))
 278                              " (agent)"
 279                            "")))
 280     (beginning-of-line)
 281     (gnus-add-text-properties
 282      (point)
 283      (prog1 (1+ (point))
 284        ;; Insert the text.
 285        (eval gnus-server-line-format-spec))
 286      (list 'gnus-server (intern gnus-tmp-name)
 287            'gnus-named-server (intern (gnus-method-to-server method t))))))
 288
 289 (defun gnus-enter-server-buffer ()
 290   "Set up the server buffer."
 291   (gnus-server-setup-buffer)
 292   (gnus-configure-windows 'server)
 293   ;; Usually `gnus-configure-windows' will finish with the
 294   ;; `gnus-server-buffer' selected as the current buffer, but not always (I
 295   ;; bumped into it when starting from a dedicated *Group* frame, and
 296   ;; gnus-configure-windows opened *Server* into its own dedicated frame).
 297   (with-current-buffer (get-buffer gnus-server-buffer)
 298     (gnus-server-prepare)))
 299
 300 (defun gnus-server-setup-buffer ()
 301   "Initialize the server buffer."
 302   (unless (get-buffer gnus-server-buffer)
 303     (with-current-buffer (gnus-get-buffer-create gnus-server-buffer)
 304       (gnus-server-mode)
 305       (when gnus-carpal
 306         (gnus-carpal-setup-buffer 'server)))))
 307
 308 (defun gnus-server-prepare ()
 309   (gnus-set-format 'server-mode)
 310   (gnus-set-format 'server t)
 311   (let ((alist gnus-server-alist)
 312         (buffer-read-only nil)
 313         done server op-ser)
 314     (erase-buffer)
 315     (setq gnus-inserted-opened-servers nil)
 316     ;; First we do the real list of servers.
 317     (while alist
 318       (unless (member (cdar alist) done)
 319         (push (cdar alist) done)
 320         (setq server (pop alist))
 321         (when (and server (car server) (cdr server))
 322           (gnus-server-insert-server-line (car server) (cdr server))))
 323       (when (member (cdar alist) done)
 324         (pop alist)))
 325     ;; Then we insert the list of servers that have been opened in
 326     ;; this session.
 327     (dolist (open gnus-opened-servers)
 328       (when (and (not (member (car open) done))
 329                  ;; Just ignore ephemeral servers.
 330                  (not (member (car open) gnus-ephemeral-servers)))
 331         (push (car open) done)
 332         (gnus-server-insert-server-line
 333          (setq op-ser (format "%s:%s" (caar open) (nth 1 (car open))))
 334          (car open))
 335         (push (list op-ser (car open)) gnus-inserted-opened-servers))))
 336   (goto-char (point-min))
 337   (gnus-server-position-point))
 338
 339 (defun gnus-server-server-name ()
 340   (let ((server (get-text-property (point-at-bol) 'gnus-server)))
 341     (and server (symbol-name server))))
 342
 343 (defun gnus-server-named-server ()
 344   "Return a server name that matches one of the names returned by
 345 `gnus-method-to-server'."
 346   (let ((server (get-text-property (point-at-bol) 'gnus-named-server)))
 347     (and server (symbol-name server))))
 348
 349 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 350
 351 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 352
 353 (defun gnus-server-update-server (server)
 354   (with-current-buffer gnus-server-buffer
 355     (let* ((buffer-read-only nil)
 356            (entry (assoc server gnus-server-alist))
 357            (oentry (assoc (gnus-server-to-method server)
 358                           gnus-opened-servers)))
 359       (when entry
 360         (gnus-dribble-enter
 361          (concat "(gnus-server-set-info \"" server "\" '"
 362                  (gnus-prin1-to-string (cdr entry)) ")\n")))
 363       (when (or entry oentry)
 364         ;; Buffer may be narrowed.
 365         (save-restriction
 366           (widen)
 367           (when (gnus-server-goto-server server)
 368             (gnus-delete-line))
 369           (if entry
 370               (gnus-server-insert-server-line (car entry) (cdr entry))
 371             (gnus-server-insert-server-line
 372              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 373              (car oentry)))
 374           (gnus-server-position-point))))))
 375
 376 (defun gnus-server-set-info (server info)
 377   ;; Enter a select method into the virtual server alist.
 378   (when (and server info)
 379     (gnus-dribble-enter
 380      (concat "(gnus-server-set-info \"" server "\" '"
 381              (gnus-prin1-to-string info) ")"))
 382     (let* ((server (nth 1 info))
 383            (entry (assoc server gnus-server-alist))
 384            (cached (assoc server gnus-server-method-cache)))
 385       (if cached
 386           (setq gnus-server-method-cache
 387                 (delq cached gnus-server-method-cache)))
 388       (if entry
 389           (progn
 390             ;; Remove the server from `gnus-opened-servers' since
 391             ;; it has never been opened with the new `info' yet.
 392             (gnus-opened-servers-remove (cdr entry))
 393             ;; Don't make a new Lisp object.
 394             (setcar (cdr entry) (car info))
 395             (setcdr (cdr entry) (cdr info)))
 396         (setq gnus-server-alist
 397               (nconc gnus-server-alist (list (cons server info))))))))
 398
 399 ;;; Interactive server functions.
 400
 401 (defun gnus-server-kill-server (server)
 402   "Kill the server on the current line."
 403   (interactive (list (gnus-server-server-name)))
 404   (unless (gnus-server-goto-server server)
 405     (if server (error "No such server: %s" server)
 406       (error "No server on the current line")))
 407   (unless (assoc server gnus-server-alist)
 408     (error "Read-only server %s" server))
 409   (gnus-dribble-touch)
 410   (let ((buffer-read-only nil))
 411     (gnus-delete-line))
 412   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 413   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 414                                 gnus-server-alist))
 415   (let ((groups (gnus-groups-from-server server)))
 416     (when (and groups
 417                (gnus-yes-or-no-p
 418                 (format "Kill all %s groups from this server? "
 419                         (length groups))))
 420       (dolist (group groups)
 421         (setq gnus-newsrc-alist
 422               (delq (assoc group gnus-newsrc-alist)
 423                     gnus-newsrc-alist))
 424         (when gnus-group-change-level-function
 425           (funcall gnus-group-change-level-function
 426                    group gnus-level-killed 3)))))
 427   (gnus-server-position-point))
 428
 429 (defun gnus-server-yank-server ()
 430   "Yank the previously killed server."
 431   (interactive)
 432   (unless gnus-server-killed-servers
 433     (error "No killed servers to be yanked"))
 434   (let ((alist gnus-server-alist)
 435         (server (gnus-server-server-name))
 436         (killed (car gnus-server-killed-servers)))
 437     (if (not server)
 438         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 439       (if (string= server (caar gnus-server-alist))
 440           (push killed gnus-server-alist)
 441         (while (and (cdr alist)
 442                     (not (string= server (caadr alist))))
 443           (setq alist (cdr alist)))
 444         (if alist
 445             (setcdr alist (cons killed (cdr alist)))
 446           (setq gnus-server-alist (list killed)))))
 447     (gnus-server-update-server (car killed))
 448     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 449     (gnus-server-position-point)))
 450
 451 (defun gnus-server-exit ()
 452   "Return to the group buffer."
 453   (interactive)
 454   (gnus-run-hooks 'gnus-server-exit-hook)
 455   (gnus-kill-buffer (current-buffer))
 456   (gnus-configure-windows 'group t))
 457
 458 (defun gnus-server-list-servers ()
 459   "List all available servers."
 460   (interactive)
 461   (let ((cur (gnus-server-server-name)))
 462     (gnus-server-prepare)
 463     (if cur (gnus-server-goto-server cur)
 464       (goto-char (point-max))
 465       (forward-line -1))
 466     (gnus-server-position-point)))
 467
 468 (defun gnus-server-set-status (method status)
 469   "Make METHOD have STATUS."
 470   (let ((entry (assoc method gnus-opened-servers)))
 471     (if entry
 472         (setcar (cdr entry) status)
 473       (push (list method status) gnus-opened-servers))))
 474
 475 (defun gnus-opened-servers-remove (method)
 476   "Remove METHOD from the list of opened servers."
 477   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 478                                   gnus-opened-servers)))
 479
 480 (defun gnus-server-open-server (server)
 481   "Force an open of SERVER."
 482   (interactive (list (gnus-server-server-name)))
 483   (let ((method (gnus-server-to-method server)))
 484     (unless method
 485       (error "No such server: %s" server))
 486     (gnus-server-set-status method 'ok)
 487     (prog1
 488         (or (gnus-open-server method)
 489             (progn (message "Couldn't open %s" server) nil))
 490       (gnus-server-update-server server)
 491       (gnus-server-position-point))))
 492
 493 (defun gnus-server-open-all-servers ()
 494   "Open all servers."
 495   (interactive)
 496   (dolist (server gnus-inserted-opened-servers)
 497     (gnus-server-open-server (car server))))
 498
 499 (defun gnus-server-close-server (server)
 500   "Close SERVER."
 501   (interactive (list (gnus-server-server-name)))
 502   (let ((method (gnus-server-to-method server)))
 503     (unless method
 504       (error "No such server: %s" server))
 505     (gnus-server-set-status method 'closed)
 506     (prog1
 507         (gnus-close-server method)
 508       (gnus-server-update-server server)
 509       (gnus-server-position-point))))
 510
 511 (defun gnus-server-offline-server (server)
 512   "Set SERVER to offline."
 513   (interactive (list (gnus-server-server-name)))
 514   (let ((method (gnus-server-to-method server)))
 515     (unless method
 516       (error "No such server: %s" server))
 517     (prog1
 518         (gnus-close-server method)
 519       (gnus-server-set-status method 'offline)
 520       (gnus-server-update-server server)
 521       (gnus-server-position-point))))
 522
 523 (defun gnus-server-close-all-servers ()
 524   "Close all servers."
 525   (interactive)
 526   (dolist (server gnus-inserted-opened-servers)
 527     (gnus-server-close-server (car server)))
 528   (dolist (server gnus-server-alist)
 529     (gnus-server-close-server (car server))))
 530
 531 (defun gnus-server-deny-server (server)
 532   "Make sure SERVER will never be attempted opened."
 533   (interactive (list (gnus-server-server-name)))
 534   (let ((method (gnus-server-to-method server)))
 535     (unless method
 536       (error "No such server: %s" server))
 537     (gnus-server-set-status method 'denied))
 538   (gnus-server-update-server server)
 539   (gnus-server-position-point)
 540   t)
 541
 542 (defun gnus-server-remove-denials ()
 543   "Make all denied servers into closed servers."
 544   (interactive)
 545   (dolist (server gnus-opened-servers)
 546     (when (eq (nth 1 server) 'denied)
 547       (setcar (nthcdr 1 server) 'closed)))
 548   (gnus-server-list-servers))
 549
 550 (defun gnus-server-copy-server (from to)
 551   "Copy a server definiton to a new name."
 552   (interactive
 553    (list
 554     (or (gnus-server-server-name)
 555         (error "No server on the current line"))
 556     (read-string "Copy to: ")))
 557   (unless from
 558     (error "No server on current line"))
 559   (unless (and to (not (string= to "")))
 560     (error "No name to copy to"))
 561   (when (assoc to gnus-server-alist)
 562     (error "%s already exists" to))
 563   (unless (gnus-server-to-method from)
 564     (error "%s: no such server" from))
 565   (let ((to-entry (cons from (gnus-copy-sequence
 566                               (gnus-server-to-method from)))))
 567     (setcar to-entry to)
 568     (setcar (nthcdr 2 to-entry) to)
 569     (push to-entry gnus-server-killed-servers)
 570     (gnus-server-yank-server)))
 571
 572 (defun gnus-server-add-server (how where)
 573   (interactive
 574    (list (intern (gnus-completing-read "Server method"
 575                                        (mapcar 'car gnus-valid-select-methods)
 576                                        t))
 577          (read-string "Server name: ")))
 578   (when (assq where gnus-server-alist)
 579     (error "Server with that name already defined"))
 580   (push (list where how where) gnus-server-killed-servers)
 581   (gnus-server-yank-server))
 582
 583 (defun gnus-server-goto-server (server)
 584   "Jump to a server line."
 585   (interactive
 586    (list (gnus-completing-read "Goto server" (mapcar 'car gnus-server-alist) t)))
 587   (let ((to (text-property-any (point-min) (point-max)
 588                                'gnus-server (intern server))))
 589     (when to
 590       (goto-char to)
 591       (gnus-server-position-point))))
 592
 593 (defun gnus-server-edit-server (server)
 594   "Edit the server on the current line."
 595   (interactive (list (gnus-server-server-name)))
 596   (unless server
 597     (error "No server on current line"))
 598   (unless (assoc server gnus-server-alist)
 599     (error "This server can't be edited"))
 600   (let ((info (cdr (assoc server gnus-server-alist))))
 601     (gnus-close-server info)
 602     (gnus-edit-form
 603      info "Editing the server."
 604      `(lambda (form)
 605         (gnus-server-set-info ,server form)
 606         (gnus-server-list-servers)
 607         (gnus-server-position-point))
 608      'edit-server)))
 609
 610 (defun gnus-server-scan-server (server)
 611   "Request a scan from the current server."
 612   (interactive (list (gnus-server-server-name)))
 613   (let ((method (gnus-server-to-method server)))
 614     (if (not (gnus-get-function method 'request-scan))
 615         (error "Server %s can't scan" (car method))
 616       (gnus-message 3 "Scanning %s..." server)
 617       (gnus-request-scan nil method)
 618       (gnus-message 3 "Scanning %s...done" server))))
 619
 620 (defun gnus-server-read-server-in-server-buffer (server)
 621   "Browse a server in server buffer."
 622   (interactive (list (gnus-server-server-name)))
 623   (let (gnus-server-browse-in-group-buffer)
 624     (gnus-server-read-server server)))
 625
 626 (defun gnus-server-read-server (server)
 627   "Browse a server."
 628   (interactive (list (gnus-server-server-name)))
 629   (let ((buf (current-buffer)))
 630     (prog1
 631         (gnus-browse-foreign-server server buf)
 632       (with-current-buffer buf
 633         (gnus-server-update-server (gnus-server-server-name))
 634         (gnus-server-position-point)))))
 635
 636 (defun gnus-server-pick-server (e)
 637   (interactive "e")
 638   (mouse-set-point e)
 639   (gnus-server-read-server (gnus-server-server-name)))
 640
 641 \f
 642 ;;;
 643 ;;; Browse Server Mode
 644 ;;;
 645
 646 (defvar gnus-browse-menu-hook nil
 647   "*Hook run after the creation of the browse mode menu.")
 648
 649 (defcustom gnus-browse-subscribe-newsgroup-method
 650   'gnus-subscribe-alphabetically
 651   "Function(s) called when subscribing groups in the Browse Server Buffer
 652 A few pre-made functions are supplied: `gnus-subscribe-randomly'
 653 inserts new groups at the beginning of the list of groups;
 654 `gnus-subscribe-alphabetically' inserts new groups in strict
 655 alphabetic order; `gnus-subscribe-hierarchically' inserts new groups
 656 in hierarchical newsgroup order; `gnus-subscribe-interactively' asks
 657 for your decision; `gnus-subscribe-killed' kills all new groups;
 658 `gnus-subscribe-zombies' will make all new groups into zombies;
 659 `gnus-subscribe-topics' will enter groups into the topics that
 660 claim them."
 661   :version "24.1"
 662   :group 'gnus-server
 663   :type '(radio (function-item gnus-subscribe-randomly)
 664                 (function-item gnus-subscribe-alphabetically)
 665                 (function-item gnus-subscribe-hierarchically)
 666                 (function-item gnus-subscribe-interactively)
 667                 (function-item gnus-subscribe-killed)
 668                 (function-item gnus-subscribe-zombies)
 669                 (function-item gnus-subscribe-topics)
 670                 function
 671                 (repeat function)))
 672
 673 (defvar gnus-browse-mode-hook nil)
 674 (defvar gnus-browse-mode-map nil)
 675 (put 'gnus-browse-mode 'mode-class 'special)
 676
 677 (unless gnus-browse-mode-map
 678   (setq gnus-browse-mode-map (make-keymap))
 679   (suppress-keymap gnus-browse-mode-map)
 680
 681   (gnus-define-keys
 682       gnus-browse-mode-map
 683     " " gnus-browse-read-group
 684     "=" gnus-browse-select-group
 685     "n" gnus-browse-next-group
 686     "p" gnus-browse-prev-group
 687     "\177" gnus-browse-prev-group
 688     [delete] gnus-browse-prev-group
 689     "N" gnus-browse-next-group
 690     "P" gnus-browse-prev-group
 691     "\M-n" gnus-browse-next-group
 692     "\M-p" gnus-browse-prev-group
 693     "\r" gnus-browse-select-group
 694     "u" gnus-browse-unsubscribe-current-group
 695     "l" gnus-browse-exit
 696     "L" gnus-browse-exit
 697     "q" gnus-browse-exit
 698     "Q" gnus-browse-exit
 699     "d" gnus-browse-describe-group
 700     "\C-c\C-c" gnus-browse-exit
 701     "?" gnus-browse-describe-briefly
 702
 703     "\C-c\C-i" gnus-info-find-node
 704     "\C-c\C-b" gnus-bug))
 705
 706 (defun gnus-browse-make-menu-bar ()
 707   (gnus-turn-off-edit-menu 'browse)
 708   (unless (boundp 'gnus-browse-menu)
 709     (easy-menu-define
 710      gnus-browse-menu gnus-browse-mode-map ""
 711      '("Browse"
 712        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 713        ["Read" gnus-browse-read-group t]
 714        ["Select" gnus-browse-select-group t]
 715        ["Describe" gnus-browse-describe-group t]
 716        ["Next" gnus-browse-next-group t]
 717        ["Prev" gnus-browse-prev-group t]
 718        ["Exit" gnus-browse-exit t]))
 719     (gnus-run-hooks 'gnus-browse-menu-hook)))
 720
 721 (defvar gnus-browse-current-method nil)
 722 (defvar gnus-browse-return-buffer nil)
 723
 724 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 725
 726 (defun gnus-browse-foreign-server (server &optional return-buffer)
 727   "Browse the server SERVER."
 728   (setq gnus-browse-current-method (gnus-server-to-method server))
 729   (setq gnus-browse-return-buffer return-buffer)
 730   (let* ((method gnus-browse-current-method)
 731          (orig-select-method gnus-select-method)
 732          (gnus-select-method method)
 733          groups group)
 734     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 735     (cond
 736      ((not (gnus-check-server method))
 737       (gnus-message
 738        1 "Unable to contact server %s: %s" (nth 1 method)
 739        (gnus-status-message method))
 740       nil)
 741      ((not
 742        (prog2
 743            (gnus-message 6 "Reading active file...")
 744            (gnus-request-list method)
 745          (gnus-message 6 "Reading active file...done")))
 746       (gnus-message
 747        1 "Couldn't request list: %s" (gnus-status-message method))
 748       nil)
 749      (t
 750       (with-current-buffer nntp-server-buffer
 751         (let ((cur (current-buffer)))
 752           (goto-char (point-min))
 753           (unless (string= gnus-ignored-newsgroups "")
 754             (delete-matching-lines gnus-ignored-newsgroups))
 755           ;; We treat NNTP as a special case to avoid problems with
 756           ;; garbage group names like `"foo' that appear in some badly
 757           ;; managed active files. -jh.
 758           (if (eq (car method) 'nntp)
 759               (while (not (eobp))
 760                 (ignore-errors
 761                   (push (cons
 762                          (mm-string-as-unibyte
 763                           (buffer-substring
 764                            (point)
 765                            (progn
 766                              (skip-chars-forward "^ \t")
 767                              (point))))
 768                          (let ((last (read cur)))
 769                            (cons (read cur) last)))
 770                         groups))
 771                 (forward-line))
 772             (while (not (eobp))
 773               (ignore-errors
 774                 (push (cons
 775                        (mm-string-as-unibyte
 776                         (if (eq (char-after) ?\")
 777                             (read cur)
 778                           (let ((p (point)) (name ""))
 779                             (skip-chars-forward "^ \t\\\\")
 780                             (setq name (buffer-substring p (point)))
 781                             (while (eq (char-after) ?\\)
 782                               (setq p (1+ (point)))
 783                               (forward-char 2)
 784                               (skip-chars-forward "^ \t\\\\")
 785                               (setq name (concat name (buffer-substring
 786                                                        p (point)))))
 787                             name)))
 788                        (let ((last (read cur)))
 789                          (cons (read cur) last)))
 790                       groups))
 791               (forward-line)))))
 792       (setq groups (sort groups
 793                          (lambda (l1 l2)
 794                            (string< (car l1) (car l2)))))
 795       (if gnus-server-browse-in-group-buffer
 796           (let* ((gnus-select-method orig-select-method)
 797                  (gnus-group-listed-groups
 798                   (mapcar (lambda (group)
 799                             (let ((name
 800                                    (gnus-group-prefixed-name
 801                                     (car group) method)))
 802                               (gnus-set-active name (cdr group))
 803                               name))
 804                           groups)))
 805             (gnus-configure-windows 'group)
 806             (funcall gnus-group-prepare-function
 807                      gnus-level-killed 'ignore 1 'ignore))
 808         (gnus-get-buffer-create gnus-browse-buffer)
 809         (when gnus-carpal
 810           (gnus-carpal-setup-buffer 'browse))
 811         (gnus-configure-windows 'browse)
 812         (buffer-disable-undo)
 813         (let ((buffer-read-only nil))
 814           (erase-buffer))
 815         (gnus-browse-mode)
 816         (setq mode-line-buffer-identification
 817               (list
 818                (format
 819                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 820         (let ((buffer-read-only nil)
 821               name
 822               (prefix (let ((gnus-select-method orig-select-method))
 823                         (gnus-group-prefixed-name "" method))))
 824           (while (setq group (pop groups))
 825             (gnus-add-text-properties
 826              (point)
 827              (prog1 (1+ (point))
 828                (insert
 829                 (format "%c%7d: %s\n"
 830                         (let ((level
 831                                (if (string= prefix "")
 832                                    (gnus-group-level (setq name (car group)))
 833                                  (gnus-group-level
 834                                   (concat prefix (setq name (car group)))))))
 835                           (cond
 836                            ((<= level gnus-level-subscribed) ? )
 837                            ((<= level gnus-level-unsubscribed) ?U)
 838                            ((= level gnus-level-zombie) ?Z)
 839                            (t ?K)))
 840                         (max 0 (- (1+ (cddr group)) (cadr group)))
 841                         ;; Don't decode if name is ASCII
 842                         (if (and (fboundp 'detect-coding-string)
 843                                  (eq (detect-coding-string name t) 'undecided))
 844                             name
 845                           (mm-decode-coding-string
 846                            name
 847                            (inline (gnus-group-name-charset method name)))))))
 848              (list 'gnus-group name)
 849              )))
 850         (switch-to-buffer (current-buffer)))
 851       (goto-char (point-min))
 852       (gnus-group-position-point)
 853       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 854       t))))
 855
 856 (defun gnus-browse-mode ()
 857   "Major mode for browsing a foreign server.
 858
 859 All normal editing commands are switched off.
 860
 861 \\<gnus-browse-mode-map>
 862 The only things you can do in this buffer is
 863
 864 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 865 The group will be inserted into the group buffer upon exit from this
 866 buffer.
 867
 868 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 869
 870 3) `\\[gnus-browse-exit]' to return to the group buffer."
 871   (interactive)
 872   (kill-all-local-variables)
 873   (when (gnus-visual-p 'browse-menu 'menu)
 874     (gnus-browse-make-menu-bar))
 875   (gnus-simplify-mode-line)
 876   (setq major-mode 'gnus-browse-mode)
 877   (setq mode-name "Browse Server")
 878   (setq mode-line-process nil)
 879   (use-local-map gnus-browse-mode-map)
 880   (buffer-disable-undo)
 881   (setq truncate-lines t)
 882   (gnus-set-default-directory)
 883   (setq buffer-read-only t)
 884   (gnus-run-mode-hooks 'gnus-browse-mode-hook))
 885
 886 (defun gnus-browse-read-group (&optional no-article number)
 887   "Enter the group at the current line.
 888 If NUMBER, fetch this number of articles."
 889   (interactive "P")
 890   (let ((group (gnus-browse-group-name)))
 891     (if (or (not (gnus-get-info group))
 892             (gnus-ephemeral-group-p group))
 893         (unless (gnus-group-read-ephemeral-group
 894                  group gnus-browse-current-method nil
 895                  (cons (current-buffer) 'browse)
 896                  nil nil nil number)
 897           (error "Couldn't enter %s" group))
 898       (unless (gnus-group-read-group nil no-article group)
 899         (error "Couldn't enter %s" group)))))
 900
 901 (defun gnus-browse-select-group (&optional number)
 902   "Select the current group.
 903 If NUMBER, fetch this number of articles."
 904   (interactive "P")
 905   (gnus-browse-read-group 'no number))
 906
 907 (defun gnus-browse-next-group (n)
 908   "Go to the next group."
 909   (interactive "p")
 910   (prog1
 911       (forward-line n)
 912     (gnus-group-position-point)))
 913
 914 (defun gnus-browse-prev-group (n)
 915   "Go to the next group."
 916   (interactive "p")
 917   (gnus-browse-next-group (- n)))
 918
 919 (defun gnus-browse-unsubscribe-current-group (arg)
 920   "(Un)subscribe to the next ARG groups.
 921 The variable `gnus-browse-subscribe-newsgroup-method' determines
 922 how new groups will be entered into the group buffer."
 923   (interactive "p")
 924   (when (eobp)
 925     (error "No group at current line"))
 926   (let ((ward (if (< arg 0) -1 1))
 927         (arg (abs arg)))
 928     (while (and (> arg 0)
 929                 (not (eobp))
 930                 (gnus-browse-unsubscribe-group)
 931                 (zerop (gnus-browse-next-group ward)))
 932       (decf arg))
 933     (gnus-group-position-point)
 934     (when (/= 0 arg)
 935       (gnus-message 7 "No more newsgroups"))
 936     arg))
 937
 938 (defun gnus-browse-group-name ()
 939   (save-excursion
 940     (beginning-of-line)
 941     (let ((name (get-text-property (point) 'gnus-group)))
 942       (when (re-search-forward ": \\(.*\\)$" (point-at-eol) t)
 943         (concat (gnus-method-to-server-name gnus-browse-current-method) ":"
 944                 (or name
 945                     (match-string-no-properties 1)))))))
 946
 947 (defun gnus-browse-describe-group (group)
 948   "Describe the current group."
 949   (interactive (list (gnus-browse-group-name)))
 950   (gnus-group-describe-group nil group))
 951
 952 (defun gnus-browse-unsubscribe-group ()
 953   "Toggle subscription of the current group in the browse buffer."
 954   (let ((sub nil)
 955         (buffer-read-only nil)
 956         group)
 957     (save-excursion
 958       (beginning-of-line)
 959       ;; If this group it killed, then we want to subscribe it.
 960       (unless (eq (char-after) ? )
 961         (setq sub t))
 962       (setq group (gnus-browse-group-name))
 963       (when (gnus-server-equal gnus-browse-current-method "native")
 964         (setq group (gnus-group-real-name group)))
 965       (if sub
 966           (progn
 967             ;; Make sure the group has been properly removed before we
 968             ;; subscribe to it.
 969             (if (gnus-ephemeral-group-p group)
 970                 (gnus-kill-ephemeral-group group))
 971             (let ((entry (gnus-group-entry group)))
 972               (if entry
 973                   ;; Just change the subscription level if it is an
 974                   ;; unsubscribed group.
 975                   (gnus-group-change-level entry
 976                                            gnus-level-default-subscribed)
 977                 ;; If it is a killed group or a zombie, feed it to the
 978                 ;; mechanism for new group subscription.
 979                 (gnus-call-subscribe-functions
 980                  gnus-browse-subscribe-newsgroup-method
 981                  group)))
 982             (delete-char 1)
 983             (insert (let ((lvl (gnus-group-level group)))
 984                       (cond
 985                        ((< lvl gnus-level-unsubscribed) ? )
 986                        ((< lvl gnus-level-zombie) ?U)
 987                        ((< lvl gnus-level-killed) ?Z)
 988                        (t ?K)))))
 989         (gnus-group-change-level
 990          group gnus-level-unsubscribed gnus-level-default-subscribed)
 991         (delete-char 1)
 992         (insert ?U)))
 993     t))
 994
 995 (defun gnus-browse-exit ()
 996   "Quit browsing and return to the group buffer."
 997   (interactive)
 998   (when (eq major-mode 'gnus-browse-mode)
 999     (gnus-kill-buffer (current-buffer)))
1000   ;; Insert the newly subscribed groups in the group buffer.
1001   (with-current-buffer gnus-group-buffer
1002     (gnus-group-list-groups nil))
1003   (if gnus-browse-return-buffer
1004       (gnus-configure-windows 'server 'force)
1005     (gnus-configure-windows 'group 'force)))
1006
1007 (defun gnus-browse-describe-briefly ()
1008   "Give a one line description of the group mode commands."
1009   (interactive)
1010   (gnus-message 6 "%s"
1011                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
1012
1013 (defun gnus-server-regenerate-server ()
1014   "Issue a command to the server to regenerate all its data structures."
1015   (interactive)
1016   (let ((server (gnus-server-server-name)))
1017     (unless server
1018       (error "No server on the current line"))
1019     (condition-case ()
1020         (gnus-get-function (gnus-server-to-method server)
1021                            'request-regenerate)
1022       (error
1023         (error "This back end doesn't support regeneration")))
1024     (gnus-message 5 "Requesting regeneration of %s..." server)
1025     (unless (gnus-open-server server)
1026       (error "Couldn't open server"))
1027     (if (gnus-request-regenerate server)
1028         (gnus-message 5 "Requesting regeneration of %s...done" server)
1029       (gnus-message 5 "Couldn't regenerate %s" server))))
1030
1031
1032 ;;;
1033 ;;; Server compaction. -- dvl
1034 ;;;
1035
1036 ;; #### FIXME: this function currently fails to update the Group buffer's
1037 ;; #### appearance.
1038 (defun gnus-server-compact-server ()
1039   "Issue a command to the server to compact all its groups.
1040
1041 Note: currently only implemented in nnml."
1042   (interactive)
1043   (let ((server (gnus-server-server-name)))
1044     (unless server
1045       (error "No server on the current line"))
1046     (condition-case ()
1047         (gnus-get-function (gnus-server-to-method server)
1048                            'request-compact)
1049       (error
1050        (error "This back end doesn't support compaction")))
1051     (gnus-message 5 "\
1052 Requesting compaction of %s... (this may take a long time)"
1053                   server)
1054     (unless (gnus-open-server server)
1055       (error "Couldn't open server"))
1056     (if (not (gnus-request-compact server))
1057         (gnus-message 5 "Couldn't compact %s" server)
1058       (gnus-message 5 "Requesting compaction of %s...done" server)
1059       ;; Invalidate the original article buffer which might be out of date.
1060       ;; #### NOTE: Yes, this might be a bit rude, but since compaction
1061       ;; #### will not happen very often, I think this is acceptable.
1062       (let ((original (get-buffer gnus-original-article-buffer)))
1063         (and original (gnus-kill-buffer original))))))
1064
1065 (provide 'gnus-srvr)
1066
1067 ;;; gnus-srvr.el ends here