cgit.sxemacs.org Git - gnus/blob - lisp/gnus-spec.el

   1 ;;; gnus-spec.el --- format spec functions for Gnus
   2 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32
  33 (defcustom gnus-use-correct-string-widths (featurep 'xemacs)
  34   "*If non-nil, use correct functions for dealing with wide characters."
  35   :group 'gnus-format
  36   :type 'boolean)
  37
  38 (defcustom gnus-make-format-preserve-properties (featurep 'xemacs)
  39   "*If non-nil, use a replacement `format' function which preserves
  40 text properties. This is only needed on XEmacs, as FSF Emacs does this anyway."
  41   :group 'gnus-format
  42   :type 'boolean)
  43
  44 ;;; Internal variables.
  45
  46 (defvar gnus-summary-mark-positions nil)
  47 (defvar gnus-group-mark-positions nil)
  48 (defvar gnus-group-indentation "")
  49
  50 ;; Format specs.  The chunks below are the machine-generated forms
  51 ;; that are to be evaled as the result of the default format strings.
  52 ;; We write them in here to get them byte-compiled.  That way the
  53 ;; default actions will be quite fast, while still retaining the full
  54 ;; flexibility of the user-defined format specs.
  55
  56 ;; First we have lots of dummy defvars to let the compiler know these
  57 ;; are really dynamic variables.
  58
  59 (defvar gnus-tmp-unread)
  60 (defvar gnus-tmp-replied)
  61 (defvar gnus-tmp-score-char)
  62 (defvar gnus-tmp-indentation)
  63 (defvar gnus-tmp-opening-bracket)
  64 (defvar gnus-tmp-lines)
  65 (defvar gnus-tmp-name)
  66 (defvar gnus-tmp-closing-bracket)
  67 (defvar gnus-tmp-subject-or-nil)
  68 (defvar gnus-tmp-subject)
  69 (defvar gnus-tmp-marked)
  70 (defvar gnus-tmp-marked-mark)
  71 (defvar gnus-tmp-subscribed)
  72 (defvar gnus-tmp-process-marked)
  73 (defvar gnus-tmp-number-of-unread)
  74 (defvar gnus-tmp-group-name)
  75 (defvar gnus-tmp-group)
  76 (defvar gnus-tmp-article-number)
  77 (defvar gnus-tmp-unread-and-unselected)
  78 (defvar gnus-tmp-news-method)
  79 (defvar gnus-tmp-news-server)
  80 (defvar gnus-tmp-article-number)
  81 (defvar gnus-mouse-face)
  82 (defvar gnus-mouse-face-prop)
  83 (defvar gnus-tmp-header)
  84 (defvar gnus-tmp-from)
  85
  86 (defun gnus-summary-line-format-spec ()
  87   (insert gnus-tmp-unread gnus-tmp-replied
  88           gnus-tmp-score-char gnus-tmp-indentation)
  89   (gnus-put-text-property
  90    (point)
  91    (progn
  92      (insert
  93       (format "%c%4s: %-23s%c" gnus-tmp-opening-bracket gnus-tmp-lines
  94               (let ((val
  95                      (inline
  96                        (gnus-summary-from-or-to-or-newsgroups
  97                         gnus-tmp-header gnus-tmp-from))))
  98                 (if (> (length val) 23)
  99                     (substring val 0 23)
 100                   val))
 101               gnus-tmp-closing-bracket))
 102      (point))
 103    gnus-mouse-face-prop gnus-mouse-face)
 104   (insert " " gnus-tmp-subject-or-nil "\n"))
 105
 106 (defvar gnus-summary-line-format-spec
 107   (gnus-byte-code 'gnus-summary-line-format-spec))
 108
 109 (defun gnus-summary-dummy-line-format-spec ()
 110   (insert "*  ")
 111   (gnus-put-text-property
 112    (point)
 113    (progn
 114      (insert ":                          :")
 115      (point))
 116    gnus-mouse-face-prop gnus-mouse-face)
 117   (insert " " gnus-tmp-subject "\n"))
 118
 119 (defvar gnus-summary-dummy-line-format-spec
 120   (gnus-byte-code 'gnus-summary-dummy-line-format-spec))
 121
 122 (defun gnus-group-line-format-spec ()
 123   (insert gnus-tmp-marked-mark gnus-tmp-subscribed
 124           gnus-tmp-process-marked
 125           gnus-group-indentation
 126           (format "%5s: " gnus-tmp-number-of-unread))
 127   (gnus-put-text-property
 128    (point)
 129    (progn
 130      (insert gnus-tmp-group "\n")
 131      (1- (point)))
 132    gnus-mouse-face-prop gnus-mouse-face))
 133 (defvar gnus-group-line-format-spec
 134   (gnus-byte-code 'gnus-group-line-format-spec))
 135
 136 (defvar gnus-format-specs
 137   `((version . ,emacs-version)
 138     (gnus-version . ,(gnus-continuum-version))
 139     (group "%M\%S\%p\%P\%5y: %(%g%)\n" ,gnus-group-line-format-spec)
 140     (summary-dummy "*  %(:                          :%) %S\n"
 141                    ,gnus-summary-dummy-line-format-spec)
 142     (summary "%U%R%z%I%(%[%4L: %-23,23f%]%) %s\n"
 143              ,gnus-summary-line-format-spec))
 144   "Alist of format specs.")
 145
 146 (defvar gnus-default-format-specs gnus-format-specs)
 147
 148 (defvar gnus-article-mode-line-format-spec nil)
 149 (defvar gnus-summary-mode-line-format-spec nil)
 150 (defvar gnus-group-mode-line-format-spec nil)
 151
 152 ;;; Phew.  All that gruft is over with, fortunately.
 153
 154 ;;;###autoload
 155 (defun gnus-update-format (var)
 156   "Update the format specification near point."
 157   (interactive
 158    (list
 159     (save-excursion
 160       (eval-defun nil)
 161       ;; Find the end of the current word.
 162       (re-search-forward "[ \t\n]" nil t)
 163       ;; Search backward.
 164       (when (re-search-backward "\\(gnus-[-a-z]+-line-format\\)" nil t)
 165         (match-string 1)))))
 166   (let* ((type (intern (progn (string-match "gnus-\\([-a-z]+\\)-line" var)
 167                               (match-string 1 var))))
 168          (entry (assq type gnus-format-specs))
 169          value spec)
 170     (when entry
 171       (setq gnus-format-specs (delq entry gnus-format-specs)))
 172     (set
 173      (intern (format "%s-spec" var))
 174      (gnus-parse-format (setq value (symbol-value (intern var)))
 175                         (symbol-value (intern (format "%s-alist" var)))
 176                         (not (string-match "mode" var))))
 177     (setq spec (symbol-value (intern (format "%s-spec" var))))
 178     (push (list type value spec) gnus-format-specs)
 179
 180     (pop-to-buffer "*Gnus Format*")
 181     (erase-buffer)
 182     (lisp-interaction-mode)
 183     (insert (gnus-pp-to-string spec))))
 184
 185 (defun gnus-update-format-specifications (&optional force &rest types)
 186   "Update all (necessary) format specifications."
 187   ;; Make the indentation array.
 188   ;; See whether all the stored info needs to be flushed.
 189   (when (or force
 190             (not gnus-newsrc-file-version)
 191             (not (equal (gnus-continuum-version)
 192                         (gnus-continuum-version gnus-newsrc-file-version)))
 193             (not (equal emacs-version
 194                         (cdr (assq 'version gnus-format-specs)))))
 195     (setq gnus-format-specs nil))
 196   ;; Flush the group format spec cache if there's the grouplens stuff.
 197   (let ((spec (assq 'group gnus-format-specs)))
 198     (when (and (memq 'group types)
 199                (string-match " gnus-tmp-grouplens[ )]"
 200                              (gnus-prin1-to-string (cdr spec))))
 201       (setq gnus-format-specs (delq spec gnus-format-specs))))
 202
 203   ;; Go through all the formats and see whether they need updating.
 204   (let (new-format entry type val)
 205     (while (setq type (pop types))
 206       ;; Jump to the proper buffer to find out the value of the
 207       ;; variable, if possible.  (It may be buffer-local.)
 208       (save-excursion
 209         (let ((buffer (intern (format "gnus-%s-buffer" type)))
 210               val)
 211           (when (and (boundp buffer)
 212                      (setq val (symbol-value buffer))
 213                      (gnus-buffer-exists-p val))
 214             (set-buffer val))
 215           (setq new-format (symbol-value
 216                             (intern (format "gnus-%s-line-format" type)))))
 217         (setq entry (cdr (assq type gnus-format-specs)))
 218         (if (and (car entry)
 219                  (equal (car entry) new-format))
 220             ;; Use the old format.
 221             (set (intern (format "gnus-%s-line-format-spec" type))
 222                  (cadr entry))
 223           ;; This is a new format.
 224           (setq val
 225                 (if (not (stringp new-format))
 226                     ;; This is a function call or something.
 227                     new-format
 228                   ;; This is a "real" format.
 229                   (gnus-parse-format
 230                    new-format
 231                    (symbol-value
 232                     (intern (format "gnus-%s-line-format-alist" type)))
 233                    (not (string-match "mode$" (symbol-name type))))))
 234           ;; Enter the new format spec into the list.
 235           (if entry
 236               (progn
 237                 (setcar (cdr entry) val)
 238                 (setcar entry new-format))
 239             (push (list type new-format val) gnus-format-specs))
 240           (set (intern (format "gnus-%s-line-format-spec" type)) val)))))
 241
 242   (unless (assq 'version gnus-format-specs)
 243     (push (cons 'version emacs-version) gnus-format-specs)))
 244
 245 (defvar gnus-mouse-face-0 'highlight)
 246 (defvar gnus-mouse-face-1 'highlight)
 247 (defvar gnus-mouse-face-2 'highlight)
 248 (defvar gnus-mouse-face-3 'highlight)
 249 (defvar gnus-mouse-face-4 'highlight)
 250
 251 (defun gnus-mouse-face-function (form type)
 252   `(gnus-put-text-property
 253     (point) (progn ,@form (point))
 254     gnus-mouse-face-prop
 255     ,(if (equal type 0)
 256          'gnus-mouse-face
 257        `(quote ,(symbol-value (intern (format "gnus-mouse-face-%d" type)))))))
 258
 259 (defvar gnus-face-0 'bold)
 260 (defvar gnus-face-1 'italic)
 261 (defvar gnus-face-2 'bold-italic)
 262 (defvar gnus-face-3 'bold)
 263 (defvar gnus-face-4 'bold)
 264
 265 (defun gnus-face-face-function (form type)
 266   `(gnus-add-text-properties
 267     (point) (progn ,@form (point))
 268     '(gnus-face t face ,(symbol-value (intern (format "gnus-face-%d" type))))))
 269
 270 (defun gnus-balloon-face-function (form type)
 271   `(gnus-put-text-property
 272     (point) (progn ,@form (point))
 273     ,(if (fboundp 'balloon-help-mode)
 274          ''balloon-help
 275        ''help-echo)
 276     ,(intern (format "gnus-balloon-face-%d" type))))
 277
 278 (defun gnus-spec-tab (column)
 279   (if (> column 0)
 280       `(insert (make-string (max (- ,column (current-column)) 0) ? ))
 281     (let ((column (abs column)))
 282       (if gnus-use-correct-string-widths
 283           `(progn
 284              (if (> (current-column) ,column)
 285                  (while (progn
 286                           (delete-backward-char 1)
 287                           (> (current-column) ,column))))
 288              (insert (make-string (max (- ,column (current-column)) 0) ? )))
 289         `(progn
 290            (if (> (current-column) ,column)
 291                (delete-region (point)
 292                               (- (point) (- (current-column) ,column)))
 293              (insert (make-string (max (- ,column (current-column)) 0)
 294                                   ? ))))))))
 295
 296 (defun gnus-correct-length (string)
 297   "Return the correct width of STRING."
 298   (let ((length 0))
 299     (mapcar (lambda (char) (incf length (char-width char))) string)
 300     length))
 301
 302 (defun gnus-correct-substring (string start &optional end)
 303   (let ((wstart 0)
 304         (wend 0)
 305         (wseek 0)
 306         (seek 0)
 307         (length (length string))
 308         (string (concat string "\0")))
 309     ;; Find the start position.
 310     (while (and (< seek length)
 311                 (< wseek start))
 312       (incf wseek (char-width (aref string seek)))
 313       (incf seek))
 314     (setq wstart seek)
 315     ;; Find the end position.
 316     (while (and (<= seek length)
 317                 (or (not end)
 318                     (<= wseek end)))
 319       (incf wseek (char-width (aref string seek)))
 320       (incf seek))
 321     (setq wend seek)
 322     (substring string wstart (1- wend))))
 323
 324 (defun gnus-string-width-function ()
 325   (cond
 326    (gnus-use-correct-string-widths
 327     'gnus-correct-length)
 328    ((fboundp 'string-width)
 329     'string-width)
 330    (t
 331     'length)))
 332
 333 (defun gnus-substring-function ()
 334   (cond
 335    (gnus-use-correct-string-widths
 336     'gnus-correct-substring)
 337    ((fboundp 'string-width)
 338     'gnus-correct-substring)
 339    (t
 340     'substring)))
 341
 342 (defun gnus-tilde-max-form (el max-width)
 343   "Return a form that limits EL to MAX-WIDTH."
 344   (let ((max (abs max-width))
 345         (length-fun (gnus-string-width-function))
 346         (substring-fun (gnus-substring-function)))
 347     (if (symbolp el)
 348         `(if (> (,length-fun ,el) ,max)
 349              ,(if (< max-width 0)
 350                   `(,substring-fun ,el (- (,length-fun ,el) ,max))
 351                 `(,substring-fun ,el 0 ,max))
 352            ,el)
 353       `(let ((val (eval ,el)))
 354          (if (> (,length-fun val) ,max)
 355              ,(if (< max-width 0)
 356                   `(,substring-fun val (- (,length-fun val) ,max))
 357                 `(,substring-fun val 0 ,max))
 358            val)))))
 359
 360 (defun gnus-tilde-cut-form (el cut-width)
 361   "Return a form that cuts CUT-WIDTH off of EL."
 362   (let ((cut (abs cut-width))
 363         (length-fun (gnus-string-width-function))
 364         (substring-fun (gnus-substring-function)))
 365     (if (symbolp el)
 366         `(if (> (,length-fun ,el) ,cut)
 367              ,(if (< cut-width 0)
 368                   `(,substring-fun ,el 0 (- (,length-fun ,el) ,cut))
 369                 `(,substring-fun ,el ,cut))
 370            ,el)
 371       `(let ((val (eval ,el)))
 372          (if (> (,length-fun val) ,cut)
 373              ,(if (< cut-width 0)
 374                   `(,substring-fun val 0 (- (,length-fun val) ,cut))
 375                 `(,substring-fun val ,cut))
 376            val)))))
 377
 378 (defun gnus-tilde-ignore-form (el ignore-value)
 379   "Return a form that is blank when EL is IGNORE-VALUE."
 380   (if (symbolp el)
 381       `(if (equal ,el ,ignore-value)
 382            "" ,el)
 383     `(let ((val (eval ,el)))
 384        (if (equal val ,ignore-value)
 385            "" val))))
 386
 387 (defun gnus-pad-form (el pad-width)
 388   "Return a form that pads EL to PAD-WIDTH accounting for multi-column
 389 characters correctly. This is because `format' may pad to columns or to
 390 characters when given a pad value."
 391   (let ((pad (abs pad-width))
 392         (side (< 0 pad-width))
 393         (length-fun (gnus-string-width-function)))
 394     (if (symbolp el)
 395         `(let ((need (- ,pad (,length-fun ,el))))
 396            (if (> need 0)
 397                (concat ,(when side '(make-string need ?\ ))
 398                        ,el
 399                        ,(when (not side) '(make-string need ?\ )))
 400              ,el))
 401       `(let* ((val (eval ,el))
 402               (need (- ,pad (,length-fun val))))
 403          (if (> need 0)
 404              (concat ,(when side '(make-string need ?\ ))
 405                      val
 406                      ,(when (not side) '(make-string need ?\ )))
 407            val)))))
 408
 409 (defun gnus-parse-format (format spec-alist &optional insert)
 410   ;; This function parses the FORMAT string with the help of the
 411   ;; SPEC-ALIST and returns a list that can be eval'ed to return the
 412   ;; string.  If the FORMAT string contains the specifiers %( and %)
 413   ;; the text between them will have the mouse-face text property.
 414   ;; If the FORMAT string contains the specifiers %[ and %], the text between
 415   ;; them will have the balloon-help text property.
 416   (let ((case-fold-search nil))
 417     (if (string-match
 418          "\\`\\(.*\\)%[0-9]?[{(«]\\(.*\\)%[0-9]?[»})]\\(.*\n?\\)\\'\\|%[-0-9]*=\\|%[-0-9]*\\*"
 419          format)
 420         (gnus-parse-complex-format format spec-alist)
 421       ;; This is a simple format.
 422       (gnus-parse-simple-format format spec-alist insert))))
 423
 424 (defun gnus-parse-complex-format (format spec-alist)
 425   (let ((cursor-spec nil))
 426     (save-excursion
 427       (gnus-set-work-buffer)
 428       (insert format)
 429       (goto-char (point-min))
 430       (while (re-search-forward "\"" nil t)
 431         (replace-match "\\\"" nil t))
 432       (goto-char (point-min))
 433       (insert "(\"")
 434       ;; Convert all font specs into font spec lists.
 435       (while (re-search-forward "%\\([0-9]+\\)?\\([«»{}()]\\)" nil t)
 436         (let ((number (if (match-beginning 1)
 437                           (match-string 1) "0"))
 438               (delim (aref (match-string 2) 0)))
 439           (if (or (= delim ?\()
 440                   (= delim ?\{)
 441                   (= delim ?\«))
 442               (replace-match (concat "\"("
 443                                      (cond ((= delim ?\() "mouse")
 444                                            ((= delim ?\{) "face")
 445                                            (t "balloon"))
 446                                      " " number " \"")
 447                              t t)
 448             (replace-match "\")\""))))
 449       (goto-char (point-max))
 450       (insert "\")")
 451       ;; Convert point position commands.
 452       (goto-char (point-min))
 453       (let ((case-fold-search nil))
 454         (while (re-search-forward "%\\([-0-9]+\\)?\\*" nil t)
 455           (replace-match "\"(point)\"" t t)
 456           (setq cursor-spec t)))
 457       ;; Convert TAB commands.
 458       (goto-char (point-min))
 459       (while (re-search-forward "%\\([-0-9]+\\)=" nil t)
 460         (replace-match (format "\"(tab %s)\"" (match-string 1)) t t))
 461       ;; Convert the buffer into the spec.
 462       (goto-char (point-min))
 463       (let ((form (read (current-buffer))))
 464         (if cursor-spec
 465             `(let (gnus-position)
 466                ,@(gnus-complex-form-to-spec form spec-alist)
 467                (if gnus-position
 468                    (gnus-put-text-property gnus-position (1+ gnus-position)
 469                                            'gnus-position t)))
 470           `(progn
 471              ,@(gnus-complex-form-to-spec form spec-alist)))))))
 472
 473 (defun gnus-complex-form-to-spec (form spec-alist)
 474   (delq nil
 475         (mapcar
 476          (lambda (sform)
 477            (cond
 478             ((stringp sform)
 479              (gnus-parse-simple-format sform spec-alist t))
 480             ((eq (car sform) 'point)
 481              '(setq gnus-position (point)))
 482             ((eq (car sform) 'tab)
 483              (gnus-spec-tab (cadr sform)))
 484             (t
 485              (funcall (intern (format "gnus-%s-face-function" (car sform)))
 486                       (gnus-complex-form-to-spec (cddr sform) spec-alist)
 487                       (nth 1 sform)))))
 488          form)))
 489
 490
 491 (defun gnus-xmas-format (fstring &rest args)
 492   "A version of `format' which preserves text properties.
 493
 494 Required for XEmacs, where the built in `format' function strips all text
 495 properties from both the format string and any inserted strings.
 496
 497 Only supports the format sequence %s, and %% for inserting
 498 literal % characters. A pad width and an optional - (to right pad)
 499 are supported for %s."
 500   (let ((re "%%\\|%\\(-\\)?\\([1-9][0-9]*\\)?s")
 501         (n (length args)))
 502     (with-temp-buffer
 503       (insert fstring)
 504       (goto-char (point-min))
 505       (while (re-search-forward re nil t)
 506         (goto-char (match-end 0))
 507         (cond
 508          ((string= (match-string 0) "%%")
 509           (delete-char -1))
 510          (t
 511           (if (null args)
 512               (error 'wrong-number-of-arguments #'my-format n fstring))
 513           (let* ((minlen (string-to-int (or (match-string 2) "")))
 514                  (arg (car args))
 515                  (str (if (stringp arg) arg (format "%s" arg)))
 516                  (lpad (null (match-string 1)))
 517                  (padlen (max 0 (- minlen (length str)))))
 518             (replace-match "")
 519             (if lpad (insert-char ?\  padlen))
 520             (insert str)
 521             (unless lpad (insert-char ?\  padlen))
 522             (setq args (cdr args))))))
 523       (buffer-string))))
 524
 525 (defun gnus-parse-simple-format (format spec-alist &optional insert)
 526   ;; This function parses the FORMAT string with the help of the
 527   ;; SPEC-ALIST and returns a list that can be eval'ed to return a
 528   ;; string.
 529   (let ((max-width 0)
 530         spec flist fstring elem result dontinsert user-defined
 531         type value pad-width spec-beg cut-width ignore-value
 532         tilde-form tilde elem-type extended-spec)
 533     (save-excursion
 534       (gnus-set-work-buffer)
 535       (insert format)
 536       (goto-char (point-min))
 537       (while (re-search-forward "%" nil t)
 538         (setq user-defined nil
 539               spec-beg nil
 540               pad-width nil
 541               max-width nil
 542               cut-width nil
 543               ignore-value nil
 544               tilde-form nil
 545               extended-spec nil)
 546         (setq spec-beg (1- (point)))
 547
 548         ;; Parse this spec fully.
 549         (while
 550             (cond
 551              ((looking-at "\\([-.0-9]+\\)\\(,[-0-9]+\\)?")
 552               (setq pad-width (string-to-number (match-string 1)))
 553               (when (match-beginning 2)
 554                 (setq max-width (string-to-number (buffer-substring
 555                                                    (1+ (match-beginning 2))
 556                                                    (match-end 2)))))
 557               (goto-char (match-end 0)))
 558              ((looking-at "~")
 559               (forward-char 1)
 560               (setq tilde (read (current-buffer))
 561                     type (car tilde)
 562                     value (cadr tilde))
 563               (cond
 564                ((memq type '(pad pad-left))
 565                 (setq pad-width value))
 566                ((eq type 'pad-right)
 567                 (setq pad-width (- value)))
 568                ((memq type '(max-right max))
 569                 (setq max-width value))
 570                ((eq type 'max-left)
 571                 (setq max-width (- value)))
 572                ((memq type '(cut cut-left))
 573                 (setq cut-width value))
 574                ((eq type 'cut-right)
 575                 (setq cut-width (- value)))
 576                ((eq type 'ignore)
 577                 (setq ignore-value
 578                       (if (stringp value) value (format "%s" value))))
 579                ((eq type 'form)
 580                 (setq tilde-form value))
 581                (t
 582                 (error "Unknown tilde type: %s" tilde)))
 583               t)
 584              (t
 585               nil)))
 586         (cond
 587          ;; User-defined spec -- find the spec name.
 588          ((eq (setq spec (char-after)) ?u)
 589           (forward-char 1)
 590           (when (and (eq (setq user-defined (char-after)) ?&)
 591                      (looking-at "&\\([^;]+\\);"))
 592             (setq user-defined (match-string 1))
 593             (goto-char (match-end 1))))
 594          ;; extended spec
 595          ((and (eq spec ?&) (looking-at "&\\([^;]+\\);"))
 596           (setq extended-spec (intern (match-string 1)))
 597           (goto-char (match-end 1))))
 598         (forward-char 1)
 599         (delete-region spec-beg (point))
 600
 601         ;; Now we have all the relevant data on this spec, so
 602         ;; we start doing stuff.
 603         (insert "%")
 604         (if (eq spec ?%)
 605             ;; "%%" just results in a "%".
 606             (insert "%")
 607           (cond
 608            ;; Do tilde forms.
 609            ((eq spec ?@)
 610             (setq elem (list tilde-form ?s)))
 611            ;; Treat user defined format specifiers specially.
 612            (user-defined
 613             (setq elem
 614                   (list
 615                    (list (intern (format
 616                                   (if (stringp user-defined)
 617                                       "gnus-user-format-function-%s"
 618                                     "gnus-user-format-function-%c")
 619                                   user-defined))
 620                          'gnus-tmp-header)
 621                    ?s)))
 622            ;; Find the specification from `spec-alist'.
 623            ((setq elem (cdr (assq (or extended-spec spec) spec-alist))))
 624            ;; We used to use "%l" for displaying the grouplens score.
 625            ((eq spec ?l)
 626             (setq elem '("" ?s)))
 627            (t
 628             (setq elem '("*" ?s))))
 629           (setq elem-type (cadr elem))
 630           ;; Insert the new format elements.
 631           (when (and pad-width
 632                      (not (and (featurep 'xemacs)
 633                                gnus-use-correct-string-widths)))
 634             (insert (number-to-string pad-width)))
 635           ;; Create the form to be evaled.
 636           (if (or max-width cut-width ignore-value
 637                   (and (featurep 'xemacs)
 638                        gnus-use-correct-string-widths))
 639               (progn
 640                 (insert ?s)
 641                 (let ((el (car elem)))
 642                   (cond ((= (cadr elem) ?c)
 643                          (setq el (list 'char-to-string el)))
 644                         ((= (cadr elem) ?d)
 645                          (setq el (list 'int-to-string el))))
 646                   (when ignore-value
 647                     (setq el (gnus-tilde-ignore-form el ignore-value)))
 648                   (when cut-width
 649                     (setq el (gnus-tilde-cut-form el cut-width)))
 650                   (when max-width
 651                     (setq el (gnus-tilde-max-form el max-width)))
 652                   (when pad-width
 653                     (setq el (gnus-pad-form el pad-width)))
 654                   (push el flist)))
 655             (insert elem-type)
 656             (push (car elem) flist))))
 657       (setq fstring (buffer-substring-no-properties (point-min) (point-max))))
 658
 659     ;; Do some postprocessing to increase efficiency.
 660     (setq
 661      result
 662      (cond
 663       ;; Emptiness.
 664       ((string= fstring "")
 665        nil)
 666       ;; Not a format string.
 667       ((not (string-match "%" fstring))
 668        (list fstring))
 669       ;; A format string with just a single string spec.
 670       ((string= fstring "%s")
 671        (list (car flist)))
 672       ;; A single character.
 673       ((string= fstring "%c")
 674        (list (car flist)))
 675       ;; A single number.
 676       ((string= fstring "%d")
 677        (setq dontinsert t)
 678        (if insert
 679            (list `(princ ,(car flist)))
 680          (list `(int-to-string ,(car flist)))))
 681       ;; Just lots of chars and strings.
 682       ((string-match "\\`\\(%[cs]\\)+\\'" fstring)
 683        (nreverse flist))
 684       ;; A single string spec at the beginning of the spec.
 685       ((string-match "\\`%[sc][^%]+\\'" fstring)
 686        (list (car flist) (substring fstring 2)))
 687       ;; A single string spec in the middle of the spec.
 688       ((string-match "\\`\\([^%]+\\)%[sc]\\([^%]+\\)\\'" fstring)
 689        (list (match-string 1 fstring) (car flist) (match-string 2 fstring)))
 690       ;; A single string spec in the end of the spec.
 691       ((string-match "\\`\\([^%]+\\)%[sc]\\'" fstring)
 692        (list (match-string 1 fstring) (car flist)))
 693       ;; Only string (and %) specs (XEmacs only!)
 694       ((and (featurep 'xemacs)
 695             gnus-make-format-preserve-properties
 696             (string-match
 697              "\\`\\([^%]*\\(%%\\|%-?\\([1-9][0-9]*\\)?s\\)\\)*[^%]*\\'"
 698              fstring))
 699        (list (cons 'gnus-xmas-format (cons fstring (nreverse flist)))))
 700       ;; A more complex spec.
 701       (t
 702        (list (cons 'format (cons fstring (nreverse flist)))))))
 703
 704     (if insert
 705         (when result
 706           (if dontinsert
 707               result
 708             (cons 'insert result)))
 709       (cond ((stringp result)
 710              result)
 711             ((consp result)
 712              (cons 'concat result))
 713             (t "")))))
 714
 715 (defun gnus-eval-format (format &optional alist props)
 716   "Eval the format variable FORMAT, using ALIST.
 717 If PROPS, insert the result."
 718   (let ((form (gnus-parse-format format alist props)))
 719     (if props
 720         (gnus-add-text-properties (point) (progn (eval form) (point)) props)
 721       (eval form))))
 722
 723 (defun gnus-compile ()
 724   "Byte-compile the user-defined format specs."
 725   (interactive)
 726   (require 'bytecomp)
 727   (let ((entries gnus-format-specs)
 728         (byte-compile-warnings '(unresolved callargs redefine))
 729         entry gnus-tmp-func)
 730     (save-excursion
 731       (gnus-message 7 "Compiling format specs...")
 732
 733       (while entries
 734         (setq entry (pop entries))
 735         (if (memq (car entry) '(gnus-version version))
 736             (setq gnus-format-specs (delq entry gnus-format-specs))
 737           (let ((form (caddr entry)))
 738             (when (and (listp form)
 739                        ;; Under GNU Emacs, it's (byte-code ...)
 740                        (not (eq 'byte-code (car form)))
 741                        ;; Under XEmacs, it's (funcall #<compiled-function ...>)
 742                        (not (and (eq 'funcall (car form))
 743                                  (byte-code-function-p (cadr form)))))
 744               (defalias 'gnus-tmp-func `(lambda () ,form))
 745               (byte-compile 'gnus-tmp-func)
 746               (setcar (cddr entry) (gnus-byte-code 'gnus-tmp-func))))))
 747
 748       (push (cons 'version emacs-version) gnus-format-specs)
 749       ;; Mark the .newsrc.eld file as "dirty".
 750       (gnus-dribble-touch)
 751       (gnus-message 7 "Compiling user specs...done"))))
 752
 753 (defun gnus-set-format (type &optional insertable)
 754   (set (intern (format "gnus-%s-line-format-spec" type))
 755        (gnus-parse-format
 756         (symbol-value (intern (format "gnus-%s-line-format" type)))
 757         (symbol-value (intern (format "gnus-%s-line-format-alist" type)))
 758         insertable)))
 759
 760 (provide 'gnus-spec)
 761
 762 ;; Local Variables:
 763 ;; coding: iso-8859-1
 764 ;; End:
 765
 766 ;;; arch-tag: a4328fa1-1f84-4b09-97ad-4b5767cfd50f
 767 ;;; gnus-spec.el ends here