cgit.sxemacs.org Git - gnus/blob - lisp/gnus-salt.el

   1 ;;; gnus-salt.el --- alternate summary mode interfaces for Gnus
   2 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gnus)
  28 (eval-when-compile (require 'cl))
  29
  30 ;;;
  31 ;;; gnus-pick-mode
  32 ;;;
  33
  34 (defvar gnus-pick-mode nil
  35   "Minor mode for providing a pick-and-read interface in Gnus summary buffers.")
  36
  37 (defvar gnus-pick-display-summary nil
  38   "*Display summary while reading.")
  39
  40 (defvar gnus-pick-mode-hook nil
  41   "Hook run in summary pick mode buffers.")
  42
  43 ;;; Internal variables.
  44
  45 (defvar gnus-pick-mode-map nil)
  46
  47 (unless gnus-pick-mode-map
  48   (setq gnus-pick-mode-map (make-sparse-keymap))
  49
  50   (gnus-define-keys
  51    gnus-pick-mode-map
  52    "t" gnus-uu-mark-thread
  53    "T" gnus-uu-unmark-thread
  54    " " gnus-summary-mark-as-processable
  55    "u" gnus-summary-unmark-as-processable
  56    "U" gnus-summary-unmark-all-processable
  57    "v" gnus-uu-mark-over
  58    "r" gnus-uu-mark-region
  59    "R" gnus-uu-unmark-region
  60    "e" gnus-uu-mark-by-regexp
  61    "E" gnus-uu-mark-by-regexp
  62    "b" gnus-uu-mark-buffer
  63    "B" gnus-uu-unmark-buffer
  64    "\r" gnus-pick-start-reading))
  65
  66 (defun gnus-pick-make-menu-bar ()
  67   (unless (boundp 'gnus-pick-menu)
  68     (easy-menu-define
  69      gnus-pick-menu gnus-pick-mode-map ""
  70      '("Pick"
  71        ("Pick"
  72         ["Article" gnus-summary-mark-as-processable t]
  73         ["Thread" gnus-uu-mark-thread t]
  74         ["Region" gnus-uu-mark-region t]
  75         ["Regexp" gnus-uu-mark-regexp t]
  76         ["Buffer" gnus-uu-mark-buffer t])
  77        ("Unpick"
  78         ["Article" gnus-summary-unmark-as-processable t]
  79         ["Thread" gnus-uu-unmark-thread t]
  80         ["Region" gnus-uu-unmark-region t]
  81         ["Regexp" gnus-uu-unmark-regexp t]
  82         ["Buffer" gnus-uu-unmark-buffer t])
  83        ["Start reading" gnus-pick-start-reading t]
  84        ["Switch pick mode off" gnus-pick-mode gnus-pick-mode]))))
  85
  86 (defun gnus-pick-mode (&optional arg)
  87   "Minor mode for providing a pick-and-read interface in Gnus summary buffers.
  88
  89 \\{gnus-pick-mode-map}"
  90   (interactive "P")
  91   (when (eq major-mode 'gnus-summary-mode)
  92     (make-local-variable 'gnus-pick-mode)
  93     (setq gnus-pick-mode
  94           (if (null arg) (not gnus-pick-mode)
  95             (> (prefix-numeric-value arg) 0)))
  96     (when gnus-pick-mode
  97       ;; Make sure that we don't select any articles upon group entry.
  98       (make-local-variable 'gnus-auto-select-first)
  99       (setq gnus-auto-select-first nil)
 100       ;; Set up the menu.
 101       (when (and menu-bar-mode
 102                  (gnus-visual-p 'pick-menu 'menu))
 103         (gnus-pick-make-menu-bar))
 104       (unless (assq 'gnus-pick-mode minor-mode-alist)
 105         (push '(gnus-pick-mode " Pick") minor-mode-alist))
 106       (unless (assq 'gnus-pick-mode minor-mode-map-alist)
 107         (push (cons 'gnus-pick-mode gnus-pick-mode-map)
 108               minor-mode-map-alist))
 109       (run-hooks 'gnus-pick-mode-hook))))
 110
 111 (defun gnus-pick-start-reading (&optional catch-up)
 112   "Start reading the picked articles.
 113 If given a prefix, mark all unpicked articles as read."
 114   (interactive "P")
 115   (unless gnus-newsgroup-processable
 116     (error "No articles have been picked"))
 117   (gnus-summary-limit-to-articles nil)
 118   (when catch-up
 119     (gnus-summary-limit-mark-excluded-as-read))
 120   (gnus-summary-first-unread-article)
 121   (gnus-configure-windows (if gnus-pick-display-summary 'article 'pick) t))
 122
 123
 124 ;;;
 125 ;;; gnus-binary-mode
 126 ;;;
 127
 128 (defvar gnus-binary-mode nil
 129   "Minor mode for provind a binary group interface in Gnus summary buffers.")
 130
 131 (defvar gnus-binary-mode-hook nil
 132   "Hook run in summary binary mode buffers.")
 133
 134 (defvar gnus-binary-mode-map nil)
 135
 136 (unless gnus-binary-mode-map
 137   (setq gnus-binary-mode-map (make-sparse-keymap))
 138
 139   (gnus-define-keys
 140    gnus-binary-mode-map
 141    "g" gnus-binary-show-article))
 142
 143 (defun gnus-binary-make-menu-bar ()
 144   (unless (boundp 'gnus-binary-menu)
 145     (easy-menu-define
 146      gnus-binary-menu gnus-binary-mode-map ""
 147      '("Pick"
 148        ["Switch binary mode off" gnus-binary-mode t]))))
 149
 150 (defun gnus-binary-mode (&optional arg)
 151   "Minor mode for providing a binary group interface in Gnus summary buffers."
 152   (interactive "P")
 153   (when (eq major-mode 'gnus-summary-mode)
 154     (make-local-variable 'gnus-binary-mode)
 155     (setq gnus-binary-mode
 156           (if (null arg) (not gnus-binary-mode)
 157             (> (prefix-numeric-value arg) 0)))
 158     (when gnus-binary-mode
 159       ;; Make sure that we don't select any articles upon group entry.
 160       (make-local-variable 'gnus-auto-select-first)
 161       (setq gnus-auto-select-first nil)
 162       (make-local-variable 'gnus-summary-display-article-function)
 163       (setq gnus-summary-display-article-function 'gnus-binary-display-article)
 164       ;; Set up the menu.
 165       (when (and menu-bar-mode
 166                  (gnus-visual-p 'binary-menu 'menu))
 167         (gnus-binary-make-menu-bar))
 168       (unless (assq 'gnus-binary-mode minor-mode-alist)
 169         (push '(gnus-binary-mode " Binary") minor-mode-alist))
 170       (unless (assq 'gnus-binary-mode minor-mode-map-alist)
 171         (push (cons 'gnus-binary-mode gnus-binary-mode-map)
 172               minor-mode-map-alist))
 173       (run-hooks 'gnus-binary-mode-hook))))
 174
 175 (defun gnus-binary-display-article (article &optional all-header)
 176   "Run ARTICLE through the binary decode functions."
 177   (when (gnus-summary-goto-subject article)
 178     (let ((gnus-view-pseudos 'automatic))
 179       (gnus-uu-decode-uu))))
 180
 181 (defun gnus-binary-show-article (&optional arg)
 182   "Bypass the binary functions and show the article."
 183   (interactive "P")
 184   (let (gnus-summary-display-article-function)
 185     (gnus-summary-show-article arg)))
 186
 187 ;;;
 188 ;;; gnus-tree-mode
 189 ;;;
 190
 191 (defvar gnus-tree-line-format "%(%[%3,3n%]%)"
 192   "Format of tree elements.")
 193
 194 (defvar gnus-tree-minimize-window t
 195   "If non-nil, minimize the tree buffer window.
 196 If a number, never let the tree buffer grow taller than that number of
 197 lines.")
 198
 199 (defvar gnus-selected-tree-face 'modeline
 200   "*Face used for highlighting selected articles in the thread tree.")
 201
 202 (defvar gnus-tree-brackets '((?\[ . ?\]) (?\( . ?\))
 203                              (?\{ . ?\}) (?< . ?>))
 204   "Brackets used in tree nodes.")
 205
 206 (defvar gnus-tree-parent-child-edges '(?- ?\\ ?|)
 207   "Charaters used to connect parents with children.")
 208
 209 (defvar gnus-tree-mode-line-format "Gnus: %%b %S %Z"
 210   "*The format specification for the tree mode line.")
 211
 212 (defvar gnus-generate-tree-function 'gnus-generate-vertical-tree
 213   "*Function for generating a thread tree.
 214 Two predefined functions are available:
 215 `gnus-generate-horizontal-tree' and `gnus-generate-vertical-tree'.")
 216
 217 (defvar gnus-tree-mode-hook nil
 218   "*Hook run in tree mode buffers.")
 219
 220 ;;; Internal variables.
 221
 222 (defvar gnus-tree-line-format-alist
 223   `((?n gnus-tmp-name ?s)
 224     (?f gnus-tmp-from ?s)
 225     (?N gnus-tmp-number ?d)
 226     (?\[ gnus-tmp-open-bracket ?c)
 227     (?\] gnus-tmp-close-bracket ?c)
 228     (?s gnus-tmp-subject ?s)))
 229
 230 (defvar gnus-tree-mode-line-format-alist gnus-summary-mode-line-format-alist)
 231
 232 (defvar gnus-tree-mode-line-format-spec nil)
 233 (defvar gnus-tree-line-format-spec nil)
 234
 235 (defvar gnus-tree-node-length nil)
 236 (defvar gnus-selected-tree-overlay nil)
 237
 238 (defvar gnus-tree-displayed-thread nil)
 239
 240 (defvar gnus-tree-mode-map nil)
 241 (put 'gnus-tree-mode 'mode-class 'special)
 242
 243 (unless gnus-tree-mode-map
 244   (setq gnus-tree-mode-map (make-keymap))
 245   (suppress-keymap gnus-tree-mode-map)
 246   (gnus-define-keys
 247    gnus-tree-mode-map
 248    "\r" gnus-tree-select-article
 249    gnus-mouse-2 gnus-tree-pick-article
 250    "\C-?" gnus-tree-read-summary-keys
 251
 252    "\C-c\C-i" gnus-info-find-node)
 253
 254   (substitute-key-definition
 255    'undefined 'gnus-tree-read-summary-keys gnus-tree-mode-map))
 256
 257 (defun gnus-tree-make-menu-bar ()
 258   (unless (boundp 'gnus-tree-menu)
 259     (easy-menu-define
 260      gnus-tree-menu gnus-tree-mode-map ""
 261      '("Tree"
 262        ["Select article" gnus-tree-select-article t]))))
 263
 264 (defun gnus-tree-mode ()
 265   "Major mode for displaying thread trees."
 266   (interactive)
 267   (setq gnus-tree-mode-line-format-spec
 268         (gnus-parse-format gnus-tree-mode-line-format
 269                            gnus-summary-mode-line-format-alist))
 270   (setq gnus-tree-line-format-spec
 271         (gnus-parse-format gnus-tree-line-format
 272                            gnus-tree-line-format-alist t))
 273   (when (and menu-bar-mode
 274              (gnus-visual-p 'tree-menu 'menu))
 275     (gnus-tree-make-menu-bar))
 276   (kill-all-local-variables)
 277   (gnus-simplify-mode-line)
 278   (setq mode-name "Tree")
 279   (setq major-mode 'gnus-tree-mode)
 280   (use-local-map gnus-tree-mode-map)
 281   (buffer-disable-undo (current-buffer))
 282   (setq buffer-read-only t)
 283   (setq truncate-lines t)
 284   (save-excursion
 285     (gnus-set-work-buffer)
 286     (gnus-tree-node-insert (make-mail-header "") nil)
 287     (setq gnus-tree-node-length (1- (point))))
 288   (run-hooks 'gnus-tree-mode-hook))
 289
 290 (defun gnus-tree-read-summary-keys (&optional arg)
 291   "Read a summary buffer key sequence and execute it."
 292   (interactive "P")
 293   (let ((buf (current-buffer))
 294         win)
 295     (gnus-article-read-summary-keys arg nil t)
 296     (when (setq win (get-buffer-window buf))
 297       (select-window win)
 298       (when gnus-selected-tree-overlay
 299         (goto-char (or (gnus-overlay-end gnus-selected-tree-overlay) 1)))
 300       (gnus-tree-minimize))))
 301
 302 (defun gnus-tree-select-article (article)
 303   "Select the article under point, if any."
 304   (interactive (list (gnus-tree-article-number)))
 305   (let ((buf (current-buffer)))
 306     (when article
 307       (save-excursion
 308         (set-buffer gnus-summary-buffer)
 309         (gnus-summary-goto-article article))
 310       (select-window (get-buffer-window buf)))))
 311
 312 (defun gnus-tree-pick-article (e)
 313   "Select the article under the mouse pointer."
 314   (interactive "e")
 315   (mouse-set-point e)
 316   (gnus-tree-select-article (gnus-tree-article-number)))
 317
 318 (defun gnus-tree-article-number ()
 319   (get-text-property (point) 'gnus-number))
 320
 321 (defun gnus-tree-article-region (article)
 322   "Return a cons with BEG and END of the article region."
 323   (let ((pos (text-property-any (point-min) (point-max) 'gnus-number article)))
 324     (when pos
 325       (cons pos (next-single-property-change pos 'gnus-number)))))
 326
 327 (defun gnus-tree-goto-article (article)
 328   (let ((pos (text-property-any (point-min) (point-max) 'gnus-number article)))
 329     (when pos
 330       (goto-char pos))))
 331
 332 (defun gnus-tree-recenter ()
 333   "Center point in the tree window."
 334   (let ((selected (selected-window))
 335         (tree-window (get-buffer-window gnus-tree-buffer t)))
 336     (when tree-window
 337       (select-window tree-window)
 338       (when gnus-selected-tree-overlay
 339         (goto-char (or (gnus-overlay-end gnus-selected-tree-overlay) 1)))
 340       (let* ((top (cond ((< (window-height) 4) 0)
 341                         ((< (window-height) 7) 1)
 342                         (t 2)))
 343              (height (1- (window-height)))
 344              (bottom (save-excursion (goto-char (point-max))
 345                                      (forward-line (- height))
 346                                      (point))))
 347         ;; Set the window start to either `bottom', which is the biggest
 348         ;; possible valid number, or the second line from the top,
 349         ;; whichever is the least.
 350         (set-window-start
 351          tree-window (min bottom (save-excursion
 352                                    (forward-line (- top)) (point)))))
 353       (select-window selected))))
 354
 355 (defun gnus-get-tree-buffer ()
 356   "Return the tree buffer properly initialized."
 357   (save-excursion
 358     (set-buffer (get-buffer-create gnus-tree-buffer))
 359     (unless (eq major-mode 'gnus-tree-mode)
 360       (gnus-add-current-to-buffer-list)
 361       (gnus-tree-mode))
 362     (current-buffer)))
 363
 364 (defun gnus-tree-minimize ()
 365   (when (and gnus-tree-minimize-window
 366              (not (one-window-p)))
 367     (let* ((window-min-height 2)
 368            (height (count-lines (point-min) (point-max)))
 369            (min (max (1- window-min-height) height))
 370            (tot (if (numberp gnus-tree-minimize-window)
 371                     (min gnus-tree-minimize-window min)
 372                   min))
 373            (win (get-buffer-window (current-buffer)))
 374            (wh (and win (1- (window-height win)))))
 375       (when (and win
 376                  (not (eq tot wh)))
 377         (let ((selected (selected-window)))
 378           (select-window win)
 379           (enlarge-window (- tot wh))
 380           (select-window selected))))))
 381
 382 ;;; Generating the tree.
 383
 384 (defun gnus-tree-node-insert (header sparse &optional adopted)
 385   (let* ((dummy (stringp header))
 386          (header (if (vectorp header) header
 387                    (progn
 388                      (setq header (make-mail-header "*****"))
 389                      (mail-header-set-number header 0)
 390                      (mail-header-set-lines header 0)
 391                      (mail-header-set-chars header 0)
 392                      header)))
 393          (gnus-tmp-from (mail-header-from header))
 394          (gnus-tmp-subject (mail-header-subject header))
 395          (gnus-tmp-number (mail-header-number header))
 396          (gnus-tmp-name
 397           (cond
 398            ((string-match "(.+)" gnus-tmp-from)
 399             (substring gnus-tmp-from
 400                        (1+ (match-beginning 0)) (1- (match-end 0))))
 401            ((string-match "<[^>]+> *$" gnus-tmp-from)
 402             (let ((beg (match-beginning 0)))
 403               (or (and (string-match "^\"[^\"]*\"" gnus-tmp-from)
 404                        (substring gnus-tmp-from (1+ (match-beginning 0))
 405                                   (1- (match-end 0))))
 406                   (substring gnus-tmp-from 0 beg))))
 407            ((memq gnus-tmp-number sparse)
 408             "***")
 409            (t gnus-tmp-from)))
 410          (gnus-tmp-open-bracket
 411           (cond ((memq gnus-tmp-number sparse)
 412                  (caadr gnus-tree-brackets))
 413                 (dummy (caaddr gnus-tree-brackets))
 414                 (adopted (car (nth 3 gnus-tree-brackets)))
 415                 (t (caar gnus-tree-brackets))))
 416          (gnus-tmp-close-bracket
 417           (cond ((memq gnus-tmp-number sparse)
 418                  (cdadr gnus-tree-brackets))
 419                 (adopted (cdr (nth 3 gnus-tree-brackets)))
 420                 (dummy
 421                  (cdaddr gnus-tree-brackets))
 422                 (t (cdar gnus-tree-brackets))))
 423          (buffer-read-only nil)
 424          beg end)
 425     (gnus-add-text-properties
 426      (setq beg (point))
 427      (setq end (progn (eval gnus-tree-line-format-spec) (point)))
 428      (list 'gnus-number gnus-tmp-number))
 429     (when (or t (gnus-visual-p 'tree-highlight 'highlight))
 430       (gnus-tree-highlight-node gnus-tmp-number beg end))))
 431
 432 (defun gnus-tree-highlight-node (article beg end)
 433   "Highlight current line according to `gnus-summary-highlight'."
 434   (let ((list gnus-summary-highlight)
 435         face)
 436     (save-excursion
 437       (set-buffer gnus-summary-buffer)
 438       (let* ((score (or (cdr (assq article gnus-newsgroup-scored))
 439                         gnus-summary-default-score 0))
 440              (default gnus-summary-default-score)
 441              (mark (or (gnus-summary-article-mark article) gnus-unread-mark)))
 442         ;; Eval the cars of the lists until we find a match.
 443         (while (and list
 444                     (not (eval (caar list))))
 445           (setq list (cdr list)))))
 446     (unless (eq (setq face (cdar list)) (get-text-property beg 'face))
 447       (gnus-put-text-property
 448        beg end 'face
 449        (if (boundp face) (symbol-value face) face)))))
 450
 451 (defun gnus-tree-indent (level)
 452   (insert (make-string (1- (* (1+ gnus-tree-node-length) level)) ? )))
 453
 454 (defvar gnus-tmp-limit)
 455 (defvar gnus-tmp-sparse)
 456 (defvar gnus-tmp-indent)
 457
 458 (defun gnus-generate-tree (thread)
 459   "Generate a thread tree for THREAD."
 460   (save-excursion
 461     (set-buffer (gnus-get-tree-buffer))
 462     (let ((buffer-read-only nil)
 463           (gnus-tmp-indent 0))
 464       (erase-buffer)
 465       (funcall gnus-generate-tree-function thread 0)
 466       (gnus-set-mode-line 'tree)
 467       (goto-char (point-min))
 468       (gnus-tree-minimize)
 469       (gnus-tree-recenter)
 470       (let ((selected (selected-window)))
 471         (when (get-buffer-window (set-buffer gnus-tree-buffer) t)
 472           (select-window (get-buffer-window (set-buffer gnus-tree-buffer) t))
 473           (gnus-horizontal-recenter)
 474           (select-window selected))))))
 475
 476 (defun gnus-generate-horizontal-tree (thread level &optional dummyp adopted)
 477   "Generate a horizontal tree."
 478   (let* ((dummy (stringp (car thread)))
 479          (do (or dummy
 480                  (memq (mail-header-number (car thread)) gnus-tmp-limit)))
 481          col beg)
 482     (if (not do)
 483         ;; We don't want this article.
 484         (setq thread (cdr thread))
 485       (if (not (bolp))
 486           ;; Not the first article on the line, so we insert a "-".
 487           (insert (car gnus-tree-parent-child-edges))
 488         ;; If the level isn't zero, then we insert some indentation.
 489         (unless (zerop level)
 490           (gnus-tree-indent level)
 491           (insert (cadr gnus-tree-parent-child-edges))
 492           (setq col (- (setq beg (point)) (gnus-point-at-bol) 1))
 493           ;; Draw "|" lines upwards.
 494           (while (progn
 495                    (forward-line -1)
 496                    (forward-char col)
 497                    (= (following-char) ? ))
 498             (delete-char 1)
 499             (insert (caddr gnus-tree-parent-child-edges)))
 500           (goto-char beg)))
 501       (setq dummyp nil)
 502       ;; Insert the article node.
 503       (gnus-tree-node-insert (pop thread) gnus-tmp-sparse adopted))
 504     (if (null thread)
 505         ;; End of the thread, so we go to the next line.
 506         (unless (bolp)
 507           (insert "\n"))
 508       ;; Recurse downwards in all children of this article.
 509       (while thread
 510         (gnus-generate-horizontal-tree
 511          (pop thread) (if do (1+ level) level)
 512          (or dummyp dummy) dummy)))))
 513
 514 (defsubst gnus-tree-indent-vertical ()
 515   (let ((len (- (* (1+ gnus-tree-node-length) gnus-tmp-indent)
 516                 (- (point) (gnus-point-at-bol)))))
 517     (when (> len 0)
 518       (insert (make-string len ? )))))
 519
 520 (defsubst gnus-tree-forward-line (n)
 521   (while (>= (decf n) 0)
 522     (unless (zerop (forward-line 1))
 523       (end-of-line)
 524       (insert "\n")))
 525   (end-of-line))
 526
 527 (defun gnus-generate-vertical-tree (thread level &optional dummyp adopted)
 528   "Generate a vertical tree."
 529   (let* ((dummy (stringp (car thread)))
 530          (do (or dummy
 531                  (memq (mail-header-number (car thread)) gnus-tmp-limit)))
 532          beg)
 533     (if (not do)
 534         ;; We don't want this article.
 535         (setq thread (cdr thread))
 536       (if (not (save-excursion (beginning-of-line) (bobp)))
 537           ;; Not the first article on the line, so we insert a "-".
 538           (progn
 539             (gnus-tree-indent-vertical)
 540             (insert (make-string (/ gnus-tree-node-length 2) ? ))
 541             (insert (caddr gnus-tree-parent-child-edges))
 542             (gnus-tree-forward-line 1))
 543         ;; If the level isn't zero, then we insert some indentation.
 544         (unless (zerop gnus-tmp-indent)
 545           (gnus-tree-forward-line (1- (* 2 level)))
 546           (gnus-tree-indent-vertical)
 547           (delete-char -1)
 548           (insert (cadr gnus-tree-parent-child-edges))
 549           (setq beg (point))
 550           ;; Draw "-" lines leftwards.
 551           (while (progn
 552                    (forward-char -2)
 553                    (= (following-char) ? ))
 554             (delete-char 1)
 555             (insert (car gnus-tree-parent-child-edges)))
 556           (goto-char beg)
 557           (gnus-tree-forward-line 1)))
 558       (setq dummyp nil)
 559       ;; Insert the article node.
 560       (gnus-tree-indent-vertical)
 561       (gnus-tree-node-insert (pop thread) gnus-tmp-sparse adopted)
 562       (gnus-tree-forward-line 1))
 563     (if (null thread)
 564         ;; End of the thread, so we go to the next line.
 565         (progn
 566           (goto-char (point-min))
 567           (end-of-line)
 568           (incf gnus-tmp-indent))
 569       ;; Recurse downwards in all children of this article.
 570       (while thread
 571         (gnus-generate-vertical-tree
 572          (pop thread) (if do (1+ level) level)
 573          (or dummyp dummy) dummy)))))
 574
 575 ;;; Interface functions.
 576
 577 (defun gnus-possibly-generate-tree (article &optional force)
 578   "Generate the thread tree for ARTICLE if it isn't displayed already."
 579   (when (save-excursion
 580           (set-buffer gnus-summary-buffer)
 581           (and gnus-use-trees
 582                (vectorp (gnus-summary-article-header article))))
 583     (save-excursion
 584       (let ((top (save-excursion
 585                    (set-buffer gnus-summary-buffer)
 586                    (gnus-cut-thread
 587                     (gnus-remove-thread
 588                      (mail-header-id
 589                       (gnus-summary-article-header article)) t))))
 590             (gnus-tmp-limit gnus-newsgroup-limit)
 591             (gnus-tmp-sparse gnus-newsgroup-sparse))
 592         (when (or force
 593                   (not (eq top gnus-tree-displayed-thread)))
 594           (gnus-generate-tree top)
 595           (setq gnus-tree-displayed-thread top))))))
 596
 597 (defun gnus-tree-open (group)
 598   (gnus-get-tree-buffer))
 599
 600 (defun gnus-tree-close (group)
 601   ;(gnus-kill-buffer gnus-tree-buffer)
 602   )
 603
 604 (defun gnus-highlight-selected-tree (article)
 605   "Highlight the selected article in the tree."
 606   (let ((buf (current-buffer))
 607         region)
 608     (set-buffer gnus-tree-buffer)
 609     (when (setq region (gnus-tree-article-region article))
 610       (when (or (not gnus-selected-tree-overlay)
 611                 (gnus-extent-detached-p gnus-selected-tree-overlay))
 612         ;; Create a new overlay.
 613         (gnus-overlay-put
 614          (setq gnus-selected-tree-overlay (gnus-make-overlay 1 2))
 615          'face gnus-selected-tree-face))
 616       ;; Move the overlay to the article.
 617       (gnus-move-overlay
 618        gnus-selected-tree-overlay (goto-char (car region)) (cdr region))
 619       (gnus-tree-minimize)
 620       (gnus-tree-recenter)
 621       (let ((selected (selected-window)))
 622         (when (get-buffer-window (set-buffer gnus-tree-buffer) t)
 623           (select-window (get-buffer-window (set-buffer gnus-tree-buffer) t))
 624           (gnus-horizontal-recenter)
 625           (select-window selected))))
 626     ;; If we remove this save-excursion, it updates the wrong mode lines?!?
 627     (save-excursion
 628       (set-buffer gnus-tree-buffer)
 629       (gnus-set-mode-line 'tree))
 630     (set-buffer buf)))
 631
 632 (defun gnus-tree-highlight-article (article face)
 633   (save-excursion
 634     (set-buffer (gnus-get-tree-buffer))
 635     (let (region)
 636       (when (setq region (gnus-tree-article-region article))
 637         (gnus-put-text-property (car region) (cdr region) 'face face)
 638         (set-window-point
 639          (get-buffer-window (current-buffer) t) (cdr region))))))
 640
 641 ;;; Allow redefinition of functions.
 642 (gnus-ems-redefine)
 643
 644 (provide 'gnus-salt)
 645
 646 ;;; gnus-salt.el ends here