cgit.sxemacs.org Git - gnus/blob - lisp/gnus-salt.el

   1 ;;; gnus-salt.el --- alternate summary mode interfaces for Gnus
   2 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gnus)
  28 (require 'gnus-sum)
  29
  30 ;;;
  31 ;;; gnus-pick-mode
  32 ;;;
  33
  34 (defvar gnus-pick-mode nil
  35   "Minor mode for providing a pick-and-read interface in Gnus summary buffers.")
  36
  37 (defvar gnus-pick-display-summary nil
  38   "*Display summary while reading.")
  39
  40 (defvar gnus-pick-mode-hook nil
  41   "Hook run in summary pick mode buffers.")
  42
  43 (defvar gnus-mark-unpicked-articles-as-read nil
  44   "*If non-nil, mark all unpicked articles as read.")
  45
  46 (defvar gnus-pick-elegant-flow t
  47   "If non-nil, gnus-pick-start-reading will run gnus-summary-next-group when no articles have been picked.")
  48
  49 (defvar gnus-summary-pick-line-format
  50   "%-5P %U\%R\%z\%I\%(%[%4L: %-20,20n%]%) %s\n"
  51   "*The format specification of the lines in pick buffers.
  52 It accepts the same format specs that `gnus-summary-line-format' does.")
  53
  54 ;;; Internal variables.
  55
  56 (defvar gnus-pick-mode-map nil)
  57
  58 (unless gnus-pick-mode-map
  59   (setq gnus-pick-mode-map (make-sparse-keymap))
  60
  61   (gnus-define-keys
  62    gnus-pick-mode-map
  63    "t" gnus-uu-mark-thread
  64    "T" gnus-uu-unmark-thread
  65    " " gnus-pick-next-page
  66    "u" gnus-summary-unmark-as-processable
  67    "U" gnus-summary-unmark-all-processable
  68    "v" gnus-uu-mark-over
  69    "r" gnus-uu-mark-region
  70    "R" gnus-uu-unmark-region
  71    "e" gnus-uu-mark-by-regexp
  72    "E" gnus-uu-mark-by-regexp
  73    "b" gnus-uu-mark-buffer
  74    "B" gnus-uu-unmark-buffer
  75    "." gnus-pick-article
  76    gnus-down-mouse-2 gnus-pick-mouse-pick-region
  77    ;;gnus-mouse-2 gnus-pick-mouse-pick
  78    "\r" gnus-pick-start-reading))
  79
  80 (defun gnus-pick-make-menu-bar ()
  81   (unless (boundp 'gnus-pick-menu)
  82     (easy-menu-define
  83      gnus-pick-menu gnus-pick-mode-map ""
  84      '("Pick"
  85        ("Pick"
  86         ["Article" gnus-summary-mark-as-processable t]
  87         ["Thread" gnus-uu-mark-thread t]
  88         ["Region" gnus-uu-mark-region t]
  89         ["Regexp" gnus-uu-mark-regexp t]
  90         ["Buffer" gnus-uu-mark-buffer t])
  91        ("Unpick"
  92         ["Article" gnus-summary-unmark-as-processable t]
  93         ["Thread" gnus-uu-unmark-thread t]
  94         ["Region" gnus-uu-unmark-region t]
  95         ["Regexp" gnus-uu-unmark-regexp t]
  96         ["Buffer" gnus-uu-unmark-buffer t])
  97        ["Start reading" gnus-pick-start-reading t]
  98        ["Switch pick mode off" gnus-pick-mode gnus-pick-mode]))))
  99
 100 (defun gnus-pick-mode (&optional arg)
 101   "Minor mode for providing a pick-and-read interface in Gnus summary buffers.
 102
 103 \\{gnus-pick-mode-map}"
 104   (interactive "P")
 105   (when (eq major-mode 'gnus-summary-mode)
 106     (when (set (make-local-variable 'gnus-pick-mode)
 107                (if (null arg) (not gnus-pick-mode)
 108                  (> (prefix-numeric-value arg) 0)))
 109       ;; Make sure that we don't select any articles upon group entry.
 110       (set (make-local-variable 'gnus-auto-select-first) nil)
 111       ;; Change line format.
 112       (setq gnus-summary-line-format gnus-summary-pick-line-format)
 113       (setq gnus-summary-line-format-spec nil)
 114       (gnus-update-format-specifications nil 'summary)
 115       (gnus-update-summary-mark-positions)
 116       (set (make-local-variable 'gnus-summary-goto-unread) 'never)
 117       ;; Set up the menu.
 118       (when (and menu-bar-mode
 119                  (gnus-visual-p 'pick-menu 'menu))
 120         (gnus-pick-make-menu-bar))
 121       (unless (assq 'gnus-pick-mode minor-mode-alist)
 122         (push '(gnus-pick-mode " Pick") minor-mode-alist))
 123       (unless (assq 'gnus-pick-mode minor-mode-map-alist)
 124         (push (cons 'gnus-pick-mode gnus-pick-mode-map)
 125               minor-mode-map-alist))
 126       (run-hooks 'gnus-pick-mode-hook))))
 127
 128 (defvar gnus-pick-line-number 1)
 129 (defun gnus-pick-line-number ()
 130   "Return the current line number."
 131   (if (bobp)
 132       (setq gnus-pick-line-number 1)
 133     (incf gnus-pick-line-number)))
 134
 135 (defun gnus-pick-start-reading (&optional catch-up)
 136   "Start reading the picked articles.
 137 If given a prefix, mark all unpicked articles as read."
 138   (interactive "P")
 139   (if gnus-newsgroup-processable
 140       (progn
 141         (gnus-summary-limit-to-articles nil)
 142         (when (or catch-up gnus-mark-unpicked-articles-as-read)
 143           (gnus-summary-limit-mark-excluded-as-read))
 144         (gnus-summary-first-unread-article)
 145         (gnus-configure-windows
 146          (if gnus-pick-display-summary 'article 'pick) t))
 147     (if gnus-pick-elegant-flow
 148         (if (gnus-group-quit-config gnus-newsgroup-name)
 149             (gnus-summary-exit)
 150           (gnus-summary-next-group))
 151       (error "No articles have been picked"))))
 152
 153 (defun gnus-pick-article (&optional arg)
 154   "Pick the article on the current line.
 155 If ARG, pick the article on that line instead."
 156   (interactive "P")
 157   (when arg
 158     (let (pos)
 159       (save-excursion
 160         (goto-char (point-min))
 161         (when (zerop (forward-line (1- (prefix-numeric-value arg))))
 162           (setq pos (point))))
 163       (if (not pos)
 164           (gnus-error 2 "No such line: %s" arg)
 165         (goto-char pos))))
 166   (gnus-summary-mark-as-processable 1))
 167
 168 (defun gnus-pick-mouse-pick (e)
 169   (interactive "e")
 170   (mouse-set-point e)
 171   (save-excursion
 172     (gnus-summary-mark-as-processable 1)))
 173
 174 (defun gnus-pick-mouse-pick-region (start-event)
 175   "Pick articles that the mouse is dragged over.
 176 This must be bound to a button-down mouse event."
 177   (interactive "e")
 178   (mouse-minibuffer-check start-event)
 179   (let* ((echo-keystrokes 0)
 180          (start-posn (event-start start-event))
 181          (start-point (posn-point start-posn))
 182          (start-line (1+ (count-lines 1 start-point)))
 183          (start-window (posn-window start-posn))
 184          (start-frame (window-frame start-window))
 185          (bounds (window-edges start-window))
 186          (top (nth 1 bounds))
 187          (bottom (if (window-minibuffer-p start-window)
 188                      (nth 3 bounds)
 189                    ;; Don't count the mode line.
 190                    (1- (nth 3 bounds))))
 191          (click-count (1- (event-click-count start-event))))
 192     (setq mouse-selection-click-count click-count)
 193     (setq mouse-selection-click-count-buffer (current-buffer))
 194     (mouse-set-point start-event)
 195     ;; In case the down click is in the middle of some intangible text,
 196     ;; use the end of that text, and put it in START-POINT.
 197     (when (< (point) start-point)
 198       (goto-char start-point))
 199     (gnus-pick-article)
 200     (setq start-point (point))
 201     ;; end-of-range is used only in the single-click case.
 202     ;; It is the place where the drag has reached so far
 203     ;; (but not outside the window where the drag started).
 204     (let (event end end-point last-end-point (end-of-range (point)))
 205       (track-mouse
 206        (while (progn
 207                 (setq event (read-event))
 208                 (or (mouse-movement-p event)
 209                     (eq (car-safe event) 'switch-frame)))
 210          (if (eq (car-safe event) 'switch-frame)
 211              nil
 212            (setq end (event-end event)
 213                  end-point (posn-point end))
 214            (when end-point
 215              (setq last-end-point end-point))
 216
 217            (cond
 218             ;; Are we moving within the original window?
 219             ((and (eq (posn-window end) start-window)
 220                   (integer-or-marker-p end-point))
 221              ;; Go to START-POINT first, so that when we move to END-POINT,
 222              ;; if it's in the middle of intangible text,
 223              ;; point jumps in the direction away from START-POINT.
 224              (goto-char start-point)
 225              (goto-char end-point)
 226              (gnus-pick-article)
 227              ;; In case the user moved his mouse really fast, pick
 228              ;; articles on the line between this one and the last one.
 229              (let* ((this-line (1+ (count-lines 1 end-point)))
 230                     (min-line (min this-line start-line))
 231                     (max-line (max this-line start-line)))
 232                (while (< min-line max-line)
 233                  (goto-line min-line)
 234                  (gnus-pick-article)
 235                  (setq min-line (1+ min-line)))
 236                (setq start-line this-line))
 237              (when (zerop (% click-count 3))
 238                (setq end-of-range (point))))
 239             (t
 240              (let ((mouse-row (cdr (cdr (mouse-position)))))
 241                (cond
 242                 ((null mouse-row))
 243                 ((< mouse-row top)
 244                  (mouse-scroll-subr start-window (- mouse-row top)))
 245                 ((>= mouse-row bottom)
 246                  (mouse-scroll-subr start-window
 247                                     (1+ (- mouse-row bottom)))))))))))
 248       (when (consp event)
 249         (let ((fun (key-binding (vector (car event)))))
 250           ;; Run the binding of the terminating up-event, if possible.
 251           ;; In the case of a multiple click, it gives the wrong results,
 252           ;; because it would fail to set up a region.
 253           (when nil
 254             ;; (and (= (mod mouse-selection-click-count 3) 0) (fboundp fun))
 255             ;; In this case, we can just let the up-event execute normally.
 256             (let ((end (event-end event)))
 257               ;; Set the position in the event before we replay it,
 258               ;; because otherwise it may have a position in the wrong
 259               ;; buffer.
 260               (setcar (cdr end) end-of-range)
 261               ;; Delete the overlay before calling the function,
 262               ;; because delete-overlay increases buffer-modified-tick.
 263               (push event unread-command-events))))))))
 264
 265 (defun gnus-pick-next-page ()
 266   "Go to the next page.  If at the end of the buffer, start reading articles."
 267   (interactive)
 268   (condition-case nil
 269       (scroll-up)
 270     (end-of-buffer (gnus-pick-start-reading))))
 271
 272 ;;;
 273 ;;; gnus-binary-mode
 274 ;;;
 275
 276 (defvar gnus-binary-mode nil
 277   "Minor mode for providing a binary group interface in Gnus summary buffers.")
 278
 279 (defvar gnus-binary-mode-hook nil
 280   "Hook run in summary binary mode buffers.")
 281
 282 (defvar gnus-binary-mode-map nil)
 283
 284 (unless gnus-binary-mode-map
 285   (setq gnus-binary-mode-map (make-sparse-keymap))
 286
 287   (gnus-define-keys
 288    gnus-binary-mode-map
 289    "g" gnus-binary-show-article))
 290
 291 (defun gnus-binary-make-menu-bar ()
 292   (unless (boundp 'gnus-binary-menu)
 293     (easy-menu-define
 294      gnus-binary-menu gnus-binary-mode-map ""
 295      '("Pick"
 296        ["Switch binary mode off" gnus-binary-mode t]))))
 297
 298 (defun gnus-binary-mode (&optional arg)
 299   "Minor mode for providing a binary group interface in Gnus summary buffers."
 300   (interactive "P")
 301   (when (eq major-mode 'gnus-summary-mode)
 302     (make-local-variable 'gnus-binary-mode)
 303     (setq gnus-binary-mode
 304           (if (null arg) (not gnus-binary-mode)
 305             (> (prefix-numeric-value arg) 0)))
 306     (when gnus-binary-mode
 307       ;; Make sure that we don't select any articles upon group entry.
 308       (make-local-variable 'gnus-auto-select-first)
 309       (setq gnus-auto-select-first nil)
 310       (make-local-variable 'gnus-summary-display-article-function)
 311       (setq gnus-summary-display-article-function 'gnus-binary-display-article)
 312       ;; Set up the menu.
 313       (when (and menu-bar-mode
 314                  (gnus-visual-p 'binary-menu 'menu))
 315         (gnus-binary-make-menu-bar))
 316       (unless (assq 'gnus-binary-mode minor-mode-alist)
 317         (push '(gnus-binary-mode " Binary") minor-mode-alist))
 318       (unless (assq 'gnus-binary-mode minor-mode-map-alist)
 319         (push (cons 'gnus-binary-mode gnus-binary-mode-map)
 320               minor-mode-map-alist))
 321       (run-hooks 'gnus-binary-mode-hook))))
 322
 323 (defun gnus-binary-display-article (article &optional all-header)
 324   "Run ARTICLE through the binary decode functions."
 325   (when (gnus-summary-goto-subject article)
 326     (let ((gnus-view-pseudos 'automatic))
 327       (gnus-uu-decode-uu))))
 328
 329 (defun gnus-binary-show-article (&optional arg)
 330   "Bypass the binary functions and show the article."
 331   (interactive "P")
 332   (let (gnus-summary-display-article-function)
 333     (gnus-summary-show-article arg)))
 334
 335 ;;;
 336 ;;; gnus-tree-mode
 337 ;;;
 338
 339 (defvar gnus-tree-line-format "%(%[%3,3n%]%)"
 340   "Format of tree elements.")
 341
 342 (defvar gnus-tree-minimize-window t
 343   "If non-nil, minimize the tree buffer window.
 344 If a number, never let the tree buffer grow taller than that number of
 345 lines.")
 346
 347 (defvar gnus-selected-tree-face 'modeline
 348   "*Face used for highlighting selected articles in the thread tree.")
 349
 350 (defvar gnus-tree-brackets '((?\[ . ?\]) (?\( . ?\))
 351                              (?\{ . ?\}) (?< . ?>))
 352   "Brackets used in tree nodes.")
 353
 354 (defvar gnus-tree-parent-child-edges '(?- ?\\ ?|)
 355   "Characters used to connect parents with children.")
 356
 357 (defvar gnus-tree-mode-line-format "Gnus: %%b %S %Z"
 358   "*The format specification for the tree mode line.")
 359
 360 (defvar gnus-generate-tree-function 'gnus-generate-vertical-tree
 361   "*Function for generating a thread tree.
 362 Two predefined functions are available:
 363 `gnus-generate-horizontal-tree' and `gnus-generate-vertical-tree'.")
 364
 365 (defvar gnus-tree-mode-hook nil
 366   "*Hook run in tree mode buffers.")
 367
 368 ;;; Internal variables.
 369
 370 (defvar gnus-tree-line-format-alist
 371   `((?n gnus-tmp-name ?s)
 372     (?f gnus-tmp-from ?s)
 373     (?N gnus-tmp-number ?d)
 374     (?\[ gnus-tmp-open-bracket ?c)
 375     (?\] gnus-tmp-close-bracket ?c)
 376     (?s gnus-tmp-subject ?s)))
 377
 378 (defvar gnus-tree-mode-line-format-alist gnus-summary-mode-line-format-alist)
 379
 380 (defvar gnus-tree-mode-line-format-spec nil)
 381 (defvar gnus-tree-line-format-spec nil)
 382
 383 (defvar gnus-tree-node-length nil)
 384 (defvar gnus-selected-tree-overlay nil)
 385
 386 (defvar gnus-tree-displayed-thread nil)
 387
 388 (defvar gnus-tree-mode-map nil)
 389 (put 'gnus-tree-mode 'mode-class 'special)
 390
 391 (unless gnus-tree-mode-map
 392   (setq gnus-tree-mode-map (make-keymap))
 393   (suppress-keymap gnus-tree-mode-map)
 394   (gnus-define-keys
 395    gnus-tree-mode-map
 396    "\r" gnus-tree-select-article
 397    gnus-mouse-2 gnus-tree-pick-article
 398    "\C-?" gnus-tree-read-summary-keys
 399
 400    "\C-c\C-i" gnus-info-find-node)
 401
 402   (substitute-key-definition
 403    'undefined 'gnus-tree-read-summary-keys gnus-tree-mode-map))
 404
 405 (defun gnus-tree-make-menu-bar ()
 406   (unless (boundp 'gnus-tree-menu)
 407     (easy-menu-define
 408      gnus-tree-menu gnus-tree-mode-map ""
 409      '("Tree"
 410        ["Select article" gnus-tree-select-article t]))))
 411
 412 (defun gnus-tree-mode ()
 413   "Major mode for displaying thread trees."
 414   (interactive)
 415   (setq gnus-tree-mode-line-format-spec
 416         (gnus-parse-format gnus-tree-mode-line-format
 417                            gnus-summary-mode-line-format-alist))
 418   (setq gnus-tree-line-format-spec
 419         (gnus-parse-format gnus-tree-line-format
 420                            gnus-tree-line-format-alist t))
 421   (when (and menu-bar-mode
 422              (gnus-visual-p 'tree-menu 'menu))
 423     (gnus-tree-make-menu-bar))
 424   (kill-all-local-variables)
 425   (gnus-simplify-mode-line)
 426   (setq mode-name "Tree")
 427   (setq major-mode 'gnus-tree-mode)
 428   (use-local-map gnus-tree-mode-map)
 429   (buffer-disable-undo (current-buffer))
 430   (setq buffer-read-only t)
 431   (setq truncate-lines t)
 432   (save-excursion
 433     (gnus-set-work-buffer)
 434     (gnus-tree-node-insert (make-mail-header "") nil)
 435     (setq gnus-tree-node-length (1- (point))))
 436   (run-hooks 'gnus-tree-mode-hook))
 437
 438 (defun gnus-tree-read-summary-keys (&optional arg)
 439   "Read a summary buffer key sequence and execute it."
 440   (interactive "P")
 441   (let ((buf (current-buffer))
 442         win)
 443     (gnus-article-read-summary-keys arg nil t)
 444     (when (setq win (get-buffer-window buf))
 445       (select-window win)
 446       (when gnus-selected-tree-overlay
 447         (goto-char (or (gnus-overlay-end gnus-selected-tree-overlay) 1)))
 448       (gnus-tree-minimize))))
 449
 450 (defun gnus-tree-select-article (article)
 451   "Select the article under point, if any."
 452   (interactive (list (gnus-tree-article-number)))
 453   (let ((buf (current-buffer)))
 454     (when article
 455       (save-excursion
 456         (set-buffer gnus-summary-buffer)
 457         (gnus-summary-goto-article article))
 458       (select-window (get-buffer-window buf)))))
 459
 460 (defun gnus-tree-pick-article (e)
 461   "Select the article under the mouse pointer."
 462   (interactive "e")
 463   (mouse-set-point e)
 464   (gnus-tree-select-article (gnus-tree-article-number)))
 465
 466 (defun gnus-tree-article-number ()
 467   (get-text-property (point) 'gnus-number))
 468
 469 (defun gnus-tree-article-region (article)
 470   "Return a cons with BEG and END of the article region."
 471   (let ((pos (text-property-any (point-min) (point-max) 'gnus-number article)))
 472     (when pos
 473       (cons pos (next-single-property-change pos 'gnus-number)))))
 474
 475 (defun gnus-tree-goto-article (article)
 476   (let ((pos (text-property-any (point-min) (point-max) 'gnus-number article)))
 477     (when pos
 478       (goto-char pos))))
 479
 480 (defun gnus-tree-recenter ()
 481   "Center point in the tree window."
 482   (let ((selected (selected-window))
 483         (tree-window (get-buffer-window gnus-tree-buffer t)))
 484     (when tree-window
 485       (select-window tree-window)
 486       (when gnus-selected-tree-overlay
 487         (goto-char (or (gnus-overlay-end gnus-selected-tree-overlay) 1)))
 488       (let* ((top (cond ((< (window-height) 4) 0)
 489                         ((< (window-height) 7) 1)
 490                         (t 2)))
 491              (height (1- (window-height)))
 492              (bottom (save-excursion (goto-char (point-max))
 493                                      (forward-line (- height))
 494                                      (point))))
 495         ;; Set the window start to either `bottom', which is the biggest
 496         ;; possible valid number, or the second line from the top,
 497         ;; whichever is the least.
 498         (set-window-start
 499          tree-window (min bottom (save-excursion
 500                                    (forward-line (- top)) (point)))))
 501       (select-window selected))))
 502
 503 (defun gnus-get-tree-buffer ()
 504   "Return the tree buffer properly initialized."
 505   (save-excursion
 506     (set-buffer (get-buffer-create gnus-tree-buffer))
 507     (unless (eq major-mode 'gnus-tree-mode)
 508       (gnus-add-current-to-buffer-list)
 509       (gnus-tree-mode))
 510     (current-buffer)))
 511
 512 (defun gnus-tree-minimize ()
 513   (when (and gnus-tree-minimize-window
 514              (not (one-window-p)))
 515     (let ((windows 0)
 516           tot-win-height)
 517       (walk-windows (lambda (window) (incf windows)))
 518       (setq tot-win-height
 519             (- (frame-height)
 520                (* window-min-height (1- windows))
 521                2))
 522       (let* ((window-min-height 2)
 523              (height (count-lines (point-min) (point-max)))
 524              (min (max (1- window-min-height) height))
 525              (tot (if (numberp gnus-tree-minimize-window)
 526                       (min gnus-tree-minimize-window min)
 527                     min))
 528              (win (get-buffer-window (current-buffer)))
 529              (wh (and win (1- (window-height win)))))
 530         (setq tot (min tot tot-win-height))
 531         (when (and win
 532                    (not (eq tot wh)))
 533           (let ((selected (selected-window)))
 534             (select-window win)
 535             (enlarge-window (- tot wh))
 536             (select-window selected)))))))
 537
 538 ;;; Generating the tree.
 539
 540 (defun gnus-tree-node-insert (header sparse &optional adopted)
 541   (let* ((dummy (stringp header))
 542          (header (if (vectorp header) header
 543                    (progn
 544                      (setq header (make-mail-header "*****"))
 545                      (mail-header-set-number header 0)
 546                      (mail-header-set-lines header 0)
 547                      (mail-header-set-chars header 0)
 548                      header)))
 549          (gnus-tmp-from (mail-header-from header))
 550          (gnus-tmp-subject (mail-header-subject header))
 551          (gnus-tmp-number (mail-header-number header))
 552          (gnus-tmp-name
 553           (cond
 554            ((string-match "(.+)" gnus-tmp-from)
 555             (substring gnus-tmp-from
 556                        (1+ (match-beginning 0)) (1- (match-end 0))))
 557            ((string-match "<[^>]+> *$" gnus-tmp-from)
 558             (let ((beg (match-beginning 0)))
 559               (or (and (string-match "^\"[^\"]*\"" gnus-tmp-from)
 560                        (substring gnus-tmp-from (1+ (match-beginning 0))
 561                                   (1- (match-end 0))))
 562                   (substring gnus-tmp-from 0 beg))))
 563            ((memq gnus-tmp-number sparse)
 564             "***")
 565            (t gnus-tmp-from)))
 566          (gnus-tmp-open-bracket
 567           (cond ((memq gnus-tmp-number sparse)
 568                  (caadr gnus-tree-brackets))
 569                 (dummy (caaddr gnus-tree-brackets))
 570                 (adopted (car (nth 3 gnus-tree-brackets)))
 571                 (t (caar gnus-tree-brackets))))
 572          (gnus-tmp-close-bracket
 573           (cond ((memq gnus-tmp-number sparse)
 574                  (cdadr gnus-tree-brackets))
 575                 (adopted (cdr (nth 3 gnus-tree-brackets)))
 576                 (dummy
 577                  (cdaddr gnus-tree-brackets))
 578                 (t (cdar gnus-tree-brackets))))
 579          (buffer-read-only nil)
 580          beg end)
 581     (gnus-add-text-properties
 582      (setq beg (point))
 583      (setq end (progn (eval gnus-tree-line-format-spec) (point)))
 584      (list 'gnus-number gnus-tmp-number))
 585     (when (or t (gnus-visual-p 'tree-highlight 'highlight))
 586       (gnus-tree-highlight-node gnus-tmp-number beg end))))
 587
 588 (defun gnus-tree-highlight-node (article beg end)
 589   "Highlight current line according to `gnus-summary-highlight'."
 590   (let ((list gnus-summary-highlight)
 591         face)
 592     (save-excursion
 593       (set-buffer gnus-summary-buffer)
 594       (let* ((score (or (cdr (assq article gnus-newsgroup-scored))
 595                         gnus-summary-default-score 0))
 596              (default gnus-summary-default-score)
 597              (mark (or (gnus-summary-article-mark article) gnus-unread-mark)))
 598         ;; Eval the cars of the lists until we find a match.
 599         (while (and list
 600                     (not (eval (caar list))))
 601           (setq list (cdr list)))))
 602     (unless (eq (setq face (cdar list)) (get-text-property beg 'face))
 603       (gnus-put-text-property
 604        beg end 'face
 605        (if (boundp face) (symbol-value face) face)))))
 606
 607 (defun gnus-tree-indent (level)
 608   (insert (make-string (1- (* (1+ gnus-tree-node-length) level)) ? )))
 609
 610 (defvar gnus-tmp-limit)
 611 (defvar gnus-tmp-sparse)
 612 (defvar gnus-tmp-indent)
 613
 614 (defun gnus-generate-tree (thread)
 615   "Generate a thread tree for THREAD."
 616   (save-excursion
 617     (set-buffer (gnus-get-tree-buffer))
 618     (let ((buffer-read-only nil)
 619           (gnus-tmp-indent 0))
 620       (erase-buffer)
 621       (funcall gnus-generate-tree-function thread 0)
 622       (gnus-set-mode-line 'tree)
 623       (goto-char (point-min))
 624       (gnus-tree-minimize)
 625       (gnus-tree-recenter)
 626       (let ((selected (selected-window)))
 627         (when (get-buffer-window (set-buffer gnus-tree-buffer) t)
 628           (select-window (get-buffer-window (set-buffer gnus-tree-buffer) t))
 629           (gnus-horizontal-recenter)
 630           (select-window selected))))))
 631
 632 (defun gnus-generate-horizontal-tree (thread level &optional dummyp adopted)
 633   "Generate a horizontal tree."
 634   (let* ((dummy (stringp (car thread)))
 635          (do (or dummy
 636                  (memq (mail-header-number (car thread)) gnus-tmp-limit)))
 637          col beg)
 638     (if (not do)
 639         ;; We don't want this article.
 640         (setq thread (cdr thread))
 641       (if (not (bolp))
 642           ;; Not the first article on the line, so we insert a "-".
 643           (insert (car gnus-tree-parent-child-edges))
 644         ;; If the level isn't zero, then we insert some indentation.
 645         (unless (zerop level)
 646           (gnus-tree-indent level)
 647           (insert (cadr gnus-tree-parent-child-edges))
 648           (setq col (- (setq beg (point)) (gnus-point-at-bol) 1))
 649           ;; Draw "|" lines upwards.
 650           (while (progn
 651                    (forward-line -1)
 652                    (forward-char col)
 653                    (= (following-char) ? ))
 654             (delete-char 1)
 655             (insert (caddr gnus-tree-parent-child-edges)))
 656           (goto-char beg)))
 657       (setq dummyp nil)
 658       ;; Insert the article node.
 659       (gnus-tree-node-insert (pop thread) gnus-tmp-sparse adopted))
 660     (if (null thread)
 661         ;; End of the thread, so we go to the next line.
 662         (unless (bolp)
 663           (insert "\n"))
 664       ;; Recurse downwards in all children of this article.
 665       (while thread
 666         (gnus-generate-horizontal-tree
 667          (pop thread) (if do (1+ level) level)
 668          (or dummyp dummy) dummy)))))
 669
 670 (defsubst gnus-tree-indent-vertical ()
 671   (let ((len (- (* (1+ gnus-tree-node-length) gnus-tmp-indent)
 672                 (- (point) (gnus-point-at-bol)))))
 673     (when (> len 0)
 674       (insert (make-string len ? )))))
 675
 676 (defsubst gnus-tree-forward-line (n)
 677   (while (>= (decf n) 0)
 678     (unless (zerop (forward-line 1))
 679       (end-of-line)
 680       (insert "\n")))
 681   (end-of-line))
 682
 683 (defun gnus-generate-vertical-tree (thread level &optional dummyp adopted)
 684   "Generate a vertical tree."
 685   (let* ((dummy (stringp (car thread)))
 686          (do (or dummy
 687                  (memq (mail-header-number (car thread)) gnus-tmp-limit)))
 688          beg)
 689     (if (not do)
 690         ;; We don't want this article.
 691         (setq thread (cdr thread))
 692       (if (not (save-excursion (beginning-of-line) (bobp)))
 693           ;; Not the first article on the line, so we insert a "-".
 694           (progn
 695             (gnus-tree-indent-vertical)
 696             (insert (make-string (/ gnus-tree-node-length 2) ? ))
 697             (insert (caddr gnus-tree-parent-child-edges))
 698             (gnus-tree-forward-line 1))
 699         ;; If the level isn't zero, then we insert some indentation.
 700         (unless (zerop gnus-tmp-indent)
 701           (gnus-tree-forward-line (1- (* 2 level)))
 702           (gnus-tree-indent-vertical)
 703           (delete-char -1)
 704           (insert (cadr gnus-tree-parent-child-edges))
 705           (setq beg (point))
 706           ;; Draw "-" lines leftwards.
 707           (while (progn
 708                    (forward-char -2)
 709                    (= (following-char) ? ))
 710             (delete-char 1)
 711             (insert (car gnus-tree-parent-child-edges)))
 712           (goto-char beg)
 713           (gnus-tree-forward-line 1)))
 714       (setq dummyp nil)
 715       ;; Insert the article node.
 716       (gnus-tree-indent-vertical)
 717       (gnus-tree-node-insert (pop thread) gnus-tmp-sparse adopted)
 718       (gnus-tree-forward-line 1))
 719     (if (null thread)
 720         ;; End of the thread, so we go to the next line.
 721         (progn
 722           (goto-char (point-min))
 723           (end-of-line)
 724           (incf gnus-tmp-indent))
 725       ;; Recurse downwards in all children of this article.
 726       (while thread
 727         (gnus-generate-vertical-tree
 728          (pop thread) (if do (1+ level) level)
 729          (or dummyp dummy) dummy)))))
 730
 731 ;;; Interface functions.
 732
 733 (defun gnus-possibly-generate-tree (article &optional force)
 734   "Generate the thread tree for ARTICLE if it isn't displayed already."
 735   (when (save-excursion
 736           (set-buffer gnus-summary-buffer)
 737           (and gnus-use-trees
 738                gnus-show-threads
 739                (vectorp (gnus-summary-article-header article))))
 740     (save-excursion
 741       (let ((top (save-excursion
 742                    (set-buffer gnus-summary-buffer)
 743                    (gnus-cut-thread
 744                     (gnus-remove-thread
 745                      (mail-header-id
 746                       (gnus-summary-article-header article))
 747                      t))))
 748             (gnus-tmp-limit gnus-newsgroup-limit)
 749             (gnus-tmp-sparse gnus-newsgroup-sparse))
 750         (when (or force
 751                   (not (eq top gnus-tree-displayed-thread)))
 752           (gnus-generate-tree top)
 753           (setq gnus-tree-displayed-thread top))))))
 754
 755 (defun gnus-tree-open (group)
 756   (gnus-get-tree-buffer))
 757
 758 (defun gnus-tree-close (group)
 759                                         ;(gnus-kill-buffer gnus-tree-buffer)
 760   )
 761
 762 (defun gnus-highlight-selected-tree (article)
 763   "Highlight the selected article in the tree."
 764   (let ((buf (current-buffer))
 765         region)
 766     (set-buffer gnus-tree-buffer)
 767     (when (setq region (gnus-tree-article-region article))
 768       (when (or (not gnus-selected-tree-overlay)
 769                 (gnus-extent-detached-p gnus-selected-tree-overlay))
 770         ;; Create a new overlay.
 771         (gnus-overlay-put
 772          (setq gnus-selected-tree-overlay (gnus-make-overlay 1 2))
 773          'face gnus-selected-tree-face))
 774       ;; Move the overlay to the article.
 775       (gnus-move-overlay
 776        gnus-selected-tree-overlay (goto-char (car region)) (cdr region))
 777       (gnus-tree-minimize)
 778       (gnus-tree-recenter)
 779       (let ((selected (selected-window)))
 780         (when (get-buffer-window (set-buffer gnus-tree-buffer) t)
 781           (select-window (get-buffer-window (set-buffer gnus-tree-buffer) t))
 782           (gnus-horizontal-recenter)
 783           (select-window selected))))
 784     ;; If we remove this save-excursion, it updates the wrong mode lines?!?
 785     (save-excursion
 786       (set-buffer gnus-tree-buffer)
 787       (gnus-set-mode-line 'tree))
 788     (set-buffer buf)))
 789
 790 (defun gnus-tree-highlight-article (article face)
 791   (save-excursion
 792     (set-buffer (gnus-get-tree-buffer))
 793     (let (region)
 794       (when (setq region (gnus-tree-article-region article))
 795         (gnus-put-text-property (car region) (cdr region) 'face face)
 796         (set-window-point
 797          (get-buffer-window (current-buffer) t) (cdr region))))))
 798
 799 ;;;
 800 ;;; gnus-carpal
 801 ;;;
 802
 803 (defvar gnus-carpal-group-buffer-buttons
 804   '(("next" . gnus-group-next-unread-group)
 805     ("prev" . gnus-group-prev-unread-group)
 806     ("read" . gnus-group-read-group)
 807     ("select" . gnus-group-select-group)
 808     ("catch-up" . gnus-group-catchup-current)
 809     ("new-news" . gnus-group-get-new-news-this-group)
 810     ("toggle-sub" . gnus-group-unsubscribe-current-group)
 811     ("subscribe" . gnus-group-unsubscribe-group)
 812     ("kill" . gnus-group-kill-group)
 813     ("yank" . gnus-group-yank-group)
 814     ("describe" . gnus-group-describe-group)
 815     "list"
 816     ("subscribed" . gnus-group-list-groups)
 817     ("all" . gnus-group-list-all-groups)
 818     ("killed" . gnus-group-list-killed)
 819     ("zombies" . gnus-group-list-zombies)
 820     ("matching" . gnus-group-list-matching)
 821     ("post" . gnus-group-post-news)
 822     ("mail" . gnus-group-mail)
 823     ("rescan" . gnus-group-get-new-news)
 824     ("browse-foreign" . gnus-group-browse-foreign)
 825     ("exit" . gnus-group-exit)))
 826
 827 (defvar gnus-carpal-summary-buffer-buttons
 828   '("mark"
 829     ("read" . gnus-summary-mark-as-read-forward)
 830     ("tick" . gnus-summary-tick-article-forward)
 831     ("clear" . gnus-summary-clear-mark-forward)
 832     ("expirable" . gnus-summary-mark-as-expirable)
 833     "move"
 834     ("scroll" . gnus-summary-next-page)
 835     ("next-unread" . gnus-summary-next-unread-article)
 836     ("prev-unread" . gnus-summary-prev-unread-article)
 837     ("first" . gnus-summary-first-unread-article)
 838     ("best" . gnus-summary-best-unread-article)
 839     "article"
 840     ("headers" . gnus-summary-toggle-header)
 841     ("uudecode" . gnus-uu-decode-uu)
 842     ("enter-digest" . gnus-summary-enter-digest-group)
 843     ("fetch-parent" . gnus-summary-refer-parent-article)
 844     "mail"
 845     ("move" . gnus-summary-move-article)
 846     ("copy" . gnus-summary-copy-article)
 847     ("respool" . gnus-summary-respool-article)
 848     "threads"
 849     ("lower" . gnus-summary-lower-thread)
 850     ("kill" . gnus-summary-kill-thread)
 851     "post"
 852     ("post" . gnus-summary-post-news)
 853     ("mail" . gnus-summary-mail)
 854     ("followup" . gnus-summary-followup-with-original)
 855     ("reply" . gnus-summary-reply-with-original)
 856     ("cancel" . gnus-summary-cancel-article)
 857     "misc"
 858     ("exit" . gnus-summary-exit)
 859     ("fed-up" . gnus-summary-catchup-and-goto-next-group)))
 860
 861 (defvar gnus-carpal-server-buffer-buttons
 862   '(("add" . gnus-server-add-server)
 863     ("browse" . gnus-server-browse-server)
 864     ("list" . gnus-server-list-servers)
 865     ("kill" . gnus-server-kill-server)
 866     ("yank" . gnus-server-yank-server)
 867     ("copy" . gnus-server-copy-server)
 868     ("exit" . gnus-server-exit)))
 869
 870 (defvar gnus-carpal-browse-buffer-buttons
 871   '(("subscribe" . gnus-browse-unsubscribe-current-group)
 872     ("exit" . gnus-browse-exit)))
 873
 874 (defvar gnus-carpal-group-buffer "*Carpal Group*")
 875 (defvar gnus-carpal-summary-buffer "*Carpal Summary*")
 876 (defvar gnus-carpal-server-buffer "*Carpal Server*")
 877 (defvar gnus-carpal-browse-buffer "*Carpal Browse*")
 878
 879 (defvar gnus-carpal-attached-buffer nil)
 880
 881 (defvar gnus-carpal-mode-hook nil
 882   "*Hook run in carpal mode buffers.")
 883
 884 (defvar gnus-carpal-button-face 'bold
 885   "*Face used on carpal buttons.")
 886
 887 (defvar gnus-carpal-header-face 'bold-italic
 888   "*Face used on carpal buffer headers.")
 889
 890 (defvar gnus-carpal-mode-map nil)
 891 (put 'gnus-carpal-mode 'mode-class 'special)
 892
 893 (if gnus-carpal-mode-map
 894     nil
 895   (setq gnus-carpal-mode-map (make-keymap))
 896   (suppress-keymap gnus-carpal-mode-map)
 897   (define-key gnus-carpal-mode-map " " 'gnus-carpal-select)
 898   (define-key gnus-carpal-mode-map "\r" 'gnus-carpal-select)
 899   (define-key gnus-carpal-mode-map gnus-mouse-2 'gnus-carpal-mouse-select))
 900
 901 (defun gnus-carpal-mode ()
 902   "Major mode for clicking buttons.
 903
 904 All normal editing commands are switched off.
 905 \\<gnus-carpal-mode-map>
 906 The following commands are available:
 907
 908 \\{gnus-carpal-mode-map}"
 909   (interactive)
 910   (kill-all-local-variables)
 911   (setq mode-line-modified "-- ")
 912   (setq major-mode 'gnus-carpal-mode)
 913   (setq mode-name "Gnus Carpal")
 914   (setq mode-line-process nil)
 915   (use-local-map gnus-carpal-mode-map)
 916   (buffer-disable-undo (current-buffer))
 917   (setq buffer-read-only t)
 918   (make-local-variable 'gnus-carpal-attached-buffer)
 919   (run-hooks 'gnus-carpal-mode-hook))
 920
 921 (defun gnus-carpal-setup-buffer (type)
 922   (let ((buffer (symbol-value (intern (format "gnus-carpal-%s-buffer" type)))))
 923     (if (get-buffer buffer)
 924         ()
 925       (save-excursion
 926         (set-buffer (get-buffer-create buffer))
 927         (gnus-carpal-mode)
 928         (setq gnus-carpal-attached-buffer
 929               (intern (format "gnus-%s-buffer" type)))
 930         (gnus-add-current-to-buffer-list)
 931         (let ((buttons (symbol-value
 932                         (intern (format "gnus-carpal-%s-buffer-buttons"
 933                                         type))))
 934               (buffer-read-only nil)
 935               button)
 936           (while buttons
 937             (setq button (car buttons)
 938                   buttons (cdr buttons))
 939             (if (stringp button)
 940                 (gnus-set-text-properties
 941                  (point)
 942                  (prog2 (insert button) (point) (insert " "))
 943                  (list 'face gnus-carpal-header-face))
 944               (gnus-set-text-properties
 945                (point)
 946                (prog2 (insert (car button)) (point) (insert " "))
 947                (list 'gnus-callback (cdr button)
 948                      'face gnus-carpal-button-face
 949                      gnus-mouse-face-prop 'highlight))))
 950           (let ((fill-column (- (window-width) 2)))
 951             (fill-region (point-min) (point-max)))
 952           (set-window-point (get-buffer-window (current-buffer))
 953                             (point-min)))))))
 954
 955 (defun gnus-carpal-select ()
 956   "Select the button under point."
 957   (interactive)
 958   (let ((func (get-text-property (point) 'gnus-callback)))
 959     (if (null func)
 960         ()
 961       (pop-to-buffer (symbol-value gnus-carpal-attached-buffer))
 962       (call-interactively func))))
 963
 964 (defun gnus-carpal-mouse-select (event)
 965   "Select the button under the mouse pointer."
 966   (interactive "e")
 967   (mouse-set-point event)
 968   (gnus-carpal-select))
 969
 970 ;;; Allow redefinition of functions.
 971 (gnus-ems-redefine)
 972
 973 (provide 'gnus-salt)
 974
 975 ;;; gnus-salt.el ends here