cgit.sxemacs.org Git - gnus/blob - lisp/gnus-picon.el

   1 ;;; gnus-picon.el --- displaying pretty icons in Gnus
   2 ;; Copyright (C) 1996,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Wes Hardaker <hardaker@ece.ucdavis.edu>
   5 ;; Keywords: news xpm annotation glyph faces
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (require 'xpm)
  30 (require 'annotations)
  31 (require 'custom)
  32 (require 'gnus-art)
  33 (require 'gnus-win)
  34
  35 ;;; User variables:
  36
  37 (defgroup picons nil
  38   "Show pictures of people, domains, and newsgroups (XEmacs).
  39 For this to work, you must add gnus-group-display-picons to the
  40 gnus-summary-display-hook or to the gnus-article-display-hook
  41 depending on what gnus-picons-display-where is set to.  You must
  42 also add gnus-article-display-picons to gnus-article-display-hook."
  43   :group 'gnus-visual)
  44
  45 (defcustom gnus-picons-display-where 'picons
  46   "Where to display the group and article icons.
  47 Legal values are `article' and `picons'."
  48   :type '(choice symbol string)
  49   :group 'picons)
  50
  51 (defcustom gnus-picons-has-modeline-p t
  52   "*Whether the picons window should have a modeline.
  53 This is only useful if `gnus-picons-display-where' is `picons'."
  54   :type 'boolean
  55   :group 'picons)
  56
  57 (defcustom gnus-picons-database "/usr/local/faces"
  58   "*Defines the location of the faces database.
  59 For information on obtaining this database of pretty pictures, please
  60 see http://www.cs.indiana.edu/picons/ftp/index.html"
  61   :type 'directory
  62   :group 'picons)
  63
  64 (defcustom gnus-picons-news-directories '("news")
  65   "*List of directories to search for newsgroups faces."
  66   :type '(repeat string)
  67   :group 'picons)
  68 (define-obsolete-variable-alias 'gnus-picons-news-directory
  69   'gnus-picons-news-directories)
  70
  71 (defcustom gnus-picons-user-directories '("local" "users" "usenix" "misc")
  72   "*List of directories to search for user faces."
  73   :type '(repeat string)
  74   :group 'picons)
  75
  76 (defcustom gnus-picons-domain-directories '("domains")
  77   "*List of directories to search for domain faces.
  78 Some people may want to add \"unknown\" to this list."
  79   :type '(repeat string)
  80   :group 'picons)
  81
  82 (defcustom gnus-picons-refresh-before-display nil
  83   "*If non-nil, display the article buffer before computing the picons."
  84   :type 'boolean
  85   :group 'picons)
  86
  87 (defcustom gnus-picons-group-excluded-groups nil
  88   "*If this regexp matches the group name, group picons will be disabled."
  89   :type 'regexp
  90   :group 'picons)
  91
  92 (defcustom gnus-picons-x-face-file-name
  93   (format "/tmp/picon-xface.%s.xbm" (user-login-name))
  94   "*The name of the file in which to store the converted X-face header."
  95   :type 'string
  96   :group 'picons)
  97
  98 (defcustom gnus-picons-convert-x-face (format "{ echo '/* Width=48, Height=48 */'; uncompface; } | icontopbm | pbmtoxbm > %s" gnus-picons-x-face-file-name)
  99   "*Command to convert the x-face header into a xbm file."
 100   :type 'string
 101   :group 'picons)
 102
 103 (defcustom gnus-picons-display-as-address t
 104   "*If t display textual email addresses along with pictures."
 105   :type 'boolean
 106   :group 'picons)
 107
 108 (defcustom gnus-picons-file-suffixes
 109   (when (featurep 'x)
 110     (let ((types (list "xbm")))
 111       (when (featurep 'gif)
 112         (push "gif" types))
 113       (when (featurep 'xpm)
 114         (push "xpm" types))
 115       types))
 116   "*List of suffixes on picon file names to try."
 117   :type '(repeat string)
 118   :group 'picons)
 119
 120 (defcustom gnus-picons-display-article-move-p t
 121   "*Whether to move point to first empty line when displaying picons.
 122 This has only an effect if `gnus-picons-display-where' has value `article'."
 123   :type 'boolean
 124   :group 'picons)
 125
 126 (defcustom gnus-picons-clear-cache-on-shutdown t
 127   "*Whether to clear the picons cache when exiting gnus.
 128 Gnus caches every picons it finds while it is running.  This saves
 129 some time in the search process but eats some memory.  If this
 130 variable is set to nil, Gnus will never clear the cache itself; you
 131 will have to manually call `gnus-picons-clear-cache' to clear it.
 132 Otherwise the cache will be cleared every time you exit Gnus."
 133   :type 'boolean
 134   :group 'picons)
 135
 136 (defcustom gnus-picons-piconsearch-url nil
 137   "*The url to query for picons.  Setting this to nil will disable it.
 138 The only publicly available address currently known is
 139 http://www.cs.indiana.edu:800/piconsearch.  If you know of any other,
 140 please tell me so that we can list it."
 141   :type '(choice (const :tag "Disable" :value nil)
 142                  (const :tag "www.cs.indiana.edu"
 143                         :value "http://www.cs.indiana.edu:800/piconsearch")
 144                  (string))
 145   :group 'picons)
 146
 147 (defface gnus-picons-xbm-face
 148   '((((background dark))
 149      (:foreground "green" :background "black"))
 150     (t
 151      (:foreground "black" :background "blue")))
 152   "Face to show xbm picons in."
 153   :group 'picons)
 154
 155 ;;; Internal variables:
 156
 157 (defvar gnus-picons-processes-alist nil
 158   "Picons processes currently running and their environment.")
 159 (defvar gnus-picons-glyph-alist nil
 160   "Picons glyphs cache.
 161 List of pairs (KEY . GLYPH) where KEY is either a filename or an URL.")
 162 (defvar gnus-picons-url-alist nil
 163   "Picons file names cache.
 164 List of pairs (KEY . NAME) where KEY is (USER HOST DBS) and NAME is an URL.")
 165
 166 (defvar gnus-picons-jobs-alist nil
 167   "List of jobs that still need be done.
 168 This is a list of (SYM-ANN TAG ARGS...) where SYM-ANN three annotations list,
 169 TAG is one of `picon' or `search' indicating that the job should query a
 170 picon or do a search for picons file names, and ARGS is some additionnal
 171 arguments necessary for the job.")
 172
 173 (defvar gnus-picons-job-already-running nil
 174   "Lock to ensure only one stream of http requests is running.")
 175
 176 ;;; Functions:
 177
 178 (defun gnus-picons-remove-all ()
 179   "Removes all picons from the Gnus display(s)."
 180   (interactive)
 181   (map-extents (function (lambda (ext unused) (delete-annotation ext) nil))
 182                nil nil nil nil nil 'gnus-picon)
 183   (setq gnus-picons-jobs-alist '())
 184   ;; notify running job that it may have been preempted
 185   (if (and (listp gnus-picons-job-already-running)
 186            gnus-picons-job-already-running)
 187       (setq gnus-picons-job-already-running t)))
 188
 189 (defun gnus-get-buffer-name (variable)
 190   "Returns the buffer name associated with the contents of a variable."
 191   (let ((buf (gnus-get-buffer-create (gnus-window-to-buffer-helper
 192                                  (cdr
 193                                   (assq variable gnus-window-to-buffer))))))
 194     (and buf
 195          (buffer-name buf))))
 196
 197 (defun gnus-picons-buffer-name ()
 198   (cond ((or (stringp gnus-picons-display-where)
 199              (bufferp gnus-picons-display-where))
 200          gnus-picons-display-where)
 201         ((eq gnus-picons-display-where 'picons)
 202          (if gnus-single-article-buffer
 203              "*Picons*"
 204            (concat "*Picons " gnus-newsgroup-name "*")))
 205         (t
 206          (gnus-get-buffer-name gnus-picons-display-where))))
 207
 208 (defun gnus-picons-kill-buffer ()
 209   (let ((buf (get-buffer (gnus-picons-buffer-name))))
 210     (if (buffer-live-p buf)
 211         (kill-buffer buf))))
 212
 213 (defun gnus-picons-setup-buffer ()
 214   (let ((name (gnus-picons-buffer-name)))
 215     (save-excursion
 216       (if (get-buffer name)
 217           (set-buffer name)
 218         (set-buffer (gnus-get-buffer-create name))
 219         (buffer-disable-undo)
 220         (setq buffer-read-only t)
 221         (add-hook 'gnus-summary-prepare-exit-hook 'gnus-picons-kill-buffer))
 222       (current-buffer))))
 223
 224 (defun gnus-picons-set-buffer ()
 225   (set-buffer (gnus-picons-setup-buffer))
 226   (goto-char (point-min))
 227   (if (and (eq gnus-picons-display-where 'article)
 228            gnus-picons-display-article-move-p)
 229       (if (search-forward "\n\n" nil t)
 230           (forward-line -1)
 231         (goto-char (point-max)))
 232     (setq buffer-read-only t)
 233     (unless gnus-picons-has-modeline-p
 234       (set-specifier has-modeline-p
 235                      (list (list (current-buffer)
 236                                  (cons nil gnus-picons-has-modeline-p)))))))
 237
 238 (defun gnus-picons-prepare-for-annotations ()
 239   "Prepare picons buffer for putting annotations."
 240   ;; let drawing catch up
 241   (when gnus-picons-refresh-before-display
 242     (sit-for 0))
 243   (gnus-picons-set-buffer)
 244   (gnus-picons-remove-all))
 245
 246 (defun gnus-picons-make-annotation (&rest args)
 247   (let ((annot (apply 'make-annotation args)))
 248     (set-extent-property annot 'gnus-picon t)
 249     (set-extent-property annot 'duplicable t)
 250     annot))
 251
 252 (defun gnus-picons-article-display-x-face ()
 253   "Display the x-face header bitmap in the 'gnus-picons-display-where buffer."
 254   (let ((gnus-article-x-face-command 'gnus-picons-display-x-face))
 255     (gnus-article-display-x-face)))
 256
 257 (defun gnus-picons-x-face-sentinel (process event)
 258   (when (memq process gnus-picons-processes-alist)
 259     (setq gnus-picons-processes-alist
 260           (delq process gnus-picons-processes-alist))
 261     (gnus-picons-set-buffer)
 262     (gnus-picons-make-annotation (make-glyph gnus-picons-x-face-file-name)
 263                                  nil 'text)
 264     (when (file-exists-p gnus-picons-x-face-file-name)
 265       (delete-file gnus-picons-x-face-file-name))))
 266
 267 (defun gnus-picons-display-x-face (beg end)
 268   "Function to display the x-face header in the picons window.
 269 To use:  (setq gnus-article-x-face-command 'gnus-picons-display-x-face)"
 270   (interactive)
 271   (if (featurep 'xface)
 272       ;; Use builtin support
 273       (save-excursion
 274         ;; Don't remove this binding, it is really needed: when
 275         ;; `gnus-picons-set-buffer' changes buffer (like when it is
 276         ;; set to display picons outside of the article buffer), BEG
 277         ;; and END still refer the buffer current now !
 278         (let ((buf (current-buffer)))
 279           (gnus-picons-set-buffer)
 280           (gnus-picons-make-annotation
 281            (vector 'xface
 282                    :data (concat "X-Face: " (buffer-substring beg end buf)))
 283            nil 'text nil nil nil t)))
 284     ;; convert the x-face header to a .xbm file
 285     (let* ((process-connection-type nil)
 286            (process (start-process-shell-command "gnus-x-face" nil
 287                                                  gnus-picons-convert-x-face)))
 288       (push process gnus-picons-processes-alist)
 289       (process-kill-without-query process)
 290       (set-process-sentinel process 'gnus-picons-x-face-sentinel)
 291       (process-send-region process beg end)
 292       (process-send-eof process))))
 293
 294 (defun gnus-article-display-picons ()
 295   "Display faces for an author and her domain in gnus-picons-display-where."
 296   (interactive)
 297   (let (from at-idx)
 298     (when (and (featurep 'xpm)
 299                (or (not (fboundp 'device-type)) (equal (device-type) 'x))
 300                (setq from (mail-fetch-field "from"))
 301                (setq from (downcase (or (cadr (mail-extract-address-components
 302                                                from))
 303                                         "")))
 304                (or (setq at-idx (string-match "@" from))
 305                    (setq at-idx (length from))))
 306       (save-excursion
 307         (let ((username (downcase (substring from 0 at-idx)))
 308               (addrs (if (eq at-idx (length from))
 309                          (if gnus-local-domain
 310                              (message-tokenize-header gnus-local-domain "."))
 311                        (message-tokenize-header (substring from (1+ at-idx))
 312                                                 "."))))
 313           (gnus-picons-prepare-for-annotations)
 314           (gnus-group-display-picons)
 315           (if (null gnus-picons-piconsearch-url)
 316               (progn
 317                 (gnus-picons-display-pairs (gnus-picons-lookup-pairs
 318                                             addrs
 319                                             gnus-picons-domain-directories)
 320                                            gnus-picons-display-as-address
 321                                            "." t)
 322                 (if (and gnus-picons-display-as-address addrs)
 323                     (gnus-picons-make-annotation
 324                      [string :data "@"] nil 'text nil nil nil t))
 325                 (gnus-picons-display-picon-or-name
 326                  (gnus-picons-lookup-user username addrs)
 327                  username t))
 328             (push (list 'gnus-article-annotations 'search username addrs
 329                         gnus-picons-domain-directories t)
 330                   gnus-picons-jobs-alist)
 331             (gnus-picons-next-job)))))))
 332
 333 (defun gnus-group-display-picons ()
 334   "Display icons for the group in the `gnus-picons-display-where' buffer."
 335   (interactive)
 336   (when (and (featurep 'xpm)
 337              (or (not (fboundp 'device-type)) (equal (device-type) 'x))
 338              (or (null gnus-picons-group-excluded-groups)
 339                  (not (string-match gnus-picons-group-excluded-groups
 340                                     gnus-newsgroup-name))))
 341     (save-excursion
 342       (gnus-picons-prepare-for-annotations)
 343       (if (null gnus-picons-piconsearch-url)
 344           (gnus-picons-display-pairs
 345                  (gnus-picons-lookup-pairs
 346                   (reverse (message-tokenize-header
 347                             (gnus-group-real-name gnus-newsgroup-name)
 348                             "."))
 349                   gnus-picons-news-directories)
 350                  t ".")
 351         (push (list 'gnus-group-annotations 'search nil
 352                     (message-tokenize-header
 353                      (gnus-group-real-name gnus-newsgroup-name) ".")
 354                     (if (listp gnus-picons-news-directories)
 355                         gnus-picons-news-directories
 356                       (list gnus-picons-news-directories))
 357                     nil)
 358               gnus-picons-jobs-alist)
 359         (gnus-picons-next-job))
 360
 361       (add-hook 'gnus-summary-exit-hook 'gnus-picons-remove-all))))
 362
 363 (defun gnus-picons-lookup-internal (addrs dir)
 364   (setq dir (expand-file-name dir gnus-picons-database))
 365   (gnus-picons-try-face (dolist (part (reverse addrs) dir)
 366                           (setq dir (expand-file-name part dir)))))
 367
 368 (defun gnus-picons-lookup (addrs dirs)
 369   "Lookup the picon for ADDRS in databases DIRS.
 370 Returns the picon filename or NIL if none found."
 371   (let (result)
 372     (while (and dirs (null result))
 373       (setq result (gnus-picons-lookup-internal addrs (pop dirs))))
 374     result))
 375
 376 (defun gnus-picons-lookup-user-internal (user domains)
 377   (let ((dirs gnus-picons-user-directories)
 378         domains-tmp dir picon)
 379     (while (and dirs (null picon))
 380       (setq domains-tmp domains
 381             dir (pop dirs))
 382       (while (and domains-tmp
 383                   (null (setq picon (gnus-picons-lookup-internal
 384                                      (cons user domains-tmp) dir))))
 385         (pop domains-tmp))
 386       ;; Also make a try in MISC subdir
 387       (unless picon
 388         (setq picon (gnus-picons-lookup-internal (list user "MISC") dir))))
 389     picon))
 390
 391 (defun gnus-picons-lookup-user (user domains)
 392   "Lookup the picon for USER at DOMAINS.
 393 USER is a string containing a name.
 394 DOMAINS is a list of strings from the fully qualified domain name."
 395   (or (gnus-picons-lookup-user-internal user domains)
 396       (gnus-picons-lookup-user-internal "unknown" domains)))
 397
 398 (defun gnus-picons-lookup-pairs (domains directories)
 399   "Lookup picons for DOMAINS and all its parents in DIRECTORIES.
 400 Returns a list of PAIRS whose CAR is the picon filename or NIL if
 401 none, and whose CDR is the corresponding element of DOMAINS."
 402   (let (picons)
 403     (setq directories (if (listp directories)
 404                           directories
 405                         (list directories)))
 406     (while domains
 407       (push (list (gnus-picons-lookup (cons "unknown" domains) directories)
 408                   (pop domains))
 409             picons))
 410     picons))
 411
 412 (defun gnus-picons-display-picon-or-name (picon name &optional right-p)
 413   (cond (picon (gnus-picons-display-glyph picon name right-p))
 414         (gnus-picons-display-as-address (list (gnus-picons-make-annotation
 415                                                (vector 'string :data name)
 416                                                nil 'text
 417                                                nil nil nil right-p)))))
 418
 419 (defun gnus-picons-display-pairs (pairs &optional bar-p dot-p right-p)
 420   "Display picons in list PAIRS."
 421   (let ((domain-p (and gnus-picons-display-as-address dot-p))
 422         pair picons)
 423     (when (and bar-p domain-p right-p)
 424       (setq picons (gnus-picons-display-glyph
 425                     (let ((gnus-picons-file-suffixes '("xbm")))
 426                       (gnus-picons-try-face
 427                        gnus-xmas-glyph-directory "bar."))
 428                     nil right-p)))
 429     (while (setq pair (pop pairs))
 430       (setq picons (nconc picons
 431                           (gnus-picons-display-picon-or-name
 432                            (car pair) (cadr pair) right-p)
 433                           (if (and domain-p pairs)
 434                               (list (gnus-picons-make-annotation
 435                                      (vector 'string :data dot-p)
 436                                      nil 'text nil nil nil right-p))))))
 437     picons))
 438
 439 (defun gnus-picons-try-face (dir &optional filebase)
 440   (let* ((dir (file-name-as-directory dir))
 441          (filebase (or filebase "face."))
 442          (key (concat dir filebase))
 443          (glyph (cdr (assoc key gnus-picons-glyph-alist)))
 444          (suffixes gnus-picons-file-suffixes)
 445          f suf)
 446     (while (setq suf (pop suffixes))
 447       (when (file-exists-p (setq f (expand-file-name
 448                                     (concat filebase suf)
 449                                     dir)))
 450         (setq suffixes nil
 451               glyph (make-glyph f))
 452         (when (equal suf "xbm")
 453           (set-glyph-face glyph 'gnus-picons-xbm-face))
 454         (push (cons key glyph) gnus-picons-glyph-alist)))
 455     glyph))
 456
 457 (defun gnus-picons-display-glyph (glyph &optional part rightp)
 458   (let ((new (gnus-picons-make-annotation
 459               glyph (point) 'text nil nil nil rightp)))
 460     (when (and part gnus-picons-display-as-address)
 461       (set-annotation-data
 462        new (cons new (make-glyph (vector 'string :data part))))
 463       (set-annotation-action new 'gnus-picons-action-toggle))
 464     (nconc
 465      (list new)
 466      (if (and (eq major-mode 'gnus-article-mode)
 467               (not gnus-picons-display-as-address)
 468               (not part))
 469          (list (gnus-picons-make-annotation [string :data " "] (point)
 470                                             'text nil nil nil rightp))))))
 471
 472 (defun gnus-picons-action-toggle (data)
 473   "Toggle annotation."
 474   (interactive "e")
 475   (let* ((annot (car data))
 476          (glyph (annotation-glyph annot)))
 477     (set-annotation-glyph annot (cdr data))
 478     (set-annotation-data annot (cons annot glyph))))
 479
 480 (defun gnus-picons-clear-cache ()
 481   "Clear the picons cache."
 482   (interactive)
 483   (setq gnus-picons-glyph-alist nil
 484         gnus-picons-url-alist nil))
 485
 486 (gnus-add-shutdown 'gnus-picons-close 'gnus)
 487
 488 (defun gnus-picons-close ()
 489   "Shut down the picons."
 490   (if gnus-picons-clear-cache-on-shutdown
 491       (gnus-picons-clear-cache)))
 492
 493 ;;; Query a remote DB.  This requires some stuff from w3 !
 494
 495 (require 'url)
 496 (require 'w3-forms)
 497
 498 (defun gnus-picons-url-retrieve (url fn arg)
 499   (let ((old-asynch (default-value 'url-be-asynchronous))
 500         (url-working-buffer (generate-new-buffer " *picons*"))
 501         (url-package-name "Gnus")
 502         (url-package-version gnus-version-number)
 503         url-request-method)
 504     (setq-default url-be-asynchronous t)
 505     (save-excursion
 506       (set-buffer url-working-buffer)
 507       (setq url-be-asynchronous t
 508             url-current-callback-data arg
 509             url-current-callback-func fn)
 510       (url-retrieve url t))
 511     (setq-default url-be-asynchronous old-asynch)))
 512
 513 (defun gnus-picons-make-glyph (type)
 514   "Make a TYPE glyph using current buffer as data.  Handles xbm nicely."
 515   (cond ((null type) nil)
 516         ((eq type 'xbm) (let ((fname (make-temp-name "/tmp/picon")))
 517                           (write-region (point-min) (point-max) fname
 518                                         nil 'quiet)
 519                           (prog1 (make-glyph (vector 'xbm :file fname))
 520                             (delete-file fname))))
 521         (t (make-glyph (vector type :data (buffer-string))))))
 522
 523 ;;; Parsing of piconsearch result page.
 524
 525 ;; Assumes:
 526 ;; 1 - each value field has the form: "<strong>key</strong> = <kbd>value</kbd>"
 527 ;; 2 - a "<p>" separates the keywords from the results
 528 ;; 3 - every results begins by the path within the database at the beginning
 529 ;;     of the line in raw text.
 530 ;; 3b - and the href following it is the preferred image type.
 531
 532 ;; if 1 or 2 is not met, it will probably cause an error.  The other
 533 ;; will go undetected
 534
 535 (defun gnus-picons-parse-value (name)
 536   (goto-char (point-min))
 537   (re-search-forward (concat "<strong>"
 538                              (regexp-quote name)
 539                              "</strong> *= *<kbd> *\\([^ <][^<]*\\) *</kbd>"))
 540   (buffer-substring (match-beginning 1) (match-end 1)))
 541
 542 (defun gnus-picons-parse-filenames ()
 543   ;; returns an alist of ((USER ADDRS DB) . URL)
 544   (let* ((case-fold-search t)
 545          (user (gnus-picons-parse-value "user"))
 546          (host (gnus-picons-parse-value "host"))
 547          (dbs (message-tokenize-header (gnus-picons-parse-value "db") " "))
 548          (start-re
 549           (concat
 550            ;; dbs
 551            "^\\(" (mapconcat 'identity dbs "\\|") "\\)/"
 552            ;; host
 553            "\\(\\(" (replace-in-string host "\\." "/\\|" t) "/\\|MISC/\\)*\\)"
 554            ;; user
 555            "\\(" (regexp-quote user) "\\|unknown\\)/"
 556            "face\\."))
 557          cur-db cur-host cur-user types res)
 558     ;; now point will be somewhere in the header.  Find beginning of
 559     ;; entries
 560     (re-search-forward "<p>[ \t\n]*")
 561     (while (re-search-forward start-re nil t)
 562       (setq cur-db (buffer-substring (match-beginning 1) (match-end 1))
 563             cur-host (buffer-substring (match-beginning 2) (match-end 2))
 564             cur-user (buffer-substring (match-beginning 4) (match-end 4))
 565             cur-host (nreverse (message-tokenize-header cur-host "/")))
 566       ;; XXX - KLUDGE: there is a blank picon in news/MISC/unknown
 567       (unless (and (string-equal cur-db "news")
 568                    (string-equal cur-user "unknown")
 569                    (equal cur-host '("MISC")))
 570         ;; ok now we have found an entry (USER HOST DB), find the
 571         ;; corresponding picon URL
 572         (save-restriction
 573           ;; restrict region to this entry
 574           (narrow-to-region (point) (search-forward "<br>"))
 575           (goto-char (point-min))
 576           (setq types gnus-picons-file-suffixes)
 577           (while (and types
 578                       (not (re-search-forward
 579                             (concat "<a[ \t\n]+href=\"\\([^\"]*\\."
 580                                     (regexp-quote (car types)) "\\)\"")
 581                             nil t)))
 582             (pop types))
 583           (push (cons (list cur-user cur-host cur-db)
 584                       (buffer-substring (match-beginning 1) (match-end 1)))
 585                 res))))
 586     (nreverse res)))
 587
 588 ;;; picon network display functions :
 589
 590 (defun gnus-picons-network-display-internal (sym-ann glyph part right-p)
 591   (gnus-picons-set-buffer)
 592   (gnus-picons-display-picon-or-name glyph part right-p)
 593   (gnus-picons-next-job-internal))
 594
 595 (defun gnus-picons-network-display-callback (url part sym-ann right-p)
 596   (let ((glyph (gnus-picons-make-glyph (cdr (assoc url-current-mime-type
 597                                                    w3-image-mappings)))))
 598     (kill-buffer (current-buffer))
 599     (push (cons url glyph) gnus-picons-glyph-alist)
 600     ;; only do the job if it has not been preempted.
 601     (if (equal gnus-picons-job-already-running
 602                (list sym-ann 'picon url part right-p))
 603         (gnus-picons-network-display-internal sym-ann glyph part right-p)
 604       (gnus-picons-next-job-internal))))
 605
 606 (defun gnus-picons-network-display (url part sym-ann right-p)
 607   (let ((cache (assoc url gnus-picons-glyph-alist)))
 608     (if (or cache (null url))
 609         (gnus-picons-network-display-internal sym-ann (cdr cache) part right-p)
 610       (gnus-picons-url-retrieve url 'gnus-picons-network-display-callback
 611                                 (list url part sym-ann right-p)))))
 612
 613 ;;; search job functions
 614
 615 (defun gnus-picons-network-search-internal (user addrs dbs sym-ann right-p
 616                                                  &optional fnames)
 617   (let (curkey dom pfx url dbs-tmp cache new-jobs)
 618     ;; First do the domain search
 619     (dolist (part (if right-p
 620                       (reverse addrs)
 621                     addrs))
 622       (setq pfx (nconc (list part) pfx)
 623             dom (cond ((and dom right-p) (concat part "." dom))
 624                       (dom (concat dom "." part))
 625                       (t part))
 626             curkey (list "unknown" dom dbs))
 627       (when (null (setq cache (assoc curkey gnus-picons-url-alist)))
 628         ;; This one is not yet in the cache, create a new entry
 629         ;; Search for an entry
 630         (setq dbs-tmp dbs
 631               url nil)
 632         (while (and dbs-tmp (null url))
 633           (setq url (or (cdr (assoc (list "unknown" pfx (car dbs-tmp)) fnames))
 634                         (and (eq dom part)
 635                              ;; This is the first component.  Try the
 636                              ;; catch-all MISC component
 637                              (cdr (assoc (list "unknown"
 638                                                '("MISC")
 639                                                (car dbs-tmp))
 640                                          fnames)))))
 641           (pop dbs-tmp))
 642         (push (setq cache (cons curkey url)) gnus-picons-url-alist))
 643       ;; Put this glyph in the job list
 644       (if (and (not (eq dom part)) gnus-picons-display-as-address)
 645           (push (list sym-ann "." right-p) new-jobs))
 646       (push (list sym-ann 'picon (cdr cache) part right-p) new-jobs))
 647     ;; next, the user search
 648     (when user
 649       (setq curkey (list user dom gnus-picons-user-directories))
 650       (if (null (setq cache (assoc curkey gnus-picons-url-alist)))
 651           (let ((users (list user "unknown"))
 652                 dirs usr domains-tmp dir picon)
 653             (while (and users (null picon))
 654               (setq dirs gnus-picons-user-directories
 655                     usr (pop users))
 656               (while (and dirs (null picon))
 657                 (setq domains-tmp addrs
 658                       dir (pop dirs))
 659                 (while (and domains-tmp
 660                             (null (setq picon (assoc (list usr domains-tmp dir)
 661                                                      fnames))))
 662                   (pop domains-tmp))
 663                 (unless picon
 664                   (setq picon (assoc (list usr '("MISC") dir) fnames)))))
 665             (push (setq cache (cons curkey (cdr picon)))
 666                   gnus-picons-url-alist)))
 667       (if (and gnus-picons-display-as-address new-jobs)
 668           (push (list sym-ann "@" right-p) new-jobs))
 669       (push (list sym-ann 'picon (cdr cache) user right-p) new-jobs))
 670     (if (and gnus-picons-display-as-address (not right-p))
 671         (push (list sym-ann 'bar right-p) new-jobs))
 672     ;; only put the jobs in the queue if this job has not been preempted.
 673     (if (equal gnus-picons-job-already-running
 674                (list sym-ann 'search user addrs dbs right-p))
 675         (setq gnus-picons-jobs-alist
 676               (nconc (if (and gnus-picons-display-as-address right-p)
 677                          (list (list sym-ann 'bar right-p)))
 678                      (nreverse new-jobs)
 679                      gnus-picons-jobs-alist)))
 680     (gnus-picons-next-job-internal)))
 681
 682 (defun gnus-picons-network-search-callback (user addrs dbs sym-ann right-p)
 683   (gnus-picons-network-search-internal user addrs dbs sym-ann right-p
 684                                        (prog1 (gnus-picons-parse-filenames)
 685                                          (kill-buffer (current-buffer)))))
 686
 687 ;; Initiate a query on the picon database
 688 (defun gnus-picons-network-search (user addrs dbs sym-ann right-p)
 689   (let* ((host (mapconcat 'identity addrs "."))
 690          (key (list (or user "unknown") host (if user
 691                                                   gnus-picons-user-directories
 692                                                 dbs)))
 693          (cache (assoc key gnus-picons-url-alist)))
 694     (if (null cache)
 695         (gnus-picons-url-retrieve
 696          (concat gnus-picons-piconsearch-url
 697                  "?user=" (w3-form-encode-xwfu (or user "unknown"))
 698                  "&host=" (w3-form-encode-xwfu host)
 699                  "&db=" (mapconcat 'w3-form-encode-xwfu
 700                                    (if user
 701                                        (append dbs
 702                                                gnus-picons-user-directories)
 703                                      dbs)
 704                                    "+"))
 705          'gnus-picons-network-search-callback
 706          (list user addrs dbs sym-ann right-p))
 707       (gnus-picons-network-search-internal user addrs dbs sym-ann right-p))))
 708
 709 ;;; Main jobs dispatcher function
 710
 711 (defun gnus-picons-next-job-internal ()
 712   (if (setq gnus-picons-job-already-running (pop gnus-picons-jobs-alist))
 713       (let* ((job gnus-picons-job-already-running)
 714              (sym-ann (pop job))
 715              (tag (pop job)))
 716         (if tag
 717             (cond ((stringp tag);; (SYM-ANN "..." RIGHT-P)
 718                    (gnus-picons-network-display-internal sym-ann nil tag
 719                                                          (pop job)))
 720                   ((eq 'bar tag)
 721                    (gnus-picons-network-display-internal
 722                     sym-ann
 723                     (let ((gnus-picons-file-suffixes '("xbm")))
 724                       (gnus-picons-try-face
 725                        gnus-xmas-glyph-directory "bar."))
 726                     nil (pop job)))
 727                   ((eq 'search tag);; (SYM-ANN 'search USER ADDRS DBS RIGHT-P)
 728                    (gnus-picons-network-search
 729                     (pop job) (pop job) (pop job) sym-ann (pop job)))
 730                   ((eq 'picon tag);; (SYM-ANN 'picon URL PART RIGHT-P)
 731                    (gnus-picons-network-display
 732                     (pop job) (pop job) sym-ann (pop job)))
 733                   (t (setq gnus-picons-job-already-running nil)
 734                      (error "Unknown picon job tag %s" tag)))))))
 735
 736 (defun gnus-picons-next-job ()
 737   "Start processing the job queue if it is not in progress."
 738   (unless gnus-picons-job-already-running
 739     (gnus-picons-next-job-internal)))
 740
 741 (provide 'gnus-picon)
 742
 743 ;;; gnus-picon.el ends here